configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.11.0.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.11
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 AG_GST_LIBTOOL_PREPARE
  47
  48 dnl FIXME: this macro doesn't actually work;
  49 dnl the generated libtool script has no support for the listed tags.
  50 dnl So this needs to be fixed first if we want to use this
  51 dnl AS_LIBTOOL_TAGS
  52
  53 AC_LIBTOOL_WIN32_DLL
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** required versions of GStreamer stuff ***
  57 GST_REQ=0.11.0
  58 GSTPB_REQ=0.11.0
  59
  60 dnl *** autotools stuff ****
  61
  62 dnl allow for different autotools
  63 AS_AUTOTOOLS_ALTERNATE
  64
  65 dnl Add parameters for aclocal
  66 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  67
  68 dnl set up gettext
  69 dnl the version check needs to stay here because autopoint greps for it
  70 AM_GNU_GETTEXT_VERSION([0.17])
  71 AM_GNU_GETTEXT([external])
  72 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  73
  74 dnl *** check for arguments to configure ***
  75
  76 AG_GST_ARG_DEBUG
  77 AG_GST_ARG_PROFILING
  78 AG_GST_ARG_VALGRIND
  79 AG_GST_ARG_GCOV
  80
  81 AG_GST_ARG_EXAMPLES
  82
  83 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  84 AG_GST_ARG_WITH_PACKAGE_NAME
  85 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  86
  87 AG_GST_ARG_WITH_PLUGINS
  88
  89 AG_GST_ARG_ENABLE_EXTERNAL
  90
  91 AG_GST_ARG_ENABLE_EXPERIMENTAL
  92
  93 dnl *** checks for platform ***
  94
  95 dnl * hardware/architecture *
  96
  97 dnl common/m4/gst-arch.m4
  98 dnl check CPU type
  99 AG_GST_ARCH
 100
 101 dnl Determine endianness
 102 AC_C_BIGENDIAN
 103
 104 dnl *** checks for programs ***
 105
 106 dnl find a compiler
 107 AC_PROG_CC
 108 AC_PROG_CC_STDC
 109
 110 dnl determine c++ compiler
 111 AC_PROG_CXX
 112 dnl determine if c++ is available on this system
 113 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 114
 115 dnl determine c++ preprocessor
 116 dnl FIXME: do we need this ?
 117 AC_PROG_CXXCPP
 118
 119 AS_PROG_OBJC
 120
 121 dnl check if the compiler supports '-c' and '-o' options
 122 AM_PROG_CC_C_O
 123
 124 dnl find an assembler
 125 AM_PROG_AS
 126
 127 dnl check if the compiler supports do while(0) macros
 128 AG_GST_CHECK_DOWHILE_MACROS
 129
 130 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 131 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 132
 133 dnl check for documentation tools
 134 GTK_DOC_CHECK([1.3])
 135 AS_PATH_PYTHON([2.1])
 136 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 137
 138 dnl *** checks for libraries ***
 139
 140 dnl check for libm, for sin()
 141 AC_CHECK_LIBM
 142 AC_SUBST(LIBM)
 143
 144 dnl *** checks for header files ***
 145
 146 dnl check if we have ANSI C header files
 147 AC_HEADER_STDC
 148
 149 dnl used by ext/wavpack
 150 AX_CREATE_STDINT_H
 151
 152 dnl used in gst/rtp/gstasteriskh263.c
 153 AC_CHECK_HEADERS([netinet/in.h])
 154 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 155 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 156
 157 dnl used in gst/udp
 158 AC_CHECK_HEADERS([sys/time.h])
 159
 160 dnl *** checks for types/defines ***
 161
 162 dnl Check for FIONREAD ioctl declaration.  This check is needed
 163 dnl for the UDP plugin to build on Solaris
 164 GST_CHECK_FIONREAD
 165
 166 dnl *** checks for structures ***
 167
 168 dnl *** checks for compiler characteristics ***
 169
 170 dnl check if we have GCC inline-asm
 171 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 172 if test x$HAVE_GCC_ASM = xyes ; then
 173   AC_DEFINE(HAVE_GCC_ASM, 1,
 174     [Define if compiler supports gcc inline assembly])
 175 fi
 176 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 177
 178 dnl *** checks for library functions ***
 179
 180 LIBS_SAVE=$LIBS
 181 LIBS="$LIBS $LIBM"
 182 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 183 LIBS=$LIBS_SAVE
 184
 185 dnl Check whether isinf() is defined by math.h
 186 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 187     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 188 if test "$ac_cv_have_isinf" = "yes"
 189 then
 190     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 191 fi
 192
 193 dnl Check for mmap (needed by electricfence plugin)
 194 AC_FUNC_MMAP
 195 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 196
 197 dnl Check for mmap (needed by electricfence plugin)
 198
 199 AC_CHECK_TYPE([struct ip_mreqn], [
 200               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 201               [#include <netinet/in.h>])
 202
 203 dnl *** checks for dependency libraries ***
 204
 205 dnl GLib is required
 206 AG_GST_GLIB_CHECK([2.20])
 207 PKG_CHECK_MODULES(GIO, [ gio-2.0 >= 2.20 ], , AC_MSG_ERROR([gio is required]))
 208
 209 dnl Orc
 210 ORC_CHECK([0.4.11])
 211
 212 dnl checks for gstreamer
 213 dnl uninstalled is selected preferentially -- see pkg-config(1)
 214 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 215 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 216 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 217 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 218 AG_GST_CHECK_GST_NET($GST_MAJORMINOR, [$GST_REQ], yes)
 219 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 220 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 221
 222 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 223 if test -z $GST_TOOLS_DIR; then
 224   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 225 fi
 226 AC_SUBST(GST_TOOLS_DIR)
 227
 228 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 229 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 230
 231 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 232
 233 dnl Check for documentation xrefs
 234 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 235 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 236 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 237 AC_SUBST(GLIB_PREFIX)
 238 AC_SUBST(GST_PREFIX)
 239 AC_SUBST(GSTPB_PREFIX)
 240
 241 dnl GTK is optional and used in examples
 242 HAVE_GTK=no
 243 GTK2_REQ=2.14.0
 244 GTK3_REQ=2.91.3
 245 if test "x$BUILD_EXAMPLES" = "xyes"; then
 246   AC_MSG_CHECKING([which gtk+ version to compile examples against (optional)])
 247   AC_ARG_WITH([gtk],
 248     AC_HELP_STRING([--with-gtk=3.0|2.0],
 249                    [which gtk+ version to compile against (default: 2.0)]),
 250     [case "$with_gtk" in
 251         2.0) GTK_REQ=$GTK2_REQ ;;
 252         3.0) GTK_REQ=$GTK3_REQ ;;
 253         *) AC_MSG_ERROR([invalid gtk+ version specified]);;
 254     esac],
 255     [with_gtk=2.0
 256      GTK_REQ=$GTK2_REQ])
 257   AC_MSG_RESULT([$with_gtk (>= $GTK_REQ)])
 258   PKG_CHECK_MODULES(GTK, gtk+-$with_gtk >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 259   dnl some examples need gtk+-x11
 260   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-$with_gtk >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 261   AC_SUBST(GTK_LIBS)
 262   AC_SUBST(GTK_CFLAGS)
 263 fi
 264 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 265 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 266
 267 dnl *** set variables based on configure arguments ***
 268
 269 dnl set license and copyright notice
 270 GST_LICENSE="LGPL"
 271 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 272 AC_SUBST(GST_LICENSE)
 273
 274 dnl set location of plugin directory
 275 AG_GST_SET_PLUGINDIR
 276
 277 dnl set release date/time
 278 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 279   ["${srcdir}/gst-plugins-good.doap"],
 280   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 281
 282 dnl define an ERROR_CFLAGS Makefile variable
 283 dnl -Wundef: too many broken headers
 284 if test "x$HAVE_OSX_VIDEO" != "xyes"; then
 285   AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 286         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 287         -Wwrite-strings -Wold-style-definition -Waggregate-return
 288         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 289         -Wnested-externs ])
 290 else
 291   dnl work-around for us passing GST_CFLAGS to the ObjC-compiler, which
 292   dnl doesn't understand all warning flags that the C compiler knows about
 293   dnl (e.g. -Waddress) or causes problems with some flags (-Waggregate-return)
 294   AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 295         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 296         -Wwrite-strings -Wold-style-definition
 297         -Winit-self -Wmissing-include-dirs -Wno-multichar
 298         -Wnested-externs ])
 299 fi
 300
 301 dnl define an ERROR_CXXFLAGS Makefile variable
 302 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 303         -Wmissing-declarations -Wredundant-decls
 304         -Wwrite-strings
 305         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar ])
 306
 307 dnl define correct level for debugging messages
 308 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 309
 310 dnl used in examples
 311 AG_GST_DEFAULT_ELEMENTS
 312
 313 dnl *** plug-ins to include ***
 314
 315 dnl Non ported plugins (non-dependant, then dependant)
 316 dnl Make sure you have a space before and after all plugins
 317 GST_PLUGINS_NONPORTED="deinterlace flx goom2k1 \
 318  imagefreeze interleave monoscope smpte \
 319  videobox videomixer \
 320  cairo cairo_gobject dv1394 gdk_pixbuf libdv libpng \
 321  oss oss4 shout2 \
 322  taglib wavpack \
 323  osx_video osx_audio "
 324 AC_SUBST(GST_PLUGINS_NONPORTED)
 325
 326 dnl these are all the gst plug-ins, compilable without additional libs
 327 dnl videofilter is at the top because others depend on it
 328 AG_GST_CHECK_PLUGIN(alpha)
 329 AG_GST_CHECK_PLUGIN(apetag)
 330 AG_GST_CHECK_PLUGIN(audiofx)
 331 AG_GST_CHECK_PLUGIN(audioparsers)
 332 AG_GST_CHECK_PLUGIN(auparse)
 333 AG_GST_CHECK_PLUGIN(autodetect)
 334 AG_GST_CHECK_PLUGIN(avi)
 335 AG_GST_CHECK_PLUGIN(cutter)
 336 AG_GST_CHECK_PLUGIN(debugutils)
 337 AG_GST_CHECK_PLUGIN(deinterlace)
 338 AG_GST_CHECK_PLUGIN(effectv)
 339 AG_GST_CHECK_PLUGIN(equalizer)
 340 AG_GST_CHECK_PLUGIN(flv)
 341 AG_GST_CHECK_PLUGIN(flx)
 342 AG_GST_CHECK_PLUGIN(goom)
 343 AG_GST_CHECK_PLUGIN(goom2k1)
 344 AG_GST_CHECK_PLUGIN(icydemux)
 345 AG_GST_CHECK_PLUGIN(id3demux)
 346 AG_GST_CHECK_PLUGIN(imagefreeze)
 347 AG_GST_CHECK_PLUGIN(interleave)
 348 AG_GST_CHECK_PLUGIN(isomp4)
 349 AG_GST_CHECK_PLUGIN(law)
 350 AG_GST_CHECK_PLUGIN(level)
 351 AG_GST_CHECK_PLUGIN(matroska)
 352 AG_GST_CHECK_PLUGIN(monoscope)
 353 AG_GST_CHECK_PLUGIN(multifile)
 354 AG_GST_CHECK_PLUGIN(multipart)
 355 AG_GST_CHECK_PLUGIN(replaygain)
 356 AG_GST_CHECK_PLUGIN(rtp)
 357 AG_GST_CHECK_PLUGIN(rtpmanager)
 358 AG_GST_CHECK_PLUGIN(rtsp)
 359 AG_GST_CHECK_PLUGIN(shapewipe)
 360 AG_GST_CHECK_PLUGIN(smpte)
 361 AG_GST_CHECK_PLUGIN(spectrum)
 362 AG_GST_CHECK_PLUGIN(udp)
 363 AG_GST_CHECK_PLUGIN(videobox)
 364 AG_GST_CHECK_PLUGIN(videocrop)
 365 AG_GST_CHECK_PLUGIN(videofilter)
 366 AG_GST_CHECK_PLUGIN(videomixer)
 367 AG_GST_CHECK_PLUGIN(wavenc)
 368 AG_GST_CHECK_PLUGIN(wavparse)
 369 AG_GST_CHECK_PLUGIN(y4m)
 370
 371 dnl *** checks for socket and nsl libraries ***
 372 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 373
 374 dnl disable gst plugins we might not be able to build on this
 375 dnl platform: udp and rtsp (ugly but minimally invasive)
 376 dnl FIXME: maybe move to sys
 377 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 378 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 379
 380 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 381   AG_GST_DISABLE_PLUGIN(udp)
 382   AG_GST_DISABLE_PLUGIN(rtsp)
 383 fi
 384
 385 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 386   WIN32_LIBS="-lws2_32"
 387   AC_SUBST(WIN32_LIBS)
 388 fi
 389
 390 dnl disable experimental plug-ins
 391 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 392   AG_GST_DISABLE_PLUGIN(monoscope)
 393 fi
 394
 395 dnl *** sys plug-ins ***
 396
 397 echo
 398 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 399 echo
 400
 401 dnl DirectSound
 402 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 403 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 404   HAVE_DIRECTSOUND="no"
 405   save_CFLAGS="$CFLAGS"
 406   save_LDFLAGS="$LDFLAGS"
 407   save_LIBS="$LIBS"
 408   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 409   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 410   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 411   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 412   AC_LINK_IFELSE([
 413 #include <windows.h>
 414 #include <dxerr9.h>
 415 #include <dsound.h>
 416
 417 int main ()
 418 {
 419   DXGetErrorString9 (0);
 420   DirectSoundCreate(NULL, NULL, NULL);
 421
 422   return 0;
 423 }
 424 ],
 425     [HAVE_DIRECTSOUND="yes"],
 426     [HAVE_DIRECTSOUND="no"])
 427   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 428   CFLAGS=$save_CFLAGS
 429   LDFLAGS=$save_LDFLAGS
 430   LIBS=$save_LIBS
 431
 432   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 433     dnl this is much more than we want
 434     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 435     AC_SUBST(DIRECTSOUND_CFLAGS)
 436     AC_SUBST(DIRECTSOUND_LDFLAGS)
 437     AC_SUBST(DIRECTSOUND_LIBS)
 438   fi
 439   AC_SUBST(HAVE_DIRECTSOUND)
 440 ])
 441
 442 dnl *** OSS audio *** (Linux, *BSD)
 443 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 444 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 445  HAVE_OSS="yes"
 446 dnl Linux and newer BSD versions :
 447  AC_CHECK_HEADER(sys/soundcard.h, [
 448    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 449    ] , [
 450 dnl Some old BSD versions and also newer OpenBSD versions :
 451    AC_CHECK_HEADER(soundcard.h, [
 452      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 453      ], [
 454   dnl Some old BSD versions :
 455      AC_CHECK_HEADER(machine/soundcard.h, [
 456        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 457          [Define if OSS includes are in /machine/])
 458        ], [
 459        HAVE_OSS="no"
 460      ])
 461    ])
 462  ])
 463 ])
 464
 465 dnl *** oss4 ***
 466 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 467 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 468   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 469   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 470       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 471       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 472 ])
 473
 474 dnl *** Sun Audio ***
 475 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 476 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 477   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 478 ])
 479
 480 dnl *** OSX Audio ***
 481 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 482 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 483   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 484 ])
 485
 486 dnl *** OS X video ***
 487 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 488 HAVE_OSX_VIDEO="no"
 489 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 490   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 491 ])
 492 dnl in case header OpenGL/gl.h is found on other platforms
 493 case "$host" in
 494   *-*darwin*)
 495     dnl do nothing
 496     ;;
 497   *)
 498     HAVE_OSX_VIDEO="no"
 499     ;;
 500 esac
 501
 502
 503 dnl *** Video 4 Linux 2 ***
 504 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 505 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 506 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 507 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 508   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 509   AC_TRY_COMPILE([
 510 #include <sys/types.h>
 511 #ifdef __sun /* Solaris */
 512 #include <sys/types.h>
 513 #include <sys/videodev2.h>
 514 #else /* Linux */
 515 #include <linux/types.h>
 516 #define _LINUX_TIME_H
 517 #define __user
 518 #include <linux/videodev2.h>
 519 #endif
 520 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 521 #error too early v4l2 version or no v4l2 at all
 522 #endif
 523     ], [
 524 return 0;
 525     ], [
 526       HAVE_GST_V4L2="yes"
 527       AC_MSG_RESULT(yes)
 528     ], [
 529       HAVE_GST_V4L2="no"
 530       AC_MSG_RESULT(no)
 531
 532       HAVE_VIDEODEV=no
 533       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 534       [
 535         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 536       ])
 537
 538       if test "x$HAVE_VIDEODEV" = "xyes"; then
 539         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 540         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 541       else
 542         AC_MSG_WARN([video4linux2 was not found])
 543       fi
 544     ])
 545
 546   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 547     dnl check for missing v4l2_buffer declaration (see #135919)
 548     MISSING_DECL=0
 549     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 550     AC_TRY_COMPILE([
 551 #include <sys/types.h>
 552 #ifdef __sun /* Solaris */
 553 #include <sys/types.h>
 554 #include <sys/videodev2.h>
 555 #else /* Linux */
 556 #include <linux/types.h>
 557 #define _LINUX_TIME_H
 558 #define __user
 559 #include <linux/videodev2.h>
 560 #endif
 561     ],[
 562 struct v4l2_buffer buf;
 563 buf.index = 0;
 564 return 0;
 565     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 566     if [ test x$MISSING_DECL = x1 ]; then
 567       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 568     fi
 569
 570     dnl check for XOverlay libraries
 571     AG_GST_CHECK_XV
 572   fi
 573 ])
 574
 575 # Optional gudev for device probing
 576 AC_ARG_WITH([gudev],
 577   AC_HELP_STRING([--with-gudev],
 578     [device detection with gudev]),
 579   [],
 580   [with_gudev=check])
 581 if test x$HAVE_GST_V4L2 = xyes; then
 582   if test x$with_gudev != xno; then
 583       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 584           [ have_gudev=yes
 585             AC_DEFINE(HAVE_GUDEV, 1,
 586                [Whether gudev is available for device detection])
 587             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 588           ], [
 589           have_gudev=no
 590           ])
 591   else
 592     have_gudev=no
 593   fi
 594 fi
 595 AC_SUBST(GUDEV_CFLAGS)
 596 AC_SUBST(GUDEV_LIBS)
 597
 598 # Make libv4l2 non-automagic
 599 AC_ARG_WITH([libv4l2],
 600   AC_HELP_STRING([--with-libv4l2],
 601     [support video buffer conversion using libv4l2]),
 602   [],
 603   [with_libv4l2=check])
 604 if test x$HAVE_GST_V4L2 = xyes; then
 605   if test x$with_libv4l2 != xno; then
 606       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 607           [ have_libv4l2=yes
 608             AC_DEFINE(HAVE_LIBV4L2, 1,
 609                 [Whether libv4l2 is available for video buffer conversion])
 610           ], [
 611           have_libv4l2=no
 612           ])
 613   else
 614     have_libv4l2=no
 615   fi
 616 fi
 617
 618 dnl Check for X11
 619 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 620 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 621                   [ximagesrc], [
 622   AC_PATH_XTRA
 623
 624   dnl now try to find the HEADER
 625   ac_cflags_save="$CFLAGS"
 626   ac_cppflags_save="$CPPFLAGS"
 627   CFLAGS="$CFLAGS $X_CFLAGS"
 628   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 629   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 630
 631   if test "x$HAVE_X" = "xno"
 632   then
 633     AC_MSG_NOTICE([cannot find X11 development files])
 634   else
 635     dnl this is much more than we want
 636     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 637     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 638     dnl it does not add the libs; therefore we add them here
 639     X_LIBS="$X_LIBS -lX11"
 640     AC_SUBST(X_CFLAGS)
 641     AC_SUBST(X_LIBS)
 642
 643     dnl check for Xfixes
 644     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 645     if test "x$HAVE_XFIXES" = "xyes"
 646     then
 647         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 648     fi
 649     AC_SUBST(XFIXES_LIBS)
 650     AC_SUBST(XFIXES_CFLAGS)
 651
 652     dnl check for Xdamage
 653     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 654     if test "x$HAVE_XDAMAGE" = "xyes"
 655     then
 656         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 657     fi
 658     AC_SUBST(XDAMAGE_LIBS)
 659     AC_SUBST(XDAMAGE_CFLAGS)
 660   fi
 661   AC_SUBST(HAVE_X)
 662   CFLAGS="$ac_cflags_save"
 663   CPPFLAGS="$ac_cppflags_save"
 664 ])
 665
 666 dnl FIXME: this should be rolled into the test above, it's just an additional
 667 dnl feature of the ximagesrc plug-in
 668 dnl This is the same as in gst-plugins-base
 669 dnl check for X Shm
 670 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 671 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 672   if test x$HAVE_X = xyes; then
 673     AC_CHECK_LIB(Xext, XShmAttach,
 674                  HAVE_XSHM="yes", HAVE_XSHM="no",
 675                  $X_LIBS)
 676     if test "x$HAVE_XSHM" = "xyes"; then
 677       XSHM_LIBS="-lXext"
 678     else
 679       dnl On AIX, it is in XextSam instead, but we still need -lXext
 680       AC_CHECK_LIB(XextSam, XShmAttach,
 681                    HAVE_XSHM="yes", HAVE_XSHM="no",
 682                    $X_LIBS)
 683       if test "x$HAVE_XSHM" = "xyes"; then
 684         XSHM_LIBS="-lXext -lXextSam"
 685       fi
 686     fi
 687   fi
 688 ], ,[
 689   AC_SUBST(HAVE_XSHM)
 690   AC_SUBST(XSHM_LIBS)
 691 ])
 692
 693 dnl for V4L2, we also need to know if we have XVIDEO
 694 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 695 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 696                   [], [
 697   AG_GST_CHECK_XV
 698 ])
 699
 700 dnl *** ext plug-ins ***
 701 dnl keep this list sorted alphabetically !
 702
 703 if test "x$BUILD_EXTERNAL" = "xyes"; then
 704
 705 echo
 706 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 707 echo
 708
 709 dnl *** aalib ***
 710 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 711 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 712   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 713   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 714 ])
 715
 716 dnl *** annodex ***
 717 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 718 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 719   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 720 ])
 721
 722 dnl *** cairo ***
 723 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 724 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 725   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 726 ])
 727
 728 dnl *** cairo-gobject ***
 729 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO_GOBJECT, true)
 730 AG_GST_CHECK_FEATURE(CAIRO_GOBJECT,
 731   [Cairo graphics rendering gobject bindings], cairooverlay, [
 732   AG_GST_PKG_CHECK_MODULES(CAIRO_GOBJECT, cairo-gobject >= 1.10.0)
 733 ])
 734
 735 dnl *** FLAC ***
 736 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 737 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 738   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 739 ])
 740
 741 dnl *** GDK pixbuf ***
 742 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 743 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 744   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 745 ])
 746
 747 dnl *** Jack ***
 748 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 749 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 750   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 751   AC_SUBST(JACK_CFLAGS)
 752   AC_SUBST(JACK_LIBS)
 753
 754   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 755   if test x$HAVE_JACK_0_120_1 = xyes; then
 756     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 757   fi
 758   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 759   if test x$HAVE_JACK_1_9_7 = xyes; then
 760     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 761   fi
 762
 763 ])
 764
 765 dnl *** jpeg ***
 766 dnl FIXME: we could use header checks here as well IMO
 767 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 768 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 769   AC_ARG_WITH(jpeg-mmx,
 770     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 771   OLD_LIBS="$LIBS"
 772   if test x$with_jpeg_mmx != x; then
 773     LIBS="$LIBS -L$with_jpeg_mmx"
 774   fi
 775   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 776   JPEG_LIBS="$LIBS -ljpeg-mmx"
 777   LIBS="$OLD_LIBS"
 778   if test x$HAVE_JPEG != xyes; then
 779     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 780     JPEG_LIBS="-ljpeg"
 781   fi
 782   AC_SUBST(JPEG_LIBS)
 783 ])
 784
 785 dnl *** libcaca ***
 786 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 787 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 788   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 789 ])
 790
 791 dnl *** libdv ***
 792 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 793 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 794   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 795 ])
 796
 797 dnl *** libpng ***
 798 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 799 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 800   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 801 ])
 802
 803 dnl *** pulseaudio ***
 804 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 805 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 806
 807   dnl used in ext/pulse/pulseutil.c
 808   AC_CHECK_HEADERS([process.h])
 809
 810   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 1.0)
 811 ])
 812
 813 dnl *** dv1394 ***
 814 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 815 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 816   dnl first test for libraw1394 >= 2.0.0
 817   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 818   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 819   dnl now see how far we got
 820   if test x$HAVE_RAW1394 = xyes && \
 821      test x$HAVE_LIBIEC61883 = xyes; then
 822        AG_GST_CHECK_LIBHEADER(AVC1394,
 823         avc1394, avc1394_send_command, $RAW1394_LIBS,
 824         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 825        AG_GST_CHECK_LIBHEADER(ROM1394,
 826         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 827         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 828        if test x$HAVE_AVC1394 = xyes && \
 829           test x$HAVE_AVC1394 = xyes && \
 830           test x$HAVE_ROM1394 = xyes; then
 831           HAVE_DV1394=yes
 832           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 833           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 834           AC_SUBST(DV1394_CFLAGS)
 835           AC_SUBST(DV1394_LIBS)
 836         fi
 837   else
 838        if test x$HAVE_RAW1394 = xno; then
 839           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 840           AG_GST_CHECK_LIBHEADER(AVC1394,
 841            avc1394, avc1394_send_command, $RAW1394_LIBS,
 842            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 843           AG_GST_CHECK_LIBHEADER(ROM1394,
 844            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 845            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 846           if test x$HAVE_RAW1394 = xyes && \
 847              test x$HAVE_AVC1394 = xyes && \
 848              test x$HAVE_ROM1394 = xyes; then
 849              HAVE_DV1394=yes
 850              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 851              DV1394_CFLAGS="$RAW1394_CFLAGS"
 852              if test x$HAVE_LIBIEC61883 = xyes; then
 853                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 854                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 855              fi
 856              AC_SUBST(DV1394_CFLAGS)
 857              AC_SUBST(DV1394_LIBS)
 858            fi
 859          fi
 860   fi
 861 ])
 862 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 863
 864 dnl *** shout2 ***
 865 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 866 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 867   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 868 ])
 869
 870 dnl *** soup ***
 871 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 872 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 873   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 874     HAVE_SOUP="yes"
 875     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 876   ],[
 877     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26, HAVE_SOUP="yes", [
 878       HAVE_SOUP="no"
 879     ])
 880   ])
 881   AC_SUBST(SOUP_CFLAGS)
 882   AC_SUBST(SOUP_LIBS)
 883 ])
 884
 885 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 886 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 887 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 888 dnl   speex_jitter.h is 1.1.x only
 889 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 890 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 891   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 892   if test $HAVE_SPEEX = no
 893   then
 894     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 895       AC_CHECK_HEADER(speex/speex_jitter.h, [
 896         dnl speex 1.1.x :
 897         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 898           dnl speex 1.1.5 or + :
 899           HAVE_SPEEX="yes"
 900           SPEEX_LIBS="-lspeex"
 901           AC_SUBST(SPEEX_CFLAGS)
 902           AC_SUBST(SPEEX_LIBS)
 903         ],[
 904           HAVE_SPEEX="no"
 905         ])
 906       ],[
 907         dnl speex 1.0.x :
 908           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 909             dnl speex 1.0.4
 910             HAVE_SPEEX="yes"
 911             SPEEX_LIBS="-lspeex"
 912             AC_SUBST(SPEEX_CFLAGS)
 913             AC_SUBST(SPEEX_LIBS)
 914
 915             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 916               [defined if speex 1.0.x API detected])
 917         ],[
 918             HAVE_SPEEX="no"
 919             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 920         ], [
 921 #include <speex/speex.h>
 922         ])
 923       ])
 924     ])
 925   fi
 926 ])
 927
 928 dnl *** taglib ***
 929 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 930 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 931   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 932   if test "x$HAVE_CXX" != "xyes"; then
 933     USE_TAGLIB=false
 934     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 935   else
 936     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 937     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 938         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 939       ], [
 940         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 941     ])
 942     AC_SUBST(TAGLIB_CXXFLAGS)
 943   fi
 944 ])
 945
 946 dnl *** wavpack ***
 947 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 948 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 949   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 950     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 951       HAVE_WAVPACK=yes
 952       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 953     ],[
 954       HAVE_WAVPACK=no
 955     ])
 956   ])
 957   AC_SUBST(WAVPACK_CFLAGS)
 958   AC_SUBST(WAVPACK_LIBS)
 959 ])
 960
 961 dnl *** qtdemux & matroska prefer to have zlib ***
 962 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 963 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
 964   AG_GST_CHECK_LIBHEADER(ZLIB,
 965     z, uncompress,, zlib.h, [
 966     HAVE_ZLIB="yes"
 967     ZLIB_LIBS="-lz"
 968     AC_SUBST(ZLIB_LIBS)
 969   ])
 970 ])
 971
 972 dnl *** matroska prefers to have bz2 ***
 973 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 974 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 975   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 976   AC_SUBST(BZ2_LIBS)
 977 ])
 978
 979 else
 980
 981 dnl not building plugins with external dependencies,
 982 dnl but we still need to set the conditionals
 983 AM_CONDITIONAL(USE_AALIB, false)
 984 AM_CONDITIONAL(USE_ANNODEX, false)
 985 AM_CONDITIONAL(USE_BZ2, false)
 986 AM_CONDITIONAL(USE_CAIRO, false)
 987 AM_CONDITIONAL(USE_CAIRO_GOBJECT, false)
 988 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 989 AM_CONDITIONAL(USE_DV1394, false)
 990 AM_CONDITIONAL(USE_FLAC, false)
 991 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 992 AM_CONDITIONAL(USE_GST_V4L2, false)
 993 AM_CONDITIONAL(USE_JACK, false)
 994 AM_CONDITIONAL(USE_JPEG, false)
 995 AM_CONDITIONAL(USE_LIBCACA, false)
 996 AM_CONDITIONAL(USE_LIBDV, false)
 997 AM_CONDITIONAL(USE_LIBIEC61883, false)
 998 AM_CONDITIONAL(USE_LIBPNG, false)
 999 AM_CONDITIONAL(USE_OSS, false)
1000 AM_CONDITIONAL(USE_OSS4, false)
1001 AM_CONDITIONAL(USE_OSX_AUDIO, false)
1002 AM_CONDITIONAL(USE_OSX_VIDEO, false)
1003 AM_CONDITIONAL(USE_PULSE, false)
1004 AM_CONDITIONAL(USE_SHOUT2, false)
1005 AM_CONDITIONAL(USE_SOUP, false)
1006 AM_CONDITIONAL(USE_SPEEX, false)
1007 AM_CONDITIONAL(USE_SUNAUDIO, false)
1008 AM_CONDITIONAL(USE_TAGLIB, false)
1009 AM_CONDITIONAL(USE_WAVPACK, false)
1010 AM_CONDITIONAL(USE_X, false)
1011 AM_CONDITIONAL(USE_XSHM, false)
1012 AM_CONDITIONAL(USE_XVIDEO, false)
1013 AM_CONDITIONAL(USE_ZLIB, false)
1014
1015 fi dnl of EXT plugins
1016
1017 dnl *** finalize CFLAGS, LDFLAGS, LIBS
1018
1019 dnl Overview:
1020 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1021 dnl GST_*:              flags shared by all built objects
1022 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1023 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
1024 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1025 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1026
1027 dnl GST_OPTION_CFLAGS
1028 if test "x$USE_DEBUG" = xyes; then
1029    PROFILE_CFLAGS="-g"
1030 fi
1031 AC_SUBST(PROFILE_CFLAGS)
1032
1033 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1034   dnl Define _only_ for git (not pre-releases or releases)
1035   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1036 else
1037   DEPRECATED_CFLAGS=""
1038 fi
1039 AC_SUBST(DEPRECATED_CFLAGS)
1040
1041 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
1042 dnl at make time with e.g. make ERROR_CFLAGS=""
1043 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1044 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1045 AC_SUBST(GST_OPTION_CFLAGS)
1046 AC_SUBST(GST_OPTION_CXXFLAGS)
1047
1048 dnl our libraries need to be versioned correctly
1049 AC_SUBST(GST_LT_LDFLAGS)
1050
1051 dnl FIXME: do we want to rename to GST_ALL_* ?
1052 dnl prefer internal headers to already installed ones
1053 dnl also add builddir include for enumtypes and marshal
1054 dnl add ERROR_CFLAGS, but overridable
1055 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
1056 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1057 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
1058 AC_SUBST(GST_CFLAGS)
1059 AC_SUBST(GST_CXXFLAGS)
1060 AC_SUBST(GST_LIBS)
1061
1062 dnl LDFLAGS really should only contain flags, not libs - they get added before
1063 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1064 GST_ALL_LDFLAGS="-no-undefined"
1065 AC_SUBST(GST_ALL_LDFLAGS)
1066
1067 dnl this really should only contain flags, not libs - they get added before
1068 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1069 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
1070 AC_SUBST(GST_PLUGIN_LDFLAGS)
1071
1072 dnl *** output files ***
1073
1074 dnl keep this alphabetic per directory, please
1075 AC_CONFIG_FILES(
1076 Makefile
1077 gst/Makefile
1078 gst/alpha/Makefile
1079 gst/apetag/Makefile
1080 gst/audiofx/Makefile
1081 gst/audioparsers/Makefile
1082 gst/auparse/Makefile
1083 gst/autodetect/Makefile
1084 gst/avi/Makefile
1085 gst/cutter/Makefile
1086 gst/deinterlace/Makefile
1087 gst/debugutils/Makefile
1088 gst/effectv/Makefile
1089 gst/equalizer/Makefile
1090 gst/flv/Makefile
1091 gst/goom/Makefile
1092 gst/goom2k1/Makefile
1093 gst/id3demux/Makefile
1094 gst/icydemux/Makefile
1095 gst/imagefreeze/Makefile
1096 gst/interleave/Makefile
1097 gst/isomp4/Makefile
1098 gst/law/Makefile
1099 gst/level/Makefile
1100 gst/matroska/Makefile
1101 gst/monoscope/Makefile
1102 gst/multifile/Makefile
1103 gst/multipart/Makefile
1104 gst/replaygain/Makefile
1105 gst/rtp/Makefile
1106 gst/rtpmanager/Makefile
1107 gst/rtsp/Makefile
1108 gst/shapewipe/Makefile
1109 gst/smpte/Makefile
1110 gst/spectrum/Makefile
1111 gst/udp/Makefile
1112 gst/videobox/Makefile
1113 gst/videocrop/Makefile
1114 gst/videofilter/Makefile
1115 gst/videomixer/Makefile
1116 gst/wavenc/Makefile
1117 gst/wavparse/Makefile
1118 gst/flx/Makefile
1119 gst/y4m/Makefile
1120 ext/Makefile
1121 ext/aalib/Makefile
1122 ext/annodex/Makefile
1123 ext/cairo/Makefile
1124 ext/dv/Makefile
1125 ext/flac/Makefile
1126 ext/gdk_pixbuf/Makefile
1127 ext/jack/Makefile
1128 ext/jpeg/Makefile
1129 ext/libcaca/Makefile
1130 ext/libpng/Makefile
1131 ext/pulse/Makefile
1132 ext/raw1394/Makefile
1133 ext/shout2/Makefile
1134 ext/soup/Makefile
1135 ext/speex/Makefile
1136 ext/taglib/Makefile
1137 ext/wavpack/Makefile
1138 sys/Makefile
1139 sys/directsound/Makefile
1140 sys/oss/Makefile
1141 sys/oss4/Makefile
1142 sys/osxaudio/Makefile
1143 sys/osxvideo/Makefile
1144 sys/sunaudio/Makefile
1145 sys/v4l2/Makefile
1146 sys/waveform/Makefile
1147 sys/ximage/Makefile
1148 po/Makefile.in
1149 tests/Makefile
1150 tests/check/Makefile
1151 tests/examples/Makefile
1152 tests/examples/audiofx/Makefile
1153 tests/examples/cairo/Makefile
1154 tests/examples/equalizer/Makefile
1155 tests/examples/jack/Makefile
1156 tests/examples/level/Makefile
1157 tests/examples/pulse/Makefile
1158 tests/examples/rtp/Makefile
1159 tests/examples/shapewipe/Makefile
1160 tests/examples/spectrum/Makefile
1161 tests/examples/v4l2/Makefile
1162 tests/files/Makefile
1163 tests/icles/Makefile
1164 common/Makefile
1165 common/m4/Makefile
1166 m4/Makefile
1167 docs/Makefile
1168 docs/plugins/Makefile
1169 docs/version.entities
1170 pkgconfig/Makefile
1171 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1172 gst-plugins-good.spec
1173 )
1174
1175 dnl Create the config.h file for Visual Studio builds
1176 dnl Beware of spaces and /'s in some of the shell variable contents.
1177 sed \
1178     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1179     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1180     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1181     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1182     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1183     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1184     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1185     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1186     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1187     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1188     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1189     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1190     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1191     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1192     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1193     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1194     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1195     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1196     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1197     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1198     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1199     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1200     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1201     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1202     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1203     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1204     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1205     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1206     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1207     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
1208     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1209     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1210     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1211     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1212     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1213     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1214     config.h.in >win32/common/config.h-new
1215
1216 AC_OUTPUT
1217
1218 AG_GST_OUTPUT_PLUGINS
1219 ORC_OUTPUT
1220