configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [1])
   4 m4_define([v_min], [6])
   5 m4_define([v_mic], [99])
   6 m4_define([v_rev], m4_esyscmd([(svnversion "${SVN_REPO_PATH:-.}" | grep -v '\(export\|Unversioned directory\)' || echo 0) | awk -F : '{printf("%s\n", $1);}' | tr -d ' :MSP\n']))
   7 m4_if(v_rev, [0], [m4_define([v_rev], m4_esyscmd([git log 2> /dev/null | (grep -m1 git-svn-id || echo 0) | sed -e 's/.*@\([0-9]*\).*/\1/' | tr -d '\n']))])
   8 ##--   When released, remove the dnl on the below line
   9 dnl m4_undefine([v_rev])
  10 ##--   When doing snapshots - change soname. remove dnl on below line
  11 dnl m4_define([relname], [ver-pre-svn-05])
  12 dnl m4_define([v_rel], [-release relname])
  13 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  14 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])], [m4_define([v_ver], [v_maj.v_min.v_mic])])
  15 m4_define([lt_cur], m4_eval(v_maj + v_min))
  16 m4_define([lt_rev], v_mic)
  17 m4_define([lt_age], v_min)
  18 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  19 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  20
  21 AC_INIT([eet], [v_ver], [enlightenment-devel@lists.sourceforge.net])
  22 AC_PREREQ([2.52])
  23 AC_CONFIG_SRCDIR([configure.ac])
  24 AC_CONFIG_MACRO_DIR([m4])
  25
  26 AC_CONFIG_HEADERS([config.h])
  27 AH_TOP([
  28 #ifndef EFL_CONFIG_H__
  29 #define EFL_CONFIG_H__
  30 ])
  31 AH_BOTTOM([
  32 #endif /* EFL_CONFIG_H__ */
  33 ])
  34
  35 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 AC_GNU_SOURCE
  39
  40 lt_cv_deplibs_check_method='pass_all'
  41 AC_LIBTOOL_WIN32_DLL
  42 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  43 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  44 AC_PROG_LIBTOOL
  45
  46 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  47 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  48 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  49 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  50 AC_DEFINE_UNQUOTED(VMAJ, [v_maj], [Major version])
  51 AC_DEFINE_UNQUOTED(VMIN, [v_min], [Minor version])
  52 AC_DEFINE_UNQUOTED(VMIC, [v_mic], [Micro version])
  53 AC_DEFINE_UNQUOTED(VREV, [v_rev], [Revison])
  54 version_info="lt_cur:lt_rev:lt_age"
  55 release_info="v_rel"
  56 AC_SUBST(version_info)
  57 AC_SUBST(release_info)
  58 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  59 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  60 VMAJ=v_maj
  61 AC_SUBST(VMAJ)
  62
  63
  64 ### Needed information
  65
  66 AC_CANONICAL_BUILD
  67 AC_CANONICAL_HOST
  68
  69 ### Default options with respect to host
  70
  71 requirements_pc_eet=""
  72 requirements_libs_eet=""
  73
  74 ### Additional options to configure
  75
  76 EFL_ENABLE_BIN([eet])
  77
  78 # Old eet file format support
  79
  80 AC_ARG_ENABLE(old-eet-file-format,
  81    [AC_HELP_STRING(
  82       [--disable-old-eet-file-format],
  83       [disable old eet file format support @<:@default=enabled@:>@])],
  84    [
  85     if test "x${enableval}" = "xyes" ; then
  86        old_eet_file_format="yes"
  87     else
  88        old_eet_file_format="no"
  89     fi
  90    ],
  91    [old_eet_file_format="yes"])
  92
  93 AC_MSG_CHECKING([whether to support old eet file format])
  94 AC_MSG_RESULT([${old_eet_file_format}])
  95
  96 if test "x${old_eet_file_format}" = "xyes" ; then
  97    AC_DEFINE(EET_OLD_EET_FILE_FORMAT, 1, [support old eet file format])
  98 else
  99    AC_DEFINE(EET_OLD_EET_FILE_FORMAT, 0, [support old eet file format])
 100 fi
 101
 102 # Openssl support
 103
 104 AC_ARG_ENABLE([openssl],
 105    [AC_HELP_STRING([--disable-openssl], [disable openssl eet support @<:@default=auto@:>@])],
 106    [
 107     if test "x${enableval}" = "xyes" ; then
 108        want_openssl="yes"
 109     else
 110        want_openssl="no"
 111     fi
 112    ],
 113    [want_openssl="auto"])
 114
 115 AC_MSG_CHECKING([whether to use OpenSSL])
 116 AC_MSG_RESULT([${want_openssl}])
 117
 118 # Cryptography support
 119
 120 AC_ARG_ENABLE([cipher],
 121    [AC_HELP_STRING([--disable-cipher], [disable cipher support for eet API @<:@default=yes@:>@])],
 122    [
 123     if test "x${enableval}" = "xyes" ; then
 124        want_cipher="yes"
 125     else
 126        want_cipher="no"
 127     fi
 128    ],
 129    [want_cipher="yes"])
 130
 131 AC_MSG_CHECKING([whether to use cipher])
 132 AC_MSG_RESULT([${want_cipher}])
 133
 134 AC_ARG_ENABLE([signature],
 135    [AC_HELP_STRING([--disable-signature], [disable signature file support for eet @<:@default=yes@:>@])],
 136    [
 137     if test "x${enableval}" = "xyes" ; then
 138        want_signature="yes"
 139     else
 140        want_signature="no"
 141     fi
 142    ],
 143    [want_signature="yes"])
 144
 145 AC_MSG_CHECKING([whether to use signature])
 146 AC_MSG_RESULT([${want_signature}])
 147
 148 # Assert or fail.
 149
 150 AC_ARG_ENABLE([assert],
 151    [AC_HELP_STRING([--enable-assert], [enable assert, @<:@default=no@:>@])],
 152    [
 153     if test "x${enableval}" = "xyes" ; then
 154        prefer_assert="yes"
 155     else
 156        prefer_assert="no"
 157     fi
 158    ],
 159    [prefer_assert="no"])
 160
 161 # Examples
 162
 163 AC_ARG_ENABLE([install-examples],
 164    [AC_HELP_STRING([--disable-install-examples],
 165        [disable installing examples (compiled or just source). @<:@default=yes@:>@])],
 166    [
 167     if test "x${enableval}" = "xyes" ; then
 168        install_examples="yes"
 169     else
 170        install_examples="no"
 171     fi
 172    ],
 173    [install_examples="yes"])
 174
 175 AM_CONDITIONAL([INSTALL_EXAMPLES], [test "x${install_examples}" = "xyes"])
 176
 177 AC_ARG_ENABLE([build-examples],
 178    [AC_HELP_STRING([--enable-build-examples],
 179        [enable building examples @<:@default=yes@:>@])],
 180    [
 181     if test "x${enableval}" = "xyes" ; then
 182        build_examples="yes"
 183     else
 184        build_examples="no"
 185     fi
 186    ],
 187    [build_examples="no"])
 188 AM_CONDITIONAL([BUILD_EXAMPLES], [test "x${build_examples}" = "xyes"])
 189
 190
 191 ### Checks for programs
 192 AC_PROG_CC
 193
 194 # pkg-config
 195 PKG_PROG_PKG_CONFIG
 196
 197 # Check whether pkg-config supports Requires.private
 198 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
 199    pkgconfig_requires_private="Requires.private"
 200 else
 201    pkgconfig_requires_private="Requires"
 202 fi
 203 AC_SUBST(pkgconfig_requires_private)
 204
 205
 206 # doxygen program for documentation building
 207
 208 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 209
 210 ### Checks for libraries
 211
 212 ## Compatibility layers
 213
 214 # Evil library for compilation on Windows
 215
 216 EFL_EET_BUILD=""
 217 case "$host_os" in
 218    mingw*)
 219       PKG_CHECK_EXISTS([evil >= 1.1.0])
 220       AC_DEFINE([HAVE_EVIL], [1], [Set to 1 if Evil package is installed])
 221       requirements_pc_eet="evil ${requirements_pc_eet}"
 222       EFL_EET_BUILD="-DEFL_EET_BUILD"
 223    ;;
 224 esac
 225 AC_SUBST(EFL_EET_BUILD)
 226
 227 # Exotic library for copilation on Coyote
 228
 229 PKG_CHECK_EXISTS([exotic],
 230    [
 231     enable_exotic="yes"
 232     AC_DEFINE([HAVE_EXOTIC_H], [1], [Define to 1 if you have Exotic.])
 233     EINA_CONFIGURE_HAVE_EXOTIC="#define EINA_HAVE_EXOTIC"
 234     requirements_pc_eina="exotic ${requirements_pc_eina}"
 235    ],
 236    [enable_exotic="no"])
 237
 238 ## Secure layer
 239
 240 # Gnutls library
 241
 242 AC_ARG_ENABLE([gnutls],
 243    [AC_HELP_STRING([--disable-gnutls], [disable gnutls eet support @<:@default=auto@:>@])],
 244    [
 245     if test "x${enableval}" = "xyes" ; then
 246        want_gnutls="yes"
 247     else
 248        want_gnutls="no"
 249     fi
 250    ],
 251    [want_gnutls="auto"])
 252
 253 AC_MSG_CHECKING([whether to use Gnutls])
 254 AC_MSG_RESULT([${want_gnutls}])
 255
 256 have_gnutls="no"
 257 if test "x${want_gnutls}" = "xyes" || test "x${want_gnutls}" = "xauto" ; then
 258    PKG_CHECK_MODULES([GNUTLS], [gnutls >= 1.7.6],
 259       [
 260        have_gnutls="yes"
 261        want_openssl="no"
 262        AC_DEFINE([HAVE_GNUTLS], [1], [Have Gnutls support])
 263        requirements_pc_eet="gnutls >= 1.7.6 ${requirements_pc_eet}"
 264       ],
 265       [have_gnutls="no"])
 266 fi
 267
 268 # libgcrypt
 269
 270 if test "x${have_gnutls}" = "xyes" ; then
 271    AC_PATH_GENERIC([libgcrypt], [], [have_gnutls="yes"], [have_gnutls="no"])
 272    if test "x${have_gnutls}" = "xyes" ; then
 273       requirements_libs_eet="${LIBGCRYPT_LIBS} ${requirements_libs_eet}"
 274    fi
 275 fi
 276
 277 # Specific GNUTLS improvement
 278
 279 AC_ARG_ENABLE(new-gnutls-api,
 280    [AC_HELP_STRING(
 281       [--disable-new-gnutls-api],
 282       [enable use of gnutls_x509_crt_verify_hash. @<:@default=yes@:>@])],
 283    [
 284     if test "x${enableval}" = "xyes" ; then
 285        new_gnutls_api="yes"
 286     else
 287        new_gnutls_api="no"
 288     fi
 289    ],
 290    [new_gnutls_api="yes"])
 291
 292 AC_MSG_CHECKING([whether to use gnutls_x509_crt_verify_hash])
 293 AC_MSG_RESULT([${new_gnutls_api}])
 294
 295 if test "x${have_gnutls}" = "xyes" && test "x${new_gnutls_api}" = "xyes" ; then
 296    CFLAGS_save="${CFLAGS}"
 297    LIBS_save="${LIBS}"
 298    CFLAGS="${GNUTLS_CFLAGS}"
 299    LIBS="${GNUTLS_LIBS}"
 300    AC_CHECK_LIB([gnutls], [gnutls_x509_crt_verify_hash],
 301       [
 302        AC_DEFINE([EET_USE_NEW_GNUTLS_API], [1], [use gnutls_x509_crt_verify_hash])
 303        new_gnutls_api="yes"
 304       ],
 305       [new_gnutls_api="no"])
 306    CFLAGS="${CFLAGS_save}"
 307    LIBS="${LIBS_save}"
 308 fi
 309
 310 use_gnutls_privkey_sign_data="no"
 311 if test "x${have_gnutls}" = "xyes" ; then
 312    CFLAGS_save="${CFLAGS}"
 313    LIBS_save="${LIBS}"
 314    CFLAGS="${GNUTLS_CFLAGS}"
 315    LIBS="${GNUTLS_LIBS}"
 316    AC_CHECK_LIB([gnutls], [gnutls_privkey_sign_data],
 317       [
 318        AC_DEFINE([EET_USE_NEW_PRIVKEY_SIGN_DATA], [1], [use gnutls_privkey_sign_data])
 319        use_gnutls_privkey_sign_data="yes"
 320       ],
 321       [use_gnutls_privkey_sign_data="no"])
 322    CFLAGS="${CFLAGS_save}"
 323    LIBS="${LIBS_save}"
 324 fi
 325
 326 AC_MSG_CHECKING([whether to use gnutls_privkey_sign_data])
 327 AC_MSG_RESULT([${use_gnutls_privkey_sign_data}])
 328
 329 use_gnutls_pubkey_verify_hash="no"
 330 if test "x${have_gnutls}" = "xyes" ; then
 331    CFLAGS_save="${CFLAGS}"
 332    LIBS_save="${LIBS}"
 333    CFLAGS="${GNUTLS_CFLAGS}"
 334    LIBS="${GNUTLS_LIBS}"
 335    AC_CHECK_LIB([gnutls], [gnutls_pubkey_verify_hash],
 336       [
 337        AC_DEFINE([EET_USE_NEW_PUBKEY_VERIFY_HASH], [1], [use gnutls_pubkey_verify_hash])
 338        use_gnutls_pubkey_verify_hash="yes"
 339       ],
 340       [use_gnutls_pubkey_verify_hash="no"])
 341    CFLAGS="${CFLAGS_save}"
 342    LIBS="${LIBS_save}"
 343 fi
 344
 345 AC_MSG_CHECKING([whether to use gnutls_pubkey_verify_hash])
 346 AC_MSG_RESULT([${use_gnutls_pubkey_verify_hash}])
 347
 348 # Openssl library
 349 have_openssl="no"
 350 if test "x${want_openssl}" = "xyes" || test "x${want_openssl}" = "xauto" ; then
 351    PKG_CHECK_EXISTS([openssl],
 352       [
 353        have_openssl="yes"
 354        AC_DEFINE([HAVE_OPENSSL], [1], [Have Openssl support])
 355        requirements_pc_eet="openssl ${requirements_pc_eet}"
 356       ],
 357       [have_openssl="no"])
 358 fi
 359
 360 if test "x${have_gnutls}" = "xyes" ; then
 361    secure_layer="GnuTLS"
 362 elif test "x${have_openssl}" = "xyes" ; then
 363    secure_layer="OpenSSL"
 364 else
 365    secure_layer="no"
 366 fi
 367
 368 have_cipher="no"
 369 if test "x${have_gnutls}" = "xyes" && test "x${want_cipher}" = "xyes" ; then
 370    have_cipher="yes"
 371    AC_DEFINE([HAVE_CIPHER], [1], [Have cipher support built in eet])
 372 elif test "x${have_openssl}" = "xyes" && test "x${want_cipher}" = "xyes" ; then
 373    have_cipher="yes"
 374    AC_DEFINE([HAVE_CIPHER], [1], [Have cipher support built in eet])
 375 fi
 376
 377 AC_MSG_CHECKING([whether to activate cipher support in eet])
 378 AC_MSG_RESULT([${have_cipher}])
 379
 380 have_signature="no"
 381 if test "x${have_gnutls}" = "xyes" && test "x${want_signature}" = "xyes" ; then
 382    have_signature="yes"
 383    AC_DEFINE([HAVE_SIGNATURE], [1], [Have signature support for eet file])
 384 elif test "x${have_openssl}" = "xyes" && test "x${want_signature}" = "xyes" ; then
 385    have_signature="yes"
 386    AC_DEFINE([HAVE_SIGNATURE], [1], [Have signature support for eet file])
 387 fi
 388
 389 AC_MSG_CHECKING([whether to activate signature support in eet])
 390 AC_MSG_RESULT([${have_signature}])
 391
 392 # libjpeg and zlib
 393 EFL_CHECK_LIBS([eet], [libjpeg zlib])
 394
 395 # Eina library
 396
 397 requirements_pc_eet="eina >= 1.2.0 ${requirements_pc_eet}"
 398 PKG_CHECK_MODULES([EET], [${requirements_pc_eet}])
 399
 400 case "$host_os" in
 401    mingw32ce*)
 402       requirements_libs_eet="${requirements_libs_eet} -lws2"
 403       ;;
 404    mingw*)
 405       requirements_libs_eet="${requirements_libs_eet} -lws2_32"
 406       ;;
 407 esac
 408
 409 EET_LIBS="${EET_LIBS} ${requirements_libs_eet}"
 410
 411
 412 ### Checks for header files
 413
 414 AC_CHECK_HEADERS(netinet/in.h unistd.h)
 415 EFL_CHECK_PATH_MAX
 416
 417 ### Checks for types
 418
 419
 420 ### Checks for structures
 421
 422
 423 ### Checks for compiler characteristics
 424 AM_PROG_CC_C_O
 425 AC_C_INLINE
 426 AC_PROG_CC_STDC
 427 AC_C___ATTRIBUTE__
 428
 429 # Check whether the null pointer is zero on this arch
 430 AC_TRY_RUN(
 431    [
 432 #include <stdlib.h>
 433 #include <inttypes.h>
 434 int main (int argc, char **argv) {
 435   void *foo = NULL;
 436   uintptr_t bar = (uintptr_t)foo;
 437   return (uintptr_t)foo;
 438 }
 439    ],
 440    [have_null="yes"],
 441    [have_null="no"],
 442    [
 443     AC_MSG_WARN([Cannot check when cross-compiling -- assuming null is okay])
 444     have_null="yes"
 445    ])
 446 AC_MSG_CHECKING([value of the null pointer])
 447 AC_MSG_RESULT([${have_null}])
 448
 449 if test ! "x${have_null}" = "xyes" ; then
 450    AC_MSG_WARN([Your system is a bit too funny, eet might not work properly])
 451 fi
 452
 453
 454 ### Checks for linker characteristics
 455
 456 # use --enable-auto-import on Windows
 457
 458 lt_enable_auto_import=""
 459 case "$host_os" in
 460    mingw*)
 461       lt_enable_auto_import="-Wl,--enable-auto-import"
 462       ;;
 463 esac
 464 AC_SUBST([lt_enable_auto_import])
 465
 466 case "${host_os}" in
 467    openbsd*)
 468       ;;
 469    *)
 470       EFL_LINKER_FLAG([-Wl,--as-needed])
 471       ;;
 472 esac
 473
 474
 475 ### Checks for library functions
 476 AC_ISC_POSIX
 477 AC_FUNC_ALLOCA
 478
 479 AC_CHECK_FUNCS(fmemopen open_memstream realpath)
 480
 481 EFL_CHECK_FUNCS([eet], [fnmatch])
 482
 483
 484 ### Unit tests, coverage and benchmarking
 485
 486 EFL_CHECK_TESTS([eet], [enable_tests="yes"], [enable_tests="no"])
 487
 488
 489 AC_SUBST([requirements_pc_eet])
 490 AC_SUBST([requirements_libs_eet])
 491
 492 AC_OUTPUT([
 493 Makefile
 494 eet.pc
 495 doc/Makefile
 496 doc/Doxyfile
 497 doc/eet.dox
 498 src/Makefile
 499 src/lib/Makefile
 500 src/bin/Makefile
 501 src/tests/Makefile
 502 src/examples/Makefile
 503 eet.spec
 504 ])
 505
 506
 507 #####################################################################
 508 ## Info
 509
 510 echo
 511 echo
 512 echo
 513 echo "------------------------------------------------------------------------"
 514 echo "$PACKAGE_NAME $PACKAGE_VERSION"
 515 echo "------------------------------------------------------------------------"
 516 echo
 517 echo "Configuration Options Summary:"
 518 echo
 519 echo "  Secure layer.........: ${secure_layer}"
 520 if test "x${have_gnutls}" = "xyes" || test "x${have_openssl}" = "xyes" ; then
 521    echo "    Cipher support.....: ${have_cipher}"
 522    echo "    Signature..........: ${have_signature}"
 523 fi
 524 echo
 525 echo "  Old eet file format..: ${old_eet_file_format}"
 526 echo
 527 echo "  Tests................: ${enable_tests} (Coverage: ${efl_enable_coverage})"
 528 echo
 529 echo "  Build eet............: $have_eet"
 530 echo
 531 echo "  Documentation........: ${build_doc}"
 532 if test "x${build_doc}" = "xyes" ; then
 533    echo "    Building...........: make doc"
 534 fi
 535 echo "  Examples.............: ${build_examples}"
 536 echo "  Examples installed...: ${install_examples}"
 537 echo
 538 echo "Compilation............: make (or gmake)"
 539 echo "  CPPFLAGS.............: $CPPFLAGS"
 540 echo "  CFLAGS...............: $CFLAGS"
 541 echo "  LDFLAGS..............: $LDFLAGS"
 542 echo
 543 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
 544 echo "  prefix...............: $prefix"
 545 echo