configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [1])
   4 m4_define([v_min], [0])
   5 m4_define([v_mic], [999])
   6 m4_define([v_rev], m4_esyscmd([(svnversion "${SVN_REPO_PATH:-.}" | grep -v export || echo 0) | awk -F : '{printf("%s\n", $1);}' | tr -d ' :MSP\n']))
   7 m4_if(v_rev, [0], [m4_define([v_rev], m4_esyscmd([git log 2> /dev/null | (grep -m1 git-svn-id || echo 0) | sed -e 's/.*@\([0-9]*\).*/\1/' | tr -d '\n']))])
   8 ##--   When released, remove the dnl on the below line
   9 dnl m4_undefine([v_rev])
  10 ##--   When doing snapshots - change soname. remove dnl on below line
  11 dnl m4_define([relname], [ver-pre-svn-07])
  12 dnl m4_define([v_rel], [-release relname])
  13 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  14 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])], [m4_define([v_ver], [v_maj.v_min.v_mic])])
  15 m4_define([lt_cur], m4_eval(v_maj + v_min))
  16 m4_define([lt_rev], v_mic)
  17 m4_define([lt_age], v_min)
  18 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  19 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  20
  21 AC_INIT([ecore], [v_ver], [enlightenment-devel@lists.sourceforge.net])
  22 AC_PREREQ([2.52])
  23 AC_CONFIG_SRCDIR([configure.ac])
  24 AC_CONFIG_MACRO_DIR([m4])
  25
  26 AC_CONFIG_HEADERS([config.h])
  27 AH_TOP([
  28 #ifndef EFL_CONFIG_H__
  29 #define EFL_CONFIG_H__
  30 ])
  31 AH_BOTTOM([
  32 #endif /* EFL_CONFIG_H__ */
  33 ])
  34
  35 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 AC_GNU_SOURCE
  39
  40 AC_LIBTOOL_WIN32_DLL
  41 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  42 AC_PROG_LIBTOOL
  43
  44 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  45 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  46 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  47 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  48 AC_DEFINE_UNQUOTED(VERS_MAJ, [v_maj], [Major version])
  49 AC_DEFINE_UNQUOTED(VERS_MIN, [v_min], [Minor version])
  50 AC_DEFINE_UNQUOTED(VERS_MIC, [v_mic], [Micro version])
  51 AC_DEFINE_UNQUOTED(VERS_REV, [v_rev], [Revison])
  52 version_info="lt_cur:lt_rev:lt_age"
  53 release_info="v_rel"
  54 AC_SUBST(version_info)
  55 AC_SUBST(release_info)
  56 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  57 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  58 VMAJ=v_maj
  59 AC_SUBST(VMAJ)
  60
  61 m4_ifdef([AM_GNU_GETTEXT_VERSION], [
  62 AM_GNU_GETTEXT_VERSION([0.14])
  63 ])
  64
  65 m4_ifdef([AM_GNU_GETTEXT], [
  66 AM_GNU_GETTEXT([external])
  67 po_makefile_in=po/Makefile.in
  68 AM_CONDITIONAL([HAVE_PO], [true])
  69 ],[
  70 AM_CONDITIONAL([HAVE_PO], [false])
  71 ])
  72 AC_SUBST(LTLIBINTL)
  73
  74 with_max_log_level="<unset>"
  75 AC_ARG_WITH(internal-maximum-log-level,
  76    [AC_HELP_STRING([--with-internal-maximum-log-level=NUMBER],
  77                    [limit ecore internal log level to the given number, any call to EINA_LOG() with values greater than this will be compiled out, ignoring runtime settings, but saving function calls.])],
  78    [
  79     if test "x${withval}" != "xno"; then
  80        if echo "${withval}" | grep '^[[0-9]]\+$' >/dev/null 2>/dev/null; then
  81           AC_MSG_NOTICE([ignoring any EINA_LOG() with level greater than ${withval}])
  82           AC_DEFINE_UNQUOTED(EINA_LOG_LEVEL_MAXIMUM, ${withval}, [if set, logging is limited to this amount.])
  83           with_max_log_level="${withval}"
  84        else
  85           AC_MSG_ERROR([--with-internal-maximum-log-level takes a decimal number, got "${withval}" instead.])
  86        fi
  87     fi
  88     ], [:])
  89
  90
  91 ### Default options with respect to host
  92
  93 AC_CANONICAL_BUILD
  94 AC_CANONICAL_HOST
  95
  96 # dependencies and options
  97 want_curl="no"
  98 want_abstract_sockets="no"
  99 want_gnutls="no"
 100 want_openssl="no"
 101 want_cares="no"
 102 want_cipher="no"
 103 want_signature="no"
 104 want_poll="yes"
 105 want_inotify="no"
 106 want_notify_win32="no"
 107 want_tslib="no"
 108 want_glib="no"
 109
 110 # core modules
 111 want_ecore_con="yes"
 112 want_ecore_ipc="yes"
 113 want_ecore_file="yes"
 114 #want_ecore_config="no"
 115 want_ecore_imf="no"
 116 want_ecore_input="yes"
 117
 118 # graphic system modules
 119 want_evas_simple_x11="no"
 120 want_ecore_x_xcb="no"
 121 want_ecore_x="no"
 122 want_ecore_win32="no"
 123 want_ecore_cocoa="no"
 124 want_ecore_sdl="no"
 125 want_ecore_fb="no"
 126 want_ecore_directfb="no"
 127 want_ecore_wince="no"
 128
 129 # ecore_x options (both xlib and xcb)
 130 want_ecore_x_composite="yes"
 131 want_ecore_x_damage="yes"
 132 want_ecore_x_dpms="yes"
 133 want_ecore_x_randr="yes"
 134 want_ecore_x_render="yes"
 135 want_ecore_x_screensaver="yes"
 136 want_ecore_x_shape="yes"
 137 want_ecore_x_sync="yes"
 138 want_ecore_x_xfixes="yes"
 139 want_ecore_x_xinerama="yes"
 140 want_ecore_x_xprint="yes"
 141 want_ecore_x_xtest="yes"
 142 want_ecore_x_cursor="yes"
 143 want_ecore_x_input="yes"
 144 want_ecore_x_dri="yes"
 145
 146 # ecore_evas modules
 147 want_ecore_evas="yes"
 148 want_ecore_evas_software_buffer="yes"
 149 want_ecore_evas_software_x11="no"
 150 want_ecore_evas_opengl_x11="no"
 151 want_ecore_evas_software_16_x11="no"
 152 want_ecore_evas_software_8_x11="no"
 153 want_ecore_evas_software_xcb="no"
 154 want_ecore_evas_software_gdi="no"
 155 want_ecore_evas_software_ddraw="no"
 156 want_ecore_evas_direct3d="no"
 157 want_ecore_evas_opengl_glew="no"
 158 want_ecore_evas_software_16_ddraw="no"
 159 want_ecore_evas_software_sdl="no"
 160 want_ecore_evas_gl_sdl="no"
 161 want_ecore_evas_directfb="no"
 162 want_ecore_evas_fb="no"
 163 want_ecore_evas_software_16_wince="no"
 164
 165 # ecore_imf modules
 166 want_ecore_imf_xim="no"
 167
 168 case "$host_os" in
 169    mingw32ce* | cegcc*)
 170       want_ecore_con="no"
 171       want_ecore_ipc="no"
 172       want_ecore_wince="yes"
 173       want_ecore_evas_software_16_wince="yes"
 174       ;;
 175    mingw*)
 176       want_notify_win32="yes"
 177       want_curl="yes"
 178       want_glib="auto"
 179       want_ecore_imf="yes"
 180       want_ecore_win32="yes"
 181       want_ecore_evas_software_gdi="yes"
 182       want_ecore_evas_software_ddraw="yes"
 183       want_ecore_evas_direct3d="yes"
 184       want_ecore_evas_opengl_glew="yes"
 185       want_ecore_evas_software_16_ddraw="auto"
 186       want_ecore_evas_software_sdl="yes"
 187       want_ecore_evas_gl_sdl="yes"
 188       ;;
 189    darwin*)
 190       want_curl="yes"
 191       want_glib="auto"
 192       want_gnutls="auto"
 193       want_openssl="auto"
 194       want_ecore_imf="yes"
 195       want_ecore_cocoa="yes"
 196       want_ecore_evas_software_sdl="yes"
 197       want_ecore_evas_gl_sdl="yes"
 198       ;;
 199    *)
 200       want_curl="yes"
 201       want_glib="auto"
 202       want_abstract_sockets="yes"
 203       want_gnutls="auto"
 204       want_openssl="auto"
 205       want_cipher="yes"
 206       want_signature="yes"
 207       want_inotify="yes"
 208       want_tslib="yes"
 209       want_ecore_fb="yes"
 210       want_ecore_imf="yes"
 211       want_ecore_x="yes"
 212       want_ecore_evas_software_x11="yes"
 213       want_ecore_evas_opengl_x11="yes"
 214       want_ecore_evas_software_16_x11="yes"
 215       want_ecore_evas_software_8_x11="yes"
 216       want_ecore_evas_software_xcb="no"
 217       want_ecore_evas_software_sdl="yes"
 218       want_ecore_evas_gl_sdl="yes"
 219       want_ecore_evas_directfb="yes"
 220       want_ecore_evas_fb="yes"
 221       want_ecore_imf_xim="yes"
 222       ;;
 223 esac
 224
 225 requirements_ecore=""
 226 requirements_ecore_con=""
 227 #requirements_ecore_config=""
 228 requirements_ecore_directfb=""
 229 requirements_ecore_evas=""
 230 requirements_ecore_fb=""
 231 requirements_ecore_file=""
 232 requirements_ecore_imf=""
 233 requirements_ecore_imf_evas=""
 234 requirements_ecore_input=""
 235 requirements_ecore_input_evas=""
 236 requirements_ecore_ipc=""
 237 requirements_ecore_cocoa=""
 238 requirements_ecore_sdl=""
 239 requirements_ecore_x=""
 240 requirements_ecore_win32=""
 241 requirements_ecore_wince=""
 242 requirements_ecore_imf_xim=""
 243
 244 AC_CHECK_DECL([MAXHOSTNAMELEN],[FOUND_MAXHOSTNAMELEN=yes])
 245
 246 if test x$FOUND_MAXHOSTNAMELEN != xyes ; then
 247   AC_MSG_CHECKING([for header that defines MAXHOSTNAMELEN])
 248
 249   FOUND_MAXHOSTNAMELEN='not found'
 250
 251   AC_COMPILE_IFELSE(
 252         AC_LANG_PROGRAM([#include <sys/param.h>],
 253                 [int h = MAXHOSTNAMELEN;]),
 254         [FOUND_MAXHOSTNAMELEN='sys/param.h'
 255            AC_DEFINE(NEED_SYS_PARAM_H,1,
 256              [Define to 1 if you need <sys/param.h> to define MAXHOSTNAMELEN])])
 257
 258         AC_COMPILE_IFELSE(
 259             AC_LANG_PROGRAM([#include <netdb.h>],
 260                             [int h = MAXHOSTNAMELEN;]),
 261             [FOUND_MAXHOSTNAMELEN='netdb.h'
 262              AC_DEFINE(NEED_NETDB_H,1,
 263                [Define to 1 if you need <netdb.h> to define MAXHOSTNAMELEN])])
 264
 265   AC_MSG_RESULT([$FOUND_MAXHOSTNAMELEN])
 266 fi
 267
 268 ### Additional options to configure
 269
 270 want_glib_integration_always=no
 271 AC_ARG_ENABLE(glib-integration-always,
 272   AC_HELP_STRING([--enable-glib-integration-always], [enable glib integration when ecore_init() is called always]),
 273   [want_glib_integration_always=$enableval])
 274
 275 if test "x${want_glib_integration_always}" = "xyes" ; then
 276   AC_DEFINE([GLIB_INTEGRATION_ALWAYS], [1], [Always integrate glib if support compiled])
 277   want_glib=yes
 278 fi
 279
 280 want_g_main_loop=no
 281 AC_ARG_ENABLE(g-main-loop,
 282   AC_HELP_STRING([--enable-g-main-loop], [ecore_main_loop based on g_main_loop]),
 283   [want_g_main_loop=$enableval])
 284
 285 if test "x${want_g_main_loop}" = "xyes" ; then
 286   AC_DEFINE([USE_G_MAIN_LOOP], [1], [Use g_main_loop in ecore])
 287   want_glib=yes
 288 fi
 289
 290 if test "x${want_glib_integration_always}" = "xyes" -a "x${want_g_main_loop}" = "xyes"; then
 291   AC_MSG_ERROR([--enable-glib-integration-always and --enable-glib-main-loop are mutually exclusive])
 292 fi
 293
 294 # abstract sockets (ecore_con.c)
 295 AC_ARG_ENABLE([abstract-sockets],
 296    [AC_HELP_STRING([--disable-abstract-sockets], [disable abstract sockets.])],
 297    [
 298     if test "x${enableval}" = "xyes" ; then
 299        want_ecore_con_abstract_sockets="yes"
 300     else
 301        want_ecore_con_abstract_sockets="no"
 302     fi
 303    ],
 304    [want_ecore_con_abstract_sockets=${want_abstract_sockets}])
 305
 306 if test "x${want_ecore_con_abstract_sockets}" = "xyes" ; then
 307    AC_DEFINE([HAVE_ABSTRACT_SOCKETS], [1], [Have abstract sockets namespace])
 308 fi
 309
 310 # Simple X11 build/link
 311
 312 AC_ARG_ENABLE(simple-x11,
 313   AC_HELP_STRING([--enable-simple-x11], [enable simple x11 linking]),
 314   [want_evas_simple_x11=$enableval])
 315
 316 # XIM
 317 AC_ARG_ENABLE([xim],
 318    [AC_HELP_STRING([--disable-xim], [disable X Input Method.])],
 319    [
 320     if test "x${enableval}" = "xyes" ; then
 321        want_xim="yes"
 322     else
 323        want_xim="no"
 324     fi
 325    ],
 326    [want_xim="yes"])
 327
 328 if test "x${want_xim}" = "xyes" ; then
 329    AC_DEFINE([ENABLE_XIM], [1], [Enable X Input Method])
 330 fi
 331
 332 # Unit tests
 333
 334 EFL_CHECK_TESTS([enable_tests="yes"], [enable_tests="no"])
 335
 336 ### Checks for programs
 337
 338 m4_ifdef([AC_PROG_OBJC],
 339    [
 340     AC_PROG_OBJC
 341     _AM_DEPENDENCIES(OBJC)
 342    ],
 343    [
 344     AC_CHECK_TOOL([OBJC], [gcc])
 345     AC_SUBST([OBJC])
 346     AC_SUBST([OBJCFLAGS])
 347    ])
 348 m4_ifndef([am__fastdepOBJC], [
 349     AM_CONDITIONAL([am__fastdepOBJC], [false])
 350     AC_SUBST([cocoa_ldflags])
 351 ])
 352
 353 AC_PROG_CXX
 354 AC_PROG_CC
 355
 356 have_gnu_objc=${ac_cv_objc_compiler_gnu}
 357
 358 # doxygen program for documentation building
 359
 360 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 361
 362 m4_ifdef([v_mic],
 363    [
 364     EFL_COMPILER_FLAG([-Wall])
 365     EFL_COMPILER_FLAG([-W])
 366    ])
 367
 368 # The first call to PKG_CHECK_MODULES is done conditionally,
 369 # so we should include this here:
 370 PKG_PROG_PKG_CONFIG
 371
 372 # Check whether pkg-config supports Requires.private
 373 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
 374    pkgconfig_requires_private="Requires.private"
 375 else
 376    pkgconfig_requires_private="Requires"
 377 fi
 378 AC_SUBST(pkgconfig_requires_private)
 379
 380 ### Checks for some build time option
 381 have_backtrace="no"
 382 AC_CHECK_FUNCS([backtrace], [have_backtrace="yes"], [])
 383
 384 want_ecore_timer_dump="yes"
 385
 386 AC_ARG_ENABLE([ecore-timer-dump],
 387    [AC_HELP_STRING([--disable-ecore-timer-dump], [disable tracking of timer allocation. @<:@default=enable@:>@])],
 388    [want_ecore_timer_dump=$enableval], [])
 389
 390 if test "x$want_ecore_timer_dump" = "xyes" -a "x$have_backtrace" = "xyes"; then
 391    AC_DEFINE(WANT_ECORE_TIMER_DUMP, [1], [Want Ecore_Timer dump infrastructure])
 392 fi
 393
 394 ### Checks for libraries
 395
 396 # Evil library for compilation on Windows
 397
 398 case "$host_os" in
 399    mingw* | cegcc*)
 400       PKG_CHECK_MODULES([EVIL], [evil])
 401       AC_DEFINE(HAVE_EVIL, 1, [Set to 1 if Evil library is installed])
 402       requirements_ecore="evil ${requirements_ecore}"
 403       requirements_ecore_evas="evil ${requirements_ecore_evas}"
 404       requirements_ecore_file="evil ${requirements_ecore_file}"
 405       requirements_ecore_imf="evil ${requirements_ecore_imf}"
 406       requirements_ecore_imf_evas="evil ${requirements_ecore_imf_evas}"
 407       EFL_ECORE_BUILD="-DEFL_ECORE_BUILD"
 408       EFL_ECORE_CON_BUILD="-DEFL_ECORE_CON_BUILD"
 409       EFL_ECORE_EVAS_BUILD="-DEFL_ECORE_EVAS_BUILD"
 410       EFL_ECORE_FILE_BUILD="-DEFL_ECORE_FILE_BUILD"
 411       EFL_ECORE_IMF_BUILD="-DEFL_ECORE_IMF_BUILD"
 412       EFL_ECORE_IMF_EVAS_BUILD="-DEFL_ECORE_IMF_EVAS_BUILD"
 413       EFL_ECORE_INPUT_BUILD="-DEFL_ECORE_INPUT_BUILD"
 414       EFL_ECORE_INPUT_EVAS_BUILD="-DEFL_ECORE_INPUT_EVAS_BUILD"
 415       EFL_ECORE_IPC_BUILD="-DEFL_ECORE_IPC_BUILD"
 416       ;;
 417 esac
 418
 419 have_win32=""
 420 have_wince=""
 421 case "$host_os" in
 422    mingw32ce* | cegcc*)
 423       EFL_ECORE_WINCE_BUILD="-DEFL_ECORE_WINCE_BUILD"
 424       requirements_ecore_wince="evil ${requirements_ecore_wince}"
 425       have_wince="yes"
 426       ;;
 427    mingw*)
 428       EFL_ECORE_WIN32_BUILD="-DEFL_ECORE_WIN32_BUILD"
 429       EFL_ECORE_SDL_BUILD="-DEFL_ECORE_SDL_BUILD"
 430       requirements_ecore_win32="evil ${requirements_ecore_win32}"
 431       requirements_ecore_sdl="evil ${requirements_ecore_sdl}"
 432       have_win32="yes"
 433       ;;
 434 esac
 435
 436 AC_SUBST(EFL_ECORE_BUILD)
 437 AC_SUBST(EFL_ECORE_CON_BUILD)
 438 AC_SUBST(EFL_ECORE_EVAS_BUILD)
 439 AC_SUBST(EFL_ECORE_FILE_BUILD)
 440 AC_SUBST(EFL_ECORE_IMF_BUILD)
 441 AC_SUBST(EFL_ECORE_IMF_EVAS_BUILD)
 442 AC_SUBST(EFL_ECORE_INPUT_BUILD)
 443 AC_SUBST(EFL_ECORE_INPUT_EVAS_BUILD)
 444 AC_SUBST(EFL_ECORE_IPC_BUILD)
 445 AC_SUBST(EFL_ECORE_WINCE_BUILD)
 446 AC_SUBST(EFL_ECORE_WIN32_BUILD)
 447 AC_SUBST(EFL_ECORE_SDL_BUILD)
 448
 449 AM_CONDITIONAL(ECORE_HAVE_WINCE, test "x${have_wince}" = "xyes")
 450 AM_CONDITIONAL(ECORE_HAVE_WIN32, test "x${have_win32}" = "xyes")
 451
 452 WIN32_LIBS=""
 453 case "$host_os" in
 454    mingw32ce* | cegcc*)
 455       WIN32_LIBS="-lws2"
 456       dlopen_libs="-ldl"
 457       ;;
 458    mingw*)
 459       WIN32_LIBS="-lws2_32"
 460       dlopen_libs="-ldl"
 461       ;;
 462    *)
 463       AC_CHECK_LIB([c], [dlopen],
 464          [],
 465          [AC_CHECK_LIB([dl], [dlopen],
 466              [dlopen_libs=-ldl])
 467          ])
 468       AC_CHECK_LIB([c], [clock_gettime],
 469          [AC_DEFINE(HAVE_CLOCK_GETTIME, [1], [Have clock_gettime()])],
 470          [AC_CHECK_LIB([rt], [clock_gettime],
 471              [
 472               rt_libs=-lrt
 473               AC_DEFINE(HAVE_CLOCK_GETTIME, [1], [Have clock_gettime()])
 474              ])
 475          ])
 476       ;;
 477 esac
 478 AC_SUBST(WIN32_LIBS)
 479 AC_SUBST(dlopen_libs)
 480 AC_SUBST(rt_libs)
 481
 482 # Eina library
 483
 484 PKG_CHECK_MODULES(EINA, [eina >= 1.0.0])
 485 #FIXME check all the requirements when the eina move will be finished
 486 requirements_ecore="eina >= 1.0.0 ${requirements_ecore}"
 487 requirements_ecore_con="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_con}"
 488 #requirements_ecore_config="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_config}"
 489 requirements_ecore_directfb="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_directfb}"
 490 requirements_ecore_evas="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_evas}"
 491 requirements_ecore_fb="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_fb}"
 492 requirements_ecore_file="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_file}"
 493 requirements_ecore_imf="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_imf}"
 494 requirements_ecore_imf_evas="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_imf_evas}"
 495 requirements_ecore_input="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_input}"
 496 requirements_ecore_input_evas="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_input_evas}"
 497 requirements_ecore_ipc="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_ipc}"
 498 requirements_ecore_cocoa="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_cocoa}"
 499 requirements_ecore_sdl="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_sdl}"
 500 requirements_ecore_win32="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_win32}"
 501 requirements_ecore_wince="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_wince}"
 502 requirements_ecore_x="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_x}"
 503
 504
 505 # glib support (main loop integration)
 506 AC_ARG_ENABLE([glib],
 507    [AC_HELP_STRING([--disable-glib], [disable glib support. @<:@default=detect@:>@])],
 508    [want_glib=$enableval], [])
 509
 510 if test "x$want_glib" != "xno"; then
 511    PKG_CHECK_MODULES([GLIB], [glib-2.0], [have_glib="yes"], [have_glib="no"])
 512 else
 513    have_glib="no"
 514 fi
 515 if test "x$want_glib" = "xyes" -a "x$have_glib" = "xno"; then
 516    AC_MSG_ERROR([GLib support requested, but no GLib found by pkg-config.])
 517 elif test "x$have_glib" = "xyes"; then
 518    AC_DEFINE(HAVE_GLIB, [1], [Have GLib])
 519    requirements_ecore="glib-2.0 ${requirements_ecore}"
 520 fi
 521
 522
 523 # SDL library (ecore_sdl)
 524
 525 have_sdl="no"
 526 SDL_CONFIG="sdl-config"
 527 AC_ARG_WITH([sdl-config],
 528    [AC_HELP_STRING([--with-sdl-config=PATH], [use sdl-config specified])],
 529    [
 530     SDL_CONFIG=$withval
 531     AC_MSG_NOTICE([using ${SDL_CONFIG} for sdl-config])
 532    ])
 533
 534 AC_PATH_PROG([SDL_CONFIG], ["sdl-config"], [""], [$PATH])
 535
 536 if test -n "$SDL_CONFIG" ; then
 537    SDL_CFLAGS=`$SDL_CONFIG --cflags`
 538    SDL_LIBS=`$SDL_CONFIG --libs`
 539    AC_SUBST(SDL_CFLAGS)
 540    AC_SUBST(SDL_LIBS)
 541    have_sdl="yes"
 542 else
 543    PKG_CHECK_MODULES([SDL], [sdl >= 1.2.0], [have_sdl="yes"], [have_sdl="no"])
 544 fi
 545
 546 if test "x${have_sdl}" = "xyes" ; then
 547    PKG_CHECK_EXISTS([sdl >= 1.3.0],
 548       [AC_DEFINE(BUILD_ECORE_EVAS_SDL_130, 1, [Support for SVN SDL])])
 549 fi
 550
 551
 552 # DirectFB library (ecore_directfb)
 553
 554 PKG_CHECK_MODULES([DIRECTFB],
 555    [directfb >= 0.9.16],
 556    [have_directfb="yes"],
 557    [have_directfb="no"])
 558
 559
 560 # Eet library (ecore_config)
 561
 562 #PKG_CHECK_MODULES([EET],
 563 #   [eet >= 1.4.0],
 564 #   [have_eet="yes"],
 565 #   [have_eet="no"])
 566
 567
 568 # Xlib and XCB (ecore_x)
 569
 570 have_x="no"
 571 have_ecore_x="no"
 572 have_ecore_x_xlib="no"
 573 have_ecore_x_xcb="no"
 574
 575 x_dir="";
 576 x_includes="";
 577 x_cflags="";
 578 x_libs="";
 579
 580 ecore_x_libs_private=""
 581
 582 AC_ARG_ENABLE(ecore-x-composite,
 583    [AC_HELP_STRING([--disable-ecore-x-composite],
 584        [disable the ecore_x support for Xcomposite extension.
 585         @<:@default=detect@:>@])],
 586    [want_ecore_x_composite=$enableval])
 587
 588 AC_ARG_ENABLE(ecore-x-damage,
 589    [AC_HELP_STRING([--disable-ecore-x-damage],
 590        [disable the ecore_x support for Xdamage extension.
 591         @<:@default=detect@:>@])],
 592    [want_ecore_x_damage=$enableval])
 593
 594 AC_ARG_ENABLE(ecore-x-dpms,
 595    [AC_HELP_STRING([--disable-ecore-x-dpms],
 596        [disable the ecore_x support for Xdpms extension.
 597         @<:@default=detect@:>@])],
 598    [want_ecore_x_dpms=$enableval])
 599
 600 AC_ARG_ENABLE(ecore-x-randr,
 601    [AC_HELP_STRING([--disable-ecore-x-randr],
 602        [disable the ecore_x support for Xrandr extension.
 603         @<:@default=detect@:>@])],
 604    [want_ecore_x_randr=$enableval])
 605
 606 AC_ARG_ENABLE(ecore-x-render,
 607    [AC_HELP_STRING([--disable-ecore-x-render],
 608        [disable the ecore_x support for Xrender extension.
 609         @<:@default=detect@:>@])],
 610    [want_ecore_x_render=$enableval])
 611
 612 AC_ARG_ENABLE(ecore-x-screensaver,
 613    [AC_HELP_STRING([--disable-ecore-x-screensaver],
 614        [disable the ecore_x support for Xscreensaver extension.
 615         @<:@default=detect@:>@])],
 616    [want_ecore_x_screensaver=$enableval])
 617
 618 AC_ARG_ENABLE(ecore-x-shape,
 619    [AC_HELP_STRING([--disable-ecore-x-shape],
 620        [disable the ecore_x support for Xshape extension.
 621         @<:@default=detect@:>@])],
 622    [want_ecore_x_shape=$enableval])
 623
 624 AC_ARG_ENABLE(ecore-x-sync,
 625    [AC_HELP_STRING([--disable-ecore-x-sync],
 626        [disable the ecore_x support for Xsync extension.
 627         @<:@default=detect@:>@])],
 628    [want_ecore_x_sync=$enableval])
 629
 630 AC_ARG_ENABLE(ecore-x-xfixes,
 631    [AC_HELP_STRING([--disable-ecore-x-xfixes],
 632        [disable the ecore_x support for Xfixes extension.
 633         @<:@default=detect@:>@])],
 634    [want_ecore_x_xfixes=$enableval])
 635
 636 AC_ARG_ENABLE(ecore-x-xinerama,
 637    [AC_HELP_STRING([--disable-ecore-x-xinerama],
 638        [disable the ecore_x support for Xinerama extension.
 639         @<:@default=detect@:>@])],
 640    [want_ecore_x_xinerama=$enableval])
 641
 642 AC_ARG_ENABLE(ecore-x-xprint,
 643    [AC_HELP_STRING([--disable-ecore-x-xprint],
 644        [disable the ecore_x support for Xprint extension.
 645         @<:@default=detect@:>@])],
 646    [want_ecore_x_xprint=$enableval])
 647
 648 AC_ARG_ENABLE(ecore-x-xtest,
 649    [AC_HELP_STRING([--disable-ecore-x-xtest],
 650        [disable the ecore_x support for Xtest extension.
 651         @<:@default=detect@:>@])],
 652    [want_ecore_x_xtest=$enableval])
 653
 654 AC_ARG_ENABLE(ecore-x-cursor,
 655    [AC_HELP_STRING([--disable-ecore-x-cursor],
 656        [disable the ecore_x support for Xcursor extension.
 657         @<:@default=detect@:>@])],
 658    [want_ecore_x_cursor=$enableval])
 659
 660 AC_ARG_ENABLE(ecore-x-input,
 661    [AC_HELP_STRING([--disable-ecore-x-input],
 662        [disable the ecore_x support for Xinput/Xinput2 extension.
 663         @<:@default=detect@:>@])],
 664    [want_ecore_x_input=$enableval])
 665
 666 AC_ARG_ENABLE(ecore-x-dri,
 667    [AC_HELP_STRING([--disable-ecore-x-dri],
 668        [disable the ecore_x support for DRI extension.
 669         @<:@default=detect@:>@])],
 670    [want_ecore_x_dri=$enableval])
 671
 672 AC_ARG_ENABLE(ecore-x-xcb,
 673    [AC_HELP_STRING([--enable-ecore-x-xcb],
 674        [enable the ecore_x module with XCB backend. @<:@default=disabled@:>@])],
 675    [want_ecore_x_xcb=$enableval])
 676
 677 AC_MSG_CHECKING(whether ecore_x with XCB backend is to be built)
 678 AC_MSG_RESULT($want_ecore_x_xcb)
 679
 680 if test "x$want_ecore_x_xcb" = "xyes" ; then
 681
 682   AC_MSG_CHECKING([keysym definitions])
 683   KEYSYMDEFDIR=`$PKG_CONFIG --variable=includedir xproto`/X11
 684   FILES="keysymdef.h XF86keysym.h Sunkeysym.h DECkeysym.h HPkeysym.h"
 685   for i in $FILES; do
 686       if test -f "$KEYSYMDEFDIR/$i"; then
 687         KEYSYMDEFS="$KEYSYMDEFS $KEYSYMDEFDIR/$i"
 688       elif test "x$i" = "xkeysymdef.h"; then
 689         AC_MSG_ERROR([Cannot find keysymdef.h])
 690       fi
 691   done
 692   AC_MSG_RESULT([$KEYSYMDEFS])
 693   AC_SUBST(KEYSYMDEFS)
 694
 695   have_iconv="no"
 696   AC_ARG_WITH([iconv-link],
 697     AC_HELP_STRING([--with-iconv-link=ICONV_LINK], [explicitly specify an iconv link option]),
 698       [
 699         LIBS="$withval $LIBS"
 700         have_iconv="yes"
 701       ])
 702
 703   AC_MSG_CHECKING(for explicit iconv link options)
 704   if test "x${iconv_libs}" = "x" ; then
 705     AC_MSG_RESULT([no explicit iconv link option])
 706   else
 707     AC_MSG_RESULT([$iconv_libs])
 708   fi
 709
 710   if test "x${have_iconv}" = "xno" ; then
 711     AC_CHECK_HEADERS([iconv.h], [have_iconv="yes"])
 712
 713     if test "x${have_iconv}" = "xyes" ; then
 714       AC_MSG_CHECKING([whether iconv() is in libc])
 715
 716       AC_LINK_IFELSE(
 717         [AC_LANG_PROGRAM(
 718         [[
 719           #include <stdlib.h>
 720           #include <iconv.h>
 721         ]],
 722         [[
 723           iconv_t ic;
 724           size_t count = iconv(ic, NULL, NULL, NULL, NULL);
 725         ]])],
 726         [have_iconv="yes"],
 727         [have_iconv="no"])
 728
 729       AC_MSG_RESULT([${have_iconv}])
 730     fi
 731
 732     if test "x${have_iconv}" = "xno" ; then
 733       AC_MSG_CHECKING([whether iconv() is in libiconv.a])
 734
 735       LIBS_save="${LIBS}"
 736       LIBS="-liconv $LIBS"
 737       AC_LINK_IFELSE(
 738       [AC_LANG_PROGRAM(
 739         [[
 740           #include <stdlib.h>
 741           #include <iconv.h>
 742         ]],
 743         [[
 744           iconv_t ic;
 745           size_t count;
 746           count = iconv(ic, NULL, NULL, NULL, NULL);
 747         ]])],
 748         [have_iconv="yes"],
 749         [
 750           have_iconv="no"
 751           LIBS=${LIBS_save}
 752         ])
 753
 754       AC_MSG_RESULT([${have_iconv}])
 755     fi
 756
 757     if test "x${have_iconv}" = "xno" ; then
 758       AC_MSG_CHECKING([whether iconv() is in libiconv_plug.a])
 759
 760       LIBS_save="${LIBS}"
 761       LIBS="-liconv_plug $LIBS"
 762       AC_LINK_IFELSE(
 763       [AC_LANG_PROGRAM(
 764       [[
 765         #include <stdlib.h>
 766         #include <iconv.h>
 767       ]],
 768       [[
 769         iconv_t ic;
 770         size_t count = iconv(ic, NULL, NULL, NULL, NULL);
 771       ]])],
 772       [have_iconv="yes"],
 773       [
 774         have_iconv="no"
 775         LIBS=${LIBS_save}
 776       ])
 777
 778       AC_MSG_RESULT([${have_iconv}])
 779     fi
 780
 781     if test "x${have_iconv}" = "xyes" ; then
 782       AC_DEFINE([HAVE_ICONV], [1], [Set to 1 if iconv library is installed])
 783     fi
 784   fi
 785
 786 ## x11-xcb
 787   PKG_CHECK_MODULES(XCB, x11-xcb xcb xcb-shm xcb-icccm xcb-image xcb-keysyms,
 788     [ have_ecore_x_xcb="yes"
 789       requirements_ecore_x="x11-xcb xcb xcb-shm xcb-icccm xcb-image xcb-keysyms ${requirements_ecore_x}" ],
 790     [ have_ecore_x_xcb="no" ])
 791
 792   if test "x$have_ecore_x_xcb" = "xyes" ; then
 793
 794    PKG_CHECK_MODULES([PIXMAN],
 795       [pixman-1],
 796       [
 797        have_pixman="yes"
 798        AC_DEFINE(HAVE_PIXMAN, 1, [have pixman for rendering])
 799        requirements_ecore_x="pixman-1 ${requirements_ecore_x}"
 800       ],
 801       [
 802        if test "x${want_pixman}" = "xyes" -a "x${use_strict}" = "xyes" ; then
 803           AC_MSG_ERROR([Pixman not found (strict dependencies checking)])
 804        fi
 805       ])
 806
 807     if test "x$want_ecore_x_composite" != "xno"; then
 808       PKG_CHECK_MODULES(XCB_COMPOSITE, xcb-composite,
 809         [ have_ecore_x_xcb_composite="yes"
 810           requirements_ecore_x="xcb-composite ${requirements_ecore_x}"
 811           AC_DEFINE(ECORE_XCB_COMPOSITE, 1, [Build support for XCB composite]) ],
 812         [ have_ecore_x_xcb_composite="no" ])
 813     else
 814       have_ecore_x_xcb_composite="no"
 815       AC_MSG_NOTICE("composite extension explicitly disabled")
 816     fi
 817
 818     if test "x$want_ecore_x_damage" != "xno"; then
 819       PKG_CHECK_MODULES(XCB_DAMAGE, xcb-damage,
 820         [ have_ecore_x_xcb_damage="yes"
 821           requirements_ecore_x="xcb-damage ${requirements_ecore_x}"
 822           AC_DEFINE(ECORE_XCB_DAMAGE, 1, [Build support for XCB damage]) ],
 823         [ have_ecore_x_xcb_damage="no" ])
 824     else
 825       have_ecore_x_xcb_damage="no"
 826       AC_MSG_NOTICE("damage extension explicitly disabled")
 827     fi
 828
 829     if test "x$want_ecore_x_dpms" != "xno"; then
 830       PKG_CHECK_MODULES(XCB_DPMS, xcb-dpms,
 831         [ have_ecore_x_xcb_dpms="yes"
 832           requirements_ecore_x="xcb-dpms ${requirements_ecore_x}"
 833           AC_DEFINE(ECORE_XCB_DPMS, 1, [Build support for XCB dpms]) ],
 834         [ have_ecore_x_xcb_dpms="no" ])
 835     else
 836       have_ecore_x_xcb_dpms="no"
 837       AC_MSG_NOTICE("dpms extension explicitly disabled")
 838     fi
 839
 840     if test "x$want_ecore_x_randr" != "xno"; then
 841       PKG_CHECK_MODULES(XCB_RANDR, xcb-randr,
 842         [ have_ecore_x_xcb_randr="yes"
 843           requirements_ecore_x="xcb-randr ${requirements_ecore_x}"
 844           AC_DEFINE(ECORE_XCB_RANDR, 1, [Build support for XCB randr]) ],
 845         [ have_ecore_x_xcb_randr="no" ])
 846     else
 847       have_ecore_x_xcb_randr="no"
 848       AC_MSG_NOTICE("randr extension explicitly disabled")
 849     fi
 850
 851     if test "x$want_ecore_x_render" != "xno"; then
 852       PKG_CHECK_MODULES(XCB_RENDER, xcb-render xcb-renderutil,
 853         [ have_ecore_x_xcb_render="yes"
 854           requirements_ecore_x="xcb-render xcb-renderutil ${requirements_ecore_x}"
 855           AC_DEFINE(ECORE_XCB_RENDER, 1, [Build support for XCB render]) ],
 856         [ have_ecore_x_xcb_render="no" ])
 857     else
 858       have_ecore_x_xcb_render="no"
 859       AC_MSG_NOTICE("render extension explicitly disabled")
 860     fi
 861
 862     if test "x$want_ecore_x_screensaver" != "xno"; then
 863       PKG_CHECK_MODULES(XCB_SCREENSAVER, xcb-screensaver,
 864         [ have_ecore_x_xcb_screensaver="yes"
 865           requirements_ecore_x="xcb-screensaver ${requirements_ecore_x}"
 866           AC_DEFINE(ECORE_XCB_SCREENSAVER, 1, [Build support for XCB screensaver]) ],
 867         [ have_ecore_x_xcb_screensaver="no" ])
 868     else
 869       have_ecore_x_xcb_screensaver="no"
 870       AC_MSG_NOTICE("screensaver extension explicitly disabled")
 871     fi
 872
 873     if test "x$want_ecore_x_shape" != "xno"; then
 874       PKG_CHECK_MODULES(XCB_SHAPE, xcb-shape,
 875         [ have_ecore_x_xcb_shape="yes"
 876           requirements_ecore_x="xcb-shape ${requirements_ecore_x}"
 877           AC_DEFINE(ECORE_XCB_SHAPE, 1, [Build support for XCB shape]) ],
 878         [ have_ecore_x_xcb_shape="no" ])
 879     else
 880       have_ecore_x_xcb_shape="no"
 881       AC_MSG_NOTICE("shape extension explicitly disabled")
 882     fi
 883
 884     if test "x$want_ecore_x_sync" != "xno"; then
 885       PKG_CHECK_MODULES(XCB_SYNC, xcb-sync,
 886         [ have_ecore_x_xcb_sync="yes"
 887           requirements_ecore_x="xcb-sync ${requirements_ecore_x}"
 888           AC_DEFINE(ECORE_XCB_SYNC, 1, [Build support for XCB sync]) ],
 889         [ have_ecore_x_xcb_sync="no" ])
 890     else
 891       have_ecore_x_xcb_sync="no"
 892       AC_MSG_NOTICE("sync extension explicitly disabled")
 893     fi
 894
 895     if test "x$want_ecore_x_xfixes" != "xno"; then
 896       PKG_CHECK_MODULES(XCB_XFIXES, xcb-xfixes,
 897         [ have_ecore_x_xcb_xfixes="yes"
 898           requirements_ecore_x="xcb-xfixes ${requirements_ecore_x}"
 899           AC_DEFINE(ECORE_XCB_XFIXES, 1, [Build support for XCB xfixes]) ],
 900         [ have_ecore_x_xcb_xfixes="no" ])
 901     else
 902       have_ecore_x_xcb_xfixes="no"
 903       AC_MSG_NOTICE("xfixes extension explicitly disabled")
 904     fi
 905
 906     if test "x$want_ecore_x_xinerama" != "xno"; then
 907       PKG_CHECK_MODULES(XCB_XINERAMA, xcb-xinerama,
 908         [ have_ecore_x_xcb_xinerama="yes"
 909           requirements_ecore_x="xcb-xinerama ${requirements_ecore_x}"
 910           AC_DEFINE(ECORE_XCB_XINERAMA, 1, [Build support for XCB xinerama]) ],
 911         [ have_ecore_x_xcb_xinerama="no" ])
 912     else
 913       have_ecore_x_xcb_xinerama="no"
 914       AC_MSG_NOTICE("xinerama extension explicitly disabled")
 915     fi
 916
 917     if test "x$want_ecore_x_xprint" != "xno"; then
 918       PKG_CHECK_MODULES(XCB_XPRINT, xcb-xprint,
 919         [ have_ecore_x_xcb_xprint="yes"
 920           requirements_ecore_x="xcb-xprint ${requirements_ecore_x}"
 921           AC_DEFINE(ECORE_XCB_XPRINT, 1, [Build support for XCB xprint]) ],
 922         [ have_ecore_x_xcb_xprint="no" ])
 923     else
 924       have_ecore_x_xcb_xprint="no"
 925       AC_MSG_NOTICE("xprint extension explicitly disabled")
 926     fi
 927
 928     if test "x$want_ecore_x_xtest" != "xno"; then
 929       PKG_CHECK_MODULES(XCB_XTEST, xcb-xtest,
 930         [ have_ecore_x_xcb_xtest="yes"
 931           requirements_ecore_x="xcb-xtest ${requirements_ecore_x}"
 932           AC_DEFINE(ECORE_XCB_XTEST, 1, [Build support for XCB xtest]) ],
 933         [ have_ecore_x_xcb_xtest="no" ])
 934     else
 935       have_ecore_x_xcb_xtest="no"
 936       AC_MSG_NOTICE("xtest extension explicitly disabled")
 937     fi
 938
 939 # input extension disabled currently in xcb as xcb-input has some issues
 940     want_ecore_x_input="no"
 941     if test "x$want_ecore_x_input" != "xno"; then
 942       PKG_CHECK_MODULES(XCB_XINPUT, xcb-xinput,
 943         [ have_ecore_x_xcb_xinput="yes"
 944           requirements_ecore_x="xcb-xinput ${requirements_ecore_x}"
 945           AC_DEFINE(ECORE_XCB_XINPUT, 1, [Build support for XCB xinput]) ],
 946         [ have_ecore_x_xcb_xinput="no" ])
 947     else
 948       have_ecore_x_xcb_xinput="no"
 949       AC_MSG_NOTICE("xinput extension explicitly disabled")
 950     fi
 951
 952     if test "x$want_ecore_x_cursor" != "xno"; then
 953       PKG_CHECK_MODULES(XCB_CURSOR, xcb-render xcb-renderutil,
 954         [ have_ecore_x_xcb_cursor="yes"
 955           requirements_ecore_x="xcb-render xcb-renderutil ${requirements_ecore_x}"
 956           AC_DEFINE(ECORE_XCB_CURSOR, 1, [Build support for XCB cursor]) ],
 957         [ have_ecore_x_xcb_cursor="no" ])
 958     else
 959       have_ecore_x_xcb_cursor="no"
 960       AC_MSG_NOTICE("cursor extension explicitly disabled")
 961     fi
 962
 963     if test "x$want_ecore_x_dri" != "xno"; then
 964       PKG_CHECK_MODULES(XCB_DRI, xcb-dri2,
 965         [ have_ecore_x_xcb_dri="yes"
 966           requirements_ecore_x="xcb-dri2 ${requirements_ecore_x}"
 967           AC_DEFINE(ECORE_XCB_DRI, 1, [Build support for XCB dri/dri2]) ],
 968         [ have_ecore_x_xcb_dri="no" ])
 969     else
 970       have_ecore_x_xcb_dri="no"
 971       AC_MSG_NOTICE("dri extension explicitly disabled")
 972     fi
 973
 974     AC_DEFINE(HAVE_ECORE_X_XCB, 1, [Defined to 1 if XCB is enabled.])
 975
 976     x_cflags=$XCB_CFLAGS
 977     x_libs=$XCB_LIBS
 978     have_x="yes"
 979
 980     have_ecore_x_xcb_define="-DHAVE_ECORE_X_XCB"
 981     AC_SUBST(have_ecore_x_xcb_define)
 982   fi
 983 fi
 984
 985 if ! test "x$have_ecore_x_xcb" = "xyes" ; then
 986   AC_PATH_XTRA
 987   AC_CHECK_HEADER(X11/X.h,
 988     [
 989      if test "x$want_evas_simple_x11" = "xyes"; then
 990        x_libs="${x_libs} -lX11 -lXext"
 991      else
 992        x_dir=${x_dir:-/usr/X11R6}
 993        x_cflags=${x_cflags:--I${x_includes:-$x_dir/include}}
 994        x_libs="${x_libs:--L${x_libraries:-$x_dir/lib}} -lX11 -lXext"
 995      fi
 996      have_ecore_x_xlib="yes"
 997     ]
 998   )
 999
1000   if test "x$have_ecore_x_xlib" = "xyes"; then
1001     Xcursor_libs=""
1002     Xcursor_cflags=""
1003     use_Xcursor="no"
1004     PCFLAGS=$CFLAGS
1005     CFLAGS="$x_cflags $x_includes"
1006
1007     if test "x$want_ecore_x_cursor" = "xyes"; then
1008       AC_CHECK_HEADER(X11/Xcursor/Xcursor.h,
1009         [
1010           AC_CHECK_LIB(Xcursor, XcursorImageLoadCursor,
1011             [
1012               AC_DEFINE(ECORE_XCURSOR, 1, [Build support for Xcursor])
1013               Xcursor_cflags=""
1014               Xcursor_libs="-lXcursor"
1015               use_Xcursor="yes"
1016             ], [
1017               Xcursor_cflags=""
1018               Xcursor_libs=""
1019               use_Xcursor="no"
1020             ], [
1021               $x_libs -lXrender
1022             ]
1023           )
1024         ], [
1025           Xcursor_cflags=""
1026           Xcursor_libs=""
1027           use_Xcursor="no"
1028         ], [
1029           #include <X11/Xlib.h>
1030         ]
1031       )
1032       CFLAGS=$PCFLAGS
1033     else
1034       Xcursor_cflags=""
1035       Xcursor_libs=""
1036       use_Xcursor="no"
1037       AC_MSG_NOTICE("Xcursor explicitly disabled")
1038     fi
1039
1040     AC_SUBST(Xcursor_cflags)
1041     AC_SUBST(Xcursor_libs)
1042
1043     ECORE_CHECK_X_EXTENSION([Xkb], [XKB.h], [X11], [XkbSetDetectableAutoRepeat], [$want_ecore_x_xkb])
1044     ECORE_CHECK_X_EXTENSION([Xcomposite], [Xcomposite.h], [Xcomposite], [XCompositeQueryExtension], [$want_ecore_x_composite])
1045     ECORE_CHECK_X_EXTENSION([Xdamage], [Xdamage.h], [Xdamage], [XDamageSubtract], [$want_ecore_x_damage])
1046     ECORE_CHECK_X_EXTENSION([Xdpms], [dpms.h], [Xdpms], [DPMSQueryExtension], [$want_ecore_x_dpms])
1047     if test "x$use_xdpms" = "xno" ; then
1048       ECORE_CHECK_X_EXTENSION([Xdpms], [dpms.h], [Xext], [DPMSQueryExtension], [$want_ecore_x_dpms])
1049     fi
1050     ECORE_CHECK_X_EXTENSION([Xfixes], [Xfixes.h], [Xfixes], [XFixesExpandRegion], [$want_ecore_x_xfixes])
1051     ECORE_CHECK_X_EXTENSION([Xinerama], [Xinerama.h], [Xinerama], [XineramaQueryScreens], [$want_ecore_x_xinerama])
1052     ECORE_CHECK_X_EXTENSION([Xprint], [Print.h], [Xp], [XpQueryScreens], [$want_ecore_x_xprint])
1053     ECORE_CHECK_X_EXTENSION([Xrandr], [Xrandr.h], [Xrandr], [XRRGetScreenResourcesCurrent], [$want_ecore_x_randr])
1054     ECORE_CHECK_X_EXTENSION([Xrender], [Xrender.h], [Xrender], [XRenderFindVisualFormat], [$want_ecore_x_render])
1055     ECORE_CHECK_X_EXTENSION([Xtest], [XTest.h], [Xtst], [XTestFakeKeyEvent], [$want_ecore_x_xtest])
1056     ECORE_CHECK_X_EXTENSION([Xss], [scrnsaver.h], [Xss], [XScreenSaverSelectInput], [$want_ecore_x_screensaver])
1057     ECORE_CHECK_X_EXTENSION([Xi2], [XInput2.h], [Xi], [XIQueryDevice], [$want_ecore_x_input])
1058
1059     ecore_x_libs_private="${Xcursor_libs} ${XKB_LIBS} ${XCOMPOSITE_LIBS} ${XDAMAGE_LIBS} ${XDPMS_LIBS} ${XFIXES_LIBS} ${XINERAMA_LIBS} ${XPRINT_LIBS} ${XRANDR_LIBS} ${XRENDER_LIBS} ${XTEST_LIBS} ${XSS_LIBS} ${XI2_LIBS}"
1060
1061     AC_DEFINE(HAVE_ECORE_X_XLIB, 1, [Defined to 1 if Xlib is enabled.])
1062     have_x="yes"
1063
1064     have_ecore_x_xlib="yes"
1065   fi
1066 fi
1067
1068 AC_SUBST(x_cflags)
1069 AC_SUBST(x_includes)
1070 AC_SUBST(x_libs)
1071 AC_SUBST(ecore_x_libs_private)
1072
1073 AM_CONDITIONAL(BUILD_ECORE_X_XLIB, test $have_ecore_x_xlib = yes)
1074 AM_CONDITIONAL(BUILD_ECORE_X_XCB, test $have_ecore_x_xcb = yes)
1075
1076
1077 # Evas library (ecore_config, ecore_input_evas, ecore_imf_evas and ecore_evas)
1078
1079 PKG_CHECK_MODULES([EVAS], [evas >= 1.0.0],
1080    [have_evas="yes"],
1081    [have_evas="no"])
1082
1083
1084 ### Checks for header files
1085
1086 EFL_CHECK_PATH_MAX
1087
1088 AC_HEADER_SYS_WAIT
1089 AC_SYS_LARGEFILE
1090
1091 have_addrinfo="no"
1092 case "$host_os" in
1093    mingw* | cegcc*)
1094       AC_DEFINE(HAVE_DLFCN_H, 1, [Define to 1 if you have the <dlfcn.h> header file.])
1095       AC_DEFINE(HAVE_SYS_MMAN_H, 1, [Define to 1 if you have the <sys/mman.h> header file.])
1096       AC_DEFINE(HAVE_SYS_TIME_H, 1, [Define to 1 if you have the <sys/time.h> header file.])
1097       have_addrinfo="yes"
1098       ;;
1099    *)
1100       AC_CHECK_HEADERS([dlfcn.h features.h langinfo.h locale.h sys/time.h sys/mman.h signal.h sys/resource.h])
1101       ;;
1102 esac
1103
1104 # ecore_con
1105
1106 AC_CHECK_HEADERS([arpa/inet.h arpa/nameser.h netinet/tcp.h netinet/in.h sys/socket.h sys/un.h ws2tcpip.h netdb.h])
1107
1108 if test "x${ac_cv_header_netdb_h}" = "xyes" ; then
1109    have_addrinfo="yes"
1110 fi
1111
1112 # Framebuffer (ecore_fb)
1113 have_fb="no"
1114 AC_CHECK_HEADER([linux/fb.h],
1115    [AC_CHECK_HEADER([linux/input.h], [have_fb="yes"])])
1116
1117 # Cocoa header files (ecore_cocoa)
1118
1119 cocoa_ldflags="";
1120 have_cocoa="no"
1121 m4_ifdef([AC_PROG_OBJC], [
1122     if test "x${have_gnu_objc}" = "xyes" ; then
1123        AC_LANG_PUSH([Objective C])
1124        AC_CHECK_HEADER([Cocoa/Cocoa.h],
1125           [
1126            have_cocoa="yes"
1127            cocoa_ldflags="-framework Cocoa"
1128           ])
1129        AC_LANG_POP([Objective C])
1130     fi
1131 ])
1132 AC_SUBST(cocoa_ldflags)
1133
1134 want_epoll=yes
1135 AC_ARG_ENABLE(epoll,
1136   AC_HELP_STRING([--enable-epoll], [enable or disable epoll support]),
1137   [want_epoll=$enableval])
1138
1139 if test "x${want_epoll}" = "xyes" ; then
1140   # check for epoll support
1141   AC_CHECK_HEADERS([sys/epoll.h])
1142 fi
1143
1144 # timerfd_create
1145 AC_CHECK_HEADERS([sys/timerfd.h])
1146 AC_CHECK_FUNCS(timerfd_create)
1147
1148 # thread support
1149
1150 EFL_CHECK_THREADS(
1151    [
1152     if test "x${_efl_have_posix_threads}" = "xyes" ; then
1153        have_threads="POSIX"
1154     else
1155        if test "x${_efl_have_win32_threads}" = "xyes" ; then
1156           have_threads="Win32"
1157        else
1158           have_threads="no"
1159        fi
1160     fi
1161    ],
1162    [have_threads="no"])
1163
1164 ### enable thread safety if we have threads, unless specifically asked not to
1165 if test "x${have_threads}" = "xno"
1166 then
1167   want_thread_safety="no"
1168 else
1169   want_thread_safety="no"  # to be changed to yes when ready
1170   AC_ARG_ENABLE(thread-safety,
1171     AC_HELP_STRING([--enable-thread-safety], [enable or disable thread safety]),
1172     [want_thread_safety=$enableval])
1173 fi
1174
1175 if test "x${want_thread_safety}" = "xyes"
1176 then
1177    AC_DEFINE([HAVE_THREAD_SAFETY], [1], [Define to enable thread safety])
1178 fi
1179
1180 ### Checks for types
1181 AC_CHECK_SIZEOF(int, 4)
1182 AC_CHECK_SIZEOF(long, 4)
1183
1184
1185 ### Checks for structures
1186
1187
1188 ### Checks for compiler characteristics
1189 AM_PROG_CC_STDC
1190 AC_C_CONST
1191 AC_C_BIGENDIAN
1192 AC_HEADER_STDC
1193 AC_C___ATTRIBUTE__
1194
1195 WIN32_CPPFLAGS=""
1196 WIN32_CFLAGS=""
1197 case "$host_os" in
1198    mingw32ce*)
1199       WIN32_CPPFLAGS="-D_WIN32_WCE=0x0420"
1200       ;;
1201    cegcc*)
1202       WIN32_CPPFLAGS="-D_WIN32_WCE=0x0420"
1203       WIN32_CFLAGS="-mwin32"
1204       ;;
1205    mingw*)
1206       WIN32_CPPFLAGS="-D_WIN32_WINNT=0x0501"
1207       ;;
1208 esac
1209 AC_SUBST(WIN32_CPPFLAGS)
1210 AC_SUBST(WIN32_CFLAGS)
1211
1212
1213 ### Checks for linker characteristics
1214
1215 # use --enable-auto-import on Windows
1216
1217 lt_enable_auto_import=""
1218 case "$host_os" in
1219    mingw* | cegcc*)
1220       lt_enable_auto_import="-Wl,--enable-auto-import"
1221       ;;
1222 esac
1223 AC_SUBST(lt_enable_auto_import)
1224
1225 ### Checks for library functions
1226 AC_ISC_POSIX
1227 AC_FUNC_ALLOCA
1228 AC_CHECK_FUNCS(gettimeofday strlcpy)
1229
1230 AC_COMPILE_IFELSE(
1231    [AC_LANG_PROGRAM(
1232        [[
1233 #include <math.h>
1234        ]],
1235        [[
1236 int i = isfinite(0);
1237        ]])],
1238    [
1239     AC_DEFINE(HAVE_ISFINITE, 1, [Define to 1 if you have `isfinite', as a function or macro.])
1240     have_isfinite="yes"
1241    ],
1242    [have_isfinite="no"])
1243
1244 AC_MSG_CHECKING([for isfinite])
1245 AC_MSG_RESULT([${have_isfinite}])
1246
1247 have_atfile_source=auto
1248 AC_ARG_ENABLE([atfile-source],
1249    [AC_HELP_STRING([--disable-atfile-source],
1250        [disable use of atfile source functions as openat and mkdirat @<:@default=detect@:>@])],
1251    [
1252     if test "x${enableval}" = "xyes" ; then
1253        have_atfile_source="yes"
1254     else
1255        have_atfile_source="no"
1256     fi],
1257    [have_atfile_source=auto])
1258
1259 if ! test "x${have_atfile_source}" = "xno" ; then
1260    AC_CHECK_FUNCS(mkdirat,
1261       [
1262        have_atfile_source="yes"
1263        AC_DEFINE(HAVE_ATFILE_SOURCE, 1, [mkdirat exists])
1264       ],
1265       [
1266        if test "x${have_atfile_source}" = "xyes" ; then
1267           AC_MSG_ERROR([required atfile-source but no mkdirat()])
1268        fi
1269        have_atfile_source="no"
1270       ])
1271 fi
1272
1273 ### Checks for optionnal feature
1274 AC_CHECK_FUNC([mallinfo],
1275    [
1276     have_mallinfo="yes"
1277     AC_DEFINE(HAVE_MALLINFO, 1, [Gather memory statistic])
1278    ],
1279    [have_mallinfo="no"])
1280
1281 ### Ecore modules
1282
1283 ## Core modules
1284
1285 # ecore_con
1286 ECORE_CHECK_MODULE([con], [${want_ecore_con}], [Con], [${have_addrinfo}])
1287
1288 have_curl="no"
1289 have_gnutls="no"
1290 have_openssl="no"
1291 have_cares="no"
1292 if test "x${have_ecore_con}" = "xyes" ; then
1293
1294    ECORE_CHECK_CURL([${want_curl}],
1295       [
1296        have_curl="yes"
1297        requirements_ecore_con="libcurl ${requirements_ecore_con}"
1298       ],
1299       [have_curl="no"])
1300
1301    ECORE_CHECK_GNUTLS([${want_gnutls}],
1302       [have_gnutls="yes"],
1303       [have_gnutls="no"])
1304
1305    ECORE_CHECK_OPENSSL([${want_openssl}],
1306       [have_openssl="yes"],
1307       [have_openssl="no"])
1308
1309    if test "x${have_gnutls}" = "xyes" ; then
1310       requirements_ecore_con="gnutls ${requirements_ecore_con}"
1311       # no need to add it to req_ecore_ipc, since they
1312       # depends on ecore_con anyway.
1313    else
1314       if test "x${have_openssl}" = "xyes" ; then
1315          requirements_ecore_con="openssl ${requirements_ecore_con}"
1316          # no need to add it to req_ecore_ipc, since they
1317          # depends on ecore_con anyway.
1318       fi
1319    fi
1320
1321    ECORE_CHECK_CARES([${want_cares}],
1322       [
1323        have_cares="yes"
1324        requirements_ecore_con="libcares ${requirements_ecore_con}"
1325       ],
1326       [have_cares="no"])
1327
1328 fi
1329
1330 AM_CONDITIONAL([HAVE_CARES], [test "x${have_cares}" = "xyes"])
1331
1332 # ecore_ipc
1333 ECORE_CHECK_MODULE([ipc], [${want_ecore_ipc}], [Ipc], [${have_ecore_con}],
1334    [requirements_ecore_ipc="ecore-con >= 1.0.0 ${requirements_ecore_ipc}"])
1335
1336 # ecore_file
1337 ECORE_CHECK_MODULE([file], [${want_ecore_file}], [File])
1338
1339 have_poll="no"
1340 have_inotify="no"
1341 have_notify_win32="no"
1342 if test "x${have_ecore_file}" = "xyes" ; then
1343    ECORE_CHECK_POLL([${want_poll}], [have_poll="yes"], [have_poll="no"])
1344    ECORE_CHECK_INOTIFY([${want_inotify}], [have_inotify="yes"], [have_inotify="no"])
1345    ECORE_CHECK_NOTIFY_WIN32([${want_notify_win32}], [have_notify_win32="yes"], [have_notify_win32="no"])
1346
1347    if test "x${have_ecore_con}" = "xyes" ; then
1348       requirements_ecore_file="ecore-con >= 1.0.0 ${requirements_ecore_file}"
1349    fi
1350 fi
1351
1352 # ecore_config
1353 #ecore_config_deps="no"
1354 #if test "x${have_eet}" = "xyes" -a "x${have_evas}"  -a "x${have_ecore_ipc}" ; then
1355 #   ecore_config_deps="yes"
1356 #fi
1357
1358 #ECORE_CHECK_MODULE([config], [${want_ecore_config}], [Config], [${ecore_config_deps}],
1359 #   [requirements_ecore_config="ecore-ipc >= 1.0.0 evas >= 1.0.0 eet >= 1.4.0 ${requirements_ecore_config}"])
1360
1361 AM_CONDITIONAL(BUILD_ECORE_CONFIG, false)
1362
1363 # ecore_imf
1364
1365 ECORE_CHECK_MODULE([imf], [${want_ecore_imf}], [Imf])
1366
1367 # ecore_imf_evas
1368
1369 ecore_imf_evas_deps="no"
1370 if test "x${have_ecore_imf}" = "xyes" -a "x${have_evas}" = "xyes" ; then
1371    ecore_imf_evas_deps="yes"
1372 fi
1373
1374 ECORE_CHECK_MODULE([imf-evas], [${want_ecore_imf}], [Imf_Evas], [${ecore_imf_evas_deps}],
1375    [requirements_ecore_imf_evas="ecore-imf >= 1.0.0 evas >= 1.0.0 ${requirements_ecore_imf_evas}"])
1376
1377 # ecore_input{_evas}
1378 ECORE_CHECK_MODULE([input], [${want_ecore_input}], [Input])
1379 ECORE_CHECK_MODULE([input-evas], [${want_ecore_input}], [Input_Evas], [${have_evas}],
1380    [requirements_ecore_input_evas="ecore-input >= 1.0.0 evas >= 1.0.0 ${requirements_ecore_input}"])
1381
1382 # ecore_imf_xim
1383 AM_CONDITIONAL(BUILD_ECORE_IMF_XIM, false)
1384 ecore_imf_xim_deps="no"
1385 echo "have_ecore_x_xlib: ${have_ecore_x_xlib}"
1386 if test    "x${have_ecore_imf}" = "xyes" \
1387         -a "x${have_ecore_x_xlib}" = "xyes" \
1388         -a "x${have_ecore_input}" = "xyes" ; then
1389    ecore_imf_xim_deps="yes"
1390    AC_DEFINE(BUILD_ECORE_IMF_XIM, 1, [Ecore Imf XIM Support])
1391 fi
1392
1393 ECORE_CHECK_MODULE([imf-xim], [${want_ecore_imf}], [Imf_XIM], [${ecore_imf_xim_deps}],
1394    [requirements_ecore_imf_xim="ecore-imf >= 1.0.0 ecore-x >= 1.0.0 ecore-input >= 1.0.0 ${requirements_ecore_imf_xim}"])
1395
1396 ## Graphic systems
1397
1398 # ecore_x{cb}
1399
1400 ecore_x_deps="no"
1401 if test "x${have_x}" = "xyes" -a \
1402         "x${have_ecore_input}" = "xyes" ; then
1403    ecore_x_deps="yes"
1404 fi
1405
1406 ECORE_CHECK_MODULE([x], [${want_ecore_x}], [X], [${ecore_x_deps}],
1407   [
1408    ecore_x_libs="$ecore_x_libs $x_libs"
1409    requirements_ecore_x="ecore-input >= 1.0.0 ${requirements_ecore_x}"
1410   ])
1411
1412 # ecore_win32
1413
1414 ECORE_CHECK_MODULE([win32], [${want_ecore_win32}], [Win32], [${have_ecore_input}],
1415    [
1416     ecore_win32_libs="-lole32 -lgdi32"
1417     requirements_ecore_win32="ecore-input >= 1.0.0 ${requirements_ecore_win32}"
1418    ])
1419 AC_SUBST(ecore_win32_libs)
1420
1421 # ecore_cocoa
1422
1423 ecore_cocoa_deps="no"
1424 if test "x${have_ecore_input}" = "xyes" -a "x${have_cocoa}" = "xyes" ; then
1425    ecore_cocoa_deps="yes"
1426 fi
1427
1428 ECORE_CHECK_MODULE([cocoa], [${want_ecore_cocoa}], [Cocoa], [${ecore_cocoa_deps}],
1429    [requirements_ecore_cocoa="ecore-input >= 1.0.0 ${requirements_ecore_cocoa}"])
1430
1431 # ecore_sdl
1432
1433 ecore_sdl_deps="no"
1434 if test "x${have_sdl}" = "xyes" -a "x${have_ecore_input}" = "xyes" ; then
1435    ecore_sdl_deps="yes"
1436 fi
1437
1438 ECORE_CHECK_MODULE([sdl], [${want_ecore_sdl}], [Sdl], [${ecore_sdl_deps}],
1439    [requirements_ecore_sdl="ecore-input >= 1.0.0 ${requirements_ecore_sdl}"])
1440
1441 # ecore_fb
1442 ECORE_CHECK_MODULE([fb], [${want_ecore_fb}], [FB], [$have_fb])
1443
1444 if test "x${have_ecore_fb}" = "xyes" ; then
1445    ECORE_CHECK_TSLIB([${want_tslib}],
1446       [
1447        have_tslib="yes"
1448        requirements_ecore_fb="${_tslib_requirement} ${requirements_ecore_fb}"
1449       ],
1450       [have_tslib="no"])
1451 fi
1452
1453 # ecore_directfb
1454
1455 ECORE_CHECK_MODULE([directfb], [${want_ecore_directfb}], [DirectFB], [${have_directfb}],
1456    [requirements_ecore_directfb="directfb ${requirements_ecore_directfb}"])
1457
1458 # ecore_wince
1459
1460 ECORE_CHECK_MODULE([wince], [${want_ecore_wince}], [WinCE], [${have_ecore_input}],
1461    [requirements_ecore_win32="ecore-input >= 1.0.0 ${requirements_ecore_win32}"])
1462
1463 ## Ecore Evas
1464
1465 # ecore_evas
1466
1467 ecore_evas_deps="no"
1468 if test "x${have_evas}" = "xyes" -a "x${have_ecore_input}" = "xyes" -a "x${have_ecore_input_evas}" = "xyes" ; then
1469    ecore_evas_deps="yes"
1470 fi
1471
1472 ECORE_CHECK_MODULE([evas], [${want_ecore_evas}], [Evas], [${ecore_evas_deps}],
1473   [requirements_ecore_evas="ecore-input >= 1.0.0 ecore-input-evas >= 1.0.0 evas >= 1.0.0 ${requirements_ecore_evas}"])
1474
1475 # ecore_evas_buffer
1476
1477 ECORE_EVAS_CHECK_MODULE([software-buffer],
1478    [${want_ecore_evas_software_buffer}],
1479    [Software Buffer],
1480    [yes])
1481
1482 # ecore_evas_x11
1483
1484 # ecore_evas_software_x11
1485
1486 ECORE_EVAS_CHECK_MODULE([software-x11],
1487    [${want_ecore_evas_software_x11}],
1488    [Software X11],
1489    [${have_ecore_x}])
1490
1491 have_ecore_evas_software_xlib="no"
1492 have_ecore_evas_software_xcb="no"
1493 if test "x$have_ecore_evas_software_x11" = "xyes" ; then
1494    have_ecore_evas_software_xlib=`${PKG_CONFIG} --variable=Xlib evas-software-x11`
1495    if test "x${have_ecore_evas_software_xlib}" = "xyes" -a "x${have_ecore_x_xlib}" = "xyes" ; then
1496       AC_DEFINE(BUILD_ECORE_EVAS_SOFTWARE_XLIB, 1, [Evas Software Xlib Engine Support])
1497    fi
1498    have_ecore_evas_software_xcb=`${PKG_CONFIG} --variable=XCB evas-software-x11`
1499    if test "x$have_ecore_evas_software_xcb" = "xyes" -a "x${have_ecore_x_xcb}" = "xyes" ; then
1500       AC_DEFINE(BUILD_ECORE_EVAS_SOFTWARE_XCB, 1, [Evas Software XCB Engine Support])
1501    fi
1502 fi
1503
1504 # ecore_evas_opengl_x11
1505
1506 ECORE_EVAS_CHECK_MODULE([opengl-x11],
1507    [${want_ecore_evas_opengl_x11}],
1508    [OpenGL Xlib],
1509    [${have_ecore_x}])
1510
1511 have_ecore_evas_opengl_xlib="no"
1512 have_ecore_evas_opengl_xcb="no"
1513 if test "x${have_ecore_evas_opengl_x11}" = "xyes" -o "x${have_ecore_evas_opengl_x11}" = "xstatic" ; then
1514    have_ecore_evas_opengl_xlib=`${PKG_CONFIG} --variable=Xlib evas-opengl-x11`
1515    if test "x${have_ecore_evas_opengl_xlib}" = "xyes" ; then
1516       AC_DEFINE(BUILD_ECORE_EVAS_OPENGL_XLIB, 1, [OpenGL Xlib rendering backend])
1517    fi
1518
1519 # opengl does not work with xcb (yet)
1520    have_ecore_evas_opengl_xcb=`${PKG_CONFIG} --variable=XCB evas-opengl-x11`
1521    if test "x${have_ecore_evas_opengl_xcb}" = "xyes" -a "x${have_ecore_x_xcb}" = "xyes" ; then
1522       PKG_CHECK_MODULES(XCB_X11, x11-xcb,
1523         [ have_ecore_x_opengl_xcb="yes"
1524           requirements_ecore_x="x11-xcb ${requirements_ecore_x}"
1525           AC_DEFINE(BUILD_ECORE_X_OPENGL_XCB, 1, [Build support for XCB-based OpenGL])
1526           AC_DEFINE(BUILD_ECORE_EVAS_OPENGL_XCB, 1, [OpenGL XCB rendering backend])
1527         ],
1528         [ have_ecore_x_opengl_xcb="no" ])
1529     else
1530       have_ecore_x_opengl_xcb="no"
1531       AC_MSG_NOTICE("XCB-based OpenGL explicitly disabled")
1532     fi
1533 fi
1534
1535 # ecore_evas_software_x11 16 bits
1536
1537 ECORE_EVAS_CHECK_MODULE([software-16-x11],
1538    [${want_ecore_evas_software_16_x11}],
1539    [Software Xlib 16 bits],
1540    [${have_ecore_x_xlib}])
1541
1542 ECORE_EVAS_CHECK_MODULE([software-8-x11],
1543     [$want_ecore_evas_software_8_x11],
1544     [Software 8bit X11],
1545     $have_ecore_x_xcb)
1546
1547
1548 if test "x$have_ecore_evas_software_x11" = "xyes" -o \
1549         "x$have_ecore_evas_opengl_x11" = "xyes" -o \
1550         "x$have_ecore_evas_software_8_x11" = "xyes" -o \
1551         "x$have_ecore_evas_software_16_x11" = "xyes" -o \
1552         "x$have_ecore_evas_software_xcb" = "xyes"; then
1553    AC_DEFINE(BUILD_ECORE_EVAS_X11, 1, [Support for X Window Engines in Ecore_Evas])
1554    requirements_ecore_evas="ecore-x >= 1.0.0 ${requirements_ecore_evas}"
1555 fi
1556
1557 # ecore_evas_win32
1558
1559 ECORE_EVAS_CHECK_MODULE([software-gdi],
1560    [${want_ecore_evas_software_gdi}],
1561    [Software GDI],
1562    [${have_ecore_win32}])
1563
1564 ECORE_EVAS_CHECK_MODULE([software-ddraw],
1565    [${want_ecore_evas_software_ddraw}],
1566    [Software DirectDraw],
1567    [${have_ecore_win32}])
1568
1569 ECORE_EVAS_CHECK_MODULE([direct3d],
1570    [${want_ecore_evas_direct3d}],
1571    [Direct3d],
1572    [${have_ecore_win32}])
1573
1574 ECORE_EVAS_CHECK_MODULE([opengl-glew],
1575    [${want_ecore_evas_opengl_glew}],
1576    [Glew OpenGL],
1577    [${have_ecore_win32}])
1578
1579 ECORE_EVAS_CHECK_MODULE([software-16-ddraw],
1580    [${want_ecore_evas_software_16_ddraw}],
1581    [16 bpp Software DirectDraw],
1582    [${have_ecore_win32}])
1583
1584 if test "x${have_ecore_evas_software_gdi}" = "xyes" -o \
1585         "x${have_ecore_evas_software_ddraw}" = "xyes" -o \
1586         "x${have_ecore_evas_direct3d}" = "xyes" -o \
1587         "x${have_ecore_evas_opengl_glew}" = "xyes" -o \
1588         "x${have_ecore_evas_software_16_ddraw}" = "xyes" ; then
1589    AC_DEFINE(BUILD_ECORE_EVAS_WIN32, 1, [Support for Win32 Engine in Ecore_Evas])
1590    requirements_ecore_evas="ecore-win32 >= 1.0.0 ${requirements_ecore_evas}"
1591 fi
1592
1593 # ecore_evas_software_sdl
1594
1595 ECORE_EVAS_CHECK_MODULE([software-sdl],
1596    [${want_ecore_evas_software_sdl}],
1597    [Software SDL],
1598    [${have_ecore_sdl}],
1599    [requirements_ecore_evas="ecore-sdl >= 1.0.0 ${requirements_ecore_evas}"])
1600
1601 # ecore_evas_gl_sdl
1602
1603 ECORE_EVAS_CHECK_MODULE([opengl-sdl],
1604    [${want_ecore_evas_gl_sdl}],
1605    [OpenGL SDL],
1606    [${have_ecore_sdl}],
1607    [requirements_ecore_evas="ecore-sdl >= 1.0.0 ${requirements_ecore_evas}"])
1608
1609 # ecore_evas_directfb
1610
1611 ECORE_EVAS_CHECK_MODULE([directfb],
1612    [${want_ecore_evas_directfb}],
1613    [DirectFB],
1614    [${have_ecore_directfb}],
1615    [requirements_ecore_evas="ecore-directfb >= 1.0.0 ${requirements_ecore_evas}"])
1616
1617 # ecore_evas_fb
1618
1619 ECORE_EVAS_CHECK_MODULE([fb],
1620    [${want_ecore_evas_fb}],
1621    [Linux Framebuffer],
1622    [${have_ecore_fb}],
1623    [requirements_ecore_evas="ecore-fb >= 1.0.0 ${requirements_ecore_evas}"])
1624
1625 # ecore_evas_wince
1626
1627 ECORE_EVAS_CHECK_MODULE([software-16-wince],
1628    [${want_ecore_evas_software_16_wince}],
1629    [16 bpp Software Windows CE],
1630    [${have_ecore_wince}],
1631    [requirements_ecore_evas="ecore-wince >= 1.0.0 ${requirements_ecore_evas}"])
1632
1633 ### install and build examples
1634
1635 EFL_CHECK_BUILD_EXAMPLES([enable_build_examples="yes"], [enable_build_examples="no"])
1636 EFL_CHECK_INSTALL_EXAMPLES([enable_install_examples="yes"], [enable_install_examples="no"])
1637
1638 ### requirements
1639
1640 AC_SUBST(requirements_ecore)
1641 AC_SUBST(requirements_ecore_con)
1642 #AC_SUBST(requirements_ecore_config)
1643 AC_SUBST(requirements_ecore_directfb)
1644 AC_SUBST(requirements_ecore_evas)
1645 AC_SUBST(requirements_ecore_fb)
1646 AC_SUBST(requirements_ecore_file)
1647 AC_SUBST(requirements_ecore_imf)
1648 AC_SUBST(requirements_ecore_imf_evas)
1649 AC_SUBST(requirements_ecore_input)
1650 AC_SUBST(requirements_ecore_input_evas)
1651 AC_SUBST(requirements_ecore_ipc)
1652 AC_SUBST(requirements_ecore_cocoa)
1653 AC_SUBST(requirements_ecore_sdl)
1654 AC_SUBST(requirements_ecore_x)
1655 AC_SUBST(requirements_ecore_win32)
1656 AC_SUBST(requirements_ecore_wince)
1657 AC_SUBST(requirements_ecore_imf_xim)
1658
1659 AC_CONFIG_FILES([
1660 Makefile
1661 ecore-con.pc
1662 ecore-config.pc
1663 ecore-directfb.pc
1664 ecore-evas.pc
1665 ecore-fb.pc
1666 ecore-file.pc
1667 ecore-cocoa.pc
1668 ecore-imf.pc
1669 ecore-imf-evas.pc
1670 ecore-ipc.pc
1671 ecore-x.pc
1672 ecore-input.pc
1673 ecore-input-evas.pc
1674 ecore-win32.pc
1675 ecore-sdl.pc
1676 ecore-wince.pc
1677 ecore.pc
1678 doc/ecore.dox
1679 doc/Makefile
1680 doc/Doxyfile
1681 src/Makefile
1682 src/util/Makefile
1683 src/bin/Makefile
1684 src/lib/Makefile
1685 src/lib/ecore/Makefile
1686 src/lib/ecore_con/Makefile
1687 src/lib/ecore_config/Makefile
1688 src/lib/ecore_directfb/Makefile
1689 src/lib/ecore_evas/Makefile
1690 src/lib/ecore_fb/Makefile
1691 src/lib/ecore_file/Makefile
1692 src/lib/ecore_cocoa/Makefile
1693 src/lib/ecore_sdl/Makefile
1694 src/lib/ecore_imf/Makefile
1695 src/lib/ecore_imf_evas/Makefile
1696 src/lib/ecore_input/Makefile
1697 src/lib/ecore_input_evas/Makefile
1698 src/lib/ecore_ipc/Makefile
1699 src/lib/ecore_win32/Makefile
1700 src/lib/ecore_wince/Makefile
1701 src/lib/ecore_x/Makefile
1702 src/lib/ecore_x/xlib/Makefile
1703 src/lib/ecore_x/xcb/Makefile
1704 src/examples/Makefile
1705 src/tests/Makefile
1706 src/modules/Makefile
1707 src/modules/immodules/Makefile
1708 src/modules/immodules/xim/Makefile
1709 README
1710 ecore.spec
1711 $po_makefile_in
1712 ])
1713
1714 AC_OUTPUT
1715
1716 echo
1717 echo "$PACKAGE $VERSION"
1718 echo
1719 echo "Optional Modules:"
1720 echo
1721 echo " Core:"
1722 echo
1723 echo "  Ecore........................: always"
1724 echo "    Thread support.............: $have_threads"
1725 echo "    Thread safety..............: $want_thread_safety"
1726 echo "    GLib support...............: $have_glib"
1727 echo "    Always integrate GLib......: $want_glib_integration_always"
1728 echo "    Use g_main_loop............: $want_g_main_loop"
1729 echo "    Gathering memory statistic.: $have_mallinfo"
1730 echo "    Gathering timer allocation.: $want_ecore_timer_dump"
1731 echo "  Ecore_Con....................: $have_ecore_con"
1732 if test "x$have_ecore_con" = "xyes" ; then
1733   echo $ECHO_N "    OpenSSL....................: $have_openssl $ECHO_C"
1734 if test "x$have_gnutls" = "xyes" ; then
1735   echo " (disabled)"
1736 else
1737   echo
1738 fi
1739   echo "    GnuTLS.....................: $have_gnutls"
1740   echo "    CURL.......................: $have_curl"
1741   echo "    Abstract Sockets...........: $want_abstract_sockets"
1742   echo "    c-ares.....................: $have_cares"
1743 fi
1744 echo "  Ecore_Ipc....................: $have_ecore_ipc"
1745 if test "x$have_ecore_ipc" = "xyes" ; then
1746   echo $ECHO_N "    OpenSSL....................: $have_openssl $ECHO_C"
1747 if test "x$have_gnutls" = "xyes" ; then
1748   echo " (disabled)"
1749 else
1750   echo
1751 fi
1752   echo "    GnuTLS.....................: $have_gnutls"
1753 fi
1754 echo "  Ecore_File...................: $have_ecore_file"
1755 if test "x$have_ecore_file" = "xyes" ; then
1756   echo "    Inotify....................: $have_inotify"
1757   echo "    Windows notification.......: $have_notify_win32"
1758   echo "    Poll.......................: $have_poll"
1759   echo "    CURL.......................: $have_curl"
1760 fi
1761 #echo "  Ecore_Config.................: $have_ecore_config (deprecated)"
1762 echo "  Ecore_IMF....................: $have_ecore_imf"
1763 echo "    XIM........................: $have_ecore_imf_xim"
1764 echo "  Ecore_IMF_Evas...............: $have_ecore_imf_evas"
1765 echo "  Ecore_Input..................: $have_ecore_input"
1766 echo "  Ecore_Input_Evas.............: $have_ecore_input_evas"
1767
1768 echo
1769 echo " Graphic systems:"
1770 echo
1771
1772 if test "x$have_ecore_x" = "xyes" ; then
1773   if test "x$have_ecore_x_xcb" = "xyes" ; then
1774     echo "  Ecore_X (XCB backend)........: $have_ecore_x_xcb"
1775     echo "    Xprint.....................: $have_ecore_x_xcb_xprint"
1776     echo "    Xinerama...................: $have_ecore_x_xcb_xinerama"
1777     echo "    Xrandr.....................: $have_ecore_x_xcb_randr"
1778     echo "    Xscreensaver...............: $have_ecore_x_xcb_screensaver"
1779     echo "    Xshape.....................: $have_ecore_x_xcb_shape"
1780     echo "    Xsync......................: $have_ecore_x_xcb_sync"
1781     echo "    Xrender....................: $have_ecore_x_xcb_render"
1782     echo "    Xcomposite.................: $have_ecore_x_xcb_composite"
1783     echo "    Xfixes.....................: $have_ecore_x_xcb_xfixes"
1784     echo "    Xdamage....................: $have_ecore_x_xcb_damage"
1785     echo "    Xdpms......................: $have_ecore_x_xcb_dpms"
1786     echo "    Xtest......................: $have_ecore_x_xcb_xtest"
1787   else
1788     echo "  Ecore_X (Xlib backend).......: $have_ecore_x"
1789     echo "    Xcursor....................: $use_Xcursor"
1790     echo "    Xkb........................: $use_xkb"
1791     echo "    Xprint.....................: $use_xprint"
1792     echo "    Xinerama...................: $use_xinerama"
1793     echo "    Xrandr.....................: $use_xrandr"
1794     echo "    Xscreensaver...............: $use_xss"
1795     echo "    Xrender....................: $use_xrender"
1796     echo "    Xcomposite.................: $use_xcomposite"
1797     echo "    Xfixes.....................: $use_xfixes"
1798     echo "    Xdamage....................: $use_xdamage"
1799     echo "    Xdpms......................: $use_xdpms"
1800     echo "    Xtest......................: $use_xtest"
1801     echo "    XIM........................: $want_xim"
1802     echo "    Xi2........................: $use_xi2"
1803   fi
1804 else
1805   echo "  Ecore_X......................: $have_ecore_x"
1806 fi
1807 echo "  Ecore_Win32..................: $have_ecore_win32"
1808 echo "  Ecore_Cocoa..................: $have_ecore_cocoa"
1809 echo "  Ecore_SDL....................: $have_ecore_sdl"
1810 echo "  Ecore_FB.....................: $have_ecore_fb"
1811 if test "x${have_ecore_fb}" = "xyes" ; then
1812   echo "    Touchscreen................: $have_tslib"
1813 fi
1814 echo "  Ecore_DirectFB...............: $have_ecore_directfb"
1815 echo "  Ecore_WinCE..................: $have_ecore_wince"
1816
1817 echo
1818 echo " Ecore Evas:"
1819 echo
1820
1821 echo "  Ecore_Evas...................: $have_ecore_evas"
1822 if test "x${have_ecore_evas}" = "xyes" ; then
1823   echo "    Software Memory Buffer.....: $have_ecore_evas_software_buffer"
1824   if test "x${have_ecore_evas_software_x11}" = "xyes" ; then
1825     echo "    Software X11...............: $have_ecore_evas_software_x11 (Xlib=${have_ecore_evas_software_xlib}) (XCB=${have_ecore_evas_software_xcb})"
1826   else
1827     echo "    Software X11...............: $have_ecore_evas_software_x11"
1828   fi
1829   if test "x${have_ecore_evas_opengl_x11}" = "xyes" ; then
1830     echo "    OpenGL X11.................: $have_ecore_evas_opengl_x11 (Xlib=${have_ecore_evas_opengl_xlib}) (XCB=${have_ecore_evas_opengl_xcb})"
1831   else
1832     echo "    OpenGL X11.................: $have_ecore_evas_opengl_x11"
1833   fi
1834   echo "    Software GDI...............: $have_ecore_evas_software_gdi"
1835   echo "    Software DirectDraw........: $have_ecore_evas_software_ddraw"
1836   echo "    Direct3D...................: $have_ecore_evas_direct3d"
1837   echo "    OpenGL Glew................: $have_ecore_evas_opengl_glew"
1838   echo "    Software SDL...............: $have_ecore_evas_software_sdl"
1839   echo "    OpenGL SDL.................: $have_ecore_evas_opengl_sdl"
1840   echo "    DirectFB...................: $have_ecore_evas_directfb"
1841   echo "    Software Framebuffer.......: $have_ecore_evas_fb"
1842   echo "    Software 8bit grayscale XCB: $have_ecore_evas_software_8_x11"
1843   echo "    Software 16bit X11.........: $have_ecore_evas_software_16_x11"
1844   echo "    Software 16bit DirectDraw..: $have_ecore_evas_software_16_ddraw"
1845   echo "    Software 16bit WinCE.......: $have_ecore_evas_software_16_wince"
1846 fi
1847 echo
1848 echo "  Tests................: ${enable_tests}"
1849 echo "  Maximum log level....: ${with_max_log_level}"
1850 echo "Documentation..........: ${build_doc}"
1851 echo
1852 echo "Compilation............: make (or gmake)"
1853 echo "  CPPFLAGS.............: $CPPFLAGS"
1854 echo "  CFLAGS...............: $CFLAGS"
1855 echo "  CXXFLAGS.............: $CXXFLAGS"
1856 echo "  LDFLAGS..............: $LDFLAGS"
1857 echo
1858 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
1859 echo "  prefix...............: $prefix"
1860 echo