configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.10.23.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.10
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 dnl FIXME: this macro doesn't actually work;
  47 dnl the generated libtool script has no support for the listed tags.
  48 dnl So this needs to be fixed first if we want to use this
  49 dnl AS_LIBTOOL_TAGS
  50
  51 AC_LIBTOOL_WIN32_DLL
  52 AM_PROG_LIBTOOL
  53
  54 dnl *** required versions of GStreamer stuff ***
  55 GST_REQ=0.10.29
  56 GSTPB_REQ=0.10.29
  57
  58 dnl *** autotools stuff ****
  59
  60 dnl allow for different autotools
  61 AS_AUTOTOOLS_ALTERNATE
  62
  63 dnl Add parameters for aclocal
  64 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  65
  66 dnl set up gettext
  67 dnl the version check needs to stay here because autopoint greps for it
  68 AM_GNU_GETTEXT_VERSION([0.17])
  69 AM_GNU_GETTEXT([external])
  70 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  71
  72 dnl *** check for arguments to configure ***
  73
  74 AG_GST_ARG_DEBUG
  75 AG_GST_ARG_PROFILING
  76 AG_GST_ARG_VALGRIND
  77 AG_GST_ARG_GCOV
  78
  79 AG_GST_ARG_EXAMPLES
  80
  81 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  82 AG_GST_ARG_WITH_PACKAGE_NAME
  83 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  84
  85 AG_GST_ARG_WITH_PLUGINS
  86
  87 AG_GST_ARG_ENABLE_EXTERNAL
  88
  89 AG_GST_ARG_ENABLE_EXPERIMENTAL
  90
  91 dnl *** checks for platform ***
  92
  93 dnl * hardware/architecture *
  94
  95 dnl common/m4/gst-arch.m4
  96 dnl check CPU type
  97 AG_GST_ARCH
  98
  99 dnl Determine endianness
 100 AC_C_BIGENDIAN
 101
 102 dnl *** checks for programs ***
 103
 104 dnl find a compiler
 105 AC_PROG_CC
 106
 107 dnl determine c++ compiler
 108 AC_PROG_CXX
 109 dnl determine if c++ is available on this system
 110 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 111
 112 dnl determine c++ preprocessor
 113 dnl FIXME: do we need this ?
 114 AC_PROG_CXXCPP
 115
 116 AS_PROG_OBJC
 117
 118 dnl check if the compiler supports '-c' and '-o' options
 119 AM_PROG_CC_C_O
 120
 121 dnl find an assembler
 122 AM_PROG_AS
 123
 124 dnl check if the compiler supports do while(0) macros
 125 AG_GST_CHECK_DOWHILE_MACROS
 126
 127 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 128 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 129
 130 dnl check for gconftool-2
 131 dnl this macro defines an am conditional, so it needs to be run always
 132 AM_GCONF_SOURCE_2
 133
 134 dnl check for documentation tools
 135 GTK_DOC_CHECK([1.3])
 136 AS_PATH_PYTHON([2.1])
 137 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 138
 139 dnl *** checks for libraries ***
 140
 141 dnl check for libm, for sin()
 142 AC_CHECK_LIBM
 143 AC_SUBST(LIBM)
 144
 145 dnl *** checks for header files ***
 146
 147 dnl check if we have ANSI C header files
 148 AC_HEADER_STDC
 149
 150 dnl used by ext/wavpack
 151 AX_CREATE_STDINT_H
 152
 153 dnl used in gst/rtp/gstasteriskh263.c
 154 AC_CHECK_HEADERS([netinet/in.h])
 155 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 156 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 157
 158 dnl used in gst/udp
 159 AC_CHECK_HEADERS([sys/time.h])
 160
 161 dnl *** checks for types/defines ***
 162
 163 dnl Check for FIONREAD ioctl declaration.  This check is needed
 164 dnl for the UDP plugin to build on Solaris
 165 GST_CHECK_FIONREAD
 166
 167 dnl *** checks for structures ***
 168
 169 dnl *** checks for compiler characteristics ***
 170
 171 dnl check if we have GCC inline-asm
 172 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 173 if test x$HAVE_GCC_ASM = xyes ; then
 174   AC_DEFINE(HAVE_GCC_ASM, 1,
 175     [Define if compiler supports gcc inline assembly])
 176 fi
 177 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 178
 179 dnl *** checks for library functions ***
 180
 181 LIBS_SAVE=$LIBS
 182 LIBS="$LIBS $LIBM"
 183 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 184 LIBS=$LIBS_SAVE
 185
 186 dnl Check whether isinf() is defined by math.h
 187 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 188     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 189 if test "$ac_cv_have_isinf" = "yes"
 190 then
 191     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 192 fi
 193
 194 dnl Check for mmap (needed by electricfence plugin)
 195 AC_FUNC_MMAP
 196 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 197
 198 dnl Check for mmap (needed by electricfence plugin)
 199
 200 AC_CHECK_TYPE([struct ip_mreqn], [
 201               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 202               [#include <netinet/in.h>])
 203
 204 dnl *** checks for dependency libraries ***
 205
 206 dnl GLib is required
 207 AG_GST_GLIB_CHECK([2.18])
 208
 209 dnl liboil is required
 210 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.8, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 211 if test "x$HAVE_LIBOIL" != "xyes"; then
 212   AC_ERROR([liboil-0.3.8 or later is required])
 213 fi
 214
 215 dnl checks for gstreamer
 216 dnl uninstalled is selected preferentially -- see pkg-config(1)
 217 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 218 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 219 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 220 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 221 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 222 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 223
 224 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 225 if test -z $GST_TOOLS_DIR; then
 226   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 227 fi
 228 AC_SUBST(GST_TOOLS_DIR)
 229
 230 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 231 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 232
 233 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 234
 235 dnl Check for documentation xrefs
 236 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 237 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 238 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 239 AC_SUBST(GLIB_PREFIX)
 240 AC_SUBST(GST_PREFIX)
 241 AC_SUBST(GSTPB_PREFIX)
 242
 243 dnl GTK is optional and used in examples
 244 if test "x$BUILD_EXAMPLES" = "xyes"; then
 245   PKG_CHECK_MODULES(GTK, gtk+-3.0, HAVE_GTK=yes,
 246   [PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.8.0, HAVE_GTK=yes, HAVE_GTK=no)])
 247   AC_SUBST(GTK_LIBS)
 248   AC_SUBST(GTK_CFLAGS)
 249 fi
 250 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 251
 252 dnl should we install schemas ?
 253 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 254 AG_GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 255   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 256   if test x$GCONFTOOL = xno; then
 257     AC_MSG_WARN(Not installing GConf schemas)
 258     HAVE_GCONFTOOL="no"
 259   else
 260     HAVE_GCONFTOOL="yes"
 261   fi
 262   AC_SUBST(HAVE_GCONFTOOL)
 263 ])
 264
 265 dnl *** set variables based on configure arguments ***
 266
 267 dnl set license and copyright notice
 268 GST_LICENSE="LGPL"
 269 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 270 AC_SUBST(GST_LICENSE)
 271
 272 dnl set location of plugin directory
 273 AG_GST_SET_PLUGINDIR
 274
 275 dnl define an ERROR_CFLAGS Makefile variable
 276 dnl -Wundef: too many broken headers
 277 dnl -Waggregate-return: causes problems with ObjC code like in osxvideosink
 278 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 279         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 280         -Wwrite-strings -Wold-style-definition
 281         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 282         -Wnested-externs ])
 283
 284 dnl define an ERROR_CXXFLAGS Makefile variable
 285 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 286         -Wmissing-declarations -Wredundant-decls
 287         -Wwrite-strings
 288         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar ])
 289
 290 dnl define correct level for debugging messages
 291 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 292
 293 dnl used in examples
 294 AG_GST_DEFAULT_ELEMENTS
 295
 296 dnl *** plug-ins to include ***
 297
 298 dnl these are all the gst plug-ins, compilable without additional libs
 299 dnl videofilter is at the top because others depend on it
 300 AG_GST_CHECK_PLUGIN(videofilter)
 301 AG_GST_CHECK_PLUGIN(alpha)
 302 AG_GST_CHECK_PLUGIN(apetag)
 303 AG_GST_CHECK_PLUGIN(audiofx)
 304 AG_GST_CHECK_PLUGIN(auparse)
 305 AG_GST_CHECK_PLUGIN(autodetect)
 306 AG_GST_CHECK_PLUGIN(avi)
 307 AG_GST_CHECK_PLUGIN(cutter)
 308 AG_GST_CHECK_PLUGIN(debugutils)
 309 AG_GST_CHECK_PLUGIN(deinterlace)
 310 AG_GST_CHECK_PLUGIN(effectv)
 311 AG_GST_CHECK_PLUGIN(equalizer)
 312 AG_GST_CHECK_PLUGIN(flv)
 313 AG_GST_CHECK_PLUGIN(id3demux)
 314 AG_GST_CHECK_PLUGIN(icydemux)
 315 AG_GST_CHECK_PLUGIN(interleave)
 316 AG_GST_CHECK_PLUGIN(flx)
 317 AG_GST_CHECK_PLUGIN(goom)
 318 AG_GST_CHECK_PLUGIN(goom2k1)
 319 AG_GST_CHECK_PLUGIN(imagefreeze)
 320 AG_GST_CHECK_PLUGIN(law)
 321 AG_GST_CHECK_PLUGIN(level)
 322 AG_GST_CHECK_PLUGIN(matroska)
 323 AG_GST_CHECK_PLUGIN(monoscope)
 324 AG_GST_CHECK_PLUGIN(multifile)
 325 AG_GST_CHECK_PLUGIN(multipart)
 326 AG_GST_CHECK_PLUGIN(qtdemux)
 327 AG_GST_CHECK_PLUGIN(replaygain)
 328 AG_GST_CHECK_PLUGIN(rtp)
 329 AG_GST_CHECK_PLUGIN(rtpmanager)
 330 AG_GST_CHECK_PLUGIN(rtsp)
 331 AG_GST_CHECK_PLUGIN(shapewipe)
 332 AG_GST_CHECK_PLUGIN(smpte)
 333 AG_GST_CHECK_PLUGIN(spectrum)
 334 AG_GST_CHECK_PLUGIN(udp)
 335 AG_GST_CHECK_PLUGIN(videobox)
 336 AG_GST_CHECK_PLUGIN(videocrop)
 337 AG_GST_CHECK_PLUGIN(videomixer)
 338 AG_GST_CHECK_PLUGIN(wavenc)
 339 AG_GST_CHECK_PLUGIN(wavparse)
 340 AG_GST_CHECK_PLUGIN(y4m)
 341
 342 dnl *** checks for socket and nsl libraries ***
 343 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 344
 345 dnl disable gst plugins we might not be able to build on this
 346 dnl platform: udp and rtsp (ugly but minimally invasive)
 347 dnl FIXME: maybe move to sys
 348 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 349 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 350
 351 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 352   AG_GST_DISABLE_PLUGIN(udp)
 353   AG_GST_DISABLE_PLUGIN(rtsp)
 354 fi
 355
 356 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 357   WIN32_LIBS="-lws2_32"
 358   AC_SUBST(WIN32_LIBS)
 359 fi
 360
 361 dnl disable experimental plug-ins
 362 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 363   AG_GST_DISABLE_PLUGIN(monoscope)
 364 fi
 365
 366 dnl *** sys plug-ins ***
 367
 368 echo
 369 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 370 echo
 371
 372 dnl DirectSound
 373 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 374 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 375   HAVE_DIRECTSOUND="no"
 376   save_CFLAGS="$CFLAGS"
 377   save_LDFLAGS="$LDFLAGS"
 378   save_LIBS="$LIBS"
 379   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 380   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 381   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 382   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 383   AC_LINK_IFELSE([
 384 #include <windows.h>
 385 #include <dxerr9.h>
 386 #include <dsound.h>
 387
 388 int main ()
 389 {
 390   DXGetErrorString9 (0);
 391   DirectSoundCreate(NULL, NULL, NULL);
 392
 393   return 0;
 394 }
 395 ],
 396     [HAVE_DIRECTSOUND="yes"],
 397     [HAVE_DIRECTSOUND="no"])
 398   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 399   CFLAGS=$save_CFLAGS
 400   LDFLAGS=$save_LDFLAGS
 401   LIBS=$save_LIBS
 402
 403   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 404     dnl this is much more than we want
 405     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 406     AC_SUBST(DIRECTSOUND_CFLAGS)
 407     AC_SUBST(DIRECTSOUND_LDFLAGS)
 408     AC_SUBST(DIRECTSOUND_LIBS)
 409   fi
 410   AC_SUBST(HAVE_DIRECTSOUND)
 411 ])
 412
 413 dnl *** OSS audio *** (Linux, *BSD)
 414 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 415 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 416  HAVE_OSS="yes"
 417 dnl Linux and newer BSD versions :
 418  AC_CHECK_HEADER(sys/soundcard.h, [
 419    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 420    ] , [
 421 dnl Some old BSD versions and also newer OpenBSD versions :
 422    AC_CHECK_HEADER(soundcard.h, [
 423      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 424      ], [
 425   dnl Some old BSD versions :
 426      AC_CHECK_HEADER(machine/soundcard.h, [
 427        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 428          [Define if OSS includes are in /machine/])
 429        ], [
 430        HAVE_OSS="no"
 431      ])
 432    ])
 433  ])
 434 ])
 435
 436 dnl *** oss4 ***
 437 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 438 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 439   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 440   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 441       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 442       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 443 ])
 444
 445 dnl *** Sun Audio ***
 446 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 447 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 448   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 449 ])
 450
 451 dnl *** OSX Audio ***
 452 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 453 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 454   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 455 ])
 456
 457 dnl *** OS X video ***
 458 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 459 HAVE_OSX_VIDEO="no"
 460 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 461   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 462 ])
 463 dnl in case header OpenGL/gl.h is found on other platforms
 464 case "$host" in
 465   *-*darwin*)
 466     dnl do nothing
 467     ;;
 468   *)
 469     HAVE_OSX_VIDEO="no"
 470     ;;
 471 esac
 472
 473
 474 dnl *** Video 4 Linux 2 ***
 475 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 476 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 477 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 478 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 479   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 480   AC_TRY_COMPILE([
 481 #include <sys/types.h>
 482 #ifdef __sun /* Solaris */
 483 #include <sys/types.h>
 484 #include <sys/videodev2.h>
 485 #else /* Linux */
 486 #include <linux/types.h>
 487 #define _LINUX_TIME_H
 488 #define __user
 489 #include <linux/videodev2.h>
 490 #endif
 491 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 492 #error too early v4l2 version or no v4l2 at all
 493 #endif
 494     ], [
 495 return 0;
 496     ], [
 497       HAVE_GST_V4L2="yes"
 498       AC_MSG_RESULT(yes)
 499     ], [
 500       HAVE_GST_V4L2="no"
 501       AC_MSG_RESULT(no)
 502
 503       HAVE_VIDEODEV=no
 504       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 505       [
 506         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 507       ])
 508
 509       if test "x$HAVE_VIDEODEV" = "xyes"; then
 510         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 511         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 512       else
 513         AC_MSG_WARN([video4linux2 was not found])
 514       fi
 515     ])
 516
 517   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 518     dnl check for missing v4l2_buffer declaration (see #135919)
 519     MISSING_DECL=0
 520     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 521     AC_TRY_COMPILE([
 522 #include <sys/types.h>
 523 #ifdef __sun /* Solaris */
 524 #include <sys/types.h>
 525 #include <sys/videodev2.h>
 526 #else /* Linux */
 527 #include <linux/types.h>
 528 #define _LINUX_TIME_H
 529 #define __user
 530 #include <linux/videodev2.h>
 531 #endif
 532     ],[
 533 struct v4l2_buffer buf;
 534 buf.index = 0;
 535 return 0;
 536     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 537     if [ test x$MISSING_DECL = x1 ]; then
 538       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 539     fi
 540
 541     dnl check for XOverlay libraries
 542     AG_GST_CHECK_XV
 543   fi
 544 ])
 545
 546 # Optional gudev for device probing
 547 AC_ARG_WITH([gudev],
 548   AC_HELP_STRING([--with-gudev],
 549     [device detection with gudev]),
 550   [],
 551   [with_gudev=check])
 552 if test x$HAVE_GST_V4L2 = xyes; then
 553   if test x$with_gudev != xno; then
 554       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 555           [ have_gudev=yes
 556             AC_DEFINE(HAVE_GUDEV, 1,
 557                [Whether gudev is available for device detection])
 558             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 559           ], [
 560           have_gudev=no
 561           ])
 562   else
 563     have_gudev=no
 564   fi
 565 fi
 566 AC_SUBST(GUDEV_CFLAGS)
 567 AC_SUBST(GUDEV_LIBS)
 568
 569 # Make libv4l2 non-automagic
 570 AC_ARG_WITH([libv4l2],
 571   AC_HELP_STRING([--with-libv4l2],
 572     [support video buffer conversion using libv4l2]),
 573   [],
 574   [with_libv4l2=check])
 575 if test x$HAVE_GST_V4L2 = xyes; then
 576   if test x$with_libv4l2 != xno; then
 577       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 578           [ have_libv4l2=yes
 579             AC_DEFINE(HAVE_LIBV4L2, 1,
 580                 [Whether libv4l2 is available for video buffer conversion])
 581           ], [
 582           have_libv4l2=no
 583           ])
 584   else
 585     have_libv4l2=no
 586   fi
 587 fi
 588
 589 dnl Check for X11
 590 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 591 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 592                   [ximagesrc], [
 593   AC_PATH_XTRA
 594
 595   dnl now try to find the HEADER
 596   ac_cflags_save="$CFLAGS"
 597   ac_cppflags_save="$CPPFLAGS"
 598   CFLAGS="$CFLAGS $X_CFLAGS"
 599   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 600   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 601
 602   if test "x$HAVE_X" = "xno"
 603   then
 604     AC_MSG_NOTICE([cannot find X11 development files])
 605   else
 606     dnl this is much more than we want
 607     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 608     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 609     dnl it does not add the libs; therefore we add them here
 610     X_LIBS="$X_LIBS -lX11"
 611     AC_SUBST(X_CFLAGS)
 612     AC_SUBST(X_LIBS)
 613
 614     dnl check for Xfixes
 615     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 616     if test "x$HAVE_XFIXES" = "xyes"
 617     then
 618         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 619     fi
 620     AC_SUBST(XFIXES_LIBS)
 621     AC_SUBST(XFIXES_CFLAGS)
 622
 623     dnl check for Xdamage
 624     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 625     if test "x$HAVE_XDAMAGE" = "xyes"
 626     then
 627         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 628     fi
 629     AC_SUBST(XDAMAGE_LIBS)
 630     AC_SUBST(XDAMAGE_CFLAGS)
 631   fi
 632   AC_SUBST(HAVE_X)
 633   CFLAGS="$ac_cflags_save"
 634   CPPFLAGS="$ac_cppflags_save"
 635 ])
 636
 637 dnl FIXME: this should be rolled into the test above, it's just an additional
 638 dnl feature of the ximagesrc plug-in
 639 dnl This is the same as in gst-plugins-base
 640 dnl check for X Shm
 641 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 642 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 643   if test x$HAVE_X = xyes; then
 644     AC_CHECK_LIB(Xext, XShmAttach,
 645                  HAVE_XSHM="yes", HAVE_XSHM="no",
 646                  $X_LIBS)
 647     if test "x$HAVE_XSHM" = "xyes"; then
 648       XSHM_LIBS="-lXext"
 649     else
 650       dnl On AIX, it is in XextSam instead, but we still need -lXext
 651       AC_CHECK_LIB(XextSam, XShmAttach,
 652                    HAVE_XSHM="yes", HAVE_XSHM="no",
 653                    $X_LIBS)
 654       if test "x$HAVE_XSHM" = "xyes"; then
 655         XSHM_LIBS="-lXext -lXextSam"
 656       fi
 657     fi
 658   fi
 659 ], ,[
 660   AC_SUBST(HAVE_XSHM)
 661   AC_SUBST(XSHM_LIBS)
 662 ])
 663
 664 dnl for V4L2, we also need to know if we have XVIDEO
 665 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 666 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 667                   [], [
 668   AG_GST_CHECK_XV
 669 ])
 670
 671 dnl *** ext plug-ins ***
 672 dnl keep this list sorted alphabetically !
 673
 674 if test "x$BUILD_EXTERNAL" = "xyes"; then
 675
 676 echo
 677 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 678 echo
 679
 680 dnl *** aalib ***
 681 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 682 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 683   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 684   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 685 ])
 686
 687 dnl *** annodex ***
 688 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 689 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 690   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 691 ])
 692
 693 dnl *** cairo ***
 694 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 695 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 696   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 697 ])
 698
 699 dnl **** ESound ****
 700 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 701 AG_GST_CHECK_FEATURE(ESD, [ESounD sound daemon], esdsink, [
 702   AG_GST_PKG_CHECK_MODULES(ESD, esound >= 0.2.12)
 703   if test $HAVE_ESD = no
 704   then
 705     AM_PATH_ESD(0.2.12, HAVE_ESD="yes")
 706     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 707   fi
 708 ])
 709
 710 dnl *** FLAC ***
 711 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 712 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 713   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 714 ])
 715
 716 dnl *** GConf ***
 717 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 718 AG_GST_CHECK_FEATURE(GCONF, [GConf libraries], gconfelements, [
 719   AG_GST_PKG_CHECK_MODULES(GCONF, gconf-2.0)
 720 ])
 721
 722 dnl *** GDK pixbuf ***
 723 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 724 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 725   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 726 ])
 727
 728 dnl *** HAL ***
 729 translit(dnm, m, l) AM_CONDITIONAL(USE_HAL, true)
 730 AG_GST_CHECK_FEATURE(HAL, [HAL libraries], halelements, [
 731   AG_GST_PKG_CHECK_MODULES(HAL, [hal >= 0.5.6, dbus-1 >= 0.32])
 732 ])
 733
 734 dnl *** jpeg ***
 735 dnl FIXME: we could use header checks here as well IMO
 736 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 737 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 738   AC_ARG_WITH(jpeg-mmx,
 739     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 740   OLD_LIBS="$LIBS"
 741   if test x$with_jpeg_mmx != x; then
 742     LIBS="$LIBS -L$with_jpeg_mmx"
 743   fi
 744   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 745   JPEG_LIBS="$LIBS -ljpeg-mmx"
 746   LIBS="$OLD_LIBS"
 747   if test x$HAVE_JPEG != xyes; then
 748     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 749     JPEG_LIBS="-ljpeg"
 750   fi
 751   AC_SUBST(JPEG_LIBS)
 752 ])
 753
 754 dnl *** libcaca ***
 755 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 756 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 757   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 758   dnl only newer versions of libcaca ship caca.pc, so try caca-config as well
 759   if test "x$HAVE_LIBCACA" != "xyes"; then
 760     AG_GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
 761     dnl see if it compilation works too, might not if we are cross-compiling
 762     if test "x$HAVE_LIBCACA" = "xyes"; then
 763       AC_CHECK_LIB([caca], [caca_init], [HAVE_LIBCACA=yes],
 764                    [HAVE_LIBCACA=no], [$LIBCACA_LIBS])
 765     fi
 766   fi
 767 ])
 768
 769 dnl *** libdv ***
 770 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 771 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 772   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 773 ])
 774
 775 dnl *** libpng ***
 776 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 777 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 778   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 779 ])
 780
 781 dnl *** pulseaudio ***
 782 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 783 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 784   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 0.9.10)
 785   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_11, libpulse >= 0.9.11)
 786   if test x$HAVE_PULSE_0_9_11 = xyes; then
 787     AC_DEFINE(HAVE_PULSE_0_9_11, 1, [defined if pulseaudio >= 0.9.11 is available])
 788   fi
 789   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_12, libpulse >= 0.9.12)
 790   if test x$HAVE_PULSE_0_9_12 = xyes; then
 791     AC_DEFINE(HAVE_PULSE_0_9_12, 1, [defined if pulseaudio >= 0.9.12 is available])
 792   fi
 793   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_13, libpulse >= 0.9.13)
 794   if test x$HAVE_PULSE_0_9_13 = xyes; then
 795     AC_DEFINE(HAVE_PULSE_0_9_13, 1, [defined if pulseaudio >= 0.9.13 is available])
 796   fi
 797   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_15, libpulse >= 0.9.15)
 798   if test x$HAVE_PULSE_0_9_15 = xyes; then
 799     AC_DEFINE(HAVE_PULSE_0_9_15, 1, [defined if pulseaudio >= 0.9.15 is available])
 800   fi
 801   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_20, libpulse >= 0.9.20)
 802   if test x$HAVE_PULSE_0_9_20 = xyes; then
 803     AC_DEFINE(HAVE_PULSE_0_9_20, 1, [defined if pulseaudio >= 0.9.20 is available])
 804   fi
 805 ])
 806
 807 dnl *** dv1394 ***
 808 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 809 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 810   dnl first test for libraw1394 >= 1.2.1
 811   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.2.1)
 812   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 813   dnl now see how far we got
 814   if test x$HAVE_RAW1394 = xyes && \
 815      test x$HAVE_LIBIEC61883 = xyes; then
 816        AG_GST_CHECK_LIBHEADER(AVC1394,
 817         avc1394, avc1394_send_command, $RAW1394_LIBS,
 818         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 819        AG_GST_CHECK_LIBHEADER(ROM1394,
 820         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 821         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 822        if test x$HAVE_AVC1394 = xyes && \
 823           test x$HAVE_AVC1394 = xyes && \
 824           test x$HAVE_ROM1394 = xyes; then
 825           HAVE_DV1394=yes
 826           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 827           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 828           AC_SUBST(DV1394_CFLAGS)
 829           AC_SUBST(DV1394_LIBS)
 830         fi
 831   else
 832        if test x$HAVE_RAW1394 = xno; then
 833           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 834           AG_GST_CHECK_LIBHEADER(AVC1394,
 835            avc1394, avc1394_send_command, $RAW1394_LIBS,
 836            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 837           AG_GST_CHECK_LIBHEADER(ROM1394,
 838            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 839            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 840           if test x$HAVE_RAW1394 = xyes && \
 841              test x$HAVE_AVC1394 = xyes && \
 842              test x$HAVE_ROM1394 = xyes; then
 843              HAVE_DV1394=yes
 844              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 845              DV1394_CFLAGS="$RAW1394_CFLAGS"
 846              if test x$HAVE_LIBIEC61883 = xyes; then
 847                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 848                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 849              fi
 850              AC_SUBST(DV1394_CFLAGS)
 851              AC_SUBST(DV1394_LIBS)
 852            fi
 853          fi
 854   fi
 855 ])
 856
 857 dnl *** shout2 ***
 858 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 859 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 860   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 861   if test $HAVE_SHOUT2 = no
 862   then
 863     AM_PATH_SHOUT2(HAVE_SHOUT2="yes")
 864     AC_SUBST(SHOUT2_CFLAGS)
 865     AC_SUBST(SHOUT2_LIBS)
 866   fi
 867 ])
 868
 869 dnl *** soup ***
 870 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 871 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 872   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 873     HAVE_SOUP="yes"
 874     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 875   ],[
 876     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26, HAVE_SOUP="yes", [
 877       HAVE_SOUP="no"
 878       AC_MSG_RESULT(no)
 879     ])
 880   ])
 881   AC_SUBST(SOUP_CFLAGS)
 882   AC_SUBST(SOUP_LIBS)
 883 ])
 884
 885 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 886 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 887 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 888 dnl   speex_jitter.h is 1.1.x only
 889 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 890 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 891   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 892   if test $HAVE_SPEEX = no
 893   then
 894     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 895       AC_CHECK_HEADER(speex/speex_jitter.h, [
 896         dnl speex 1.1.x :
 897         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 898           dnl speex 1.1.5 or + :
 899           HAVE_SPEEX="yes"
 900           SPEEX_LIBS="-lspeex"
 901           AC_SUBST(SPEEX_CFLAGS)
 902           AC_SUBST(SPEEX_LIBS)
 903         ],[
 904           HAVE_SPEEX="no"
 905         ])
 906       ],[
 907         dnl speex 1.0.x :
 908           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 909             dnl speex 1.0.4
 910             HAVE_SPEEX="yes"
 911             SPEEX_LIBS="-lspeex"
 912             AC_SUBST(SPEEX_CFLAGS)
 913             AC_SUBST(SPEEX_LIBS)
 914
 915             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 916               [defined if speex 1.0.x API detected])
 917         ],[
 918             HAVE_SPEEX="no"
 919             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 920         ], [
 921 #include <speex/speex.h>
 922         ])
 923       ])
 924     ])
 925   fi
 926 ])
 927
 928 dnl *** taglib ***
 929 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 930 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 931   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 932   if test "x$HAVE_CXX" != "xyes"; then
 933     USE_TAGLIB=false
 934     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 935   else
 936     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 937     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 938         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 939       ], [
 940         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 941     ])
 942     AC_SUBST(TAGLIB_CXXFLAGS)
 943   fi
 944 ])
 945
 946 dnl *** wavpack ***
 947 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 948 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 949   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 950     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 951       HAVE_WAVPACK=yes
 952       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 953     ],[
 954       HAVE_WAVPACK=no
 955       AC_MSG_RESULT(no)
 956     ])
 957   ])
 958   AC_SUBST(WAVPACK_CFLAGS)
 959   AC_SUBST(WAVPACK_LIBS)
 960 ])
 961
 962 dnl *** qtdemux & id3demux & matroska prefer to have zlib ***
 963 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 964 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for id3demux/qtdemux/matroska],, [
 965   AG_GST_CHECK_LIBHEADER(ZLIB,
 966     z, uncompress,, zlib.h, [
 967     HAVE_ZLIB="yes"
 968     ZLIB_LIBS="-lz"
 969     AC_SUBST(ZLIB_LIBS)
 970   ])
 971 ])
 972
 973 dnl *** matroska prefers to have bz2 ***
 974 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 975 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 976   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 977   AC_SUBST(BZ2_LIBS)
 978 ])
 979
 980 else
 981
 982 dnl not building plugins with external dependencies,
 983 dnl but we still need to set the conditionals
 984 AM_CONDITIONAL(USE_AALIB, false)
 985 AM_CONDITIONAL(USE_ANNODEX, false)
 986 AM_CONDITIONAL(USE_BZ2, false)
 987 AM_CONDITIONAL(USE_CAIRO, false)
 988 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 989 AM_CONDITIONAL(USE_DV1394, false)
 990 AM_CONDITIONAL(USE_ESD, false)
 991 AM_CONDITIONAL(USE_FLAC, false)
 992 AM_CONDITIONAL(USE_GCONF, false)
 993 AM_CONDITIONAL(USE_GCONFTOOL, false)
 994 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 995 AM_CONDITIONAL(USE_GST_V4L2, false)
 996 AM_CONDITIONAL(USE_HAL, false)
 997 AM_CONDITIONAL(USE_JPEG, false)
 998 AM_CONDITIONAL(USE_LIBCACA, false)
 999 AM_CONDITIONAL(USE_LIBDV, false)
1000 AM_CONDITIONAL(USE_LIBPNG, false)
1001 AM_CONDITIONAL(USE_OSS, false)
1002 AM_CONDITIONAL(USE_OSS4, false)
1003 AM_CONDITIONAL(USE_OSX_AUDIO, false)
1004 AM_CONDITIONAL(USE_OSX_VIDEO, false)
1005 AM_CONDITIONAL(USE_PULSE, false)
1006 AM_CONDITIONAL(USE_SHOUT2, false)
1007 AM_CONDITIONAL(USE_SOUP, false)
1008 AM_CONDITIONAL(USE_SPEEX, false)
1009 AM_CONDITIONAL(USE_SUNAUDIO, false)
1010 AM_CONDITIONAL(USE_TAGLIB, false)
1011 AM_CONDITIONAL(USE_WAVPACK, false)
1012 AM_CONDITIONAL(USE_X, false)
1013 AM_CONDITIONAL(USE_XSHM, false)
1014 AM_CONDITIONAL(USE_XVIDEO, false)
1015 AM_CONDITIONAL(USE_ZLIB, false)
1016
1017 fi dnl of EXT plugins
1018
1019 dnl *** finalize CFLAGS, LDFLAGS, LIBS
1020
1021 dnl Overview:
1022 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1023 dnl GST_*:              flags shared by all built objects
1024 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1025 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
1026 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1027 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1028
1029 dnl GST_OPTION_CFLAGS
1030 if test "x$USE_DEBUG" = xyes; then
1031    PROFILE_CFLAGS="-g"
1032 fi
1033 AC_SUBST(PROFILE_CFLAGS)
1034
1035 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1036   dnl Define _only_ for git (not pre-releases or releases)
1037   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1038 else
1039   DEPRECATED_CFLAGS=""
1040 fi
1041 AC_SUBST(DEPRECATED_CFLAGS)
1042
1043 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
1044 dnl at make time with e.g. make ERROR_CFLAGS=""
1045 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1046 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1047 AC_SUBST(GST_OPTION_CFLAGS)
1048 AC_SUBST(GST_OPTION_CXXFLAGS)
1049
1050 dnl our libraries need to be versioned correctly
1051 AC_SUBST(GST_LT_LDFLAGS)
1052
1053 dnl FIXME: do we want to rename to GST_ALL_* ?
1054 dnl prefer internal headers to already installed ones
1055 dnl also add builddir include for enumtypes and marshal
1056 dnl add ERROR_CFLAGS, but overridable
1057 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1058 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
1059 AC_SUBST(GST_CFLAGS)
1060 AC_SUBST(GST_CXXFLAGS)
1061 AC_SUBST(GST_LIBS)
1062
1063 dnl LDFLAGS really should only contain flags, not libs - they get added before
1064 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1065 GST_ALL_LDFLAGS="-no-undefined"
1066 AC_SUBST(GST_ALL_LDFLAGS)
1067
1068 dnl this really should only contain flags, not libs - they get added before
1069 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1070 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
1071 AC_SUBST(GST_PLUGIN_LDFLAGS)
1072
1073 dnl *** output files ***
1074
1075 dnl keep this alphabetic per directory, please
1076 AC_CONFIG_FILES(
1077 Makefile
1078 gst/Makefile
1079 gst/alpha/Makefile
1080 gst/apetag/Makefile
1081 gst/audiofx/Makefile
1082 gst/auparse/Makefile
1083 gst/autodetect/Makefile
1084 gst/avi/Makefile
1085 gst/cutter/Makefile
1086 gst/deinterlace/Makefile
1087 gst/debugutils/Makefile
1088 gst/effectv/Makefile
1089 gst/equalizer/Makefile
1090 gst/flv/Makefile
1091 gst/id3demux/Makefile
1092 gst/icydemux/Makefile
1093 gst/imagefreeze/Makefile
1094 gst/interleave/Makefile
1095 gst/goom/Makefile
1096 gst/goom2k1/Makefile
1097 gst/law/Makefile
1098 gst/level/Makefile
1099 gst/matroska/Makefile
1100 gst/monoscope/Makefile
1101 gst/multifile/Makefile
1102 gst/multipart/Makefile
1103 gst/qtdemux/Makefile
1104 gst/replaygain/Makefile
1105 gst/rtp/Makefile
1106 gst/rtpmanager/Makefile
1107 gst/rtsp/Makefile
1108 gst/shapewipe/Makefile
1109 gst/smpte/Makefile
1110 gst/spectrum/Makefile
1111 gst/udp/Makefile
1112 gst/videobox/Makefile
1113 gst/videocrop/Makefile
1114 gst/videofilter/Makefile
1115 gst/videomixer/Makefile
1116 gst/wavenc/Makefile
1117 gst/wavparse/Makefile
1118 gst/flx/Makefile
1119 gst/y4m/Makefile
1120 ext/jpeg/Makefile
1121 ext/Makefile
1122 ext/aalib/Makefile
1123 ext/annodex/Makefile
1124 ext/cairo/Makefile
1125 ext/dv/Makefile
1126 ext/esd/Makefile
1127 ext/flac/Makefile
1128 ext/gconf/Makefile
1129 ext/gdk_pixbuf/Makefile
1130 ext/hal/Makefile
1131 ext/libcaca/Makefile
1132 ext/libpng/Makefile
1133 ext/pulse/Makefile
1134 ext/raw1394/Makefile
1135 ext/shout2/Makefile
1136 ext/soup/Makefile
1137 ext/speex/Makefile
1138 ext/taglib/Makefile
1139 ext/wavpack/Makefile
1140 sys/Makefile
1141 sys/directsound/Makefile
1142 sys/oss/Makefile
1143 sys/oss4/Makefile
1144 sys/osxaudio/Makefile
1145 sys/osxvideo/Makefile
1146 sys/sunaudio/Makefile
1147 sys/v4l2/Makefile
1148 sys/waveform/Makefile
1149 sys/ximage/Makefile
1150 po/Makefile.in
1151 tests/Makefile
1152 tests/check/Makefile
1153 tests/examples/Makefile
1154 tests/examples/audiofx/Makefile
1155 tests/examples/equalizer/Makefile
1156 tests/examples/level/Makefile
1157 tests/examples/rtp/Makefile
1158 tests/examples/shapewipe/Makefile
1159 tests/examples/spectrum/Makefile
1160 tests/examples/v4l2/Makefile
1161 tests/files/Makefile
1162 tests/icles/Makefile
1163 gconf/Makefile
1164 gconf/gstreamer.schemas
1165 common/Makefile
1166 common/m4/Makefile
1167 m4/Makefile
1168 docs/Makefile
1169 docs/plugins/Makefile
1170 docs/version.entities
1171 pkgconfig/Makefile
1172 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1173 gst-plugins-good.spec
1174 )
1175
1176 dnl Create the config.h file for Visual Studio builds
1177 dnl Beware of spaces and /'s in some of the shell variable contents.
1178 sed \
1179     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1180     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1181     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1182     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1183     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1184     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1185     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1186     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1187     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1188     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1189     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1190     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1191     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1192     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1193     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1194     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1195     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1196     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1197     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1198     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1199     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1200     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1201     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1202     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1203     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1204     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1205     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1206     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1207     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
1208     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1209     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1210     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directaudiosink\"/" \
1211     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1212     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1213     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1214     config.h.in >win32/common/config.h-new
1215
1216 AC_OUTPUT
1217
1218 AG_GST_OUTPUT_PLUGINS