configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of polypaudio.
   7 #
   8 # polypaudio is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as published by
  10 # the Free Software Foundation; either version 2 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # polypaudio is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  16 # General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public License
  19 # along with polypaudio; if not, write to the Free Software Foundation,
  20 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  21
  22 AC_PREREQ(2.57)
  23 AC_INIT([polypaudio],[0.8],[mzcbylcnhqvb (at) 0pointer (dot) de])
  24 AC_CONFIG_SRCDIR([polyp/main.c])
  25 AC_CONFIG_HEADERS([config.h])
  26 AM_INIT_AUTOMAKE([foreign -Wall])
  27
  28 AC_SUBST(PA_MAJORMINOR, "$PACKAGE_VERSION")
  29 AC_SUBST(PACKAGE_URL, [http://0pointer.de/lennart/projects/polypaudio/])
  30
  31 AC_SUBST(PA_API_VERSION, 8)
  32
  33 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  34    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  35    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  36 fi
  37
  38 #### Checks for programs. ####
  39
  40 # CC
  41
  42 AC_PROG_CC
  43 AC_PROG_GCC_TRADITIONAL
  44 AC_GNU_SOURCE
  45
  46 # M4
  47
  48 AC_PATH_PROG([M4], [m4 gm4], [no])
  49 if test "x$M4" = xno ; then
  50    AC_MSG_ERROR([m4 missing])
  51 fi
  52
  53 # GCC flags
  54
  55 test_gcc_flag() {
  56     AC_LANG_CONFTEST([int main() {}])
  57     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
  58     ret=$?
  59     rm -f conftest.o
  60     return $ret
  61 }
  62
  63 # If using GCC specify some additional parameters
  64 if test "x$GCC" = "xyes" ; then
  65
  66     # We use gnu99 instead of c99 because many have interpreted the standard
  67     # in a way that int64_t isn't defined on non-64 bit platforms.
  68     DESIRED_FLAGS="-std=gnu99 -Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Winline -Wno-unused-parameter"
  69
  70     for flag in $DESIRED_FLAGS ; do
  71         AC_MSG_CHECKING([whether $CC accepts $flag])
  72         if test_gcc_flag $flag ; then
  73            CFLAGS="$CFLAGS $flag"
  74            AC_MSG_RESULT([yes])
  75         else
  76            AC_MSG_RESULT([no])
  77         fi
  78     done
  79 fi
  80
  81 # LYNX documentation generation
  82 AC_ARG_ENABLE(lynx,
  83         AC_HELP_STRING(--disable-lynx,Turn off lynx usage for documentation generation),
  84 [case "${enableval}" in
  85   yes) lynx=yes ;;
  86   no)  lynx=no ;;
  87   *) AC_MSG_ERROR(bad value ${enableval} for --disable-lynx) ;;
  88 esac],[lynx=yes])
  89
  90 if test x$lynx = xyes ; then
  91    AC_CHECK_PROG(have_lynx, lynx, yes, no)
  92
  93    if test x$have_lynx = xno ; then
  94      AC_MSG_WARN([*** lynx not found, plain text README will not be built ***])
  95    fi
  96 fi
  97
  98 AM_CONDITIONAL([USE_LYNX], [test "x$have_lynx" = xyes])
  99
 100 #### libtool stuff ####
 101
 102 AC_LTDL_ENABLE_INSTALL
 103 AC_LIBLTDL_INSTALLABLE
 104 AC_SUBST(LTDLINCL)
 105 AC_SUBST(LIBLTDL)
 106 AC_LIBTOOL_DLOPEN
 107 AC_LIBTOOL_WIN32_DLL
 108 AC_PROG_LIBTOOL
 109 AC_CONFIG_SUBDIRS(libltdl)
 110
 111 if test "x$enable_ltdl_install" = "xno" && test "x$ac_cv_lib_ltdl_lt_dlinit" = "xno" ; then
 112     AC_MSG_ERROR([[
 113
 114         *** Cannot find the libltdl development files.
 115         *** Maybe you need to install the libltdl-dev package.
 116         ]])
 117 fi
 118
 119 #### Determine build environment ####
 120
 121 os_is_win32=0
 122
 123 case "$host_os" in
 124         mingw*)
 125         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 126         os_is_win32=1
 127                 ;;
 128         esac
 129
 130 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 131
 132 ###################################
 133 #   Basic environment checks      #
 134 ###################################
 135
 136 #### Checks for header files. ####
 137
 138 # ISO
 139 AC_HEADER_STDC
 140
 141 # POSIX
 142 AC_CHECK_HEADERS([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
 143     netinet/in_systm.h netinet/ip.h netinet/tcp.h pwd.h sched.h \
 144     sys/resource.h sys/select.h sys/socket.h sys/wait.h \
 145     syslog.h])
 146 AC_CHECK_HEADERS([regex.h], [HAVE_REGEX=1], [HAVE_REGEX=0])
 147 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 148
 149 AM_CONDITIONAL(HAVE_REGEX, test "x$HAVE_REGEX" = "x1")
 150 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 151
 152 # XPG4-UNIX
 153 AC_CHECK_HEADERS([sys/poll.h])
 154
 155 # Linux
 156 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 157
 158 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 159
 160 # Windows
 161 AC_CHECK_HEADERS([windows.h winsock2.h ws2tcpip.h])
 162
 163 # Other
 164 AC_CHECK_HEADERS([sys/ioctl.h])
 165
 166 #### Typdefs, structures, etc. ####
 167
 168 AC_C_CONST
 169 AC_C_BIGENDIAN
 170 AC_TYPE_PID_T
 171 AC_TYPE_SIZE_T
 172 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
 173     [Define ssize_t if it is not done by the standard libs.])])
 174 AC_TYPE_OFF_T
 175 AC_TYPE_SIGNAL
 176 AC_TYPE_UID_T
 177
 178 AC_CHECK_DEFINE([SIGXCPU], [signal.h], [HAVE_SIGXCPU=1], [HAVE_SIGXCPU=0])
 179 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 180
 181 # Solaris lacks this
 182 AC_CHECK_DEFINE([INADDR_NONE], [netinet/in.h], [],
 183     [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])
 184
 185 #### Check for libs ####
 186
 187 # ISO
 188 AC_SEARCH_LIBS([pow], [m])
 189
 190 # POSIX
 191 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 192
 193 # BSD
 194 AC_SEARCH_LIBS([connect], [socket])
 195
 196 # Non-standard
 197
 198 # This magic is needed so we do not needlessly add static libs to the win32
 199 # build, disabling its ability to make dlls.
 200 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 201
 202 #### Check for functions ####
 203
 204 # POSIX
 205 AC_FUNC_FORK
 206 AC_FUNC_GETGROUPS
 207 AC_FUNC_SELECT_ARGTYPES
 208 AC_CHECK_FUNCS([getaddrinfo getgrgid_r getpwuid_r gettimeofday getuid \
 209     inet_ntop nanosleep setpgid setsid sigaction sleep])
 210 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 211
 212 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 213
 214 # X/OPEN
 215 AC_CHECK_FUNCS([readlink])
 216
 217 # SUSv2
 218 AC_CHECK_FUNCS([ctime_r usleep])
 219
 220 # BSD
 221 AC_CHECK_FUNCS([lstat])
 222
 223 # Non-standard
 224
 225 AC_CHECK_FUNCS(setresuid)
 226 AC_CHECK_FUNCS(setreuid)
 227
 228 #### POSIX threads ####
 229
 230 ACX_PTHREAD
 231
 232 ###################################
 233 #      External libraries         #
 234 ###################################
 235
 236 #### X11 (optional) ####
 237
 238 HAVE_X11=0
 239
 240 # The macro tests the host, not the build target
 241 if test "x$os_is_win32" != "x1" ; then
 242     AC_PATH_XTRA
 243     test "x$no_x" != "xyes" && HAVE_X11=1
 244 fi
 245
 246 AC_SUBST(HAVE_X11)
 247 AM_CONDITIONAL(HAVE_X11, test "x$HAVE_X11" = "x1")
 248 if test "x$HAVE_X11" = "x1" ; then
 249     AC_DEFINE([HAVE_X11], 1, [Have X11])
 250 fi
 251
 252 #### Capabilities (optional) ####
 253
 254 CAP_LIBS=''
 255
 256 AC_ARG_WITH(
 257         [caps],
 258         AC_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 259
 260 if test "x${with_caps}" != "xno"; then
 261     AC_SEARCH_LIBS([cap_init], [cap])
 262     AC_CHECK_HEADERS([sys/capability.h])
 263 fi
 264
 265 #### pkg-config ####
 266
 267 # Check for pkg-config manually first, as if its not installed the
 268 # PKG_PROG_PKG_CONFIG macro won't be defined.
 269 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 270
 271 if test x"$have_pkg_config" = "xno"; then
 272     AC_MSG_ERROR(pkg-config is required to install this program)
 273 fi
 274
 275 PKG_PROG_PKG_CONFIG
 276
 277 #### Sample rate conversion ####
 278
 279 PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ])
 280 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 281 AC_SUBST(LIBSAMPLERATE_LIBS)
 282
 283 #### Sound file ####
 284
 285 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.10 ])
 286 AC_SUBST(LIBSNDFILE_CFLAGS)
 287 AC_SUBST(LIBSNDFILE_LIBS)
 288
 289 #### OSS support (optional) ####
 290
 291 AC_CHECK_HEADERS([sys/soundcard.h], [HAVE_OSS=1], [HAVE_OSS=0])
 292 AC_SUBST(HAVE_OSS)
 293 AM_CONDITIONAL([HAVE_OSS], [test "x$HAVE_OSS" = x1])
 294
 295 #### ALSA support (optional) ####
 296
 297 PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.0 ], [HAVE_ALSA=1], [HAVE_ALSA=0])
 298 AC_SUBST(ASOUNDLIB_CFLAGS)
 299 AC_SUBST(ASOUNDLIB_LIBS)
 300 AC_SUBST(HAVE_ALSA)
 301 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 302
 303 #### Solaris audio support (optional) ####
 304
 305 AC_CHECK_HEADERS([sys/audio.h], [HAVE_SOLARIS=1], [HAVE_SOLARIS=0])
 306 AC_SUBST(HAVE_SOLARIS)
 307 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 308
 309 #### GLib 2 support (optional) ####
 310
 311 PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ], HAVE_GLIB20=1, HAVE_GLIB20=0)
 312 AC_SUBST(GLIB20_CFLAGS)
 313 AC_SUBST(GLIB20_LIBS)
 314 AC_SUBST(HAVE_GLIB20)
 315 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 316
 317 #### GLib 1 support (optional) ####
 318
 319 PKG_CHECK_MODULES(GLIB12, [ glib >= 1.2.0 ], HAVE_GLIB12=1, HAVE_GLIB12=0)
 320 AC_SUBST(GLIB12_CFLAGS)
 321 AC_SUBST(GLIB12_LIBS)
 322 AC_SUBST(HAVE_GLIB12)
 323 AM_CONDITIONAL([HAVE_GLIB12], [test "x$HAVE_GLIB12" = x1])
 324
 325 #### Howl support (optional) ####
 326
 327 PKG_CHECK_MODULES(HOWL, [ howl >= 0.9.8 ], HAVE_HOWL=1, HAVE_HOWL=0)
 328 AC_SUBST(HOWL_CFLAGS)
 329 AC_SUBST(HOWL_LIBS)
 330 AC_SUBST(HAVE_HOWL)
 331 AM_CONDITIONAL([HAVE_HOWL], [test "x$HAVE_HOWL" = x1])
 332
 333
 334 PKG_CHECK_MODULES(LIBOIL, [ liboil-0.3 >= 0.3.0 ])
 335 AC_SUBST(LIBOIL_CFLAGS)
 336 AC_SUBST(LIBOIL_LIBS)
 337
 338 #### Async DNS support (optional) ####
 339
 340 PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ], HAVE_LIBASYNCNS=1, HAVE_LIBASYNCNS=0)
 341 AC_SUBST(LIBASYNCNS_CFLAGS)
 342 AC_SUBST(LIBASYNCNS_LIBS)
 343 AC_SUBST(HAVE_LIBASYNCNS)
 344 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 345
 346 if test "x$HAVE_LIBASYNCNS" != "x0" ; then
 347    AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?])
 348 fi
 349
 350 #### TCP wrappers (optional) ####
 351
 352 ACX_LIBWRAP
 353 AC_SUBST(LIBWRAP_LIBS)
 354
 355 #### LIRC support (optional) ####
 356
 357 ACX_LIRC
 358 AC_SUBST(LIRC_CFLAGS)
 359 AC_SUBST(LIRC_LIBS)
 360 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 361
 362 ###################################
 363 #            Output               #
 364 ###################################
 365
 366 AC_ARG_ENABLE(
 367         [static-bins],
 368         AC_HELP_STRING([--enable-static-bins],[Statically link executables.]),
 369         [STATIC_BINS=1], [STATIC_BINS=0])
 370 AM_CONDITIONAL([STATIC_BINS], [test "x$STATIC_BINS" = "x1"])
 371
 372 AC_ARG_WITH(
 373         [preopen-mods],
 374         AC_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
 375         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
 376 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
 377 if test "x$PREOPEN_MODS" != "xall" ; then
 378     tmpLIBS=""
 379     for mod in $PREOPEN_MODS; do
 380         tmpLIBS="$tmpLIBS module-$mod.la"
 381     done
 382     PREOPEN_MODS="$tmpLIBS"
 383     AC_SUBST(PREOPEN_MODS)
 384 fi
 385
 386 AC_CONFIG_FILES([
 387 Makefile
 388 polyp/Makefile
 389 polyplib.pc
 390 polyplib-simple.pc
 391 polyplib-mainloop.pc
 392 polyplib-browse.pc
 393 polyplib-error.pc
 394 polyplib-glib-mainloop.pc
 395 polyplib-glib12-mainloop.pc
 396 doc/Makefile
 397 doc/README.html
 398 doc/cli.html
 399 doc/daemon.html
 400 doc/modules.html
 401 doxygen/Makefile
 402 doxygen/doxygen.conf
 403 polyp/polyplib-version.h
 404 doc/FAQ.html
 405 ])
 406 AC_OUTPUT