configure.ac

   1 m4_define(LIBUSB_MAJOR, [1])
   2 m4_define(LIBUSB_MINOR, [0])
   3 m4_define(LIBUSB_MICRO, [8])
   4
   5 AC_INIT([libusb], LIBUSB_MAJOR.LIBUSB_MINOR.LIBUSB_MICRO, [libusb-devel@lists.sourceforge.net], [libusb], [http://www.libusb.org/])
   6
   7 AC_SUBST([LIBUSB_VERSION_MAJOR], [LIBUSB_MAJOR])
   8 AC_SUBST([LIBUSB_VERSION_MINOR], [LIBUSB_MINOR])
   9 AC_SUBST([LIBUSB_VERSION_MICRO], [LIBUSB_MICRO])
  10
  11 # Library versioning
  12 # These numbers should be tweaked on every release. Read carefully:
  13 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  14 # http://sourceware.org/autobook/autobook/autobook_91.html
  15 lt_current="1"
  16 lt_revision="0"
  17 lt_age="1"
  18 AC_SUBST(lt_current)
  19 AC_SUBST(lt_revision)
  20 AC_SUBST(lt_age)
  21
  22 AM_INIT_AUTOMAKE
  23 AC_CONFIG_SRCDIR([libusb/core.c])
  24 AC_CONFIG_MACRO_DIR([m4])
  25 AM_CONFIG_HEADER([config.h])
  26 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  27
  28 AC_PREREQ([2.50])
  29 AC_PROG_CC
  30 AC_PROG_LIBTOOL
  31 AC_C_INLINE
  32 AM_PROG_CC_C_O
  33 AC_DEFINE([_GNU_SOURCE], [], [Use GNU extensions])
  34
  35 AM_MAINTAINER_MODE
  36
  37 AC_MSG_CHECKING([operating system])
  38 PC_LIBS_PRIVATE=
  39 case $host in
  40 *-linux*)
  41         AC_DEFINE(OS_LINUX, [], [Linux backend])
  42         AC_SUBST(OS_LINUX)
  43         AC_DEFINE([THREADS_POSIX], [], [Use Posix Threads])
  44         AC_MSG_RESULT([Linux])
  45         backend="linux"
  46         AC_CHECK_LIB(rt, clock_gettime, PC_LIBS_PRIVATE="-lrt")
  47         LIBS="${LIBS} ${PC_LIBS_PRIVATE}"
  48         threads="posix"
  49         THREAD_CFLAGS="-pthread"
  50         PC_LIBS_PRIVATE="${PC_LIBS_PRIVATE} -pthread"
  51         AM_LDFLAGS=""
  52         ;;
  53 *-darwin*)
  54         AC_DEFINE(OS_DARWIN, [], [Darwin backend])
  55         AC_SUBST(OS_DARWIN)
  56         AC_DEFINE([THREADS_POSIX], [], [Use Posix Threads])
  57         AC_DEFINE(USBI_OS_HANDLES_TIMEOUT, [], [Backend handles timeout])
  58         AC_MSG_RESULT([Darwin/MacOS X])
  59         backend="darwin"
  60         threads="posix"
  61         THREAD_CFLAGS="-pthread"
  62         PC_LIBS_PRIVATE="-Wl,-framework,IOKit -Wl,-framework,CoreFoundation -Wl,-prebind -no-undefined -pthread"
  63         AM_LDFLAGS=${PC_LIBS_PRIVATE}
  64 ;;
  65 *-mingw*)
  66         AC_DEFINE(OS_WINDOWS, [], [Windows backend])
  67         AC_SUBST(OS_WINDOWS)
  68         AC_MSG_RESULT([Windows])
  69         backend="windows"
  70         threads="windows"
  71         PC_LIBS_PRIVATE="-lsetupapi -lole32 -ladvapi32"
  72         LIBS="${LIBS} ${PC_LIBS_PRIVATE}"
  73         # -avoid-version to avoid a naming scheme such as libusb-0.dll
  74         AM_LDFLAGS="-no-undefined -avoid-version --add-stdcall-alias"
  75         AC_CHECK_TOOL(RC, windres, no)
  76         ;;
  77 *-cygwin*)
  78         AC_DEFINE(OS_WINDOWS, [], [Windows backend])
  79         AC_SUBST(OS_WINDOWS)
  80         AC_DEFINE([THREADS_POSIX], [], [Use Posix Threads])
  81         AC_MSG_RESULT([Windows])
  82         backend="windows"
  83         threads="posix"
  84         PC_LIBS_PRIVATE="-lsetupapi -lole32 -ladvapi32"
  85         LIBS="${LIBS} ${PC_LIBS_PRIVATE}"
  86         AM_LDFLAGS="-no-undefined -avoid-version"
  87         AC_CHECK_TOOL(RC, windres, no)
  88         ;;
  89 *)
  90         AC_MSG_ERROR([unsupported operating system])
  91 esac
  92 AC_SUBST(PC_LIBS_PRIVATE)
  93
  94 AM_CONDITIONAL([OS_LINUX], [test "x$backend" = "xlinux"])
  95 AM_CONDITIONAL([OS_DARWIN], [test "x$backend" = "xdarwin"])
  96 AM_CONDITIONAL([OS_WINDOWS], [test "x$backend" = "xwindows"])
  97 AM_CONDITIONAL([THREADS_POSIX], [test "x$threads" = "xposix"])
  98
  99 # timerfd
 100 AC_CHECK_HEADER([sys/timerfd.h], [timerfd_h=1], [timerfd_h=0])
 101 AC_ARG_ENABLE([timerfd],
 102         [AS_HELP_STRING([--enable-timerfd],
 103                 [use timerfd for timing (default auto)])],
 104         [use_timerfd=$enableval], [use_timerfd='auto'])
 105
 106 if test "x$use_timerfd" = "xyes" -a "x$timerfd_h" = "x0"; then
 107         AC_MSG_ERROR([timerfd header not available; glibc 2.9+ required])
 108 fi
 109
 110 AC_CHECK_DECL([TFD_NONBLOCK], [tfd_hdr_ok=yes], [tfd_hdr_ok=no], [#include <sys/timerfd.h>])
 111 if test "x$use_timerfd" = "xyes" -a "x$tfd_hdr_ok" = "xno"; then
 112         AC_MSG_ERROR([timerfd header not usable; glibc 2.9+ required])
 113 fi
 114
 115 AC_MSG_CHECKING([whether to use timerfd for timing])
 116 if test "x$use_timerfd" = "xno"; then
 117         AC_MSG_RESULT([no (disabled by user)])
 118 else
 119         if test "x$timerfd_h" = "x1" -a "x$tfd_hdr_ok" = "xyes"; then
 120                 AC_MSG_RESULT([yes])
 121                 AC_DEFINE(USBI_TIMERFD_AVAILABLE, [], [timerfd headers available])
 122         else
 123                 AC_MSG_RESULT([no (header not available)])
 124         fi
 125 fi
 126
 127 AC_CHECK_TYPES(struct timespec)
 128
 129 # Message logging
 130 AC_ARG_ENABLE([log], [AS_HELP_STRING([--disable-log], [disable all logging])],
 131         [log_enabled=$enableval],
 132         [log_enabled='yes'])
 133 if test "x$log_enabled" != "xno"; then
 134         AC_DEFINE([ENABLE_LOGGING], 1, [Message logging])
 135 fi
 136
 137 AC_ARG_ENABLE([debug-log], [AS_HELP_STRING([--enable-debug-log],
 138         [enable debug logging (default n)])],
 139         [debug_log_enabled=$enableval],
 140         [debug_log_enabled='no'])
 141 if test "x$debug_log_enabled" != "xno"; then
 142         AC_DEFINE([ENABLE_DEBUG_LOGGING], 1, [Debug message logging])
 143 fi
 144
 145 # Examples build
 146 AC_ARG_ENABLE([examples-build], [AS_HELP_STRING([--enable-examples-build],
 147         [build example applications (default n)])],
 148         [build_examples=$enableval],
 149         [build_examples='no'])
 150 AM_CONDITIONAL([BUILD_EXAMPLES], [test "x$build_examples" != "xno"])
 151
 152 # Restore gnu89 inline semantics on gcc 4.3 and newer
 153 saved_cflags="$CFLAGS"
 154 CFLAGS="$CFLAGS -fgnu89-inline"
 155 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]), inline_cflags="-fgnu89-inline", inline_cflags="")
 156 CFLAGS="$saved_cflags"
 157
 158 # check for -fvisibility=hidden compiler support (GCC >= 3.4)
 159 saved_cflags="$CFLAGS"
 160 # -Werror required for cygwin
 161 CFLAGS="$CFLAGS -Werror -fvisibility=hidden"
 162 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),
 163         [VISIBILITY_CFLAGS="-fvisibility=hidden"
 164          AC_DEFINE([DEFAULT_VISIBILITY], [__attribute__((visibility("default")))], [Default visibility]) ],
 165         [ VISIBILITY_CFLAGS=""
 166          AC_DEFINE([DEFAULT_VISIBILITY], [], [Default visibility]) ],
 167         ])
 168 CFLAGS="$saved_cflags"
 169
 170 # check for -Wno-pointer-sign compiler support (GCC >= 4)
 171 saved_cflags="$CFLAGS"
 172 CFLAGS="$CFLAGS -Wno-pointer-sign"
 173 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),
 174         nopointersign_cflags="-Wno-pointer-sign", nopointersign_cflags="")
 175 CFLAGS="$saved_cflags"
 176
 177 # sigaction not available on MinGW
 178 AC_CHECK_FUNC([sigaction], [have_sigaction=yes], [have_sigaction=no])
 179 AM_CONDITIONAL([HAVE_SIGACTION], [test "x$have_sigaction" = "xyes"])
 180
 181 # headers not available on all platforms but required on others
 182 AC_CHECK_HEADERS([sys/time.h])
 183
 184 AC_SUBST([THREAD_CFLAGS])
 185
 186 AM_CFLAGS="-std=gnu99 $inline_cflags -Wall -Wundef -Wunused -Wstrict-prototypes -Werror-implicit-function-declaration $nopointersign_cflags -Wshadow"
 187
 188 AC_SUBST(VISIBILITY_CFLAGS)
 189 AC_SUBST(AM_CFLAGS)
 190 AC_SUBST(AM_LDFLAGS)
 191
 192 AC_CONFIG_FILES([libusb-1.0.pc] [Makefile] [libusb/Makefile] [libusb/libusb-1.0.rc] [examples/Makefile] [doc/Makefile] [doc/doxygen.cfg])
 193 AC_OUTPUT
 194