configure.ac

   1 AC_PREREQ([2.68])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT([GStreamer Good Plug-ins],[1.4.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-good])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 AG_GST_LIBTOOL_PREPARE
  46 AS_LIBTOOL(GST, 401, 0, 401)
  47
  48 dnl *** required versions of GStreamer stuff ***
  49 GST_REQ=1.4.0
  50 GSTPB_REQ=1.4.0
  51
  52 dnl *** autotools stuff ****
  53
  54 dnl allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 dnl Add parameters for aclocal
  58 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  59
  60 dnl set up gettext
  61 dnl the version check needs to stay here because autopoint greps for it
  62 AM_GNU_GETTEXT_VERSION([0.17])
  63 AM_GNU_GETTEXT([external])
  64 AG_GST_GETTEXT([gst-plugins-good-$GST_API_VERSION])
  65
  66 dnl *** check for arguments to configure ***
  67
  68 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  69
  70 AG_GST_ARG_DEBUG
  71 AG_GST_ARG_PROFILING
  72 AG_GST_ARG_VALGRIND
  73 AG_GST_ARG_GCOV
  74
  75 AG_GST_ARG_EXAMPLES
  76
  77 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  78 AG_GST_ARG_WITH_PACKAGE_NAME
  79 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  80
  81 AG_GST_ARG_WITH_PLUGINS
  82
  83 AG_GST_ARG_ENABLE_EXTERNAL
  84
  85 AG_GST_ARG_ENABLE_EXPERIMENTAL
  86
  87 dnl *** checks for platform ***
  88
  89 dnl * hardware/architecture *
  90
  91 dnl common/m4/gst-arch.m4
  92 dnl check CPU type
  93 AG_GST_ARCH
  94
  95 dnl Determine endianness
  96 AC_C_BIGENDIAN
  97
  98 dnl *** checks for programs ***
  99
 100 dnl find a compiler
 101 AC_PROG_CC
 102 AC_PROG_CC_STDC
 103
 104 dnl determine c++ compiler
 105 AC_PROG_CXX
 106 dnl determine if c++ is available on this system
 107 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 108
 109 dnl determine c++ preprocessor
 110 dnl FIXME: do we need this ?
 111 AC_PROG_CXXCPP
 112
 113 AC_PROG_OBJC
 114
 115 dnl check if the compiler supports '-c' and '-o' options
 116 AM_PROG_CC_C_O
 117
 118 dnl find an assembler
 119 AM_PROG_AS
 120
 121 dnl check if the compiler supports do while(0) macros
 122 AG_GST_CHECK_DOWHILE_MACROS
 123
 124 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 125 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 126
 127 dnl check for documentation tools
 128 GTK_DOC_CHECK([1.12])
 129 AG_GST_PLUGIN_DOCS([1.12])
 130
 131 dnl *** checks for libraries ***
 132
 133 dnl check for libm, for sin()
 134 LT_LIB_M
 135 AC_SUBST(LIBM)
 136
 137 AC_CHECK_FUNCS(clock_gettime, [], [
 138   AC_CHECK_LIB(rt, clock_gettime, [
 139     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 140     LIBRT="-lrt"
 141     AC_SUBST([LIBRT])
 142   ])
 143 ])
 144
 145 dnl *** checks for header files ***
 146
 147 dnl check if we have ANSI C header files
 148 AC_HEADER_STDC
 149
 150 dnl used by ext/wavpack
 151 AX_CREATE_STDINT_H
 152
 153 dnl used in gst/udp
 154 AC_CHECK_HEADERS([sys/time.h])
 155
 156 dnl used in gst/udp
 157 AC_CHECK_HEADERS([sys/socket.h])
 158
 159 dnl *** checks for types/defines ***
 160
 161 dnl Check for FIONREAD ioctl declaration.  This check is needed
 162 dnl for the UDP plugin to build on Solaris
 163 GST_CHECK_FIONREAD
 164
 165 dnl *** checks for structures ***
 166
 167 dnl *** checks for compiler characteristics ***
 168
 169 dnl check if we have GCC inline-asm
 170 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 171 if test x$HAVE_GCC_ASM = xyes ; then
 172   AC_DEFINE(HAVE_GCC_ASM, 1,
 173     [Define if compiler supports gcc inline assembly])
 174 fi
 175 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 176
 177 dnl *** checks for library functions ***
 178
 179 LIBS_SAVE=$LIBS
 180 LIBS="$LIBS $LIBM"
 181 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 182 LIBS=$LIBS_SAVE
 183
 184 dnl Check whether isinf() is defined by math.h
 185 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 186     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 187 if test "$ac_cv_have_isinf" = "yes"
 188 then
 189     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 190 fi
 191
 192 dnl Check for mmap (needed by electricfence plugin)
 193 AC_FUNC_MMAP
 194 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 195
 196 dnl Check for mmap (needed by electricfence plugin)
 197
 198 AC_CHECK_TYPE([struct ip_mreqn], [
 199               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 200               [#include <netinet/in.h>])
 201
 202 dnl *** checks for dependency libraries ***
 203
 204
 205 dnl GLib
 206 GLIB_REQ=2.32.0
 207 AG_GST_GLIB_CHECK([$GLIB_REQ])
 208
 209 dnl Orc
 210 ORC_CHECK([0.4.17])
 211
 212 dnl checks for gstreamer
 213 dnl uninstalled is selected preferentially -- see pkg-config(1)
 214 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 215 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 216 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 217 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 218 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 219 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 220
 221 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_API_VERSION`
 222 if test -z $GST_TOOLS_DIR; then
 223   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 224 fi
 225 AC_SUBST(GST_TOOLS_DIR)
 226
 227 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 228 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 229
 230 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 231
 232 dnl Check for documentation xrefs
 233 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 234 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 235 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 236 AC_SUBST(GLIB_PREFIX)
 237 AC_SUBST(GST_PREFIX)
 238 AC_SUBST(GSTPB_PREFIX)
 239
 240 dnl GTK is optional and used in examples
 241 HAVE_GTK=no
 242 GTK_REQ=3.0.0
 243 if test "x$BUILD_EXAMPLES" = "xyes"; then
 244   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 245   dnl some examples need gtk+-x11
 246   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 247   AC_SUBST(GTK_LIBS)
 248   AC_SUBST(GTK_CFLAGS)
 249 fi
 250 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 251 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 252
 253 AC_ARG_ENABLE(pcmdump, AC_HELP_STRING([--enable-pcmdump], [pcm dump]),
 254   [
 255     case "${enableval}" in
 256       yes) PCM_DUMP_ENABLE=yes ;;
 257       no)  PCM_DUMP_ENABLE=no ;;
 258       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-pcmdump) ;;
 259     esac
 260   ],
 261   [PCM_DUMP_ENABLE=no])
 262 AM_CONDITIONAL([PCM_DUMP_ENABLE], [test "x$PCM_DUMP_ENABLE" = "xyes"])
 263
 264 if test "x$PCM_DUMP_ENABLE" = "xyes"; then
 265 PKG_CHECK_MODULES(VCONF, vconf)
 266 AC_SUBST(VCONF_CFLAGS)
 267 AC_SUBST(VCONF_LIBS)
 268 fi
 269
 270 dnl *** set variables based on configure arguments ***
 271
 272 dnl set license and copyright notice
 273 GST_LICENSE="LGPL"
 274 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 275 AC_SUBST(GST_LICENSE)
 276
 277 dnl set location of plugin directory
 278 AG_GST_SET_PLUGINDIR
 279
 280 dnl set release date/time
 281 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 282   ["${srcdir}/gst-plugins-good.doap"],
 283   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 284
 285 dnl build static plugins or not
 286 AC_MSG_CHECKING([whether to build static plugins or not])
 287 AC_ARG_ENABLE(
 288   static-plugins,
 289   AC_HELP_STRING(
 290     [--enable-static-plugins],
 291     [build static plugins @<:@default=no@:>@]),
 292   [AS_CASE(
 293     [$enableval], [no], [], [yes], [],
 294     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 295   [enable_static_plugins=no])
 296 AC_MSG_RESULT([$enable_static_plugins])
 297 if test "x$enable_static_plugins" = xyes; then
 298   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 299     [Define if static plugins should be built])
 300   GST_PLUGIN_LIBTOOLFLAGS=""
 301 else
 302   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 303 fi
 304 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 305 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 306
 307 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 308 dnl make sure it doesn't complain about unused variables if debugging is disabled
 309 NO_WARNINGS=""
 310 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 311
 312 dnl define an ERROR_CFLAGS Makefile variable
 313 dnl -Wundef: too many broken headers
 314 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 315       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 316       -Wwrite-strings -Wold-style-definition -Waggregate-return
 317       -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 318       -Wnested-externs $NO_WARNINGS])
 319
 320 dnl define an ERROR_CXXFLAGS Makefile variable
 321 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 322         -Wmissing-declarations -Wredundant-decls
 323         -Wwrite-strings
 324         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 325         $NO_WARNINGS])
 326
 327 dnl define an ERROR_OBJCFLAGS Makefile variable
 328 AG_GST_SET_ERROR_OBJCFLAGS($FATAL_WARNINGS, [
 329       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 330       -Wwrite-strings -Wold-style-definition
 331       -Winit-self -Wmissing-include-dirs -Wno-multichar
 332       -Wnested-externs $NO_WARNINGS])
 333
 334 dnl define correct level for debugging messages
 335 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 336
 337 dnl used in examples
 338 AG_GST_DEFAULT_ELEMENTS
 339
 340 dnl *** plug-ins to include ***
 341
 342 dnl these are all the gst plug-ins, compilable without additional libs
 343 dnl videofilter is at the top because others depend on it
 344 AG_GST_CHECK_PLUGIN(alpha)
 345 AG_GST_CHECK_PLUGIN(apetag)
 346 AG_GST_CHECK_PLUGIN(audiofx)
 347 AG_GST_CHECK_PLUGIN(audioparsers)
 348 AG_GST_CHECK_PLUGIN(auparse)
 349 AG_GST_CHECK_PLUGIN(autodetect)
 350 AG_GST_CHECK_PLUGIN(avi)
 351 AG_GST_CHECK_PLUGIN(cutter)
 352 AG_GST_CHECK_PLUGIN(debugutils)
 353 AG_GST_CHECK_PLUGIN(deinterlace)
 354 AG_GST_CHECK_PLUGIN(dtmf)
 355 AG_GST_CHECK_PLUGIN(effectv)
 356 AG_GST_CHECK_PLUGIN(equalizer)
 357 AG_GST_CHECK_PLUGIN(flv)
 358 AG_GST_CHECK_PLUGIN(flx)
 359 AG_GST_CHECK_PLUGIN(goom)
 360 AG_GST_CHECK_PLUGIN(goom2k1)
 361 AG_GST_CHECK_PLUGIN(icydemux)
 362 AG_GST_CHECK_PLUGIN(id3demux)
 363 AG_GST_CHECK_PLUGIN(imagefreeze)
 364 AG_GST_CHECK_PLUGIN(interleave)
 365 AG_GST_CHECK_PLUGIN(isomp4)
 366 AG_GST_CHECK_PLUGIN(law)
 367 AG_GST_CHECK_PLUGIN(level)
 368 AG_GST_CHECK_PLUGIN(matroska)
 369 AG_GST_CHECK_PLUGIN(monoscope)
 370 AG_GST_CHECK_PLUGIN(multifile)
 371 AG_GST_CHECK_PLUGIN(multipart)
 372 AG_GST_CHECK_PLUGIN(replaygain)
 373 AG_GST_CHECK_PLUGIN(rtp)
 374 AG_GST_CHECK_PLUGIN(rtpmanager)
 375 AG_GST_CHECK_PLUGIN(rtsp)
 376 AG_GST_CHECK_PLUGIN(shapewipe)
 377 AG_GST_CHECK_PLUGIN(smpte)
 378 AG_GST_CHECK_PLUGIN(spectrum)
 379 AG_GST_CHECK_PLUGIN(udp)
 380 AG_GST_CHECK_PLUGIN(videobox)
 381 AG_GST_CHECK_PLUGIN(videocrop)
 382 AG_GST_CHECK_PLUGIN(videofilter)
 383 AG_GST_CHECK_PLUGIN(videomixer)
 384 AG_GST_CHECK_PLUGIN(wavenc)
 385 AG_GST_CHECK_PLUGIN(wavparse)
 386 AG_GST_CHECK_PLUGIN(y4m)
 387
 388 dnl disable experimental plug-ins
 389 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 390   AG_GST_DISABLE_PLUGIN(monoscope)
 391 fi
 392
 393 dnl *** sys plug-ins ***
 394
 395 echo
 396 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 397 echo
 398
 399 dnl DirectSound
 400 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 401 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 402   HAVE_DIRECTSOUND="no"
 403   save_CFLAGS="$CFLAGS"
 404   save_LDFLAGS="$LDFLAGS"
 405   save_LIBS="$LIBS"
 406   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 407   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 408   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 409   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 410   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 411 #include <windows.h>
 412 #include <dxerr9.h>
 413 #include <dsound.h>
 414 ]], [[
 415   DXGetErrorString9 (0);
 416   DirectSoundCreate(NULL, NULL, NULL);
 417 ]])
 418 ],
 419     [HAVE_DIRECTSOUND="yes"],
 420     [HAVE_DIRECTSOUND="no"])
 421   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 422   CFLAGS=$save_CFLAGS
 423   LDFLAGS=$save_LDFLAGS
 424   LIBS=$save_LIBS
 425
 426   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 427     dnl this is much more than we want
 428     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 429     AC_SUBST(DIRECTSOUND_CFLAGS)
 430     AC_SUBST(DIRECTSOUND_LDFLAGS)
 431     AC_SUBST(DIRECTSOUND_LIBS)
 432   fi
 433   AC_SUBST(HAVE_DIRECTSOUND)
 434 ])
 435
 436 dnl *** Win32 WaveOut ***
 437 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVEFORM, true)
 438 AG_GST_CHECK_FEATURE(WAVEFORM, [Win32 WaveForm], waveformsink, [
 439   AC_CHECK_HEADER(mmsystem.h, HAVE_WAVEFORM="yes", HAVE_WAVEFORM="no", [#include <windows.h>])
 440 ])
 441
 442 dnl *** OSS audio *** (Linux, *BSD)
 443 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 444 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 445  HAVE_OSS="yes"
 446 dnl Linux and newer BSD versions :
 447  AC_CHECK_HEADER(sys/soundcard.h, [
 448    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 449    ] , [
 450 dnl Some old BSD versions and also newer OpenBSD versions :
 451    AC_CHECK_HEADER(soundcard.h, [
 452      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 453      ], [
 454   dnl Some old BSD versions :
 455      AC_CHECK_HEADER(machine/soundcard.h, [
 456        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 457          [Define if OSS includes are in /machine/])
 458        ], [
 459        HAVE_OSS="no"
 460      ])
 461    ])
 462  ])
 463 ])
 464
 465 dnl *** oss4 ***
 466 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 467 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 468   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 469   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 470       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 471       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 472 ])
 473
 474 dnl *** Sun Audio ***
 475 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 476 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 477   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 478 ])
 479
 480 dnl *** OSX Audio ***
 481 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 482 HAVE_IOS="no"
 483 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 484   AC_CHECK_HEADER(CoreAudio/CoreAudio.h,
 485     [HAVE_OSX_AUDIO="yes"],
 486     [AC_CHECK_HEADER(CoreAudio/CoreAudioTypes.h,
 487     [
 488       HAVE_OSX_AUDIO="yes"
 489       HAVE_IOS="yes"
 490     ], [
 491       HAVE_OSX_AUDIO="no"
 492       HAVE_IOS="no"
 493     ])]
 494   )
 495 ])
 496 if test "x$HAVE_IOS" = "xyes"; then
 497   AC_DEFINE(HAVE_IOS, 1, [building for iOS platofrm])
 498 fi
 499 AM_CONDITIONAL(HAVE_IOS, test "x$HAVE_IOS" = "xyes")
 500
 501 dnl *** OS X video ***
 502 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 503 HAVE_OSX_VIDEO="no"
 504 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 505   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 506
 507   dnl in case header OpenGL/gl.h is found on other platforms (or older, unsupported OS X)
 508   dnl also require Snow Leopard or newer
 509
 510   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 511         #include <AvailabilityMacros.h>
 512         #if MAC_OS_X_VERSION_MIN_REQUIRED < 1060
 513         #error Too old OSX version
 514         #endif
 515       ]], [[return 0;]])],[HAVE_OSX_VIDEO="yes"],[HAVE_OSX_VIDEO="no"])
 516 ])
 517
 518 dnl *** Video 4 Linux 2 ***
 519 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 520 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 521 HAVE_GST_V4L2=no
 522 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], video4linux2, [
 523   AC_MSG_CHECKING([Checking for video4linux2 header ...])
 524   AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_GST_V4L2=yes ],
 525   [
 526     AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_GST_V4L2=yes ])
 527   ])
 528   if test "x$HAVE_VIDEODEV" = "xno"; then
 529      AC_MSG_WARN([video4linux2 was not found])
 530   fi
 531 ])
 532
 533 # Optional gudev for device probing
 534 AC_ARG_WITH([gudev],
 535   AS_HELP_STRING([--with-gudev],[device detection with gudev]),
 536   [],
 537   [with_gudev=check])
 538 if test x$HAVE_GST_V4L2 = xyes; then
 539   if test x$with_gudev != xno; then
 540     PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 147 ],
 541       [ AC_DEFINE(HAVE_GUDEV, 1,
 542           [Whether gudev is available for device detection])
 543       ],
 544       [true])
 545   fi
 546 fi
 547
 548 AC_SUBST(GUDEV_CFLAGS)
 549 AC_SUBST(GUDEV_LIBS)
 550
 551 # Make libv4l2 non-automagic
 552 AC_ARG_WITH([libv4l2],
 553   AS_HELP_STRING([--with-libv4l2],[support video buffer conversion using libv4l2]),
 554   [],
 555   [with_libv4l2=check])
 556 if test x$HAVE_GST_V4L2 = xyes; then
 557   if test x$with_libv4l2 != xno; then
 558       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 559           [ have_libv4l2=yes
 560             AC_DEFINE(HAVE_LIBV4L2, 1,
 561                 [Whether libv4l2 is available for video buffer conversion])
 562           ], [
 563           have_libv4l2=no
 564           ])
 565   else
 566     have_libv4l2=no
 567   fi
 568 fi
 569
 570 dnl Check for X11
 571 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 572 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 573                   [ximagesrc], [
 574   AG_GST_CHECK_X
 575
 576   if test "x$HAVE_X" = "xyes"
 577   then
 578     dnl check for Xfixes
 579     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 580     if test "x$HAVE_XFIXES" = "xyes"
 581     then
 582         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 583     fi
 584     AC_SUBST(XFIXES_LIBS)
 585     AC_SUBST(XFIXES_CFLAGS)
 586
 587     dnl check for Xdamage
 588     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 589     if test "x$HAVE_XDAMAGE" = "xyes"
 590     then
 591         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 592     fi
 593     AC_SUBST(XDAMAGE_LIBS)
 594     AC_SUBST(XDAMAGE_CFLAGS)
 595   fi
 596 ])
 597
 598 dnl FIXME: this should be rolled into the test above, it's just an additional
 599 dnl feature of the ximagesrc plug-in
 600 dnl This is the same as in gst-plugins-base
 601 dnl check for X Shm
 602 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 603 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 604   if test x$HAVE_X = xyes; then
 605     AC_CHECK_LIB(Xext, XShmAttach,
 606                  HAVE_XSHM="yes", HAVE_XSHM="no",
 607                  $X_LIBS)
 608     if test "x$HAVE_XSHM" = "xyes"; then
 609       XSHM_LIBS="-lXext"
 610     else
 611       dnl On AIX, it is in XextSam instead, but we still need -lXext
 612       AC_CHECK_LIB(XextSam, XShmAttach,
 613                    HAVE_XSHM="yes", HAVE_XSHM="no",
 614                    $X_LIBS)
 615       if test "x$HAVE_XSHM" = "xyes"; then
 616         XSHM_LIBS="-lXext -lXextSam"
 617       fi
 618     fi
 619   fi
 620 ], ,[
 621   AC_SUBST(HAVE_XSHM)
 622   AC_SUBST(XSHM_LIBS)
 623 ])
 624
 625 dnl *** ext plug-ins ***
 626 dnl keep this list sorted alphabetically !
 627
 628 if test "x$BUILD_EXTERNAL" = "xyes"; then
 629
 630 echo
 631 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 632 echo
 633
 634 dnl *** aalib ***
 635 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 636 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 637   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 638 ])
 639
 640 dnl *** cairo ***
 641 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 642 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering and gobject bindings], cairo, [
 643   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.10.0 cairo-gobject >= 1.10.0)
 644 ])
 645
 646 dnl *** FLAC ***
 647 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 648 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 649   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 650 ])
 651
 652 dnl *** GDK pixbuf ***
 653 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 654 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 655   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 656 ])
 657
 658 dnl *** Jack ***
 659 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 660 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 661   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 662   AC_SUBST(JACK_CFLAGS)
 663   AC_SUBST(JACK_LIBS)
 664
 665   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 666   if test x$HAVE_JACK_0_120_1 = xyes; then
 667     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 668   fi
 669   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 670   if test x$HAVE_JACK_1_9_7 = xyes; then
 671     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 672   fi
 673
 674 ])
 675
 676 dnl *** jpeg ***
 677 dnl FIXME: we could use header checks here as well IMO
 678 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 679 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 680   AC_ARG_WITH(jpeg-mmx,
 681     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 682   OLD_LIBS="$LIBS"
 683   if test x$with_jpeg_mmx != x; then
 684     LIBS="$LIBS -L$with_jpeg_mmx"
 685   fi
 686   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 687   JPEG_LIBS="$LIBS -ljpeg-mmx"
 688   LIBS="$OLD_LIBS"
 689   if test x$HAVE_JPEG != xyes; then
 690     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 691     JPEG_LIBS="-ljpeg"
 692   fi
 693   AC_SUBST(JPEG_LIBS)
 694 ])
 695
 696 dnl *** libcaca ***
 697 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 698 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 699   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 700 ])
 701
 702 dnl *** libdv ***
 703 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 704 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 705   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 706 ])
 707
 708 dnl *** libpng ***
 709 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 710 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 711   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 712 ])
 713
 714 dnl *** pulseaudio ***
 715 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 716 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 717
 718   dnl used in ext/pulse/pulseutil.c
 719   AC_CHECK_HEADERS([process.h])
 720
 721   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 2.0)
 722 ])
 723
 724 dnl *** dv1394 ***
 725 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 726 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 727   dnl first test for libraw1394 >= 2.0.0
 728   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 729   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 730   dnl now see how far we got
 731   if test x$HAVE_RAW1394 = xyes && \
 732      test x$HAVE_LIBIEC61883 = xyes; then
 733        AG_GST_CHECK_LIBHEADER(AVC1394,
 734         avc1394, avc1394_send_command, $RAW1394_LIBS,
 735         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 736        AG_GST_CHECK_LIBHEADER(ROM1394,
 737         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 738         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 739        if test x$HAVE_AVC1394 = xyes && \
 740           test x$HAVE_AVC1394 = xyes && \
 741           test x$HAVE_ROM1394 = xyes; then
 742           HAVE_DV1394=yes
 743           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 744           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 745           AC_SUBST(DV1394_CFLAGS)
 746           AC_SUBST(DV1394_LIBS)
 747         fi
 748   else
 749        if test x$HAVE_RAW1394 = xno; then
 750           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 751           AG_GST_CHECK_LIBHEADER(AVC1394,
 752            avc1394, avc1394_send_command, $RAW1394_LIBS,
 753            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 754           AG_GST_CHECK_LIBHEADER(ROM1394,
 755            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 756            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 757           if test x$HAVE_RAW1394 = xyes && \
 758              test x$HAVE_AVC1394 = xyes && \
 759              test x$HAVE_ROM1394 = xyes; then
 760              HAVE_DV1394=yes
 761              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 762              DV1394_CFLAGS="$RAW1394_CFLAGS"
 763              if test x$HAVE_LIBIEC61883 = xyes; then
 764                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 765                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 766              fi
 767              AC_SUBST(DV1394_CFLAGS)
 768              AC_SUBST(DV1394_LIBS)
 769            fi
 770          fi
 771   fi
 772 ])
 773 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 774
 775 dnl *** shout2 ***
 776 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 777 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 778   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 779 ])
 780
 781 dnl *** soup ***
 782 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 783 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 784   PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.40, [HAVE_SOUP="yes"], [HAVE_SOUP="no"])
 785   AC_SUBST(SOUP_CFLAGS)
 786   AC_SUBST(SOUP_LIBS)
 787 ])
 788
 789 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 790 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 791 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 792 dnl   speex_jitter.h is 1.1.x only
 793 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 794 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 795   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 796   if test $HAVE_SPEEX = no
 797   then
 798     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 799       AC_CHECK_HEADER(speex/speex_jitter.h, [
 800         dnl speex 1.1.x :
 801         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 802           dnl speex 1.1.5 or + :
 803           HAVE_SPEEX="yes"
 804           SPEEX_LIBS="-lspeex"
 805           AC_SUBST(SPEEX_CFLAGS)
 806           AC_SUBST(SPEEX_LIBS)
 807         ],[
 808           HAVE_SPEEX="no"
 809         ])
 810       ],[
 811         dnl speex 1.0.x :
 812           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 813             dnl speex 1.0.4
 814             HAVE_SPEEX="yes"
 815             SPEEX_LIBS="-lspeex"
 816             AC_SUBST(SPEEX_CFLAGS)
 817             AC_SUBST(SPEEX_LIBS)
 818
 819             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 820               [defined if speex 1.0.x API detected])
 821         ],[
 822             HAVE_SPEEX="no"
 823             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 824         ], [
 825 #include <speex/speex.h>
 826         ])
 827       ])
 828     ])
 829   fi
 830 ])
 831
 832 dnl *** taglib ***
 833 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 834 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 835   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 836   if test "x$HAVE_CXX" != "xyes"; then
 837     USE_TAGLIB=false
 838     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 839   else
 840     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 841     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 842         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 843       ], [
 844         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 845     ])
 846     AC_SUBST(TAGLIB_CXXFLAGS)
 847   fi
 848 ])
 849
 850 dnl *** vpx ***
 851 translit(dnm, m, l) AM_CONDITIONAL(USE_VPX, vpx)
 852 AG_GST_CHECK_FEATURE(VPX, [VPX decoder], vpx, [
 853   PKG_CHECK_MODULES(VPX, vpx >= 1.1.0, [HAVE_VPX="yes"], [HAVE_VPX="no"])
 854   HAVE_VP8=no
 855   HAVE_VP9=no
 856
 857   if test $HAVE_VPX = "yes"; then
 858     OLD_LIBS="$LIBS"
 859     OLD_CFLAGS="$CFLAGS"
 860     CFLAGS="$CFLAGS $VPX_CFLAGS"
 861     LIBS="$LIBS $VPX_LIBS"
 862     AC_CHECK_LIB(vpx, vpx_codec_vp8_cx_algo, [
 863       HAVE_VP8=yes
 864       AC_DEFINE(HAVE_VP8_ENCODER, 1, [Defined if the VP8 encoder is available])
 865     ])
 866     AC_CHECK_LIB(vpx, vpx_codec_vp8_dx_algo, [
 867       HAVE_VP8=yes
 868       AC_DEFINE(HAVE_VP8_DECODER, 1, [Defined if the VP8 decoder is available])
 869     ])
 870
 871     PKG_CHECK_MODULES(VPX_130, vpx >= 1.3.0, [
 872       AC_CHECK_LIB(vpx, vpx_codec_vp9_cx_algo, [
 873         HAVE_VP9=yes
 874         AC_DEFINE(HAVE_VP9_ENCODER, 1, [Defined if the VP9 encoder is available])
 875       ])
 876       AC_CHECK_LIB(vpx, vpx_codec_vp9_dx_algo, [
 877         HAVE_VP9=yes
 878         AC_DEFINE(HAVE_VP9_DECODER, 1, [Defined if the VP9 decoder is available])
 879       ])
 880     ], [true])
 881     LIBS="$OLD_LIBS"
 882     CFLAGS="$OLD_CFLAGS"
 883   fi
 884   AC_SUBST(VPX_LIBS)
 885   AC_SUBST(VPX_CFLAGS)
 886 ])
 887
 888 dnl *** wavpack ***
 889 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 890 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 891   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 892     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 893       HAVE_WAVPACK=yes
 894       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 895     ],[
 896       HAVE_WAVPACK=no
 897     ])
 898   ])
 899   AC_SUBST(WAVPACK_CFLAGS)
 900   AC_SUBST(WAVPACK_LIBS)
 901 ])
 902
 903 dnl *** qtdemux & matroska prefer to have zlib ***
 904 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 905 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
 906   AG_GST_CHECK_LIBHEADER(ZLIB,
 907     z, uncompress,, zlib.h, [
 908     HAVE_ZLIB="yes"
 909     ZLIB_LIBS="-lz"
 910     AC_SUBST(ZLIB_LIBS)
 911   ])
 912 ])
 913
 914 dnl *** matroska prefers to have bz2 ***
 915 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 916 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 917   save_LIBS=$LIBS
 918   LIBS="$LIBS -lbz2"
 919   AC_MSG_CHECKING([for BZ2_bzlibVersion in -lbz2])
 920   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <bzlib.h>]], [[const char *version = BZ2_bzlibVersion ();]])],[HAVE_BZ2=yes],[HAVE_BZ2=no])
 921   AC_MSG_RESULT($HAVE_BZ2)
 922   LIBS=$save_LIBS
 923   if test "x$HAVE_BZ2" = "xyes"; then
 924     BZ2_LIBS="-lbz2"
 925   fi
 926   AC_SUBST(BZ2_LIBS)
 927 ])
 928
 929 else
 930
 931 dnl not building plugins with external dependencies,
 932 dnl but we still need to set the conditionals
 933 AM_CONDITIONAL(USE_AALIB, false)
 934 AM_CONDITIONAL(USE_BZ2, false)
 935 AM_CONDITIONAL(USE_CAIRO, false)
 936 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 937 AM_CONDITIONAL(USE_DV1394, false)
 938 AM_CONDITIONAL(USE_FLAC, false)
 939 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 940 AM_CONDITIONAL(USE_JACK, false)
 941 AM_CONDITIONAL(USE_JPEG, false)
 942 AM_CONDITIONAL(USE_LIBCACA, false)
 943 AM_CONDITIONAL(USE_LIBDV, false)
 944 AM_CONDITIONAL(USE_LIBIEC61883, false)
 945 AM_CONDITIONAL(USE_LIBPNG, false)
 946 AM_CONDITIONAL(USE_OSS, false)
 947 AM_CONDITIONAL(USE_OSS4, false)
 948 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 949 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 950 AM_CONDITIONAL(USE_PULSE, false)
 951 AM_CONDITIONAL(USE_SHOUT2, false)
 952 AM_CONDITIONAL(USE_SOUP, false)
 953 AM_CONDITIONAL(USE_SPEEX, false)
 954 AM_CONDITIONAL(USE_SUNAUDIO, false)
 955 AM_CONDITIONAL(USE_TAGLIB, false)
 956 AM_CONDITIONAL(USE_VPX, false)
 957 AM_CONDITIONAL(USE_WAVEFORM, false)
 958 AM_CONDITIONAL(USE_WAVPACK, false)
 959 AM_CONDITIONAL(USE_X, false)
 960 AM_CONDITIONAL(USE_XSHM, false)
 961 AM_CONDITIONAL(USE_ZLIB, false)
 962
 963 fi dnl of EXT plugins
 964
 965 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 966
 967 dnl Overview:
 968 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 969 dnl GST_*:              flags shared by all built objects
 970 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 971 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
 972 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 973 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 974
 975 dnl GST_OPTION_CFLAGS
 976 if test "x$USE_DEBUG" = xyes; then
 977    PROFILE_CFLAGS="-g"
 978 fi
 979 AC_SUBST(PROFILE_CFLAGS)
 980
 981 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 982   dnl Define _only_ for git (not pre-releases or releases)
 983   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 984 else
 985   DEPRECATED_CFLAGS=""
 986 fi
 987 AC_SUBST(DEPRECATED_CFLAGS)
 988
 989 dnl every flag in GST_OPTION_CFLAGS, GST_OPTION_CXXFLAGS and GST_OPTION_OBJCFLAGS can be overridden
 990 dnl at make time with e.g. make ERROR_CFLAGS=""
 991 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 992 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 993 GST_OPTION_OBJCFLAGS="\$(WARNING_OBJCFLAGS) \$(ERROR_OBJCFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 994 AC_SUBST(GST_OPTION_CFLAGS)
 995 AC_SUBST(GST_OPTION_CXXFLAGS)
 996 AC_SUBST(GST_OPTION_OBJCFLAGS)
 997
 998 dnl our libraries need to be versioned correctly
 999 AC_SUBST(GST_LT_LDFLAGS)
1000
1001 dnl FIXME: do we want to rename to GST_ALL_* ?
1002 dnl prefer internal headers to already installed ones
1003 dnl also add builddir include for enumtypes and marshal
1004 dnl add ERROR_CFLAGS, but overridable
1005 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
1006 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1007 GST_OBJCFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_OBJCFLAGS)"
1008 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
1009 AC_SUBST(GST_CFLAGS)
1010 AC_SUBST(GST_CXXFLAGS)
1011 AC_SUBST(GST_OBJCFLAGS)
1012 AC_SUBST(GST_LIBS)
1013
1014 dnl LDFLAGS really should only contain flags, not libs - they get added before
1015 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1016 GST_ALL_LDFLAGS="-no-undefined"
1017 AC_SUBST(GST_ALL_LDFLAGS)
1018
1019 dnl this really should only contain flags, not libs - they get added before
1020 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1021 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
1022 AC_SUBST(GST_PLUGIN_LDFLAGS)
1023
1024 dnl *** output files ***
1025
1026 $MKDIR_P tests/check/orc
1027
1028 dnl keep this alphabetic per directory, please
1029 AC_CONFIG_FILES(
1030 Makefile
1031 gst/Makefile
1032 gst/alpha/Makefile
1033 gst/apetag/Makefile
1034 gst/audiofx/Makefile
1035 gst/audioparsers/Makefile
1036 gst/auparse/Makefile
1037 gst/autodetect/Makefile
1038 gst/avi/Makefile
1039 gst/cutter/Makefile
1040 gst/deinterlace/Makefile
1041 gst/dtmf/Makefile
1042 gst/debugutils/Makefile
1043 gst/effectv/Makefile
1044 gst/equalizer/Makefile
1045 gst/flv/Makefile
1046 gst/goom/Makefile
1047 gst/goom2k1/Makefile
1048 gst/id3demux/Makefile
1049 gst/icydemux/Makefile
1050 gst/imagefreeze/Makefile
1051 gst/interleave/Makefile
1052 gst/isomp4/Makefile
1053 gst/law/Makefile
1054 gst/level/Makefile
1055 gst/matroska/Makefile
1056 gst/monoscope/Makefile
1057 gst/multifile/Makefile
1058 gst/multipart/Makefile
1059 gst/replaygain/Makefile
1060 gst/rtp/Makefile
1061 gst/rtpmanager/Makefile
1062 gst/rtsp/Makefile
1063 gst/shapewipe/Makefile
1064 gst/smpte/Makefile
1065 gst/spectrum/Makefile
1066 gst/udp/Makefile
1067 gst/videobox/Makefile
1068 gst/videocrop/Makefile
1069 gst/videofilter/Makefile
1070 gst/videomixer/Makefile
1071 gst/wavenc/Makefile
1072 gst/wavparse/Makefile
1073 gst/flx/Makefile
1074 gst/y4m/Makefile
1075 ext/Makefile
1076 ext/aalib/Makefile
1077 ext/cairo/Makefile
1078 ext/dv/Makefile
1079 ext/flac/Makefile
1080 ext/gdk_pixbuf/Makefile
1081 ext/jack/Makefile
1082 ext/jpeg/Makefile
1083 ext/libcaca/Makefile
1084 ext/libpng/Makefile
1085 ext/pulse/Makefile
1086 ext/raw1394/Makefile
1087 ext/shout2/Makefile
1088 ext/soup/Makefile
1089 ext/speex/Makefile
1090 ext/taglib/Makefile
1091 ext/vpx/Makefile
1092 ext/wavpack/Makefile
1093 sys/Makefile
1094 sys/directsound/Makefile
1095 sys/oss/Makefile
1096 sys/oss4/Makefile
1097 sys/osxaudio/Makefile
1098 sys/osxvideo/Makefile
1099 sys/sunaudio/Makefile
1100 sys/v4l2/Makefile
1101 sys/waveform/Makefile
1102 sys/ximage/Makefile
1103 po/Makefile.in
1104 tests/Makefile
1105 tests/check/Makefile
1106 tests/examples/Makefile
1107 tests/examples/audiofx/Makefile
1108 tests/examples/cairo/Makefile
1109 tests/examples/equalizer/Makefile
1110 tests/examples/jack/Makefile
1111 tests/examples/level/Makefile
1112 tests/examples/pulse/Makefile
1113 tests/examples/rtp/Makefile
1114 tests/examples/shapewipe/Makefile
1115 tests/examples/spectrum/Makefile
1116 tests/examples/v4l2/Makefile
1117 tests/files/Makefile
1118 tests/icles/Makefile
1119 common/Makefile
1120 common/m4/Makefile
1121 m4/Makefile
1122 docs/Makefile
1123 docs/plugins/Makefile
1124 docs/version.entities
1125 pkgconfig/Makefile
1126 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1127 gst-plugins-good.spec
1128 )
1129
1130 dnl Create the config.h file for Visual Studio builds
1131 dnl Beware of spaces and /'s in some of the shell variable contents.
1132 sed \
1133     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1134     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1135     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1136     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1137     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1138     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
1139     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1140     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1141     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1142     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1143     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1144     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1145     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1146     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1147     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1148     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1149     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1150     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1151     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1152     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1153     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1154     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1155     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1156     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1157     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1158     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1159     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1160     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1161     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
1162     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1163     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1164     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1165     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1166     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1167     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1168     config.h.in >win32/common/config.h-new
1169
1170 AC_OUTPUT
1171
1172 AG_GST_OUTPUT_PLUGINS
1173 ORC_OUTPUT
1174