configure.ac

   1 # get rid of that stupid cache mechanism
   2 rm -f config.cache
   3
   4 AC_INIT([ecore], [0.9.9.063], [enlightenment-devel@lists.sourceforge.net])
   5 release="ver-pre-svn-05"
   6 AC_PREREQ([2.52])
   7 AC_CONFIG_SRCDIR([configure.ac])
   8 AC_CONFIG_MACRO_DIR([m4])
   9 AC_CANONICAL_BUILD
  10 AC_CANONICAL_HOST
  11 AC_ISC_POSIX
  12
  13 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  14 AM_CONFIG_HEADER([config.h])
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 AC_GNU_SOURCE
  18
  19 AC_LIBTOOL_WIN32_DLL
  20 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  21 AC_PROG_LIBTOOL
  22
  23 VMAJ=`echo $PACKAGE_VERSION | awk -F. '{printf("%s", $1);}'`
  24 VMIN=`echo $PACKAGE_VERSION | awk -F. '{printf("%s", $2);}'`
  25 VMIC=`echo $PACKAGE_VERSION | awk -F. '{printf("%s", $3);}'`
  26 SNAP=`echo $PACKAGE_VERSION | awk -F. '{printf("%s", $4);}'`
  27 version_info=`expr $VMAJ + $VMIN`":$VMIC:$VMIN"
  28 AC_SUBST(version_info)
  29
  30 AM_GNU_GETTEXT_VERSION([0.12.1])
  31 AM_GNU_GETTEXT([external])
  32
  33 EFL_CHECK_PATH_MAX
  34
  35 case "$host_os" in
  36    mingw32ce* | cegcc*)
  37       ;;
  38    *)
  39       ecore_config_release_info="-release $release"
  40       ecore_con_release_info="-release $release"
  41       ecore_directfb_release_info="-release $release"
  42       ecore_evas_release_info="-release $release"
  43       ecore_fb_release_info="-release $release"
  44       ecore_file_release_info="-release $release"
  45       ecore_imf_evas_release_info="-release $release"
  46       ecore_imf_release_info="-release $release"
  47       ecore_input_release_info="-release $release"
  48       ecore_input_evas_release_info="-release $release"
  49       ecore_ipc_release_info="-release $release"
  50       ecore_quartz_release_info="-release $release"
  51       ecore_release_info="-release $release"
  52       ecore_sdl_release_info="-release $release"
  53       ecore_txt_release_info="-release $release"
  54       ecore_win32_release_info="-release $release"
  55       ecore_x_release_info="-release $release"
  56       ;;
  57 esac
  58 AC_SUBST(ecore_config_release_info)
  59 AC_SUBST(ecore_con_release_info)
  60 AC_SUBST(ecore_directfb_release_info)
  61 AC_SUBST(ecore_evas_release_info)
  62 AC_SUBST(ecore_fb_release_info)
  63 AC_SUBST(ecore_file_release_info)
  64 AC_SUBST(ecore_imf_evas_release_info)
  65 AC_SUBST(ecore_imf_release_info)
  66 AC_SUBST(ecore_input_release_info)
  67 AC_SUBST(ecore_input_evas_release_info)
  68 AC_SUBST(ecore_ipc_release_info)
  69 AC_SUBST(ecore_quartz_release_info)
  70 AC_SUBST(ecore_release_info)
  71 AC_SUBST(ecore_sdl_release_info)
  72 AC_SUBST(ecore_txt_release_info)
  73 AC_SUBST(ecore_win32_release_info)
  74 AC_SUBST(ecore_wince_release_info)
  75 AC_SUBST(ecore_x_release_info)
  76
  77 AC_DEFINE_UNQUOTED(SHARED_LIB_SUFFIX, "$shrext_cmds", [Suffix for shared objects])
  78
  79
  80 ### Default options with respect to host
  81
  82 # dependencies and options
  83 want_curl="no"
  84 want_abstract_sockets="no"
  85 want_gnutls="no"
  86 want_openssl="no"
  87 want_cares="no"
  88 want_cipher="no"
  89 want_signature="no"
  90 want_poll="yes"
  91 want_inotify="no"
  92 want_notify_win32="no"
  93 want_tslib="no"
  94 want_glib="no"
  95
  96 # core modules
  97 want_ecore_txt="yes"
  98 want_ecore_con="no"
  99 want_ecore_ipc="no"
 100 want_ecore_file="yes"
 101 want_ecore_config="no"
 102 want_ecore_imf="no"
 103 want_ecore_input="yes"
 104
 105 # graphic system modules
 106 want_evas_simple_x11="no"
 107 want_ecore_x_xcb="no"
 108 want_ecore_x="no"
 109 want_ecore_win32="no"
 110 want_ecore_quartz="no"
 111 want_ecore_sdl="no"
 112 want_ecore_fb="no"
 113 want_ecore_directfb="no"
 114 want_ecore_wince="no"
 115
 116 # ecore_evas modules
 117 want_ecore_evas="yes"
 118 want_ecore_evas_software_buffer="yes"
 119 want_ecore_evas_software_x11="no"
 120 want_ecore_evas_xrender_x11="no"
 121 want_ecore_evas_opengl_x11="no"
 122 want_ecore_evas_software_16_x11="no"
 123 want_ecore_evas_software_xcb="no"
 124 want_ecore_evas_xrender_xcb="no"
 125 want_ecore_evas_software_gdi="no"
 126 want_ecore_evas_software_ddraw="no"
 127 want_ecore_evas_direct3d="no"
 128 want_ecore_evas_opengl_glew="no"
 129 want_ecore_evas_software_16_ddraw="no"
 130 want_ecore_evas_quartz="no"
 131 want_ecore_evas_software_sdl="no"
 132 want_ecore_evas_directfb="no"
 133 want_ecore_evas_fb="no"
 134 want_ecore_evas_software_16_wince="no"
 135
 136 case "$host_os" in
 137    mingw32ce* | cegcc*)
 138       want_ecore_wince="yes"
 139       want_ecore_evas_software_16_wince="yes"
 140       ;;
 141    mingw*)
 142       want_notify_win32="yes"
 143       want_curl="yes"
 144       want_glib="auto"
 145       want_ecore_imf="yes"
 146       want_ecore_win32="yes"
 147       want_ecore_evas_software_gdi="yes"
 148       want_ecore_evas_software_ddraw="yes"
 149       want_ecore_evas_direct3d="yes"
 150       want_ecore_evas_opengl_glew="yes"
 151       want_ecore_evas_software_16_ddraw="auto"
 152       want_ecore_evas_software_sdl="yes"
 153       ;;
 154    darwin*)
 155       want_curl="yes"
 156       want_glib="auto"
 157       want_gnutls="auto"
 158       want_openssl="auto"
 159       want_ecore_con="yes"
 160       want_ecore_ipc="yes"
 161       want_ecore_config="yes"
 162       want_ecore_imf="yes"
 163       want_ecore_quartz="yes"
 164       want_ecore_evas_quartz="yes"
 165       want_ecore_evas_software_sdl="yes"
 166       ;;
 167    *)
 168       want_curl="yes"
 169       want_glib="auto"
 170       want_abstract_sockets="yes"
 171       want_gnutls="auto"
 172       want_openssl="auto"
 173       want_cipher="yes"
 174       want_signature="yes"
 175       want_inotify="yes"
 176       want_tslib="yes"
 177       want_ecore_con="yes"
 178       want_ecore_ipc="yes"
 179       want_ecore_config="yes"
 180       want_ecore_imf="yes"
 181       want_ecore_x="yes"
 182       want_ecore_evas_software_x11="yes"
 183       want_ecore_evas_xrender_x11="yes"
 184       want_ecore_evas_opengl_x11="yes"
 185       want_ecore_evas_software_16_x11="yes"
 186       want_ecore_evas_software_xcb="yes"
 187       want_ecore_evas_xrender_xcb="yes"
 188       want_ecore_evas_software_sdl="yes"
 189       want_ecore_evas_directfb="yes"
 190       want_ecore_evas_fb="yes"
 191       ;;
 192 esac
 193
 194 requirements_ecore=""
 195 requirements_ecore_con=""
 196 requirements_ecore_config=""
 197 requirements_ecore_directfb=""
 198 requirements_ecore_evas=""
 199 requirements_ecore_fb=""
 200 requirements_ecore_file=""
 201 requirements_ecore_imf=""
 202 requirements_ecore_imf_evas=""
 203 requirements_ecore_input=""
 204 requirements_ecore_input_evas=""
 205 requirements_ecore_ipc=""
 206 requirements_ecore_quartz=""
 207 requirements_ecore_sdl=""
 208 requirements_ecore_txt=""
 209 requirements_ecore_x=""
 210 requirements_ecore_win32=""
 211 requirements_ecore_wince=""
 212
 213 ### Additional options to configure
 214
 215 # abstract sockets (ecore_con.c)
 216 AC_ARG_ENABLE([abstract-sockets],
 217    [AC_HELP_STRING([--disable-abstract-sockets], [disable abstract sockets.])],
 218    [
 219     if test "x${enableval}" = "xyes" ; then
 220        want_abstract_sockets="yes"
 221     else
 222        want_abstract_sockets="no"
 223     fi
 224    ],
 225    [want_abstract_sockets="yes"])
 226
 227 if test "x${want_abstract_sockets}" = "xyes" ; then
 228    AC_DEFINE([HAVE_ABSTRACT_SOCKETS], [1], [Have abstract sockets namespace])
 229 fi
 230
 231 # Simple X11 build/link
 232
 233 AC_ARG_ENABLE(simple-x11,
 234   AC_HELP_STRING([--enable-simple-x11], [enable simple x11 linking]),
 235   [want_evas_simple_x11=$enableval])
 236
 237 # XIM
 238 AC_ARG_ENABLE([xim],
 239    [AC_HELP_STRING([--enable-xim], [enable X Input Method.])],
 240    [
 241     if test "x${enableval}" = "xyes" ; then
 242        want_xim="yes"
 243     else
 244        want_xim="no"
 245     fi
 246    ],
 247    [want_xim="no"])
 248
 249 if test "x${want_xim}" = "xyes" ; then
 250    AC_DEFINE([ENABLE_XIM], [1], [Enable X Input Method])
 251 fi
 252
 253
 254 ### Checks for programs
 255
 256 m4_ifdef([AC_PROG_OBJC],
 257    [
 258     AC_PROG_OBJC
 259     _AM_DEPENDENCIES(OBJC)
 260    ],
 261    [
 262     AC_CHECK_TOOL([OBJC], [gcc])
 263     AC_SUBST([OBJC])
 264     AC_SUBST([OBJCFLAGS])
 265    ])
 266 AC_PROG_CXX
 267 AC_PROG_CC
 268
 269 have_gnu_objc=${ac_cv_objc_compiler_gnu}
 270
 271 # doxygen program for documentation building
 272
 273 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 274
 275 # The first call to PKG_CHECK_MODULES is done conditionally,
 276 # so we should include this here:
 277 PKG_PROG_PKG_CONFIG
 278
 279 # Check whether pkg-config supports Requires.private
 280 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
 281    pkgconfig_requires_private="Requires.private"
 282 else
 283    pkgconfig_requires_private="Requires"
 284 fi
 285 AC_SUBST(pkgconfig_requires_private)
 286
 287
 288 ### Checks for libraries
 289
 290 # Evil library for compilation on Windows
 291
 292 case "$host_os" in
 293    mingw* | cegcc*)
 294       PKG_CHECK_MODULES([EVIL], [evil])
 295       AC_DEFINE(HAVE_EVIL, 1, [Set to 1 if Evil library is installed])
 296       requirements_ecore="evil ${requirements_ecore}"
 297       requirements_ecore_evas="evil ${requirements_ecore_evas}"
 298       requirements_ecore_file="evil ${requirements_ecore_file}"
 299       requirements_ecore_imf="evil ${requirements_ecore_imf}"
 300       requirements_ecore_imf_evas="evil ${requirements_ecore_imf_evas}"
 301       requirements_ecore_txt="evil ${requirements_ecore_txt}"
 302       EFL_ECORE_BUILD="-DEFL_ECORE_BUILD"
 303       EFL_ECORE_TXT_BUILD="-DEFL_ECORE_TXT_BUILD"
 304       EFL_ECORE_FILE_BUILD="-DEFL_ECORE_FILE_BUILD"
 305       EFL_ECORE_EVAS_BUILD="-DEFL_ECORE_EVAS_BUILD"
 306       EFL_ECORE_IMF_BUILD="-DEFL_ECORE_IMF_BUILD"
 307       EFL_ECORE_INPUT_BUILD="-DEFL_ECORE_INPUT_BUILD"
 308       ;;
 309 esac
 310
 311 have_win32=""
 312 have_wince=""
 313 case "$host_os" in
 314    mingw32ce* | cegcc*)
 315       EFL_ECORE_WINCE_BUILD="-DEFL_ECORE_WINCE_BUILD"
 316       requirements_ecore_wince="evil ${requirements_ecore_wince}"
 317       have_wince="yes"
 318       ;;
 319    mingw*)
 320       EFL_ECORE_WIN32_BUILD="-DEFL_ECORE_WIN32_BUILD"
 321       EFL_ECORE_SDL_BUILD="-DEFL_ECORE_SDL_BUILD"
 322       requirements_ecore_win32="evil ${requirements_ecore_win32}"
 323       requirements_ecore_sdl="evil ${requirements_ecore_sdl}"
 324       have_win32="yes"
 325       ;;
 326 esac
 327
 328 AC_SUBST(EFL_ECORE_BUILD)
 329 AC_SUBST(EFL_ECORE_TXT_BUILD)
 330 AC_SUBST(EFL_ECORE_FILE_BUILD)
 331 AC_SUBST(EFL_ECORE_EVAS_BUILD)
 332 AC_SUBST(EFL_ECORE_IMF_BUILD)
 333 AC_SUBST(EFL_ECORE_INPUT_BUILD)
 334 AC_SUBST(EFL_ECORE_WINCE_BUILD)
 335 AC_SUBST(EFL_ECORE_WIN32_BUILD)
 336 AC_SUBST(EFL_ECORE_SDL_BUILD)
 337
 338 AM_CONDITIONAL(ECORE_HAVE_WINCE, test "x${have_wince}" = "xyes")
 339 AM_CONDITIONAL(ECORE_HAVE_WIN32, test "x${have_win32}" = "xyes")
 340
 341 WIN32_LIBS=""
 342 case "$host_os" in
 343    mingw32ce* | cegcc*)
 344       WIN32_LIBS="-lws2"
 345       dlopen_libs="-ldl"
 346       ;;
 347    mingw*)
 348       WIN32_LIBS="-lws2_32"
 349       dlopen_libs="-ldl"
 350       ;;
 351    *)
 352       AC_CHECK_LIB(dl, dlopen, dlopen_libs=-ldl)
 353       ;;
 354 esac
 355 AC_SUBST(WIN32_LIBS)
 356 AC_SUBST(dlopen_libs)
 357
 358 # Eina library
 359
 360 PKG_CHECK_MODULES(EINA, [eina-0])
 361 #FIXME check all the requirements when the eina move will be finished
 362 requirements_ecore="eina-0 ${requirements_ecore}"
 363 requirements_ecore_con="ecore eina-0 ${requirements_ecore_con}"
 364 requirements_ecore_config="ecore eina-0 ${requirements_ecore_config}"
 365 requirements_ecore_directfb="ecore eina-0 ${requirements_ecore_directfb}"
 366 requirements_ecore_evas="ecore eina-0 ${requirements_ecore_evas}"
 367 requirements_ecore_fb="ecore eina-0 ${requirements_ecore_fb}"
 368 requirements_ecore_file="ecore eina-0 ${requirements_ecore_file}"
 369 requirements_ecore_imf="ecore eina-0 ${requirements_ecore_imf}"
 370 requirements_ecore_imf_evas="ecore eina-0 ${requirements_ecore_imf_evas}"
 371 requirements_ecore_input="ecore eina-0 ${requirements_ecore_input}"
 372 requirements_ecore_input_evas="ecore eina-0 ${requirements_ecore_input_evas}"
 373 requirements_ecore_ipc="ecore eina-0 ${requirements_ecore_ipc}"
 374 requirements_ecore_quartz="ecore eina-0 ${requirements_ecore_quartz}"
 375 requirements_ecore_sdl="ecore eina-0 ${requirements_ecore_sdl}"
 376 requirements_ecore_win32="ecore eina-0 ${requirements_ecore_win32}"
 377 requirements_ecore_wince="ecore eina-0 ${requirements_ecore_wince}"
 378 requirements_ecore_x="ecore eina-0 ${requirements_ecore_x}"
 379
 380
 381 # glib support (main loop integration)
 382 AC_ARG_ENABLE([glib],
 383    [AC_HELP_STRING([--disable-glib], [enable glib support. @<:@default=detect@:>@])],
 384    [want_glib=$enableval], [])
 385
 386 if test "x$want_glib" != "xno"; then
 387    PKG_CHECK_MODULES([GLIB], [glib-2.0], [have_glib="yes"], [have_glib="no"])
 388 else
 389    have_glib="no"
 390 fi
 391 if test "x$want_glib" = "xyes" -a "x$have_glib" = "xno"; then
 392    AC_MSG_ERROR([GLib support requested, but no GLib found by pkg-config.])
 393 elif test "x$have_glib" = "xyes"; then
 394    AC_DEFINE(HAVE_GLIB, [1], [Have GLib])
 395    requirements_ecore="glib-2.0 ${requirements_ecore}"
 396 fi
 397
 398
 399 # iconv library (ecore_txt)
 400
 401 iconv_cflags=""
 402 iconv_libs=""
 403 have_iconv="no"
 404 AC_ARG_WITH([iconv-link],
 405    AC_HELP_STRING([--with-iconv-link=ICONV_LINK], [explicitly specify an iconv link option]),
 406    [
 407     iconv_libs=$withval
 408     have_iconv="yes"
 409    ])
 410
 411 AC_MSG_CHECKING(for explicit iconv link options)
 412 if test "x${iconv_libs}" = "x" ; then
 413    AC_MSG_RESULT([no explicit iconv link option])
 414 else
 415    AC_MSG_RESULT([$iconv_libs])
 416 fi
 417
 418 AM_ICONV
 419
 420 if test "x${have_iconv}" = "xno" && test "x${am_cv_func_iconv}" = "xyes" ; then
 421    iconv_cflags=${LIBICONV}
 422    iconv_libs=${LTLIBICONV}
 423    have_iconv="yes"
 424 fi
 425
 426 AC_SUBST(iconv_cflags)
 427 AC_SUBST(iconv_libs)
 428
 429
 430 # SDL library (ecore_sdl)
 431
 432 have_sdl="no"
 433 SDL_CONFIG="sdl-config"
 434 AC_ARG_WITH([sdl-config],
 435    [AC_HELP_STRING([--with-sdl-config=PATH], [use sdl-config specified])],
 436    [
 437     SDL_CONFIG=$withval
 438     AC_MSG_NOTICE([using ${SDL_CONFIG} for sdl-config])
 439    ])
 440
 441 AC_PATH_PROG([SDL_CONFIG], ["sdl-config"], [""], [$PATH])
 442
 443 if test -z "$SDL_CONFIG" ; then
 444    SDL_CFLAGS=`$SDL_CONFIG --cflags`
 445    SDL_LIBS=`$SDL_CONFIG --libs`
 446    AC_SUBST(SDL_CFLAGS)
 447    AC_SUBST(SDL_LIBS)
 448    have_sdl="no"
 449 else
 450    PKG_CHECK_MODULES([SDL], [sdl >= 1.2.0], [have_sdl="yes"], [have_sdl="no"])
 451 fi
 452
 453 if test "x${have_sdl}" = "xyes" ; then
 454    PKG_CHECK_EXISTS([sdl >= 1.3.0],
 455       [AC_DEFINE(BUILD_ECORE_EVAS_SDL_130, 1, [Support for SVN SDL])])
 456 fi
 457
 458
 459 # DirectFB library (ecore_directfb)
 460
 461 PKG_CHECK_MODULES([DIRECTFB],
 462    [directfb >= 0.9.16],
 463    [have_directfb="yes"],
 464    [have_directfb="no"])
 465
 466
 467 # Eet library (ecore_config)
 468
 469 PKG_CHECK_MODULES([EET],
 470    [eet >= 1.0.0],
 471    [have_eet="yes"],
 472    [have_eet="no"])
 473
 474
 475 # Xlib and XCB (ecore_x)
 476
 477 have_x="no"
 478 have_ecore_x="no"
 479 have_ecore_x_xlib="no"
 480 have_ecore_x_xcb="no"
 481
 482 x_dir="";
 483 x_includes="";
 484 x_cflags="";
 485 x_libs="";
 486
 487 ecore_x_libs_private=""
 488
 489 AC_ARG_ENABLE(ecore-x-xcb,
 490    [AC_HELP_STRING([--enable-ecore-x-xcb],
 491        [enable the ecore_x module with XCB backend. [[default=disabled]]])],
 492    [want_ecore_x_xcb=$enableval],
 493    [want_ecore_x_xcb="no"])
 494
 495 AC_MSG_CHECKING(whether ecore_x with XCB backend is to be built)
 496 AC_MSG_RESULT($want_ecore_x_xcb)
 497
 498 if test "x$want_ecore_x_xcb" = "xyes" ; then
 499   PKG_CHECK_MODULES(XCB, xcb xcb-icccm xcb-image xcb-keysyms pixman-1,
 500     [ have_ecore_x_xcb="yes"
 501       requirements_ecore_x="xcb xcb-icccm xcb-image xcb-keysyms pixman-1 ${requirements_ecore_x}" ],
 502     [ have_ecore_x_xcb="no" ])
 503
 504   if test "x$have_ecore_x_xcb" = "xyes" ; then
 505     PKG_CHECK_MODULES(XCB_COMPOSITE, xcb-composite,
 506       [ have_ecore_x_xcb_composite="yes"
 507         requirements_ecore_x="xcb-composite ${requirements_ecore_x}"
 508         AC_DEFINE(ECORE_XCB_COMPOSITE, 1, [Build support for XCB composite]) ],
 509       [ have_ecore_x_xcb_composite="no" ])
 510
 511     PKG_CHECK_MODULES(XCB_DAMAGE, xcb-damage,
 512       [ have_ecore_x_xcb_damage="yes"
 513         requirements_ecore_x="xcb-damage ${requirements_ecore_x}"
 514         AC_DEFINE(ECORE_XCB_DAMAGE, 1, [Build support for XCB damage]) ],
 515       [ have_ecore_x_xcb_damage="no" ])
 516
 517     PKG_CHECK_MODULES(XCB_DPMS, xcb-dpms,
 518       [ have_ecore_x_xcb_dpms="yes"
 519         requirements_ecore_x="xcb-dpms ${requirements_ecore_x}"
 520         AC_DEFINE(ECORE_XCB_DPMS, 1, [Build support for XCB dpms]) ],
 521       [ have_ecore_x_xcb_dpms="no" ])
 522
 523     PKG_CHECK_MODULES(XCB_RANDR, xcb-randr,
 524       [ have_ecore_x_xcb_randr="yes"
 525         requirements_ecore_x="xcb-randr ${requirements_ecore_x}"
 526         AC_DEFINE(ECORE_XCB_RANDR, 1, [Build support for XCB randr]) ],
 527       [ have_ecore_x_xcb_randr="no" ])
 528
 529     PKG_CHECK_MODULES(XCB_RENDER, xcb-render,
 530       [ have_ecore_x_xcb_render="yes"
 531         requirements_ecore_x="xcb-render ${requirements_ecore_x}"
 532         AC_DEFINE(ECORE_XCB_RENDER, 1, [Build support for XCB render]) ],
 533       [ have_ecore_x_xcb_render="no" ])
 534
 535     PKG_CHECK_MODULES(XCB_SCREENSAVER, xcb-screensaver,
 536       [ have_ecore_x_xcb_screensaver="yes"
 537         requirements_ecore_x="xcb-screensaver ${requirements_ecore_x}"
 538         AC_DEFINE(ECORE_XCB_SCREENSAVER, 1, [Build support for XCB screensaver]) ],
 539       [ have_ecore_x_xcb_screensaver="no" ])
 540
 541     PKG_CHECK_MODULES(XCB_SHAPE, xcb-shape,
 542       [ have_ecore_x_xcb_shape="yes"
 543         requirements_ecore_x="xcb-shape ${requirements_ecore_x}"
 544         AC_DEFINE(ECORE_XCB_SHAPE, 1, [Build support for XCB shape]) ],
 545       [ have_ecore_x_xcb_shape="no" ])
 546
 547     PKG_CHECK_MODULES(XCB_SYNC, xcb-sync,
 548       [ have_ecore_x_xcb_sync="yes"
 549         requirements_ecore_x="xcb-sync ${requirements_ecore_x}"
 550         AC_DEFINE(ECORE_XCB_SYNC, 1, [Build support for XCB sync]) ],
 551       [ have_ecore_x_xcb_sync="no" ])
 552
 553     PKG_CHECK_MODULES(XCB_XFIXES, xcb-xfixes,
 554       [ have_ecore_x_xcb_xfixes="yes"
 555         requirements_ecore_x="xcb-xfixes ${requirements_ecore_x}"
 556         AC_DEFINE(ECORE_XCB_FIXES, 1, [Build support for XCB xfixes]) ],
 557       [ have_ecore_x_xcb_xfixes="no" ])
 558
 559     PKG_CHECK_MODULES(XCB_XINERAMA, xcb-xinerama,
 560       [ have_ecore_x_xcb_xinerama="yes"
 561         requirements_ecore_x="xcb-xinerama ${requirements_ecore_x}"
 562         AC_DEFINE(ECORE_XCB_XINERAMA, 1, [Build support for XCB xinerama]) ],
 563       [ have_ecore_x_xcb_xinerama="no" ])
 564
 565     PKG_CHECK_MODULES(XCB_XPRINT, xcb-xprint,
 566       [ have_ecore_x_xcb_xprint="yes"
 567         requirements_ecore_x="xcb-xprint ${requirements_ecore_x}"
 568         AC_DEFINE(ECORE_XCB_XPRINT, 1, [Build support for XCB xprint]) ],
 569       [ have_ecore_x_xcb_xprint="no" ])
 570
 571     PKG_CHECK_MODULES(XCB_XTEST, xcb-xtest,
 572       [ have_ecore_x_xcb_xtest="yes"
 573         requirements_ecore_x="xcb-xtest ${requirements_ecore_x}"
 574         AC_DEFINE(ECORE_XCB_XTEST, 1, [Build support for XCB xtest]) ],
 575       [ have_ecore_x_xcb_xtest="no" ])
 576
 577     AC_DEFINE(HAVE_ECORE_X_XCB, 1, [Defined to 1 if XCB is enabled.])
 578
 579     x_cflags=$XCB_CFLAGS
 580     x_libs=$XCB_LIBS
 581     have_x="yes"
 582
 583     have_ecore_x_xcb_define="-DHAVE_ECORE_X_XCB"
 584     AC_SUBST(have_ecore_x_xcb_define)
 585   fi
 586 fi
 587
 588 if ! test "x$have_ecore_x_xcb" = "xyes" ; then
 589   AC_PATH_XTRA
 590   AC_CHECK_HEADER(X11/X.h,
 591     [
 592      if test "x$want_evas_simple_x11" = "xyes"; then
 593        x_libs="${x_libs} -lX11 -lXext"
 594      else
 595        x_dir=${x_dir:-/usr/X11R6}
 596        x_cflags=${x_cflags:--I${x_includes:-$x_dir/include}}
 597        x_libs="${x_libs:--L${x_libraries:-$x_dir/lib}} -lX11 -lXext"
 598      fi
 599      have_ecore_x_xlib="yes"
 600     ]
 601   )
 602
 603   if test "x$have_ecore_x_xlib" = "xyes"; then
 604     Xcursor_libs=""
 605     Xcursor_cflags=""
 606     use_Xcursor="no"
 607     PCFLAGS=$CFLAGS
 608     CFLAGS="$x_cflags $x_includes"
 609     AC_CHECK_HEADER(X11/Xcursor/Xcursor.h,
 610       [
 611         AC_CHECK_LIB(Xcursor, XcursorImageLoadCursor,
 612           [
 613             AC_DEFINE(ECORE_XCURSOR, 1, [Build support for Xcursor])
 614             Xcursor_cflags=""
 615             Xcursor_libs="-lXcursor"
 616             use_Xcursor="yes"
 617           ], [
 618             Xcursor_cflags=""
 619             Xcursor_libs=""
 620             use_Xcursor="no"
 621           ], [
 622             $x_libs -lXrender
 623           ]
 624         )
 625       ], [
 626         Xcursor_cflags=""
 627         Xcursor_libs=""
 628         use_Xcursor="no"
 629       ], [
 630         #include <X11/Xlib.h>
 631       ]
 632     )
 633     CFLAGS=$PCFLAGS
 634
 635     AC_SUBST(Xcursor_cflags)
 636     AC_SUBST(Xcursor_libs)
 637
 638     ECORE_CHECK_X_EXTENSION([Xkb], [XKB.h], [X11], [XkbSetDetectableAutoRepeat])
 639     ECORE_CHECK_X_EXTENSION([Xcomposite], [Xcomposite.h], [Xcomposite], [XCompositeQueryExtension])
 640     ECORE_CHECK_X_EXTENSION([Xdamage], [Xdamage.h], [Xdamage], [XDamageSubtract])
 641     ECORE_CHECK_X_EXTENSION([Xdpms], [dpms.h], [Xdpms], [DPMSQueryExtension])
 642     if test "x$use_xdpms" = "xno" ; then
 643       ECORE_CHECK_X_EXTENSION([Xdpms], [dpms.h], [Xext], [DPMSQueryExtension])
 644     fi
 645     ECORE_CHECK_X_EXTENSION([Xfixes], [Xfixes.h], [Xfixes], [XFixesExpandRegion])
 646     ECORE_CHECK_X_EXTENSION([Xinerama], [Xinerama.h], [Xinerama], [XineramaQueryScreens])
 647     ECORE_CHECK_X_EXTENSION([Xprint], [Print.h], [Xp], [XpQueryScreens])
 648     ECORE_CHECK_X_EXTENSION([Xrandr], [Xrandr.h], [Xrandr], [XRRGetScreenResourcesCurrent])
 649     ECORE_CHECK_X_EXTENSION([Xrender], [Xrender.h], [Xrender], [XRenderFindVisualFormat])
 650     ECORE_CHECK_X_EXTENSION([Xtest], [XTest.h], [Xtst], [XTestFakeKeyEvent])
 651     ECORE_CHECK_X_EXTENSION([Xss], [scrnsaver.h], [Xss], [XScreenSaverSelectInput])
 652     ECORE_CHECK_X_EXTENSION([Xi2], [XInput2.h], [Xi], [XIQueryDevice])
 653
 654     ecore_x_libs_private="${Xcursor_libs} ${XKB_LIBS} ${XCOMPOSITE_LIBS} ${XDAMAGE_LIBS} ${XDPMS_LIBS} ${XFIXES_LIBS} ${XINERAMA_LIBS} ${XPRINT_LIBS} ${XRANDR_LIBS} ${XRENDER_LIBS} ${XTEST_LIBS} ${XSS_LIBS} ${XI2_LIBS}"
 655
 656     AC_DEFINE(HAVE_ECORE_X_XLIB, 1, [Defined to 1 if Xlib is enabled.])
 657     have_x="yes"
 658
 659     have_ecore_x_xlib="yes"
 660   fi
 661 fi
 662
 663 AC_SUBST(x_cflags)
 664 AC_SUBST(x_includes)
 665 AC_SUBST(x_libs)
 666 AC_SUBST(ecore_x_libs_private)
 667
 668 AM_CONDITIONAL(BUILD_ECORE_X_XLIB, test $have_ecore_x_xlib = yes)
 669 AM_CONDITIONAL(BUILD_ECORE_X_XCB, test $have_ecore_x_xcb = yes)
 670
 671
 672 # Evas library (ecore_config, ecore_input_evas, ecore_imf_evas and ecore_evas)
 673
 674 PKG_CHECK_MODULES([EVAS], [evas >= 0.9.9],
 675    [have_evas="yes"],
 676    [have_evas="no"])
 677
 678
 679 ### Checks for header files
 680
 681 AC_HEADER_SYS_WAIT
 682
 683 case "$host_os" in
 684    mingw* | cegcc*)
 685       AC_DEFINE(HAVE_DLFCN_H, 1, [Define to 1 if you have the <dlfcn.h> header file.])
 686       AC_DEFINE(HAVE_SYS_MMAN_H, 1, [Define to 1 if you have the <sys/mman.h> header file.])
 687       AC_DEFINE(HAVE_SYS_TIME_H, 1, [Define to 1 if you have the <sys/time.h> header file.])
 688       ;;
 689    *)
 690       AC_CHECK_HEADERS([dlfcn.h features.h langinfo.h locale.h netdb.h netinet/in.h sys/time.h sys/mman.h signal.h sys/resource.h])
 691       ;;
 692 esac
 693
 694 # Framebuffer (ecore_fb)
 695 have_fb="no"
 696 AC_CHECK_HEADER([linux/fb.h],
 697    [AC_CHECK_HEADER([linux/input.h], [have_fb="yes"])])
 698
 699 # Quartz header files (ecore_quartz)
 700
 701 quartz_ldflags="";
 702 have_quartz="no"
 703
 704 if test "x${have_gnu_objc}" = "xyes" ; then
 705    AC_LANG_PUSH([Objective C])
 706    AC_CHECK_HEADER([Cocoa/Cocoa.h],
 707       [
 708        have_quartz="yes"
 709        quartz_ldflags="-framework Cocoa"
 710       ],
 711       [have_quartz="no"])
 712    AC_LANG_POP([Objective C])
 713 fi
 714
 715 AC_SUBST(quartz_ldflags)
 716
 717 # basic pthread support
 718
 719 EFL_CHECK_PTHREAD([have_pthread="yes"], [have_pthread="no"])
 720
 721 ### Checks for types
 722 AC_CHECK_SIZEOF(int, 4)
 723 AC_CHECK_SIZEOF(long, 4)
 724
 725
 726 ### Checks for structures
 727
 728
 729 ### Checks for compiler characteristics
 730 AM_PROG_CC_STDC
 731 AC_C_CONST
 732 AC_C_BIGENDIAN
 733 AC_HEADER_STDC
 734 AC_C___ATTRIBUTE__
 735
 736 WIN32_CPPFLAGS=""
 737 WIN32_CFLAGS=""
 738 case "$host_os" in
 739    mingw32ce*)
 740       WIN32_CPPFLAGS="-D_WIN32_WCE=0x0420"
 741       ;;
 742    cegcc*)
 743       WIN32_CPPFLAGS="-D_WIN32_WCE=0x0420"
 744       WIN32_CFLAGS="-mwin32"
 745       ;;
 746    mingw*)
 747       WIN32_CPPFLAGS="-D_WIN32_WINNT=0x0500"
 748       ;;
 749 esac
 750 AC_SUBST(WIN32_CPPFLAGS)
 751 AC_SUBST(WIN32_CFLAGS)
 752
 753
 754 ### Checks for linker characteristics
 755
 756 # use --enable-auto-import on Windows
 757
 758 lt_enable_auto_import=""
 759 case "$host_os" in
 760    mingw* | cegcc*)
 761       lt_enable_auto_import="-Wl,--enable-auto-import"
 762       ;;
 763 esac
 764 AC_SUBST(lt_enable_auto_import)
 765
 766 ### Checks for library functions
 767 AC_FUNC_ALLOCA
 768 AC_CHECK_FUNCS(gettimeofday strlcpy)
 769
 770 have_atfile_source=auto
 771 AC_ARG_ENABLE(atfile-source,
 772         AC_HELP_STRING([--disable-atfile-source],
 773                        [disable use of atfile source functions as openat and mkdirat @<:@default=detect@:>@]),
 774         [have_atfile_source=$enableval], [have_atfile_source=auto])
 775
 776 if test "x$have_atfile_source" != "xno"; then
 777         AC_CHECK_FUNCS(mkdirat,
 778                 [
 779                 have_atfile_source=yes
 780                 AC_DEFINE(HAVE_ATFILE_SOURCE, 1, [mkdirat exists])
 781                 ],
 782                 [
 783                 if test "x$have_atfile_source" = "xyes"; then
 784                         AC_MSG_ERROR([required atfile-source but no mkdirat()])
 785                 fi
 786                 have_atfile_source=no
 787                 ])
 788 fi
 789
 790 ### Ecore modules
 791
 792 ## Core modules
 793
 794 # ecore_txt
 795 ECORE_CHECK_MODULE([txt], [${want_ecore_txt}], [Txt], [$have_iconv])
 796
 797 # ecore_con
 798 ECORE_CHECK_MODULE([con], [${want_ecore_con}], [Con])
 799
 800 have_curl="no"
 801 have_gnutls="no"
 802 have_openssl="no"
 803 have_cares="no"
 804 if test "x${have_ecore_con}" = "xyes" ; then
 805
 806    ECORE_CHECK_CURL([${want_curl}],
 807       [
 808        have_curl="yes"
 809        requirements_ecore_con="libcurl ${requirements_ecore_con}"
 810       ],
 811       [have_curl="no"])
 812
 813    ECORE_CHECK_GNUTLS([${want_gnutls}],
 814       [have_gnutls="yes"],
 815       [have_gnutls="no"])
 816
 817    ECORE_CHECK_OPENSSL([${want_openssl}],
 818       [have_openssl="yes"],
 819       [have_openssl="no"])
 820
 821    if test "x${have_gnutls}" = "xyes" ; then
 822       requirements_ecore_con="gnutls ${requirements_ecore_con}"
 823       # no need to add it to req_ecore_ipc, since they
 824       # depends on ecore_con anyway.
 825    else
 826       if test "x${have_openssl}" = "xyes" ; then
 827          requirements_ecore_con="openssl ${requirements_ecore_con}"
 828          # no need to add it to req_ecore_ipc, since they
 829          # depends on ecore_con anyway.
 830       fi
 831    fi
 832
 833    ECORE_CHECK_CARES([${want_cares}],
 834       [
 835        have_cares="yes"
 836        requirements_ecore_con="libcares ${requirements_ecore_con}"
 837       ],
 838       [have_cares="no"])
 839
 840 fi
 841
 842 AM_CONDITIONAL([HAVE_CARES], [test "x${have_cares}" = "xyes"])
 843
 844 # ecore_ipc
 845 ECORE_CHECK_MODULE([ipc], [${want_ecore_ipc}], [Ipc], [${have_ecore_con}],
 846    [requirements_ecore_ipc="ecore-con ${requirements_ecore_ipc}"])
 847
 848 # ecore_file
 849 ECORE_CHECK_MODULE([file], [${want_ecore_file}], [File])
 850
 851 have_poll="no"
 852 have_inotify="no"
 853 have_notify_win32="no"
 854 if test "x${have_ecore_file}" = "xyes" ; then
 855    ECORE_CHECK_POLL([${want_poll}], [have_poll="yes"], [have_poll="no"])
 856    ECORE_CHECK_INOTIFY([${want_inotify}], [have_inotify="yes"], [have_inotify="no"])
 857    ECORE_CHECK_NOTIFY_WIN32([${want_notify_win32}], [have_notify_win32="yes"], [have_notify_win32="no"])
 858
 859    if test "x${have_ecore_con}" = "xyes" ; then
 860       requirements_ecore_file="ecore-con ${requirements_ecore_file}"
 861    fi
 862 fi
 863
 864 # ecore_config
 865 ecore_config_deps="no"
 866 if test "x${have_eet}" = "xyes" -a "x${have_evas}"  -a "x${have_ecore_ipc}" ; then
 867    ecore_config_deps="yes"
 868 fi
 869
 870 ECORE_CHECK_MODULE([config], [${want_ecore_config}], [Config], [${ecore_config_deps}],
 871    [requirements_ecore_config="ecore-ipc evas eet ${requirements_ecore_config}"])
 872
 873 # ecore_imf
 874
 875 ECORE_CHECK_MODULE([imf], [${want_ecore_imf}], [Imf])
 876
 877 # ecore_imf_evas
 878
 879 ecore_imf_evas_deps="no"
 880 if test "x${have_ecore_imf}" = "xyes" -a "x${have_evas}" = "xyes" ; then
 881    ecore_imf_evas_deps="yes"
 882 fi
 883
 884 ECORE_CHECK_MODULE([imf-evas], [${want_ecore_imf}], [Imf_Evas], [${ecore_imf_evas_deps}],
 885    [requirements_ecore_imf_evas="ecore-imf evas ${requirements_ecore_imf_evas}"])
 886
 887 # ecore_input{_evas}
 888 ECORE_CHECK_MODULE([input], [${want_ecore_input}], [Input])
 889 ECORE_CHECK_MODULE([input-evas], [${want_ecore_input}], [Input_Evas], [${have_evas}],
 890    [requirements_ecore_input_evas="ecore-input evas ${requirements_ecore_input}"])
 891
 892 ## Graphic systems
 893
 894 # ecore_x{cb}
 895
 896 ecore_x_deps="no"
 897 if test "x${have_x}" = "xyes" -a \
 898         "x${have_ecore_input}" = "xyes" -a \
 899         "x${have_ecore_txt}" = "xyes" ; then
 900    ecore_x_deps="yes"
 901 fi
 902
 903 ECORE_CHECK_MODULE([x], [${want_ecore_x}], [X], [${ecore_x_deps}],
 904   [
 905    ecore_x_libs="$ecore_x_libs $x_libs"
 906    requirements_ecore_x="ecore-input ecore-txt ${requirements_ecore_x}"
 907   ])
 908
 909 # ecore_win32
 910
 911 ECORE_CHECK_MODULE([win32], [${want_ecore_win32}], [Win32], [${have_ecore_input}],
 912    [
 913     ecore_win32_libs="-lole32 -lgdi32"
 914     requirements_ecore_win32="ecore-input ${requirements_ecore_win32}"
 915    ])
 916 AC_SUBST(ecore_win32_libs)
 917
 918 # ecore_quartz
 919
 920 ecore_quartz_deps="no"
 921 if test "x${have_ecore_input}" = "xyes" -a "x${have_quartz}" = "xyes" ; then
 922    ecore_quartz_deps="yes"
 923 fi
 924
 925 ECORE_CHECK_MODULE([quartz], [${want_ecore_quartz}], [Quartz], [${ecore_quartz_deps}],
 926    [requirements_ecore_quartz="ecore-input ${requirements_ecore_quartz}"])
 927
 928 # ecore_sdl
 929
 930 ecore_sdl_deps="no"
 931 if test "x${have_sdl}" = "xyes" -a "x${have_ecore_input}" = "xyes" ; then
 932    ecore_sdl_deps="yes"
 933 fi
 934
 935 ECORE_CHECK_MODULE([sdl], [${want_ecore_sdl}], [Sdl], [${ecore_sdl_deps}],
 936    [requirements_ecore_sdl="ecore-input ${requirements_ecore_sdl}"])
 937
 938 # ecore_fb
 939 ECORE_CHECK_MODULE([fb], [${want_ecore_fb}], [FB], [$have_fb])
 940
 941 if test "x${have_ecore_fb}" = "xyes" ; then
 942    ECORE_CHECK_TSLIB([${want_tslib}],
 943       [
 944        have_tslib="yes"
 945        requirements_ecore_fb="${_tslib_requirement} ${requirements_ecore_fb}"
 946       ],
 947       [have_tslib="no"])
 948 fi
 949
 950 # ecore_directfb
 951
 952 ECORE_CHECK_MODULE([directfb], [${want_ecore_directfb}], [DirectFB], [${have_directfb}],
 953    [requirements_ecore_directfb="directfb ${requirements_ecore_directfb}"])
 954
 955 # ecore_wince
 956
 957 ECORE_CHECK_MODULE([wince], [${want_ecore_wince}], [WinCE], [${have_ecore_input}],
 958    [requirements_ecore_win32="ecore-input ${requirements_ecore_win32}"])
 959
 960 ## Ecore Evas
 961
 962 # ecore_evas
 963
 964 ecore_evas_deps="no"
 965 if test "x${have_evas}" = "xyes" -a "x${have_ecore_input}" = "xyes" -a "x${have_ecore_input_evas}" = "xyes" ; then
 966    ecore_evas_deps="yes"
 967 fi
 968
 969 ECORE_CHECK_MODULE([evas], [${want_ecore_evas}], [Evas], [${ecore_evas_deps}],
 970   [requirements_ecore_evas="ecore-input ecore-input-evas evas ${requirements_ecore_evas}"])
 971
 972 # ecore_evas_buffer
 973
 974 ECORE_EVAS_CHECK_MODULE([software-buffer],
 975    [${want_ecore_evas_software_buffer}],
 976    [Software Buffer],
 977    [yes])
 978
 979 # ecore_evas_x11
 980
 981 # ecore_evas_software_x11
 982
 983 ECORE_EVAS_CHECK_MODULE([software-x11],
 984    [${want_ecore_evas_software_x11}],
 985    [Software X11],
 986    [${have_ecore_x}])
 987
 988 have_ecore_evas_software_xlib=no"
 989 have_ecore_evas_software_xcb=no"
 990 if test "x$have_ecore_evas_software_x11" = "xyes" ; then
 991    have_ecore_evas_software_xlib=`${PKG_CONFIG} --variable=Xlib evas-software-x11`
 992    if test "x${have_ecore_evas_software_xlib}" = "xyes" -a "x${have_ecore_x_xlib}" = "xyes" ; then
 993       AC_DEFINE(BUILD_ECORE_EVAS_SOFTWARE_XLIB, 1, [Evas Software Xlib Engine Support])
 994    fi
 995    have_ecore_evas_software_xcb=`${PKG_CONFIG} --variable=XCB evas-software-x11`
 996    if test "x$have_ecore_evas_software_xcb" = "xyes" -a "x${have_ecore_x_xcb}" = "xyes" ; then
 997       AC_DEFINE(BUILD_ECORE_EVAS_SOFTWARE_XCB, 1, [Evas Software XCB Engine Support])
 998    fi
 999 fi
1000
1001 # ecore_evas_xrender_x11
1002
1003 ECORE_EVAS_CHECK_MODULE([xrender-x11],
1004    [${want_ecore_evas_xrender_x11}],
1005    [XRender Xlib],
1006    [${have_ecore_x_xlib}])
1007
1008 # ecore_evas_opengl_x11
1009
1010 ECORE_EVAS_CHECK_MODULE([opengl-x11],
1011    [${want_ecore_evas_opengl_x11}],
1012    [OpenGL Xlib],
1013    [${have_ecore_x_xlib}])
1014
1015 # ecore_evas_software_x11 16 bits
1016
1017 ECORE_EVAS_CHECK_MODULE([software-16-x11],
1018    [${want_ecore_evas_software_16_x11}],
1019    [Software Xlib 16 bits],
1020    [${have_ecore_x_xlib}])
1021
1022 # ecore_evas_xrender_xcb
1023
1024 ECORE_EVAS_CHECK_MODULE([xrender-xcb],
1025    [${want_ecore_evas_xrender_xcb}],
1026    [XRender XCB],
1027    [${ecore_evas_xcb_deps}])
1028
1029 if test "x$have_ecore_evas_software_x11" = "xyes" -o \
1030         "x$have_ecore_evas_xrender_x11" = "xyes" -o \
1031         "x$have_ecore_evas_opengl_x11" = "xyes" -o \
1032         "x$have_ecore_evas_software_16_x11" = "xyes" -o \
1033         "x$have_ecore_evas_software_xcb" = "xyes" -o \
1034         "x$have_ecore_evas_xrender_xcb" = "xyes"; then
1035    AC_DEFINE(BUILD_ECORE_EVAS_X11, 1, [Support for X Window Engines in Ecore_Evas])
1036    requirements_ecore_evas="ecore-x ${requirements_ecore_evas}"
1037 fi
1038
1039 # ecore_evas_win32
1040
1041 ECORE_EVAS_CHECK_MODULE([software-gdi],
1042    [${want_ecore_evas_software_gdi}],
1043    [Software GDI],
1044    [${have_ecore_win32}])
1045
1046 ECORE_EVAS_CHECK_MODULE([software-ddraw],
1047    [${want_ecore_evas_software_ddraw}],
1048    [Software DirectDraw],
1049    [${have_ecore_win32}])
1050
1051 ECORE_EVAS_CHECK_MODULE([direct3d],
1052    [${want_ecore_evas_direct3d}],
1053    [Direct3d],
1054    [${have_ecore_win32}])
1055
1056 ECORE_EVAS_CHECK_MODULE([opengl-glew],
1057    [${want_ecore_evas_opengl_glew}],
1058    [Glew OpenGL],
1059    [${have_ecore_win32}])
1060
1061 ECORE_EVAS_CHECK_MODULE([software-16-ddraw],
1062    [${want_ecore_evas_software_16_ddraw}],
1063    [16 bpp Software DirectDraw],
1064    [${have_ecore_win32}])
1065
1066 if test "x${have_ecore_evas_software_gdi}" = "xyes" -o \
1067         "x${have_ecore_evas_software_ddraw}" = "xyes" -o \
1068         "x${have_ecore_evas_direct3d}" = "xyes" -o \
1069         "x${have_ecore_evas_opengl_glew}" = "xyes" -o \
1070         "x${have_ecore_evas_software_16_ddraw}" = "xyes" ; then
1071    AC_DEFINE(BUILD_ECORE_EVAS_WIN32, 1, [Support for Win32 Engine in Ecore_Evas])
1072    requirements_ecore_evas="ecore-win32 ${requirements_ecore_evas}"
1073 fi
1074
1075 # ecore_evas_quartz
1076
1077 ECORE_EVAS_CHECK_MODULE([quartz],
1078    [${want_ecore_evas_quartz}],
1079    [Quartz],
1080    [${have_ecore_quartz}],
1081    [requirements_ecore_evas="ecore-quartz ${requirements_ecore_evas}"])
1082
1083 # ecore_evas_software_sdl
1084
1085 ECORE_EVAS_CHECK_MODULE([software-sdl],
1086    [${want_ecore_evas_software_sdl}],
1087    [Software SDL],
1088    [${have_ecore_sdl}],
1089    [requirements_ecore_evas="ecore-sdl ${requirements_ecore_evas}"])
1090
1091 # ecore_evas_directfb
1092
1093 ECORE_EVAS_CHECK_MODULE([directfb],
1094    [${want_ecore_evas_directfb}],
1095    [DirectFB],
1096    [${have_ecore_directfb}],
1097    [requirements_ecore_evas="ecore-directfb ${requirements_ecore_evas}"])
1098
1099 # ecore_evas_fb
1100
1101 ECORE_EVAS_CHECK_MODULE([fb],
1102    [${want_ecore_evas_fb}],
1103    [Linux Framebuffer],
1104    [${have_ecore_fb}],
1105    [requirements_ecore_evas="ecore-fb ${requirements_ecore_evas}"])
1106
1107 # ecore_evas_wince
1108
1109 ECORE_EVAS_CHECK_MODULE([software-16-wince],
1110    [${want_ecore_evas_software_16_wince}],
1111    [16 bpp Software Windows CE],
1112    [${have_ecore_wince}],
1113    [requirements_ecore_evas="ecore-wince ${requirements_ecore_evas}"])
1114
1115
1116
1117 ### requirements
1118
1119 AC_SUBST(requirements_ecore)
1120 AC_SUBST(requirements_ecore_con)
1121 AC_SUBST(requirements_ecore_config)
1122 AC_SUBST(requirements_ecore_directfb)
1123 AC_SUBST(requirements_ecore_evas)
1124 AC_SUBST(requirements_ecore_fb)
1125 AC_SUBST(requirements_ecore_file)
1126 AC_SUBST(requirements_ecore_imf)
1127 AC_SUBST(requirements_ecore_imf_evas)
1128 AC_SUBST(requirements_ecore_input)
1129 AC_SUBST(requirements_ecore_input_evas)
1130 AC_SUBST(requirements_ecore_ipc)
1131 AC_SUBST(requirements_ecore_quartz)
1132 AC_SUBST(requirements_ecore_sdl)
1133 AC_SUBST(requirements_ecore_txt)
1134 AC_SUBST(requirements_ecore_x)
1135 AC_SUBST(requirements_ecore_win32)
1136 AC_SUBST(requirements_ecore_wince)
1137
1138 AC_OUTPUT([
1139 Makefile
1140 ecore-con.pc
1141 ecore-config.pc
1142 ecore-directfb.pc
1143 ecore-evas.pc
1144 ecore-fb.pc
1145 ecore-file.pc
1146 ecore-imf.pc
1147 ecore-imf-evas.pc
1148 ecore-ipc.pc
1149 ecore-txt.pc
1150 ecore-x.pc
1151 ecore-input.pc
1152 ecore-input-evas.pc
1153 ecore-win32.pc
1154 ecore-sdl.pc
1155 ecore-quartz.pc
1156 ecore-wince.pc
1157 ecore.pc
1158 doc/ecore.dox
1159 doc/Makefile
1160 src/Makefile
1161 src/bin/Makefile
1162 src/lib/Makefile
1163 src/lib/ecore/Makefile
1164 src/lib/ecore_x/Makefile
1165 src/lib/ecore_x/xlib/Makefile
1166 src/lib/ecore_x/xcb/Makefile
1167 src/lib/ecore_fb/Makefile
1168 src/lib/ecore_sdl/Makefile
1169 src/lib/ecore_quartz/Makefile
1170 src/lib/ecore_evas/Makefile
1171 src/lib/ecore_con/Makefile
1172 src/lib/ecore_imf/Makefile
1173 src/lib/ecore_imf_evas/Makefile
1174 src/lib/ecore_input/Makefile
1175 src/lib/ecore_input_evas/Makefile
1176 src/lib/ecore_ipc/Makefile
1177 src/lib/ecore_txt/Makefile
1178 src/lib/ecore_config/Makefile
1179 src/lib/ecore_file/Makefile
1180 src/lib/ecore_directfb/Makefile
1181 src/lib/ecore_win32/Makefile
1182 src/lib/ecore_wince/Makefile
1183 README
1184 ecore.spec
1185 po/Makefile.in
1186 ])
1187
1188 echo
1189 echo "$PACKAGE $VERSION"
1190 echo
1191 echo "Optional Modules:"
1192 echo
1193 echo " Core:"
1194 echo
1195 echo "  Ecore........................: always"
1196 echo "    Thread support.............: $have_pthread"
1197 echo "    GLib support...............: $have_glib"
1198 echo "  Ecore_Txt....................: $have_ecore_txt"
1199 echo "  Ecore_Con....................: $have_ecore_con"
1200 if test "x$have_ecore_con" = "xyes" ; then
1201   echo $ECHO_N "    OpenSSL....................: $have_openssl $ECHO_C"
1202 if test "x$have_gnutls" = "xyes" ; then
1203   echo " (disabled)"
1204 else
1205   echo
1206 fi
1207   echo "    GnuTLS.....................: $have_gnutls"
1208   echo "    CURL.......................: $have_curl"
1209   echo "    Abstract Sockets...........: $want_abstract_sockets"
1210   echo "    c-ares.....................: $have_cares"
1211 fi
1212 echo "  Ecore_Ipc....................: $have_ecore_ipc"
1213 if test "x$have_ecore_ipc" = "xyes" ; then
1214   echo $ECHO_N "    OpenSSL....................: $have_openssl $ECHO_C"
1215 if test "x$have_gnutls" = "xyes" ; then
1216   echo " (disabled)"
1217 else
1218   echo
1219 fi
1220   echo "    GnuTLS.....................: $have_gnutls"
1221 fi
1222 echo "  Ecore_File...................: $have_ecore_file"
1223 if test "x$have_ecore_file" = "xyes" ; then
1224   echo "    Inotify....................: $have_inotify"
1225   echo "    Windows notification.......: $have_notify_win32"
1226   echo "    Poll.......................: $have_poll"
1227   echo "    CURL.......................: $have_curl"
1228 fi
1229 echo "  Ecore_Config.................: $have_ecore_config"
1230 echo "  Ecore_IMF....................: $have_ecore_imf"
1231 echo "  Ecore_IMF_Evas...............: $have_ecore_imf_evas"
1232 echo "  Ecore_Input..................: $have_ecore_input"
1233 echo "  Ecore_Input_Evas.............: $have_ecore_input_evas"
1234
1235 echo
1236 echo " Graphic systems:"
1237 echo
1238
1239 if test "x$have_ecore_x" = "xyes" ; then
1240   if test "x$have_ecore_x_xcb" = "xyes" ; then
1241     echo "  Ecore_X (XCB backend)........: $have_ecore_x_xcb"
1242     echo "    Xprint.....................: $have_ecore_x_xcb_xprint"
1243     echo "    Xinerama...................: $have_ecore_x_xcb_xinerama"
1244     echo "    Xrandr.....................: $have_ecore_x_xcb_randr"
1245     echo "    Xscreensaver...............: $have_ecore_x_xcb_screensaver"
1246     echo "    Xshape.....................: $have_ecore_x_xcb_shape"
1247     echo "    Xsync......................: $have_ecore_x_xcb_sync"
1248     echo "    Xrender....................: $have_ecore_x_xcb_render"
1249     echo "    Xcomposite.................: $have_ecore_x_xcb_composite"
1250     echo "    Xfixes.....................: $have_ecore_x_xcb_xfixes"
1251     echo "    Xdamage....................: $have_ecore_x_xcb_damage"
1252     echo "    Xdpms......................: $have_ecore_x_xcb_dpms"
1253     echo "    Xtest......................: $have_ecore_x_xcb_xtest"
1254   else
1255     echo "  Ecore_X (Xlib backend).......: $have_ecore_x"
1256     echo "    Xcursor....................: $use_Xcursor"
1257     echo "    Xkb........................: $use_xkb"
1258     echo "    Xprint.....................: $use_xprint"
1259     echo "    Xinerama...................: $use_xinerama"
1260     echo "    Xrandr.....................: $use_xrandr"
1261     echo "    Xscreensaver...............: $use_xss"
1262     echo "    Xrender....................: $use_xrender"
1263     echo "    Xcomposite.................: $use_xcomposite"
1264     echo "    Xfixes.....................: $use_xfixes"
1265     echo "    Xdamage....................: $use_xdamage"
1266     echo "    Xdpms......................: $use_xdpms"
1267     echo "    Xtest......................: $use_xtest"
1268     echo "    XIM........................: $want_xim"
1269     echo "    Xi2........................: $use_xi2"
1270   fi
1271 else
1272   echo "  Ecore_X......................: $have_ecore_x"
1273 fi
1274 echo "  Ecore_Win32..................: $have_ecore_win32"
1275 echo "  Ecore_Quartz.................: $have_ecore_quartz"
1276 echo "  Ecore_SDL....................: $have_ecore_sdl"
1277 echo "  Ecore_FB.....................: $have_ecore_fb"
1278 if test "x${have_ecore_fb}" = "xyes" ; then
1279   echo "    Touchscreen................: $have_tslib"
1280 fi
1281 echo "  Ecore_DirectFB...............: $have_ecore_directfb"
1282 echo "  Ecore_WinCE..................: $have_ecore_wince"
1283
1284 echo
1285 echo " Ecore Evas:"
1286 echo
1287
1288 echo "  Ecore_Evas...................: $have_ecore_evas"
1289 if test "x${have_ecore_evas}" = "xyes" ; then
1290   echo "    Software Memory Buffer.....: $have_ecore_evas_software_buffer"
1291   if test "x${have_ecore_evas_software_x11}" = "xyes" ; then
1292     echo "    Software X11...............: $have_ecore_evas_software_x11 (Xlib=${have_ecore_evas_software_xlib}) (XCB=${have_ecore_evas_software_xcb})"
1293   else
1294     echo "    Software X11...............: $have_ecore_evas_software_x11"
1295   fi
1296   echo "    XRender X11................: $have_ecore_evas_xrender_x11"
1297   echo "    OpenGL X11.................: $have_ecore_evas_opengl_x11"
1298   echo "    XRender XCB................: $have_ecore_evas_xrender_xcb"
1299   echo "    Software GDI...............: $have_ecore_evas_software_gdi"
1300   echo "    Software DirectDraw........: $have_ecore_evas_software_ddraw"
1301   echo "    Direct3D...................: $have_ecore_evas_direct3d"
1302   echo "    OpenGL Glew................: $have_ecore_evas_opengl_glew"
1303   echo "    Quartz.....................: $have_ecore_evas_quartz"
1304   echo "    Software SDL...............: $have_ecore_evas_software_sdl"
1305   echo "    DirectFB...................: $have_ecore_evas_directfb"
1306   echo "    Software Framebuffer.......: $have_ecore_evas_fb"
1307   echo "    Software 16bit X11.........: $have_ecore_evas_software_16_x11"
1308   echo "    Software 16bit DirectDraw..: $have_ecore_evas_software_16_ddraw"
1309   echo "    Software 16bit WinCE.......: $have_ecore_evas_software_16_wince"
1310 fi
1311 echo
1312 echo " Documentation.................: ${build_doc}"
1313 echo
1314 echo " Compilation...................: make (or gmake)"
1315 if test "x${build_doc}" = "xyes" ; then
1316    echo " Build of the documentation....: make doc"
1317 fi
1318 echo
1319 echo " Installation..................: make install"
1320 echo
1321 echo "    prefix.....................: $prefix"
1322 echo
1323
1324 echo
1325 echo "Compilation............: make (or gmake)"
1326 echo "  CPPFLAGS.............: $CPPFLAGS"
1327 echo "  CFLAGS...............: $CFLAGS"
1328 echo "  CXXFLAGS.............: $CXXFLAGS"
1329 echo "  LDFLAGS..............: $LDFLAGS"
1330 echo
1331 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
1332 echo "  prefix...............: $prefix"
1333 echo