configure.ac

   1 AC_PREREQ(2.69)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 AC_INIT(GStreamer libav, 1.7.0.1,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gst-libav)
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([ext/libav/gstav.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output by default
  34 AM_SILENT_RULES([yes])
  35
  36 dnl our libraries and install dirs use major.minor as a version
  37 GST_API_VERSION=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  38 dnl we override it here if we need to for the release candidate of new series
  39 GST_API_VERSION=1.0
  40 AC_SUBST(GST_API_VERSION)
  41
  42 AG_GST_LIBTOOL_PREPARE
  43 AS_LIBTOOL(GST, 700, 0, 700)
  44
  45 dnl *** required versions of GStreamer stuff ***
  46 GST_REQ=1.7.0.1
  47 GST_PBREQ=1.7.0.1
  48
  49 ORC_REQ=0.4.16
  50 ORC_CHECK([$ORC_REQ])
  51
  52 dnl *** autotools stuff ****
  53
  54 dnl allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 dnl Add parameters for aclocal
  58 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  59
  60 dnl *** check for arguments to configure ***
  61
  62 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  63 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  64
  65 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  66 AG_GST_ARG_WITH_PACKAGE_NAME
  67 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  68 AG_GST_ARG_VALGRIND
  69 AG_GST_ARG_GCOV
  70
  71 dnl *** checks for platform ***
  72
  73 dnl * hardware/architecture *
  74
  75 dnl common/m4/gst-arch.m4
  76 dnl check CPU type
  77 AG_GST_ARCH
  78
  79 dnl *** checks for programs ***
  80
  81 dnl find a compiler
  82 AC_PROG_CC
  83 AC_PROG_CC_STDC
  84
  85 dnl check if the compiler supports '-c' and '-o' options
  86 AM_PROG_CC_C_O
  87
  88 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
  89 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
  90
  91 dnl check for documentation tools
  92 GTK_DOC_CHECK([1.12])
  93 AG_GST_PLUGIN_DOCS([1.12])
  94
  95 dnl *** checks for libraries ***
  96
  97 dnl check for libm, for sin()
  98 LT_LIB_M
  99 AC_SUBST(LIBM)
 100
 101 dnl *** checks for header files ***
 102
 103 dnl check if we have ANSI C header files
 104 AC_HEADER_STDC
 105
 106 dnl *** checks for types/defines ***
 107
 108 dnl *** checks for structures ***
 109
 110 dnl *** checks for compiler characteristics ***
 111
 112 dnl *** checks for library functions ***
 113
 114 dnl *** checks for dependancy libraries ***
 115
 116 dnl GLib is required
 117 GLIB_REQ=2.40.0
 118 AC_SUBST([GLIB_REQ])
 119 AG_GST_GLIB_CHECK([$GLIB_REQ])
 120
 121 dnl checks for gstreamer
 122 dnl uninstalled is selected preferentially -- see pkg-config(1)
 123 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ])
 124 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ])
 125 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GST_PBREQ])
 126 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 127 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 128
 129 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 130 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 131
 132 dnl *** set variables based on configure arguments ***
 133
 134 dnl set location of plugin directory
 135 AG_GST_SET_PLUGINDIR
 136
 137 dnl build static plugins or not
 138 AC_MSG_CHECKING([whether to build static plugins or not])
 139 AC_ARG_ENABLE(
 140   static-plugins,
 141   AC_HELP_STRING(
 142     [--enable-static-plugins],
 143     [build static plugins @<:@default=no@:>@]),
 144   [AS_CASE(
 145     [$enableval], [no], [], [yes], [],
 146     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 147   [enable_static_plugins=no])
 148 AC_MSG_RESULT([$enable_static_plugins])
 149 if test "x$enable_static_plugins" = xyes; then
 150   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 151     [Define if static plugins should be built])
 152   GST_PLUGIN_LIBTOOLFLAGS=""
 153 else
 154   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 155 fi
 156 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 157 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 158
 159 dnl define an ERROR_CFLAGS Makefile variable
 160 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 161     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 162     -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition
 163     -Winit-self -Wmissing-include-dirs -Waddress
 164     -Waggregate-return -Wno-multichar -Wnested-externs ])
 165
 166 dnl define correct level for debugging messages
 167 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 168
 169 dnl *** finalize CFLAGS, LDFLAGS, LIBS ***
 170
 171 dnl Overview:
 172 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 173 dnl GST_*:              flags shared by built objects to link against GStreamer
 174 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 175 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 176 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 177 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 178
 179 dnl GST_OPTION_CFLAGS
 180 if test "x$USE_DEBUG" = xyes; then
 181    PROFILE_CFLAGS="-g"
 182 fi
 183 AC_SUBST(PROFILE_CFLAGS)
 184
 185 if test "x$GST_GIT" = "xyes"; then
 186   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 187 else
 188   DEPRECATED_CFLAGS=""
 189 fi
 190 AC_SUBST(DEPRECATED_CFLAGS)
 191
 192 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 193 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 194
 195 AC_SUBST(GST_OPTION_CFLAGS)
 196
 197 dnl FIXME: do we want to rename to GST_ALL_* ?
 198 dnl prefer internal headers to already installed ones
 199 dnl also add builddir include for enumtypes and marshal
 200 dnl add GST_OPTION_CFLAGS, but overridable
 201 GST_CFLAGS="$GST_CFLAGS"
 202 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 203 AC_SUBST(GST_CFLAGS)
 204 AC_SUBST(GST_LIBS)
 205
 206 GST_ALL_LDFLAGS="-no-undefined"
 207 AC_SUBST(GST_ALL_LDFLAGS)
 208
 209 dnl this really should only contain flags, not libs - they get added before
 210 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 211 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 212 AC_SUBST(GST_PLUGIN_LDFLAGS)
 213
 214 dnl Add MacOSX specific flags
 215 AC_CANONICAL_HOST
 216 case $host_os in
 217      darwin*)
 218         DARWIN_LDFLAGS="-Wl,-read_only_relocs,suppress"
 219         ;;
 220      *)
 221         DARWIN_LDFLAGS=""
 222         ;;
 223 esac
 224 AC_SUBST(DARWIN_LDFLAGS)
 225
 226 dnl *** Check for bz2
 227 save_LIBS=$LIBS
 228 LIBS="$LIBS -lbz2"
 229 AC_MSG_CHECKING([for BZ2_bzlibVersion in -lbz2])
 230 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <bzlib.h>]], [[const char *version = BZ2_bzlibVersion ();]])],[HAVE_BZ2=yes],[HAVE_BZ2=no])
 231 AC_MSG_RESULT($HAVE_BZ2)
 232 LIBS=$save_LIBS
 233 AM_CONDITIONAL(HAVE_BZ2, test "x$HAVE_BZ2" = "xyes")
 234 if test "x$HAVE_BZ2" = "xno"; then
 235   AC_WARN([libbz2 not found, matroska demuxer will not be able to read bz2 tracks])
 236 fi
 237
 238 dnl *** Check for lzma
 239 save_LIBS=$LIBS
 240 LIBS="$LIBS -llzma"
 241 AC_MSG_CHECKING([for lzma_version_string in -llzma])
 242 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <lzma.h>]], [[const char *version = lzma_version_string ();]])],[HAVE_LZMA=yes],[HAVE_LZMA=no])
 243 AC_MSG_RESULT($HAVE_LZMA)
 244 LIBS=$save_LIBS
 245 AM_CONDITIONAL(HAVE_LZMA, test "x$HAVE_LZMA" = "xyes")
 246 if test "x$HAVE_LZMA" = "xno"; then
 247     AC_WARN([lzma not found, tiff reader will not be able to read lzma files])
 248 fi
 249
 250 AC_ARG_ENABLE(gpl,
 251               [AC_HELP_STRING([--enable-gpl], [build a GPL licensed gst-libav])])
 252 AM_CONDITIONAL(GST_LIBAV_ENABLE_GPL, test "x$enable_gpl" = "xyes")
 253 if test "x$enable_gpl" = "xyes"; then
 254   AC_DEFINE([GST_LIBAV_ENABLE_GPL], [], [Defined if building a GPL-licensed version of gst-libav])
 255 fi
 256
 257 dnl *** configure external libs ***
 258
 259 HAVE_LIBAV_UNINSTALLED=1
 260
 261 AC_ARG_WITH(system-libav,
 262             [AC_HELP_STRING([--with-system-libav], [use system Libav libraries])])
 263
 264 if test "x$with_system_libav" = "xyes"; then
 265   PKG_CHECK_MODULES(LIBAV, libavformat libavcodec libavutil)
 266   PKG_CHECK_MODULES(SWSCALE, libswscale libavutil)
 267   saved_CPPFLAGS="$CPPFLAGS"
 268   CPPFLAGS="$CPPFLAGS $LIBAV_CFLAGS"
 269   AC_CHECK_HEADERS([avi.h])
 270   CPPFLAGS="$saved_CPPFLAGS"
 271   AC_DEFINE([LIBAV_SOURCE], ["system install"], [Describes where the Libav libraries come from.])
 272   HAVE_LIBAV_UNINSTALLED=0
 273   AC_MSG_NOTICE([Using system-installed libav code])
 274   AC_MSG_CHECKING([whether libav is provided by FFmpeg])
 275   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 276     #include <libavcodec/avcodec.h>
 277     ]],[[
 278         #if LIBAVCODEC_VERSION_MICRO >= 100
 279         /* FFmpeg uses 100+ as its micro version */
 280         #else
 281         #error libav provider should be FFmpeg
 282         #endif
 283     ]])], [is_ffmpeg=yes], [is_ffmpeg=no])
 284   AC_MSG_RESULT([$is_ffmpeg])
 285   if test "$is_ffmpeg" = no; then
 286     AC_MSG_ERROR([Uncompatible libavcodec found])
 287   fi
 288 else
 289   AC_MSG_NOTICE([Using local Libav snapshot])
 290
 291   dnl libgstlibav.la: include dirs
 292   LIBAV_CFLAGS="-I \$(top_srcdir)/gst-libs/ext/libav \
 293                 -I \$(top_builddir)/gst-libs/ext/libav \
 294                  -Wno-deprecated-declarations"
 295
 296   LIBAV_DEPS="\$(top_builddir)/gst-libs/ext/libav/libavformat/libavformat.a \
 297               \$(top_builddir)/gst-libs/ext/libav/libavcodec/libavcodec.a \
 298               \$(top_builddir)/gst-libs/ext/libav/libswresample/libswresample.a \
 299               \$(top_builddir)/gst-libs/ext/libav/libavutil/libavutil.a"
 300   if test "x$enable_static_plugins" = xyes; then
 301       dnl with static linking we can't use the .a archive directly as they would
 302       dnl be included in the final libgstlibav.a as a file and won't be usable.
 303       dnl libav*.a must be copied to the final destination too
 304       LIBAV_LIBS="-lavformat -lavcodec -lswresample -lavutil"
 305   else
 306       dnl libgstlibav.la: libs to statically link to
 307       LIBAV_LIBS="$LIBAV_DEPS"
 308   fi
 309
 310   dnl
 311   SWSCALE_CFLAGS="-I \$(top_srcdir)/gst-libs/ext/libav \
 312                   -I \$(top_builddir)/gst-libs/ext/libav \
 313                   -Wno-deprecated-declarations"
 314
 315   SWSCALE_DEPS="\$(top_builddir)/gst-libs/ext/libav/libswscale/libswscale.a \
 316                 \$(top_builddir)/gst-libs/ext/libav/libavutil/libavutil.a"
 317   if test "x$enable_static_plugins" = xyes; then
 318       dnl with static linking we can't use the .a archive directly as they would
 319       dnl be included in the final libgstswscale.a as a file and won't be usable.
 320       dnl libav*.a must be copied to the final destination too
 321       SWSCALE_LIBS="-lswscale -lavutil"
 322   else
 323       dnl libgstswscale.la: libs to statically link to
 324       SWSCALE_LIBS="$SWSCALE_DEPS"
 325   fi
 326
 327   LIBAV_SUBDIRS=gst-libs
 328   AC_DEFINE(HAVE_AVI_H)
 329   AC_DEFINE([LIBAV_SOURCE], ["local snapshot"], [Describes where the Libav libraries come from.])
 330
 331   AC_ARG_WITH(libav-extra-configure,
 332       AC_HELP_STRING([--with-libav-extra-configure="xxx"],
 333       [extra configure options for internal libav ./configure script]),,
 334       with_libav=no)
 335
 336   # basic arguments
 337   emblibav_configure_args="--prefix=$prefix"
 338
 339   # Enable pic and static so that we get .a files, but with PIC code.
 340   emblibav_configure_args="$emblibav_configure_args \
 341         --enable-static --enable-pic \
 342         --disable-avdevice --disable-postproc --disable-avfilter \
 343         --disable-programs --disable-ffserver --disable-ffplay --disable-ffprobe --disable-ffmpeg \
 344         --disable-encoder=flac --disable-protocols --disable-devices \
 345         --disable-network --disable-hwaccels --disable-dxva2 --disable-vdpau \
 346         --disable-filters --disable-doc --disable-vda --disable-d3d11va --disable-dxva2 \
 347         --disable-iconv --enable-optimizations"
 348
 349   if test "x$enable_gpl" == "xyes"; then
 350     emblibav_configure_args="$emblibav_configure_args --enable-gpl"
 351   fi
 352
 353   # if we are cross-compiling, tell libav so
 354   case $host in
 355       *android*)
 356         target_os=linux
 357       ;;
 358       *darwin*)
 359         target_os=darwin
 360       ;;
 361       *)
 362         target_os=`echo $host_os | sed 's/-gnu//'`
 363       ;;
 364   esac
 365
 366   if test "x$cross_compiling" = xyes; then
 367     emblibav_configure_args="$emblibav_configure_args --enable-cross-compile \
 368         --target-os=$target_os --arch=$host_cpu --cross-prefix=$host_alias-"
 369   fi
 370
 371   case $host_os in
 372     mingw32*)
 373       emblibav_configure_args="$emblibav_configure_args --enable-memalign-hack"
 374       WIN32_LIBS="-lws2_32"
 375       ;;
 376     *)
 377       WIN32_LIBS=
 378       ;;
 379   esac
 380
 381   if test x"$AR" != x; then
 382     emblibav_configure_args="$emblibav_configure_args --ar=\\\"\\\$AR\\\""
 383   fi
 384
 385   if test x"$AS" != x; then
 386     emblibav_configure_args="$emblibav_configure_args --as=\\\"\\\$CC\\\""
 387   fi
 388
 389   if test x"$CC" != x; then
 390     emblibav_configure_args="$emblibav_configure_args --cc=\\\"\\\$CC\\\""
 391   fi
 392
 393   if test x"$LD" != x; then
 394     emblibav_configure_args="$emblibav_configure_args --ld=\\\"\\\$CC\\\""
 395   fi
 396
 397   if test x"$NM" != x; then
 398     emblibav_configure_args="$emblibav_configure_args --nm=\\\"\\\$NM\\\""
 399   fi
 400
 401   dnl checks for extra enable/disable flags
 402   LIBAV_OPTS=`cd $srcdir/gst-libs/ext/libav && ./configure --help`
 403   # Let's check if we can disable the building of the libav binary
 404   can_disable=`echo "$LIBAV_OPTS" | grep 'disable-ffmpeg'`
 405   if test "$can_disable" != ""; then
 406     emblibav_configure_args="$emblibav_configure_args --disable-ffmpeg"
 407   fi
 408   dnl check if libswscale needs enabling explicitly
 409   can_enable=`echo "$LIBAV_OPTS" | grep 'enable-swscale'`
 410   if test "$can_enable" != ""; then
 411     emblibav_configure_args="$emblibav_configure_args --enable-swscale"
 412   fi
 413
 414   # append extra configure options to emblibav_configure_args if needed
 415   if test "x$with_libav_extra_configure" != "xno"; then
 416     emblibav_configure_args="$emblibav_configure_args $with_libav_extra_configure"
 417   fi
 418
 419   AC_SUBST(LIBAV_CO_DIR)
 420   AC_SUBST(LIBAV_SVN)
 421   AC_SUBST(LIBAV_REVISION)
 422   AC_SUBST(LIBAV_EXTERNALS_REVISION)
 423   AC_CONFIG_COMMANDS([configure-embedded-libav],
 424     [echo "Configuring included Libav instance with args $emblibav_configure_args"
 425      origdir=`pwd`
 426      dnl Don't put path on the configure call when not needed, as FFmpeg's configure relies on it
 427      dnl to detect out-of-tree builds
 428      if test -z "$srcdir" -o "$srcdir" = .; then
 429        confcmd=./configure
 430      else
 431        confcmd="$ac_abs_top_srcdir"/gst-libs/ext/libav/configure
 432      fi
 433
 434      AS_MKDIR_P(["$ac_top_build_prefix"gst-libs/ext/libav])
 435      cd "$ac_top_build_prefix"gst-libs/ext/libav &&
 436          eval "$confcmd $emblibav_configure_args" ||
 437          AC_MSG_ERROR([Failed to configure embedded Libav tree])
 438      cd "$origdir"
 439     ],
 440     [emblibav_configure_args="$emblibav_configure_args"])
 441   AC_MSG_NOTICE([Using included Libav code])
 442 fi
 443
 444 AC_SUBST(LIBAV_CFLAGS)
 445 AC_SUBST(LIBAV_DEPS)
 446 AC_SUBST(LIBAV_LIBS)
 447 AC_SUBST(LIBAV_SUBDIRS)
 448 AC_SUBST(SWSCALE_CFLAGS)
 449 AC_SUBST(SWSCALE_DEPS)
 450 AC_SUBST(SWSCALE_LIBS)
 451 AC_SUBST(WIN32_LIBS)
 452
 453 if test x$HAVE_LIBAV_UNINSTALLED = x1; then
 454   AC_DEFINE(HAVE_LIBAV_UNINSTALLED, [], [Defined if building against uninstalled Libav source])
 455 fi
 456 AM_CONDITIONAL(HAVE_LIBAV_UNINSTALLED, test x$HAVE_LIBAV_UNINSTALLED = x1)
 457
 458 AC_CONFIG_FILES(
 459 Makefile
 460 common/Makefile
 461 common/m4/Makefile
 462 gst-libav.spec
 463 ext/Makefile
 464 ext/libav/Makefile
 465 ext/libswscale/Makefile
 466 gst-libs/Makefile
 467 gst-libs/ext/Makefile
 468 docs/Makefile
 469 docs/plugins/Makefile
 470 docs/version.entities
 471 tests/Makefile
 472 tests/check/Makefile
 473 tests/files/Makefile
 474 pkgconfig/Makefile
 475 pkgconfig/gstreamer-plugins-libav-uninstalled.pc
 476 )
 477 AC_OUTPUT
 478
 479 ORC_OUTPUT