configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [1])
   4 m4_define([v_min], [6])
   5 m4_define([v_mic], [99])
   6 m4_define([v_rev], m4_esyscmd([(svnversion "${SVN_REPO_PATH:-.}" | grep -v '\(export\|Unversioned directory\)' || echo 0) | awk -F : '{printf("%s\n", $1);}' | tr -d ' :MSP\n']))
   7 m4_if(v_rev, [0], [m4_define([v_rev], m4_esyscmd([git log 2> /dev/null | (grep -m1 git-svn-id || echo 0) | sed -e 's/.*@\([0-9]*\).*/\1/' | tr -d '\n']))])
   8 ##--   When released, remove the dnl on the below line
   9 dnl m4_undefine([v_rev])
  10 ##--   When doing snapshots - change soname. remove dnl on below line
  11 dnl m4_define([relname], [ver-pre-svn-07])
  12 dnl m4_define([v_rel], [-release relname])
  13 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  14 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])], [m4_define([v_ver], [v_maj.v_min.v_mic])])
  15 m4_define([lt_cur], m4_eval(v_maj + v_min))
  16 m4_define([lt_rev], v_mic)
  17 m4_define([lt_age], v_min)
  18 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  19 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  20
  21 AC_INIT([eina], [v_ver], [enlightenment-devel@lists.sourceforge.net])
  22 AC_PREREQ([2.59])
  23 AC_CONFIG_SRCDIR([configure.ac])
  24 AC_CONFIG_MACRO_DIR([m4])
  25
  26 AC_CONFIG_HEADERS([config.h])
  27 AH_TOP([
  28 #ifndef EFL_CONFIG_H__
  29 #define EFL_CONFIG_H__
  30 ])
  31 AH_BOTTOM([
  32 #endif /* EFL_CONFIG_H__ */
  33 ])
  34
  35 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 AC_GNU_SOURCE
  39 AC_SYS_LARGEFILE
  40
  41 AC_LIBTOOL_WIN32_DLL
  42 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  43 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  44 AC_PROG_LIBTOOL
  45
  46 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  47 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  48 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  49 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  50 AC_DEFINE_UNQUOTED(VMAJ, [v_maj], [Major version])
  51 AC_DEFINE_UNQUOTED(VMIN, [v_min], [Minor version])
  52 AC_DEFINE_UNQUOTED(VMIC, [v_mic], [Micro version])
  53 AC_DEFINE_UNQUOTED(VREV, [v_rev], [Revison])
  54 version_info="lt_cur:lt_rev:lt_age"
  55 release_info="v_rel"
  56 AC_SUBST(version_info)
  57 AC_SUBST(release_info)
  58 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  59 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  60 VMAJ=v_maj
  61 AC_SUBST(VMAJ)
  62
  63
  64 ### Needed information
  65
  66 AC_CANONICAL_BUILD
  67 AC_CANONICAL_HOST
  68
  69 requirements_pc_eina=""
  70
  71 have_wince="no"
  72 have_win32="no"
  73 case "$host_os" in
  74    mingw32ce*)
  75       have_win32="yes"
  76       have_wince="yes"
  77       MODULE_ARCH="$host_os-$host_cpu"
  78       MODULE_EXT=".dll"
  79       ;;
  80    mingw*)
  81       have_win32="yes"
  82       MODULE_ARCH="$host_os-$host_cpu-v_maj.v_min.v_mic"
  83       MODULE_EXT=".dll"
  84       ;;
  85    *)
  86       MODULE_ARCH="$host_os-$host_cpu-v_maj.v_min.v_mic"
  87       MODULE_EXT=".so"
  88       ;;
  89 esac
  90 AM_CONDITIONAL([EINA_HAVE_WINCE], [test "x$have_wince" = "xyes"])
  91 AM_CONDITIONAL([EINA_HAVE_WIN32], [test "x$have_win32" = "xyes"])
  92 AC_SUBST([MODULE_ARCH])
  93 AC_DEFINE_UNQUOTED([MODULE_ARCH], ["${MODULE_ARCH}"], ["Module architecture"])
  94 AC_DEFINE_UNQUOTED([SHARED_LIB_SUFFIX], ["${MODULE_EXT}"], [Suffix for shared objects])
  95
  96 EFL_CHECK_CPU_MMX([have_mmx="yes"], [have_mmx="no"])
  97 EFL_CHECK_CPU_SSE([have_sse="yes"], [have_sse="no"])
  98 EFL_CHECK_CPU_SSE2([have_sse2="yes"], [have_sse2="no"])
  99 EFL_CHECK_CPU_ALTIVEC([have_altivec="yes"], [have_altivec="no"])
 100
 101 EFL_CHECK_THREADS
 102
 103 if ! test "x${efl_have_threads}" = "xno" ; then
 104    EINA_CONFIGURE_HAVE_THREADS="#define EINA_HAVE_THREADS"
 105 fi
 106 AC_SUBST(EINA_CONFIGURE_HAVE_THREADS)
 107 AM_CONDITIONAL([EINA_HAVE_THREADS], [! test "x${efl_have_threads}" = "xno"])
 108
 109 if test "x${efl_have_debug_threads}" = "xyes"; then
 110    EINA_CONFIGURE_HAVE_DEBUG_THREADS="#define EINA_HAVE_DEBUG_THREADS"
 111 fi
 112 AC_SUBST(EINA_CONFIGURE_HAVE_DEBUG_THREADS)
 113 AM_CONDITIONAL([EINA_DEBUG_THREADS], [test "x${efl_have_debug_threads}" = "xyes"])
 114
 115 if ! test "x${efl_have_on_off_threads}" = "xno"; then
 116    EINA_CONFIGURE_HAVE_ON_OFF_THREADS="#define EINA_HAVE_ON_OFF_THREADS"
 117 fi
 118 AC_SUBST(EINA_CONFIGURE_HAVE_ON_OFF_THREADS)
 119 AM_CONDITIONAL([EINA_ON_OFF_THREADS], [! test "x${efl_have_on_off_threads}" = "xno"])
 120
 121 ### Additional options to configure
 122
 123 # Magic debug
 124 AC_ARG_ENABLE([magic-debug],
 125    [AC_HELP_STRING([--disable-magic-debug], [disable magic debug of eina structure @<:@default=enabled@:>@])],
 126    [
 127     if test "x${enableval}" = "xyes" ; then
 128        have_magic_debug="yes"
 129     else
 130        have_magic_debug="no"
 131     fi
 132    ],
 133    [have_magic_debug="yes"])
 134
 135 AC_MSG_CHECKING([whether magic debug is enable])
 136 AC_MSG_RESULT([${have_magic_debug}])
 137
 138 if test "x${have_magic_debug}" = "xyes" ; then
 139    EINA_CONFIGURE_MAGIC_DEBUG="#define EINA_MAGIC_DEBUG"
 140 fi
 141 AC_SUBST(EINA_CONFIGURE_MAGIC_DEBUG)
 142
 143 # Safety checks (avoid crashes on wrong api usage)
 144 AC_ARG_ENABLE(safety-checks,
 145    [AC_HELP_STRING([--disable-safety-checks], [disable safety checks for NULL pointers and like. @<:@default=enabled@:>@])],
 146    [
 147     if test "x${enableval}" = "xyes" ; then
 148        have_safety_checks="yes"
 149     else
 150        have_safety_checks="no"
 151     fi
 152    ],
 153    [have_safety_checks="yes"])
 154
 155 AC_MSG_CHECKING(whether to do safety checking on api parameters)
 156 AC_MSG_RESULT($have_safety_checks)
 157
 158 AM_CONDITIONAL(SAFETY_CHECKS, test "x$have_safety_checks" = "xyes")
 159 if test "x$have_safety_checks" = "xyes"; then
 160   AC_DEFINE(EINA_SAFETY_CHECKS, 1, [disable safety checks for NULL pointers and like.])
 161   EINA_CONFIGURE_SAFETY_CHECKS="#define EINA_SAFETY_CHECKS"
 162 fi
 163 AC_SUBST(EINA_CONFIGURE_SAFETY_CHECKS)
 164
 165 with_max_log_level="<unset>"
 166 AC_ARG_WITH(internal-maximum-log-level,
 167    [AC_HELP_STRING([--with-internal-maximum-log-level=NUMBER],
 168                    [limit eina internal log level to the given number, any call to EINA_LOG() with values greater than this will be compiled out, ignoring runtime settings, but saving function calls.])],
 169    [
 170     if test "x${withval}" != "xno"; then
 171        if echo "${withval}" | grep -E '^[[0-9]]+$' >/dev/null 2>/dev/null; then
 172           AC_MSG_NOTICE([ignoring any EINA_LOG() with level greater than ${withval}])
 173           AC_DEFINE_UNQUOTED(EINA_LOG_LEVEL_MAXIMUM, ${withval}, [if set, logging is limited to this amount.])
 174           with_max_log_level="${withval}"
 175        else
 176           AC_MSG_ERROR([--with-internal-maximum-log-level takes a decimal number, got "${withval}" instead.])
 177        fi
 178     fi
 179     ], [:])
 180
 181 AC_ARG_ENABLE([amalgamation],
 182    [AC_HELP_STRING([--enable-amalgamation], [enable generation of one single file with all source code in it, helps compiler optimizations.])],
 183    [if test "x${enableval}" = "xyes"; then
 184        do_amalgamation="yes"
 185     else
 186        do_amalgamation="no"
 187     fi
 188    ],
 189    [do_amalgamation="no"]
 190 )
 191 AM_CONDITIONAL(EINA_AMALGAMATION, test "x${do_amalgamation}" = "xyes")
 192
 193 # Choose best memory pool
 194 AC_ARG_ENABLE([default-mempool],
 195    [AC_HELP_STRING([--enable-default-mempool], [Default memory allocator could be faster for some computer. @<:@default=disabled@:>@])],
 196    [
 197     if test "x${enableval}" = "xyes"; then
 198        have_default_mempool="yes"
 199     else
 200        have_default_mempool="no"
 201     fi
 202    ],
 203    [have_default_mempool="no"]
 204 )
 205 AC_MSG_CHECKING([whether to use default mempool allocator])
 206 AC_MSG_RESULT([${have_default_mempool}])
 207
 208 if test "x${have_default_mempool}" = "xyes" ; then
 209    EINA_CONFIGURE_DEFAULT_MEMPOOL="#define EINA_DEFAULT_MEMPOOL"
 210 fi
 211 AC_SUBST(EINA_CONFIGURE_DEFAULT_MEMPOOL)
 212
 213 # Report stringshare usage
 214 AC_ARG_ENABLE([stringshare-usage],
 215    [AC_HELP_STRING([--enable-stringshare-usage], [Report stringshare usage on stringshare shutdown. @<:@default=disabled@:>@])],
 216    [
 217     if test "x${enableval}" = "xyes"; then
 218        have_stringshare_usage="yes"
 219     else
 220        have_stringshare_usage="no"
 221     fi
 222    ],
 223    [have_stringshare_usage="no"]
 224 )
 225 AC_MSG_CHECKING([whether to report stringshare usage])
 226 AC_MSG_RESULT([${have_stringshare_usage}])
 227
 228 if test "x${have_stringshare_usage}" = "xyes"; then
 229    AC_DEFINE(EINA_STRINGSHARE_USAGE, 1, [Report Eina stringshare usage pattern])
 230 fi
 231
 232 # Assert or fail.
 233
 234 AC_ARG_ENABLE([assert],
 235    [AC_HELP_STRING([--enable-assert], [enable assert, @<:@default=no@:>@])],
 236    [
 237     if test "x${enableval}" = "xyes" ; then
 238        prefer_assert="yes"
 239     else
 240        prefer_assert="no"
 241     fi
 242    ],
 243    [prefer_assert="no"])
 244
 245 # Check if we want to benchmark on real data
 246 enable_benchmark_e17="no"
 247 AC_ARG_ENABLE([e17],
 248    [AC_HELP_STRING([--enable-e17], [enable heavy benchmark @<:@default=no@:>@])],
 249    [
 250     if test "x${enableval}" = "xyes" ; then
 251        enable_benchmark_e17="yes"
 252     else
 253        enable_benchmark_e17="no"
 254     fi
 255    ],
 256    [enable_benchmark_e17="no"])
 257
 258 AC_MSG_CHECKING([whether e17 real data benchmark are built])
 259 AC_MSG_RESULT([${enable_benchmark_e17}])
 260
 261 AM_CONDITIONAL(EINA_ENABLE_BENCHMARK_E17, test "x${enable_benchmark_e17}" = "xyes")
 262
 263
 264 ### Checks for programs
 265 AC_PROG_CC
 266 #for src/tests...
 267 AC_PROG_CXX
 268
 269 # pkg-config
 270 PKG_PROG_PKG_CONFIG
 271
 272 # Check whether pkg-config supports Requires.private
 273 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
 274    pkgconfig_requires_private="Requires.private"
 275 else
 276    pkgconfig_requires_private="Requires"
 277 fi
 278 AC_SUBST(pkgconfig_requires_private)
 279
 280 # doxygen program for documentation building
 281
 282 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 283
 284
 285 ### Checks for libraries
 286
 287 ## Compatibility layers
 288
 289 # Evil library for compilation on Windows
 290
 291 EFL_EINA_BUILD=""
 292 case "$host_os" in
 293    mingw*)
 294       PKG_CHECK_EXISTS([evil >= 1.6.99])
 295       AC_DEFINE([HAVE_EVIL], [1], [Set to 1 if Evil package is installed])
 296       requirements_pc_eina="${requirements_pc_eina} evil"
 297       EFL_EINA_BUILD="-DEFL_EINA_BUILD"
 298    ;;
 299 esac
 300 AC_SUBST([EFL_EINA_BUILD])
 301
 302 # Escape library for compilation on Playstation 3
 303
 304 case "$host_vendor" in
 305   ps3*)
 306       PKG_CHECK_EXISTS([escape])
 307       AC_DEFINE([HAVE_ESCAPE], [1], [Set to 1 if Escape package is installed])
 308       requirements_pc_eina="${requirements_pc_eina} escape"
 309     ;;
 310 esac
 311
 312 # Exotic library for copilation on Coyote
 313
 314 PKG_CHECK_EXISTS([exotic],
 315    [
 316     enable_exotic="yes"
 317     AC_DEFINE([HAVE_EXOTIC_H], [1], [Define to 1 if you have Exotic.])
 318     EINA_CONFIGURE_HAVE_EXOTIC="#define EINA_HAVE_EXOTIC"
 319     requirements_pc_eina="exotic ${requirements_pc_eina}"
 320    ],
 321    [enable_exotic="no"])
 322
 323 AM_CONDITIONAL([EINA_HAVE_EXOTIC], [test "x${enable_exotic}" = "xyes"])
 324 AC_SUBST([EINA_CONFIGURE_HAVE_EXOTIC])
 325
 326 if ! test "x${requirements_pc_eina}" = "x" ; then
 327    PKG_CHECK_MODULES([EINA], [${requirements_pc_eina}])
 328 fi
 329
 330 ## Options
 331
 332 # Valgrind
 333
 334 AC_ARG_ENABLE([valgrind],
 335    [AC_HELP_STRING([--enable-valgrind], [improve valgrind support by hinting it of our memory usages, having it to report proper mempool leaks.])],
 336    [
 337     if test "x${enableval}" = "xyes" ; then
 338        want_valgrind="yes"
 339     else
 340        want_valgrind="no"
 341     fi
 342    ],
 343    [want_valgrind="auto"])
 344
 345 AC_MSG_CHECKING([whether to enable build with valgrind])
 346 AC_MSG_RESULT([${want_valgrind}])
 347
 348 if test "x${want_valgrind}" = "xyes" || test "x${want_valgrind}" = "xauto"; then
 349    PKG_CHECK_MODULES([VALGRIND], [valgrind >= 2.4.0],
 350       [
 351        have_valgrind="yes"
 352        requirements_pc_eina="valgrind ${requirements_pc_eina}"
 353       ],
 354       [
 355        have_valgrind="no"
 356        AC_DEFINE([NVALGRIND], [1], [Valgrind support disabled])
 357        if test "x${want_valgrind}" = "xyes"; then
 358           AC_MSG_ERROR([Valgrind >= 2.4.0 is required])
 359        fi
 360       ])
 361 else
 362     AC_DEFINE([NVALGRIND], [1], [Valgrind support disabled])
 363 fi
 364
 365 ## Modules
 366
 367 # Check ememoa memory pool library
 368
 369 AC_ARG_ENABLE([ememoa],
 370    [AC_HELP_STRING([--enable-ememoa], [build ememoa memory pool module @<:@default=yes@:>@])],
 371    [
 372     if test "x${enableval}" = "xyes" ; then
 373        enable_ememoa="yes"
 374     else
 375        enable_ememoa="no"
 376     fi
 377    ],
 378    [enable_ememoa="yes"])
 379
 380 AC_MSG_CHECKING([whether to use ememoa for memory pool])
 381 AC_MSG_RESULT([${enable_ememoa}])
 382
 383 if test "x${enable_ememoa}" = "xyes" ; then
 384    PKG_CHECK_MODULES([EMEMOA],
 385       [ememoa >= 0.0.26 ],
 386       [enable_ememoa="yes"],
 387       [enable_ememoa="no"])
 388 fi
 389
 390 ## Examples
 391
 392 PKG_CHECK_MODULES([ECORE_EVAS],
 393    [ecore-evas ecore evas],
 394    [build_tiler_example="yes"],
 395    [build_tiler_example="no"])
 396
 397 AM_CONDITIONAL([BUILD_TILER_EXAMPLE], [test "x${build_tiler_example}" = "xyes"])
 398
 399 ### Checks for header files
 400 AC_HEADER_ASSERT
 401 AC_HEADER_TIME
 402 AC_HEADER_DIRENT
 403
 404 AC_CHECK_HEADERS([unistd.h libgen.h inttypes.h stdint.h sys/types.h siginfo.h strings.h sys/mman.h execinfo.h mcheck.h])
 405
 406 if test "x${ac_cv_header_inttypes_h}" = "xyes" ; then
 407    EINA_CONFIGURE_HAVE_INTTYPES_H="#define EINA_HAVE_INTTYPES_H"
 408    AC_DEFINE([HAVE_INTTYPES_H], [1], [Define to 1 if you have the <inttypes.h> header file.])
 409 fi
 410 AC_SUBST([EINA_CONFIGURE_HAVE_INTTYPES_H])
 411
 412 if test "x${ac_cv_header_inttypes_h}" = "xyes" ; then
 413     EINA_CONFIGURE_HAVE_STDINT_H="#define EINA_HAVE_STDINT_H"
 414     AC_DEFINE([HAVE_STDINT_H], [1], [Define to 1 if you have the <stdint.h> header file.])
 415 fi
 416 AC_SUBST([EINA_CONFIGURE_HAVE_STDINT_H])
 417
 418 ### Checks for types
 419
 420 # wchar_t
 421
 422 AC_CHECK_SIZEOF([wchar_t])
 423 EINA_SIZEOF_WCHAR_T=$ac_cv_sizeof_wchar_t
 424 AC_SUBST([EINA_SIZEOF_WCHAR_T])
 425 AC_CHECK_TYPES([siginfo_t], [], [],
 426    [[
 427 #include <signal.h>
 428 #if HAVE_SIGINFO_H
 429 # include <siginfo.h>
 430 #endif
 431    ]])
 432
 433 # struct dirent
 434
 435 AC_CHECK_TYPES([struct dirent], [have_dirent="yes"], [have_dirent="no"],
 436    [[
 437 #include <dirent.h>
 438    ]])
 439
 440 if test "x${have_dirent}" = "xyes" ; then
 441     EINA_CONFIGURE_HAVE_DIRENT_H="#define EINA_HAVE_DIRENT_H"
 442     AC_DEFINE([HAVE_DIRENT_H], [1], [Define to 1 if you have a valid <dirent.h> header file.])
 443 fi
 444 AC_SUBST([EINA_CONFIGURE_HAVE_DIRENT_H])
 445
 446 ### Checks for structures
 447
 448 ### Checks for compiler characteristics
 449 AC_C_BIGENDIAN
 450 AC_C_INLINE
 451 AC_PROG_CC_STDC
 452 EFL_ATTRIBUTE_UNUSED
 453
 454 m4_ifdef([v_mic],
 455    [
 456     EFL_COMPILER_FLAG([-Wall])
 457     EFL_COMPILER_FLAG([-W])
 458    ])
 459
 460 EFL_COMPILER_FLAG([-Wshadow])
 461
 462 EFL_CHECK_PATH_MAX
 463
 464 ### Checks for linker characteristics
 465 lt_enable_auto_import=""
 466 case "${host_os}" in
 467    mingw*)
 468       lt_enable_auto_import="-Wl,--enable-auto-import"
 469    ;;
 470 esac
 471 AC_SUBST([lt_enable_auto_import])
 472
 473 EFL_LINKER_FLAG([-fno-strict-aliasing])
 474
 475 ### Checks for library functions
 476 AC_FUNC_ALLOCA
 477
 478 AC_CHECK_FUNCS([strlcpy openat fstatat fpathconf execvp backtrace backtrace_symbols malloc_usable_size mtrace])
 479
 480 EFL_CHECK_FUNCS([eina], [dirfd dlopen dladdr fnmatch iconv shm_open setxattr])
 481
 482 want_debug_malloc="no"
 483 AC_ARG_ENABLE([debug-malloc],
 484    [AC_HELP_STRING([--enable-debug-malloc], [enable debugging of malloc usage overhead in our allocator @<:@default=enabled@:>@])],
 485    [
 486      if test "x${enableval}" = "xyes" ; then
 487         want_debug_malloc="yes"
 488      else
 489         want_debug_malloc="no"
 490      fi
 491    ], [want_debug_malloc="no"])
 492
 493 if test "x${ac_cv_func_malloc_usable_size}" = "xyes" && test "x${want_debug_malloc}" = "xyes"; then
 494    AC_DEFINE([EINA_DEBUG_MALLOC], [1], [Turn on debugging overhead in mempool])
 495 fi
 496
 497 AC_ARG_ENABLE([log],
 498    [AC_HELP_STRING([--disable-log], [disable Eina_Log infrastructure completly @<:@default=enabled@:>@])],
 499    [
 500     if test "x${enableval}" = "xyes" ; then
 501        want_log="yes"
 502     else
 503        want_log="no"
 504     fi
 505    ],
 506    [want_log="yes"])
 507
 508 enable_log="no"
 509 if test "x${efl_func_fnmatch}" = "xyes" && test "x${want_log}" = "xyes" ; then
 510    enable_log="yes"
 511 fi
 512
 513 AC_MSG_CHECKING([wether to build Eina_Log infrastructure])
 514 AC_MSG_RESULT([${enable_log}])
 515
 516 if test "x${enable_log}" = "xyes"; then
 517     EINA_CONFIGURE_ENABLE_LOG="#define EINA_ENABLE_LOG"
 518     AC_DEFINE([HAVE_LOG], [1], [Define to 1 if we log support is on])
 519 fi
 520 AC_SUBST([EINA_CONFIGURE_ENABLE_LOG])
 521
 522
 523 ### Modules
 524
 525 if test "x${have_default_mempool}" = "xyes" ; then
 526    enable_chained_pool="no"
 527    enable_pass_through="static"
 528 else
 529    enable_chained_pool="static"
 530    enable_pass_through="no"
 531 fi
 532
 533 enable_one_big="static"
 534
 535 EINA_CHECK_MODULE([chained-pool],   [${enable_chained_pool}], [chained pool])
 536 EINA_CHECK_MODULE([ememoa-fixed],   [${enable_ememoa}],       [ememoa fixed])
 537 EINA_CHECK_MODULE([ememoa-unknown], [${enable_ememoa}],       [ememoa unknown])
 538 EINA_CHECK_MODULE([fixed-bitmap],   [no],                     [fixed bitmap])
 539 EINA_CHECK_MODULE([pass-through],   [${enable_pass_through}], [pass through])
 540 EINA_CHECK_MODULE([buddy],          [no],                     [buddy])
 541 EINA_CHECK_MODULE([one-big],        [${enable_one_big}],      [one big])
 542
 543 ### Make the debug preprocessor configurable
 544
 545 ### Unit tests, coverage and benchmarking
 546
 547 EFL_CHECK_TESTS([eina], [enable_tests="yes"], [enable_tests="no"])
 548
 549 EFL_CHECK_BENCHMARK([enable_benchmark="yes"], [enable_benchmark="no"])
 550 EINA_BENCH_MODULE([glib], [${enable_benchmark}], [glib-2.0], [enable_benchmark_glib="yes"], [enable_benchmark_glib="no"])
 551 if test -n "$CXX" && test "x$enable_benchmark" = "xyes" ; then
 552    AC_DEFINE_UNQUOTED([CITYHASH_BENCH], [1], [enable bench tests for google hash method])
 553 fi
 554 AM_CONDITIONAL([CITYHASH_BENCH], [test -n "$CXX" && test "x$enable_benchmark" = "xyes"])
 555
 556 AC_SUBST([requirements_pc_eina])
 557 AC_SUBST([requirements_libs_eina])
 558
 559 ### Build and install examples
 560 EFL_CHECK_BUILD_EXAMPLES([enable_build_examples="yes"], [enable_build_examples="no"])
 561 EFL_CHECK_INSTALL_EXAMPLES([enable_install_examples="yes"], [enable_install_examples="no"])
 562
 563 AC_CONFIG_FILES([
 564 Makefile
 565 eina.pc
 566 eina.spec
 567 doc/Makefile
 568 doc/Doxyfile
 569 src/Makefile
 570 src/include/Makefile
 571 src/include/eina_config.h
 572 src/lib/Makefile
 573 src/modules/Makefile
 574 src/modules/mp/Makefile
 575 src/modules/mp/chained_pool/Makefile
 576 src/modules/mp/ememoa_fixed/Makefile
 577 src/modules/mp/ememoa_unknown/Makefile
 578 src/modules/mp/pass_through/Makefile
 579 src/modules/mp/fixed_bitmap/Makefile
 580 src/modules/mp/buddy/Makefile
 581 src/modules/mp/one_big/Makefile
 582 src/tests/Makefile
 583 src/examples/Makefile
 584 ])
 585
 586 AC_OUTPUT
 587
 588 #####################################################################
 589 ## Info
 590
 591 echo
 592 echo
 593 echo
 594 echo "------------------------------------------------------------------------"
 595 echo "$PACKAGE $VERSION"
 596 echo "------------------------------------------------------------------------"
 597 echo
 598 echo
 599 echo "Configuration Options Summary:"
 600 echo
 601 echo "  Magic debug..........: ${have_magic_debug}"
 602 echo "  Safety checks........: ${have_safety_checks}"
 603 echo "  Maximum log level....: ${with_max_log_level}"
 604 echo "  Report string usage..: ${have_stringshare_usage}"
 605 echo "  Valgrind support.....: ${have_valgrind}"
 606 echo "  Default mempool......: ${have_default_mempool}"
 607 echo "  Log support..........: ${enable_log}"
 608 echo "  Thread Support.......: ${efl_have_threads}"
 609 if test "${efl_have_threads}" = "POSIX" ; then
 610 echo "    spinlock...........: ${efl_have_posix_threads_spinlock}"
 611 echo "    debug usage........: ${efl_have_debug_threads}"
 612 echo "    on/off support.....: ${efl_have_on_off_threads}"
 613 fi
 614 echo "  Amalgamation.........: ${do_amalgamation}"
 615 echo "  Iconv support........: ${efl_func_iconv}"
 616 echo "  File dirfd...........: ${efl_func_dirfd}"
 617 echo "  File xattr...........: ${efl_func_setxattr}"
 618 echo "  shm_open.............: ${efl_func_shm_open}"
 619 echo
 620 echo "  Documentation........: ${build_doc}"
 621 echo "  Tests................: ${enable_tests} (Coverage: ${efl_enable_coverage})"
 622 echo "  Examples.............: ${enable_build_examples}"
 623 echo "  Tiler Example........: ${build_tiler_example}"
 624 echo "  Examples installed...: ${enable_install_examples}"
 625 echo "  Benchmark............: ${enable_benchmark}"
 626 if test "x${enable_benchmark}" = "xyes" ; then
 627 echo "    Glib...............: ${enable_benchmark_glib}"
 628 echo "    E17 real data......: ${enable_benchmark_e17}"
 629 fi
 630 echo
 631 echo "  CPU Specific Extensions:"
 632 echo "    MMX................: ${have_mmx}"
 633 echo "    SSE................: ${have_sse}"
 634 echo "    SSE2...............: ${have_sse2}"
 635 echo "    ALTIVEC............: ${have_altivec}"
 636 echo
 637 echo "  Memory pools:"
 638 echo "    Buddy..............: ${enable_buddy}"
 639 echo "    Chained pool.......: ${enable_chained_pool}"
 640 echo "    Ememoa fixed.......: ${enable_ememoa_fixed}"
 641 echo "    Ememoa unknown.....: ${enable_ememoa_unknown}"
 642 echo "    Fixed bitmap.......: ${enable_fixed_bitmap}"
 643 echo "    One big............: ${enable_one_big}"
 644 echo "    Pass through.......: ${enable_pass_through}"
 645 echo
 646 echo "Compilation............: make (or gmake)"
 647 echo "  CPPFLAGS.............: $CPPFLAGS"
 648 echo "  CFLAGS...............: $CFLAGS"
 649 echo "  LDFLAGS..............: $LDFLAGS"
 650 echo
 651 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
 652 echo "  prefix...............: $prefix"
 653 echo
 654 EFL_FORM_VOLTRON