configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 AC_INIT([Mesa], [8.1.0],
  10     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  11 AC_CONFIG_AUX_DIR([bin])
  12 AC_CANONICAL_HOST
  13 AM_INIT_AUTOMAKE([foreign])
  14
  15 dnl http://people.gnome.org/~walters/docs/build-api.txt
  16 dnl We don't support srcdir != builddir.
  17 echo \#buildapi-variable-no-builddir >/dev/null
  18
  19 # Support silent build rules, requires at least automake-1.11. Disable
  20 # by either passing --disable-silent-rules to configure or passing V=1
  21 # to make
  22 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  23
  24 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  25
  26 LT_PREREQ([2.2])
  27 LT_INIT([disable-static])
  28
  29 dnl Save user CFLAGS and CXXFLAGS so one can override the default ones
  30 USER_CFLAGS="$CFLAGS"
  31 USER_CXXFLAGS="$CXXFLAGS"
  32
  33 dnl Versions for external dependencies
  34 LIBDRM_REQUIRED=2.4.24
  35 LIBDRM_RADEON_REQUIRED=2.4.31
  36 LIBDRM_INTEL_REQUIRED=2.4.34
  37 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  38 LIBDRM_NOUVEAU_REQUIRED=2.4.33
  39 DRI2PROTO_REQUIRED=2.6
  40 GLPROTO_REQUIRED=1.4.14
  41 LIBDRM_XORG_REQUIRED=2.4.24
  42 LIBKMS_XORG_REQUIRED=1.0.0
  43
  44 dnl Check for progs
  45 AC_PROG_CPP
  46 AC_PROG_CC
  47 AC_PROG_CXX
  48 AM_PROG_CC_C_O
  49 AM_PROG_AS
  50 AC_CHECK_PROGS([MAKE], [gmake make])
  51 AC_CHECK_PROGS([PYTHON2], [python2 python])
  52 AC_PROG_SED
  53 AC_PROG_MKDIR_P
  54 AC_PATH_PROG([MKDEP], [makedepend])
  55
  56 if test "x$MKDEP" = "x"; then
  57     AC_MSG_ERROR([makedepend is required to build Mesa])
  58 fi
  59
  60 AC_PROG_YACC
  61 AC_PATH_PROG([YACC_INST], $YACC)
  62 if test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.y"; then
  63     if test -z "$YACC_INST"; then
  64         AC_MSG_ERROR([yacc not found - unable to compile glcpp-parse.y])
  65     fi
  66 fi
  67 AC_PROG_LEX
  68
  69 AC_PATH_PROG([PERL], [perl])
  70
  71 AC_CHECK_PROG(INDENT, indent, indent, cat)
  72 if test "x$INDENT" != "xcat"; then
  73     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -T GLubyte -T GLbyte -T Bool')
  74 fi
  75
  76 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  77 dnl configuration in that case.
  78 AC_PROG_INSTALL
  79 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  80
  81 dnl We need a POSIX shell for parts of the build. Assume we have one
  82 dnl in most cases.
  83 case "$host_os" in
  84 solaris*)
  85     # Solaris /bin/sh is too old/non-POSIX compliant
  86     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  87     SHELL="$POSIX_SHELL"
  88     ;;
  89 esac
  90
  91 dnl clang is mostly GCC-compatible, but its version is much lower,
  92 dnl so we have to check for it.
  93 AC_MSG_CHECKING([if compiling with clang])
  94
  95 AC_COMPILE_IFELSE(
  96 [AC_LANG_PROGRAM([], [[
  97 #ifndef __clang__
  98        not clang
  99 #endif
 100 ]])],
 101 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 102
 103 AC_MSG_RESULT([$acv_mesa_CLANG])
 104
 105 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 106 dnl versions are explictly not supported.
 107 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 108     AC_MSG_CHECKING([whether gcc version is sufficient])
 109     major=0
 110     minor=0
 111
 112     GCC_VERSION=`$CC -dumpversion`
 113     if test $? -eq 0; then
 114         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 115         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 116     fi
 117
 118     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 119         AC_MSG_RESULT([no])
 120         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 121     else
 122         AC_MSG_RESULT([yes])
 123     fi
 124 fi
 125
 126
 127 MKDEP_OPTIONS=-fdepend
 128 dnl Ask gcc where it's keeping its secret headers
 129 if test "x$GCC" = xyes; then
 130     for dir in include include-fixed; do
 131         GCC_INCLUDES=`$CC -print-file-name=$dir`
 132         if test "x$GCC_INCLUDES" != x && \
 133            test "$GCC_INCLUDES" != "$dir" && \
 134            test -d "$GCC_INCLUDES"; then
 135             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
 136         fi
 137     done
 138 fi
 139 AC_SUBST([MKDEP_OPTIONS])
 140
 141 dnl Make sure the pkg-config macros are defined
 142 m4_ifndef([PKG_PROG_PKG_CONFIG],
 143     [m4_fatal([Could not locate the pkg-config autoconf macros.
 144   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 145   are in a different location, try setting the environment variable
 146   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 147 PKG_PROG_PKG_CONFIG()
 148
 149 dnl LIB_DIR - library basename
 150 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 151 AC_SUBST([LIB_DIR])
 152
 153 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
 154 _SAVE_LDFLAGS="$LDFLAGS"
 155 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
 156 AC_SUBST([EXTRA_LIB_PATH])
 157
 158 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
 159 _SAVE_CPPFLAGS="$CPPFLAGS"
 160 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
 161 AC_SUBST([X11_INCLUDES])
 162
 163 dnl Compiler macros
 164 DEFINES=""
 165 AC_SUBST([DEFINES])
 166 case "$host_os" in
 167 linux*|*-gnu*|gnu*)
 168     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 169     ;;
 170 solaris*)
 171     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 172     ;;
 173 cygwin*)
 174     DEFINES="$DEFINES -DPTHREADS"
 175     ;;
 176 esac
 177
 178 dnl Add flags for gcc and g++
 179 if test "x$GCC" = xyes; then
 180     CFLAGS="$CFLAGS -Wall -std=c99"
 181
 182     # Enable -Werror=implicit-function-declaration and
 183     # -Werror=missing-prototypes, if available, or otherwise, just
 184     # -Wmissing-prototypes.  This is particularly useful to avoid
 185     # generating a loadable driver module that has undefined symbols.
 186     save_CFLAGS="$CFLAGS"
 187     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 188     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 189     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 190     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 191                    AC_MSG_RESULT([yes]),
 192                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 193                     AC_MSG_RESULT([no])]);
 194
 195     # Enable -fvisibility=hidden if using a gcc that supports it
 196     save_CFLAGS="$CFLAGS"
 197     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 198     VISIBILITY_CFLAGS="-fvisibility=hidden"
 199     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 200     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 201                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 202
 203     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 204     CFLAGS=$save_CFLAGS
 205
 206     # Work around aliasing bugs - developers should comment this out
 207     CFLAGS="$CFLAGS -fno-strict-aliasing"
 208
 209     # gcc's builtin memcmp is slower than glibc's
 210     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 211     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 212 fi
 213 if test "x$GXX" = xyes; then
 214     CXXFLAGS="$CXXFLAGS -Wall"
 215
 216     # Enable -fvisibility=hidden if using a gcc that supports it
 217     save_CXXFLAGS="$CXXFLAGS"
 218     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 219     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 220     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 221     AC_LANG_PUSH([C++])
 222     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 223                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 224     AC_LANG_POP([C++])
 225
 226     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 227     CXXFLAGS=$save_CXXFLAGS
 228
 229     # Work around aliasing bugs - developers should comment this out
 230     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 231
 232     # gcc's builtin memcmp is slower than glibc's
 233     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 234     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 235 fi
 236
 237 dnl even if the compiler appears to support it, using visibility attributes isn't
 238 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 239 case "$host_os" in
 240 cygwin*)
 241     VISIBILITY_CFLAGS=""
 242     VISIBILITY_CXXFLAGS=""
 243     ;;
 244 esac
 245
 246 AC_SUBST([VISIBILITY_CFLAGS])
 247 AC_SUBST([VISIBILITY_CXXFLAGS])
 248
 249 dnl These should be unnecessary, but let the user set them if they want
 250 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 251     Default is to use CFLAGS.])
 252 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 253     compiler. Default is to use CFLAGS.])
 254 AC_SUBST([OPT_FLAGS])
 255 AC_SUBST([ARCH_FLAGS])
 256
 257 dnl
 258 dnl Hacks to enable 32 or 64 bit build
 259 dnl
 260 AC_ARG_ENABLE([32-bit],
 261     [AS_HELP_STRING([--enable-32-bit],
 262         [build 32-bit libraries @<:@default=auto@:>@])],
 263     [enable_32bit="$enableval"],
 264     [enable_32bit=auto]
 265 )
 266 if test "x$enable_32bit" = xyes; then
 267     if test "x$GCC" = xyes; then
 268         CFLAGS="$CFLAGS -m32"
 269         ARCH_FLAGS="$ARCH_FLAGS -m32"
 270         CCASFLAGS="$CCASFLAGS -m32"
 271     fi
 272     if test "x$GXX" = xyes; then
 273         CXXFLAGS="$CXXFLAGS -m32"
 274     fi
 275 fi
 276 AC_ARG_ENABLE([64-bit],
 277     [AS_HELP_STRING([--enable-64-bit],
 278         [build 64-bit libraries @<:@default=auto@:>@])],
 279     [enable_64bit="$enableval"],
 280     [enable_64bit=auto]
 281 )
 282 if test "x$enable_64bit" = xyes; then
 283     if test "x$GCC" = xyes; then
 284         CFLAGS="$CFLAGS -m64"
 285     fi
 286     if test "x$GXX" = xyes; then
 287         CXXFLAGS="$CXXFLAGS -m64"
 288     fi
 289 fi
 290
 291 dnl Can't have static and shared libraries, default to static if user
 292 dnl explicitly requested. If both disabled, set to static since shared
 293 dnl was explicitly requested.
 294 case "x$enable_static$enable_shared" in
 295 xyesyes )
 296     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 297     enable_shared=no
 298     ;;
 299 xnono )
 300     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 301     enable_static=yes
 302     ;;
 303 esac
 304
 305 dnl
 306 dnl mklib options
 307 dnl
 308 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 309 if test "$enable_static" = yes; then
 310     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 311 fi
 312 AC_SUBST([MKLIB_OPTIONS])
 313
 314 dnl
 315 dnl other compiler options
 316 dnl
 317 AC_ARG_ENABLE([debug],
 318     [AS_HELP_STRING([--enable-debug],
 319         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 320     [enable_debug="$enableval"],
 321     [enable_debug=no]
 322 )
 323 if test "x$enable_debug" = xyes; then
 324     DEFINES="$DEFINES -DDEBUG"
 325     if test "x$GCC" = xyes; then
 326         CFLAGS="$CFLAGS -g"
 327     fi
 328     if test "x$GXX" = xyes; then
 329         CXXFLAGS="$CXXFLAGS -g"
 330     fi
 331 fi
 332
 333 dnl
 334 dnl library names
 335 dnl
 336 LIB_PREFIX_GLOB='lib'
 337 LIB_VERSION_SEPARATOR='.'
 338 if test "$enable_static" = yes; then
 339     LIB_EXTENSION='a'
 340 else
 341     case "$host_os" in
 342     darwin* )
 343         LIB_EXTENSION='dylib' ;;
 344     cygwin* )
 345         dnl prefix can be 'cyg' or 'lib'
 346         LIB_PREFIX_GLOB='???'
 347         LIB_VERSION_SEPARATOR='-'
 348         LIB_EXTENSION='dll' ;;
 349     aix* )
 350         LIB_EXTENSION='a' ;;
 351     * )
 352         LIB_EXTENSION='so' ;;
 353     esac
 354 fi
 355 AC_ARG_WITH([gl-lib-name],
 356   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 357     [specify GL library name @<:@default=GL@:>@])],
 358   [GL_LIB=$withval],
 359   [GL_LIB=GL])
 360 AC_ARG_WITH([glu-lib-name],
 361   [AS_HELP_STRING([--with-glu-lib-name@<:@=NAME@:>@],
 362     [specify GLU library name @<:@default=GLU@:>@])],
 363   [GLU_LIB=$withval],
 364   [GLU_LIB=GLU])
 365 AC_ARG_WITH([osmesa-lib-name],
 366   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 367     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 368   [OSMESA_LIB=$withval],
 369   [OSMESA_LIB=OSMesa])
 370 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 371 AS_IF([test "x$GLU_LIB" = xyes], [GLU_LIB=GLU])
 372 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 373
 374 dnl
 375 dnl Mangled Mesa support
 376 dnl
 377 AC_ARG_ENABLE([mangling],
 378   [AS_HELP_STRING([--enable-mangling],
 379     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 380   [enable_mangling="${enableval}"],
 381   [enable_mangling=no]
 382 )
 383 if test "x${enable_mangling}" = "xyes" ; then
 384   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 385   GL_LIB="Mangled${GL_LIB}"
 386   GLU_LIB="Mangled${GLU_LIB}"
 387   OSMESA_LIB="Mangled${OSMESA_LIB}"
 388 fi
 389 AC_SUBST([GL_LIB])
 390 AC_SUBST([GLU_LIB])
 391 AC_SUBST([OSMESA_LIB])
 392 AM_CONDITIONAL(HAVE_MANGLED_GL, test "x${enable_mangling}" = "xyes")
 393
 394 dnl
 395 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 396 dnl
 397 AC_ARG_ENABLE([texture-float],
 398     [AS_HELP_STRING([--enable-texture-float],
 399         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 400     [enable_texture_float="$enableval"],
 401     [enable_texture_float=no]
 402 )
 403 if test "x$enable_texture_float" = xyes; then
 404     AC_MSG_WARN([Floating-point textures enabled.])
 405     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 406     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 407 fi
 408
 409 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 410 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 411 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 412 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 413 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 414 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 415 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 416 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 417
 418 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 419 GLU_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLU_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 420 OSMESA_LIB_GLOB=${LIB_PREFIX_GLOB}'$(OSMESA_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 421 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 422 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 423 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 424 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 425 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 426 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 427
 428 AC_SUBST([GL_LIB_NAME])
 429 AC_SUBST([GLU_LIB_NAME])
 430 AC_SUBST([OSMESA_LIB_NAME])
 431 AC_SUBST([EGL_LIB_NAME])
 432 AC_SUBST([GLESv1_CM_LIB_NAME])
 433 AC_SUBST([GLESv2_LIB_NAME])
 434 AC_SUBST([VG_LIB_NAME])
 435 AC_SUBST([GLAPI_LIB_NAME])
 436
 437 AC_SUBST([GL_LIB_GLOB])
 438 AC_SUBST([GLU_LIB_GLOB])
 439 AC_SUBST([OSMESA_LIB_GLOB])
 440 AC_SUBST([EGL_LIB_GLOB])
 441 AC_SUBST([GLESv1_CM_LIB_GLOB])
 442 AC_SUBST([GLESv2_LIB_GLOB])
 443 AC_SUBST([VG_LIB_GLOB])
 444 AC_SUBST([GLAPI_LIB_GLOB])
 445
 446 dnl
 447 dnl Arch/platform-specific settings
 448 dnl
 449 AC_ARG_ENABLE([asm],
 450     [AS_HELP_STRING([--disable-asm],
 451         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 452     [enable_asm="$enableval"],
 453     [enable_asm=yes]
 454 )
 455 asm_arch=""
 456 MESA_ASM_FILES=""
 457 GLAPI_ASM_SOURCES=""
 458 AC_MSG_CHECKING([whether to enable assembly])
 459 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 460 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 461 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 462     case "$host_cpu" in
 463     i?86 | x86_64)
 464         enable_asm=no
 465         AC_MSG_RESULT([no, cross compiling])
 466         ;;
 467     esac
 468 fi
 469 # check for supported arches
 470 if test "x$enable_asm" = xyes; then
 471     case "$host_cpu" in
 472     i?86)
 473         case "$host_os" in
 474         linux* | *freebsd* | dragonfly* | *netbsd*)
 475             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 476             ;;
 477         esac
 478         ;;
 479     x86_64)
 480         case "$host_os" in
 481         linux* | *freebsd* | dragonfly* | *netbsd*)
 482             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 483             ;;
 484         esac
 485         ;;
 486     powerpc)
 487         case "$host_os" in
 488         linux*)
 489             asm_arch=ppc
 490             ;;
 491         esac
 492         ;;
 493     sparc*)
 494         case "$host_os" in
 495         linux*)
 496             asm_arch=sparc
 497             ;;
 498         esac
 499         ;;
 500     esac
 501
 502     case "$asm_arch" in
 503     x86)
 504         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 505         MESA_ASM_FILES='$(X86_FILES)'
 506         GLAPI_ASM_SOURCES='$(X86_API)'
 507         AC_MSG_RESULT([yes, x86])
 508         ;;
 509     x86_64)
 510         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 511         MESA_ASM_FILES='$(X86_64_FILES)'
 512         GLAPI_ASM_SOURCES='$(X86-64_API)'
 513         AC_MSG_RESULT([yes, x86_64])
 514         ;;
 515     sparc)
 516         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 517         MESA_ASM_FILES='$(SPARC_FILES)'
 518         GLAPI_ASM_SOURCES='$(SPARC_API)'
 519         AC_MSG_RESULT([yes, sparc])
 520         ;;
 521     *)
 522         AC_MSG_RESULT([no, platform not supported])
 523         ;;
 524     esac
 525 fi
 526 AC_SUBST([MESA_ASM_FILES])
 527 AC_SUBST([GLAPI_ASM_SOURCES])
 528
 529 dnl PIC code macro
 530 MESA_PIC_FLAGS
 531
 532 dnl Check to see if dlopen is in default libraries (like Solaris, which
 533 dnl has it in libc), or if libdl is needed to get it.
 534 AC_CHECK_FUNC([dlopen], [],
 535     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 536 AC_SUBST([DLOPEN_LIBS])
 537
 538 dnl See if posix_memalign is available
 539 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 540
 541 dnl SELinux awareness.
 542 AC_ARG_ENABLE([selinux],
 543     [AS_HELP_STRING([--enable-selinux],
 544         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 545     [MESA_SELINUX="$enableval"],
 546     [MESA_SELINUX=no])
 547 if test "x$enable_selinux" = "xyes"; then
 548     AC_CHECK_HEADER([selinux/selinux.h],[],
 549                     [AC_MSG_ERROR([SELinux headers not found])])
 550     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 551                  [AC_MSG_ERROR([SELinux library not found])])
 552     SELINUX_LIBS="-lselinux"
 553     DEFINES="$DEFINES -DMESA_SELINUX"
 554 fi
 555
 556 dnl Options for APIs
 557 AC_ARG_ENABLE([opengl],
 558     [AS_HELP_STRING([--disable-opengl],
 559         [disable support for standard OpenGL API @<:@default=no@:>@])],
 560     [enable_opengl="$enableval"],
 561     [enable_opengl=yes])
 562 AC_ARG_ENABLE([gles1],
 563     [AS_HELP_STRING([--enable-gles1],
 564         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 565     [enable_gles1="$enableval"],
 566     [enable_gles1=no])
 567 AC_ARG_ENABLE([gles2],
 568     [AS_HELP_STRING([--enable-gles2],
 569         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 570     [enable_gles2="$enableval"],
 571     [enable_gles2=no])
 572 AC_ARG_ENABLE([openvg],
 573     [AS_HELP_STRING([--enable-openvg],
 574         [enable support for OpenVG API @<:@default=no@:>@])],
 575     [enable_openvg="$enableval"],
 576     [enable_openvg=no])
 577
 578 AC_ARG_ENABLE([dri],
 579     [AS_HELP_STRING([--enable-dri],
 580         [enable DRI modules @<:@default=auto@:>@])],
 581     [enable_dri="$enableval"],
 582     [enable_dri=auto])
 583 AC_ARG_ENABLE([glx],
 584     [AS_HELP_STRING([--enable-glx],
 585         [enable GLX library @<:@default=auto@:>@])],
 586     [enable_glx="$enableval"],
 587     [enable_glx=auto])
 588 AC_ARG_ENABLE([osmesa],
 589     [AS_HELP_STRING([--enable-osmesa],
 590         [enable OSMesa library @<:@default=auto@:>@])],
 591     [enable_osmesa="$enableval"],
 592     [enable_osmesa=auto])
 593 AC_ARG_ENABLE([egl],
 594     [AS_HELP_STRING([--disable-egl],
 595         [disable EGL library @<:@default=enabled@:>@])],
 596     [enable_egl="$enableval"],
 597     [enable_egl=yes])
 598
 599 AC_ARG_ENABLE([xorg],
 600     [AS_HELP_STRING([--enable-xorg],
 601         [enable support for X.Org DDX API @<:@default=no@:>@])],
 602     [enable_xorg="$enableval"],
 603     [enable_xorg=no])
 604 AC_ARG_ENABLE([xa],
 605     [AS_HELP_STRING([--enable-xa],
 606         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 607     [enable_xa="$enableval"],
 608     [enable_xa=no])
 609 AC_ARG_ENABLE([d3d1x],
 610     [AS_HELP_STRING([--enable-d3d1x],
 611         [enable support for Direct3D 10 & 11 low-level API @<:@default=no@:>@])],
 612     [enable_d3d1x="$enableval"],
 613     [enable_d3d1x=no])
 614 AC_ARG_ENABLE([gbm],
 615    [AS_HELP_STRING([--enable-gbm],
 616          [enable gbm library @<:@default=auto@:>@])],
 617    [enable_gbm="$enableval"],
 618    [enable_gbm=auto])
 619
 620 AC_ARG_ENABLE([xvmc],
 621    [AS_HELP_STRING([--enable-xvmc],
 622          [enable xvmc library @<:@default=auto@:>@])],
 623    [enable_xvmc="$enableval"],
 624    [enable_xvmc=auto])
 625 AC_ARG_ENABLE([vdpau],
 626    [AS_HELP_STRING([--enable-vdpau],
 627          [enable vdpau library @<:@default=auto@:>@])],
 628    [enable_vdpau="$enableval"],
 629    [enable_vdpau=auto])
 630 AC_ARG_ENABLE([va],
 631    [AS_HELP_STRING([--enable-va],
 632          [enable va library @<:@default=auto@:>@])],
 633    [enable_va="$enableval"],
 634    [enable_va=auto])
 635 AC_ARG_ENABLE([opencl],
 636    [AS_HELP_STRING([--enable-opencl],
 637          [enable OpenCL library @<:@default=no@:>@])],
 638    [enable_opencl="$enableval"],
 639    [enable_opencl=no])
 640 AC_ARG_ENABLE([xlib_glx],
 641     [AS_HELP_STRING([--enable-xlib-glx],
 642         [make GLX library Xlib-based instead of DRI-based @<:@default=disable@:>@])],
 643     [enable_xlib_glx="$enableval"],
 644     [enable_xlib_glx=auto])
 645 AC_ARG_ENABLE([gallium_egl],
 646     [AS_HELP_STRING([--enable-gallium-egl],
 647         [enable optional EGL state tracker (not required
 648          for EGL support in Gallium with OpenGL and OpenGL ES)
 649          @<:@default=disable@:>@])],
 650     [enable_gallium_egl="$enableval"],
 651     [enable_gallium_egl=no])
 652 AC_ARG_ENABLE([gallium_gbm],
 653     [AS_HELP_STRING([--enable-gallium-gbm],
 654         [enable optional gbm state tracker (not required for
 655          gbm support in Gallium)
 656          @<:@default=auto@:>@])],
 657     [enable_gallium_gbm="$enableval"],
 658     [enable_gallium_gbm=auto])
 659
 660 AC_ARG_ENABLE([r600-llvm-compiler],
 661     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 662         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 663     [enable_r600_llvm="$enableval"],
 664     [enable_r600_llvm=no])
 665
 666 AC_ARG_ENABLE([gallium_tests],
 667     [AS_HELP_STRING([--enable-gallium-tests],
 668         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 669     [enable_gallium_tests="$enableval"],
 670     [enable_gallium_tests=no])
 671
 672 # Option for Gallium drivers
 673 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 674
 675 AC_ARG_WITH([gallium-drivers],
 676     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 677         [comma delimited Gallium drivers list, e.g.
 678         "i915,nouveau,r300,r600,svga,swrast"
 679         @<:@default=r300,r600,swrast@:>@])],
 680     [with_gallium_drivers="$withval"],
 681     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 682
 683 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 684 # here so that the script doesn't choke on an unknown driver name later.
 685 case "$with_gallium_drivers" in
 686     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 687     no) with_gallium_drivers='' ;;
 688 esac
 689
 690 if test "x$enable_opengl" = xno -a \
 691         "x$enable_gles1" = xno -a \
 692         "x$enable_gles2" = xno -a \
 693         "x$enable_openvg" = xno -a \
 694         "x$enable_xorg" = xno -a \
 695         "x$enable_xa" = xno -a \
 696         "x$enable_d3d1x" = xno -a \
 697         "x$enable_xvmc" = xno -a \
 698         "x$enable_vdpau" = xno -a \
 699         "x$enable_va" = xno -a \
 700         "x$enable_opencl" = xno; then
 701     AC_MSG_ERROR([at least one API should be enabled])
 702 fi
 703
 704 API_DEFINES=""
 705 if test "x$enable_opengl" = xno; then
 706     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 707 else
 708     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 709 fi
 710 if test "x$enable_gles1" = xyes; then
 711     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 712 fi
 713 if test "x$enable_gles2" = xyes; then
 714     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 715 fi
 716 AC_SUBST([API_DEFINES])
 717
 718 AC_ARG_ENABLE([shared-glapi],
 719     [AS_HELP_STRING([--enable-shared-glapi],
 720         [EXPERIMENTAL.  Enable shared glapi for OpenGL @<:@default=no@:>@])],
 721     [enable_shared_glapi="$enableval"],
 722     [enable_shared_glapi=no])
 723
 724 SHARED_GLAPI="0"
 725 if test "x$enable_shared_glapi" = xyes; then
 726     SHARED_GLAPI="1"
 727     # libGL will use libglapi for function lookups (IN_DRI_DRIVER means to use
 728     # the remap table)
 729     DEFINES="$DEFINES -DIN_DRI_DRIVER"
 730     SRC_DIRS="$SRC_DIRS mapi/shared-glapi"
 731 fi
 732 AC_SUBST([SHARED_GLAPI])
 733 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test $SHARED_GLAPI = 1)
 734
 735 dnl
 736 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 737 dnl More later: fbdev, ...
 738 dnl
 739 default_driver="xlib"
 740
 741 case "$host_os" in
 742 linux*)
 743     case "$host_cpu" in
 744     i*86|x86_64|powerpc*|sparc*|ia64*) default_driver="dri";;
 745     esac
 746     ;;
 747 *freebsd* | dragonfly* | *netbsd*)
 748     case "$host_cpu" in
 749     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 750     esac
 751     ;;
 752 esac
 753
 754 if test "x$enable_opengl" = xno; then
 755     default_driver="no"
 756 fi
 757
 758 AC_ARG_WITH([driver],
 759     [AS_HELP_STRING([--with-driver=DRIVER], [DEPRECATED])],
 760     [mesa_driver="$withval"],
 761     [mesa_driver=auto])
 762 dnl Check for valid option
 763 case "x$mesa_driver" in
 764 xxlib|xdri|xosmesa|xno)
 765     if test "x$enable_dri" != xauto -o \
 766             "x$enable_glx" != xauto -o \
 767             "x$enable_osmesa" != xauto -o \
 768             "x$enable_xlib_glx" != xauto; then
 769         AC_MSG_ERROR([--with-driver=$mesa_driver is deprecated])
 770     fi
 771     ;;
 772 xauto)
 773     mesa_driver="$default_driver"
 774     ;;
 775 *)
 776     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 777     ;;
 778 esac
 779
 780 # map $mesa_driver to APIs
 781 if test "x$enable_dri" = xauto; then
 782     case "x$mesa_driver" in
 783     xdri) enable_dri=yes ;;
 784     *)    enable_dri=no ;;
 785     esac
 786 fi
 787
 788 if test "x$enable_glx" = xauto; then
 789     case "x$mesa_driver" in
 790     xdri|xxlib) enable_glx=yes ;;
 791     *)          enable_glx=no ;;
 792     esac
 793 fi
 794
 795 if test "x$enable_osmesa" = xauto; then
 796     case "x$mesa_driver" in
 797     xxlib|xosmesa) enable_osmesa=yes ;;
 798     *)             enable_osmesa=no ;;
 799     esac
 800 fi
 801
 802 if test "x$enable_xlib_glx" = xauto; then
 803     case "x$mesa_driver" in
 804     xxlib) enable_xlib_glx=yes ;;
 805     *)     enable_xlib_glx=no ;;
 806     esac
 807 fi
 808
 809 if test "x$enable_glx" = xno; then
 810     enable_xlib_glx=no
 811 fi
 812
 813 AM_CONDITIONAL(HAVE_DRI, test x"$enable_dri" = xyes)
 814
 815 dnl
 816 dnl Driver specific build directories
 817 dnl
 818
 819 dnl this variable will be prepended to SRC_DIRS and is not exported
 820 CORE_DIRS=""
 821
 822 SRC_DIRS="gtest"
 823 GLU_DIRS="sgi"
 824 GALLIUM_DIRS="auxiliary drivers state_trackers"
 825 GALLIUM_TARGET_DIRS=""
 826 GALLIUM_WINSYS_DIRS="sw"
 827 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 828 GALLIUM_STATE_TRACKERS_DIRS=""
 829
 830 # build shared-glapi if enabled for OpenGL or if OpenGL ES is enabled
 831 case "x$enable_shared_glapi$enable_gles1$enable_gles2" in
 832 x*yes*)
 833     CORE_DIRS="$CORE_DIRS mapi/shared-glapi"
 834     ;;
 835 esac
 836
 837 # build glapi if OpenGL is enabled
 838 if test "x$enable_opengl" = xyes; then
 839     CORE_DIRS="$CORE_DIRS mapi/glapi"
 840 fi
 841
 842 # build es1api if OpenGL ES 1.x is enabled
 843 if test "x$enable_gles1" = xyes; then
 844     CORE_DIRS="$CORE_DIRS mapi/es1api"
 845 fi
 846
 847 # build es2api if OpenGL ES 2.x is enabled
 848 if test "x$enable_gles2" = xyes; then
 849     CORE_DIRS="$CORE_DIRS mapi/es2api"
 850 fi
 851
 852 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 853 case "x$enable_opengl$enable_gles1$enable_gles2" in
 854 x*yes*)
 855     CORE_DIRS="mapi/glapi/gen $CORE_DIRS glsl mesa"
 856     ;;
 857 esac
 858
 859 case "x$enable_glx$enable_xlib_glx" in
 860 xyesyes)
 861     DRIVER_DIRS="$DRIVER_DIRS x11"
 862     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 863     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 864     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 865     HAVE_WINSYS_XLIB="yes"
 866     ;;
 867 xyesno)
 868     # DRI-based GLX
 869     SRC_DIRS="$SRC_DIRS glx"
 870     ;;
 871 esac
 872
 873 if test "x$enable_dri" = xyes; then
 874     DRIVER_DIRS="$DRIVER_DIRS dri"
 875
 876     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 877     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 878     HAVE_ST_DRI="yes"
 879 fi
 880
 881 if test "x$enable_osmesa" = xyes; then
 882     # the empty space matters for osmesa... (see src/mesa/Makefile)
 883     if test -n "$DRIVER_DIRS"; then
 884         DRIVER_DIRS="$DRIVER_DIRS osmesa"
 885     else
 886         DRIVER_DIRS="osmesa"
 887     fi
 888 fi
 889
 890 AC_SUBST([SRC_DIRS])
 891 AC_SUBST([GLU_DIRS])
 892 AC_SUBST([DRIVER_DIRS])
 893 AC_SUBST([GALLIUM_DIRS])
 894 AC_SUBST([GALLIUM_TARGET_DIRS])
 895 AC_SUBST([GALLIUM_WINSYS_DIRS])
 896 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 897 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 898 AC_SUBST([MESA_LLVM])
 899
 900 # Check for libdrm
 901 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 902                   [have_libdrm=yes], [have_libdrm=no])
 903
 904 if test "x$enable_dri" = xyes; then
 905     # DRI must be shared, I think
 906     if test "$enable_static" = yes; then
 907         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 908     fi
 909
 910     # not a hard requirement as swrast does not depend on it
 911     if test "x$have_libdrm" = xyes; then
 912         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 913     fi
 914 fi
 915
 916 dnl
 917 dnl Find out if X is available. The variable have_x is set if libX11 is
 918 dnl found to mimic AC_PATH_XTRA.
 919 dnl
 920 if test -n "$PKG_CONFIG"; then
 921     AC_MSG_CHECKING([pkg-config files for X11 are available])
 922     PKG_CHECK_EXISTS([x11],[
 923         x11_pkgconfig=yes
 924         have_x=yes
 925         ],[
 926         x11_pkgconfig=no
 927     ])
 928     AC_MSG_RESULT([$x11_pkgconfig])
 929 else
 930     x11_pkgconfig=no
 931 fi
 932 dnl Use the autoconf macro if no pkg-config files
 933 if test "$x11_pkgconfig" = yes; then
 934     PKG_CHECK_MODULES([X11], [x11])
 935 else
 936     AC_PATH_XTRA
 937     test -z "$X11_CFLAGS" && X11_CFLAGS="$X_CFLAGS"
 938     test -z "$X11_LIBS" && X11_LIBS="$X_LIBS -lX11"
 939     AC_SUBST([X11_CFLAGS])
 940     AC_SUBST([X11_LIBS])
 941 fi
 942
 943 dnl Try to tell the user that the --x-* options are only used when
 944 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 945 m4_divert_once([HELP_BEGIN],
 946 [These options are only used when the X libraries cannot be found by the
 947 pkg-config utility.])
 948
 949 dnl We need X for xlib and dri, so bomb now if it's not found
 950 if test "x$enable_glx" = xyes -a "x$no_x" = xyes; then
 951     AC_MSG_ERROR([X11 development libraries needed for GLX])
 952 fi
 953
 954 if test "x$enable_glx" = xyes; then
 955     DEFINES="$DEFINES -DUSE_XCB"
 956 fi
 957
 958 dnl Direct rendering or just indirect rendering
 959 case "$host_os" in
 960 gnu*)
 961     dnl Disable by default on GNU/Hurd
 962     driglx_direct_default="no"
 963     ;;
 964 cygwin*)
 965     dnl Disable by default on cygwin
 966     driglx_direct_default="no"
 967     ;;
 968 *)
 969     driglx_direct_default="yes"
 970     ;;
 971 esac
 972 AC_ARG_ENABLE([driglx-direct],
 973     [AS_HELP_STRING([--disable-driglx-direct],
 974         [enable direct rendering in GLX and EGL for DRI \
 975             @<:@default=auto@:>@])],
 976     [driglx_direct="$enableval"],
 977     [driglx_direct="$driglx_direct_default"])
 978
 979 dnl
 980 dnl libGL configuration per driver
 981 dnl
 982 case "x$enable_glx$enable_xlib_glx" in
 983 xyesyes)
 984     # Xlib-based GLX
 985     if test "$x11_pkgconfig" = yes; then
 986         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 987         GL_PC_REQ_PRIV="x11 xext"
 988         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 989         GL_LIB_DEPS="$XLIBGL_LIBS"
 990     else
 991         # should check these...
 992         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 993         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 994         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 995         GL_PC_CFLAGS="$X11_INCLUDES"
 996     fi
 997     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread $DLOPEN_LIBS"
 998     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 999     ;;
1000 xyesno)
1001     # DRI-based GLX
1002     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1003     GL_PC_REQ_PRIV="glproto >= $GLPROTO_REQUIRED"
1004     if test x"$driglx_direct" = xyes; then
1005         if test "x$have_libdrm" != xyes; then
1006             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
1007         fi
1008         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1009         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED"
1010     fi
1011
1012     # find the DRI deps for libGL
1013     if test "$x11_pkgconfig" = yes; then
1014         dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx"
1015
1016         # add xf86vidmode if available
1017         PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1018         if test "$HAVE_XF86VIDMODE" = yes ; then
1019             dri_modules="$dri_modules xxf86vm"
1020         fi
1021
1022         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1023         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1024         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1025         GL_LIB_DEPS="$DRIGL_LIBS"
1026     else
1027         # should check these...
1028         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
1029         if test "x$HAVE_XF86VIDMODE" == xyes; then
1030            GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
1031         else
1032            GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXdamage -lXfixes"
1033         fi
1034         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
1035         GL_PC_CFLAGS="$X11_INCLUDES"
1036
1037         # XCB can only be used from pkg-config
1038         PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
1039         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
1040         X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
1041         GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
1042     fi
1043
1044     # Check to see if the xcb-glx library is new enough to support
1045     # GLX_ARB_create_context.  This bit of hackery is necessary until XCB 1.8
1046     # is released.
1047     save_CPPFLAGS="$CPPFLAGS"
1048     save_LDFLAGS="$LDFLAGS"
1049     CPPFLAGS="$CPPFLAGS $X11_INCLUDES"
1050     LDFLAGS="$LDFLAGS $GL_LIB_DEPS"
1051     AC_CHECK_LIB(xcb-glx, xcb_glx_create_context_attribs_arb_checked,
1052         [HAVE_XCB_GLX_CREATE_CONTEXT=yes],
1053         [HAVE_XCB_GLX_CREATE_CONTEXT=no])
1054     CPPFLAGS="$save_CPPFLAGS"
1055     LDFLAGS="$save_LDFLAGS"
1056
1057     if test x$HAVE_XCB_GLX_CREATE_CONTEXT = xyes; then
1058         X11_INCLUDES="$X11_INCLUDES -DHAVE_XCB_GLX_CREATE_CONTEXT"
1059     fi
1060
1061     # need DRM libs, -lpthread, etc.
1062     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1063     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1064     ;;
1065 esac
1066
1067 # This is outside the case (above) so that it is invoked even for non-GLX
1068 # builds.
1069 AM_CONDITIONAL(HAVE_XCB_GLX_CREATE_CONTEXT,
1070     test x$HAVE_XCB_GLX_CREATE_CONTEXT = xyes)
1071 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1072
1073 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1074 GLESv1_CM_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1075 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1076 GLESv2_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1077
1078 AC_SUBST([GL_LIB_DEPS])
1079 AC_SUBST([GL_PC_REQ_PRIV])
1080 AC_SUBST([GL_PC_LIB_PRIV])
1081 AC_SUBST([GL_PC_CFLAGS])
1082 AC_SUBST([DRI_PC_REQ_PRIV])
1083 AC_SUBST([GLESv1_CM_LIB_DEPS])
1084 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1085 AC_SUBST([GLESv2_LIB_DEPS])
1086 AC_SUBST([GLESv2_PC_LIB_PRIV])
1087
1088 GLAPI_LIB_DEPS="-lpthread $SELINUX_LIBS"
1089 AC_SUBST([GLAPI_LIB_DEPS])
1090
1091
1092 dnl Setup default DRI CFLAGS
1093 DRI_CFLAGS='$(CFLAGS)'
1094 DRI_CXXFLAGS='$(CXXFLAGS)'
1095 DRI_LIB_DEPS='$(TOP)/src/mesa/libmesa.a'
1096 MESA_MODULES='$(TOP)/src/mesa/libmesa.a'
1097
1098 if test "x$enable_dri" = xyes && test "x$driglx_direct" = xyes ; then
1099     DRICORE_LIBS='$(TOP)/$(LIB_DIR)/libdricore.so'
1100     DRICORE_LIB_DEPS='-L$(TOP)/$(LIB_DIR) -Wl,-R$(DRI_DRIVER_INSTALL_DIR)'
1101     DRI_LIB_DEPS='-L$(TOP)/$(LIB_DIR) -Wl,-R$(DRI_DRIVER_INSTALL_DIR) -ldricore'
1102     DRI_CFLAGS='$(CFLAGS_NOVISIBILITY) -DUSE_DRICORE'
1103     DRI_CXXFLAGS='$(CXXFLAGS_NOVISIBILITY) -DUSE_DRICORE'
1104     MESA_MODULES='$(DRICORE_LIBS)'
1105     HAVE_DRICORE=yes
1106 fi
1107 AM_CONDITIONAL(HAVE_DRICORE, test x$HAVE_DRICORE = xyes)
1108 AC_SUBST([DRICORE_LIBS])
1109 AC_SUBST([DRICORE_LIB_DEPS])
1110 AC_SUBST([DRI_CXXFLAGS])
1111 AC_SUBST([DRI_CFLAGS])
1112 AC_SUBST([MESA_MODULES])
1113
1114 AC_SUBST([HAVE_XF86VIDMODE])
1115
1116 dnl
1117 dnl More GLX setup
1118 dnl
1119 case "x$enable_glx$enable_xlib_glx" in
1120 xyesyes)
1121     DEFINES="$DEFINES -DUSE_XSHM"
1122     ;;
1123 xyesno)
1124     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1125     if test "x$driglx_direct" = xyes; then
1126         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1127     fi
1128     ;;
1129 esac
1130
1131 dnl
1132 dnl TLS detection
1133 dnl
1134
1135 AC_ARG_ENABLE([glx-tls],
1136     [AS_HELP_STRING([--enable-glx-tls],
1137         [enable TLS support in GLX @<:@default=disabled@:>@])],
1138     [GLX_USE_TLS="$enableval"],
1139     [GLX_USE_TLS=no])
1140 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1141
1142 AS_IF([test "x$GLX_USE_TLS" = xyes],
1143       [DEFINES="${DEFINES} -DGLX_USE_TLS -DPTHREADS"])
1144
1145 dnl
1146 dnl More DRI setup
1147 dnl
1148 dnl Directory for DRI drivers
1149 AC_ARG_WITH([dri-driverdir],
1150     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1151         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1152     [DRI_DRIVER_INSTALL_DIR="$withval"],
1153     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1154 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1155 dnl Extra search path for DRI drivers
1156 AC_ARG_WITH([dri-searchpath],
1157     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1158         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1159     [DRI_DRIVER_SEARCH_DIR="$withval"],
1160     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1161 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1162 dnl Which drivers to build - default is chosen by platform
1163 AC_ARG_WITH([dri-drivers],
1164     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1165         [comma delimited DRI drivers list, e.g.
1166         "swrast,i965,radeon" @<:@default=auto@:>@])],
1167     [with_dri_drivers="$withval"],
1168     [with_dri_drivers=yes])
1169 if test "x$with_dri_drivers" = x; then
1170     with_dri_drivers=no
1171 fi
1172
1173 dnl If $with_dri_drivers is yes, directories will be added through
1174 dnl platform checks
1175 DRI_DIRS=""
1176 case "$with_dri_drivers" in
1177 no) ;;
1178 yes)
1179     # classic DRI drivers require FEATURE_GL to build
1180     if test "x$enable_opengl" = xyes; then
1181         DRI_DIRS="yes"
1182     fi
1183     ;;
1184 *)
1185     # verify the requested driver directories exist
1186     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1187     for driver in $dri_drivers; do
1188         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
1189             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
1190     done
1191     DRI_DIRS="$dri_drivers"
1192     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
1193         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1194     fi
1195     ;;
1196 esac
1197
1198 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
1199 if test "x$enable_dri" = xyes; then
1200     # Platform specific settings and drivers to build
1201     case "$host_os" in
1202     linux*)
1203         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1204         DEFINES="$DEFINES -DHAVE_ALIAS"
1205
1206         case "$host_cpu" in
1207         x86_64)
1208             if test "x$DRI_DIRS" = "xyes"; then
1209                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1210             fi
1211             ;;
1212         powerpc*)
1213             # Build only the drivers for cards that exist on PowerPC.
1214             if test "x$DRI_DIRS" = "xyes"; then
1215                 DRI_DIRS="r200 radeon swrast"
1216             fi
1217             ;;
1218         sparc*)
1219             # Build only the drivers for cards that exist on sparc
1220             if test "x$DRI_DIRS" = "xyes"; then
1221                 DRI_DIRS="r200 radeon swrast"
1222             fi
1223             ;;
1224         esac
1225         ;;
1226     freebsd* | dragonfly* | *netbsd*)
1227         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
1228         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
1229
1230         if test "x$DRI_DIRS" = "xyes"; then
1231             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1232         fi
1233         ;;
1234     gnu*)
1235         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1236         DEFINES="$DEFINES -DHAVE_ALIAS"
1237         ;;
1238     solaris*)
1239         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1240         ;;
1241     cygwin*)
1242         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1243         if test "x$DRI_DIRS" = "xyes"; then
1244             DRI_DIRS="swrast"
1245         fi
1246         ;;
1247     esac
1248
1249     # default drivers
1250     if test "x$DRI_DIRS" = "xyes"; then
1251         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1252     fi
1253
1254     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1255
1256     # Check for expat
1257     if test "x$enable_dri" = xyes; then
1258         EXPAT_INCLUDES=""
1259         EXPAT_LIB=-lexpat
1260         AC_ARG_WITH([expat],
1261             [AS_HELP_STRING([--with-expat=DIR],
1262                 [expat install directory])],[
1263             EXPAT_INCLUDES="-I$withval/include"
1264             CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1265             LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1266             EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1267             ])
1268         AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1269         save_LIBS="$LIBS"
1270         AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1271             [AC_MSG_ERROR([Expat required for DRI.])])
1272         LIBS="$save_LIBS"
1273     fi
1274
1275     # if we are building any dri driver other than swrast ...
1276     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast; then
1277         # ... libdrm is required
1278         if test "x$have_libdrm" != xyes; then
1279             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1280         fi
1281         # ... and build dricommon
1282         HAVE_COMMON_DRI=yes
1283     fi
1284
1285     # put all the necessary libs together
1286     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
1287 fi
1288 AC_SUBST([DRI_DIRS])
1289 AC_SUBST([EXPAT_INCLUDES])
1290 AC_SUBST([DRI_LIB_DEPS])
1291
1292 case $DRI_DIRS in
1293 *i915*|*i965*)
1294     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1295
1296     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1297         case $d in
1298         i915)
1299             HAVE_I915_DRI=yes;
1300             ;;
1301         i965)
1302             HAVE_I965_DRI=yes;
1303             ;;
1304         esac
1305     done
1306
1307     ;;
1308 esac
1309
1310 case $DRI_DIRS in
1311 *nouveau*)
1312     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1313     HAVE_NOUVEAU_DRI=yes;
1314     ;;
1315 esac
1316
1317 case $DRI_DIRS in
1318 *radeon*|*r200*)
1319     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1320
1321     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1322         case $d in
1323         radeon)
1324             HAVE_RADEON_DRI=yes;
1325             ;;
1326         r200)
1327             HAVE_R200_DRI=yes;
1328             ;;
1329         esac
1330     done
1331
1332     ;;
1333 esac
1334
1335 case $DRI_DIRS in
1336 *swrast*)
1337     HAVE_SWRAST_DRI=yes;
1338     ;;
1339 esac
1340
1341 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1342 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1343 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1344 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1345 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1346 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1347 AM_CONDITIONAL(HAVE_COMMON_DRI, test x$HAVE_COMMON_DRI = xyes)
1348
1349 dnl
1350 dnl OSMesa configuration
1351 dnl
1352
1353 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1354 AC_ARG_WITH([osmesa-bits],
1355     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1356         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1357     [osmesa_bits="$withval"],
1358     [osmesa_bits=8])
1359 if test "x$osmesa_bits" != x8; then
1360     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1361         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1362         osmesa_bits=8
1363     fi
1364 fi
1365 case "x$osmesa_bits" in
1366 x8)
1367     OSMESA_LIB="${OSMESA_LIB}"
1368     ;;
1369 x16|x32)
1370     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1371     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1372     ;;
1373 *)
1374     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1375     ;;
1376 esac
1377
1378 if test "x$enable_osmesa" = xyes; then
1379     # only link libraries with osmesa if shared
1380     if test "$enable_static" = no; then
1381         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1382     else
1383         OSMESA_LIB_DEPS=""
1384     fi
1385     OSMESA_MESA_DEPS=""
1386     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1387 fi
1388 AC_SUBST([OSMESA_LIB_DEPS])
1389 AC_SUBST([OSMESA_MESA_DEPS])
1390 AC_SUBST([OSMESA_PC_REQ])
1391 AC_SUBST([OSMESA_PC_LIB_PRIV])
1392
1393 dnl
1394 dnl gbm configuration
1395 dnl
1396 if test "x$enable_gbm" = xauto; then
1397     case "$with_egl_platforms" in
1398         *drm*)
1399             enable_gbm=yes ;;
1400          *)
1401             enable_gbm=no ;;
1402     esac
1403 fi
1404 if test "x$enable_gbm" = xyes; then
1405     SRC_DIRS="$SRC_DIRS gbm"
1406
1407     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1408                       AC_MSG_ERROR([gbm needs udev]))
1409
1410     if test "x$enable_dri" = xyes; then
1411         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1412         if test "$SHARED_GLAPI" -eq 0; then
1413             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1414         fi
1415     fi
1416 fi
1417 GBM_PC_REQ_PRIV="libudev"
1418 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1419 AC_SUBST([GBM_PC_REQ_PRIV])
1420 AC_SUBST([GBM_PC_LIB_PRIV])
1421
1422 dnl
1423 dnl EGL configuration
1424 dnl
1425 EGL_CLIENT_APIS=""
1426
1427 if test "x$enable_egl" = xyes; then
1428     SRC_DIRS="$SRC_DIRS egl"
1429     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS -lpthread"
1430
1431     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1432
1433     if test "$enable_static" != yes; then
1434         # build egl_glx when libGL is built
1435         if test "x$enable_glx" = xyes; then
1436             HAVE_EGL_DRIVER_GLX=1
1437         fi
1438
1439         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1440                           [have_libudev=yes],[have_libudev=no])
1441         if test "$have_libudev" = yes; then
1442             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1443         fi
1444
1445         if test "x$enable_dri" = xyes; then
1446             HAVE_EGL_DRIVER_DRI2=1
1447         fi
1448
1449     fi
1450 fi
1451 AC_SUBST([EGL_LIB_DEPS])
1452
1453 dnl
1454 dnl EGL Gallium configuration
1455 dnl
1456 if test "x$enable_gallium_egl" = xyes; then
1457     if test "x$with_gallium_drivers" = x; then
1458         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1459     fi
1460     if test "x$enable_egl" = xno; then
1461         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1462     fi
1463     if test "x$have_libdrm" != xyes; then
1464         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1465     fi
1466
1467     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1468     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1469     HAVE_ST_EGL="yes"
1470 fi
1471
1472 dnl
1473 dnl gbm Gallium configuration
1474 dnl
1475 if test "x$enable_gallium_gbm" = xauto; then
1476     case "$enable_gbm$HAVE_ST_EGL$enable_dri$with_egl_platforms" in
1477         yesyesyes*drm*)
1478             enable_gallium_gbm=yes ;;
1479          *)
1480             enable_gallium_gbm=no ;;
1481     esac
1482 fi
1483 if test "x$enable_gallium_gbm" = xyes; then
1484     if test "x$with_gallium_drivers" = x; then
1485         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1486     fi
1487     if test "x$enable_gbm" = xno; then
1488         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1489     fi
1490     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1491     if test "x$enable_dri" = xno; then
1492         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1493     fi
1494
1495     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1496     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1497     HAVE_ST_GBM="yes"
1498     enable_gallium_loader=yes
1499 fi
1500
1501 dnl
1502 dnl X.Org DDX configuration
1503 dnl
1504 if test "x$enable_xorg" = xyes; then
1505     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1506     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1507     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1508     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1509         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1510         HAVE_XEXTPROTO_71="no")
1511     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1512     HAVE_ST_XORG=yes
1513 fi
1514
1515 dnl
1516 dnl XA configuration
1517 dnl
1518 if test "x$enable_xa" = xyes; then
1519 AC_PROG_AWK
1520 AC_PROG_GREP
1521 AC_CHECK_PROG(NM, nm, "nm")
1522 if test "x$AWK" = x || test "x$GREP" = x || test "x$NM" = x; then
1523 AC_MSG_WARN([Missing one of nm, grep or awk. Disabling xa.])
1524 enable_xa=no
1525 fi
1526 fi
1527 if test "x$enable_xa" = xyes; then
1528     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1529     HAVE_ST_XA=yes
1530     AC_SUBST(AWK)
1531     AC_SUBST(GREP)
1532     AC_SUBST(NM)
1533 fi
1534
1535 dnl
1536 dnl OpenVG configuration
1537 dnl
1538 VG_LIB_DEPS=""
1539
1540 if test "x$enable_openvg" = xyes; then
1541     if test "x$enable_egl" = xno; then
1542         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1543     fi
1544     if test "x$with_gallium_drivers" = x; then
1545         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1546     fi
1547     if test "x$enable_gallium_egl" = xno; then
1548         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1549     fi
1550
1551     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1552     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS -lpthread"
1553     CORE_DIRS="$CORE_DIRS mapi/vgapi"
1554     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1555     HAVE_ST_VEGA=yes
1556 fi
1557
1558 dnl
1559 dnl D3D1X configuration
1560 dnl
1561
1562 if test "x$enable_d3d1x" = xyes; then
1563     if test "x$with_gallium_drivers" = x; then
1564         AC_MSG_ERROR([cannot enable D3D1X without Gallium])
1565     fi
1566
1567     GALLIUM_STATE_TRACKERS_DIRS="d3d1x $GALLIUM_STATE_TRACKERS_DIRS"
1568     HAVE_ST_D3D1X=yes
1569 fi
1570
1571 dnl
1572 dnl Gallium G3DVL configuration
1573 dnl
1574 AC_ARG_ENABLE([gallium-g3dvl],
1575     [AS_HELP_STRING([--enable-gallium-g3dvl],
1576         [build gallium g3dvl @<:@default=disabled@:>@])],
1577     [enable_gallium_g3dvl="$enableval"],
1578     [enable_gallium_g3dvl=no])
1579 if test "x$enable_gallium_g3dvl" = xyes; then
1580     if test "x$with_gallium_drivers" = x; then
1581         AC_MSG_ERROR([cannot enable G3DVL without Gallium])
1582     fi
1583
1584     if test "x$enable_xvmc" = xauto; then
1585         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1586     fi
1587
1588     if test "x$enable_vdpau" = xauto; then
1589         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1590     fi
1591
1592     if test "x$enable_va" = xauto; then
1593         #don't enable vaapi state tracker even if package exists
1594         #PKG_CHECK_EXISTS([libva], [enable_vdpau=yes], [enable_vdpau=no])
1595         enable_va=no
1596     fi
1597 fi
1598
1599 if test "x$enable_xvmc" = xyes; then
1600     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1601     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1602     HAVE_ST_XVMC="yes"
1603 fi
1604
1605 if test "x$enable_vdpau" = xyes; then
1606     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1607     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1608     HAVE_ST_VDPAU="yes"
1609 fi
1610
1611 if test "x$enable_va" = xyes; then
1612     PKG_CHECK_MODULES([LIBVA], [libva = 0.31.1 x11-xcb xcb-dri2 >= 1.8])
1613     AC_MSG_WARN([vaapi state tracker currently unmaintained])
1614     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS va"
1615     HAVE_ST_VA="yes"
1616 fi
1617
1618 dnl
1619 dnl OpenCL configuration
1620 dnl
1621
1622 AC_ARG_WITH([libclc-path],
1623    [AS_HELP_STRING([--with-libclc-path],
1624          [Path to libclc builtins library.  Example: --with-libclc-path=\$HOME/libclc/])],
1625    [LIBCLC_PATH="$withval"],
1626    [LIBCLC_PATH=""])
1627
1628 AC_SUBST([LIBCLC_PATH])
1629
1630 if test "x$enable_opencl" = xyes; then
1631     if test "x$with_gallium_drivers" = x; then
1632         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1633     fi
1634
1635     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1636         AC_MSG_ERROR([gcc >= 4.6 is required to build clover])
1637     fi
1638
1639     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1640     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1641     enable_gallium_loader=yes
1642 fi
1643
1644 dnl
1645 dnl GLU configuration
1646 dnl
1647 AC_ARG_ENABLE([glu],
1648     [AS_HELP_STRING([--disable-glu],
1649         [enable OpenGL Utility library @<:@default=enabled@:>@])],
1650     [enable_glu="$enableval"],
1651     [enable_glu=yes])
1652
1653 if test "x$enable_glu" = xyes; then
1654     if test "x$enable_glx" = xno -a "x$enable_osmesa" = xno; then
1655         AC_MSG_NOTICE([Disabling GLU since there is no OpenGL driver])
1656         enable_glu=no
1657     fi
1658 fi
1659
1660 if test "x$enable_glu" = xyes; then
1661     SRC_DIRS="$SRC_DIRS glu"
1662
1663     if test "x$enable_glx" = xno; then
1664         # Link libGLU to libOSMesa instead of libGL
1665         GLU_LIB_DEPS=""
1666         GLU_PC_REQ="osmesa"
1667         if test "$enable_static" = no; then
1668             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
1669         else
1670             GLU_MESA_DEPS=""
1671         fi
1672     else
1673         # If static, empty GLU_LIB_DEPS and add libs for programs to link
1674         GLU_PC_REQ="gl"
1675         GLU_PC_LIB_PRIV="-lm"
1676         if test "$enable_static" = no; then
1677             GLU_LIB_DEPS="-lm"
1678             GLU_MESA_DEPS='-l$(GL_LIB)'
1679         else
1680             GLU_LIB_DEPS=""
1681             GLU_MESA_DEPS=""
1682         fi
1683     fi
1684 fi
1685 if test "$enable_static" = no; then
1686     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1687 fi
1688 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1689 AC_SUBST([GLU_LIB_DEPS])
1690 AC_SUBST([GLU_MESA_DEPS])
1691 AC_SUBST([GLU_PC_REQ])
1692 AC_SUBST([GLU_PC_REQ_PRIV])
1693 AC_SUBST([GLU_PC_LIB_PRIV])
1694 AC_SUBST([GLU_PC_CFLAGS])
1695
1696 AC_SUBST([PROGRAM_DIRS])
1697
1698 dnl
1699 dnl Gallium configuration
1700 dnl
1701 if test "x$with_gallium_drivers" != x; then
1702     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1703 fi
1704
1705 AC_SUBST([LLVM_BINDIR])
1706 AC_SUBST([LLVM_CFLAGS])
1707 AC_SUBST([LLVM_CPPFLAGS])
1708 AC_SUBST([LLVM_CXXFLAGS])
1709 AC_SUBST([LLVM_LIBDIR])
1710 AC_SUBST([LLVM_LIBS])
1711 AC_SUBST([LLVM_LDFLAGS])
1712 AC_SUBST([LLVM_INCLUDEDIR])
1713 AC_SUBST([LLVM_VERSION])
1714
1715 case "x$enable_opengl$enable_gles1$enable_gles2" in
1716 x*yes*)
1717     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1718     ;;
1719 esac
1720
1721 AC_SUBST([VG_LIB_DEPS])
1722 AC_SUBST([EGL_CLIENT_APIS])
1723
1724 dnl
1725 dnl EGL Platforms configuration
1726 dnl
1727 AC_ARG_WITH([egl-platforms],
1728     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1729         [comma delimited native platforms libEGL supports, e.g.
1730         "x11,drm" @<:@default=auto@:>@])],
1731     [with_egl_platforms="$withval"],
1732     [if test "x$enable_egl" = xyes; then
1733         with_egl_platforms="x11"
1734     else
1735         with_egl_platforms=""
1736     fi])
1737
1738 EGL_PLATFORMS=""
1739
1740 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1741     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1742 fi
1743
1744 # Do per-EGL platform setups and checks
1745 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1746 for plat in $egl_platforms; do
1747         case "$plat" in
1748         fbdev|null)
1749                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/$plat"
1750                 ;;
1751
1752         wayland)
1753                 PKG_CHECK_MODULES([WAYLAND], [wayland-client wayland-server],, \
1754                                   [AC_MSG_ERROR([cannot find libwayland-client])])
1755                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1756
1757                 m4_ifdef([WAYLAND_SCANNER_RULES],
1758                          [WAYLAND_SCANNER_RULES(['$(top_srcdir)/src/egl/wayland/wayland-drm/protocol'])])
1759                 ;;
1760
1761         x11)
1762                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 xcb-xfixes])
1763                 # workaround a bug in xcb-dri2 generated by xcb-proto 1.6
1764                 save_LIBS="$LIBS"
1765                 AC_CHECK_LIB(xcb-dri2, xcb_dri2_connect_alignment_pad, [],
1766                              [DEFINES="$DEFINES -DXCB_DRI2_CONNECT_DEVICE_NAME_BROKEN"])
1767                 LIBS="$save_LIBS"
1768                 ;;
1769
1770         drm)
1771                 test "x$enable_gbm" = "xno" &&
1772                         AC_MSG_ERROR([EGL platform drm needs gbm])
1773                 ;;
1774
1775         android|gdi)
1776                 ;;
1777
1778         *)
1779                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1780                 ;;
1781         esac
1782
1783         case "$plat$have_libudev" in
1784                 waylandno|drmno)
1785                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1786         esac
1787 done
1788
1789 # libEGL wants to default to the first platform specified in
1790 # ./configure.  parse that here.
1791 if test "x$egl_platforms" != "x"; then
1792     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1793     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1794 else
1795     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1796 fi
1797
1798 EGL_PLATFORMS="$egl_platforms"
1799
1800 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1801 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1802 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1803 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1804 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1805
1806 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1807 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1808
1809 AC_SUBST([EGL_NATIVE_PLATFORM])
1810 AC_SUBST([EGL_PLATFORMS])
1811 AC_SUBST([EGL_CFLAGS])
1812
1813 AC_ARG_WITH([egl-driver-dir],
1814     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1815                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1816     [EGL_DRIVER_INSTALL_DIR="$withval"],
1817     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1818 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1819
1820 AC_ARG_WITH([xorg-driver-dir],
1821     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1822                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1823     [XORG_DRIVER_INSTALL_DIR="$withval"],
1824     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1825 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1826
1827 AC_ARG_WITH([max-width],
1828     [AS_HELP_STRING([--with-max-width=N],
1829                     [Maximum framebuffer width (4096)])],
1830     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1831      AS_IF([test "${withval}" -gt "4096"],
1832            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1833 )
1834 AC_ARG_WITH([max-height],
1835     [AS_HELP_STRING([--with-max-height=N],
1836                     [Maximum framebuffer height (4096)])],
1837     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1838      AS_IF([test "${withval}" -gt "4096"],
1839            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1840 )
1841
1842 dnl
1843 dnl Gallium LLVM
1844 dnl
1845 AC_ARG_ENABLE([gallium-llvm],
1846     [AS_HELP_STRING([--enable-gallium-llvm],
1847         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1848     [enable_gallium_llvm="$enableval"],
1849     [enable_gallium_llvm=auto])
1850
1851 AC_ARG_WITH([llvm-shared-libs],
1852     [AS_HELP_STRING([--with-llvm-shared-libs],
1853         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1854     [with_llvm_shared_libs=yes],
1855     [with_llvm_shared_libs=no])
1856
1857 if test "x$with_gallium_drivers" = x; then
1858     enable_gallium_llvm=no
1859 fi
1860 if test "x$enable_gallium_llvm" = xauto; then
1861     case "$host_cpu" in
1862     i*86|x86_64) enable_gallium_llvm=yes;;
1863     esac
1864 fi
1865 if test "x$enable_gallium_llvm" = xyes; then
1866     AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1867
1868     if test "x$LLVM_CONFIG" != xno; then
1869         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1870         LLVM_CFLAGS=`$LLVM_CONFIG --cppflags|sed -e 's/-DNDEBUG\>//g' -e 's/-pedantic//g' -e 's/-Wcovered-switch-default//g'`
1871         if test "x$with_llvm_shared_libs" = xyes; then
1872             dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1873             LLVM_LIBS="-lLLVM-`$LLVM_CONFIG --version`"
1874         else
1875             LLVM_LIBS="`$LLVM_CONFIG --libs engine bitwriter`"
1876             if test "x$enable_opencl" = xyes; then
1877                 LLVM_LIBS="${LLVM_LIBS} `llvm-config --libs ipo linker instrumentation`"
1878             fi
1879         fi
1880         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1881         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1882         LLVM_CXXFLAGS=`$LLVM_CONFIG --cxxflags`
1883         LLVM_CPPFLAGS=`$LLVM_CONFIG --cppflags`
1884         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1885         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1886         DEFINES="${DEFINES} -DHAVE_LLVM=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/0x0\10\2/g'`"
1887         MESA_LLVM=1
1888     else
1889         MESA_LLVM=0
1890     fi
1891 else
1892     MESA_LLVM=0
1893 fi
1894
1895 dnl Directory for XVMC libs
1896 AC_ARG_WITH([xvmc-libdir],
1897     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1898         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1899     [XVMC_LIB_INSTALL_DIR="$withval"],
1900     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1901 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1902
1903 dnl
1904 dnl Gallium Tests
1905 dnl
1906 if test "x$enable_gallium_tests" = xyes; then
1907     SRC_DIRS="$SRC_DIRS gallium/tests/trivial"
1908     enable_gallium_loader=yes
1909 fi
1910
1911 dnl Directory for VDPAU libs
1912 AC_ARG_WITH([vdpau-libdir],
1913     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1914         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1915     [VDPAU_LIB_INSTALL_DIR="$withval"],
1916     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1917 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1918
1919 dnl Directory for VA libs
1920 AC_ARG_WITH([va-libdir],
1921     [AS_HELP_STRING([--with-va-libdir=DIR],
1922         [directory for the VA libraries @<:@default=${libdir}/va@:>@])],
1923     [VA_LIB_INSTALL_DIR="$withval"],
1924     [VA_LIB_INSTALL_DIR='${libdir}/va'])
1925 AC_SUBST([VA_LIB_INSTALL_DIR])
1926
1927 dnl Directory for OpenCL libs
1928 AC_ARG_WITH([opencl-libdir],
1929     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1930         [directory for the OpenCL libraries @<:@default=${libdir}/opencl@:>@])],
1931     [OPENCL_LIB_INSTALL_DIR="$withval"],
1932     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1933 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1934
1935 dnl
1936 dnl Gallium helper functions
1937 dnl
1938 gallium_check_st() {
1939     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes ||
1940          test "x$HAVE_ST_XA" = xyes || test "x$HAVE_ST_XVMC" = xyes ||
1941          test "x$HAVE_ST_VDPAU" = xyes || test "x$HAVE_ST_VA" = xyes; then
1942          if test "x$have_libdrm" != xyes; then
1943             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1944          fi
1945          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1946     fi
1947     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1948          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1949     fi
1950     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1951          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1952     fi
1953     if test "x$HAVE_ST_XA" = xyes && test "x$4" != x; then
1954          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1955     fi
1956     if test "x$HAVE_ST_XVMC" = xyes && test "x$5" != x; then
1957          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1958     fi
1959     if test "x$HAVE_ST_VDPAU" = xyes && test "x$6" != x; then
1960          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1961     fi
1962     if test "x$HAVE_ST_VA" = xyes && test "x$7" != x; then
1963          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
1964     fi
1965 }
1966
1967 gallium_require_llvm() {
1968     if test "x$MESA_LLVM" = x0; then
1969         case "$host_cpu" in
1970         i*86|x86_64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1971         esac
1972     fi
1973 }
1974
1975 gallium_require_drm_loader() {
1976     if test "x$enable_gallium_loader" = xyes; then
1977         PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1978                           AC_MSG_ERROR([Gallium drm loader requrires libudev]))
1979         if test "x$have_libdrm" != xyes; then
1980             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1981         fi
1982         enable_gallium_drm_loader=yes
1983     fi
1984 }
1985
1986 dnl Gallium drivers
1987 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1988 if test "x$with_gallium_drivers" != x; then
1989     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1990     for driver in $gallium_drivers; do
1991         case "x$driver" in
1992         xsvga)
1993             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1994             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1995             ;;
1996         xi915)
1997             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1998             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1999             if test "x$MESA_LLVM" = x1; then
2000                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
2001             fi
2002             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
2003             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
2004             ;;
2005         xr300)
2006             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2007             gallium_require_llvm "Gallium R300"
2008             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
2009             gallium_check_st "radeon/drm" "dri-r300" "xorg-r300" "" "xvmc-r300" "vdpau-r300" "va-r300"
2010             ;;
2011         xr600)
2012             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2013             gallium_require_drm_loader
2014             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
2015             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
2016                 if test "x$LLVM_VERSION" != "x3.1"; then
2017                     AC_MSG_ERROR([LLVM 3.1 is required for the r600 llvm compiler.])
2018                 fi
2019                 NEED_RADEON_GALLIUM=yes;
2020             fi
2021             if test "x$enable_r600_llvm" = xyes; then
2022                 USE_R600_LLVM_COMPILER=yes;
2023             fi
2024             if test "x$enable_opencl" = xyes -a "x$with_llvm_shared_libs" = xno; then
2025                 LLVM_LIBS="${LLVM_LIBS} `llvm-config --libs bitreader asmparser`"
2026             fi
2027             gallium_check_st "radeon/drm" "dri-r600" "xorg-r600" "" "xvmc-r600" "vdpau-r600" "va-r600"
2028             ;;
2029         xradeonsi)
2030             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2031             gallium_require_drm_loader
2032             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
2033             if test "x$LLVM_VERSION" != "x3.1"; then
2034                 AC_MSG_ERROR([LLVM 3.1 is required to build the radeonsi driver.])
2035             fi
2036             NEED_RADEON_GALLIUM=yes;
2037             gallium_check_st "radeon/drm" "dri-radeonsi" "xorg-radeonsi"
2038             ;;
2039         xnouveau)
2040             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2041             gallium_require_drm_loader
2042             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nv30 nv50 nvc0"
2043             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
2044             ;;
2045         xswrast)
2046             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
2047             if test "x$MESA_LLVM" = x1; then
2048                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
2049             fi
2050
2051             if test "x$HAVE_ST_DRI" = xyes; then
2052                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
2053             fi
2054             if test "x$HAVE_ST_VDPAU" = xyes; then
2055                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
2056             fi
2057             if test "x$HAVE_ST_XVMC" = xyes; then
2058                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
2059             fi
2060             if test "x$HAVE_ST_VA" = xyes; then
2061                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS va-softpipe"
2062             fi
2063             if test "x$HAVE_ST_VDPAU" = xyes ||
2064                test "x$HAVE_ST_XVMC" = xyes ||
2065                test "x$HAVE_ST_VA" = xyes; then
2066                if test "x$HAVE_WINSYS_XLIB" != xyes; then
2067                   GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
2068                fi
2069             fi
2070             ;;
2071         *)
2072             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2073             ;;
2074         esac
2075     done
2076 fi
2077
2078 if test "x$enable_gallium_loader" = xyes; then
2079     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
2080     GALLIUM_PIPE_LOADER_DEFINES="-DHAVE_PIPE_LOADER_SW"
2081     GALLIUM_PIPE_LOADER_LIBS="\$(TOP)/src/gallium/auxiliary/pipe-loader/libpipe_loader.a"
2082     GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/null/libws_null.a"
2083
2084     if test "x$HAVE_WINSYS_XLIB" = xyes; then
2085         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2086         GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/xlib/libws_xlib.a"
2087     fi
2088
2089     if test "x$enable_gallium_drm_loader" = xyes; then
2090         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2091     fi
2092
2093     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2094     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2095 fi
2096
2097 dnl Tell Automake which drivers to build
2098 for driver in $GALLIUM_DRIVERS_DIRS; do
2099     case "x$driver" in
2100         xgalahad)
2101             HAVE_GALAHAD_GALLIUM=yes;
2102             ;;
2103         xidentity)
2104             HAVE_IDENTITY_GALLIUM=yes;
2105             ;;
2106         xnoop)
2107             HAVE_NOOP_GALLIUM=yes;
2108             ;;
2109         *)
2110             GALLIUM_MAKE_DIRS="$GALLIUM_MAKE_DIRS $driver"
2111             ;;
2112     esac
2113 done
2114
2115 AM_CONDITIONAL(HAVE_GALAHAD_GALLIUM, test x$HAVE_GALAHAD_GALLIUM = xyes)
2116 AM_CONDITIONAL(HAVE_IDENTITY_GALLIUM, test x$HAVE_IDENTITY_GALLIUM = xyes)
2117 AM_CONDITIONAL(HAVE_NOOP_GALLIUM, test x$HAVE_NOOP_GALLIUM = xyes)
2118 AM_CONDITIONAL(NEED_RADEON_GALLIUM, test x$NEED_RADEON_GALLIUM = xyes)
2119 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2120 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2121 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2122 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2123 AC_SUBST([GALLIUM_MAKE_DIRS])
2124
2125 AM_CONDITIONAL(HAVE_X11_DRIVER, echo "$DRIVER_DIRS" | grep 'x11' >/dev/null 2>&1)
2126 AM_CONDITIONAL(HAVE_DRI_DRIVER, echo "$DRIVER_DIRS" | grep 'dri' >/dev/null 2>&1)
2127 AM_CONDITIONAL(HAVE_OSMESA_DRIVER, echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1)
2128
2129 AM_CONDITIONAL(HAVE_X86_ASM, echo "$DEFINES" | grep 'X86_ASM' >/dev/null 2>&1)
2130 AM_CONDITIONAL(HAVE_X86_64_ASM, echo "$DEFINES" | grep 'X86_64_ASM' >/dev/null 2>&1)
2131 AM_CONDITIONAL(HAVE_SPARC_ASM, echo "$DEFINES" | grep 'SPARC_ASM' >/dev/null 2>&1)
2132
2133 dnl prepend CORE_DIRS to SRC_DIRS
2134 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
2135
2136 dnl Restore LDFLAGS and CPPFLAGS
2137 LDFLAGS="$_SAVE_LDFLAGS"
2138 CPPFLAGS="$_SAVE_CPPFLAGS"
2139
2140 dnl Add user CFLAGS and CXXFLAGS
2141 CFLAGS="$CFLAGS $USER_CFLAGS"
2142 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2143
2144 dnl Substitute the config
2145 AC_CONFIG_FILES([configs/current
2146                 Makefile
2147                 src/Makefile
2148                 src/gallium/auxiliary/pipe-loader/Makefile
2149                 src/gallium/state_trackers/clover/Makefile
2150                 src/gallium/drivers/Makefile
2151                 src/gallium/drivers/r300/Makefile
2152                 src/gallium/drivers/r600/Makefile
2153                 src/gallium/targets/opencl/Makefile
2154                 src/gbm/Makefile
2155                 src/gbm/main/gbm.pc
2156                 src/egl/drivers/Makefile
2157                 src/egl/drivers/dri2/Makefile
2158                 src/egl/drivers/glx/Makefile
2159                 src/egl/Makefile
2160                 src/egl/main/Makefile
2161                 src/egl/main/egl.pc
2162                 src/egl/wayland/Makefile
2163                 src/egl/wayland/wayland-egl/Makefile
2164                 src/egl/wayland/wayland-egl/wayland-egl.pc
2165                 src/egl/wayland/wayland-drm/Makefile
2166                 src/glsl/tests/Makefile
2167                 src/glx/Makefile
2168                 src/glx/tests/Makefile
2169                 src/mapi/shared-glapi/Makefile
2170                 src/mapi/glapi/tests/Makefile
2171                 src/gtest/Makefile
2172                 src/mesa/libdricore/Makefile
2173                 src/mesa/main/tests/Makefile
2174                 src/mesa/x86/Makefile
2175                 src/mesa/x86-64/Makefile
2176                 src/mesa/drivers/Makefile
2177                 src/mesa/drivers/dri/dri.pc
2178                 src/mesa/drivers/dri/Makefile
2179                 src/mesa/drivers/dri/common/Makefile
2180                 src/mesa/drivers/dri/i915/Makefile
2181                 src/mesa/drivers/dri/i965/Makefile
2182                 src/mesa/drivers/dri/nouveau/Makefile
2183                 src/mesa/drivers/dri/r200/Makefile
2184                 src/mesa/drivers/dri/radeon/Makefile
2185                 src/mesa/drivers/dri/swrast/Makefile])
2186
2187 dnl Sort the dirs alphabetically
2188 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2189 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2190 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2191 GALLIUM_MAKE_DIRS=`echo $GALLIUM_MAKE_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2192 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2193
2194 AC_OUTPUT
2195
2196 dnl
2197 dnl Output some configuration info for the user
2198 dnl
2199 echo ""
2200 echo "        prefix:          $prefix"
2201 echo "        exec_prefix:     $exec_prefix"
2202 echo "        libdir:          $libdir"
2203 echo "        includedir:      $includedir"
2204
2205 dnl API info
2206 echo ""
2207 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2208 echo "        OpenVG:          $enable_openvg"
2209
2210 dnl Driver info
2211 echo ""
2212 if test "x$enable_osmesa" != xno; then
2213         echo "        OSMesa:          lib$OSMESA_LIB"
2214 else
2215         echo "        OSMesa:          no"
2216 fi
2217
2218 if test "x$enable_dri" != xno; then
2219         # cleanup the drivers var
2220         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2221         if test "x$DRI_DIRS" = x; then
2222             echo "        DRI drivers:     no"
2223         else
2224             echo "        DRI drivers:     $dri_dirs"
2225         fi
2226         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2227 fi
2228
2229 case "x$enable_glx$enable_xlib_glx" in
2230 xyesyes)
2231     echo "        GLX:             Xlib-based"
2232     ;;
2233 xyesno)
2234     echo "        GLX:             DRI-based"
2235     ;;
2236 *)
2237     echo "        GLX:             $enable_glx"
2238     ;;
2239 esac
2240
2241 echo ""
2242 echo "        GLU:             $enable_glu"
2243
2244 dnl EGL
2245 echo ""
2246 echo "        EGL:             $enable_egl"
2247 if test "$enable_egl" = yes; then
2248     echo "        EGL platforms:   $EGL_PLATFORMS"
2249
2250     egl_drivers=""
2251     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2252         egl_drivers="$egl_drivers builtin:egl_glx"
2253     fi
2254     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2255         egl_drivers="$egl_drivers builtin:egl_dri2"
2256     fi
2257
2258     if test "x$HAVE_ST_EGL" = xyes; then
2259         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2260         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2261     else
2262         echo "        EGL drivers:    $egl_drivers"
2263     fi
2264 fi
2265
2266 echo ""
2267 if test "x$MESA_LLVM" = x1; then
2268     echo "        llvm:            yes"
2269     echo "        llvm-config:     $LLVM_CONFIG"
2270     echo "        llvm-version:    $LLVM_VERSION"
2271 else
2272     echo "        llvm:            no"
2273 fi
2274
2275 echo ""
2276 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
2277     echo "        Gallium:         yes"
2278     echo "        Gallium dirs:    $GALLIUM_DIRS"
2279     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2280     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2281     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2282     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2283 else
2284     echo "        Gallium:         no"
2285 fi
2286
2287
2288 dnl Libraries
2289 echo ""
2290 echo "        Shared libs:     $enable_shared"
2291 echo "        Static libs:     $enable_static"
2292
2293 dnl Compiler options
2294 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2295 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
2296     $SED 's/^ *//;s/  */ /;s/ *$//'`
2297 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
2298     $SED 's/^ *//;s/  */ /;s/ *$//'`
2299 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2300 echo ""
2301 echo "        CFLAGS:          $cflags"
2302 echo "        CXXFLAGS:        $cxxflags"
2303 echo "        Macros:          $defines"
2304 echo ""
2305 echo "        PYTHON2:         $PYTHON2"
2306
2307 echo ""
2308 echo "        Run '${MAKE-make}' to build Mesa"
2309 echo ""