configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.10.29.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.10
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 dnl CURRENT, REVISION, AGE
  47 dnl - library source changed -> increment REVISION
  48 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  49 dnl - interfaces added -> increment AGE
  50 dnl - interfaces removed -> AGE = 0
  51 dnl sets GST_LT_LDFLAGS
  52 AS_LIBTOOL(GST, 20, 0, 20)
  53
  54 dnl FIXME: this macro doesn't actually work;
  55 dnl the generated libtool script has no support for the listed tags.
  56 dnl So this needs to be fixed first if we want to use this
  57 dnl AS_LIBTOOL_TAGS
  58
  59 AC_LIBTOOL_WIN32_DLL
  60 AM_PROG_LIBTOOL
  61
  62 dnl *** required versions of GStreamer stuff ***
  63 GST_REQ=0.10.29.1
  64
  65 dnl *** autotools stuff ****
  66
  67 dnl allow for different autotools
  68 AS_AUTOTOOLS_ALTERNATE
  69
  70 dnl Add parameters for aclocal
  71 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  72
  73 dnl set up gettext
  74 dnl the version check needs to stay here because autopoint greps for it
  75 AM_GNU_GETTEXT_VERSION([0.17])
  76 AM_GNU_GETTEXT([external])
  77 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  78
  79 dnl *** check for arguments to configure ***
  80
  81 AG_GST_ARG_DEBUG
  82 AG_GST_ARG_PROFILING
  83 AG_GST_ARG_VALGRIND
  84 AG_GST_ARG_GCOV
  85
  86 AG_GST_ARG_EXAMPLES
  87
  88 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  89 AG_GST_ARG_WITH_PACKAGE_NAME
  90 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  91
  92 dnl let distro override plugin install helper path
  93 AC_ARG_WITH(install-plugins-helper,
  94   AC_HELP_STRING([--with-install-plugins-helper],
  95     [specify path of helper script to call to install plugins]),
  96   [
  97     case "${withval}" in
  98       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  99       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 100       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 101     esac
 102   ],
 103   [
 104     dnl Default value
 105     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 106   ]
 107 )
 108 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 109 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 110     [plugin install helper script])
 111 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 112
 113 AG_GST_ARG_WITH_PLUGINS
 114
 115 AG_GST_ARG_ENABLE_EXTERNAL
 116
 117 AG_GST_ARG_ENABLE_EXPERIMENTAL
 118
 119 dnl *** checks for platform ***
 120
 121 dnl * hardware/architecture *
 122
 123 dnl common/m4/gst-arch.m4
 124 dnl check CPU type
 125 AG_GST_ARCH
 126
 127 dnl check for large file support
 128 dnl affected plugins must include config.h
 129 AC_SYS_LARGEFILE
 130
 131 dnl *** checks for programs ***
 132
 133 dnl find a compiler
 134 AC_PROG_CC
 135 AC_PROG_CXX
 136
 137 dnl determine if c++ is available on this system
 138 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 139
 140 dnl determine c++ preprocessor
 141 dnl FIXME: do we need this ?
 142 AC_PROG_CXXCPP
 143
 144 dnl check if the compiler supports '-c' and '-o' options
 145 AM_PROG_CC_C_O
 146
 147 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 148 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 149
 150 dnl check for gobject-introspection
 151 GOBJECT_INTROSPECTION_CHECK([0.6.3])
 152
 153 dnl check for documentation tools
 154 GTK_DOC_CHECK([1.3])
 155 AS_PATH_PYTHON([2.1])
 156 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 157
 158 dnl *** checks for libraries ***
 159
 160 dnl libm, for sin() etc.
 161 AC_CHECK_LIBM
 162 AC_SUBST(LIBM)
 163
 164 dnl *** checks for header files ***
 165
 166 dnl check if we have ANSI C header files
 167 AC_HEADER_STDC
 168
 169 dnl used in gst/ffmpegcolorspace/mem.c
 170 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 171 AC_CHECK_HEADERS([malloc.h])
 172
 173 ac_cppflags_save="$CPPFLAGS"
 174 CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 175 AC_COMPILE_IFELSE(
 176   AC_LANG_PROGRAM([
 177 #include <libxml/HTMLparser.h>
 178                      ],[
 179 #ifndef LIBXML_HTML_ENABLED
 180 #error libxml2 has no HTML support
 181 #endif /* LIBXML_HTML_ENABLED */
 182                    ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 183 CPPFLAGS="$ac_cppflags_save"
 184 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 185
 186 dnl used in gst/tcp
 187 AC_CHECK_HEADERS([sys/socket.h],
 188   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 189 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 190
 191 dnl used in gst-libs/gst/rtsp
 192 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 193 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 194   WIN32_LIBS="-lws2_32"
 195   AC_SUBST(WIN32_LIBS)
 196 fi
 197
 198 dnl check for hstrerror, for gst-libs/gst/rtsp
 199 save_libs="$LIBS"
 200 AC_CHECK_FUNC(hstrerror, ,
 201     AC_CHECK_LIB(resolv, hstrerror, ,
 202         [AC_DEFINE(NO_HSTRERROR, 1,
 203              [Define if you have no native hstrerror() function.])]))
 204 HSTRERROR_LIBS=$LIBS
 205 AC_SUBST(HSTRERROR_LIBS)
 206 LIBS="$save_libs"
 207
 208 dnl used in gst-libs/gst/pbutils and associated unit test
 209 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 210
 211 dnl ffmpegcolorspace includes _stdint.h
 212 dnl also, Windows does not have long long
 213 AX_CREATE_STDINT_H
 214
 215 dnl *** checks for functions ***
 216 AC_CHECK_FUNCS([localtime_r gmtime_r])
 217
 218 dnl *** checks for math functions ***
 219
 220 dnl *** checks for types/defines ***
 221
 222 dnl Check for FIONREAD ioctl declaration
 223 dnl used in gst/tcp
 224 GST_CHECK_FIONREAD
 225
 226 dnl *** checks for structures ***
 227
 228 dnl *** checks for compiler characteristics ***
 229
 230 dnl *** checks for library functions ***
 231
 232 dnl check for fseeko()
 233 AC_FUNC_FSEEKO
 234
 235 dnl Check for fast float to int casting as defined in C99
 236 dnl used in gst-libs/gst/floatcast/floatcast.h
 237 save_libs=$LIBS
 238 LIBS="$LIBS $LIBM"
 239 AC_C99_FUNC_LRINT
 240 AC_C99_FUNC_LRINTF
 241 LIBS=$save_libs
 242
 243 dnl Check for a way to display the function name in debug output
 244 AG_GST_CHECK_FUNCTION
 245
 246 dnl *** checks for socket and nsl libraries ***
 247 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 248 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 249
 250 dnl *** checks for dependency libraries ***
 251
 252 dnl GLib is required
 253 AG_GST_GLIB_CHECK([2.20])
 254
 255 ORC_CHECK([0.4.5])
 256
 257 dnl checks for gstreamer
 258 dnl uninstalled is selected preferentially -- see pkg-config(1)
 259 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 260 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 261 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 262 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 263 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 264 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 265
 266 dnl Check for documentation xrefs
 267 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 268 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 269 AC_SUBST(GLIB_PREFIX)
 270 AC_SUBST(GST_PREFIX)
 271
 272 dnl GTK is optional and only used in examples
 273 PKG_CHECK_MODULES(GTK, gtk+-3.0, HAVE_GTK=yes,
 274     [PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.14.0, HAVE_GTK=yes, HAVE_GTK=no)])
 275 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 276
 277 dnl some examples need gtk+-x11
 278 PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0, HAVE_GTK_X11=yes,
 279     [PKG_CHECK_MODULES(GTK_X11, gtk+-x11-2.0 >= 2.14.0, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)])
 280 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 281
 282 dnl QT is optional and only used in examples
 283 PKG_CHECK_MODULES(QT, QtGui >= 4.6, [
 284   HAVE_QT_GV=yes
 285   HAVE_QT=yes
 286 ], [
 287   HAVE_QT_GV=no
 288   PKG_CHECK_MODULES(QT, QtGui >= 4.0, HAVE_QT=yes, HAVE_QT=no)
 289 ])
 290 if test "x$HAVE_QT" = "xyes"; then
 291   AC_MSG_CHECKING([Qt moc])
 292   QT4_MOC=`$PKG_CONFIG --variable=moc_location QtGui`
 293   AC_MSG_RESULT($QT4_MOC)
 294   AC_SUBST(QT4_MOC)
 295 fi
 296 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 297 AM_CONDITIONAL(HAVE_QT_GV, test "x$HAVE_QT_GV" = "xyes")
 298
 299 dnl chck for linux headers needed by the joystick seek example
 300 AC_COMPILE_IFELSE(
 301 [
 302   AC_LANG_PROGRAM([
 303     #include <linux/input.h>
 304     #include <linux/joystick.h>
 305   ],[
 306     struct js_event js;
 307     js.type = JS_EVENT_AXIS;
 308   ])
 309 ], [
 310   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 311 ], [
 312   HAVE_LINUX_JOYSTICK_HEADERS="no"
 313 ])
 314 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 315
 316 dnl *** set variables based on configure arguments ***
 317
 318 dnl set license and copyright notice
 319 GST_LICENSE="LGPL"
 320 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 321 AC_SUBST(GST_LICENSE)
 322
 323 dnl set location of plugin directory
 324 AG_GST_SET_PLUGINDIR
 325
 326 dnl define an ERROR_CFLAGS Makefile variable
 327 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 328 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 329     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 330     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 331     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 332     -Wno-multichar -Wnested-externs ])
 333
 334 dnl define an ERROR_CXXFLAGS Makefile variable
 335 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 336     -Wmissing-declarations -Wredundant-decls -Wundef
 337     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 338     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 339     -Wno-multichar])
 340
 341 dnl define correct level for debugging messages
 342 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 343
 344 dnl used in examples
 345 AG_GST_DEFAULT_ELEMENTS
 346
 347 dnl behaviour of speex based audio resampler
 348 AC_MSG_CHECKING(which audio resample format to use for integer)
 349 AC_ARG_WITH([audioresample_format],
 350         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 351         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 352 AC_MSG_RESULT($ac_cv_audioresample_format)
 353 case $ac_cv_audioresample_format in
 354   int)
 355     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 356     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 357   ;;
 358   float)
 359     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 360     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 361   ;;
 362   auto)
 363     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 364     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 365 esac
 366
 367 dnl *** plug-ins to include ***
 368
 369 dnl these are all the gst plug-ins, compilable without additional libs
 370 AG_GST_CHECK_PLUGIN(adder)
 371 AG_GST_CHECK_PLUGIN(app)
 372 AG_GST_CHECK_PLUGIN(audioconvert)
 373 AG_GST_CHECK_PLUGIN(audiorate)
 374 AG_GST_CHECK_PLUGIN(audiotestsrc)
 375 AG_GST_CHECK_PLUGIN(ffmpegcolorspace)
 376 AG_GST_CHECK_PLUGIN(gdp)
 377 AG_GST_CHECK_PLUGIN(playback)
 378 AG_GST_CHECK_PLUGIN(audioresample)
 379 AG_GST_CHECK_PLUGIN(subparse)
 380 AG_GST_CHECK_PLUGIN(tcp)
 381 AG_GST_CHECK_PLUGIN(typefind)
 382 AG_GST_CHECK_PLUGIN(videotestsrc)
 383 AG_GST_CHECK_PLUGIN(videorate)
 384 AG_GST_CHECK_PLUGIN(videoscale)
 385 AG_GST_CHECK_PLUGIN(volume)
 386
 387 dnl check for gstreamer core features (subsystems)
 388 dnl FIXME: this assumes srcdir == builddir for uninstalled setups
 389 GST_CONFIGPATH=`$PKG_CONFIG --variable=includedir gstreamer-0.10`"/gst/gstconfig.h"
 390 AG_GST_PARSE_SUBSYSTEM_DISABLES($GST_CONFIGPATH)
 391 AM_CONDITIONAL(USE_XML, test $GST_DISABLE_XML != "1")
 392
 393 dnl disable plug-ins that require libxml2's HTML support if it is not available
 394 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 395   AG_GST_DISABLE_PLUGIN(subparse)
 396 fi
 397
 398 dnl disable plug-ins that require sys/socket.h if it is not available
 399 if test "x$HAVE_SYS_SOCKET_H" != "xyes"; then
 400   AG_GST_DISABLE_PLUGIN(tcp)
 401 fi
 402
 403 dnl iso-codes is optional, used by libgsttag
 404 AC_ARG_ENABLE(iso-codes,
 405 AC_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 406 [case "${enableval}" in
 407   yes) enable_iso_codes=yes ;;
 408   no)  enable_iso_codes=no ;;
 409   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 410 esac
 411 ],
 412 [enable_iso_codes=yes]) dnl Default value
 413
 414 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 415 if test "x$enable_iso_codes" = "xyes"; then
 416   AC_MSG_RESULT([yes])
 417   have_iso_codes=no
 418   AC_MSG_CHECKING([whether iso-codes are available on this system])
 419   if $PKG_CONFIG iso-codes; then
 420     AC_MSG_RESULT([yes])
 421     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 422     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 423       AC_MSG_RESULT([yes])
 424       AC_MSG_CHECKING([for iso-codes prefix])
 425       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 426       if test -d "$ISO_CODES_PREFIX"; then
 427         AC_MSG_RESULT([yes])
 428         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 429         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 430         ISO_639_DOMAIN="iso_639"
 431         AC_MSG_CHECKING([ISO_639_DOMAIN])
 432         AC_MSG_RESULT([$ISO_639_DOMAIN])
 433         have_iso_codes=yes
 434         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 435         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 436         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 437         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 438       else
 439         AC_MSG_RESULT([no])
 440       fi
 441     else
 442       AC_MSG_RESULT([no])
 443     fi
 444   else
 445     AC_MSG_RESULT([no])
 446   fi
 447   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 448 else
 449   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 450   AM_CONDITIONAL(USE_ISO_CODES, false)
 451 fi
 452
 453 dnl *** sys plug-ins ***
 454
 455 echo
 456 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 457 echo
 458
 459 dnl *** X11 ***
 460 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 461 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 462                   [ximagesink], [
 463   AC_PATH_XTRA
 464   ac_cflags_save="$CFLAGS"
 465   ac_cppflags_save="$CPPFLAGS"
 466   CFLAGS="$CFLAGS $X_CFLAGS"
 467   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 468
 469   dnl now try to find the HEADER
 470   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 471
 472   if test "x$HAVE_X" = "xno"
 473   then
 474     AC_MSG_NOTICE([cannot find X11 development files])
 475   else
 476     dnl this is much more than we want
 477     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 478     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 479     dnl it does not add the libs; therefore we add them here
 480     X_LIBS="$X_LIBS -lX11"
 481     AC_SUBST(X_CFLAGS)
 482     AC_SUBST(X_LIBS)
 483   fi
 484   AC_SUBST(HAVE_X)
 485   CFLAGS="$ac_cflags_save"
 486   CPPFLAGS="$ac_cppflags_save"
 487 ])
 488
 489 dnl Check for Xv extension
 490 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 491 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 492                   [xvimagesink], [
 493   AG_GST_CHECK_XV
 494 ])
 495
 496 dnl check for X Shm
 497 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 498 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 499   if test x$HAVE_X = xyes; then
 500     AC_CHECK_LIB(Xext, XShmAttach,
 501                  HAVE_XSHM="yes", HAVE_XSHM="no",
 502                  $X_LIBS)
 503     if test "x$HAVE_XSHM" = "xyes"; then
 504       XSHM_LIBS="-lXext"
 505     else
 506       dnl On AIX, it is in XextSam instead, but we still need -lXext
 507       AC_CHECK_LIB(XextSam, XShmAttach,
 508                    HAVE_XSHM="yes", HAVE_XSHM="no",
 509                    $X_LIBS)
 510       if test "x$HAVE_XSHM" = "xyes"; then
 511         XSHM_LIBS="-lXext -lXextSam"
 512       fi
 513     fi
 514   fi
 515 ], , [
 516   AC_SUBST(HAVE_XSHM)
 517   AC_SUBST(XSHM_LIBS)
 518 ])
 519
 520 dnl v4l/v4l2 checks have been moved down because they require X
 521
 522 dnl *** Video 4 Linux ***
 523 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 524 dnl renamed to GST_V4L in accordance with V4L2 below
 525 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 526 AG_GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], video4linux, [
 527   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 528 #include <sys/types.h>
 529 #define _LINUX_TIME_H
 530 #define __user
 531 #include <linux/videodev.h>
 532   ])
 533
 534   dnl we can build v4l without Xv, but then we won't have XOverlay support
 535   if test "x$HAVE_GST_V4L" = "xyes" -a "x$HAVE_XVIDEO" != "xyes"
 536   then
 537     AC_MSG_NOTICE([NO XVIDEO FOUND, VIDEO4LINUX WILL BE BUILT])
 538     AC_MSG_NOTICE([WITHOUT XOVERLAY SUPPORT])
 539   fi
 540 ])
 541
 542 # Optional gudev for device probing
 543 AC_ARG_WITH([gudev],
 544   AC_HELP_STRING([--with-gudev],
 545     [device detection with gudev]),
 546   [],
 547   [with_gudev=check])
 548 if test x$HAVE_GST_V4L = xyes; then
 549   if test x$with_gudev != xno; then
 550       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 551           [ have_gudev=yes
 552             AC_DEFINE(HAVE_GUDEV, 1,
 553                [Whether gudev is available for device detection])
 554             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 555           ], [
 556           have_gudev=no
 557           ])
 558   else
 559     have_gudev=no
 560   fi
 561 fi
 562 AC_SUBST(GUDEV_CFLAGS)
 563 AC_SUBST(GUDEV_LIBS)
 564
 565 dnl *** ext plug-ins ***
 566 dnl keep this list sorted alphabetically !
 567
 568 if test "x$BUILD_EXTERNAL" = "xyes"; then
 569
 570 echo
 571 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 572 echo
 573
 574 dnl *** alsa ***
 575 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 576 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 577   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 578     HAVE_ALSA="yes"
 579     AC_SUBST(ALSA_CFLAGS)
 580     AC_SUBST(ALSA_LIBS)
 581   ], [
 582     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 583   ])
 584 ])
 585
 586 dnl *** CDParanoia ***
 587 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 588 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 589 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 590   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 591     HAVE_CDPARANOIA="yes"
 592   ], [
 593     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 594                         cdda_open, -lm,
 595                         cdda_interface.h,
 596                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 597                         HEADER_DIR="no"
 598                         FOUND_CDPARANOIA="yes")
 599     if test "x$FOUND_CDPARANOIA" != "xyes";
 600     then
 601       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 602                           cdda_open, -lm,
 603                           cdda/cdda_interface.h,
 604                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 605                           HEADER_DIR="yes"
 606                           FOUND_CDPARANOIA="yes")
 607     fi
 608     if test "x$HEADER_DIR" = "xyes";
 609     then
 610       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 611                          defined if cdda headers are in a cdda/ directory)
 612     fi
 613     if test "x$FOUND_CDPARANOIA" = "xyes";
 614     then
 615       AC_CHECK_LIB(cdda_paranoia,
 616                    paranoia_cachemodel_size,
 617                    : ,
 618                    HAVE_CDPARANOIA=no,
 619                  [-lcdda_interface])
 620     fi
 621
 622     AC_SUBST(CDPARANOIA_LIBS)
 623   ])
 624 ])
 625 dnl FIXME : add second check somehow if that is necessary
 626 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 627 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 628
 629 dnl *** GNOME VFS ***
 630 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 631 AG_GST_CHECK_FEATURE(GNOME_VFS, [GNOME VFS], gnomevfs, [
 632   PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0, [
 633       HAVE_GNOME_VFS="yes"
 634       AC_SUBST(GNOME_VFS_CFLAGS)
 635       AC_SUBST(GNOME_VFS_LIBS)
 636       GNOME_VFS_MODULES_DIR="`$PKG_CONFIG --variable=modulesdir gnome-vfs-2.0`"
 637       AC_DEFINE_UNQUOTED(GNOME_VFS_MODULES_DIR, "$GNOME_VFS_MODULES_DIR",
 638              [The GnomeVFS modules directory.])
 639     ],[
 640       HAVE_GNOME_VFS="no"
 641     ]
 642     )
 643 ])
 644
 645 dnl *** ivorbis ***
 646 dnl AM_PATH_IVORBIS only takes two options
 647 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 648 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 649   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 650   if test $HAVE_IVORBIS = no
 651   then
 652     IVORBIS_LIBS=
 653     IVORBIS_CFLAGS=
 654     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 655       [IVORBIS_LIBS=-lvorbisidec
 656       HAVE_IVORBIS=yes
 657       case $host in
 658       arm-*-*)
 659         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 660       esac
 661       ],
 662       HAVE_IVORBIS=no)
 663     AC_SUBST(IVORBIS_LIBS)
 664     AC_SUBST(IVORBIS_CFLAGS)
 665   fi
 666 ])
 667
 668 dnl *** libgio ***
 669 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO, true)
 670 AG_GST_CHECK_FEATURE(GIO, [GIO library], gio, [
 671   PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.16, [
 672     HAVE_GIO="yes"
 673     GIO_MODULE_DIR="`$PKG_CONFIG --variable=giomoduledir gio-2.0`"
 674     AC_DEFINE_UNQUOTED(GIO_MODULE_DIR, "$GIO_MODULE_DIR",
 675            [The GIO modules directory.])
 676     GIO_LIBDIR="`$PKG_CONFIG --variable=libdir gio-2.0`"
 677     AC_DEFINE_UNQUOTED(GIO_LIBDIR, "$GIO_LIBDIR",
 678            [The GIO library directory.])
 679   ], [
 680     HAVE_GIO="no"
 681     AC_MSG_RESULT(no)
 682   ])
 683   AC_SUBST(GIO_CFLAGS)
 684   AC_SUBST(GIO_LIBS)
 685   AC_SUBST(GIO_LDFLAGS)
 686 ])
 687
 688 dnl *** libvisual ***
 689 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 690 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 691   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 692   if test $HAVE_LIBVISUAL = no
 693   then
 694     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 695     if test x$HAVE_LIBVISUAL = xyes; then
 696       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 697     fi
 698   else
 699     if test x$HAVE_LIBVISUAL = xyes; then
 700       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 701     fi
 702   fi
 703   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 704   if test x$LIBVIS_PLUGINSDIR != x; then
 705     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 706         "$LIBVIS_PLUGINSDIR",
 707         [directory in which the detected libvisual's plugins are located])
 708   fi
 709 ])
 710
 711 dnl *** ogg ***
 712 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 713 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 714   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 715   if test $HAVE_OGG = no
 716   then
 717     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 718     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 719   fi
 720 ])
 721
 722 dnl *** pango ***
 723 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 724 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 725   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.16.0  pangocairo >= 1.16.0)
 726 ])
 727
 728 dnl *** theora ***
 729 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 730 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 731   dnl theora uses pkg-config version incorrectly, for pkg-config:
 732   dnl 1.0 < 1.0RCX < 1.0alphaX < 1.0betaX < 1.0.0
 733   dnl theoraenc and theoradec appeared in 1.0beta3
 734
 735   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec theoraenc)
 736 ])
 737
 738 dnl *** vorbis ***
 739 dnl AM_PATH_VORBIS only takes two options
 740 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 741 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 742   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 743   if test $HAVE_VORBIS = no
 744   then
 745     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 746     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 747   fi
 748 ])
 749
 750 if test "x$HAVE_VORBIS" = "xyes"; then
 751   ac_cflags_save="$CFLAGS"
 752   AC_COMPILE_IFELSE(
 753     AC_LANG_PROGRAM([
 754 #include <vorbis/codec.h>
 755                      ],[
 756 vorbis_dsp_state *v;
 757
 758 vorbis_synthesis_restart (v);
 759                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 760   if test "x$HAVE_VSR" = "xyes"; then
 761     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 762                        [defined if vorbis_synthesis_restart is present])
 763   fi
 764   CFLAGS="$ac_cflags_save"
 765 fi
 766
 767 else
 768
 769 dnl not building plugins with external dependencies,
 770 dnl but we still need to set the conditionals
 771 AM_CONDITIONAL(USE_ALSA, false)
 772 AM_CONDITIONAL(USE_CDPARANOIA, false)
 773 AM_CONDITIONAL(USE_GNOME_VFS, false)
 774 AM_CONDITIONAL(USE_GIO, false)
 775 AM_CONDITIONAL(USE_LIBVISUAL, false)
 776 AM_CONDITIONAL(USE_OGG, false)
 777 AM_CONDITIONAL(USE_PANGO, false)
 778 AM_CONDITIONAL(USE_THEORA, false)
 779 AM_CONDITIONAL(USE_VORBIS, false)
 780
 781 fi dnl of EXT plugins
 782
 783 dnl seeking needs freetype, so check for it here
 784 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 785   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 786 ])
 787 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 788 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 789 AC_SUBST(FT2_CFLAGS)
 790 AC_SUBST(FT2_LIBS)
 791
 792 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 793
 794 dnl Overview:
 795 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 796 dnl GST_*:              flags shared by built objects to link against GStreamer
 797 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 798 dnl                          (compare to other modules) or for i18n
 799 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 800 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 801 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 802 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 803
 804 dnl GST_OPTION_CFLAGS
 805 if test "x$USE_DEBUG" = xyes; then
 806    PROFILE_CFLAGS="-g"
 807 fi
 808 AC_SUBST(PROFILE_CFLAGS)
 809
 810 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 811   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 812   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 813 else
 814   DEPRECATED_CFLAGS=""
 815 fi
 816 AC_SUBST(DEPRECATED_CFLAGS)
 817
 818 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 819 dnl at make time with e.g. make ERROR_CFLAGS=""
 820 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 821 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 822 AC_SUBST(GST_OPTION_CFLAGS)
 823 AC_SUBST(GST_OPTION_CXXFLAGS)
 824
 825 dnl our libraries need to be versioned correctly
 826 AC_SUBST(GST_LT_LDFLAGS)
 827
 828 dnl GST_PLUGINS_BASE_CFLAGS
 829 dnl prefer internal headers to already installed ones
 830 dnl also add builddir include for enumtypes and marshal
 831 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 832 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 833
 834 dnl FIXME: do we want to rename to GST_ALL_* ?
 835 dnl add GST_OPTION_CFLAGS, but overridable
 836 GST_CXXFLAGS="$GST_CFLAGS \$(GST_OPTION_CXXFLAGS)"
 837 GST_CFLAGS="$GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 838 AC_SUBST(GST_CFLAGS)
 839 AC_SUBST(GST_CXXFLAGS)
 840 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 841 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 842 AC_SUBST(GST_LIBS)
 843
 844 dnl LDFLAGS really should only contain flags, not libs - they get added before
 845 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 846 GST_ALL_LDFLAGS="-no-undefined"
 847 AC_SUBST(GST_ALL_LDFLAGS)
 848
 849 dnl GST_LIB_LDFLAGS
 850 dnl linker flags shared by all libraries
 851 dnl LDFLAGS modifier defining exported symbols from built libraries
 852 dnl (export _gst_foo but not __gst_foo)
 853 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 854 AC_SUBST(GST_LIB_LDFLAGS)
 855
 856 dnl this really should only contain flags, not libs - they get added before
 857 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 858 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 859 AC_SUBST(GST_PLUGIN_LDFLAGS)
 860
 861 dnl *** output files ***
 862
 863 AC_CONFIG_FILES(
 864 Makefile
 865 gst-plugins-base.spec
 866 gst/Makefile
 867 gst/adder/Makefile
 868 gst/app/Makefile
 869 gst/audioconvert/Makefile
 870 gst/audiorate/Makefile
 871 gst/audiotestsrc/Makefile
 872 gst/ffmpegcolorspace/Makefile
 873 gst/gdp/Makefile
 874 gst/playback/Makefile
 875 gst/audioresample/Makefile
 876 gst/subparse/Makefile
 877 gst/tcp/Makefile
 878 gst/typefind/Makefile
 879 gst/videotestsrc/Makefile
 880 gst/videorate/Makefile
 881 gst/videoscale/Makefile
 882 gst/volume/Makefile
 883 sys/Makefile
 884 sys/ximage/Makefile
 885 sys/xvimage/Makefile
 886 sys/v4l/Makefile
 887 ext/Makefile
 888 ext/alsa/Makefile
 889 ext/cdparanoia/Makefile
 890 ext/gnomevfs/Makefile
 891 ext/gio/Makefile
 892 ext/libvisual/Makefile
 893 ext/ogg/Makefile
 894 ext/pango/Makefile
 895 ext/theora/Makefile
 896 ext/vorbis/Makefile
 897 gst-libs/Makefile
 898 gst-libs/gst/Makefile
 899 gst-libs/gst/audio/Makefile
 900 gst-libs/gst/app/Makefile
 901 gst-libs/gst/cdda/Makefile
 902 gst-libs/gst/fft/Makefile
 903 gst-libs/gst/floatcast/Makefile
 904 gst-libs/gst/interfaces/Makefile
 905 gst-libs/gst/netbuffer/Makefile
 906 gst-libs/gst/riff/Makefile
 907 gst-libs/gst/rtp/Makefile
 908 gst-libs/gst/rtsp/Makefile
 909 gst-libs/gst/sdp/Makefile
 910 gst-libs/gst/tag/Makefile
 911 gst-libs/gst/pbutils/Makefile
 912 gst-libs/gst/video/Makefile
 913 tools/Makefile
 914 pkgconfig/Makefile
 915 pkgconfig/gstreamer-audio.pc
 916 pkgconfig/gstreamer-audio-uninstalled.pc
 917 pkgconfig/gstreamer-app.pc
 918 pkgconfig/gstreamer-app-uninstalled.pc
 919 pkgconfig/gstreamer-cdda.pc
 920 pkgconfig/gstreamer-cdda-uninstalled.pc
 921 pkgconfig/gstreamer-fft.pc
 922 pkgconfig/gstreamer-fft-uninstalled.pc
 923 pkgconfig/gstreamer-floatcast.pc
 924 pkgconfig/gstreamer-floatcast-uninstalled.pc
 925 pkgconfig/gstreamer-interfaces.pc
 926 pkgconfig/gstreamer-interfaces-uninstalled.pc
 927 pkgconfig/gstreamer-netbuffer.pc
 928 pkgconfig/gstreamer-netbuffer-uninstalled.pc
 929 pkgconfig/gstreamer-pbutils.pc
 930 pkgconfig/gstreamer-pbutils-uninstalled.pc
 931 pkgconfig/gstreamer-riff.pc
 932 pkgconfig/gstreamer-riff-uninstalled.pc
 933 pkgconfig/gstreamer-rtp.pc
 934 pkgconfig/gstreamer-rtp-uninstalled.pc
 935 pkgconfig/gstreamer-rtsp.pc
 936 pkgconfig/gstreamer-rtsp-uninstalled.pc
 937 pkgconfig/gstreamer-sdp.pc
 938 pkgconfig/gstreamer-sdp-uninstalled.pc
 939 pkgconfig/gstreamer-tag.pc
 940 pkgconfig/gstreamer-tag-uninstalled.pc
 941 pkgconfig/gstreamer-video.pc
 942 pkgconfig/gstreamer-video-uninstalled.pc
 943 pkgconfig/gstreamer-plugins-base.pc
 944 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 945 tests/Makefile
 946 tests/check/Makefile
 947 tests/examples/Makefile
 948 tests/examples/app/Makefile
 949 tests/examples/dynamic/Makefile
 950 tests/examples/overlay/Makefile
 951 tests/examples/seek/Makefile
 952 tests/examples/volume/Makefile
 953 tests/examples/snapshot/Makefile
 954 tests/examples/gio/Makefile
 955 tests/examples/v4l/Makefile
 956 tests/files/Makefile
 957 tests/icles/Makefile
 958 docs/Makefile
 959 docs/design/Makefile
 960 docs/libs/Makefile
 961 docs/plugins/Makefile
 962 docs/version.entities
 963 po/Makefile.in
 964 common/Makefile
 965 common/m4/Makefile
 966 m4/Makefile
 967 )
 968
 969 dnl Create the config.h file for Visual Studio builds
 970 dnl Beware of spaces and /'s in some of the shell variable contents.
 971 sed \
 972     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 973     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 974     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 975     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 976     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 977     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 978     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 979     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 980     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 981     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 982     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 983     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 984     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 985     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 986     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 987     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 988     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 989     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 990     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 991     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 992     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 993     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 994     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
 995     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
 996     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 997     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 998     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 999     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1000     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1001     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1002     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1003     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1004     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
1005     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1006     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1007     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directaudiosink\"/" \
1008     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
1009     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1010     config.h.in >win32/common/config.h-new
1011
1012
1013
1014 AC_OUTPUT
1015
1016 AG_GST_OUTPUT_PLUGINS
1017 ORC_OUTPUT
1018