configure.ac

   1 # clutter package version number, (as distinct from shared library version)
   2 # An odd micro number indicates in-progress development from Git
   3 # An even micro number indicates a released version
   4 #
   5 # Making a point release:
   6 # - increase clutter_micro_version to the next even number
   7 # - increase clutter_interface_age to the next even number
   8 # After the release:
   9 # - increase clutter_micro_version to the next odd number
  10 # - increase clutter_interface_version to the next odd number
  11 m4_define([clutter_major_version], [1])
  12 m4_define([clutter_minor_version], [9])
  13 m4_define([clutter_micro_version], [1])
  14
  15 # • for stable releases: increase the interface age by 1 for each release;
  16 #   if the API changes, set to 0. interface_age and binary_age are used to
  17 #   create the soname of the shared object:
  18 #
  19 #  (<minor> * 100 + <micro>) - <interface_age>
  20 #
  21 # this allows using the same soname for different micro-releases in case
  22 # no API was added or deprecated. for instance:
  23 #
  24 #   clutter 1.2.0  -> 100 * 2 + 0  = 200, interface age = 0 -> 200
  25 #   clutter 1.2.2  -> 100 * 2 + 2  = 202, interface age = 2 -> 200
  26 #   clutter 1.2.4  -> 100 * 2 + 4  = 204, interface age = 4 -> 200
  27 #   [ API addition, deprecation ]
  28 #   clutter 1.2.6  -> 100 * 2 + 6  = 206, interface age = 0 -> 206
  29 #   clutter 1.2.8  -> 100 * 2 + 8  = 208, interface age = 2 -> 206
  30 #   clutter 1.2.10 -> 100 * 2 + 10 = 210, interface age = 4 -> 206
  31 #   ...
  32 #
  33 # • for development releases: keep clutter_interface_age to 0
  34 m4_define([clutter_interface_age], [0])
  35
  36 m4_define([clutter_binary_age], [m4_eval(100 * clutter_minor_version + clutter_micro_version)])
  37
  38 m4_define([clutter_release_status],
  39           [m4_if(m4_eval(clutter_micro_version % 2), [1], [git],
  40                  [m4_if(m4_eval(clutter_minor_version % 2), [1], [snapshot],
  41                                                                  [release])])])
  42
  43 m4_define([clutter_version], [clutter_major_version.clutter_minor_version.clutter_micro_version])
  44
  45 # change this only when breaking the API
  46 m4_define([clutter_api_version], [1.0])
  47
  48 AC_PREREQ([2.63])
  49
  50 AC_INIT([clutter],
  51         [clutter_version],
  52         [http://bugzilla.gnome.org/enter_bug.cgi?product=clutter],
  53         [clutter],
  54         [http://www.clutter-project.org])
  55
  56 AC_CONFIG_SRCDIR([clutter/clutter.h])
  57 AC_CONFIG_HEADERS([config.h])
  58 AC_CONFIG_AUX_DIR([build])
  59 AC_CONFIG_MACRO_DIR([build/autotools])
  60
  61 AM_INIT_AUTOMAKE([1.11 foreign -Wno-portability no-define no-dist-gzip dist-xz tar-ustar])
  62 AM_SILENT_RULES([yes])
  63
  64 AC_SUBST([CLUTTER_MAJOR_VERSION],  [clutter_major_version])
  65 AC_SUBST([CLUTTER_MINOR_VERSION],  [clutter_minor_version])
  66 AC_SUBST([CLUTTER_MICRO_VERSION],  [clutter_micro_version])
  67 AC_SUBST([CLUTTER_VERSION],        [clutter_version])
  68 AC_SUBST([CLUTTER_API_VERSION],    [clutter_api_version])
  69 AC_SUBST([CLUTTER_API_VERSION_AM], [$CLUTTER_MAJOR_VERSION\_0])
  70 AC_SUBST([CLUTTER_RELEASE_STATUS], [clutter_release_status])
  71
  72 m4_define([lt_current],  [m4_eval(100 * clutter_minor_version + clutter_micro_version - clutter_interface_age)])
  73 m4_define([lt_revision], [clutter_interface_age])
  74 m4_define([lt_age],      [m4_eval(clutter_binary_age - clutter_interface_age)])
  75 CLUTTER_LT_CURRENT=lt_current
  76 CLUTTER_LT_REV=lt_revision
  77 CLUTTER_LT_AGE=lt_age
  78 CLUTTER_LT_VERSION="$CLUTTER_LT_CURRENT:$CLUTTER_LT_REV:$CLUTTER_LT_AGE"
  79 CLUTTER_LT_LDFLAGS="-version-info $CLUTTER_LT_VERSION"
  80 AC_SUBST([CLUTTER_LT_CURRENT],  [lt_current])
  81 AC_SUBST([CLUTTER_LT_REVISION], [lt_revision])
  82 AC_SUBST([CLUTTER_LT_VERSION],  [$CLUTTER_LT_VERSION])
  83
  84 AC_PROG_SED
  85
  86 dnl = Preliminary platform checks =============================================
  87
  88 AC_CANONICAL_HOST
  89
  90 platform_win32=no
  91 platform_quartz=no
  92 platform_linux=no
  93
  94 AC_MSG_CHECKING([if building for some Win32 platform])
  95 AS_CASE([$host],
  96         [*-*-mingw*|*-*-cygwin*],
  97         [
  98           CLUTTER_LT_LDFLAGS="$CLUTTER_LT_LDFLAGS -no-undefined"
  99           platform_win32=yes
 100         ],
 101
 102         []
 103 )
 104 AC_MSG_RESULT([$platform_win32])
 105
 106 AM_CONDITIONAL(OS_WIN32, [test "$platform_win32" = "yes"])
 107
 108 AC_CHECK_HEADER([OpenGL/gl.h], [platform_quartz=yes], [platform_quartz=no])
 109 AM_CONDITIONAL(OS_QUARTZ, [test "$platform_quartz" = "yes"])
 110
 111 AC_CHECK_HEADER([GL/glx.h], [platform_glx=yes], [platform_glx=no])
 112 AC_CHECK_LIB([GL], [glXCreateContext], [platform_glx=yes], [platform_glx=no])
 113 AM_CONDITIONAL(OS_GLX, [test "$platform_glx" = "yes"])
 114
 115 AC_SUBST(CLUTTER_LT_LDFLAGS)
 116
 117 AC_CACHE_SAVE
 118
 119 dnl = Dependencies =========================================================
 120
 121 # Checks for programs.
 122 AM_PROG_CC_C_O
 123
 124 # require libtool >= 2.2
 125 LT_PREREQ([2.2.6])
 126 LT_INIT([disable-static])
 127
 128 # Checks for header files.
 129 AC_HEADER_STDC
 130
 131 # required versions for dependencies
 132 m4_define([glib_req_version],           [2.31.0])
 133 m4_define([cogl_req_version],           [1.9.1])
 134 m4_define([json_glib_req_version],      [0.12.0])
 135 m4_define([atk_req_version],            [2.1.5])
 136 m4_define([cairo_req_version],          [1.10])
 137 m4_define([pango_req_version],          [1.20])
 138 m4_define([gi_req_version],             [0.9.5])
 139 m4_define([uprof_req_version],          [0.3])
 140 m4_define([gtk_doc_req_version],        [1.15])
 141 m4_define([xfixes_req_version],         [3])
 142 m4_define([xcomposite_req_version],     [0.4])
 143 m4_define([gdk_req_version],            [3.0.0])
 144
 145 AC_SUBST([GLIB_REQ_VERSION],       [glib_req_version])
 146 AC_SUBST([COGL_REQ_VERSION],       [cogl_req_version])
 147 AC_SUBST([JSON_GLIB_REQ_VERSION],  [json_glib_req_version])
 148 AC_SUBST([ATK_REQ_VERSION],        [atk_req_version])
 149 AC_SUBST([CAIRO_REQ_VERSION],      [cairo_req_version])
 150 AC_SUBST([PANGO_REQ_VERSION],      [pango_req_version])
 151 AC_SUBST([GI_REQ_VERSION],         [gi_req_version])
 152 AC_SUBST([UPROF_REQ_VERSION],      [uprof_req_version])
 153 AC_SUBST([GTK_DOC_REQ_VERSION],    [gtk_doc_req_version])
 154 AC_SUBST([XFIXES_REQ_VERSION],     [xfixes_req_version])
 155 AC_SUBST([XCOMPOSITE_REQ_VERSION], [xcomposite_req_version])
 156 AC_SUBST([GDK_REQ_VERSION],        [gdk_req_version])
 157
 158 # Checks for typedefs, structures, and compiler characteristics.
 159 AM_PATH_GLIB_2_0([glib_req_version],
 160                  [],
 161                  [AC_MSG_ERROR([glib-2.0 is required])],
 162                  [gobject gthread gmodule-no-export])
 163
 164 # Check for -Bsymbolic-functions to avoid intra-library PLT jumps
 165 AC_ARG_ENABLE([Bsymbolic],
 166               [AS_HELP_STRING([--disable-Bsymbolic],
 167                               [Avoid linking with -Bsymbolic])],
 168               [],
 169               [
 170                 saved_LDFLAGS="${LDFLAGS}"
 171                 AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 172                 LDFLAGS=-Wl,-Bsymbolic-functions
 173                 AC_TRY_LINK([], [int main (void) { return 0; }],
 174                             [
 175                               AC_MSG_RESULT([yes])
 176                               enable_Bsymbolic=yes
 177                             ],
 178                             [
 179                               AC_MSG_RESULT([no])
 180                               enable_Bsymbolic=no
 181                             ])
 182                 LDFLAGS="${saved_LDFLAGS}"
 183               ])
 184
 185 AS_IF([test "x$enable_Bsymbolic" = "xyes"], [CLUTTER_LINK_FLAGS=-Wl[,]-Bsymbolic-functions])
 186 AC_SUBST(CLUTTER_LINK_FLAGS)
 187
 188 AC_CACHE_SAVE
 189
 190 dnl ========================================================================
 191
 192 FLAVOUR_LIBS=""
 193 FLAVOUR_CFLAGS=""
 194 CLUTTER_BACKENDS=""
 195
 196 experimental_backend=no
 197
 198 # base dependencies for core
 199 CLUTTER_BASE_PC_FILES="cogl-1.0 >= $COGL_REQ_VERSION cairo-gobject >= $CAIRO_REQ_VERSION atk >= $ATK_REQ_VERSION pangocairo >= $PANGO_REQ_VERSION cogl-pango-1.0 json-glib-1.0 >= $JSON_GLIB_REQ_VERSION"
 200
 201 # backend specific pkg-config files
 202 BACKEND_PC_FILES=""
 203
 204 dnl === Clutter windowing system backend ======================================
 205
 206 AC_ARG_ENABLE([x11-backend],
 207               [AS_HELP_STRING([--enable-x11-backend=@<:@yes/no@:>@], [Enable the X11 backend (default=check)])],
 208               [enable_x11=$enableval],
 209               [enable_x11=check])
 210 AC_ARG_ENABLE([win32-backend],
 211               [AS_HELP_STRING([--enable-win32-backend=@<:@yes/no@:>@], [Enable the Windows backend (default=check)])],
 212               [enable_win32=$enableval],
 213               [enable_win32=check])
 214 AC_ARG_ENABLE([quartz-backend],
 215               [AS_HELP_STRING([--enable-quartz-backend=@<:@yes/no@:>@], [Enable the OS X backend (default=check)])],
 216               [enable_osx=$enableval],
 217               [enable_osx=check])
 218 AC_ARG_ENABLE([gdk-backend],
 219               [AS_HELP_STRING([--enable-gdk-backend=@<:@yes/no@:>@], [Enable the GDK backend (default=check)])],
 220               [enable_gdk=$enableval],
 221               [enable_gdk=check])
 222 AC_ARG_ENABLE([wayland-backend],
 223               [AS_HELP_STRING([--enable-wayland-backend=@<:@yes/no@:>@], [Enable the Wayland client backend (default=no)])],
 224               [enable_wayland=$enableval],
 225               [enable_wayland=no])
 226 AC_ARG_ENABLE([egl-backend],
 227               [AS_HELP_STRING([--enable-egl-backend=@<:@yes/no@:>@], [Enable the EGL framebuffer backend (default=no)])],
 228               [enable_egl=$enableval],
 229               [enable_egl=no])
 230
 231 dnl Define default values
 232 AS_IF([test "x$enable_x11" = "xcheck"],
 233       [
 234         AS_IF([test "x$platform_glx" = "xyes"], [enable_x11=yes], [enable_x11=no])
 235       ])
 236
 237 AS_IF([test "x$enable_win32" = "xcheck"],
 238       [
 239         AS_IF([test "x$platform_win32" = "xyes"], [enable_win32=yes], [enable_win32=no])
 240       ])
 241
 242 AS_IF([test "x$enable_osx" = "xcheck"],
 243       [
 244         AS_IF([test "x$platform_quartz" = "xyes"], [enable_osx=yes], [enable_osx=no])
 245       ])
 246
 247 AS_IF([test "x$enable_gdk" = "xcheck"],
 248       [
 249         PKG_CHECK_EXISTS([gdk-3.0 >= gdk_req_version], [enable_gdk=yes], [enable_gdk=no])
 250       ])
 251
 252 dnl Per-backend rules
 253 AS_IF([test "x$enable_x11" = "xyes"],
 254       [
 255         CLUTTER_BACKENDS="$CLUTTER_BACKENDS x11"
 256
 257         SUPPORT_X11=1
 258         SUPPORT_GLX=1
 259         SUPPORT_COGL=1
 260
 261         # Mesa 7.3 added a GL pkg-config file, finally, but if a pkg-config
 262         # file isn't found just add -lGL and hope for the best.
 263         PKG_CHECK_EXISTS([gl],
 264                          [BACKEND_PC_FILES="$BACKEND_PC_FILES gl"],
 265                          [FLAVOUR_LIBS="$FLAVOUR_LIBS -lGL"])
 266
 267         # We might fall back to DRM for sync-to-vblank on GLX
 268         PKG_CHECK_EXISTS([libdrm],
 269                          [
 270                            AC_DEFINE([HAVE_DRM], [1], [Have libdrm support])
 271                            BACKEND_PC_FILES="$BACKEND_PC_FILES libdrm"
 272                          ],
 273                          [])
 274
 275         # we use fontconfig API and pango-fc when the fontconfig
 276         # configuration changes
 277         PKG_CHECK_EXISTS([pangoft2],
 278                          [
 279                            AC_DEFINE([HAVE_PANGO_FT2], [1], [Supports PangoFt2])
 280                            BACKEND_PC_FILES="$BACKEND_PC_FILES pangoft2"
 281                          ],
 282                          [])
 283
 284         AC_DEFINE([HAVE_CLUTTER_GLX], [1], [Have the GLX backend])
 285       ])
 286
 287 AS_IF([test "x$enable_gdk" = "xyes"],
 288       [
 289         CLUTTER_BACKENDS="$CLUTTER_BACKENDS gdk"
 290
 291         SUPPORT_GDK=1
 292         SUPPORT_COGL=1
 293
 294         BACKEND_PC_FILES="$BACKEND_PC_FILES gdk-3.0"
 295         PKG_CHECK_EXISTS([gl], [BACKEND_PC_FILES="$BACKEND_PC_FILES gl"], [])
 296       ])
 297
 298 AS_IF([test "x$enable_wayland" = "xyes"],
 299       [
 300         CLUTTER_BACKENDS="$CLUTTER_BACKENDS wayland"
 301
 302         experimental_backend="yes"
 303
 304         SUPPORT_WAYLAND=1
 305         SUPPORT_EVDEV=1
 306
 307         PKG_CHECK_EXISTS([gl], [BACKEND_PC_FILES="$BACKEND_PC_FILES gl"], [])
 308         PKG_CHECK_EXISTS([egl], [BACKEND_PC_FILES="$BACKEND_PC_FILES egl"], [])
 309         PKG_CHECK_EXISTS([wayland-client xkbcommon],
 310                          [BACKEND_PC_FILES="$BACKEND_PC_FILES wayland-client xkbcommon"],
 311                          [])
 312
 313         AC_DEFINE([HAVE_CLUTTER_WAYLAND], [1], [Have the Wayland backend])
 314       ])
 315
 316 AS_IF([test "x$enable_egl" = "xyes"],
 317       [
 318         CLUTTER_BACKENDS="$CLUTTER_BACKENDS egl"
 319
 320         SUPPORT_EGL=1
 321         SUPPORT_COGL=1
 322
 323         # if Mesa has support for egl, we can use it as well
 324         PKG_CHECK_EXISTS([egl],
 325                          [
 326                            BACKEND_PC_FILES="$BACKEND_PC_FILES egl"
 327                          ],
 328                          [])
 329
 330         AC_ARG_WITH([tslib],
 331                     [AS_HELP_STRING([--with-tslib=@<:@yes/no@:>@], [Use TSLib for events (default=no)])],
 332                     [],
 333                     [with_tslib=no])
 334
 335         AC_ARG_WITH([evdev],
 336                     [AS_HELP_STRING([--with-evdev=@<:@yes/no@:>@], [Use evdev for events (default=yes)])],
 337                     [],
 338                     [with_evdev=yes])
 339
 340         AC_ARG_WITH([gdl],
 341                     [AS_HELP_STRING([--with-gdl=@<:@yes/no@:>@], [Use libgdl for CE3100/CE4100 support (default=no)])],
 342                     [],
 343                     [with_gdl=no])
 344
 345         AS_IF([test "x$with_tslib" = "xyes"],
 346               [
 347                 PKG_CHECK_MODULES(TSLIB, [tslib-1.0], [have_tslib=yes], [have_tslib=no])
 348                 AS_IF([test "x$have_tslib" = "xyes"],
 349                       [
 350                         AC_DEFINE([HAVE_TSLIB], [1], [Have tslib for touchscreen handling])
 351                         SUPPORT_TSLIB=1
 352                       ])
 353               ],
 354               [have_tslib=no])
 355
 356         AS_IF([test "x$with_evdev" = "xyes"],
 357               [
 358                 PKG_CHECK_MODULES(EVDEV, [gudev-1.0 xkbcommon], [have_evdev=yes], [have_evdev=no])
 359                 AS_IF([test "x$have_evdev" = "xyes"],
 360                       [
 361                         AC_DEFINE([HAVE_EVDEV], [1], [Have evdev support for input handling])
 362                         SUPPORT_EVDEV=1
 363                       ])
 364               ],
 365               [have_evdev=no])
 366
 367         AS_IF([test "x$with_gdl" = "xyes"],
 368               [
 369                 have_gdl=no
 370
 371                 AC_CHECK_HEADERS([libgdl.h], [have_gdl=yes])
 372
 373                 AS_IF([test "x$have_gdl" = "xno"],
 374                       [
 375                         AC_CHECK_HEADERS([CE4100/libgdl.h],
 376                                          [
 377                                            FLAVOUR_CFLAGS="-I/usr/include/CE4100"
 378                                            have_gdl=yes
 379                                            CLUTTER_CEX100_LIBGDL_PREFIX=CE4100/
 380                                          ])
 381                       ])
 382
 383                 AC_SUBST(CLUTTER_CEX100_LIBGDL_PREFIX)
 384
 385                 AS_IF([test "x$have_gdl" = "xno"], [AC_MSG_ERROR([libgdl.h not found])])
 386
 387                 FLAVOUR_LIBS="$FLAVOUR_LIBS -lgdl"
 388
 389                 SUPPORT_EGL_PLATFORM_GDL=1
 390
 391                 AC_DEFINE([CLUTTER_EGL_BACKEND_CEX100], [1], [Use CEX100 EGL backend])
 392               ],
 393               [have_gdl=no])
 394
 395         FLAVOUR_LIBS="$FLAVOUR_LIBS $TSLIB_LIBS $EVDEV_LIBS"
 396         FLAVOUR_CFLAGS="$FLAVOUR_CFLAGS $TSLIB_CFLAGS $EVDEV_CFLAGS"
 397
 398         AC_DEFINE([CLUTTER_EGL_BACKEND_GENERIC], [1], [Use Generic EGL backend])
 399
 400         AC_DEFINE([HAVE_CLUTTER_EGL], [1], [Have the EGL backend])
 401       ])
 402
 403 AS_IF([test "x$enable_osx" = "xyes"],
 404       [
 405         CLUTTER_BACKENDS="$CLUTTER_BACKENDS osx"
 406
 407         AC_DEFINE([HAVE_CLUTTER_OSX], [1], [Have the OSX backend])
 408
 409         FLAVOUR_LIBS="$FLAVOUR_LIBS -framework Cocoa -framework OpenGL"
 410
 411         SUPPORT_OSX=1
 412       ])
 413
 414 AS_IF([test "x$enable_win32" = "xyes"],
 415       [
 416         CLUTTER_BACKENDS="$CLUTTER_BACKENDS win32"
 417
 418         AC_DEFINE([HAVE_CLUTTER_WIN32], [1], [Have the Win32 backend])
 419
 420         FLAVOUR_LIBS="$FLAVOUR_LIBS -lopengl32 -lgdi32 -lwinmm"
 421         FLAVOUR_CFLAGS="$FLAVOUR_CFLAGS -D_WIN32_WINNT=0x0500"
 422
 423         AC_CHECK_TOOL(WINDRES, [windres], [AC_MSG_ERROR([*** windres is required])])
 424
 425         SUPPORT_WIN32=1
 426       ])
 427
 428 AS_IF([test "x$CLUTTER_BACKENDS" = "x"],
 429       [
 430         AC_MSG_ERROR([No backend enabled. You need to enable at least one backend.])
 431       ])
 432
 433 # conditionals for use in automake files...
 434 AM_CONDITIONAL(SUPPORT_GLX,     [test "x$SUPPORT_GLX" = "x1"])
 435 AM_CONDITIONAL(SUPPORT_X11,     [test "x$SUPPORT_X11" = "x1"])
 436 AM_CONDITIONAL(SUPPORT_GDK,     [test "x$SUPPORT_GDK" = "x1"])
 437 AM_CONDITIONAL(SUPPORT_EGL,     [test "x$SUPPORT_EGL" = "x1"])
 438 AM_CONDITIONAL(SUPPORT_OSX,     [test "x$SUPPORT_OSX" = "x1"])
 439 AM_CONDITIONAL(SUPPORT_WIN32,   [test "x$SUPPORT_WIN32" = "x1"])
 440 AM_CONDITIONAL(SUPPORT_CEX100,  [test "x$SUPPORT_EGL_PLATFORM_GDL" = "x1"])
 441 AM_CONDITIONAL(SUPPORT_WAYLAND, [test "x$SUPPORT_WAYLAND" = "x1"])
 442 AM_CONDITIONAL(SUPPORT_STUB,    [test "x$SUPPORT_WIN32" = "x1" -o \
 443                                       "x$SUPPORT_OSX" = "x1" -o \
 444                                       "x$SUPPORT_WAYLAND" = "x1"])
 445
 446 AM_CONDITIONAL(USE_COGL,  [test "x$SUPPORT_COGL" = "x1"])
 447 AM_CONDITIONAL(USE_TSLIB, [test "x$have_tslib" = "xyes"])
 448 AM_CONDITIONAL(USE_EVDEV, [test "x$have_evdev" = "xyes"])
 449 AM_CONDITIONAL(USE_GLD,   [test "x$have_gdl" = "xyes"])
 450
 451 dnl Instead of using AM_CFLAGS to ensure
 452 dnl COGL_ENABLE_EXPERIMENTAL_2_0_API is defined while compiling clutter
 453 dnl and cogl code we use a define in config.h instead. This helps ensure
 454 dnl other tools such as glib-mkenums and gir-scanner don't end up
 455 dnl using the define also.
 456 AC_DEFINE([COGL_ENABLE_EXPERIMENTAL_2_0_API], [1], [Can use Cogl 2.0 API internally])
 457
 458 dnl strip leading spaces
 459 CLUTTER_BACKENDS=${CLUTTER_BACKENDS#* }
 460 AC_SUBST(CLUTTER_BACKENDS)
 461
 462 AC_CACHE_SAVE
 463
 464 dnl === Clutter configuration =================================================
 465
 466 CLUTTER_CONFIG_DEFINES=
 467
 468 # windowing systems
 469 AS_IF([test "x$SUPPORT_X11" = "x1"],
 470       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 471 #define CLUTTER_WINDOWING_X11 \"x11\""])
 472 AS_IF([test "x$SUPPORT_GDK" = "x1"],
 473       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 474 #define CLUTTER_WINDOWING_GDK \"gdk\""])
 475 AS_IF([test "x$SUPPORT_GLX" = "x1"],
 476       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 477 #define CLUTTER_WINDOWING_GLX \"glx\""])
 478 AS_IF([test "x$SUPPORT_EGL" = "x1"],
 479       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 480 #define CLUTTER_WINDOWING_EGL \"eglnative\""])
 481 AS_IF([test "x$SUPPORT_WAYLAND" = "x1"],
 482       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 483 #define CLUTTER_WINDOWING_WAYLAND \"wayland\""])
 484 AS_IF([test "x$SUPPORT_OSX" = "x1"],
 485       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 486 #define CLUTTER_WINDOWING_OSX \"osx\""])
 487 AS_IF([test "x$SUPPORT_WIN32" = "x1"],
 488       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 489 #define CLUTTER_WINDOWING_WIN32 \"win32\""])
 490 AS_IF([test "x$SUPPORT_EGL_PLATFORM_GDL" = "x1"],
 491       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 492 #define CLUTTER_WINDOWING_CEX100 \"cex100\""])
 493 AS_IF([test "x$SUPPORT_EVDEV" = "x1"],
 494       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 495 #define CLUTTER_INPUT_EVDEV \"evdev\""])
 496 AS_IF([test "x$SUPPORT_TSLIB" = "x1"],
 497       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 498 #define CLUTTER_INPUT_TSLIB \"tslib\""])
 499
 500 AC_SUBST([CLUTTER_CONFIG_DEFINES])
 501
 502 dnl === Clutter substitutions kept for backwards compatibility ================
 503 AC_SUBST([CLUTTER_WINSYS],       [deprecated])
 504 AC_SUBST([CLUTTER_WINSYS_BASE],  [deprecated])
 505 AC_SUBST([CLUTTER_STAGE_TYPE],   [deprecated])
 506 AC_SUBST([CLUTTER_SONAME_INFIX], [deprecated])
 507 AC_SUBST([CLUTTER_FLAVOUR],      [deprecated])
 508 AC_SUBST([CLUTTER_COGL],         [deprecated])
 509 AC_SUBST([COGL_DRIVER],          [deprecated])
 510
 511 dnl === Image loading backend =================================================
 512 IMAGE_PC_FILES=""
 513
 514 dnl === X11 checks, only for X11-based backends ===============================
 515 X11_PC_FILES=""
 516 x11_tests=no
 517
 518 AS_IF([test "x$SUPPORT_X11" = "x1"],
 519       [
 520         # base X11 includes and libraries
 521         AC_MSG_CHECKING([for X11])
 522
 523         # start with pkg-config
 524         PKG_CHECK_EXISTS([x11], [have_x11=yes], [have_x11=no])
 525         AS_IF([test "x$have_x11" = "xyes"],
 526               [
 527                 X11_PC_FILES="x11"
 528
 529                 # we actually need to ask for CFLAGS and LIBS
 530                 X11_CFLAGS=`$PKG_CONFIG --cflags $X11_PC_FILES`
 531                 X11_LIBS=`$PKG_CONFIG --libs $X11_PC_FILES`
 532
 533                 AC_MSG_RESULT([found])
 534               ],
 535               [
 536                 # no pkg-config, let's go old school
 537                 AC_PATH_X
 538
 539                 AS_IF([test "x$no_x" = "xyes"],
 540                       [AC_MSG_ERROR([No X11 Libraries found])],
 541                       [
 542                         AS_IF([test "x$x_includes" != "xNONE" && test -n "$x_includes"],
 543                               [X11_CFLAGS=-I`echo $x_includes | sed -e "s/:/ -I/g"`])
 544
 545                         AS_IF([test "x$x_libraries" != "xNONE" && test -n "$x_libraries"],
 546                               [X11_LIBS=-L`echo $x_libraries | sed -e "s/:/ -L/g"`])
 547
 548                         AC_MSG_RESULT([found])
 549                       ]
 550                 )
 551               ]
 552         )
 553
 554         # XEXT (required)
 555         AC_MSG_CHECKING([for XEXT extension])
 556         PKG_CHECK_EXISTS([xext], [have_xext=yes], [have_xext=no])
 557         AS_IF([test "x$have_xext" = "xyes"],
 558               [
 559                 AC_DEFINE(HAVE_XEXT, [1], [Define to 1 if we have the XEXT X extension])
 560
 561                 X11_LIBS="$X11_LIBS -lXext"
 562                 X11_PC_FILES="$X11_PC_FILES xext"
 563
 564                 AC_MSG_RESULT([found])
 565               ],
 566               [AC_MSG_ERROR([Not found])]
 567         )
 568
 569         # XFIXES (required)
 570         AC_MSG_CHECKING([for XFIXES extension >= $XFIXES_REQ_VERSION])
 571         PKG_CHECK_EXISTS([xfixes >= $XFIXES_REQ_VERSION], [have_xfixes=yes], [have_xfixes=no])
 572         AS_IF([test "x$have_xfixes" = "xyes"],
 573               [
 574                 AC_DEFINE(HAVE_XFIXES, [1], [Define to 1 if we have the XFIXES X extension])
 575
 576                 X11_LIBS="$X11_LIBS -lXfixes"
 577                 X11_PC_FILES="$X11_PC_FILES xfixes >= $XFIXES_REQ_VERSION"
 578
 579                 AC_MSG_RESULT([found])
 580               ],
 581               [AC_MSG_ERROR([Not found])]
 582         )
 583
 584         # XDAMAGE (required)
 585         AC_MSG_CHECKING([for XDAMAGE extension])
 586         PKG_CHECK_EXISTS([xdamage], [have_xdamage=yes], [have_xdamage=no])
 587         AS_IF([test "x$have_xdamage" = "xyes"],
 588               [
 589                 AC_DEFINE(HAVE_XDAMAGE, [1], [Define to 1 if we have the XDAMAGE X extension])
 590
 591                 X11_LIBS="$X11_LIBS -lXdamage"
 592                 X11_PC_FILES="$X11_PC_FILES xdamage"
 593
 594                 AC_MSG_RESULT([found])
 595               ],
 596               [AC_MSG_ERROR([not found])]
 597         )
 598
 599         # XCOMPOSITE (optional)
 600         AC_MSG_CHECKING([for XCOMPOSITE extension >= $XCOMPOSITE_REQ_VERSION])
 601         PKG_CHECK_EXISTS([xcomposite >= $XCOMPOSITE_REQ_VERSION], [have_xcomposite=yes], [have_xcomposite=no])
 602         AS_IF([test "x$have_xcomposite" = "xyes"],
 603               [
 604                 AC_DEFINE(HAVE_XCOMPOSITE, [1], [Define to 1 if we have the XCOMPOSITE X extension])
 605
 606                 X11_LIBS="$X11_LIBS -lXcomposite"
 607                 X11_PC_FILES="$X11_PC_FILES xcomposite >= $XCOMPOSITE_REQ_VERSION"
 608
 609                 AC_MSG_RESULT([found])
 610               ],
 611               [AC_MSG_ERROR([not found])]
 612         )
 613
 614         # X Generic Extensions (optional)
 615         clutter_save_CPPFLAGS="$CPPFLAGS"
 616         CPPFLAGS="$CPPFLAGS $X11_CFLAGS"
 617
 618         clutter_save_LIBS="$LIBS"
 619         LIBS="$LIBS $X11_LIBS"
 620
 621         have_xge=no
 622         AC_CHECK_FUNC([XGetEventData],
 623                       [
 624                         AC_DEFINE([HAVE_XGE], [1], [Define to 1 if X Generic Extensions is available])
 625                         have_xge=yes
 626                       ])
 627
 628         CPPFLAGS="$clutter_save_CPPFLAGS"
 629         LIBS="$clutter_save_LIBS"
 630
 631         # XI (optional)
 632         AC_ARG_ENABLE([xinput],
 633                       [AS_HELP_STRING([--enable-xinput], [Use the XI X extension])],
 634                       [],
 635                       [enable_xinput=yes])
 636
 637         AS_IF([test "x$enable_xinput" = "xyes"],
 638               [
 639                 PKG_CHECK_EXISTS([xi], [have_xinput=yes], [have_xinput=no])
 640               ],
 641               [
 642                 have_xinput=no
 643               ])
 644
 645         AS_CASE([$have_xinput],
 646
 647                 [yes],
 648                 [
 649                   AC_CHECK_HEADERS([X11/extensions/XInput2.h],
 650                                    [
 651                                      have_xinput2=yes
 652                                      AC_DEFINE([HAVE_XINPUT_2],
 653                                                [1],
 654                                                [Define to 1 if XI2 is available])
 655                                    ],
 656                                    [
 657                                      have_xinput2=no
 658                                      AC_DEFINE([HAVE_XINPUT],
 659                                                [1],
 660                                                [Define to 1 if XInput is available])
 661                                    ])
 662
 663                   X11_LIBS="$X11_LIBS $XINPUT_LIBS"
 664                   X11_PC_FILES="$X11_PC_FILES xi"
 665                 ],
 666
 667                 [no],
 668                 [have_xinput2=no],
 669
 670                 [*],
 671                 [AC_MSG_ERROR([Invalid argument for --enable-xinput])]
 672         )
 673
 674         # XKB
 675         clutter_save_CPPFLAGS="$CPPFLAGS"
 676         CPPFLAGS="$CPPFLAGS $X11_CFLAGS"
 677
 678         clutter_save_LIBS="$LIBS"
 679         LIBS="$LIBS $X11_LIBS"
 680
 681         have_xkb=no
 682         AC_CHECK_FUNC([XkbQueryExtension],
 683                       [
 684                         AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension])
 685                         have_xkb=yes
 686                       ])
 687
 688         CPPFLAGS="$clutter_save_CPPFLAGS"
 689         LIBS="$clutter_save_LIBS"
 690
 691         x11_tests=yes
 692         BACKEND_PC_FILES="$BACKEND_PC_FILES $X11_PC_FILES"
 693         FLAVOUR_LIBS="$FLAVOUR_LIBS $X11_LIBS"
 694         FLAVOUR_CFLAGS="$FLAVOUR_CFLAGS $X11_CFLAGS"
 695       ]
 696 )
 697
 698 AM_CONDITIONAL([BUILD_XI2], [test "x$have_xinput2" = "xyes"])
 699 AM_CONDITIONAL([X11_TESTS], [test "x$x11_tests" = "xyes"])
 700
 701 dnl === Enable debug level ====================================================
 702
 703 m4_define([debug_default], [m4_if(m4_eval(clutter_minor_version % 2), [1], [yes], [minimum])])
 704 AC_ARG_ENABLE([debug],
 705               [AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 706                               [Control Clutter debugging level @<:@default=]debug_default[@:>@])],
 707               [],
 708               [enable_debug=debug_default])
 709
 710 AS_CASE([$enable_debug],
 711
 712         [yes],
 713         [
 714           test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 715           CLUTTER_DEBUG_CFLAGS="-DCLUTTER_ENABLE_DEBUG"
 716         ],
 717
 718         [minimum],
 719         [CLUTTER_DEBUG_CFLAGS="-DCLUTTER_ENABLE_DEBUG -DG_DISABLE_CAST_CHECKS"],
 720
 721         [no],
 722         [CLUTTER_DEBUG_CFLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"],
 723
 724         [AC_MSG_ERROR([Unknown argument for --enable-debug])]
 725 )
 726
 727 AC_SUBST(CLUTTER_DEBUG_CFLAGS)
 728
 729 dnl === Enable deprecation guards ==================================================
 730
 731 m4_define([deprecated_default],
 732           [m4_if(m4_eval(clutter_minor_version % 2),
 733                  [1],
 734                  [no],
 735                  [yes])])
 736
 737 AC_ARG_ENABLE([deprecated],
 738               [AS_HELP_STRING([--enable-deprecated=@<:@no/yes@:>@],
 739                               [Whether deprecated symbols should be disabled when compiling Clutter @<:@default=]deprecated_default[@:>@])],
 740               [],
 741               [enable_deprecated=deprecated_default])
 742
 743 AS_CASE([$enable_deprecated],
 744
 745         [no],
 746         [
 747           CLUTTER_DEPRECATED_CFLAGS="-DG_DISABLE_SINGLE_INCLUDES -DCOGL_DISABLE_DEPRECATED -DCLUTTER_DISABLE_DEPRECATED"
 748         ],
 749
 750         [yes],
 751         [
 752           CLUTTER_DEPRECATED_CFLAGS="-DGLIB_DISABLE_DEPRECATION_WARNINGS -DCLUTTER_DISABLE_DEPRECATION_WARNINGS"
 753         ],
 754
 755         [AC_MSG_ERROR([Unknown argument for --enable-deprecated])]
 756 )
 757
 758 AC_SUBST([CLUTTER_DEPRECATED_CFLAGS])
 759
 760
 761 dnl === Conformance test suite ================================================
 762
 763 AC_ARG_ENABLE([conformance],
 764               [AS_HELP_STRING([--enable-conformance=@<:@no/yes@:>@],
 765                               [Build conformance test suite @<:@default=yes@:>@])],
 766               [],
 767               [enable_conformance=yes])
 768
 769 AM_CONDITIONAL([BUILD_TESTS], [test "x$enable_conformance" = "xyes"])
 770
 771 dnl === Profiling =============================================================
 772
 773 m4_define([profile_default], [no])
 774 AC_ARG_ENABLE(profile,
 775               AS_HELP_STRING([--enable-profile=@<:@no/yes@:>@],
 776                              [Turn on profiling support. yes; All profiling probe points are compiled in and may be runtime enabled. no; No profiling support will built into clutter.  @<:@default=no@:>@]),
 777               [],
 778               [enable_profile=profile_default])
 779
 780 AS_CASE([$enable_profile],
 781
 782         [yes],
 783         [
 784           AS_IF([test "x$GCC" = "xyes"],
 785                 [
 786                   PKG_CHECK_MODULES([PROFILE_DEP], [uprof-0.3])
 787                   CLUTTER_PROFILE_CFLAGS="-DCLUTTER_ENABLE_PROFILE $PROFILE_DEP_CFLAGS"
 788                   CLUTTER_PROFILE_LDFLAGS="$PROFILE_DEP_LIBS"
 789
 790                   AS_IF([test "x$enable_debug" = "xyes"], [CLUTTER_PROFILE_CFLAGS+=" -DUPROF_DEBUG"])
 791                 ],
 792                 [
 793                   AC_MSG_ERROR([--enable-profile is currently only supported if using GCC])
 794                 ])
 795         ],
 796
 797         [no],
 798         [
 799           CLUTTER_PROFILE_CFLAGS=""
 800           CLUTTER_PROFILE_LDFLAGS=""
 801         ],
 802
 803         [*], [AC_MSG_ERROR([Invalid value for --enable-profile])]
 804 )
 805 AM_CONDITIONAL(PROFILE, test "x$enable_profile" != "xno")
 806 AC_SUBST(CLUTTER_PROFILE_CFLAGS)
 807 AC_SUBST(CLUTTER_PROFILE_LDFLAGS)
 808
 809 dnl === Coverage report =======================================================
 810
 811 AC_PATH_PROG([GCOV], [gcov], [enable_gcov=no])
 812
 813 AC_MSG_CHECKING([whether to build with gcov testing])
 814
 815 AC_ARG_ENABLE([gcov],
 816               [AS_HELP_STRING([--enable-gcov],
 817                               [Whether to enable coverage testing (requires gcc
 818 and gcov)])],
 819               [],
 820               [enable_gcov=no])
 821
 822 AS_IF([test "x$enable_gcov" = "xyes" && test "x$GCC" = "xyes"],
 823       [
 824         AS_IF([test "x$enable_conformance" = "xno"],
 825               [AC_MSG_WARN([Conformance test suite is disabled, the coverage report will be incomplete])],
 826               [AC_MSG_RESULT([yes])]
 827         )
 828
 829         GCOV_CFLAGS="-g -O0 -fprofile-arcs -ftest-coverage"
 830         GCOV_LDFLAGS="-lgcov"
 831       ],
 832       [AC_MSG_RESULT([no])]
 833 )
 834
 835 AM_CONDITIONAL([GCOV_ENABLED], [test "x$enable_gcov" = "xyes"])
 836 AC_SUBST([GCOV_CFLAGS])
 837 AC_SUBST([GCOV_LDFLAGS])
 838
 839 dnl === Enable strict compiler flags ==========================================
 840
 841 # use strict compiler flags only when building from git; the rules for
 842 # distcheck will take care of turning this on when making a release
 843 m4_define([maintainer_flags_default], [m4_if(m4_eval(clutter_micro_version % 2), [1], [yes], [no])])
 844 AC_ARG_ENABLE([maintainer-flags],
 845               [AS_HELP_STRING([--enable-maintainer-flags=@<:@no/yes/error@:>@],
 846                               [Use strict compiler flags @<:@default=]maintainer_flags_default[@:>@])],
 847               [],
 848               [enable_maintainer_flags=maintainer_flags_default])
 849
 850 MAINTAINER_COMPILER_FLAGS="-Wall -Wshadow -Wcast-align -Wuninitialized
 851                            -Wno-strict-aliasing -Wempty-body -Wformat
 852                            -Wformat-security -Winit-self
 853                            -Wdeclaration-after-statement -Wvla
 854                            -Wpointer-arith"
 855
 856 AS_CASE([$enable_maintainer_flags],
 857         [yes],
 858         [
 859           AS_COMPILER_FLAGS([MAINTAINER_CFLAGS], [$MAINTAINER_COMPILER_FLAGS])
 860         ],
 861
 862         [no],
 863         [
 864         ],
 865
 866         [error],
 867         [
 868           MAINTAINER_COMPILER_FLAGS="$MAINTAINER_COMPILER_FLAGS -Werror"
 869           AS_COMPILER_FLAGS([MAINTAINER_CFLAGS], [$MAINTAINER_COMPILER_FLAGS])
 870         ],
 871
 872         [*],
 873         [AC_MSG_ERROR([Invalid option for --enable-maintainer-flags])]
 874 )
 875
 876 # strip leading spaces
 877 MAINTAINER_CFLAGS=${MAINTAINER_CFLAGS#*  }
 878 AC_SUBST(MAINTAINER_CFLAGS)
 879
 880 dnl === Dependencies, compiler flags and linker libraries =====================
 881 # strip leading space
 882 BACKEND_PC_FILES=${BACKEND_PC_FILES#* }
 883
 884 CLUTTER_REQUIRES="$CLUTTER_BASE_PC_FILES $IMAGE_PC_FILES $BACKEND_PC_FILES"
 885 PKG_CHECK_MODULES(CLUTTER_DEPS, [$CLUTTER_REQUIRES])
 886 AC_SUBST(CLUTTER_REQUIRES)
 887
 888 CLUTTER_CFLAGS="$FLAVOUR_CFLAGS $CLUTTER_DEPS_CFLAGS $CLUTTER_PROFILE_CFLAGS $GLIB_CFLAGS"
 889 CLUTTER_LIBS="$FLAVOUR_LIBS $CLUTTER_DEPS_LIBS $CLUTTER_PROFILE_LDFLAGS $GLIB_LIBS"
 890 AC_SUBST(CLUTTER_CFLAGS)
 891 AC_SUBST(CLUTTER_LIBS)
 892
 893
 894 dnl === GObject-Introspection check ===========================================
 895
 896 GOBJECT_INTROSPECTION_CHECK([gi_req_version])
 897
 898 dnl === GTK Doc check =========================================================
 899
 900 GTK_DOC_CHECK([gtk_doc_req_version], [--flavour no-tmpl])
 901
 902 # we don't want to build the documentation from a Git clone unless we
 903 # explicitly tell configure to do so; this allows avoiding to recurse into
 904 # the documentation directory when building Clutter inside Poky for a
 905 # target device that doesn't have gtk-doc installed. for reference
 906 # see: http://bugzilla.openedhand.com/show_bug.cgi?id=1047
 907 #
 908 # we use autogen.sh as it exists only inside the Git clones, and it
 909 # is not packaged into tarballs.
 910 AM_CONDITIONAL([BUILD_GTK_DOC], [test "x$enable_gtk_doc" = "xyes" || test ! -f "autogen.sh"])
 911
 912 # prefixes for fixing gtk-doc references
 913 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
 914 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 915 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
 916 COGL_PREFIX="`$PKG_CONFIG --variable=prefix cogl-1.0`"
 917 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
 918 AC_SUBST(CAIRO_PREFIX)
 919 AC_SUBST(GLIB_PREFIX)
 920 AC_SUBST(PANGO_PREFIX)
 921 AC_SUBST(COGL_PREFIX)
 922 AC_SUBST(ATK_PREFIX)
 923
 924 dnl === Manual ================================================================
 925
 926 AC_ARG_ENABLE([docs],
 927               [AS_HELP_STRING([--enable-docs=@<:@no/yes@:>@],
 928                               [Build optional documentation; requires xsltproc and jw.])],
 929               [enable_docs=$enableval],
 930               [enable_docs=no])
 931
 932 enable_pdfs=no
 933 AS_IF([test "x$enable_docs" = "xyes"],
 934       [
 935         AC_PATH_PROG(JW, [jw], [no])
 936         AS_IF([test "x$JW" = "xno"],
 937               [
 938                 AC_MSG_WARN([jw not found; pdf generation has been disabled])
 939               ],
 940               [enable_pdfs=yes])
 941
 942         AC_PATH_PROG(XSLTPROC, [xsltproc], [no])
 943         AS_IF([test "x$XSLTPROC" = "xno"],
 944               [
 945                 AC_MSG_ERROR([xsltproc not found])
 946               ])
 947       ]
 948 )
 949
 950 AM_CONDITIONAL(ENABLE_DOCS, [test "x$enable_docs" = "xyes"])
 951 AM_CONDITIONAL(ENABLE_PDFS, [test "x$enable_pdfs" = "xyes"])
 952
 953 dnl === I18N ==================================================================
 954
 955 AM_GNU_GETTEXT_VERSION([0.17])
 956 AM_GNU_GETTEXT([external])
 957
 958 GETTEXT_PACKAGE="clutter-1.0"
 959 AC_SUBST(GETTEXT_PACKAGE)
 960 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],
 961                    ["$GETTEXT_PACKAGE"],
 962                    [The prefix for our gettext translation domains.])
 963 AS_ALL_LINGUAS
 964
 965 dnl ===========================================================================
 966
 967 AC_CONFIG_FILES([
 968         Makefile
 969
 970         README
 971
 972         build/Makefile
 973         build/autotools/Makefile
 974         build/mingw/Makefile
 975
 976         clutter/Makefile
 977         clutter/clutter-config.h
 978         clutter/clutter-version.h
 979         clutter/clutter-$CLUTTER_API_VERSION.pc:clutter/clutter.pc.in
 980
 981         clutter/cally/cally-$CLUTTER_API_VERSION.pc:clutter/cally/cally.pc.in
 982
 983         clutter/egl/clutter-cex100.h
 984
 985         tests/Makefile
 986         tests/accessibility/Makefile
 987         tests/conform/Makefile
 988         tests/conform/test-launcher.sh
 989         tests/data/Makefile
 990         tests/interactive/Makefile
 991         tests/interactive/wrapper.sh
 992         tests/micro-bench/Makefile
 993         tests/performance/Makefile
 994
 995         doc/Makefile
 996         doc/reference/Makefile
 997         doc/reference/clutter/Makefile
 998         doc/reference/clutter/clutter-docs.xml
 999         doc/reference/cally/Makefile
1000         doc/reference/cally/cally-docs.xml
1001         doc/common/Makefile
1002         doc/cookbook/Makefile
1003         doc/cookbook/clutter-cookbook.xml
1004         doc/cookbook/examples/Makefile
1005
1006         po/Makefile.in
1007 ])
1008
1009 AC_OUTPUT
1010
1011 dnl === Summary ===============================================================
1012
1013 echo ""
1014 echo "Clutter - $VERSION (${CLUTTER_RELEASE_STATUS})"
1015
1016 # Global flags
1017 echo ""
1018 echo " • Global:"
1019 echo "        Prefix: ${prefix}"
1020 echo "        Libdir: ${libdir}"
1021 echo "        Sysconfdir: ${sysconfdir}"
1022
1023 # Compiler/Debug related flags
1024 echo ""
1025 echo " • Compiler options:"
1026 echo "        Clutter debug level: ${enable_debug}"
1027 echo "        Compiler flags: ${CFLAGS} ${MAINTAINER_CFLAGS}"
1028 echo "        Profiling enabled: ${enable_profile}"
1029 echo "        Enable coverage tests: ${enable_gcov}"
1030 echo "        Enable deprecated symbols: ${enable_deprecated}"
1031
1032 # Documentation
1033 echo ""
1034 echo " • Documentation:"
1035 echo "        Build API Reference: ${enable_gtk_doc}"
1036 echo "        Build Additional Documentation: ${enable_docs} (Generate PDF: ${enable_pdfs})"
1037
1038 # Miscellaneous
1039 echo ""
1040 echo " • Extra:"
1041 echo "        Build introspection data: ${enable_introspection}"
1042 echo "        Build conformance test suite: ${enable_conformance}"
1043 echo "        Build X11-specific tests: ${x11_tests}"
1044
1045 # Clutter backend related flags
1046 echo ""
1047 echo " • Clutter Backends:"
1048
1049 if test "x$experimental_backend" = "xno"; then
1050 echo "        Windowing systems: ${CLUTTER_BACKENDS}"
1051 else
1052 echo "        Windowing systems: ${CLUTTER_BACKENDS} (WARNING: Experimental backends enabled)"
1053 fi
1054
1055 if test "x$SUPPORT_X11" = "x1"; then
1056 echo ""
1057 echo "        Enable XComposite: ${have_xcomposite}"
1058 echo "        Enable XInput: ${have_xinput}"
1059 echo "        Enable Xge: ${have_xge}"
1060 echo "        Enable XI2: ${have_xinput2}"
1061 echo "        Enable XKB: ${have_xkb}"
1062 fi
1063
1064 if test "x$SUPPORT_EGL" = "x1"; then
1065 echo ""
1066 echo "        Enable TSLib: ${have_tslib}"
1067 echo "        Enable evdev: ${have_evdev}"
1068 echo "        Enable GDL: ${have_gdl}"
1069 fi
1070
1071 echo ""
1072
1073 # General warning about experimental features
1074 if test "x$experimental_backend" = "xyes"; then
1075 echo ""
1076 echo "☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠"
1077 echo " *WARNING*"
1078 echo ""
1079 echo "  The stability of your build might be affected by one or more"
1080 echo "  experimental backends or experimental and unsupported features"
1081 echo "☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠"
1082 echo ""
1083 fi