configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT([GStreamer Good Plug-ins],[1.6.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-good])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 AG_GST_LIBTOOL_PREPARE
  46 AS_LIBTOOL(GST, 601, 0, 601)
  47
  48 dnl *** required versions of GStreamer stuff ***
  49 GST_REQ=1.6.1
  50 GSTPB_REQ=1.6.1
  51
  52 dnl *** autotools stuff ****
  53
  54 dnl allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 dnl Add parameters for aclocal
  58 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  59
  60 dnl set up gettext
  61 dnl the version check needs to stay here because autopoint greps for it
  62 AM_GNU_GETTEXT_VERSION([0.17])
  63 AM_GNU_GETTEXT([external])
  64 AG_GST_GETTEXT([gst-plugins-good-$GST_API_VERSION])
  65
  66 dnl *** check for arguments to configure ***
  67
  68 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  69
  70 AG_GST_ARG_DEBUG
  71 AG_GST_ARG_PROFILING
  72 AG_GST_ARG_VALGRIND
  73 AG_GST_ARG_GCOV
  74
  75 AG_GST_ARG_EXAMPLES
  76
  77 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  78 AG_GST_ARG_WITH_PACKAGE_NAME
  79 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  80
  81 AG_GST_ARG_WITH_PLUGINS
  82
  83 AG_GST_ARG_ENABLE_EXTERNAL
  84
  85 AG_GST_ARG_ENABLE_EXPERIMENTAL
  86
  87 dnl *** checks for platform ***
  88
  89 dnl * hardware/architecture *
  90
  91 dnl common/m4/gst-arch.m4
  92 dnl check CPU type
  93 AG_GST_ARCH
  94
  95 dnl Determine endianness
  96 AC_C_BIGENDIAN
  97
  98 dnl *** checks for programs ***
  99
 100 dnl find a compiler
 101 AC_PROG_CC
 102 AC_PROG_CC_STDC
 103
 104 dnl determine c++ compiler
 105 AC_PROG_CXX
 106 dnl determine if c++ is available on this system
 107 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 108
 109 dnl determine c++ preprocessor
 110 dnl FIXME: do we need this ?
 111 AC_PROG_CXXCPP
 112
 113 AC_PROG_OBJC
 114
 115 dnl check if the compiler supports '-c' and '-o' options
 116 AM_PROG_CC_C_O
 117
 118 dnl find an assembler
 119 AM_PROG_AS
 120
 121 dnl check if the compiler supports do while(0) macros
 122 AG_GST_CHECK_DOWHILE_MACROS
 123
 124 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 125 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 126
 127 dnl check for documentation tools
 128 GTK_DOC_CHECK([1.12])
 129 AG_GST_PLUGIN_DOCS([1.12])
 130
 131 dnl *** checks for libraries ***
 132
 133 dnl check for libm, for sin()
 134 LT_LIB_M
 135 AC_SUBST(LIBM)
 136
 137 AC_CHECK_FUNCS(clock_gettime, [], [
 138   AC_CHECK_LIB(rt, clock_gettime, [
 139     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 140     LIBRT="-lrt"
 141     AC_SUBST([LIBRT])
 142   ])
 143 ])
 144
 145 dnl *** checks for header files ***
 146
 147 dnl check if we have ANSI C header files
 148 AC_HEADER_STDC
 149
 150 dnl used by ext/wavpack
 151 AX_CREATE_STDINT_H
 152
 153 dnl used in gst/udp
 154 AC_CHECK_HEADERS([sys/time.h])
 155
 156 dnl used in gst/udp
 157 AC_CHECK_HEADERS([sys/socket.h])
 158
 159 dnl *** checks for types/defines ***
 160
 161 dnl Check for FIONREAD ioctl declaration.  This check is needed
 162 dnl for the UDP plugin to build on Solaris
 163 GST_CHECK_FIONREAD
 164
 165 dnl *** checks for structures ***
 166
 167 dnl *** checks for compiler characteristics ***
 168
 169 dnl check if we have GCC inline-asm
 170 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 171 if test x$HAVE_GCC_ASM = xyes ; then
 172   AC_DEFINE(HAVE_GCC_ASM, 1,
 173     [Define if compiler supports gcc inline assembly])
 174 fi
 175 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 176
 177 dnl *** checks for library functions ***
 178
 179 LIBS_SAVE=$LIBS
 180 LIBS="$LIBS $LIBM"
 181 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 182 LIBS=$LIBS_SAVE
 183
 184 dnl Check whether isinf() is defined by math.h
 185 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 186     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 187 if test "$ac_cv_have_isinf" = "yes"
 188 then
 189     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 190 fi
 191
 192 dnl Check for mmap (needed by electricfence plugin)
 193 AC_FUNC_MMAP
 194 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 195
 196 dnl Check for mmap (needed by electricfence plugin)
 197
 198 AC_CHECK_TYPE([struct ip_mreqn], [
 199               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 200               [#include <netinet/in.h>])
 201
 202 dnl *** checks for dependency libraries ***
 203
 204
 205 dnl GLib
 206 GLIB_REQ=2.32.0
 207 AG_GST_GLIB_CHECK([$GLIB_REQ])
 208
 209 dnl Orc
 210 ORC_CHECK([0.4.17])
 211
 212 dnl checks for gstreamer
 213 dnl uninstalled is selected preferentially -- see pkg-config(1)
 214 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 215 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 216 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 217 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 218 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 219 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 220
 221 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_API_VERSION`
 222 if test -z $GST_TOOLS_DIR; then
 223   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 224 fi
 225 AC_SUBST(GST_TOOLS_DIR)
 226
 227 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 228 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 229
 230 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 231
 232 dnl Check for documentation xrefs
 233 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 234 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 235 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 236 AC_SUBST(GLIB_PREFIX)
 237 AC_SUBST(GST_PREFIX)
 238 AC_SUBST(GSTPB_PREFIX)
 239
 240 dnl GTK is optional and used in examples
 241 HAVE_GTK=no
 242 GTK_REQ=3.0.0
 243 if test "x$BUILD_EXAMPLES" = "xyes"; then
 244   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 245   dnl some examples need gtk+-x11
 246   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 247   AC_SUBST(GTK_LIBS)
 248   AC_SUBST(GTK_CFLAGS)
 249 fi
 250 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 251 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 252
 253 AC_ARG_ENABLE(pcmdump, AC_HELP_STRING([--enable-pcmdump], [pcm dump]),
 254   [
 255     case "${enableval}" in
 256       yes) PCM_DUMP_ENABLE=yes ;;
 257       no)  PCM_DUMP_ENABLE=no ;;
 258       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-pcmdump) ;;
 259     esac
 260   ],
 261   [PCM_DUMP_ENABLE=no])
 262 AM_CONDITIONAL([PCM_DUMP_ENABLE], [test "x$PCM_DUMP_ENABLE" = "xyes"])
 263
 264 if test "x$PCM_DUMP_ENABLE" = "xyes"; then
 265 PKG_CHECK_MODULES(VCONF, vconf)
 266 AC_SUBST(VCONF_CFLAGS)
 267 AC_SUBST(VCONF_LIBS)
 268 fi
 269
 270 dnl *** set variables based on configure arguments ***
 271
 272 dnl set license and copyright notice
 273 GST_LICENSE="LGPL"
 274 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 275 AC_SUBST(GST_LICENSE)
 276
 277 dnl set location of plugin directory
 278 AG_GST_SET_PLUGINDIR
 279
 280 dnl set release date/time
 281 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 282   ["${srcdir}/gst-plugins-good.doap"],
 283   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 284
 285 dnl build static plugins or not
 286 AC_MSG_CHECKING([whether to build static plugins or not])
 287 AC_ARG_ENABLE(
 288   static-plugins,
 289   AC_HELP_STRING(
 290     [--enable-static-plugins],
 291     [build static plugins @<:@default=no@:>@]),
 292   [AS_CASE(
 293     [$enableval], [no], [], [yes], [],
 294     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 295   [enable_static_plugins=no])
 296 AC_MSG_RESULT([$enable_static_plugins])
 297 if test "x$enable_static_plugins" = xyes; then
 298   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 299     [Define if static plugins should be built])
 300   GST_PLUGIN_LIBTOOLFLAGS=""
 301 else
 302   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 303 fi
 304 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 305 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 306
 307 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 308 dnl make sure it doesn't complain about unused variables if debugging is disabled
 309 NO_WARNINGS=""
 310 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 311
 312 dnl define an ERROR_CFLAGS Makefile variable
 313 dnl -Wundef: too many broken headers
 314 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 315       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 316       -Wwrite-strings -Wold-style-definition -Waggregate-return
 317       -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 318       -Wnested-externs $NO_WARNINGS])
 319
 320 dnl define an ERROR_CXXFLAGS Makefile variable
 321 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 322         -Wmissing-declarations -Wredundant-decls
 323         -Wwrite-strings
 324         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 325         $NO_WARNINGS])
 326
 327 dnl define an ERROR_OBJCFLAGS Makefile variable
 328 AG_GST_SET_ERROR_OBJCFLAGS($FATAL_WARNINGS, [
 329       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 330       -Wwrite-strings -Wold-style-definition
 331       -Winit-self -Wmissing-include-dirs -Wno-multichar
 332       -Wnested-externs $NO_WARNINGS])
 333
 334 dnl define correct level for debugging messages
 335 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 336
 337 dnl used in examples
 338 AG_GST_DEFAULT_ELEMENTS
 339
 340 dnl *** plug-ins to include ***
 341
 342 dnl these are all the gst plug-ins, compilable without additional libs
 343 dnl videofilter is at the top because others depend on it
 344 AG_GST_CHECK_PLUGIN(alpha)
 345 AG_GST_CHECK_PLUGIN(apetag)
 346 AG_GST_CHECK_PLUGIN(audiofx)
 347 AG_GST_CHECK_PLUGIN(audioparsers)
 348 AG_GST_CHECK_PLUGIN(auparse)
 349 AG_GST_CHECK_PLUGIN(autodetect)
 350 AG_GST_CHECK_PLUGIN(avi)
 351 AG_GST_CHECK_PLUGIN(cutter)
 352 AG_GST_CHECK_PLUGIN(debugutils)
 353 AG_GST_CHECK_PLUGIN(deinterlace)
 354 AG_GST_CHECK_PLUGIN(dtmf)
 355 AG_GST_CHECK_PLUGIN(effectv)
 356 AG_GST_CHECK_PLUGIN(equalizer)
 357 AG_GST_CHECK_PLUGIN(flv)
 358 AG_GST_CHECK_PLUGIN(flx)
 359 AG_GST_CHECK_PLUGIN(goom)
 360 AG_GST_CHECK_PLUGIN(goom2k1)
 361 AG_GST_CHECK_PLUGIN(icydemux)
 362 AG_GST_CHECK_PLUGIN(id3demux)
 363 AG_GST_CHECK_PLUGIN(imagefreeze)
 364 AG_GST_CHECK_PLUGIN(interleave)
 365 AG_GST_CHECK_PLUGIN(isomp4)
 366 AG_GST_CHECK_PLUGIN(law)
 367 AG_GST_CHECK_PLUGIN(level)
 368 AG_GST_CHECK_PLUGIN(matroska)
 369 AG_GST_CHECK_PLUGIN(monoscope)
 370 AG_GST_CHECK_PLUGIN(multifile)
 371 AG_GST_CHECK_PLUGIN(multipart)
 372 AG_GST_CHECK_PLUGIN(replaygain)
 373 AG_GST_CHECK_PLUGIN(rtp)
 374 AG_GST_CHECK_PLUGIN(rtpmanager)
 375 AG_GST_CHECK_PLUGIN(rtsp)
 376 AG_GST_CHECK_PLUGIN(shapewipe)
 377 AG_GST_CHECK_PLUGIN(smpte)
 378 AG_GST_CHECK_PLUGIN(spectrum)
 379 AG_GST_CHECK_PLUGIN(udp)
 380 AG_GST_CHECK_PLUGIN(videobox)
 381 AG_GST_CHECK_PLUGIN(videocrop)
 382 AG_GST_CHECK_PLUGIN(videofilter)
 383 AG_GST_CHECK_PLUGIN(videomixer)
 384 AG_GST_CHECK_PLUGIN(wavenc)
 385 AG_GST_CHECK_PLUGIN(wavparse)
 386 AG_GST_CHECK_PLUGIN(y4m)
 387
 388 dnl disable experimental plug-ins
 389 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 390   AG_GST_DISABLE_PLUGIN(monoscope)
 391 fi
 392
 393 dnl *** sys plug-ins ***
 394
 395 echo
 396 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 397 echo
 398
 399 dnl DirectSound
 400 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 401 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 402   HAVE_DIRECTSOUND="no"
 403   save_CFLAGS="$CFLAGS"
 404   save_LDFLAGS="$LDFLAGS"
 405   save_LIBS="$LIBS"
 406   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 407   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 408   LIBS="$LIBS -ldsound -ldxerr9 -luser32 -lole32"
 409   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 410   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 411 #include <windows.h>
 412 #include <dxerr9.h>
 413 #include <dsound.h>
 414 ]], [[
 415   DXGetErrorString9 (0);
 416   DirectSoundCreate(NULL, NULL, NULL);
 417   CLSIDFromString(NULL, NULL);
 418 ]])
 419 ],
 420     [HAVE_DIRECTSOUND="yes"],
 421     [HAVE_DIRECTSOUND="no"])
 422   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 423   CFLAGS=$save_CFLAGS
 424   LDFLAGS=$save_LDFLAGS
 425   LIBS=$save_LIBS
 426
 427   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 428     dnl this is much more than we want
 429     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32 -lole32"
 430     AC_SUBST(DIRECTSOUND_CFLAGS)
 431     AC_SUBST(DIRECTSOUND_LDFLAGS)
 432     AC_SUBST(DIRECTSOUND_LIBS)
 433   fi
 434   AC_SUBST(HAVE_DIRECTSOUND)
 435 ])
 436
 437 dnl *** Win32 WaveOut ***
 438 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVEFORM, true)
 439 AG_GST_CHECK_FEATURE(WAVEFORM, [Win32 WaveForm], waveformsink, [
 440   AC_CHECK_HEADER(mmsystem.h, HAVE_WAVEFORM="yes", HAVE_WAVEFORM="no", [#include <windows.h>])
 441 ])
 442
 443 dnl *** OSS audio *** (Linux, *BSD)
 444 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 445 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 446  HAVE_OSS="yes"
 447 dnl Linux and newer BSD versions :
 448  AC_CHECK_HEADER(sys/soundcard.h, [
 449    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 450    ] , [
 451 dnl Some old BSD versions and also newer OpenBSD versions :
 452    AC_CHECK_HEADER(soundcard.h, [
 453      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 454      ], [
 455   dnl Some old BSD versions :
 456      AC_CHECK_HEADER(machine/soundcard.h, [
 457        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 458          [Define if OSS includes are in /machine/])
 459        ], [
 460        HAVE_OSS="no"
 461      ])
 462    ])
 463  ])
 464 ])
 465
 466 dnl *** oss4 ***
 467 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 468 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 469   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 470   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 471       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 472       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 473 ])
 474
 475 dnl *** Sun Audio ***
 476 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 477 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 478   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 479 ])
 480
 481 dnl *** OSX Audio ***
 482 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 483 HAVE_IOS="no"
 484 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 485   AC_CHECK_HEADER(CoreAudio/CoreAudio.h,
 486     [HAVE_OSX_AUDIO="yes"],
 487     [AC_CHECK_HEADER(CoreAudio/CoreAudioTypes.h,
 488     [
 489       HAVE_OSX_AUDIO="yes"
 490       HAVE_IOS="yes"
 491     ], [
 492       HAVE_OSX_AUDIO="no"
 493       HAVE_IOS="no"
 494     ])]
 495   )
 496 ])
 497 if test "x$HAVE_IOS" = "xyes"; then
 498   AC_DEFINE(HAVE_IOS, 1, [building for iOS platofrm])
 499 fi
 500 AM_CONDITIONAL(HAVE_IOS, test "x$HAVE_IOS" = "xyes")
 501
 502 dnl *** OS X video ***
 503 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 504 HAVE_OSX_VIDEO="no"
 505 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 506   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 507
 508   dnl in case header OpenGL/gl.h is found on other platforms (or older, unsupported OS X)
 509   dnl also require Snow Leopard or newer
 510
 511   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 512         #include <AvailabilityMacros.h>
 513         #if MAC_OS_X_VERSION_MIN_REQUIRED < 1060
 514         #error Too old OSX version
 515         #endif
 516       ]], [[return 0;]])],[HAVE_OSX_VIDEO="yes"],[HAVE_OSX_VIDEO="no"])
 517 ])
 518
 519 dnl *** Video 4 Linux 2 ***
 520 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 521 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 522 HAVE_GST_V4L2=no
 523 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], video4linux2, [
 524   AC_MSG_CHECKING([Checking for video4linux2 header ...])
 525   AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_GST_V4L2=yes ],
 526   [
 527     AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_GST_V4L2=yes ],
 528     [
 529       AC_CHECK_HEADER(sys/videoio.h, [ HAVE_GST_V4L2=yes ])
 530     ])
 531   ])
 532   if test "x$HAVE_VIDEODEV" = "xno"; then
 533      AC_MSG_WARN([video4linux2 was not found])
 534   fi
 535 ])
 536
 537 # Optional gudev for device probing
 538 AC_ARG_WITH([gudev],
 539   AS_HELP_STRING([--with-gudev],[device detection with gudev]),
 540   [],
 541   [with_gudev=check])
 542 if test x$HAVE_GST_V4L2 = xyes; then
 543   if test x$with_gudev != xno; then
 544     PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 147 ],
 545       [ AC_DEFINE(HAVE_GUDEV, 1,
 546           [Whether gudev is available for device detection])
 547       ],
 548       [true])
 549   fi
 550 fi
 551
 552 AC_SUBST(GUDEV_CFLAGS)
 553 AC_SUBST(GUDEV_LIBS)
 554
 555 # Make libv4l2 non-automagic
 556 AC_ARG_WITH([libv4l2],
 557   AS_HELP_STRING([--with-libv4l2],[support video buffer conversion using libv4l2]),
 558   [],
 559   [with_libv4l2=check])
 560 if test x$HAVE_GST_V4L2 = xyes; then
 561   if test x$with_libv4l2 != xno; then
 562       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 563           [ have_libv4l2=yes
 564             AC_DEFINE(HAVE_LIBV4L2, 1,
 565                 [Whether libv4l2 is available for video buffer conversion])
 566           ], [
 567           have_libv4l2=no
 568           ])
 569   else
 570     have_libv4l2=no
 571   fi
 572 fi
 573
 574 dnl Check for X11
 575 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 576 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 577                   [ximagesrc], [
 578   PKG_CHECK_MODULES([X], [x11], [
 579     HAVE_X="yes"
 580     dnl check for Xfixes
 581     PKG_CHECK_MODULES([XFIXES], [ xfixes ], [
 582       AC_DEFINE(HAVE_XFIXES, 1, [Defined if Xfixes is available])
 583     ], [ HAVE_XFIXES="no" ])
 584
 585     dnl check for Xdamage
 586     PKG_CHECK_MODULES([XDAMAGE], [ xdamage ], [
 587       AC_DEFINE(HAVE_XDAMAGE, 1, [Defined if Xdamage is available])
 588     ], [ HAVE_XDAMAGE="no" ])
 589
 590     dnl check for X Shm
 591     PKG_CHECK_MODULES([XEXT], [ xext ], [
 592       AC_CHECK_LIB([Xext], [ XShmAttach ], [
 593         AC_DEFINE(HAVE_XSHM, 1, [Defined if XShm is available])
 594         XSHM_LIBS="$XEXT_LIBS"
 595         XSHM_CFLAGS="$XEXT_CFLAGS"
 596       ], [ HAVE_XEXT="no" ] , [ $X_LIBS ])
 597     ])
 598     AC_SUBST(XSHM_LIBS)
 599     AC_SUBST(XSHM_CFLAGS)
 600   ], [ HAVE_X="no" ])
 601 ])
 602
 603 dnl *** ext plug-ins ***
 604 dnl keep this list sorted alphabetically !
 605
 606 if test "x$BUILD_EXTERNAL" = "xyes"; then
 607
 608 echo
 609 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 610 echo
 611
 612 dnl *** aalib ***
 613 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 614 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 615   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 616 ])
 617
 618 dnl *** cairo ***
 619 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 620 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering and gobject bindings], cairo, [
 621   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.10.0 cairo-gobject >= 1.10.0)
 622 ])
 623
 624 dnl *** FLAC ***
 625 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 626 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 627   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 628 ])
 629
 630 dnl *** GDK pixbuf ***
 631 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 632 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 633   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 634 ])
 635
 636 dnl *** Jack ***
 637 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 638 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 639   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 640   AC_SUBST(JACK_CFLAGS)
 641   AC_SUBST(JACK_LIBS)
 642
 643   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 644   if test x$HAVE_JACK_0_120_1 = xyes; then
 645     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 646   fi
 647   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 648   if test x$HAVE_JACK_1_9_7 = xyes; then
 649     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 650   fi
 651
 652 ])
 653
 654 dnl *** jpeg ***
 655 dnl FIXME: we could use header checks here as well IMO
 656 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 657 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 658   AC_ARG_WITH(jpeg-mmx,
 659     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 660   OLD_LIBS="$LIBS"
 661   if test x$with_jpeg_mmx != x; then
 662     LIBS="$LIBS -L$with_jpeg_mmx"
 663   fi
 664   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 665   JPEG_LIBS="$LIBS -ljpeg-mmx"
 666   LIBS="$OLD_LIBS"
 667   if test x$HAVE_JPEG != xyes; then
 668     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 669     JPEG_LIBS="-ljpeg"
 670   fi
 671   AC_SUBST(JPEG_LIBS)
 672 ])
 673
 674 dnl *** libcaca ***
 675 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 676 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 677   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 678 ])
 679
 680 dnl *** libdv ***
 681 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 682 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 683   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 684 ])
 685
 686 dnl *** libpng ***
 687 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 688 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 689   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 690 ])
 691
 692 dnl *** pulseaudio ***
 693 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 694 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 695
 696   dnl used in ext/pulse/pulseutil.c
 697   AC_CHECK_HEADERS([process.h])
 698
 699   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 2.0)
 700 ])
 701
 702 dnl *** dv1394 ***
 703 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 704 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 705   dnl first test for libraw1394 >= 2.0.0
 706   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 707   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 708   dnl now see how far we got
 709   if test x$HAVE_RAW1394 = xyes && \
 710      test x$HAVE_LIBIEC61883 = xyes; then
 711        AG_GST_CHECK_LIBHEADER(AVC1394,
 712         avc1394, avc1394_send_command, $RAW1394_LIBS,
 713         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 714        AG_GST_CHECK_LIBHEADER(ROM1394,
 715         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 716         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 717        if test x$HAVE_AVC1394 = xyes && \
 718           test x$HAVE_AVC1394 = xyes && \
 719           test x$HAVE_ROM1394 = xyes; then
 720           HAVE_DV1394=yes
 721           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 722           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 723           AC_SUBST(DV1394_CFLAGS)
 724           AC_SUBST(DV1394_LIBS)
 725         fi
 726   else
 727        if test x$HAVE_RAW1394 = xno; then
 728           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 729           AG_GST_CHECK_LIBHEADER(AVC1394,
 730            avc1394, avc1394_send_command, $RAW1394_LIBS,
 731            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 732           AG_GST_CHECK_LIBHEADER(ROM1394,
 733            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 734            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 735           if test x$HAVE_RAW1394 = xyes && \
 736              test x$HAVE_AVC1394 = xyes && \
 737              test x$HAVE_ROM1394 = xyes; then
 738              HAVE_DV1394=yes
 739              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 740              DV1394_CFLAGS="$RAW1394_CFLAGS"
 741              if test x$HAVE_LIBIEC61883 = xyes; then
 742                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 743                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 744              fi
 745              AC_SUBST(DV1394_CFLAGS)
 746              AC_SUBST(DV1394_LIBS)
 747            fi
 748          fi
 749   fi
 750 ])
 751 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 752
 753 dnl *** shout2 ***
 754 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 755 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 756   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 757 ])
 758
 759 dnl *** soup ***
 760 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 761 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 762   PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.40, [HAVE_SOUP="yes"], [HAVE_SOUP="no"])
 763   AC_SUBST(SOUP_CFLAGS)
 764   AC_SUBST(SOUP_LIBS)
 765 ])
 766
 767 dnl *** speex ***
 768 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 769 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 770   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 771 ])
 772
 773 dnl *** taglib ***
 774 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 775 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 776   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 777   if test "x$HAVE_CXX" != "xyes"; then
 778     USE_TAGLIB=false
 779     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 780   else
 781     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 782     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 783         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 784       ], [
 785         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 786     ])
 787     AC_SUBST(TAGLIB_CXXFLAGS)
 788   fi
 789 ])
 790
 791 dnl *** vpx ***
 792 translit(dnm, m, l) AM_CONDITIONAL(USE_VPX, vpx)
 793 AG_GST_CHECK_FEATURE(VPX, [VPX decoder], vpx, [
 794   PKG_CHECK_MODULES(VPX, vpx >= 1.1.0, [HAVE_VPX="yes"], [HAVE_VPX="no"])
 795   HAVE_VP8=no
 796   HAVE_VP9=no
 797
 798   if test $HAVE_VPX = "yes"; then
 799     OLD_LIBS="$LIBS"
 800     OLD_CFLAGS="$CFLAGS"
 801     CFLAGS="$CFLAGS $VPX_CFLAGS"
 802     LIBS="$LIBS $VPX_LIBS"
 803     AC_CHECK_LIB(vpx, vpx_codec_vp8_cx_algo, [
 804       HAVE_VP8=yes
 805       AC_DEFINE(HAVE_VP8_ENCODER, 1, [Defined if the VP8 encoder is available])
 806     ])
 807     AC_CHECK_LIB(vpx, vpx_codec_vp8_dx_algo, [
 808       HAVE_VP8=yes
 809       AC_DEFINE(HAVE_VP8_DECODER, 1, [Defined if the VP8 decoder is available])
 810     ])
 811
 812     PKG_CHECK_MODULES(VPX_130, vpx >= 1.3.0, [
 813       AC_CHECK_LIB(vpx, vpx_codec_vp9_cx_algo, [
 814         HAVE_VP9=yes
 815         AC_DEFINE(HAVE_VP9_ENCODER, 1, [Defined if the VP9 encoder is available])
 816       ])
 817       AC_CHECK_LIB(vpx, vpx_codec_vp9_dx_algo, [
 818         HAVE_VP9=yes
 819         AC_DEFINE(HAVE_VP9_DECODER, 1, [Defined if the VP9 decoder is available])
 820       ])
 821     ], [true])
 822     LIBS="$OLD_LIBS"
 823     CFLAGS="$OLD_CFLAGS"
 824   fi
 825   AC_SUBST(VPX_LIBS)
 826   AC_SUBST(VPX_CFLAGS)
 827 ])
 828
 829 dnl *** wavpack ***
 830 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 831 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 832   AG_GST_PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.60.0)
 833 ])
 834
 835 dnl *** qtdemux & matroska prefer to have zlib ***
 836 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 837 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
 838   AG_GST_CHECK_LIBHEADER(ZLIB,
 839     z, uncompress,, zlib.h, [
 840     HAVE_ZLIB="yes"
 841     ZLIB_LIBS="-lz"
 842     AC_SUBST(ZLIB_LIBS)
 843   ])
 844 ])
 845
 846 dnl *** matroska prefers to have bz2 ***
 847 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 848 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 849   save_LIBS=$LIBS
 850   LIBS="$LIBS -lbz2"
 851   AC_MSG_CHECKING([for BZ2_bzlibVersion in -lbz2])
 852   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <bzlib.h>]], [[const char *version = BZ2_bzlibVersion ();]])],[HAVE_BZ2=yes],[HAVE_BZ2=no])
 853   AC_MSG_RESULT($HAVE_BZ2)
 854   LIBS=$save_LIBS
 855   if test "x$HAVE_BZ2" = "xyes"; then
 856     BZ2_LIBS="-lbz2"
 857   fi
 858   AC_SUBST(BZ2_LIBS)
 859 ])
 860
 861 else
 862
 863 dnl not building plugins with external dependencies,
 864 dnl but we still need to set the conditionals
 865 AM_CONDITIONAL(USE_AALIB, false)
 866 AM_CONDITIONAL(USE_BZ2, false)
 867 AM_CONDITIONAL(USE_CAIRO, false)
 868 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 869 AM_CONDITIONAL(USE_DV1394, false)
 870 AM_CONDITIONAL(USE_FLAC, false)
 871 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 872 AM_CONDITIONAL(USE_JACK, false)
 873 AM_CONDITIONAL(USE_JPEG, false)
 874 AM_CONDITIONAL(USE_LIBCACA, false)
 875 AM_CONDITIONAL(USE_LIBDV, false)
 876 AM_CONDITIONAL(USE_LIBIEC61883, false)
 877 AM_CONDITIONAL(USE_LIBPNG, false)
 878 AM_CONDITIONAL(USE_OSS, false)
 879 AM_CONDITIONAL(USE_OSS4, false)
 880 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 881 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 882 AM_CONDITIONAL(USE_PULSE, false)
 883 AM_CONDITIONAL(USE_SHOUT2, false)
 884 AM_CONDITIONAL(USE_SOUP, false)
 885 AM_CONDITIONAL(USE_SPEEX, false)
 886 AM_CONDITIONAL(USE_SUNAUDIO, false)
 887 AM_CONDITIONAL(USE_TAGLIB, false)
 888 AM_CONDITIONAL(USE_VPX, false)
 889 AM_CONDITIONAL(USE_WAVEFORM, false)
 890 AM_CONDITIONAL(USE_WAVPACK, false)
 891 AM_CONDITIONAL(USE_X, false)
 892 AM_CONDITIONAL(USE_ZLIB, false)
 893
 894 fi dnl of EXT plugins
 895
 896 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 897
 898 dnl Overview:
 899 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 900 dnl GST_*:              flags shared by all built objects
 901 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 902 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
 903 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 904 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 905
 906 dnl GST_OPTION_CFLAGS
 907 if test "x$USE_DEBUG" = xyes; then
 908    PROFILE_CFLAGS="-g"
 909 fi
 910 AC_SUBST(PROFILE_CFLAGS)
 911
 912 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 913   dnl Define _only_ for git (not pre-releases or releases)
 914   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 915 else
 916   DEPRECATED_CFLAGS=""
 917 fi
 918 AC_SUBST(DEPRECATED_CFLAGS)
 919
 920 dnl every flag in GST_OPTION_CFLAGS, GST_OPTION_CXXFLAGS and GST_OPTION_OBJCFLAGS can be overridden
 921 dnl at make time with e.g. make ERROR_CFLAGS=""
 922 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 923 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 924 GST_OPTION_OBJCFLAGS="\$(WARNING_OBJCFLAGS) \$(ERROR_OBJCFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 925 AC_SUBST(GST_OPTION_CFLAGS)
 926 AC_SUBST(GST_OPTION_CXXFLAGS)
 927 AC_SUBST(GST_OPTION_OBJCFLAGS)
 928
 929 dnl our libraries need to be versioned correctly
 930 AC_SUBST(GST_LT_LDFLAGS)
 931
 932 dnl FIXME: do we want to rename to GST_ALL_* ?
 933 dnl prefer internal headers to already installed ones
 934 dnl also add builddir include for enumtypes and marshal
 935 dnl add ERROR_CFLAGS, but overridable
 936 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
 937 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
 938 GST_OBJCFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_OBJCFLAGS)"
 939 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 940 AC_SUBST(GST_CFLAGS)
 941 AC_SUBST(GST_CXXFLAGS)
 942 AC_SUBST(GST_OBJCFLAGS)
 943 AC_SUBST(GST_LIBS)
 944
 945 dnl LDFLAGS really should only contain flags, not libs - they get added before
 946 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 947 GST_ALL_LDFLAGS="-no-undefined"
 948 AC_SUBST(GST_ALL_LDFLAGS)
 949
 950 dnl this really should only contain flags, not libs - they get added before
 951 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 952 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 953 AC_SUBST(GST_PLUGIN_LDFLAGS)
 954
 955 dnl *** output files ***
 956
 957 $MKDIR_P tests/check/orc
 958
 959 dnl keep this alphabetic per directory, please
 960 AC_CONFIG_FILES(
 961 Makefile
 962 gst/Makefile
 963 gst/alpha/Makefile
 964 gst/apetag/Makefile
 965 gst/audiofx/Makefile
 966 gst/audioparsers/Makefile
 967 gst/auparse/Makefile
 968 gst/autodetect/Makefile
 969 gst/avi/Makefile
 970 gst/cutter/Makefile
 971 gst/deinterlace/Makefile
 972 gst/dtmf/Makefile
 973 gst/debugutils/Makefile
 974 gst/effectv/Makefile
 975 gst/equalizer/Makefile
 976 gst/flv/Makefile
 977 gst/goom/Makefile
 978 gst/goom2k1/Makefile
 979 gst/id3demux/Makefile
 980 gst/icydemux/Makefile
 981 gst/imagefreeze/Makefile
 982 gst/interleave/Makefile
 983 gst/isomp4/Makefile
 984 gst/law/Makefile
 985 gst/level/Makefile
 986 gst/matroska/Makefile
 987 gst/monoscope/Makefile
 988 gst/multifile/Makefile
 989 gst/multipart/Makefile
 990 gst/replaygain/Makefile
 991 gst/rtp/Makefile
 992 gst/rtpmanager/Makefile
 993 gst/rtsp/Makefile
 994 gst/shapewipe/Makefile
 995 gst/smpte/Makefile
 996 gst/spectrum/Makefile
 997 gst/udp/Makefile
 998 gst/videobox/Makefile
 999 gst/videocrop/Makefile
1000 gst/videofilter/Makefile
1001 gst/videomixer/Makefile
1002 gst/wavenc/Makefile
1003 gst/wavparse/Makefile
1004 gst/flx/Makefile
1005 gst/y4m/Makefile
1006 ext/Makefile
1007 ext/aalib/Makefile
1008 ext/cairo/Makefile
1009 ext/dv/Makefile
1010 ext/flac/Makefile
1011 ext/gdk_pixbuf/Makefile
1012 ext/jack/Makefile
1013 ext/jpeg/Makefile
1014 ext/libcaca/Makefile
1015 ext/libpng/Makefile
1016 ext/pulse/Makefile
1017 ext/raw1394/Makefile
1018 ext/shout2/Makefile
1019 ext/soup/Makefile
1020 ext/speex/Makefile
1021 ext/taglib/Makefile
1022 ext/vpx/Makefile
1023 ext/wavpack/Makefile
1024 sys/Makefile
1025 sys/directsound/Makefile
1026 sys/oss/Makefile
1027 sys/oss4/Makefile
1028 sys/osxaudio/Makefile
1029 sys/osxvideo/Makefile
1030 sys/sunaudio/Makefile
1031 sys/v4l2/Makefile
1032 sys/waveform/Makefile
1033 sys/ximage/Makefile
1034 po/Makefile.in
1035 tests/Makefile
1036 tests/check/Makefile
1037 tests/examples/Makefile
1038 tests/examples/audiofx/Makefile
1039 tests/examples/cairo/Makefile
1040 tests/examples/equalizer/Makefile
1041 tests/examples/jack/Makefile
1042 tests/examples/level/Makefile
1043 tests/examples/pulse/Makefile
1044 tests/examples/rtp/Makefile
1045 tests/examples/shapewipe/Makefile
1046 tests/examples/spectrum/Makefile
1047 tests/examples/v4l2/Makefile
1048 tests/files/Makefile
1049 tests/icles/Makefile
1050 common/Makefile
1051 common/m4/Makefile
1052 m4/Makefile
1053 docs/Makefile
1054 docs/plugins/Makefile
1055 docs/version.entities
1056 pkgconfig/Makefile
1057 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1058 gst-plugins-good.spec
1059 )
1060
1061 dnl Create the config.h file for Visual Studio builds
1062 dnl Beware of spaces and /'s in some of the shell variable contents.
1063 sed \
1064     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1065     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1066     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1067     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1068     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1069     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
1070     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1071     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1072     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1073     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1074     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1075     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1076     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1077     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1078     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1079     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1080     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1081     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1082     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1083     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1084     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1085     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1086     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1087     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1088     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1089     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1090     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1091     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1092     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
1093     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1094     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1095     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1096     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1097     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1098     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1099     config.h.in >win32/common/config.h-new
1100
1101 AC_OUTPUT
1102
1103 AG_GST_OUTPUT_PLUGINS
1104 ORC_OUTPUT
1105