configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of polypaudio.
   7 #
   8 # polypaudio is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as published by
  10 # the Free Software Foundation; either version 2 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # polypaudio is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  16 # General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public License
  19 # along with polypaudio; if not, write to the Free Software Foundation,
  20 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  21
  22 AC_PREREQ(2.57)
  23 AC_INIT([polypaudio],[0.8],[mzcbylcnhqvb (at) 0pointer (dot) de])
  24 AC_CONFIG_SRCDIR([polyp/main.c])
  25 AC_CONFIG_HEADERS([config.h])
  26 AM_INIT_AUTOMAKE([foreign -Wall])
  27
  28 AC_SUBST(PA_MAJORMINOR, "$PACKAGE_VERSION")
  29 AC_SUBST(PACKAGE_URL, [http://0pointer.de/lennart/projects/polypaudio/])
  30
  31 AC_SUBST(PA_API_VERSION, 8)
  32
  33 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  34    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  35    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  36 fi
  37
  38 # Checks for programs.
  39 AC_PROG_CC
  40
  41 # libtool stuff
  42 AC_LIBLTDL_INSTALLABLE
  43 AC_SUBST(LTDLINCL)
  44 AC_SUBST(LIBLTDL)
  45 AC_LIBTOOL_DLOPEN
  46 AC_PROG_LIBTOOL
  47 AC_CONFIG_SUBDIRS(libltdl)
  48
  49 # Checks for header files.
  50 AC_HEADER_STDC
  51 AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h limits.h malloc.h netdb.h netinet/in.h stddef.h stdint.h stdlib.h string.h sys/ioctl.h sys/socket.h sys/time.h unistd.h syslog.h])
  52
  53 ACX_PTHREAD
  54 AC_PATH_XTRA
  55
  56 HAVE_X11=0
  57 test "x$no_x" != "xyes" && HAVE_X11=1
  58 AC_SUBST(HAVE_X11)
  59 AM_CONDITIONAL(HAVE_X11, test "x$no_x" != "xyes")
  60 AC_DEFINE([HAVE_X11], [], [Have X11])
  61
  62 # Checks for typedefs, structures, and compiler characteristics.
  63 AC_C_CONST
  64 AC_TYPE_PID_T
  65 AC_TYPE_SIZE_T
  66 AC_TYPE_OFF_T
  67 AC_HEADER_TIME
  68
  69 # Checks for library functions.
  70 AC_FUNC_FORK
  71 AC_PROG_GCC_TRADITIONAL
  72 AC_FUNC_LSTAT
  73 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
  74 AC_FUNC_MALLOC
  75 AC_FUNC_MEMCMP
  76 AC_FUNC_MMAP
  77 AC_FUNC_REALLOC
  78 AC_FUNC_SETPGRP
  79 AC_FUNC_VPRINTF
  80 AC_FUNC_CLOSEDIR_VOID
  81 AC_FUNC_SELECT_ARGTYPES
  82 AC_TYPE_SIGNAL
  83 AC_TYPE_UID_T
  84 AC_CHECK_FUNCS([gethostname gettimeofday memchr memmove memset mkdir mkfifo munmap rmdir socket strcspn strerror strrchr strspn strstr strtol strtoul strcasecmp putenv strchr strpbrk strdup getgrgid_r getpwuid_r regcomp ftruncate select])
  85 AC_CHECK_LIB(m, pow)
  86 AC_CHECK_FUNCS(pow)
  87 AC_FUNC_STAT
  88 AC_HEADER_SYS_WAIT
  89 AC_HEADER_DIRENT
  90
  91 AC_C_BIGENDIAN
  92 AC_FUNC_GETGROUPS
  93
  94 AC_CHECK_LIB(cap, cap_init, [CAP_LIBS='-lcap'], [CAP_LIBS=''])
  95 AC_SUBST(CAP_LIBS)
  96
  97 AC_CHECK_HEADERS(sys/capability.h)
  98
  99 AC_CHECK_FUNCS(setresuid)
 100 AC_CHECK_FUNCS(setreuid)
 101
 102 PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ])
 103 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 104 AC_SUBST(LIBSAMPLERATE_LIBS)
 105
 106 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.10 ])
 107 AC_SUBST(LIBSNDFILE_CFLAGS)
 108 AC_SUBST(LIBSNDFILE_LIBS)
 109
 110 PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.0 ], [HAVE_ALSA=1], [HAVE_ALSA=0])
 111 AC_SUBST(ASOUNDLIB_CFLAGS)
 112 AC_SUBST(ASOUNDLIB_LIBS)
 113 AC_SUBST(HAVE_ALSA)
 114 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 115
 116 PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ], HAVE_GLIB20=1, HAVE_GLIB20=0)
 117 AC_SUBST(GLIB20_CFLAGS)
 118 AC_SUBST(GLIB20_LIBS)
 119 AC_SUBST(HAVE_GLIB20)
 120 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 121
 122 PKG_CHECK_MODULES(GLIB12, [ glib >= 1.2.0 ], HAVE_GLIB12=1, HAVE_GLIB12=0)
 123 AC_SUBST(GLIB12_CFLAGS)
 124 AC_SUBST(GLIB12_LIBS)
 125 AC_SUBST(HAVE_GLIB12)
 126 AM_CONDITIONAL([HAVE_GLIB12], [test "x$HAVE_GLIB12" = x1])
 127
 128 PKG_CHECK_MODULES(HOWL, [ howl >= 0.9.8 ], HAVE_HOWL=1, HAVE_HOWL=0)
 129 AC_SUBST(HOWL_CFLAGS)
 130 AC_SUBST(HOWL_LIBS)
 131 AC_SUBST(HAVE_HOWL)
 132 AM_CONDITIONAL([HAVE_HOWL], [test "x$HAVE_HOWL" = x1])
 133
 134 AC_PATH_PROG([M4], [m4 gm4], [no])
 135 if test "x$M4" = xno ; then
 136    AC_MSG_ERROR([m4 missing])
 137 fi
 138
 139 AC_MSG_CHECKING([for tcpwrap library and headers])
 140 LIBWRAP_LIBS=
 141 saved_LIBS="$LIBS"
 142 LIBS="$LIBS -lwrap"
 143 AC_LINK_IFELSE(
 144 AC_LANG_PROGRAM(
 145 [#include <tcpd.h>
 146 #include <syslog.h>
 147 int allow_severity = LOG_INFO;
 148 int deny_severity = LOG_WARNING;],
 149 [struct request_info *req;
 150 return hosts_access (req);]),
 151 [AC_DEFINE(HAVE_LIBWRAP, [], [Have tcpwrap?])
 152 LIBWRAP_LIBS="-lwrap"
 153 AC_MSG_RESULT(yes)],
 154 [AC_MSG_RESULT(no)])
 155 AC_SUBST(LIBWRAP_LIBS)
 156 LIBS="$saved_LIBS"
 157
 158 # If using GCC specify some additional parameters
 159 if test "x$GCC" = "xyes" ; then
 160    CFLAGS="$CFLAGS -pipe -W -Wall -pedantic"
 161
 162    AC_LANG_CONFTEST([int main() {}])
 163    $CC -c conftest.c -std=c99 -Wno-unused-parameter $CFLAGS > /dev/null 2> /dev/null && CFLAGS="$CFLAGS -std=c99 -Wno-unused-parameter"
 164    rm -f conftest.o
 165 fi
 166
 167 # LYNX documentation generation
 168 AC_ARG_ENABLE(lynx,
 169         AC_HELP_STRING(--disable-lynx,Turn off lynx usage for documentation generation),
 170 [case "${enableval}" in
 171   yes) lynx=yes ;;
 172   no)  lynx=no ;;
 173   *) AC_MSG_ERROR(bad value ${enableval} for --disable-lynx) ;;
 174 esac],[lynx=yes])
 175
 176 if test x$lynx = xyes ; then
 177    AC_CHECK_PROG(have_lynx, lynx, yes, no)
 178
 179    if test x$have_lynx = xno ; then
 180      AC_MSG_WARN([*** lynx not found, plain text README will not be built ***])
 181    fi
 182 fi
 183
 184 AM_CONDITIONAL([USE_LYNX], [test "x$lynx" = xyes])
 185
 186 AM_CONDITIONAL(BUILD_LIBPOLYPCORE, false)
 187
 188 AC_CONFIG_FILES([Makefile polyp/Makefile polyplib.pc polyplib-simple.pc polyplib-mainloop.pc polyplib-error.pc polyplib-glib-mainloop.pc polyplib-glib12-mainloop.pc doc/Makefile doc/README.html doc/cli.html doc/daemon.html doc/modules.html doxygen/Makefile doxygen/doxygen.conf polyp/polyplib-version.h doc/FAQ.html])
 189 AC_OUTPUT