configure.ac

   1 dnl
   2 dnl  fontconfig/configure.in
   3 dnl
   4 dnl  Copyright © 2003 Keith Packard
   5 dnl
   6 dnl  Permission to use, copy, modify, distribute, and sell this software and its
   7 dnl  documentation for any purpose is hereby granted without fee, provided that
   8 dnl  the above copyright notice appear in all copies and that both that
   9 dnl  copyright notice and this permission notice appear in supporting
  10 dnl  documentation, and that the name of the author(s) not be used in
  11 dnl  advertising or publicity pertaining to distribution of the software without
  12 dnl  specific, written prior permission.  The authors make no
  13 dnl  representations about the suitability of this software for any purpose.  It
  14 dnl  is provided "as is" without express or implied warranty.
  15 dnl
  16 dnl  THE AUTHOR(S) DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
  17 dnl  INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
  18 dnl  EVENT SHALL THE AUTHOR(S) BE LIABLE FOR ANY SPECIAL, INDIRECT OR
  19 dnl  CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
  20 dnl  DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
  21 dnl  TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
  22 dnl  PERFORMANCE OF THIS SOFTWARE.
  23 dnl
  24 dnl Process this file with autoconf to create configure.
  25
  26 AC_PREREQ(2.61)
  27 AC_INIT(fonts.dtd)
  28
  29 dnl ==========================================================================
  30 dnl                               Versioning
  31 dnl ==========================================================================
  32
  33 dnl This is the package version number, not the shared library
  34 dnl version.  This same version number must appear in fontconfig/fontconfig.h
  35 dnl Yes, it is a pain to synchronize version numbers.  Unfortunately, it's
  36 dnl not possible to extract the version number here from fontconfig.h
  37 AM_INIT_AUTOMAKE(fontconfig, 2.10.0)
  38 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  39
  40 dnl libtool versioning
  41
  42 dnl bump revision when fixing bugs
  43 dnl bump current and age, reset revision to zero when adding APIs
  44 dnl bump current, leave age, reset revision to zero when changing/removing APIS
  45 LIBT_CURRENT=7
  46 LIBT_REVISION=2
  47 AC_SUBST(LIBT_CURRENT)
  48 AC_SUBST(LIBT_REVISION)
  49 LIBT_AGE=6
  50
  51 LIBT_VERSION_INFO="$LIBT_CURRENT:$LIBT_REVISION:$LIBT_AGE"
  52 AC_SUBST(LIBT_VERSION_INFO)
  53
  54 LIBT_CURRENT_MINUS_AGE=`expr $LIBT_CURRENT - $LIBT_AGE`
  55 AC_SUBST(LIBT_CURRENT_MINUS_AGE)
  56
  57 dnl ==========================================================================
  58
  59 AC_CONFIG_HEADERS(config.h)
  60
  61 AC_PROG_CC
  62 AC_PROG_INSTALL
  63 AC_PROG_LN_S
  64 AC_LIBTOOL_WIN32_DLL
  65 AM_PROG_LIBTOOL
  66 AC_PROG_MAKE_SET
  67 PKG_PROG_PKG_CONFIG
  68
  69 AC_MSG_CHECKING([for RM macro])
  70 _predefined_rm=`make -p -f /dev/null 2>/dev/null|grep '^RM ='|sed -e 's/^RM = //'`
  71 if test "x$_predefined_rm" = "x"; then
  72         AC_MSG_RESULT([no predefined RM])
  73         AC_CHECK_PROG(RM, rm, [rm -f])
  74 else
  75         AC_MSG_RESULT($_predefined_rm)
  76 fi
  77
  78 dnl ==========================================================================
  79
  80 case "$host" in
  81   *-*-mingw*)
  82     os_win32=yes
  83     ;;
  84   *)
  85     os_win32=no
  86 esac
  87 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
  88
  89 if test "$os_win32" = "yes"; then
  90   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
  91 fi
  92 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
  93
  94 WARN_CFLAGS=""
  95 if test "x$GCC" = "xyes"; then
  96         WARN_CFLAGS="-Wall -Wpointer-arith -Wstrict-prototypes \
  97         -Wmissing-prototypes -Wmissing-declarations \
  98         -Wnested-externs -fno-strict-aliasing"
  99         AC_DEFINE_UNQUOTED(HAVE_WARNING_CPP_DIRECTIVE,1,
 100         [Can use #warning in C files])
 101 fi
 102 AC_SUBST(WARN_CFLAGS)
 103
 104
 105 dnl ==========================================================================
 106
 107 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
 108 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = "yes")
 109
 110 dnl ==========================================================================
 111
 112 AC_ARG_WITH(arch,
 113         [AC_HELP_STRING([--with-arch=ARCH],
 114                         [Force architecture to ARCH])],
 115         arch="$withval", arch=auto)
 116
 117 if test "x$arch" != xauto; then
 118         AC_DEFINE_UNQUOTED([FC_ARCHITECTURE], "$arch", [Architecture prefix to use for cache file names])
 119 fi
 120
 121
 122 dnl ==========================================================================
 123
 124 # Checks for header files.
 125 AC_HEADER_DIRENT
 126 AC_HEADER_STDC
 127 AC_CHECK_HEADERS([fcntl.h regex.h stdlib.h string.h unistd.h sys/vfs.h sys/statfs.h sys/param.h sys/mount.h])
 128
 129 # Checks for typedefs, structures, and compiler characteristics.
 130 AC_C_CONST
 131 AC_C_INLINE
 132 AC_C_FLEXIBLE_ARRAY_MEMBER
 133 AC_TYPE_PID_T
 134
 135 # Checks for library functions.
 136 AC_FUNC_VPRINTF
 137 AC_FUNC_MMAP
 138 AC_CHECK_FUNCS([geteuid getuid link memmove memset mkstemp strchr strrchr strtol getopt getopt_long sysconf ftruncate chsize rand random lrand48 random_r rand_r regcomp regerror regexec regfree posix_fadvise fstatvfs fstatfs])
 139
 140 #
 141 if test "x$ac_cv_func_fstatvfs" = "xyes"; then
 142         AC_CHECK_MEMBERS([struct statvfs.f_basetype, struct statvfs.f_fstypename],,,
 143                 [#include <sys/statvfs.h>])
 144 fi
 145 if test "x$ac_cv_func_fstatfs" = "xyes"; then
 146         AC_CHECK_MEMBERS([struct statfs.f_flags, struct statfs.f_fstypename],,, [
 147 #ifdef HAVE_SYS_VFS_H
 148 #include <sys/vfs.h>
 149 #endif
 150 #ifdef HAVE_SYS_STATFS_H
 151 #include <sys/statfs.h>
 152 #endif
 153 #ifdef HAVE_SYS_PARAM_H
 154 #include <sys/param.h>
 155 #endif
 156 #ifdef HAVE_SYS_MOUNT_H
 157 #include <sys/mount.h>
 158 #endif])
 159 fi
 160 AC_CHECK_MEMBERS([struct dirent.d_type],,,
 161         [#include <dirent.h>])
 162 #
 163 # regex
 164 #
 165 if test "x$ac_cv_func_regcomp" = "xyes" -a "x$ac_cv_func_regerror" = "xyes" -a "x$ac_cv_func_regexec" = "xyes" -a "x$ac_cv_func_regfree"; then
 166         AC_DEFINE(USE_REGEX,,[Use regex])
 167 fi
 168
 169 #
 170 # Checks for iconv
 171 #
 172 AC_ARG_ENABLE(iconv,
 173         [AC_HELP_STRING([--enable-iconv],
 174                         [Use iconv to support non-Unicode SFNT name])],
 175         ,enable_iconv=no)
 176 AC_ARG_WITH(libiconv,
 177         [AC_HELP_STRING([--with-libiconv=DIR],
 178                         [Use libiconv in DIR])],
 179         [if test "x$withval" = "xyes"; then
 180                 libiconv_prefix=$prefix
 181          else
 182                 libiconv_prefix=$withval
 183          fi],
 184         [libiconv_prefix=auto])
 185 AC_ARG_WITH(libiconv-includes,
 186         [AC_HELP_STRING([--with-libiconv-includes=DIR],
 187                         [Use libiconv includes in DIR])],
 188         [libiconv_includes=$withval],
 189         [libiconv_includes=auto])
 190 AC_ARG_WITH(libiconv-lib,
 191         [AC_HELP_STRING([--with-libiconv-lib=DIR],
 192                         [Use libiconv library in DIR])],
 193         [libiconv_lib=$withval],
 194         [libiconv_lib=auto])
 195
 196 # if no libiconv,libiconv-includes,libiconv-lib are specified,
 197 # libc's iconv has a priority.
 198 if test "$libiconv_includes" != "auto" -a -r ${libiconv_includes}/iconv.h; then
 199         libiconv_cflags="-I${libiconv_includes}"
 200 elif test "$libiconv_prefix" != "auto" -a -r ${libiconv_prefix}/include/iconv.h; then
 201         libiconv_cflags="-I${libiconv_prefix}/include"
 202 else
 203         libiconv_cflags=""
 204 fi
 205 libiconv_libs=""
 206 if test "x$libiconv_cflags" != "x"; then
 207         if test "$libiconv_lib" != "auto" -a -d ${libiconv_lib}; then
 208                 libiconv_libs="-L${libiconv_lib} -liconv"
 209         elif test "$libiconv_prefix" != "auto" -a -d ${libiconv_prefix}/lib; then
 210                 libiconv_libs="-L${libiconv_prefix}/lib -liconv"
 211         else
 212                 libiconv_libs="-liconv"
 213         fi
 214 fi
 215
 216 use_iconv=0
 217 if test "x$enable_iconv" != "xno"; then
 218         AC_MSG_CHECKING([for a usable iconv])
 219         if test "x$libiconv_cflags" != "x" -o "x$libiconv_libs" != "x"; then
 220                 iconvsaved_CFLAGS="$CFLAGS"
 221                 iconvsaved_LIBS="$LIBS"
 222                 CFLAGS="$CFLAGS $libiconv_cflags"
 223                 LIBS="$LIBS $libiconv_libs"
 224
 225                 AC_TRY_LINK([#include <iconv.h>],
 226                         [iconv_open ("from", "to");],
 227                         [iconv_type="libiconv"
 228                          use_iconv=1],
 229                         [use_iconv=0])
 230
 231                 CFLAGS="$iconvsaved_CFLAGS"
 232                 LIBS="$iconvsaved_LIBS"
 233                 ICONV_CFLAGS="$libiconv_cflags"
 234                 ICONV_LIBS="$libiconv_libs"
 235         fi
 236         if test "x$use_iconv" = "x0"; then
 237                 AC_TRY_LINK([#include <iconv.h>],
 238                         [iconv_open ("from", "to");],
 239                         [iconv_type="libc"
 240                          use_iconv=1],
 241                         [iconv_type="not found"
 242                          use_iconv=0])
 243         fi
 244
 245         AC_MSG_RESULT([$iconv_type])
 246         AC_SUBST(ICONV_CFLAGS)
 247         AC_SUBST(ICONV_LIBS)
 248 fi
 249 AC_DEFINE_UNQUOTED(USE_ICONV,$use_iconv,[Use iconv.])
 250 #
 251 # Checks for FreeType
 252 #
 253 PKG_CHECK_MODULES(FREETYPE, freetype2)
 254
 255 AC_SUBST(FREETYPE_LIBS)
 256 AC_SUBST(FREETYPE_CFLAGS)
 257
 258 fontconfig_save_libs="$LIBS"
 259 fontconfig_save_cflags="$CFLAGS"
 260 LIBS="$LIBS $FREETYPE_LIBS"
 261 CFLAGS="$CFLAGS $FREETYPE_CFLAGS"
 262 AC_CHECK_FUNCS(FT_Get_Next_Char FT_Get_BDF_Property FT_Get_PS_Font_Info FT_Has_PS_Glyph_Names FT_Get_X11_Font_Format FT_Select_Size)
 263 AC_CHECK_MEMBER(FT_Bitmap_Size.y_ppem,
 264                 HAVE_FT_BITMAP_SIZE_Y_PPEM=1,
 265                 HAVE_FT_BITMAP_SIZE_Y_PPEM=0,
 266 [#include <ft2build.h>
 267 #include FT_FREETYPE_H])
 268 AC_DEFINE_UNQUOTED(HAVE_FT_BITMAP_SIZE_Y_PPEM,$HAVE_FT_BITMAP_SIZE_Y_PPEM,
 269                    [FT_Bitmap_Size structure includes y_ppem field])
 270 CFLAGS="$fontconfig_save_cflags"
 271 LIBS="$fontconfig_save_libs"
 272
 273 #
 274 # Check expat configuration
 275 #
 276 AC_ARG_WITH(expat,
 277         [AC_HELP_STRING([--with-expat=DIR],
 278                         [Use Expat in DIR])],
 279         [expat_prefix=$withval],
 280         [expat_prefix=auto])
 281 AC_ARG_WITH(expat-includes,
 282         [AC_HELP_STRING([--with-expat-includes=DIR],
 283                         [Use Expat includes in DIR])],
 284         [expat_includes=$withval],
 285         [expat_includes=auto])
 286 AC_ARG_WITH(expat-lib,
 287         [AC_HELP_STRING([--with-expat-lib=DIR])],
 288         [expat_lib=$withval],
 289         [expat_lib=auto])
 290
 291 if test "$enable_libxml2" != "yes"; then
 292         use_pkgconfig_for_expat=yes
 293         if test "$expat_prefix" = "auto" -a "$expat_includes" = "auto" -a "$expat_lib" = "auto"; then
 294                 PKG_CHECK_MODULES(EXPAT, expat,,use_pkgconfig_for_expat=no)
 295         else
 296                 use_pkgconfig_for_expat=no
 297         fi
 298         if test "x$use_pkgconfig_for_expat" = "xno"; then
 299                 if test "$expat_includes" != "auto" -a -r ${expat_includes}/expat.h; then
 300                         EXPAT_CFLAGS="-I${expat_includes}"
 301                 elif test "$expat_prefix" != "auto" -a -r ${expat_prefix}/include/expat.h; then
 302                         EXPAT_CFLAGS="-I${expat_prefix}/include"
 303                 else
 304                         EXPAT_CFLAGS=""
 305                 fi
 306                 if test "$expat_lib" != "auto"; then
 307                         EXPAT_LIBS="-L${expat_lib} -lexpat"
 308                 elif test "$expat_prefix" != "auto"; then
 309                         EXPAT_LIBS="-L${expat_prefix}/lib -lexpat"
 310                 else
 311                         EXPAT_LIBS="-lexpat"
 312                 fi
 313         fi
 314
 315         expatsaved_CPPFLAGS="$CPPFLAGS"
 316         expatsaved_LIBS="$LIBS"
 317         CPPFLAGS="$CPPFLAGS $EXPAT_CFLAGS"
 318         LIBS="$LIBS $EXPAT_LIBS"
 319
 320         AC_CHECK_HEADER(expat.h)
 321         if test "$ac_cv_header_expat_h" = "no"; then
 322                 AC_CHECK_HEADER(xmlparse.h)
 323                 if test "$ac_cv_header_xmlparse_h" = "yes"; then
 324                         HAVE_XMLPARSE_H=1
 325                         AC_SUBST(HAVE_XMLPARSE_H)
 326                         AC_DEFINE_UNQUOTED(HAVE_XMLPARSE_H,$HAVE_XMLPARSE_H,
 327                                 [Use xmlparse.h instead of expat.h])
 328                 else
 329                         AC_MSG_ERROR([
 330 *** expat is required. or try to use --enable-libxml2])
 331                 fi
 332         fi
 333         AC_CHECK_FUNCS(XML_SetDoctypeDeclHandler)
 334         if test "$ac_cv_func_XML_SetDoctypeDeclHandler" = "no"; then
 335                 AC_MSG_ERROR([
 336 *** expat is required. or try to use --enable-libxml2])
 337         fi
 338         CPPFLAGS="$expatsaved_CPPFLAGS"
 339         LIBS="$expatsaved_LIBS"
 340
 341         AC_SUBST(EXPAT_CFLAGS)
 342         AC_SUBST(EXPAT_LIBS)
 343 fi
 344
 345 #
 346 # Check libxml2 configuration
 347 #
 348 AC_ARG_ENABLE(libxml2,
 349         [AC_HELP_STRING([--enable-libxml2],
 350                         [Use libxml2 instead of Expat])])
 351
 352 if test "$enable_libxml2" = "yes"; then
 353     PKG_CHECK_MODULES([LIBXML2], [libxml-2.0 >= 2.6])
 354     AC_DEFINE_UNQUOTED(ENABLE_LIBXML2,1,[Use libxml2 instead of Expat])
 355
 356     AC_SUBST(LIBXML2_CFLAGS)
 357     AC_SUBST(LIBXML2_LIBS)
 358
 359     fc_saved_CFLAGS="$CFLAGS"
 360     CFLAGS="$CFLAGS $LIBXML2_CFLAGS"
 361     AC_MSG_CHECKING([SAX1 support in libxml2])
 362     AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 363         #include <libxml/xmlversion.h>
 364         #if !defined(LIBXML_SAX1_ENABLED)
 365         #  include "error: No SAX1 support in libxml2"
 366         #endif
 367         ]])], [AC_MSG_RESULT([found])], [AC_MSG_ERROR([
 368 *** SAX1 support in libxml2 is required. enable it or use expat instead.])])
 369     CFLAGS="$fc_saved_CFLAGS"
 370 fi
 371
 372 #
 373 # Set default font directory
 374 #
 375
 376 AC_ARG_WITH(default-fonts,
 377         [AC_HELP_STRING([--with-default-fonts=DIR],
 378                         [Use fonts from DIR when config is busted])],
 379         default_fonts="$withval", default_fonts=yes)
 380
 381 case "$default_fonts" in
 382 yes)
 383         if test "$os_win32" = "yes"; then
 384                 FC_DEFAULT_FONTS="WINDOWSFONTDIR"
 385                 AC_DEFINE_UNQUOTED(FC_DEFAULT_FONTS, "WINDOWSFONTDIR",
 386                                    [Windows font directory])
 387         else
 388                 FC_DEFAULT_FONTS="/usr/share/fonts"
 389                 AC_DEFINE_UNQUOTED(FC_DEFAULT_FONTS, "/usr/share/fonts",
 390                                    [System font directory])
 391         fi
 392         ;;
 393 *)
 394         FC_DEFAULT_FONTS="$default_fonts"
 395         AC_DEFINE_UNQUOTED(FC_DEFAULT_FONTS, "$default_fonts",
 396                            [System font directory])
 397         ;;
 398 esac
 399
 400 AC_SUBST(FC_DEFAULT_FONTS)
 401
 402 #
 403 # Add more fonts if available.  By default, add only the directories
 404 # with outline fonts; those with bitmaps can be added as desired in
 405 # local.conf or ~/.fonts.conf
 406 #
 407 AC_ARG_WITH(add-fonts,
 408         [AC_HELP_STRING([--with-add-fonts=DIR1,DIR2,...],
 409                         [Find additional fonts in DIR1,DIR2,... ])],
 410         add_fonts="$withval", add_fonts=yes)
 411
 412 case "$add_fonts" in
 413 yes)
 414         FC_ADD_FONTS=""
 415         for dir in /usr/X11R6/lib/X11 /usr/X11/lib/X11 /usr/lib/X11; do
 416                 case x"$FC_ADD_FONTS" in
 417                 x)
 418                         sub="$dir/fonts"
 419                         if test -d "$sub"; then
 420                                 case x$FC_ADD_FONTS in
 421                                 x)
 422                                         FC_ADD_FONTS="$sub"
 423                                         ;;
 424                                 *)
 425                                         FC_ADD_FONTS="$FC_ADD_FONTS,$sub"
 426                                         ;;
 427                                 esac
 428                         fi
 429                         ;;
 430                 esac
 431         done
 432         AC_DEFINE_UNQUOTED(FC_ADD_FONTS,"$add_fonts",[Additional font directories])
 433         ;;
 434 no)
 435         FC_ADD_FONTS=""
 436         ;;
 437 *)
 438         FC_ADD_FONTS="$add_fonts"
 439         AC_DEFINE_UNQUOTED(FC_ADD_FONTS,"$add_fonts",[Additional font directories])
 440         ;;
 441 esac
 442
 443 AC_SUBST(FC_ADD_FONTS)
 444
 445 FC_FONTPATH=""
 446
 447 case "$FC_ADD_FONTS" in
 448 "")
 449         ;;
 450 *)
 451         FC_FONTPATH=`echo $FC_ADD_FONTS |
 452                         sed -e 's/^/<dir>/' -e 's/$/<\/dir>/' -e 's/,/<\/dir> <dir>/g'`
 453         ;;
 454 esac
 455
 456 AC_SUBST(FC_FONTPATH)
 457
 458 #
 459 # Set default cache directory path
 460 #
 461 AC_ARG_WITH(cache-dir,
 462         [AC_HELP_STRING([--with-cache-dir=DIR],
 463                         [Use DIR to store cache files [default=LOCALSTATEDIR/cache/fontconfig]])],
 464         fc_cachedir="$withval", fc_cachedir=yes)
 465
 466 case $fc_cachedir in
 467 no|yes)
 468         if test "$os_win32" = "yes"; then
 469                 fc_cachedir="WINDOWSTEMPDIR_FONTCONFIG_CACHE"
 470         else
 471                 fc_cachedir='${localstatedir}/cache/${PACKAGE}'
 472         fi
 473         ;;
 474 *)
 475         ;;
 476 esac
 477 AC_SUBST(fc_cachedir)
 478 FC_CACHEDIR=${fc_cachedir}
 479 AC_SUBST(FC_CACHEDIR)
 480
 481 FC_FONTDATE=`LC_ALL=C date`
 482
 483 AC_SUBST(FC_FONTDATE)
 484
 485 #
 486 # Set configuration paths
 487 #
 488
 489 AC_ARG_WITH(templatedir,
 490         [AC_HELP_STRING([--with-templatedir=DIR],
 491                         [Use DIR to store the configuration template files [default=DATADIR/fontconfig/conf.avail]])],
 492         [templatedir="$withval"],
 493         [templatedir=yes])
 494 AC_ARG_WITH(baseconfigdir,
 495         [AC_HELP_STRING([--with-baseconfigdir=DIR],
 496                         [Use DIR to store the base configuration files [default=SYSCONFDIR/fonts]])],
 497         [baseconfigdir="$withval"],
 498         [baseconfigdir=yes])
 499 AC_ARG_WITH(configdir,
 500         [AC_HELP_STRING([--with-configdir=DIR],
 501                         [Use DIR to store active configuration files [default=BASECONFIGDIR/conf.d]])],
 502         [configdir="$withval"],
 503         [configdir=yes])
 504 AC_ARG_WITH(xmldir,
 505         [AC_HELP_STRING([--with-xmldir=DIR],
 506                         [Use DIR to store XML schema files [default=DATADIR/xml/fontconfig]])],
 507         [xmldir="$withval"],
 508         [xmldir=yes])
 509
 510 case "$templatedir" in
 511 no|yes)
 512         templatedir='${datadir}'/fontconfig/conf.avail
 513         ;;
 514 *)
 515         ;;
 516 esac
 517 case "$baseconfigdir" in
 518 no|yes)
 519         baseconfigdir='${sysconfdir}'/fonts
 520         ;;
 521 *)
 522         ;;
 523 esac
 524 case "$configdir" in
 525 no|yes)
 526         configdir='${baseconfigdir}'/conf.d
 527         ;;
 528 *)
 529         ;;
 530 esac
 531 case "$xmldir" in
 532 no|yes)
 533         xmldir='${datadir}'/xml/fontconfig
 534         ;;
 535 *)
 536         ;;
 537 esac
 538
 539 TEMPLATEDIR=${templatedir}
 540 BASECONFIGDIR=${baseconfigdir}
 541 CONFIGDIR=${configdir}
 542 XMLDIR=${xmldir}
 543 AC_SUBST(templatedir)
 544 AC_SUBST(TEMPLATEDIR)
 545 AC_SUBST(baseconfigdir)
 546 AC_SUBST(BASECONFIGDIR)
 547 AC_SUBST(configdir)
 548 AC_SUBST(CONFIGDIR)
 549 AC_SUBST(xmldir)
 550 AC_SUBST(XMLDIR)
 551
 552 #
 553 # Let people not build/install docs if they don't have docbook
 554 #
 555
 556 AC_CHECK_PROG(HASDOCBOOK, docbook2html, yes, no)
 557
 558 AM_CONDITIONAL(USEDOCBOOK, test "x$HASDOCBOOK" = xyes)
 559
 560 default_docs="yes"
 561 #
 562 # Check if docs exist or can be created
 563 #
 564 if test x$HASDOCBOOK = xno; then
 565         if test -f $srcdir/doc/fonts-conf.5; then
 566                 :
 567         else
 568                 default_docs="no"
 569         fi
 570 fi
 571
 572 AC_ARG_ENABLE(docs,
 573         [AC_HELP_STRING([--disable-docs],
 574                         [Don't build and install documentation])],
 575         ,
 576         enable_docs=$default_docs)
 577
 578 AM_CONDITIONAL(ENABLE_DOCS, test "x$enable_docs" = xyes)
 579
 580 if test "x$enable_docs" = xyes; then
 581         DOCSRC="doc"
 582         tmp=funcs.$$
 583         cat $srcdir/doc/*.fncs | awk '
 584         /^@TITLE@/      { if (!done) { printf ("%s\n", $2); done = 1; } }
 585         /^@FUNC@/       { if (!done) { printf ("%s\n", $2); done = 1; } }
 586         /^@@/           { done = 0; }' > $tmp
 587         DOCMAN3=`cat $tmp | awk '{ printf ("%s.3 ", $1); }'`
 588         echo DOCMAN3 $DOCMAN3
 589         rm -f $tmp
 590 else
 591         DOCSRC=""
 592         DOCMAN3=""
 593 fi
 594
 595 AC_SUBST(DOCSRC)
 596 AC_SUBST(DOCMAN3)
 597
 598
 599 dnl Figure out what cache format suffix to use for this architecture
 600 AC_C_BIGENDIAN
 601 AC_CHECK_SIZEOF([void *])
 602 AC_CHECK_ALIGNOF([double])
 603
 604 dnl include the header file for workaround of miscalculating size on autoconf
 605 dnl particularly for fat binaries
 606 AH_BOTTOM([#include "config-fixups.h"])
 607
 608 AC_OUTPUT([
 609 Makefile
 610 fontconfig/Makefile
 611 fc-lang/Makefile
 612 fc-glyphname/Makefile
 613 fc-case/Makefile
 614 src/Makefile
 615 conf.d/Makefile
 616 fc-cache/Makefile
 617 fc-cat/Makefile
 618 fc-list/Makefile
 619 fc-match/Makefile
 620 fc-pattern/Makefile
 621 fc-query/Makefile
 622 fc-scan/Makefile
 623 doc/Makefile
 624 doc/version.sgml
 625 test/Makefile
 626 fontconfig.spec
 627 fontconfig.pc
 628 fontconfig-zip
 629 ])