configure.ac

   1 #  Copyright 2005 Adam Jackson.
   2 #
   3 #  Permission is hereby granted, free of charge, to any person obtaining a
   4 #  copy of this software and associated documentation files (the "Software"),
   5 #  to deal in the Software without restriction, including without limitation
   6 #  on the rights to use, copy, modify, merge, publish, distribute, sub
   7 #  license, and/or sell copies of the Software, and to permit persons to whom
   8 #  the Software is furnished to do so, subject to the following conditions:
   9 #
  10 #  The above copyright notice and this permission notice (including the next
  11 #  paragraph) shall be included in all copies or substantial portions of the
  12 #  Software.
  13 #
  14 #  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15 #  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16 #  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
  17 #  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
  18 #  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  19 #  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  20
  21 AC_PREREQ(2.60)
  22 AC_INIT([libdrm], 2.4.19, [dri-devel@lists.sourceforge.net], libdrm)
  23 AC_USE_SYSTEM_EXTENSIONS
  24 AC_CONFIG_SRCDIR([Makefile.am])
  25 AM_INIT_AUTOMAKE([dist-bzip2])
  26
  27 AM_CONFIG_HEADER([config.h])
  28
  29 AC_DISABLE_STATIC
  30 AC_PROG_LIBTOOL
  31 AC_PROG_CC
  32
  33 AC_HEADER_STDC
  34 AC_SYS_LARGEFILE
  35 AC_FUNC_ALLOCA
  36
  37 PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
  38 AC_SUBST(PTHREADSTUBS_CFLAGS)
  39 AC_SUBST(PTHREADSTUBS_LIBS)
  40
  41 pkgconfigdir=${libdir}/pkgconfig
  42 AC_SUBST(pkgconfigdir)
  43 AC_ARG_ENABLE(udev,     AS_HELP_STRING([--enable-udev],
  44                                 [Enable support for using udev instead of mknod (default: disabled)]),
  45                                 [UDEV=$enableval], [UDEV=no])
  46
  47 AC_ARG_ENABLE(libkms,
  48               AS_HELP_STRING([--disable-libkms],
  49               [Disable KMS mm abstraction library (default: enabled)]),
  50               [LIBKMS=$enableval], [LIBKMS=yes])
  51
  52 AC_ARG_ENABLE(intel,
  53               AS_HELP_STRING([--disable-intel],
  54               [Enable support for intel's KMS API (default: auto)]),
  55               [INTEL=$enableval], [INTEL=auto])
  56
  57 AC_ARG_ENABLE(radeon,
  58               AS_HELP_STRING([--disable-radeon],
  59               [Enable support for radeon's KMS API (default: auto)]),
  60               [RADEON=$enableval], [RADEON=auto])
  61
  62 AC_ARG_ENABLE(vmwgfx-experimental-api,
  63               AS_HELP_STRING([--enable-vmwgfx-experimental-api],
  64               [Install vmwgfx's experimental kernel API header (default: disabled)]),
  65               [VMWGFX=$enableval], [VMWGFX=no])
  66
  67 AC_ARG_ENABLE(nouveau-experimental-api,
  68               AS_HELP_STRING([--enable-nouveau-experimental-api],
  69               [Enable support for nouveau's experimental API (default: disabled)]),
  70               [NOUVEAU=$enableval], [NOUVEAU=no])
  71
  72
  73 dnl ===========================================================================
  74 dnl check compiler flags
  75 AC_DEFUN([LIBDRM_CC_TRY_FLAG], [
  76   AC_MSG_CHECKING([whether $CC supports $1])
  77
  78   libdrm_save_CFLAGS="$CFLAGS"
  79   CFLAGS="$CFLAGS $1"
  80
  81   AC_COMPILE_IFELSE([ ], [libdrm_cc_flag=yes], [libdrm_cc_flag=no])
  82   CFLAGS="$libdrm_save_CFLAGS"
  83
  84   if test "x$libdrm_cc_flag" = "xyes"; then
  85     ifelse([$2], , :, [$2])
  86   else
  87     ifelse([$3], , :, [$3])
  88   fi
  89   AC_MSG_RESULT([$libdrm_cc_flag])
  90 ])
  91
  92 dnl We use clock_gettime to check for timeouts in drmWaitVBlank
  93
  94 AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
  95                [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
  96                              [AC_MSG_ERROR([Couldn't find clock_gettime])])])
  97 AC_SUBST([CLOCK_LIB])
  98
  99 dnl Use lots of warning flags with with gcc and compatible compilers
 100
 101 dnl Note: if you change the following variable, the cache is automatically
 102 dnl skipped and all flags rechecked.  So there's no need to do anything
 103 dnl else.  If for any reason you need to force a recheck, just change
 104 dnl MAYBE_WARN in an ignorable way (like adding whitespace)
 105
 106 MAYBE_WARN="-Wall -Wextra \
 107 -Wsign-compare -Werror-implicit-function-declaration \
 108 -Wpointer-arith -Wwrite-strings -Wstrict-prototypes \
 109 -Wmissing-prototypes -Wmissing-declarations -Wnested-externs \
 110 -Wpacked -Wswitch-enum -Wmissing-format-attribute \
 111 -Wstrict-aliasing=2 -Winit-self -Wunsafe-loop-optimizations \
 112 -Wdeclaration-after-statement -Wold-style-definition \
 113 -Wno-missing-field-initializers -Wno-unused-parameter \
 114 -Wno-attributes -Wno-long-long -Winline"
 115
 116 # invalidate cached value if MAYBE_WARN has changed
 117 if test "x$libdrm_cv_warn_maybe" != "x$MAYBE_WARN"; then
 118         unset libdrm_cv_warn_cflags
 119 fi
 120 AC_CACHE_CHECK([for supported warning flags], libdrm_cv_warn_cflags, [
 121         echo
 122         WARN_CFLAGS=""
 123
 124         # Some warning options are not supported by all versions of
 125         # gcc, so test all desired options against the current
 126         # compiler.
 127         #
 128         # Note that there are some order dependencies
 129         # here. Specifically, an option that disables a warning will
 130         # have no net effect if a later option then enables that
 131         # warnings, (perhaps implicitly). So we put some grouped
 132         # options (-Wall and -Wextra) up front and the -Wno options
 133         # last.
 134
 135         for W in $MAYBE_WARN; do
 136                 LIBDRM_CC_TRY_FLAG([$W], [WARN_CFLAGS="$WARN_CFLAGS $W"])
 137         done
 138
 139         libdrm_cv_warn_cflags=$WARN_CFLAGS
 140         libdrm_cv_warn_maybe=$MAYBE_WARN
 141
 142         AC_MSG_CHECKING([which warning flags were supported])])
 143 WARN_CFLAGS="$libdrm_cv_warn_cflags"
 144
 145 if test "x$UDEV" = xyes; then
 146         AC_DEFINE(UDEV, 1, [Have UDEV support])
 147 fi
 148
 149 AM_CONDITIONAL(HAVE_LIBKMS, [test "x$LIBKMS" = xyes])
 150
 151 AM_CONDITIONAL(HAVE_VMWGFX, [test "x$VMWGFX" = xyes])
 152 if test "x$VMWGFX" = xyes; then
 153         AC_DEFINE(HAVE_VMWGFX, 1, [Have vmwgfx kernel headers])
 154 fi
 155
 156 AM_CONDITIONAL(HAVE_NOUVEAU, [test "x$NOUVEAU" = xyes])
 157 if test "x$NOUVEAU" = xyes; then
 158         AC_DEFINE(HAVE_NOUVEAU, 1, [Have nouveau (nvidia) support])
 159 fi
 160
 161 PKG_CHECK_MODULES(CAIRO, cairo, [HAVE_CAIRO=yes], [HAVE_CAIRO=no])
 162 if test "x$HAVE_CAIRO" = xyes; then
 163         AC_DEFINE(HAVE_CAIRO, 1, [Have cairo support])
 164 fi
 165 AM_CONDITIONAL(HAVE_CAIRO, [test "x$HAVE_CAIRO" = xyes])
 166
 167 # For enumerating devices in test case
 168 PKG_CHECK_MODULES(LIBUDEV, libudev, [HAVE_LIBUDEV=yes], [HAVE_LIBUDEV=no])
 169 if test "x$HAVE_LIBUDEV" = xyes; then
 170         AC_DEFINE(HAVE_LIBUDEV, 1, [Have libudev support])
 171 fi
 172 AM_CONDITIONAL(HAVE_LIBUDEV, [test "x$HAVE_LIBUDEV" = xyes])
 173
 174 if test "x$INTEL" != "xno" -o "x$RADEON" != "xno"; then
 175     # Check for atomic intrinsics
 176     AC_CACHE_CHECK([for native atomic primitives], drm_cv_atomic_primitives,
 177     [
 178             drm_cv_atomic_primitives="none"
 179
 180             AC_TRY_LINK([
 181     int atomic_add(int i) { return __sync_fetch_and_add (&i, 1); }
 182     int atomic_cmpxchg(int i, int j, int k) { return __sync_val_compare_and_swap (&i, j, k); }
 183     ], [],
 184               drm_cv_atomic_primitives="Intel"
 185               )
 186
 187             if test "x$drm_cv_atomic_primitives" = "xnone"; then
 188                     AC_CHECK_HEADER([atomic_ops.h], drm_cv_atomic_primitives="libatomic-ops")
 189             fi
 190
 191             # atomic functions defined in <atomic.h> & libc on Solaris
 192             if test "x$drm_cv_atomic_primitives" = "xnone"; then
 193                     AC_CHECK_FUNC([atomic_cas_uint],
 194                                   drm_cv_atomic_primitives="Solaris")
 195             fi
 196
 197     ])
 198     if test "x$drm_cv_atomic_primitives" = xIntel; then
 199             AC_DEFINE(HAVE_LIBDRM_ATOMIC_PRIMITIVES, 1,
 200                       [Enable if your compiler supports the Intel __sync_* atomic primitives])
 201     fi
 202     if test "x$drm_cv_atomic_primitives" = "xlibatomic-ops"; then
 203             AC_DEFINE(HAVE_LIB_ATOMIC_OPS, 1, [Enable if you have libatomic-ops-dev installed])
 204     fi
 205
 206     if test "x$drm_cv_atomic_primitives" = "xnone"; then
 207            if test "x$INTEL" != "xauto"; then
 208                    if test "x$INTEL" != "xno"; then
 209                         AC_MSG_ERROR([libdrm_intel depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for Intel GPUs by passing --disable-intel to ./configure])
 210                    fi
 211            else
 212                    AC_MSG_WARN([Disabling libdrm_intel. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.])
 213                    INTEL=no
 214            fi
 215            if test "x$RADEON" != "xauto"; then
 216                    if test "x$RADEON" != "xno"; then
 217                         AC_MSG_ERROR([libdrm_radeon depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for Radeon support by passing --disable-radeon to ./configure])
 218                    fi
 219            else
 220                    AC_MSG_WARN([Disabling libdrm_radeon. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.])
 221                    RADEON=no
 222            fi
 223
 224     else
 225            if test "x$INTEL" != "xno"; then
 226                    INTEL=yes
 227            fi
 228            if test "x$RADEON" != "xno"; then
 229                    RADEON=yes
 230            fi
 231     fi
 232 fi
 233
 234 AM_CONDITIONAL(HAVE_INTEL, [test "x$INTEL" != "xno"])
 235 AM_CONDITIONAL(HAVE_RADEON, [test "x$RADEON" != "xno"])
 236
 237 AC_ARG_WITH([kernel-source],
 238             [AS_HELP_STRING([--with-kernel-source],
 239               [specify path to linux kernel source])],
 240             [kernel_source="$with_kernel_source"])
 241 AC_SUBST(kernel_source)
 242
 243 AC_SUBST(WARN_CFLAGS)
 244 AC_OUTPUT([
 245         Makefile
 246         libkms/Makefile
 247         libkms/libkms.pc
 248         intel/Makefile
 249         intel/libdrm_intel.pc
 250         radeon/Makefile
 251         radeon/libdrm_radeon.pc
 252         nouveau/Makefile
 253         nouveau/libdrm_nouveau.pc
 254         tests/Makefile
 255         tests/modeprint/Makefile
 256         tests/modetest/Makefile
 257         tests/kmstest/Makefile
 258         include/Makefile
 259         include/drm/Makefile
 260         libdrm.pc])
 261
 262 echo ""
 263 echo "$PACKAGE_STRING will be compiled with:"
 264 echo ""
 265 echo "  libkms         $LIBKMS"
 266 echo "  Intel API      $INTEL"
 267 echo "  vmwgfx API     $VMWGFX"
 268 echo "  Radeon API     $RADEON"
 269 echo "  Nouveau API    $NOUVEAU"
 270 echo ""