configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # in easier to understand terms:
  24 #
  25 # <mclasen> on the stable branch, interface age == micro
  26 # <mclasen> on the unstable (ie master), interface age = 0
  27
  28 m4_define([glib_major_version], [2])
  29 m4_define([glib_minor_version], [31])
  30 m4_define([glib_micro_version], [9])
  31 m4_define([glib_interface_age], [0])
  32 m4_define([glib_binary_age],
  33           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  34 m4_define([glib_version],
  35           [glib_major_version.glib_minor_version.glib_micro_version])
  36
  37 # libtool version related macros
  38 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  39 m4_define([glib_lt_current],
  40           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  41 m4_define([glib_lt_revision], [glib_interface_age])
  42 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  43 m4_define([glib_lt_current_minus_age],
  44           [m4_eval(glib_lt_current - glib_lt_age)])
  45
  46 # if the minor version number is odd, then we want debugging.  Otherwise
  47 # we only want minimal debugging support.
  48 m4_define([glib_debug_default],
  49           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  50
  51
  52 AC_INIT(glib, [glib_version],
  53         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  54
  55 AC_CONFIG_HEADER([config.h])
  56 AC_CONFIG_SRCDIR([glib/glib.h])
  57 AC_CONFIG_MACRO_DIR([m4macros])
  58
  59 # Save this value here, since automake will set cflags later
  60 cflags_set=${CFLAGS+set}
  61
  62 AM_INIT_AUTOMAKE([1.11 no-define no-dist-gzip dist-xz tar-ustar])
  63 AM_MAINTAINER_MODE([enable])
  64
  65 # Support silent build rules. Disable
  66 # by either passing --disable-silent-rules to configure or passing V=1
  67 # to make
  68 AM_SILENT_RULES([yes])
  69
  70 GLIB_MAJOR_VERSION=glib_major_version
  71 GLIB_MINOR_VERSION=glib_minor_version
  72 GLIB_MICRO_VERSION=glib_micro_version
  73 GLIB_INTERFACE_AGE=glib_interface_age
  74 GLIB_BINARY_AGE=glib_binary_age
  75 GLIB_VERSION=glib_version
  76
  77 AC_SUBST(GLIB_MAJOR_VERSION)
  78 AC_SUBST(GLIB_MINOR_VERSION)
  79 AC_SUBST(GLIB_MICRO_VERSION)
  80 AC_SUBST(GLIB_VERSION)
  81 AC_SUBST(GLIB_INTERFACE_AGE)
  82 AC_SUBST(GLIB_BINARY_AGE)
  83
  84 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  85           [Define to the GLIB major version])
  86 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  87           [Define to the GLIB minor version])
  88 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  89           [Define to the GLIB micro version])
  90 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  91           [Define to the GLIB interface age])
  92 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  93           [Define to the GLIB binary age])
  94
  95 # libtool versioning
  96 LT_RELEASE=glib_lt_release
  97 LT_CURRENT=glib_lt_current
  98 LT_REVISION=glib_lt_revision
  99 LT_AGE=glib_lt_age
 100 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 101 AC_SUBST(LT_RELEASE)
 102 AC_SUBST(LT_CURRENT)
 103 AC_SUBST(LT_REVISION)
 104 AC_SUBST(LT_AGE)
 105 AC_SUBST(LT_CURRENT_MINUS_AGE)
 106
 107 dnl Checks for programs.
 108 AC_PROG_CC
 109 AC_PROG_CPP
 110
 111 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 112
 113 AC_CANONICAL_HOST
 114
 115 AC_MSG_CHECKING([for the BeOS])
 116 case $host in
 117   *-*-beos*)
 118     glib_native_beos="yes"
 119     ;;
 120   *)
 121     glib_native_beos="no"
 122     ;;
 123 esac
 124 AC_MSG_RESULT([$glib_native_beos])
 125
 126 dnl
 127
 128 AC_MSG_CHECKING([for Win32])
 129 LIB_EXE_MACHINE_FLAG=X86
 130 case "$host" in
 131   *-*-mingw*)
 132     glib_native_win32=yes
 133     glib_pid_type='void *'
 134     glib_cv_stack_grows=no
 135     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 136     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 137     # (Sorry, I don't know exactly what is the problem, but it is related to
 138     # floating point formatting and decimal point vs. comma.)
 139     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 140     # rigorous enough to notice, though.
 141     # So preset the autoconf cache variables.
 142     ac_cv_func_vsnprintf_c99=no
 143     ac_cv_func_snprintf_c99=no
 144     case "$host" in
 145     x86_64-*-*)
 146       LIB_EXE_MACHINE_FLAG=X64
 147       ;;
 148     esac
 149     ;;
 150   *)
 151     glib_native_win32=no
 152     glib_pid_type=int
 153     ;;
 154 esac
 155 case $host in
 156   *-*-linux*)
 157     glib_os_linux=yes
 158     ;;
 159 esac
 160
 161 AC_MSG_RESULT([$glib_native_win32])
 162
 163 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 164
 165 glib_have_carbon=no
 166 AC_MSG_CHECKING([for Mac OS X Carbon support])
 167 AC_TRY_CPP([
 168 #include <Carbon/Carbon.h>
 169 #include <CoreServices/CoreServices.h>
 170 ], glib_have_carbon=yes)
 171
 172 AC_MSG_RESULT([$glib_have_carbon])
 173
 174 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 175 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 176 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 177 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 178 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 179
 180 if test "$glib_native_win32" = "yes"; then
 181   AC_CHECK_TOOL(WINDRES, windres, no)
 182   if test "$WINDRES" = no; then
 183     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 184   fi
 185   AC_CHECK_TOOL(NM, nm, no)
 186   if test "$NM" = no; then
 187     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 188   fi
 189   AC_CHECK_TOOL(RANLIB, ranlib, :)
 190   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 191 fi
 192 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 193
 194 if test "$glib_native_win32" != yes; then
 195     # libtool option to control which symbols are exported
 196     # right now, symbols starting with _ are not exported
 197     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^g.*"'
 198 else
 199     # We currently use .def files on Windows
 200     LIBTOOL_EXPORT_OPTIONS=
 201 fi
 202 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 203
 204 if test "x$glib_have_carbon" = "xyes"; then
 205   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 206   LDFLAGS="$LDFLAGS -framework Carbon"
 207 fi
 208
 209 gl_GLIBC21
 210 if test "x$GLIBC21" = "xyes"; then
 211   AC_DEFINE([_GNU_SOURCE], 1, [Make all glibc extensions visible])
 212 fi
 213
 214 dnl declare --enable-* args and collect ac_help strings
 215 AC_ARG_ENABLE(debug,
 216               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 217                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 218               enable_debug=glib_debug_default)
 219
 220 AC_ARG_ENABLE(gc_friendly,
 221               [AC_HELP_STRING([--enable-gc-friendly],
 222                               [turn on garbage collector friendliness [default=no]])],,
 223               [enable_gc_friendly=no])
 224 AC_ARG_ENABLE(mem_pools,
 225               [AC_HELP_STRING([--disable-mem-pools],
 226                               [disable all glib memory pools])],,
 227               [disable_mem_pools=no])
 228 AC_ARG_ENABLE(rebuilds,
 229               [AC_HELP_STRING([--disable-rebuilds],
 230                               [disable all source autogeneration rules])],,
 231               [enable_rebuilds=yes])
 232
 233 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 234 if test "x$enable_gc_friendly" = "xyes"; then
 235   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 236   AC_MSG_RESULT([yes])
 237 else
 238   AC_MSG_RESULT([no])
 239 fi
 240
 241 AC_MSG_CHECKING([whether to disable memory pools])
 242 if test "x$disable_mem_pools" = "xno"; then
 243   AC_MSG_RESULT([no])
 244 else
 245   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 246   AC_MSG_RESULT([yes])
 247 fi
 248
 249 dnl location to install runtime libraries, e.g. ../../lib to install
 250 dnl to /lib if libdir is /usr/lib
 251 AC_ARG_WITH(runtime-libdir,
 252            [AC_HELP_STRING([--with-runtime-libdir=RELPATH],
 253                            [install runtime libraries relative to libdir])],
 254            [],
 255            [with_runtime_libdir=""])
 256 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 257 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 258 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 259 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 260 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 261
 262 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 263 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 264 AC_LANG_SAVE
 265 AC_LANG_CPLUSPLUS
 266 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 267 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 268 AC_LANG_RESTORE
 269
 270 AM_PROG_CC_STDC
 271 AM_PROG_CC_C_O
 272 AC_PROG_INSTALL
 273
 274 AC_SYS_LARGEFILE
 275
 276 PKG_PROG_PKG_CONFIG(0.16)
 277
 278 if test "x$enable_debug" = "xyes"; then
 279   if test x$cflags_set != xset ; then
 280       case " $CFLAGS " in
 281       *[[\ \    ]]-g[[\ \       ]]*) ;;
 282       *) CFLAGS="$CFLAGS -g" ;;
 283       esac
 284   fi
 285   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 286 else
 287   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 288
 289   if test "x$enable_debug" = "xno"; then
 290     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 291   fi
 292 fi
 293
 294 # Ensure MSVC-compatible struct packing convention is used when
 295 # compiling for Win32 with gcc.
 296 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 297 # gcc2 uses "-fnative-struct".
 298 if test x"$glib_native_win32" = xyes; then
 299   if test x"$GCC" = xyes; then
 300     msnative_struct=''
 301     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 302     if test -z "$ac_cv_prog_CC"; then
 303       our_gcc="$CC"
 304     else
 305       our_gcc="$ac_cv_prog_CC"
 306     fi
 307     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 308       2.)
 309         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 310           msnative_struct='-fnative-struct'
 311         fi
 312         ;;
 313       *)
 314         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 315           msnative_struct='-mms-bitfields'
 316         fi
 317         ;;
 318     esac
 319     if test x"$msnative_struct" = x ; then
 320       AC_MSG_RESULT([no way])
 321       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 322     else
 323       CFLAGS="$CFLAGS $msnative_struct"
 324       AC_MSG_RESULT([${msnative_struct}])
 325     fi
 326   fi
 327 fi
 328 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 329 AC_SUBST(GLIB_EXTRA_CFLAGS)
 330
 331 AC_EXEEXT
 332
 333 # define a MAINT-like variable REBUILD which is set if Perl
 334 # and awk are found, so autogenerated sources can be rebuilt
 335 AC_PROG_AWK
 336 AC_CHECK_PROGS(PERL, [perl5 perl])
 337 # We would like indent, but don't require it.
 338 AC_CHECK_PROG(INDENT, indent, indent)
 339 REBUILD=\#
 340 if test "x$enable_rebuilds" = "xyes" && \
 341      test -n "$PERL" && \
 342      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 343      test -n "$AWK" ; then
 344   REBUILD=
 345 fi
 346 AC_SUBST(REBUILD)
 347
 348 # Need full path to Perl for glib-mkenums
 349 #
 350 if test "x$PERL" != x ; then
 351   AC_PATH_PROG(PERL_PATH, [$PERL])
 352 fi
 353 if test "x$PERL_PATH" = x ; then
 354   PERL_PATH="/usr/bin/env perl"
 355 fi
 356 AC_SUBST(PERL_PATH)
 357
 358 # Need suitable python path for greport
 359 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 360
 361
 362 dnl ***********************
 363 dnl *** Tests for iconv ***
 364 dnl ***********************
 365 dnl
 366 dnl We do this before the gettext checks, to avoid distortion
 367
 368 dnl On Windows we use a native implementation
 369
 370 if test x"$glib_native_win32" = xyes; then
 371   with_libiconv=native
 372 else
 373   AC_ARG_WITH(libiconv,
 374               [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 375                               [use the libiconv library])],,
 376               [with_libiconv=maybe])
 377
 378   found_iconv=no
 379   case $with_libiconv in
 380     maybe)
 381       # Check in the C library first
 382       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 383       # Check if we have GNU libiconv
 384       if test $found_iconv = "no"; then
 385         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 386       fi
 387       # Check if we have a iconv in -liconv, possibly from vendor
 388       if test $found_iconv = "no"; then
 389         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 390       fi
 391       ;;
 392     no)
 393       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 394       ;;
 395     gnu|yes)
 396       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 397       ;;
 398     native)
 399       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 400       ;;
 401   esac
 402
 403   if test "x$found_iconv" = "xno" ; then
 404      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 405   fi
 406 fi
 407
 408 AC_ARG_ENABLE(iconv-cache,
 409               [AC_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 410                               [cache iconv descriptors [default=auto]])],,
 411               [enable_iconv_cache=auto])
 412
 413 AC_MSG_CHECKING([whether to cache iconv descriptors])
 414 case $enable_iconv_cache in
 415   auto)
 416     if test $ac_cv_gnu_library_2_1 = yes; then
 417       enable_iconv_cache=no
 418     else
 419       enable_iconv_cache=yes
 420     fi
 421   ;;
 422   yes|no)
 423   ;;
 424   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 425   ;;
 426 esac
 427
 428 if test $enable_iconv_cache = yes; then
 429    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 430 fi
 431
 432 AC_MSG_RESULT($enable_iconv_cache)
 433
 434
 435 dnl
 436 dnl zlib support
 437 dnl
 438 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 439 if test "x$found_zlib" = "xno" ; then
 440   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 441   if test "x$found_zlib" = "xno" ; then
 442     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 443   fi
 444   ZLIB_LIBS='-lz'
 445   AC_SUBST(ZLIB_LIBS)
 446 fi
 447
 448 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 449 AC_SUBST(LIBFFI_CFLAGS)
 450 AC_SUBST(LIBFFI_LIBS)
 451
 452 dnl
 453 dnl gettext support
 454 dnl
 455
 456 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 457 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 458 GLIB_GNU_GETTEXT
 459
 460 if test "$gt_cv_have_gettext" != "yes" ; then
 461   AC_MSG_ERROR([
 462 *** You must have either have gettext support in your C library, or use the
 463 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 464 ])
 465 fi
 466
 467 LIBS="$INTLLIBS $LIBS"
 468
 469 GETTEXT_PACKAGE=glib20
 470 AC_SUBST(GETTEXT_PACKAGE)
 471 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 472   [Define the gettext package to be used])
 473
 474 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 475
 476 dnl
 477 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 478 dnl
 479
 480 if test x"$glib_native_win32" != xyes; then
 481   if test x$with_libiconv != xno ; then
 482     case " $INTLLIBS " in
 483     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 484     *) ICONV_LIBS="-liconv" ;;
 485     esac
 486   fi
 487 fi
 488 AC_SUBST(ICONV_LIBS)
 489
 490 case $with_libiconv in
 491   gnu)
 492     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 493     ;;
 494   native)
 495     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 496     ;;
 497 esac
 498
 499 dnl Initialize libtool
 500 LT_PREREQ([2.2])
 501 LT_INIT([disable-static win32-dll])
 502 dnl when using libtool 2.x create libtool early, because it's used in configure
 503 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 504
 505
 506 if test "x$GCC" = "xyes"; then
 507   case " $CFLAGS " in
 508   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 509   *) CFLAGS="$CFLAGS -Wall" ;;
 510   esac
 511 fi
 512
 513 if test "$glib_native_win32" = "yes"; then
 514   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 515     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 516   fi
 517   if test x$enable_static = xyes; then
 518     glib_win32_static_compilation=yes
 519     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 520 #define GOBJECT_STATIC_COMPILATION 1"
 521     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 522   fi
 523 fi
 524 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 525
 526 dnl
 527 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 528 dnl
 529 if test $cross_compiling != yes ; then
 530     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 531     glib_save_LIBS=$LIBS
 532     LIBS="$LIBS -lm"
 533     AC_TRY_RUN([#include <math.h>
 534                  int main (void) { return (log(1) != log(1.)); }],
 535          AC_MSG_RESULT(none needed),
 536          glib_save_CFLAGS=$CFLAGS
 537          CFLAGS="$CFLAGS -std1"
 538          AC_TRY_RUN([#include <math.h>
 539                      int main (void) { return (log(1) != log(1.)); }],
 540              AC_MSG_RESULT(-std1),
 541              AC_MSG_RESULT()
 542              CFLAGS=$glib_save_CFLAGS
 543              AC_MSG_WARN(
 544                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 545          )
 546     )
 547     LIBS=$glib_save_LIBS
 548 fi
 549
 550 dnl NeXTStep cc seems to need this
 551 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 552 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 553   AC_MSG_RESULT(none needed),
 554   glib_save_CFLAGS=$CFLAGS
 555   CFLAGS="$CFLAGS -posix"
 556   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 557     AC_MSG_RESULT(-posix),
 558     AC_MSG_RESULT()
 559     CFLAGS=$glib_save_CFLAGS
 560     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 561
 562 # Checks for library functions.
 563 AC_FUNC_VPRINTF
 564 AC_FUNC_ALLOCA
 565 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2)
 566 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 567
 568 dnl don't use AC_CHECK_FUNCS here, otherwise HAVE_QSORT_R will
 569 dnl be automatically defined, which we don't want to do
 570 dnl until we have checked this function is actually usable
 571 AC_CHECK_FUNC([qsort_r])
 572
 573 # BSD has a qsort_r with wrong argument order
 574 if test x$ac_cv_func_qsort_r = xyes ; then
 575   AC_CACHE_CHECK([if qsort_r uses glibc compatible argument order], glib_cv_have_qsort_r, [
 576   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 577   #define _GNU_SOURCE
 578   #include <stdlib.h>
 579
 580   static int
 581   cmp (const void *a, const void *b, void *c)
 582   {
 583     const int *ia = a;
 584     const int *ib = b;
 585
 586     if (*ia < *ib)
 587       return -1;
 588     else if (*ia > *ib)
 589       return 1;
 590     else
 591       return 0;
 592   }
 593
 594   int
 595   main (int argc, char **argv)
 596   {
 597     int arr[3] = { 1, 2, 0 };
 598     int d = 3;
 599
 600     qsort_r (arr, 3, sizeof (int), cmp, &d);
 601
 602     if (arr[0] == 0 && arr[1] == 1 && arr[2] == 2)
 603       return 0;
 604     else
 605       return 1;
 606   }]])],[glib_cv_have_qsort_r=yes],[glib_cv_have_qsort_r=no],[glib_cv_have_qsort_r=no])])
 607 fi
 608
 609 if test x$glib_cv_have_qsort_r = xyes ; then
 610   AC_DEFINE(HAVE_QSORT_R, 1, [Define to 1 if you have the 'qsort_r' function])
 611 fi
 612
 613 AC_CHECK_SIZEOF(char)
 614 AC_CHECK_SIZEOF(short)
 615 AC_CHECK_SIZEOF(long)
 616 AC_CHECK_SIZEOF(int)
 617 AC_CHECK_SIZEOF(void *)
 618 AC_CHECK_SIZEOF(long long)
 619 AC_CHECK_SIZEOF(__int64)
 620
 621 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 622   :
 623 else
 624   AC_MSG_ERROR([
 625 *** GLib requires a 64 bit type. You might want to consider
 626 *** using the GNU C compiler.
 627 ])
 628 fi
 629
 630 if test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8; then
 631         # long long is a 64 bit integer.
 632         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 633         AC_CACHE_VAL(glib_cv_long_long_format,[
 634                 for format in ll q I64; do
 635                   AC_TRY_RUN([#include <stdio.h>
 636                         int main()
 637                         {
 638                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 639                           char buffer[1000];
 640                           sprintf (buffer, "%${format}u", a);
 641                           sscanf (buffer, "%${format}u", &b);
 642                           exit (b!=a);
 643                         }
 644                         ],
 645                         [glib_cv_long_long_format=${format}
 646                         break],
 647                         [],[:])
 648                 done])
 649         if test -n "$glib_cv_long_long_format"; then
 650           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 651           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 652           if test x"$glib_cv_long_long_format" = xI64; then
 653             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 654           fi
 655         else
 656           AC_MSG_RESULT(none)
 657         fi
 658 elif test x$ac_cv_sizeof___int64 = x8; then
 659         # __int64 is a 64 bit integer.
 660         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 661         # We know this is MSVCRT.DLL, and what the formats are
 662         glib_cv_long_long_format=I64
 663         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 664         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 665         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 666 fi
 667
 668 AC_C_CONST
 669
 670 dnl ok, here we try to check whether the systems prototypes for
 671 dnl malloc and friends actually match the prototypes provided
 672 dnl by gmem.h (keep in sync). i currently only know how to check
 673 dnl this reliably with gcc (-Werror), improvements for other
 674 dnl compilers are apprechiated.
 675 SANE_MALLOC_PROTOS=no
 676 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 677 glib_save_CFLAGS=$CFLAGS
 678 if test "x$GCC" = "xyes"; then
 679   CFLAGS="$CFLAGS -Werror"
 680   AC_TRY_COMPILE([#include <stdlib.h>], [
 681     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 682     void* (*my_malloc_p)  (size_t)         = malloc;
 683     void  (*my_free_p)    (void*)          = free;
 684     void* (*my_realloc_p) (void*, size_t)  = realloc;
 685     my_calloc_p = 0;
 686     my_malloc_p = 0;
 687     my_free_p = 0;
 688     my_realloc_p = 0;
 689   ],
 690     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 691       [Define if you have correct malloc prototypes])
 692     SANE_MALLOC_PROTOS=yes)
 693 fi
 694 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 695 CFLAGS=$glib_save_CFLAGS
 696
 697 dnl
 698 dnl check in which direction the stack grows
 699 dnl
 700 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 701         AC_TRY_RUN([
 702         volatile int *a = 0, *b = 0;
 703         void foo (void);
 704         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 705         void foo (void) { volatile int x = 5; b = &x; }
 706         ],
 707         glib_cv_stack_grows=no
 708         ,
 709         glib_cv_stack_grows=yes
 710         ,)
 711 ])
 712
 713 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 714 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 715 dnl actually supported.
 716 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 717         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 718         __inline int foo () { return 0; }
 719         int main () { return foo (); }
 720         ]])],
 721         glib_cv_has__inline=yes
 722         ,
 723         glib_cv_has__inline=no
 724         ,)
 725 ])
 726 case x$glib_cv_has__inline in
 727 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 728 esac
 729 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 730         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 731         __inline__ int foo () { return 0; }
 732         int main () { return foo (); }
 733         ]])],
 734         glib_cv_has__inline__=yes
 735         ,
 736         glib_cv_has__inline__=no
 737         ,)
 738 ])
 739 case x$glib_cv_has__inline__ in
 740 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 741 esac
 742 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 743         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 744         #undef inline
 745         inline int foo () { return 0; }
 746         int main () { return foo (); }
 747         ]])],
 748         glib_cv_hasinline=yes
 749         ,
 750         glib_cv_hasinline=no
 751         ,)
 752 ])
 753 case x$glib_cv_hasinline in
 754 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 755 esac
 756
 757 # if we can use inline functions in headers
 758 AC_MSG_CHECKING(if inline functions in headers work)
 759 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 760 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 761 #  undef inline
 762 #  define inline __inline__
 763 #elif !defined (G_HAVE_INLINE)
 764 #  undef inline
 765 #  if defined (G_HAVE___INLINE__)
 766 #    define inline __inline__
 767 #  elif defined (G_HAVE___INLINE)
 768 #    define inline __inline
 769 #  endif
 770 #endif
 771
 772 int glib_test_func2 (int);
 773
 774 static inline int
 775 glib_test_func1 (void) {
 776   return glib_test_func2 (1);
 777 }
 778
 779 int
 780 main (void) {
 781   int i = 1;
 782 }]])],[g_can_inline=yes],[g_can_inline=no])
 783 AC_MSG_RESULT($g_can_inline)
 784
 785 dnl *** check for working do while(0) macros ***
 786 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 787         AC_TRY_COMPILE([],[
 788         #define STMT_START do
 789         #define STMT_END while(0)
 790         #define STMT_TEST STMT_START { i = 0; } STMT_END
 791         int main(void) { int i = 1; STMT_TEST; return i; }],
 792         [g_cv_support_dowhile_macros=yes],
 793         [g_cv_support_dowhile_macros=no],
 794         [g_cv_support_dowhile_macros=yes])
 795 ])
 796 if test x$g_cv_support_dowhile_macros = xyes; then
 797   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 798 fi
 799
 800 # check for flavours of varargs macros
 801 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 802 AC_TRY_COMPILE([],[
 803 int a(int p1, int p2, int p3);
 804 #define call_a(...) a(1,__VA_ARGS__)
 805 call_a(2,3);
 806 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 807 AC_MSG_RESULT($g_have_iso_c_varargs)
 808
 809 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 810 if test "$CXX" = ""; then
 811 dnl No C++ compiler
 812   g_have_iso_cxx_varargs=no
 813 else
 814   AC_LANG_CPLUSPLUS
 815   AC_TRY_COMPILE([],[
 816 int a(int p1, int p2, int p3);
 817 #define call_a(...) a(1,__VA_ARGS__)
 818 call_a(2,3);
 819 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 820   AC_LANG_C
 821 fi
 822 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 823
 824 AC_MSG_CHECKING(for GNUC varargs macros)
 825 AC_TRY_COMPILE([],[
 826 int a(int p1, int p2, int p3);
 827 #define call_a(params...) a(1,params)
 828 call_a(2,3);
 829 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 830 AC_MSG_RESULT($g_have_gnuc_varargs)
 831
 832 # check for GNUC visibility support
 833 AC_MSG_CHECKING(for GNUC visibility attribute)
 834 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 835 void
 836 __attribute__ ((visibility ("hidden")))
 837      f_hidden (void)
 838 {
 839 }
 840 void
 841 __attribute__ ((visibility ("internal")))
 842      f_internal (void)
 843 {
 844 }
 845 void
 846 __attribute__ ((visibility ("protected")))
 847      f_protected (void)
 848 {
 849 }
 850 void
 851 __attribute__ ((visibility ("default")))
 852      f_default (void)
 853 {
 854 }
 855 int main (int argc, char **argv)
 856 {
 857         f_hidden();
 858         f_internal();
 859         f_protected();
 860         f_default();
 861         return 0;
 862 }
 863 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 864 AC_MSG_RESULT($g_have_gnuc_visibility)
 865 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 866
 867 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 868 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 869 #else
 870 # include "error: this is not Sun Studio."
 871 #endif
 872 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 873 AC_MSG_RESULT($g_have_sunstudio_visibility)
 874 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 875
 876 # check for bytesex stuff
 877 AC_C_BIGENDIAN
 878 if test x$ac_cv_c_bigendian = xuniversal ; then
 879 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 880 #else
 881 #error Not a big endian.
 882 #endif],
 883     ac_cv_c_bigendian=yes
 884     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 885 #else
 886 #error Not a little endian.
 887 #endif],
 888     ac_cv_c_bigendian=no
 889     ,AC_MSG_WARN([Could not determine endianness.])))
 890 fi
 891
 892
 893 # check for header files
 894 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 895 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 896 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 897 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h])
 898 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
 899 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 900 AC_CHECK_HEADERS([linux/magic.h])
 901 AC_CHECK_HEADERS([sys/prctl.h])
 902
 903 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
 904 [#if HAVE_SYS_PARAM_H
 905  #include <sys/param.h>
 906  #endif
 907 ])
 908
 909 AC_CHECK_HEADERS([xlocale.h])
 910
 911 # check for structure fields
 912 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 913 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 914 #include <sys/stat.h>
 915 #include <unistd.h>
 916 #ifdef HAVE_SYS_STATFS_H
 917 #include <sys/statfs.h>
 918 #endif
 919 #ifdef HAVE_SYS_PARAM_H
 920 #include <sys/param.h>
 921 #endif
 922 #ifdef HAVE_SYS_MOUNT_H
 923 #include <sys/mount.h>
 924 #endif])
 925 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 926 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 927 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 928 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 929
 930 AC_STRUCT_DIRENT_D_TYPE
 931
 932 # Checks for libcharset
 933 AM_LANGINFO_CODESET
 934 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 935 AC_CHECK_FUNCS(setlocale)
 936
 937 # check additional type sizes
 938 AC_CHECK_SIZEOF(size_t)
 939
 940 dnl Try to figure out whether gsize, gssize should be long or int
 941 AC_MSG_CHECKING([for the appropriate definition for size_t])
 942
 943 case $ac_cv_sizeof_size_t in
 944   $ac_cv_sizeof_short)
 945       glib_size_type=short
 946       ;;
 947   $ac_cv_sizeof_int)
 948       glib_size_type=int
 949       ;;
 950   $ac_cv_sizeof_long)
 951       glib_size_type=long
 952       ;;
 953   $ac_cv_sizeof_long_long)
 954       glib_size_type='long long'
 955       ;;
 956   $ac_cv_sizeof__int64)
 957       glib_size_type='__int64'
 958       ;;
 959   *)  AC_MSG_ERROR([No type matching size_t in size])
 960       ;;
 961 esac
 962
 963 dnl If int/long are the same size, we see which one produces
 964 dnl warnings when used in the location as size_t. (This matters
 965 dnl on AIX with xlc)
 966 dnl
 967 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 968    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 969   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 970 #if defined(_AIX) && !defined(__GNUC__)
 971 #pragma options langlvl=stdc89
 972 #endif
 973 #include <stddef.h>
 974 int main ()
 975 {
 976   size_t s = 1;
 977   unsigned int *size_int = &s;
 978   return (int)*size_int;
 979 }
 980     ]])],glib_size_type=int,
 981       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 982 #if defined(_AIX) && !defined(__GNUC__)
 983 #pragma options langlvl=stdc89
 984 #endif
 985 #include <stddef.h>
 986 int main ()
 987 {
 988    size_t s = 1;
 989    unsigned long *size_long = &s;
 990    return (int)*size_long;
 991 }
 992         ]])],glib_size_type=long)])
 993 fi
 994
 995 AC_MSG_RESULT(unsigned $glib_size_type)
 996
 997 # Check for some functions
 998 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
 999 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid)
1000 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat)
1001 # Check for high-resolution sleep functions
1002 AC_CHECK_FUNCS(splice)
1003 AC_CHECK_FUNCS(prlimit)
1004
1005 # To avoid finding a compatibility unusable statfs, which typically
1006 # successfully compiles, but warns to use the newer statvfs interface:
1007 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
1008 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
1009
1010 AC_MSG_CHECKING([whether to use statfs or statvfs])
1011 # Some systems have both statfs and statvfs, pick the most "native" for these
1012 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
1013    [
1014    # on solaris and irix, statfs doesn't even have the f_bavail field
1015    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
1016       [ac_cv_func_statfs=no],
1017    # else, at least on linux, statfs is the actual syscall
1018       [ac_cv_func_statvfs=no])
1019    ])
1020
1021 AS_IF([test x$ac_cv_func_statfs = xyes],
1022       [
1023          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1024          AC_MSG_RESULT([statfs])
1025       ],
1026       [test x$ac_cv_func_statvfs = xyes],
1027       [
1028          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1029          AC_MSG_RESULT([statvfs])
1030       ],
1031       [  AC_MSG_RESULT([neither])])
1032
1033 AC_CHECK_HEADERS(crt_externs.h)
1034 AC_CHECK_FUNCS(_NSGetEnviron)
1035
1036 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
1037
1038 AC_FUNC_VSNPRINTF_C99
1039 AC_FUNC_PRINTF_UNIX98
1040
1041 # Internet address families
1042 if test $glib_native_win32 = yes; then
1043   glib_inet_includes=["
1044 #include <winsock2.h>
1045   "]
1046 else
1047   glib_inet_includes=["
1048 #include <sys/types.h>
1049 #include <sys/socket.h>
1050   "]
1051 fi
1052
1053 glib_failed=false
1054 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1055 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1056 # winsock defines this even though it doesn't support it
1057 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1058 if $glib_failed ; then
1059   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1060 fi
1061
1062 glib_failed=false
1063 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1064 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1065 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1066 if $glib_failed ; then
1067   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1068 fi
1069
1070 AC_CHECK_FUNCS(getprotobyname_r endservent)
1071 AC_CHECK_HEADERS([netdb.h wspiapi.h arpa/nameser_compat.h])
1072
1073 if test $glib_native_win32 = no; then
1074   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1075   NETWORK_LIBS=""
1076   AC_MSG_CHECKING([for res_query])
1077   AC_TRY_LINK([#include <sys/types.h>
1078                #include <netinet/in.h>
1079                #include <arpa/nameser.h>
1080                #include <resolv.h>
1081               ],[
1082                res_query("test", 0, 0, (void *)0, 0);
1083               ],[AC_MSG_RESULT([yes])],
1084               [save_libs="$LIBS"
1085                LIBS="-lresolv $LIBS"
1086                AC_TRY_LINK([#include <sys/types.h>
1087                             #include <netinet/in.h>
1088                             #include <arpa/nameser.h>
1089                             #include <resolv.h>
1090                            ],[
1091                             res_query("test", 0, 0, (void *)0, 0);
1092                            ],[AC_MSG_RESULT([in -lresolv])
1093                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1094                            [LIBS="-lbind $save_libs"
1095                             AC_TRY_LINK([#include <resolv.h>],
1096                                         [res_query("test", 0, 0, (void *)0, 0);],
1097                                         [AC_MSG_RESULT([in -lbind])
1098                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1099                                         [AC_MSG_ERROR(not found)])])
1100                LIBS="$save_libs"])
1101   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1102                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1103                                         [AC_MSG_ERROR(Could not find socket())]))
1104 fi
1105 AC_SUBST(NETWORK_LIBS)
1106
1107 AC_CHECK_HEADER([linux/netlink.h],
1108                 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1109                 [#include <sys/socket.h>])
1110 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1111
1112 case $host in
1113   *-*-solaris* )
1114      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1115      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1116      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1117      ;;
1118 esac
1119
1120 dnl
1121 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1122 dnl
1123 if test "$ac_cv_func_statfs" = yes ; then
1124   AC_MSG_CHECKING([number of arguments to statfs()])
1125   AC_TRY_COMPILE([#include <unistd.h>
1126   #ifdef HAVE_SYS_PARAM_H
1127   #include <sys/param.h>
1128   #endif
1129   #ifdef HAVE_SYS_VFS_H
1130   #include <sys/vfs.h>
1131   #endif
1132   #ifdef HAVE_SYS_MOUNT_H
1133   #include <sys/mount.h>
1134   #endif
1135   #ifdef HAVE_SYS_STATFS_H
1136   #include <sys/statfs.h>
1137   #endif], [struct statfs st;
1138   statfs(NULL, &st);],[
1139     AC_MSG_RESULT([2])
1140     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1141     AC_TRY_COMPILE([#include <unistd.h>
1142   #ifdef HAVE_SYS_PARAM_H
1143   #include <sys/param.h>
1144   #endif
1145   #ifdef HAVE_SYS_VFS_H
1146   #include <sys/vfs.h>
1147   #endif
1148   #ifdef HAVE_SYS_MOUNT_H
1149   #include <sys/mount.h>
1150   #endif
1151   #ifdef HAVE_SYS_STATFS_H
1152   #include <sys/statfs.h>
1153   #endif], [struct statfs st;
1154   statfs(NULL, &st, sizeof (st), 0);],[
1155       AC_MSG_RESULT([4])
1156       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1157       AC_MSG_RESULT(unknown)
1158       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1159 fi
1160
1161 #
1162 # Check whether to use an included printf
1163 #
1164
1165 AC_ARG_ENABLE(included-printf,
1166               [AC_HELP_STRING([--enable-included-printf],
1167                               [use included printf [default=auto]])],
1168               enable_included_printf="$enableval")
1169
1170 need_included_printf=no
1171 if test "x$enable_included_printf" = "xyes" ; then
1172   need_included_printf=yes
1173 fi
1174 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1175   need_included_printf=yes
1176 fi
1177 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1178   need_included_printf=yes
1179 fi
1180 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1181    test -z "$glib_cv_long_long_format" ; then
1182   need_included_printf=yes
1183 fi
1184
1185 if test "x$enable_included_printf" = "xno" &&
1186    test "x$need_included_printf" = "xyes" ; then
1187   AC_MSG_ERROR([
1188 *** Your C library's printf doesn't appear to have the features that
1189 *** GLib needs, but you specified --enable-included-printf=no.])
1190 fi
1191
1192 enable_included_printf=$need_included_printf
1193
1194 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1195 if test "$enable_included_printf" != "yes" ; then
1196   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1197 else
1198   if test -z "$glib_cv_long_long_format" ; then
1199     glib_cv_long_long_format="ll"
1200   fi
1201   AC_DEFINE(HAVE_VASPRINTF,1)
1202 fi
1203
1204 # Checks needed for gnulib vasnprintf
1205 bh_C_SIGNED
1206 jm_AC_TYPE_LONG_LONG
1207 gt_TYPE_LONGDOUBLE
1208 gt_TYPE_WCHAR_T
1209 gt_TYPE_WINT_T
1210 AC_TYPE_SIZE_T
1211 AC_CHECK_TYPES(ptrdiff_t)
1212 jm_AC_TYPE_INTMAX_T
1213 AC_CHECK_FUNCS([snprintf wcslen])
1214 AC_FUNC_SNPRINTF_C99
1215
1216 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1217 # The check is borrowed from the PERL Configure script.
1218 if test "$ac_cv_func_memmove" != "yes"; then
1219   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1220     glib_cv_working_bcopy,[AC_TRY_RUN([
1221       int main() {
1222         char buf[128], abc[128], *b;
1223         int len, off, align;
1224         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1225         for (align = 7; align >= 0; align--) {
1226           for (len = 36; len; len--) {
1227             b = buf+align; bcopy(abc, b, len);
1228             for (off = 1; off <= len; off++) {
1229               bcopy(b, b+off, len); bcopy(b+off, b, len);
1230                 if (bcmp(b, abc, len)) return(1);
1231             }
1232           }
1233         }
1234         return(0);
1235       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1236
1237   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1238   if test "$glib_cv_working_bcopy" = "yes"; then
1239     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1240   fi
1241 fi
1242
1243 # Check if <sys/select.h> needs to be included for fd_set
1244 AC_MSG_CHECKING([for fd_set])
1245 AC_TRY_COMPILE([#include <sys/types.h>],
1246         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1247 if test "$gtk_ok" = "yes"; then
1248     AC_MSG_RESULT([yes, found in sys/types.h])
1249 else
1250     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1251     if test "$gtk_ok" = "yes"; then
1252         # *** FIXME: give it a different name
1253         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1254         AC_MSG_RESULT([yes, found in sys/select.h])
1255     else
1256         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1257         AC_MSG_RESULT(no)
1258     fi
1259 fi
1260
1261 dnl *** check for sane realloc() ***
1262 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1263         AC_TRY_RUN([#include <stdlib.h>
1264         int main() {
1265           return realloc (0, sizeof (int)) == 0;
1266         }],
1267         [glib_cv_sane_realloc=yes],
1268         [glib_cv_sane_realloc=no],
1269         [glib_cv_sane_realloc=yes])
1270 ])
1271 if test x$glib_cv_sane_realloc = xyes; then
1272   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1273 fi
1274
1275 dnl Check for nl_langinfo and CODESET
1276 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1277         AC_TRY_COMPILE([#include <langinfo.h>],
1278                 [char *codeset = nl_langinfo (CODESET);],
1279                 [glib_cv_langinfo_codeset=yes],
1280                 [glib_cv_langinfo_codeset=no])])
1281 if test x$glib_cv_langinfo_codeset = xyes; then
1282   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1283 fi
1284
1285 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1286 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1287         AC_TRY_COMPILE([#include <langinfo.h>],
1288                 [char *str;
1289                  str = nl_langinfo (PM_STR);
1290                  str = nl_langinfo (D_T_FMT);
1291                  str = nl_langinfo (D_FMT);
1292                  str = nl_langinfo (T_FMT);
1293                  str = nl_langinfo (T_FMT_AMPM);
1294                  str = nl_langinfo (MON_1);
1295                  str = nl_langinfo (ABMON_12);
1296                  str = nl_langinfo (DAY_1);
1297                  str = nl_langinfo (ABDAY_7);],
1298                 [glib_cv_langinfo_time=yes],
1299                 [glib_cv_langinfo_time=no])])
1300 if test x$glib_cv_langinfo_time = xyes; then
1301   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1302 fi
1303
1304 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_WC
1305 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_WC)], glib_cv_langinfo_outdigit,[
1306         AC_TRY_COMPILE([#include <langinfo.h>],
1307                 [char *str;
1308                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_WC);
1309                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_WC);
1310                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_WC);
1311                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_WC);
1312                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_WC);
1313                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_WC);
1314                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_WC);
1315                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_WC);
1316                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_WC);
1317                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_WC);],
1318                 [glib_cv_langinfo_outdigit=yes],
1319                 [glib_cv_langinfo_outdigit=no])])
1320 if test x$glib_cv_langinfo_outdigit = xyes; then
1321   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_WC)])
1322 fi
1323
1324 dnl ****************************************
1325 dnl *** posix_memalign                   ***
1326 dnl ****************************************
1327 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1328 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1329     glib_cv_compliant_posix_memalign=0
1330     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1331         AC_TRY_RUN([
1332                 #define _XOPEN_SOURCE 600
1333                 #include <stdlib.h> /* posix_memalign() should be defined here */
1334                 /* some systems break if #include <malloc.h> used */
1335                 static void test_memalign (size_t boundary, size_t size) {
1336                     void *mem = 0;
1337                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1338                         exit (1);
1339                     else
1340                       free (mem);
1341                 }
1342                 int main() {
1343                     test_memalign (  128,   128 - 2 * sizeof (void*));
1344                     test_memalign (  256,   256 - 2 * sizeof (void*));
1345                     test_memalign (  512,   512 - 2 * sizeof (void*));
1346                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1347                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1348                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1349                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1350                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1351                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1352                     exit (0); /* success */
1353                 }
1354                 ],
1355             [glib_cv_compliant_posix_memalign=1], [], [:])
1356       :
1357     fi
1358     ])
1359 if test "$glib_cv_compliant_posix_memalign" = "1"; then
1360     AC_MSG_RESULT(yes)
1361     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1362 else
1363     AC_MSG_RESULT(no)
1364 fi
1365
1366
1367 dnl ****************************************
1368 dnl *** strlcpy/strlcat                  ***
1369 dnl ****************************************
1370 # Check for strlcpy
1371 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1372 AC_TRY_RUN([#include <stdlib.h>
1373 #include <string.h>
1374 int main() {
1375   char p[10];
1376   (void) strlcpy (p, "hi", 10);
1377   if (strlcat (p, "bye", 0) != 3)
1378     return 1;
1379   return 0;
1380 }], glib_cv_have_strlcpy=yes,
1381     glib_cv_have_strlcpy=no,
1382     glib_cv_have_strlcpy=no)])
1383 if test "$glib_cv_have_strlcpy" = "yes"; then
1384     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1385 fi
1386
1387
1388 dnl **********************
1389 dnl *** va_copy checks ***
1390 dnl **********************
1391 dnl we currently check for all three va_copy possibilities, so we get
1392 dnl all results in config.log for bug reports.
1393 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1394         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1395 #include <stdlib.h>
1396         void f (int i, ...) {
1397         va_list args1, args2;
1398         va_start (args1, i);
1399         va_copy (args2, args1);
1400         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1401           exit (1);
1402         va_end (args1); va_end (args2);
1403         }
1404         int main() {
1405           f (0, 42);
1406           return 0;
1407         }]])],
1408         [glib_cv_va_copy=yes],
1409         [glib_cv_va_copy=no])
1410 ])
1411 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1412         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1413 #include <stdlib.h>
1414         void f (int i, ...) {
1415         va_list args1, args2;
1416         va_start (args1, i);
1417         __va_copy (args2, args1);
1418         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1419           exit (1);
1420         va_end (args1); va_end (args2);
1421         }
1422         int main() {
1423           f (0, 42);
1424           return 0;
1425         }]])],
1426         [glib_cv___va_copy=yes],
1427         [glib_cv___va_copy=no])
1428 ])
1429
1430 if test "x$glib_cv_va_copy" = "xyes"; then
1431   g_va_copy_func=va_copy
1432 else if test "x$glib_cv___va_copy" = "xyes"; then
1433   g_va_copy_func=__va_copy
1434 fi
1435 fi
1436
1437 if test -n "$g_va_copy_func"; then
1438   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1439 fi
1440
1441 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1442         AC_TRY_RUN([#include <stdarg.h>
1443 #include <stdlib.h>
1444         void f (int i, ...) {
1445         va_list args1, args2;
1446         va_start (args1, i);
1447         args2 = args1;
1448         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1449           exit (1);
1450         va_end (args1); va_end (args2);
1451         }
1452         int main() {
1453           f (0, 42);
1454           return 0;
1455         }],
1456         [glib_cv_va_val_copy=yes],
1457         [glib_cv_va_val_copy=no],
1458         [glib_cv_va_val_copy=yes])
1459 ])
1460
1461 if test "x$glib_cv_va_val_copy" = "xno"; then
1462   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1463 fi
1464
1465 dnl ***********************
1466 dnl *** g_module checks ***
1467 dnl ***********************
1468 G_MODULE_LIBS=
1469 G_MODULE_LIBS_EXTRA=
1470 G_MODULE_PLUGIN_LIBS=
1471 if test x"$glib_native_win32" = xyes; then
1472   dnl No use for this on Win32
1473   G_MODULE_LDFLAGS=
1474 else
1475   export SED
1476   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1477 fi
1478 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1479 G_MODULE_NEED_USCORE=0
1480 G_MODULE_BROKEN_RTLD_GLOBAL=0
1481 G_MODULE_HAVE_DLERROR=0
1482 dnl *** force native WIN32 shared lib loader
1483 if test -z "$G_MODULE_IMPL"; then
1484   case "$host" in
1485   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1486   esac
1487 fi
1488 dnl *** force native AIX library loader
1489 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1490 if test -z "$G_MODULE_IMPL"; then
1491   case "$host" in
1492   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1493   esac
1494 fi
1495 dnl *** dlopen() and dlsym() in system libraries
1496 if test -z "$G_MODULE_IMPL"; then
1497         AC_CHECK_FUNC(dlopen,
1498                       [AC_CHECK_FUNC(dlsym,
1499                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1500                       [])
1501 fi
1502 dnl *** load_image (BeOS)
1503 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1504   AC_CHECK_LIB(root, load_image,
1505       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1506       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1507       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1508       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1509       [])
1510 fi
1511 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1512 if test -z "$G_MODULE_IMPL"; then
1513         AC_CHECK_FUNC(NSLinkModule,
1514                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1515                        G_MODULE_NEED_USCORE=1],
1516                       [])
1517 fi
1518 dnl *** dlopen() and dlsym() in libdl
1519 if test -z "$G_MODULE_IMPL"; then
1520         AC_CHECK_LIB(dl, dlopen,
1521                      [AC_CHECK_LIB(dl, dlsym,
1522                                    [G_MODULE_LIBS=-ldl
1523                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1524                      [])
1525 fi
1526 dnl *** shl_load() in libdld (HP-UX)
1527 if test -z "$G_MODULE_IMPL"; then
1528         AC_CHECK_LIB(dld, shl_load,
1529                 [G_MODULE_LIBS=-ldld
1530                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1531                 [])
1532 fi
1533 dnl *** additional checks for G_MODULE_IMPL_DL
1534 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1535         LIBS_orig="$LIBS"
1536         LDFLAGS_orig="$LDFLAGS"
1537         LIBS="$G_MODULE_LIBS $LIBS"
1538         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1539 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1540         echo "void glib_plugin_test(void) { }" > plugin.c
1541         ${SHELL} ./libtool --mode=compile ${CC} -shared \
1542                 -export-dynamic -o plugin.o plugin.c 2>&1 >/dev/null
1543         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1544                 glib_cv_rtldglobal_broken,[
1545                 AC_TRY_RUN([
1546 #include <dlfcn.h>
1547 #ifndef RTLD_GLOBAL
1548 #  define RTLD_GLOBAL 0
1549 #endif
1550 #ifndef RTLD_LAZY
1551 #  define RTLD_LAZY 0
1552 #endif
1553 int glib_plugin_test;
1554 int main () {
1555     void *handle, *global, *local;
1556     global = &glib_plugin_test;
1557     handle = dlopen ("./.libs/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1558     if (!handle) return 0;
1559     local = dlsym (handle, "glib_plugin_test");
1560     return global == local;
1561 }                       ],
1562                         [glib_cv_rtldglobal_broken=no],
1563                         [glib_cv_rtldglobal_broken=yes],
1564                         [glib_cv_rtldglobal_broken=no])
1565                 rm -f plugin.c plugin.o plugin.lo .libs/plugin.o
1566                 rmdir .libs 2>/dev/null
1567         ])
1568         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1569                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1570         else
1571                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1572         fi
1573 dnl *** check whether we need preceeding underscores
1574         AC_CACHE_CHECK([for preceeding underscore in symbols],
1575                 glib_cv_uscore,[
1576                 AC_TRY_RUN([#include <dlfcn.h>
1577                 int glib_underscore_test (void) { return 42; }
1578                 int main() {
1579                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1580                   handle = dlopen ((void*)0, 0);
1581                   if (handle) {
1582                     f1 = dlsym (handle, "glib_underscore_test");
1583                     f2 = dlsym (handle, "_glib_underscore_test");
1584                   } return (!f2 || f1);
1585                 }],
1586                         [glib_cv_uscore=yes],
1587                         [glib_cv_uscore=no],
1588                         [])
1589                 rm -f plugin.c plugin.$ac_objext plugin.lo
1590         ])
1591         GLIB_ASSERT_SET(glib_cv_uscore)
1592         if test "x$glib_cv_uscore" = "xyes"; then
1593                 G_MODULE_NEED_USCORE=1
1594         else
1595                 G_MODULE_NEED_USCORE=0
1596         fi
1597
1598         LDFLAGS="$LDFLAGS_orig"
1599 dnl *** check for having dlerror()
1600         AC_CHECK_FUNC(dlerror,
1601                 [G_MODULE_HAVE_DLERROR=1],
1602                 [G_MODULE_HAVE_DLERROR=0])
1603         LIBS="$LIBS_orig"
1604 fi
1605 dnl *** done, have we got an implementation?
1606 if test -z "$G_MODULE_IMPL"; then
1607         G_MODULE_IMPL=0
1608         G_MODULE_SUPPORTED=false
1609 else
1610         G_MODULE_SUPPORTED=true
1611 fi
1612
1613 AC_MSG_CHECKING(for the suffix of module shared libraries)
1614 export SED
1615 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1616 eval $shrext_cmds
1617 module=yes eval std_shrext=$shrext_cmds
1618 # chop the initial dot
1619 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1620 AC_MSG_RESULT(.$glib_gmodule_suffix)
1621 # any reason it may fail?
1622 if test "x$glib_gmodule_suffix" = x; then
1623         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1624 fi
1625
1626 AC_SUBST(G_MODULE_SUPPORTED)
1627 AC_SUBST(G_MODULE_IMPL)
1628 AC_SUBST(G_MODULE_LIBS)
1629 AC_SUBST(G_MODULE_LIBS_EXTRA)
1630 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1631 AC_SUBST(G_MODULE_LDFLAGS)
1632 AC_SUBST(G_MODULE_HAVE_DLERROR)
1633 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1634 AC_SUBST(G_MODULE_NEED_USCORE)
1635 AC_SUBST(GLIB_DEBUG_FLAGS)
1636
1637 dnl **********************
1638 dnl *** g_spawn checks ***
1639 dnl **********************
1640
1641 AC_MSG_CHECKING(for gspawn implementation)
1642 case "$host" in
1643   *-*-mingw*)
1644     GSPAWN=gspawn-win32.lo
1645     ;;
1646   *)
1647     GSPAWN=gspawn.lo
1648     ;;
1649 esac
1650 AC_MSG_RESULT($GSPAWN)
1651 AC_SUBST(GSPAWN)
1652
1653 dnl *************************
1654 dnl *** GIOChannel checks ***
1655 dnl *************************
1656
1657 AC_MSG_CHECKING(for GIOChannel implementation)
1658 case "$host" in
1659   *-*-mingw*)
1660     GIO=giowin32.lo
1661     ;;
1662   *)
1663     GIO=giounix.lo
1664     ;;
1665 esac
1666 AC_MSG_RESULT($GIO)
1667 AC_SUBST(GIO)
1668
1669 dnl *********************************
1670 dnl *** Directory for GIO modules ***
1671 dnl *********************************
1672
1673 AC_ARG_WITH(gio-module-dir,
1674            [AC_HELP_STRING([--with-gio-module-dir=DIR],
1675                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1676            [],
1677            [with_gio_module_dir='${libdir}/gio/modules'])
1678 GIO_MODULE_DIR=$with_gio_module_dir
1679 AC_SUBST(GIO_MODULE_DIR)
1680
1681 dnl **********************************
1682 dnl *** Check for libselinux (GIO) ***
1683 dnl **********************************
1684 AC_ARG_ENABLE(selinux,
1685               AC_HELP_STRING([--disable-selinux],
1686                              [build without selinux support]))
1687 msg_selinux=no
1688 SELINUX_LIBS=
1689 if test "x$enable_selinux" != "xno"; then
1690
1691  AC_CHECK_LIB(selinux, is_selinux_enabled,
1692    [AC_CHECK_HEADERS(selinux/selinux.h,
1693      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1694        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1695         SELINUX_LIBS="-lselinux"
1696         msg_selinux=yes])
1697      ])
1698    ])
1699 fi
1700 AC_SUBST(SELINUX_LIBS)
1701
1702 dnl *****************************
1703 dnl ** Check for inotify (GIO) **
1704 dnl *****************************
1705 inotify_support=no
1706 AC_CHECK_HEADERS([sys/inotify.h],
1707 [
1708         inotify_support=yes
1709         AC_CHECK_FUNCS(inotify_init1)
1710 ])
1711
1712 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1713
1714 dnl *********************************
1715 dnl ** Check for Solaris FEN (GIO) **
1716 dnl *********************************
1717 fen_support=no
1718 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1719 #include <port.h>
1720 #ifndef PORT_SOURCE_FILE
1721 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1722 #endif
1723 int main() { return 0; } ]])],
1724 [
1725         fen_support=yes
1726 ],)
1727
1728 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1729
1730 dnl ****************************
1731 dnl *** Checks for FAM (GIO) ***
1732 dnl ****************************
1733
1734 should_disable_fam=no
1735
1736 AC_ARG_ENABLE(fam,
1737               AC_HELP_STRING([--disable-fam],
1738                              [don't use fam for file system monitoring]),
1739                          [
1740                                 if test "x$enable_fam" = "xno"; then
1741                                         should_disable_fam=yes
1742                                 fi
1743                          ]
1744                          )
1745 fam_support=no
1746 FAM_LIBS=
1747 if test "x$should_disable_fam" = "xno"; then
1748 AC_CHECK_LIB(fam, FAMOpen,
1749   [AC_CHECK_HEADERS(fam.h,
1750     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1751      AC_CHECK_LIB(fam, FAMNoExists,
1752                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1753      FAM_LIBS="-lfam"]
1754      fam_support=yes,
1755     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1756   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1757 AC_SUBST(FAM_LIBS)
1758 fi
1759 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1760
1761
1762 dnl *****************************
1763 dnl *** Check for xattr (GIO) ***
1764 dnl *****************************
1765 AC_ARG_ENABLE(xattr,
1766               AC_HELP_STRING([--disable-xattr], [build without xattr support]))
1767 msg_xattr=no
1768 XATTR_LIBS=
1769 if test "x$enable_xattr" != "xno"; then
1770
1771 dnl either glibc or libattr can provide xattr support
1772
1773 dnl for both of them, we check for getxattr being in
1774 dnl the library and a valid xattr header.
1775
1776 dnl try glibc
1777  AC_CHECK_LIB(c, getxattr,
1778    [AC_CHECK_HEADERS(sys/xattr.h,
1779      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1780       msg_xattr=yes])
1781    ])
1782
1783   if test "x$msg_xattr" != "xyes"; then
1784 dnl   failure. try libattr
1785    AC_CHECK_LIB(attr, getxattr,
1786       [AC_CHECK_HEADERS(attr/xattr.h,
1787        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1788         XATTR_LIBS="-lattr"
1789         msg_xattr=yes])
1790       ])
1791   fi
1792
1793   if test "x$msg_xattr" = "xyes"; then
1794     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1795     AC_TRY_COMPILE([
1796       #include <stdio.h>
1797       #ifdef HAVE_SYS_TYPES_H
1798       #include <sys/types.h>
1799       #endif
1800       #ifdef HAVE_SYS_XATTR_H
1801       #include <sys/xattr.h>
1802       #elif HAVE_ATTR_XATTR_H
1803       #include <attr/xattr.h>
1804       #endif
1805     ],
1806     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1807     [
1808       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1809       AC_MSG_RESULT([yes])
1810     ],
1811     [AC_MSG_RESULT([no])]
1812     )
1813   fi
1814
1815 fi
1816 AC_SUBST(XATTR_LIBS)
1817
1818 dnl ****************************************
1819 dnl *** platform dependent source checks ***
1820 dnl ****************************************
1821
1822 AC_MSG_CHECKING(for platform-dependent source)
1823 case "$host" in
1824   *-*-cygwin*|*-*-mingw*)
1825     PLATFORMDEP=gwin32.lo
1826     ;;
1827   *)
1828     PLATFORMDEP=
1829     ;;
1830 esac
1831 AC_MSG_RESULT($PLATFORMDEP)
1832 AC_SUBST(PLATFORMDEP)
1833
1834 AC_MSG_CHECKING([whether to compile timeloop])
1835 case "$host" in
1836   *-*-cygwin*|*-*-mingw*|*-*-minix)
1837     enable_timeloop=no
1838     ;;
1839   *)
1840     enable_timeloop=yes
1841     ;;
1842 esac
1843 AC_MSG_RESULT($enable_timeloop)
1844 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1845
1846 AC_MSG_CHECKING([if building for some Win32 platform])
1847 case "$host" in
1848   *-*-mingw*|*-*-cygwin*)
1849     platform_win32=yes
1850     ;;
1851   *)
1852     platform_win32=no
1853     ;;
1854 esac
1855 AC_MSG_RESULT($platform_win32)
1856 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1857
1858 dnl ***********************
1859 dnl *** g_thread checks ***
1860 dnl ***********************
1861
1862 AC_ARG_WITH(threads,
1863            [AC_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1864                            [specify a thread implementation to use])],
1865            [],
1866            [with_threads=yes])
1867
1868 dnl error and warning message
1869 dnl *************************
1870
1871 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1872
1873 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1874                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1875                 compilation now, but then your programs might not work.
1876                 Please provide information on how it is done on your system."
1877
1878 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1879                  "
1880
1881 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1882                   provide information on your thread implementation."
1883
1884 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1885                 functions will not be MT-safe during their first call because
1886                 there is no working 'getpwuid_r' on your system."
1887
1888 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1889                 because there is no 'localtime_r' on your system."
1890
1891 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1892                 linking threaded applications. As GLib cannot do that
1893                 automatically, you will get an linkg error everytime you are
1894                 not using the right compiler. In that case you have to relink
1895                 with the right compiler. Ususally just '_r' is appended
1896                 to the compiler name."
1897
1898 dnl determination of thread implementation
1899 dnl ***************************************
1900
1901 AC_MSG_CHECKING(for thread implementation)
1902
1903 have_threads=no
1904 if test "x$with_threads" = xyes || test "x$with_threads" = xposix; then
1905         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1906         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1907         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1908         glib_save_CPPFLAGS="$CPPFLAGS"
1909         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1910         if test "x$have_threads" = xno; then
1911                 AC_TRY_COMPILE([#include <pthread.h>],
1912                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1913                         have_threads=posix)
1914         fi
1915         # Tru64Unix requires -pthread to find pthread.h. See #103020
1916         CPPFLAGS="$CPPFLAGS -pthread"
1917         if test "x$have_threads" = xno; then
1918         AC_TRY_COMPILE([#include <pthread.h>],
1919                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1920                        have_threads=posix)
1921         fi
1922         CPPFLAGS="$glib_save_CPPFLAGS"
1923 fi
1924 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1925         case $host in
1926                 *-*-mingw*)
1927                 have_threads=win32
1928                 ;;
1929         esac
1930 fi
1931
1932 if test "x$have_threads" = xno; then
1933         AC_MSG_RESULT(none available)
1934         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1935 else
1936         AC_MSG_RESULT($have_threads)
1937 fi
1938
1939
1940 dnl determination of G_THREAD_CFLAGS
1941 dnl ********************************
1942
1943 G_THREAD_LIBS=
1944 G_THREAD_LIBS_EXTRA=
1945 G_THREAD_CFLAGS=
1946
1947 dnl
1948 dnl Test program for basic POSIX threads functionality
1949 dnl
1950 m4_define([glib_thread_test],[
1951 #include <pthread.h>
1952 int check_me = 0;
1953 void* func(void* data) {check_me = 42; return &check_me;}
1954 int main()
1955  { pthread_t t;
1956    void *ret;
1957    pthread_create (&t, $1, func, 0);
1958    pthread_join (t, &ret);
1959    return (check_me != 42 || ret != &check_me);
1960 }])
1961
1962 if test x"$have_threads" = xposix; then
1963   # First we test for posix, whether -pthread or -pthreads do the trick as
1964   # both CPPFLAG and LIBS.
1965   # One of them does for most gcc versions and some other platforms/compilers
1966   # too and could be considered as the canonical way to go.
1967   case $host in
1968     *-*-cygwin*|*-*-darwin*)
1969        # skip cygwin and darwin -pthread or -pthreads test
1970        ;;
1971     *-solaris*)
1972       # These compiler/linker flags work with both Sun Studio and gcc
1973       # Sun Studio expands -mt to -D_REENTRANT and -lthread
1974       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
1975       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
1976       G_THREAD_LIBS="-lpthread -lthread"
1977       ;;
1978     *)
1979       for flag in pthread pthreads mt; do
1980         glib_save_CFLAGS="$CFLAGS"
1981         CFLAGS="$CFLAGS -$flag"
1982         AC_TRY_RUN(glib_thread_test(0),
1983                    glib_flag_works=yes,
1984                    glib_flag_works=no,
1985                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
1986                                    glib_flag_works=yes,
1987                                    glib_flag_works=no)])
1988         CFLAGS="$glib_save_CFLAGS"
1989         if test $glib_flag_works = yes ; then
1990            G_THREAD_CFLAGS=-$flag
1991         G_THREAD_LIBS=-$flag
1992         break;
1993         fi
1994       done
1995        ;;
1996   esac
1997 fi
1998
1999 if test x"$G_THREAD_CFLAGS" = x; then
2000
2001   # The canonical -pthread[s] does not work. Try something different.
2002
2003   case $host in
2004         *-aix*)
2005                 if test x"$GCC" = xyes; then
2006                         # GCC 3.0 and above needs -pthread.
2007                         # Should be coverd by the case above.
2008                         # GCC 2.x and below needs -mthreads
2009                         G_THREAD_CFLAGS="-mthreads"
2010                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2011                 else
2012                         # We are probably using the aix compiler. Normaly a
2013                         # program would have to be compiled with the _r variant
2014                         # of the corresponding compiler, but we as GLib cannot
2015                         # do that: but the good news is that for compiling the
2016                         # only difference is the added -D_THREAD_SAFE compile
2017                         # option. This is according to the "C for AIX User's
2018                         # Guide".
2019                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2020                 fi
2021                 ;;
2022         *-dg-dgux*)  # DG/UX
2023                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2024                 ;;
2025         *-sysv5uw7*) # UnixWare 7
2026                 # We are not using gcc with -pthread. Catched above.
2027                 G_THREAD_CFLAGS="-Kthread"
2028                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2029                 ;;
2030         *-mingw*)
2031                 # No flag needed when using MSVCRT.DLL
2032                 G_THREAD_CFLAGS=""
2033                 ;;
2034         *)
2035                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2036                 ;;
2037   esac
2038
2039 fi
2040
2041 # if we are not finding the localtime_r function, then we probably are
2042 # not using the proper multithread flag
2043
2044 glib_save_CPPFLAGS="$CPPFLAGS"
2045 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2046
2047 # First we test, whether localtime_r is declared in time.h
2048 # directly. Then we test whether a macro localtime_r exists, in
2049 # which case localtime_r in the test program is replaced and thus
2050 # if we still find localtime_r in the output, it is not defined as
2051 # a macro.
2052
2053 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2054   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2055                                                            localtime_r(a,b)],
2056                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2057
2058 CPPFLAGS="$glib_save_CPPFLAGS"
2059
2060 AC_MSG_CHECKING(thread related cflags)
2061 AC_MSG_RESULT($G_THREAD_CFLAGS)
2062 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2063
2064 dnl determination of G_THREAD_LIBS
2065 dnl ******************************
2066
2067 case $have_threads in
2068         posix)
2069           glib_save_CPPFLAGS="$CPPFLAGS"
2070           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2071           if test x"$G_THREAD_LIBS" = x; then
2072             case $host in
2073               *-aix*)
2074                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2075                 # probably using the aix compiler.
2076                 AC_MSG_WARN($AIX_COMPILE_INFO)
2077                 ;;
2078               *)
2079                 G_THREAD_LIBS=error
2080                 glib_save_LIBS="$LIBS"
2081                 for thread_lib in "" pthread pthread32 pthreads thread; do
2082                         if test x"$thread_lib" = x; then
2083                                 add_thread_lib=""
2084                                 IN=""
2085                         else
2086                                 add_thread_lib="-l$thread_lib"
2087                                 IN=" in -l$thread_lib"
2088                         fi
2089                         if test x"$have_threads" = xposix; then
2090                                 defattr=0
2091                         else
2092                                 defattr=pthread_attr_default
2093                         fi
2094
2095                         LIBS="$add_thread_lib $glib_save_LIBS"
2096
2097                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2098                         AC_TRY_RUN(glib_thread_test($defattr),
2099                                    glib_result=yes,
2100                                    glib_result=no,
2101                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2102                                                    glib_result=yes,
2103                                                    glib_result=no)])
2104                         AC_MSG_RESULT($glib_result)
2105
2106                         if test "$glib_result" = "yes" ; then
2107                           G_THREAD_LIBS="$add_thread_lib"
2108                           break
2109                         fi
2110                 done
2111                 if test "x$G_THREAD_LIBS" = xerror; then
2112                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2113                 fi
2114                 LIBS="$glib_save_LIBS"
2115                 ;;
2116             esac
2117           fi
2118
2119           g_threads_impl="POSIX"
2120           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2121           CPPFLAGS="$glib_save_CPPFLAGS"
2122           ;;
2123         win32)
2124            g_threads_impl="WIN32"
2125            ;;
2126         *)
2127            g_threads_impl="NONE"
2128            G_THREAD_LIBS=error
2129            ;;
2130 esac
2131
2132 if test "x$G_THREAD_LIBS" = xerror; then
2133         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2134 fi
2135
2136 case $host in
2137   *-*-beos*)
2138     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2139     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2140     ;;
2141   *)
2142     ;;
2143 esac
2144
2145 AC_MSG_CHECKING(thread related libraries)
2146 AC_MSG_RESULT($G_THREAD_LIBS)
2147
2148 dnl check for mt safe function variants and some posix functions
2149 dnl ************************************************************
2150
2151 glib_save_LIBS="$LIBS"
2152 # we are not doing the following for now, as this might require glib
2153 # to always be linked with the thread libs on some platforms.
2154 # LIBS="$LIBS $G_THREAD_LIBS"
2155 AC_CHECK_FUNCS(localtime_r gmtime_r)
2156 if test "$ac_cv_header_pwd_h" = "yes"; then
2157         AC_CACHE_CHECK([for posix getpwuid_r],
2158                 ac_cv_func_posix_getpwuid_r,
2159                 [AC_TRY_RUN([
2160 #include <errno.h>
2161 #include <pwd.h>
2162 int main () {
2163     char buffer[10000];
2164     struct passwd pwd, *pwptr = &pwd;
2165     int error;
2166     errno = 0;
2167     error = getpwuid_r (0, &pwd, buffer,
2168                         sizeof (buffer), &pwptr);
2169    return (error < 0 && errno == ENOSYS)
2170            || error == ENOSYS;
2171 }                               ],
2172                         [ac_cv_func_posix_getpwuid_r=yes],
2173                         [ac_cv_func_posix_getpwuid_r=no])])
2174         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2175         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2176                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2177                         [Have POSIX function getpwuid_r])
2178         else
2179                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2180                         ac_cv_func_nonposix_getpwuid_r,
2181                         [AC_TRY_LINK([#include <pwd.h>],
2182                                 [char buffer[10000];
2183                                 struct passwd pwd;
2184                                 getpwuid_r (0, &pwd, buffer,
2185                                                 sizeof (buffer));],
2186                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2187                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2188                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2189                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2190                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2191                                 [Have non-POSIX function getpwuid_r])
2192                 fi
2193         fi
2194 fi
2195 if test "$ac_cv_header_grp_h" = "yes"; then
2196         AC_CACHE_CHECK([for posix getgrgid_r],
2197                 ac_cv_func_posix_getgrgid_r,
2198                 [AC_TRY_RUN([
2199 #include <errno.h>
2200 #include <grp.h>
2201 int main () {
2202     char buffer[10000];
2203     struct group grp, *grpptr = &grp;
2204     int error;
2205     errno = 0;
2206     error = getgrgid_r (0, &grp, buffer,
2207                         sizeof (buffer), &grpptr);
2208    return (error < 0 && errno == ENOSYS)
2209            || error == ENOSYS;
2210 }                              ],
2211                        [ac_cv_func_posix_getgrgid_r=yes],
2212                        [ac_cv_func_posix_getgrgid_r=no])])
2213         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2214         if test "$ac_cv_func_posix_getgrgid_r" = yes; then
2215                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2216                         [Have POSIX function getgrgid_r])
2217         else
2218                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2219                         ac_cv_func_nonposix_getgrgid_r,
2220                         [AC_TRY_LINK([#include <grp.h>],
2221                                 [char buffer[10000];
2222                                 struct group grp;
2223                                 getgrgid_r (0, &grp, buffer,
2224                                 sizeof (buffer));],
2225                         [ac_cv_func_nonposix_getgrgid_r=yes],
2226                         [ac_cv_func_nonposix_getgrgid_r=no])])
2227                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2228                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2229                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2230                                 [Have non-POSIX function getgrgid_r])
2231                 fi
2232         fi
2233 fi
2234 LIBS="$G_THREAD_LIBS $LIBS"
2235 if test x"$have_threads" = xposix; then
2236         glib_save_CPPFLAGS="$CPPFLAGS"
2237         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2238         # This is not AC_CHECK_FUNC to also work with function
2239         # name mangling in header files.
2240         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2241         AC_TRY_LINK([#include <pthread.h>],
2242                     [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
2243                     [AC_MSG_RESULT(yes)
2244                      AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,[Have function pthread_attr_setstacksize])],
2245                     [AC_MSG_RESULT(no)])
2246         CPPFLAGS="$glib_save_CPPFLAGS"
2247 fi
2248
2249 LIBS="$glib_save_LIBS"
2250
2251 # now spit out all the warnings.
2252 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2253    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2254         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2255 fi
2256 if test "$ac_cv_func_localtime_r" != "yes"; then
2257         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2258 fi
2259
2260 #
2261 # Hack to deal with:
2262 #
2263 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2264 #     building shared libraries with linux.
2265 #  b) FreeBSD doesn't do this either.
2266 #
2267 case $host in
2268   *-*-freebsd*|*-*-linux*)
2269     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2270     ;;
2271   *-*-openbsd*)
2272     LDFLAGS="$LDFLAGS -pthread"
2273     ;;
2274   *)
2275     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2276     ;;
2277 esac
2278
2279 AC_SUBST(G_THREAD_CFLAGS)
2280 AC_SUBST(G_THREAD_LIBS)
2281 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2282 AC_SUBST(G_THREAD_LIBS_EXTRA)
2283
2284 AC_CHECK_FUNCS(clock_gettime, [], [
2285   AC_CHECK_LIB(rt, clock_gettime, [
2286     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2287     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2288     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2289     GLIB_RT_LIBS="-lrt"
2290   ])
2291 ])
2292 AC_SUBST(GLIB_RT_LIBS)
2293
2294
2295 dnl ************************
2296 dnl *** g_atomic_* tests ***
2297 dnl ************************
2298
2299 dnl We need to decide at configure time if GLib will use real atomic
2300 dnl operations ("lock free") or emulated ones with a mutex.  This is
2301 dnl because we must put this information in glibconfig.h so we know if
2302 dnl it is safe or not to inline using compiler intrinsics directly from
2303 dnl the header.
2304 dnl
2305 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2306 dnl user is interested in knowing if they can use the atomic ops across
2307 dnl processes.
2308 dnl
2309 dnl We can currently support the atomic ops natively when building GLib
2310 dnl with recent versions of GCC or MSVC.  MSVC doesn't run ./configure,
2311 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2312 dnl we are using GCC.
2313 dnl
2314 dnl Note that the atomic ops are only available with GCC on x86 when
2315 dnl using -march=i486 or higher.  If we detect that the atomic ops are
2316 dnl not available but would be available given the right flags, we want
2317 dnl to abort and advise the user to fix their CFLAGS.  It's better to do
2318 dnl that then to silently fall back on emulated atomic ops just because
2319 dnl the user had the wrong build environment.
2320
2321 dnl We may add other compilers here in the future...
2322 AC_MSG_CHECKING([for lock-free atomic intrinsics])
2323 AC_TRY_COMPILE([],
2324                [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2325                [glib_cv_g_atomic_lock_free=yes],
2326                [glib_cv_g_atomic_lock_free=no])
2327 AC_MSG_RESULT($glib_cv_g_atomic_lock_free)
2328
2329 if test "$glib_cv_g_atomic_lock_free" = "no"; then
2330   SAVE_CFLAGS="${CFLAGS}"
2331   CFLAGS="-march=i486"
2332   AC_TRY_COMPILE([],
2333                  [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2334                  [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2335                  [])
2336   CFLAGS="${SAVE_CFLAGS}"
2337 fi
2338
2339 dnl We need a more robust approach here...
2340 case $host_cpu in
2341   i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2342     glib_memory_barrier_needed=no
2343     ;;
2344   sparc*|alpha*|powerpc*|ia64)
2345     glib_memory_barrier_needed=yes
2346     ;;
2347   *)
2348     glib_memory_barrier_needed=yes
2349     ;;
2350 esac
2351
2352 dnl ************************
2353 dnl ** Check for futex(2) **
2354 dnl ************************
2355 AC_CACHE_CHECK(for futex(2) system call,
2356     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2357 #include <linux/futex.h>
2358 #include <sys/syscall.h>
2359 #include <unistd.h>
2360 ],[
2361 int
2362 main (void)
2363 {
2364   /* it is not like this actually runs or anything... */
2365   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2366   return 0;
2367 }
2368 ])],glib_cv_futex=yes,glib_cv_futex=no))
2369 if test x"$glib_cv_futex" = xyes; then
2370   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2371 fi
2372
2373 AC_CACHE_CHECK(for eventfd(2) system call,
2374     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2375 #include <sys/eventfd.h>
2376 #include <unistd.h>
2377 ],[
2378 int
2379 main (void)
2380 {
2381   eventfd (0, EFD_CLOEXEC);
2382   return 0;
2383 }
2384 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2385 if test x"$glib_cv_eventfd" = x"yes"; then
2386   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2387 fi
2388 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2389
2390 dnl ****************************************
2391 dnl *** GLib POLL* compatibility defines ***
2392 dnl ****************************************
2393
2394 glib_poll_includes=["
2395 #include <sys/types.h>
2396 #include <sys/poll.h>
2397 "]
2398
2399 if test $ac_cv_header_sys_types_h = yes &&
2400    test $ac_cv_header_sys_poll_h = yes ; then
2401   glib_failed=false
2402   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2403   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2404   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2405   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2406   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2407   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2408   if $glib_failed ; then
2409     AC_MSG_ERROR([Could not determine values for POLL* constants])
2410   fi
2411 else
2412   glib_cv_value_POLLIN=1
2413   glib_cv_value_POLLOUT=4
2414   glib_cv_value_POLLPRI=2
2415   glib_cv_value_POLLERR=8
2416   glib_cv_value_POLLHUP=16
2417   glib_cv_value_POLLNVAL=32
2418 fi
2419
2420 AC_MSG_CHECKING([for broken poll])
2421 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2422         #include <stdlib.h>
2423         #include <fcntl.h>
2424         #include <poll.h>
2425         #ifdef HAVE_SYS_POLL_H
2426         #include <sys/poll.h>
2427         #endif
2428         int main(void) {
2429           struct pollfd fds[1];
2430           int fd;
2431           fd = open("/dev/null", 1);
2432           fds[0].fd = fd;
2433           fds[0].events = POLLIN;
2434           fds[0].revents = 0;
2435           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2436                 exit(1);  /* Does not work for devices -- fail */
2437           }
2438           exit(0);
2439         }]])],
2440   [broken_poll=no],
2441   [broken_poll=yes
2442    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2443   [broken_poll="no (cross compiling)"])
2444 AC_MSG_RESULT($broken_poll)
2445
2446 dnl *********************
2447 dnl *** GRegex checks ***
2448 dnl *********************
2449 PCRE_REQUIRED_VERSION=8.11
2450
2451 # Check if we should compile GRegex
2452 AC_ARG_ENABLE(regex, AC_HELP_STRING([--disable-regex],
2453                                     [disable the compilation of GRegex]),
2454 [case "${enableval}" in
2455   yes) enable_regex=true ;;
2456   no)  enable_regex=false ;;
2457   *) AC_MSG_ERROR(bad value ${enableval} for --enable-regex) ;;
2458 esac],
2459 [enable_regex=true])
2460
2461 AM_CONDITIONAL(ENABLE_REGEX, $enable_regex)
2462
2463 if test x$enable_regex = xtrue; then
2464   AC_DEFINE(ENABLE_REGEX, [], [include GRegex])
2465   # Check if we should use the internal or the system-supplied pcre
2466   AC_ARG_WITH(pcre,
2467              [AC_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2468                              [whether to use system PCRE [default=internal]])])
2469
2470   AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2471
2472   if test "x$with_pcre" = xsystem; then
2473     PKG_CHECK_MODULES(PCRE,
2474                       libpcre >= $PCRE_REQUIRED_VERSION)
2475     AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2476                    glib_save_CFLAGS="$CFLAGS"
2477                    glib_save_LIBS="$LIBS"
2478                    CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2479                    AC_TRY_RUN([#include <pcre.h>
2480                                int main () {
2481                                  int support;
2482                                  pcre_config (PCRE_CONFIG_UTF8, &support);
2483                                  if (!support)
2484                                    return 1;
2485                                  pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2486                                  if (!support)
2487                                    return 1;
2488                                  return 0;
2489                                }],
2490                    glib_cv_pcre_has_unicode=yes,
2491                    glib_cv_pcre_has_unicode=no,
2492                    glib_cv_pcre_has_unicode=yes)
2493                    CFLAGS="$glib_save_CFLAGS"
2494                    LIBS="$glib_save_LIBS"
2495         ])
2496     if test "$glib_cv_pcre_has_unicode" = "no"; then
2497       AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2498     fi
2499     AC_SUBST(PCRE_CFLAGS)
2500     AC_SUBST(PCRE_LIBS)
2501     AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2502     PCRE_REQUIRES=libpcre
2503     AC_SUBST(PCRE_REQUIRES)
2504   else
2505     # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2506     if test x"$GCC" = xyes; then
2507       AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2508       save_CFLAGS="$CFLAGS"
2509       CFLAGS="$CFLAGS -Wno-pointer-sign"
2510       AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2511                             AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2512       CFLAGS="$save_CFLAGS"
2513     fi
2514   fi
2515   AC_SUBST(PCRE_WARN_CFLAGS)
2516 else
2517   AM_CONDITIONAL(USE_SYSTEM_PCRE, false])
2518 fi
2519
2520 dnl **********************
2521 dnl *** Win32 API libs ***
2522 dnl **********************
2523
2524 case $host in
2525   *-*-cygwin*)
2526         G_LIBS_EXTRA="-luser32 -lkernel32"
2527     ;;
2528   *-*-mingw*)
2529         G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm"
2530     ;;
2531   *)
2532         G_LIBS_EXTRA=""
2533     ;;
2534 esac
2535 AC_SUBST(G_LIBS_EXTRA)
2536
2537 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2538 dnl since we need it for g_iconv()
2539
2540 AC_MSG_CHECKING([for EILSEQ])
2541 AC_TRY_COMPILE([
2542 #include <errno.h>
2543 ],
2544 [
2545 int error = EILSEQ;
2546 ], have_eilseq=yes, have_eilseq=no);
2547 AC_MSG_RESULT($have_eilseq)
2548
2549 dnl ******************************************************************
2550 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2551 dnl *** glib-compile-schemas in PATH                               ***
2552 dnl ******************************************************************
2553
2554 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2555
2556 if test $cross_compiling = yes; then
2557   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2558   if test x$GLIB_GENMARSHAL = xno; then
2559     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2560   fi
2561
2562   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2563   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2564     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2565   fi
2566 fi
2567
2568 dnl **************************
2569 dnl *** Checks for gtk-doc ***
2570 dnl **************************
2571
2572 GTK_DOC_CHECK([1.15], [--flavour no-tmpl])
2573
2574 AC_ARG_ENABLE(man,
2575               [AC_HELP_STRING([--enable-man],
2576                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2577               enable_man=no)
2578
2579 if test "${enable_man}" != no; then
2580 dnl
2581 dnl Check for xsltproc
2582 dnl
2583 AC_PATH_PROG([XSLTPROC], [xsltproc])
2584   if test -z "$XSLTPROC"; then
2585     enable_man=no
2586   fi
2587
2588   dnl check for DocBook DTD and stylesheets in the local catalog.
2589   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2590      [DocBook XML DTD V4.1.2],,enable_man=no)
2591   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2592      [DocBook XSL Stylesheets],,enable_man=no)
2593 fi
2594
2595 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2596
2597 dnl
2598 dnl Tracing
2599 dnl
2600
2601 AC_ARG_ENABLE([dtrace],
2602              [AS_HELP_STRING([--enable-dtrace],
2603                               [include tracing support for dtrace])])
2604 have_dtrace=no
2605 AC_MSG_CHECKING([whether to include dtrace tracing support])
2606 if test "x$enable_dtrace" != xno; then
2607   if test x$glib_have_carbon = xyes; then
2608     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2609   else
2610     AC_MSG_RESULT([yes])
2611     AC_CHECK_PROGS(DTRACE, dtrace)
2612     if test -z "$DTRACE"; then
2613       if test "x$enable_dtrace" = xyes; then
2614         AC_MSG_ERROR([dtrace not found])
2615       fi
2616     else
2617       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2618                       [if test "x$enable_dtrace" = xyes; then
2619                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2620                        fi])
2621     fi
2622   fi
2623 else
2624   AC_MSG_RESULT([no])
2625 fi
2626 if test "x$have_dtrace" = xyes; then
2627   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2628 fi
2629 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2630
2631 AC_MSG_CHECKING([whether to include systemtap tracing support])
2632 AC_ARG_ENABLE([systemtap],
2633              [AS_HELP_STRING([--enable-systemtap],
2634                               [include tracing support for systemtap])])
2635 have_systemtap=no
2636 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2637   have_systemtap=yes
2638 fi
2639 AC_MSG_RESULT(${have_systemtap})
2640
2641 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2642
2643 AC_ARG_WITH([tapset-install-dir],
2644             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2645                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2646             [if test "x${withval}" = x; then
2647                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2648              else
2649                ABS_TAPSET_DIR="${withval}"
2650               fi],
2651             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2652 AC_SUBST(ABS_TAPSET_DIR)
2653
2654 dnl ************************************
2655 dnl *** Enable lcov coverage reports ***
2656 dnl ************************************
2657
2658 AC_ARG_ENABLE(gcov,
2659   AS_HELP_STRING([--enable-gcov],
2660                  [enable coverage testing with gcov]),
2661   [use_gcov=$enableval], [use_gcov=no])
2662
2663 if test "x$use_gcov" = "xyes"; then
2664   dnl we need gcc:
2665   if test "$GCC" != "yes"; then
2666     AC_MSG_ERROR([GCC is required for --enable-gcov])
2667   fi
2668
2669   dnl Check if ccache is being used
2670   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2671   case `$SHTOOL path $CC` in
2672     *ccache*[)] gcc_ccache=yes;;
2673     *[)] gcc_ccache=no;;
2674   esac
2675
2676   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2677     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2678   fi
2679
2680   ltp_version_list="1.6 1.7 1.8 1.9"
2681   AC_CHECK_PROG(LTP, lcov, lcov)
2682   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2683
2684   if test "$LTP"; then
2685     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2686       glib_cv_ltp_version=invalid
2687       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2688       for ltp_check_version in $ltp_version_list; do
2689         if test "$ltp_version" = "$ltp_check_version"; then
2690           glib_cv_ltp_version="$ltp_check_version (ok)"
2691         fi
2692       done
2693     ])
2694   else
2695     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2696     AC_MSG_ERROR([$ltp_msg])
2697   fi
2698
2699   case $glib_cv_ltp_version in
2700     ""|invalid[)]
2701       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2702       AC_MSG_ERROR([$ltp_msg])
2703       LTP="exit 0;"
2704       ;;
2705   esac
2706
2707   if test -z "$LTP_GENHTML"; then
2708     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2709   fi
2710
2711   dnl Remove all optimization flags from CFLAGS
2712   changequote({,})
2713   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2714   changequote([,])
2715
2716   dnl Add the special gcc flags
2717   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2718   LDFLAGS="$LDFLAGS -lgcov"
2719 fi
2720
2721 dnl ******************************
2722 dnl *** output the whole stuff ***
2723 dnl ******************************
2724
2725 dnl this section will only be run if config.status is invoked with no
2726 dnl arguments, or with "glib/glibconfig.h" as an argument.
2727 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2728 [
2729         outfile=glib/glibconfig.h-tmp
2730         cat > $outfile <<\_______EOF
2731 /* glibconfig.h
2732  *
2733  * This is a generated file.  Please modify 'configure.ac'
2734  */
2735
2736 #ifndef __GLIBCONFIG_H__
2737 #define __GLIBCONFIG_H__
2738
2739 #include <glib/gmacros.h>
2740
2741 _______EOF
2742
2743         if test x$glib_limits_h = xyes; then
2744           echo '#include <limits.h>' >> $outfile
2745         fi
2746         if test x$glib_float_h = xyes; then
2747           echo '#include <float.h>' >> $outfile
2748         fi
2749         if test x$glib_values_h = xyes; then
2750           echo '#include <values.h>' >> $outfile
2751         fi
2752         if test "$glib_header_alloca_h" = "yes"; then
2753           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2754         fi
2755         if test x$glib_sys_poll_h = xyes; then
2756           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2757         fi
2758         if test x$glib_included_printf != xyes; then
2759           echo "
2760 /* Specifies that GLib's g_print*() functions wrap the
2761  * system printf functions.  This is useful to know, for example,
2762  * when using glibc's register_printf_function().
2763  */" >> $outfile
2764           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2765         fi
2766
2767         cat >> $outfile <<_______EOF
2768
2769 G_BEGIN_DECLS
2770
2771 #define G_MINFLOAT      $glib_mf
2772 #define G_MAXFLOAT      $glib_Mf
2773 #define G_MINDOUBLE     $glib_md
2774 #define G_MAXDOUBLE     $glib_Md
2775 #define G_MINSHORT      $glib_ms
2776 #define G_MAXSHORT      $glib_Ms
2777 #define G_MAXUSHORT     $glib_Mus
2778 #define G_MININT        $glib_mi
2779 #define G_MAXINT        $glib_Mi
2780 #define G_MAXUINT       $glib_Mui
2781 #define G_MINLONG       $glib_ml
2782 #define G_MAXLONG       $glib_Ml
2783 #define G_MAXULONG      $glib_Mul
2784
2785 _______EOF
2786
2787
2788         ### this should always be true in a modern C/C++ compiler
2789         cat >>$outfile <<_______EOF
2790 typedef signed char gint8;
2791 typedef unsigned char guint8;
2792 _______EOF
2793
2794
2795         if test -n "$gint16"; then
2796           cat >>$outfile <<_______EOF
2797 typedef signed $gint16 gint16;
2798 typedef unsigned $gint16 guint16;
2799 #define G_GINT16_MODIFIER $gint16_modifier
2800 #define G_GINT16_FORMAT $gint16_format
2801 #define G_GUINT16_FORMAT $guint16_format
2802 _______EOF
2803         fi
2804
2805
2806         if test -n "$gint32"; then
2807           cat >>$outfile <<_______EOF
2808 typedef signed $gint32 gint32;
2809 typedef unsigned $gint32 guint32;
2810 #define G_GINT32_MODIFIER $gint32_modifier
2811 #define G_GINT32_FORMAT $gint32_format
2812 #define G_GUINT32_FORMAT $guint32_format
2813 _______EOF
2814         fi
2815
2816         cat >>$outfile <<_______EOF
2817 #define G_HAVE_GINT64 1          /* deprecated, always true */
2818
2819 ${glib_extension}typedef signed $gint64 gint64;
2820 ${glib_extension}typedef unsigned $gint64 guint64;
2821
2822 #define G_GINT64_CONSTANT(val)  $gint64_constant
2823 #define G_GUINT64_CONSTANT(val) $guint64_constant
2824 _______EOF
2825
2826         if test x$gint64_format != x ; then
2827           cat >>$outfile <<_______EOF
2828 #define G_GINT64_MODIFIER $gint64_modifier
2829 #define G_GINT64_FORMAT $gint64_format
2830 #define G_GUINT64_FORMAT $guint64_format
2831 _______EOF
2832         else
2833           cat >>$outfile <<_______EOF
2834 #undef G_GINT64_MODIFIER
2835 #undef G_GINT64_FORMAT
2836 #undef G_GUINT64_FORMAT
2837 _______EOF
2838         fi
2839
2840         cat >>$outfile <<_______EOF
2841
2842 #define GLIB_SIZEOF_VOID_P $glib_void_p
2843 #define GLIB_SIZEOF_LONG   $glib_long
2844 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2845
2846 _______EOF
2847
2848         cat >>$outfile <<_______EOF
2849 typedef signed $glib_size_type_define gssize;
2850 typedef unsigned $glib_size_type_define gsize;
2851 #define G_GSIZE_MODIFIER $gsize_modifier
2852 #define G_GSSIZE_FORMAT $gssize_format
2853 #define G_GSIZE_FORMAT $gsize_format
2854
2855 #define G_MAXSIZE       G_MAXU$glib_msize_type
2856 #define G_MINSSIZE      G_MIN$glib_msize_type
2857 #define G_MAXSSIZE      G_MAX$glib_msize_type
2858
2859 typedef gint64 goffset;
2860 #define G_MINOFFSET     G_MININT64
2861 #define G_MAXOFFSET     G_MAXINT64
2862
2863 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
2864 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
2865 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2866
2867 _______EOF
2868
2869         if test -z "$glib_unknown_void_p"; then
2870           cat >>$outfile <<_______EOF
2871
2872 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2873 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2874
2875 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2876 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2877
2878 typedef signed $glib_intptr_type_define gintptr;
2879 typedef unsigned $glib_intptr_type_define guintptr;
2880
2881 #define G_GINTPTR_MODIFIER      $gintptr_modifier
2882 #define G_GINTPTR_FORMAT        $gintptr_format
2883 #define G_GUINTPTR_FORMAT       $guintptr_format
2884 _______EOF
2885         else
2886           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2887         fi
2888
2889
2890
2891         cat >>$outfile <<_______EOF
2892 $glib_atexit
2893 $glib_memmove
2894 $glib_defines
2895 $glib_os
2896 $glib_static_compilation
2897
2898 $glib_vacopy
2899
2900 #ifdef  __cplusplus
2901 #define G_HAVE_INLINE   1
2902 #else   /* !__cplusplus */
2903 $glib_inline
2904 #endif  /* !__cplusplus */
2905
2906 #ifdef  __cplusplus
2907 #define G_CAN_INLINE    1
2908 _______EOF
2909
2910         if test x$g_can_inline = xyes ; then
2911                 cat >>$outfile <<_______EOF
2912 #else   /* !__cplusplus */
2913 #define G_CAN_INLINE    1
2914 _______EOF
2915         fi
2916
2917         cat >>$outfile <<_______EOF
2918 #endif
2919
2920 _______EOF
2921
2922         if test x$g_have_iso_c_varargs = xyes ; then
2923                 cat >>$outfile <<_______EOF
2924 #ifndef __cplusplus
2925 # define G_HAVE_ISO_VARARGS 1
2926 #endif
2927 _______EOF
2928         fi
2929         if test x$g_have_iso_cxx_varargs = xyes ; then
2930                 cat >>$outfile <<_______EOF
2931 #ifdef __cplusplus
2932 # define G_HAVE_ISO_VARARGS 1
2933 #endif
2934 _______EOF
2935         fi
2936         if test x$g_have_gnuc_varargs = xyes ; then
2937                 cat >>$outfile <<_______EOF
2938
2939 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2940  * is passed ISO vararg support is turned off, and there is no work
2941  * around to turn it on, so we unconditionally turn it off.
2942  */
2943 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2944 #  undef G_HAVE_ISO_VARARGS
2945 #endif
2946
2947 #define G_HAVE_GNUC_VARARGS 1
2948 _______EOF
2949         fi
2950
2951         case x$g_stack_grows in
2952         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2953         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2954         esac
2955
2956
2957         echo >>$outfile
2958         if test x$g_have_eilseq = xno; then
2959                 cat >>$outfile <<_______EOF
2960 #ifndef EILSEQ
2961 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
2962  * The correspondence between this and the corresponding definition
2963  * in libiconv is essential.
2964  */
2965 #  define EILSEQ ENOENT
2966 #endif
2967 _______EOF
2968
2969         fi
2970
2971         if test x$g_have_gnuc_visibility = xyes; then
2972                 cat >>$outfile <<_______EOF
2973 #define G_HAVE_GNUC_VISIBILITY 1
2974 _______EOF
2975         fi
2976                 cat >>$outfile <<_______EOF
2977 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
2978 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2979 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
2980 #define G_GNUC_INTERNAL __hidden
2981 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
2982 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2983 #else
2984 #define G_GNUC_INTERNAL
2985 #endif
2986 _______EOF
2987
2988         echo >>$outfile
2989         cat >>$outfile <<_______EOF
2990 #define G_THREADS_ENABLED
2991 #define G_THREADS_IMPL_$g_threads_impl_def
2992 _______EOF
2993
2994         if test x"$g_memory_barrier_needed" != xno; then
2995           echo >>$outfile
2996           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
2997         fi
2998         if test x"$g_atomic_lock_free" = xyes; then
2999           echo >>$outfile
3000           echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
3001         fi
3002         echo >>$outfile
3003         g_bit_sizes="16 32 64"
3004         for bits in $g_bit_sizes; do
3005           cat >>$outfile <<_______EOF
3006 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3007 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3008 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3009 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3010 _______EOF
3011         done
3012
3013         cat >>$outfile <<_______EOF
3014 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3015 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3016 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3017 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3018 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3019 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3020 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3021 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3022 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3023 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gsizebits}_TO_LE (val))
3024 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3025 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gsizebits}_TO_BE (val))
3026 #define G_BYTE_ORDER $g_byte_order
3027
3028 #define GLIB_SYSDEF_POLLIN =$g_pollin
3029 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3030 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3031 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3032 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3033 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3034
3035 #define G_MODULE_SUFFIX "$g_module_suffix"
3036
3037 typedef $g_pid_type GPid;
3038
3039 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3040 #define GLIB_SYSDEF_AF_INET $g_af_inet
3041 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3042
3043 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3044 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3045 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3046
3047 G_END_DECLS
3048
3049 #endif /* __GLIBCONFIG_H__ */
3050 _______EOF
3051
3052
3053         if cmp -s $outfile glib/glibconfig.h; then
3054           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3055           rm -f $outfile
3056         else
3057           mv $outfile glib/glibconfig.h
3058         fi
3059 ],[
3060
3061 # Note that if two cases are the same, case goes with the first one.
3062 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3063 # on variable expansion in case labels.  Look at the generated config.status
3064 # for a hint.
3065
3066 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3067   glib_header_alloca_h="$ac_cv_working_alloca_h"
3068 else
3069   glib_header_alloca_h="$ac_cv_header_alloca_h"
3070 fi
3071
3072 case xyes in
3073 x$ac_cv_header_float_h)
3074   glib_float_h=yes
3075   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3076   glib_md=DBL_MIN glib_Md=DBL_MAX
3077   ;;
3078 x$ac_cv_header_values_h)
3079   glib_values_h=yes
3080   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3081   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3082   ;;
3083 esac
3084
3085 case xyes in
3086 x$ac_cv_header_limits_h)
3087   glib_limits_h=yes
3088   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3089   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3090   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3091   ;;
3092 x$ac_cv_header_values_h)
3093   glib_values_h=yes
3094   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3095   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3096   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3097   ;;
3098 esac
3099
3100 if test x$ac_cv_header_sys_poll_h = xyes ; then
3101   glib_sys_poll_h=yes
3102 fi
3103
3104 if test x$enable_included_printf = xyes ; then
3105   glib_included_printf=yes
3106 fi
3107
3108 case 2 in
3109 $ac_cv_sizeof_short)
3110   gint16=short
3111   gint16_modifier='"h"'
3112   gint16_format='"hi"'
3113   guint16_format='"hu"'
3114   ;;
3115 $ac_cv_sizeof_int)
3116   gint16=int
3117   gint16_modifier='""'
3118   gint16_format='"i"'
3119   guint16_format='"u"'
3120   ;;
3121 esac
3122 case 4 in
3123 $ac_cv_sizeof_short)
3124   gint32=short
3125   gint32_modifier='"h"'
3126   gint32_format='"hi"'
3127   guint32_format='"hu"'
3128   ;;
3129 $ac_cv_sizeof_int)
3130   gint32=int
3131   gint32_modifier='""'
3132   gint32_format='"i"'
3133   guint32_format='"u"'
3134   ;;
3135 $ac_cv_sizeof_long)
3136   gint32=long
3137   gint32_modifier='"l"'
3138   gint32_format='"li"'
3139   guint32_format='"lu"'
3140   ;;
3141 esac
3142 case 8 in
3143 $ac_cv_sizeof_int)
3144   gint64=int
3145   gint64_modifier='""'
3146   gint64_format='"i"'
3147   guint64_format='"u"'
3148   glib_extension=
3149   gint64_constant='(val)'
3150   guint64_constant='(val)'
3151   ;;
3152 $ac_cv_sizeof_long)
3153   gint64=long
3154   gint64_modifier='"l"'
3155   gint64_format='"li"'
3156   guint64_format='"lu"'
3157   glib_extension=
3158   gint64_constant='(val##L)'
3159   guint64_constant='(val##UL)'
3160   ;;
3161 $ac_cv_sizeof_long_long)
3162   gint64='long long'
3163   if test -n "$glib_cv_long_long_format"; then
3164     gint64_modifier='"'$glib_cv_long_long_format'"'
3165     gint64_format='"'$glib_cv_long_long_format'i"'
3166     guint64_format='"'$glib_cv_long_long_format'u"'
3167   fi
3168   glib_extension='G_GNUC_EXTENSION '
3169   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3170   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3171   ;;
3172 $ac_cv_sizeof___int64)
3173   gint64='__int64'
3174   if test -n "$glib_cv_long_long_format"; then
3175     gint64_modifier='"'$glib_cv_long_long_format'"'
3176     gint64_format='"'$glib_cv_long_long_format'i"'
3177     guint64_format='"'$glib_cv_long_long_format'u"'
3178   fi
3179   glib_extension=
3180   gint64_constant='(val##i64)'
3181   guint64_constant='(val##ui64)'
3182   ;;
3183 esac
3184 glib_size_t=$ac_cv_sizeof_size_t
3185 glib_size_type_define="$glib_size_type"
3186 glib_void_p=$ac_cv_sizeof_void_p
3187 glib_long=$ac_cv_sizeof_long
3188
3189 case "$glib_size_type" in
3190 short)
3191   gsize_modifier='"h"'
3192   gsize_format='"hu"'
3193   gssize_format='"hi"'
3194   glib_msize_type='SHRT'
3195   ;;
3196 int)
3197   gsize_modifier='""'
3198   gsize_format='"u"'
3199   gssize_format='"i"'
3200   glib_msize_type='INT'
3201   ;;
3202 long)
3203   gsize_modifier='"l"'
3204   gsize_format='"lu"'
3205   gssize_format='"li"'
3206   glib_msize_type='LONG'
3207   ;;
3208 "long long"|__int64)
3209   gsize_modifier='"I64"'
3210   gsize_format='"I64u"'
3211   gssize_format='"I64i"'
3212   glib_msize_type='INT64'
3213   ;;
3214 esac
3215
3216 gintbits=`expr $ac_cv_sizeof_int \* 8`
3217 glongbits=`expr $ac_cv_sizeof_long \* 8`
3218 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3219
3220 case $ac_cv_sizeof_void_p in
3221 $ac_cv_sizeof_int)
3222   glib_intptr_type_define=int
3223   gintptr_modifier='""'
3224   gintptr_format='"i"'
3225   guintptr_format='"u"'
3226   glib_gpi_cast='(gint)'
3227   glib_gpui_cast='(guint)'
3228   ;;
3229 $ac_cv_sizeof_long)
3230   glib_intptr_type_define=long
3231   gintptr_modifier='"l"'
3232   gintptr_format='"li"'
3233   guintptr_format='"lu"'
3234   glib_gpi_cast='(glong)'
3235   glib_gpui_cast='(gulong)'
3236   ;;
3237 $ac_cv_sizeof_long_long)
3238   glib_intptr_type_define='long long'
3239   gintptr_modifier='"I64"'
3240   gintptr_format='"I64i"'
3241   guintptr_format='"I64u"'
3242   glib_gpi_cast='(gint64)'
3243   glib_gpui_cast='(guint64)'
3244   ;;
3245 $ac_cv_sizeof___int64)
3246   glib_intptr_type_define=__int64
3247   gintptr_modifier='"I64"'
3248   gintptr_format='"I64i"'
3249   guintptr_format='"I64u"'
3250   glib_gpi_cast='(gint64)'
3251   glib_gpui_cast='(guint64)'
3252   ;;
3253 *)
3254   glib_unknown_void_p=yes
3255   ;;
3256 esac
3257
3258
3259 case xyes in
3260 x$ac_cv_func_atexit)
3261   glib_atexit="
3262 #ifdef NeXT /* @#%@! NeXTStep */
3263 # define g_ATEXIT(proc) (!atexit (proc))
3264 #else
3265 # define g_ATEXIT(proc) (atexit (proc))
3266 #endif"
3267   ;;
3268 x$ac_cv_func_on_exit)
3269   glib_atexit="
3270 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3271   ;;
3272 esac
3273
3274 case xyes in
3275 x$ac_cv_func_memmove)
3276   glib_memmove='
3277 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3278   ;;
3279 x$glib_cv_working_bcopy)
3280   glib_memmove="
3281 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3282 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3283   ;;
3284 *)
3285   glib_memmove="
3286 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3287  * so we have to roll our own copy routine. */
3288 void g_memmove (void* dest, const void * src, unsigned long len);"
3289   ;;
3290 esac
3291
3292 glib_defines="
3293 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3294 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3295 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3296 "
3297
3298 case xyes in
3299 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3300 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3301 *)                      glib_vacopy=''
3302 esac
3303
3304 if test x$glib_cv_va_val_copy = xno; then
3305   glib_vacopy="\$glib_vacopy
3306 #define G_VA_COPY_AS_ARRAY 1"
3307 fi
3308
3309 if test x$glib_cv_hasinline = xyes; then
3310     glib_inline='#define G_HAVE_INLINE 1'
3311 fi
3312 if test x$glib_cv_has__inline = xyes; then
3313     glib_inline="\$glib_inline
3314 #define G_HAVE___INLINE 1"
3315 fi
3316 if test x$glib_cv_has__inline__ = xyes; then
3317     glib_inline="\$glib_inline
3318 #define G_HAVE___INLINE__ 1"
3319 fi
3320
3321 g_have_gnuc_varargs=$g_have_gnuc_varargs
3322 g_have_iso_c_varargs=$g_have_iso_c_varargs
3323 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3324
3325 g_can_inline=$g_can_inline
3326 g_have_gnuc_visibility=$g_have_gnuc_visibility
3327 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3328
3329 if test x$ac_cv_c_bigendian = xyes; then
3330   g_byte_order=G_BIG_ENDIAN
3331   g_bs_native=BE
3332   g_bs_alien=LE
3333 else
3334   g_byte_order=G_LITTLE_ENDIAN
3335   g_bs_native=LE
3336   g_bs_alien=BE
3337 fi
3338
3339 g_pollin=$glib_cv_value_POLLIN
3340 g_pollout=$glib_cv_value_POLLOUT
3341 g_pollpri=$glib_cv_value_POLLPRI
3342 g_pollhup=$glib_cv_value_POLLHUP
3343 g_pollerr=$glib_cv_value_POLLERR
3344 g_pollnval=$glib_cv_value_POLLNVAL
3345
3346 g_af_unix=$glib_cv_value_AF_UNIX
3347 g_af_inet=$glib_cv_value_AF_INET
3348 g_af_inet6=$glib_cv_value_AF_INET6
3349
3350 g_msg_peek=$glib_cv_value_MSG_PEEK
3351 g_msg_oob=$glib_cv_value_MSG_OOB
3352 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3353
3354 g_stack_grows=$glib_cv_stack_grows
3355
3356 g_have_eilseq=$have_eilseq
3357
3358 g_threads_impl_def=$g_threads_impl
3359
3360 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3361 g_memory_barrier_needed="$glib_memory_barrier_needed"
3362 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3363
3364 g_module_suffix="$glib_gmodule_suffix"
3365
3366 g_pid_type="$glib_pid_type"
3367 case $host in
3368   *-*-beos*)
3369     glib_os="#define G_OS_BEOS"
3370     ;;
3371   *-*-cygwin*)
3372     glib_os="#define G_OS_UNIX
3373 #define G_PLATFORM_WIN32
3374 #define G_WITH_CYGWIN"
3375     ;;
3376   *-*-mingw*)
3377     glib_os="#define G_OS_WIN32
3378 #define G_PLATFORM_WIN32"
3379     ;;
3380   *)
3381     glib_os="#define G_OS_UNIX"
3382     ;;
3383 esac
3384 glib_static_compilation=""
3385 if test x$glib_win32_static_compilation = xyes; then
3386   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3387 #define GOBJECT_STATIC_COMPILATION 1"
3388 fi
3389 ])
3390
3391 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3392 #
3393 # 1.2.14 required for dbus_message_set_serial
3394 PKG_CHECK_MODULES(DBUS1,
3395                   dbus-1 >= 1.2.14,
3396                   [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3397                   have_dbus1=no)
3398 AC_SUBST(DBUS1_CFLAGS)
3399 AC_SUBST(DBUS1_LIBS)
3400 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3401
3402 dnl
3403 dnl Check for -Bsymbolic-functions linker flag used to avoid
3404 dnl intra-library PLT jumps, if available.
3405 dnl
3406
3407 AC_ARG_ENABLE(Bsymbolic,
3408               [AC_HELP_STRING([--disable-Bsymbolic],
3409                               [avoid linking with -Bsymbolic])],,
3410               [SAVED_LDFLAGS="${LDFLAGS}"
3411                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3412                LDFLAGS=-Wl,-Bsymbolic-functions
3413                AC_TRY_LINK([], [int main (void) { return 0; }],
3414                            AC_MSG_RESULT(yes)
3415                            enable_Bsymbolic=yes,
3416                            AC_MSG_RESULT(no)
3417                            enable_Bsymbolic=no)
3418                LDFLAGS="${SAVED_LDFLAGS}"])
3419
3420 if test "x${enable_Bsymbolic}" = "xyes"; then
3421   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3422 fi
3423
3424 AC_SUBST(GLIB_LINK_FLAGS)
3425
3426 #
3427 # Define variables corresponding to the correct include paths to use for
3428 # in-tree building.
3429 #
3430
3431 # for config.h:
3432 config_h_INCLUDES='-I$(top_builddir)'
3433 AC_SUBST(config_h_INCLUDES)
3434
3435 # glib:
3436 #   config.h
3437 #   $(top_builddir)/glib: for glibconfig.h
3438 #   $(top_srcdir)/glib:   for glib.h
3439 #   $(top_srcdir):        for everything
3440 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3441 AC_SUBST(glib_INCLUDES)
3442
3443 # gthread:
3444 #   same as glib
3445 gthread_INCLUDES='$(glib_INCLUDES)'
3446 AC_SUBST(gthread_INCLUDES)
3447
3448 # gobject:
3449 #   same as gthread
3450 gobject_INCLUDES='$(gthread_INCLUDES)'
3451 AC_SUBST(gobject_INCLUDES)
3452
3453 # gmodule:
3454 #   glib includes
3455 #   $(top_srcdir)/gmodule: for gmodule.h
3456 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3457 AC_SUBST(gmodule_INCLUDES)
3458
3459 # gio:
3460 #   same as gmodule
3461 gio_INCLUDES='$(gmodule_INCLUDES)'
3462 AC_SUBST(gio_INCLUDES)
3463
3464
3465 AC_CONFIG_FILES([
3466 glib-2.0.pc
3467 gmodule-2.0.pc
3468 gmodule-export-2.0.pc
3469 gmodule-no-export-2.0.pc
3470 gthread-2.0.pc
3471 gobject-2.0.pc
3472 gio-2.0.pc
3473 gio-unix-2.0.pc
3474 gio-windows-2.0.pc
3475 glib-zip
3476 glib-gettextize
3477 Makefile
3478 build/Makefile
3479 build/win32/Makefile
3480 build/win32/dirent/Makefile
3481 build/win32/vs9/Makefile
3482 build/win32/vs10/Makefile
3483 glib/Makefile
3484 glib/glib.stp
3485 glib/libcharset/Makefile
3486 glib/gnulib/Makefile
3487 glib/pcre/Makefile
3488 glib/update-pcre/Makefile
3489 glib/tests/Makefile
3490 gmodule/Makefile
3491 gmodule/gmoduleconf.h
3492 gobject/Makefile
3493 gobject/gobject.stp
3494 gobject/glib-mkenums
3495 gobject/tests/Makefile
3496 gthread/Makefile
3497 gio/Makefile
3498 gio/gdbus-2.0/codegen/Makefile
3499 gio/gdbus-2.0/codegen/config.py
3500 gio/xdgmime/Makefile
3501 gio/inotify/Makefile
3502 gio/fen/Makefile
3503 gio/fam/Makefile
3504 gio/win32/Makefile
3505 gio/tests/Makefile
3506 gio/tests/gdbus-object-manager-example/Makefile
3507 po/Makefile.in
3508 docs/Makefile
3509 docs/reference/Makefile
3510 docs/reference/glib/Makefile
3511 docs/reference/glib/version.xml
3512 docs/reference/gobject/Makefile
3513 docs/reference/gobject/version.xml
3514 docs/reference/gio/Makefile
3515 docs/reference/gio/gdbus-object-manager-example/Makefile
3516 docs/reference/gio/version.xml
3517 tests/Makefile
3518 tests/gobject/Makefile
3519 tests/refcount/Makefile
3520 m4macros/Makefile
3521 ])
3522
3523 AC_CONFIG_COMMANDS([chmod-scripts],
3524 [chmod 0755 glib-zip
3525 chmod 0755 glib-gettextize
3526 chmod 0755 gobject/glib-mkenums])
3527
3528 # we want to invoke this macro solely so that the config.status script
3529 # and automake generated makefiles know about these generated files.
3530 # They are only needed to distcheck the package
3531 if false; then
3532   AC_CONFIG_FILES([
3533     INSTALL
3534     README
3535     config.h.win32
3536     glib/glibconfig.h.win32
3537     glib/makefile.msc
3538     glib/glib.rc
3539     gmodule/makefile.msc
3540     gmodule/gmodule.rc
3541     gobject/makefile.msc
3542     gobject/gobject.rc
3543     gthread/makefile.msc
3544     gthread/gthread.rc
3545     gio/gio.rc
3546     tests/makefile.msc
3547   ])
3548 fi
3549
3550 AC_OUTPUT