configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [1])
   4 m4_define([v_min], [0])
   5 m4_define([v_mic], [0])
   6 m4_define([v_rev], m4_esyscmd([(svnversion "${SVN_REPO_PATH:-.}" | grep -v export || echo 0) | awk -F : '{printf("%s\n", $1);}' | tr -d ' :MSP\n']))
   7 m4_if(v_rev, [0], [m4_define([v_rev], m4_esyscmd([git log 2> /dev/null | (grep -m1 git-svn-id || echo 0) | sed -e 's/.*@\([0-9]*\).*/\1/' | tr -d '\n']))])
   8 ##--   When released, remove the dnl on the below line
   9 m4_undefine([v_rev])
  10 ##--   When doing snapshots - change soname. remove dnl on below line
  11 dnl m4_define([relname], [ver-pre-svn-07])
  12 dnl m4_define([v_rel], [-release relname])
  13 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  14 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])], [m4_define([v_ver], [v_maj.v_min.v_mic])])
  15 m4_define([lt_rev], m4_eval(v_maj + v_min))
  16 m4_define([lt_cur], v_mic)
  17 m4_define([lt_age], v_min)
  18 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  19 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  20
  21 AC_INIT([eina], [v_ver.beta], [enlightenment-devel@lists.sourceforge.net])
  22 AC_PREREQ([2.59])
  23 AC_CONFIG_SRCDIR([configure.ac])
  24 AC_CONFIG_MACRO_DIR([m4])
  25 AC_CANONICAL_BUILD
  26 AC_CANONICAL_HOST
  27 AC_ISC_POSIX
  28 AC_GNU_SOURCE
  29
  30 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  31 AM_CONFIG_HEADER([config.h])
  32 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  33
  34 AC_LIBTOOL_WIN32_DLL
  35 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  36 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  37 AC_PROG_LIBTOOL
  38
  39 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  40 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  41 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  42 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  43 AC_DEFINE_UNQUOTED(VMAJ, [v_maj], [Major version])
  44 AC_DEFINE_UNQUOTED(VMIN, [v_min], [Minor version])
  45 AC_DEFINE_UNQUOTED(VMIC, [v_mic], [Micro version])
  46 AC_DEFINE_UNQUOTED(VREV, [v_rev], [Revison])
  47 version_info="lt_rev:lt_cur:lt_age"
  48 release_info="v_rel"
  49 AC_SUBST(version_info)
  50 AC_SUBST(release_info)
  51 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  52 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  53 VMAJ=v_maj
  54 AC_SUBST(VMAJ)
  55
  56 ### Needed information
  57
  58 requirement_eina=""
  59
  60 case "$host_os" in
  61    mingw32ce*)
  62       MODULE_ARCH="$host_os-$host_cpu"
  63       ;;
  64    *)
  65       MODULE_ARCH="$host_os-$host_cpu-v_maj.v_min.v_mic"
  66       ;;
  67 esac
  68 AC_SUBST(MODULE_ARCH)
  69 AC_DEFINE_UNQUOTED(MODULE_ARCH, "${MODULE_ARCH}", "Module architecture")
  70
  71 case "$host_os" in
  72    mingw*)
  73       MODULE_EXT=".dll"
  74       ;;
  75    *)
  76       MODULE_EXT=".so"
  77       ;;
  78 esac
  79
  80 AC_DEFINE_UNQUOTED(SHARED_LIB_SUFFIX, "${MODULE_EXT}", [Suffix for shared objects])
  81
  82 EFL_CHECK_CPU_MMX([have_mmx="yes"], [have_mmx="no"])
  83 EFL_CHECK_CPU_SSE([have_sse="yes"], [have_sse="no"])
  84 EFL_CHECK_CPU_SSE2([have_sse2="yes"], [have_sse2="no"])
  85 EFL_CHECK_CPU_ALTIVEC([have_altivec="yes"], [have_altivec="no"])
  86
  87 EFL_CHECK_THREADS(
  88    [
  89     if test "x${_efl_have_posix_threads}" = "xyes" ; then
  90        have_threads="POSIX"
  91     else
  92        if test "x${_efl_have_win32_threads}" = "xyes" ; then
  93           have_threads="Win32"
  94        else
  95           have_threads="no"
  96        fi
  97     fi
  98    ],
  99    [have_threads="no"])
 100 EFL_CHECK_SPINLOCK([have_posix_threads_spinlock="yes"], [have_posix_threads_spinlock="no"])
 101
 102 ### Additional options to configure
 103
 104 # Magic debug
 105 AC_ARG_ENABLE([magic-debug],
 106    [AC_HELP_STRING([--disable-magic-debug], [disable magic debug of eina structure @<:@default=enabled@:>@])],
 107    [
 108     if test "x${enableval}" = "xyes" ; then
 109        have_magic_debug="yes"
 110     else
 111        have_magic_debug="no"
 112     fi
 113    ],
 114    [have_magic_debug="yes"])
 115
 116 AC_MSG_CHECKING([whether magic debug is enable])
 117 AC_MSG_RESULT([${have_magic_debug}])
 118
 119 if test "x${have_magic_debug}" = "xyes" ; then
 120    EINA_CONFIGURE_MAGIC_DEBUG="#define EINA_MAGIC_DEBUG"
 121 fi
 122 AC_SUBST(EINA_CONFIGURE_MAGIC_DEBUG)
 123
 124 # Valgrind
 125 want_valgrind="no"
 126
 127 AC_MSG_CHECKING(whether to enable build with valgrind)
 128 AC_ARG_ENABLE(valgrind,
 129   AC_HELP_STRING([--enable-valgrind], [enable valgrind fixes to stop false reports]),
 130   [want_valgrind=$enableval]
 131 )
 132 AC_MSG_RESULT($want_valgrind)
 133
 134 if test x$want_valgrind = "xyes"; then
 135     PKG_CHECK_MODULES(VALGRIND, valgrind >= 2.4.0,
 136         [
 137          requirement_eina="valgrind ${requirement_eina}"
 138         ],
 139         [
 140          AC_DEFINE(NVALGRIND, 1, [Valgrind support disabled])
 141          if test "x$want_valgrind" = "xyes"; then
 142             AC_MSG_ERROR([Valgrind >= 2.4.0 is required)])
 143          fi
 144         ]
 145     )
 146 else
 147     AC_DEFINE(NVALGRIND, 1, [Valgrind support disabled])
 148 fi
 149
 150 # Safety checks (avoid crashes on wrong api usage)
 151 AC_ARG_ENABLE(safety-checks,
 152    [AC_HELP_STRING([--disable-safety-checks], [disable safety checks for NULL pointers and like. @<:@default=enabled@:>@])],
 153    [
 154     if test "x${enableval}" = "xyes" ; then
 155        have_safety_checks="yes"
 156     else
 157        have_safety_checks="no"
 158     fi
 159    ],
 160    [have_safety_checks="yes"])
 161
 162 AC_MSG_CHECKING(whether to do safety checking on api parameters)
 163 AC_MSG_RESULT($have_safety_checks)
 164
 165 AM_CONDITIONAL(SAFETY_CHECKS, test "x$have_safety_checks" = "xyes")
 166 if test "x$have_safety_checks" = "xyes"; then
 167   AC_DEFINE(EINA_SAFETY_CHECKS, 1, [disable safety checks for NULL pointers and like.])
 168   EINA_CONFIGURE_SAFETY_CHECKS="#define EINA_SAFETY_CHECKS"
 169 fi
 170 AC_SUBST(EINA_CONFIGURE_SAFETY_CHECKS)
 171
 172 with_max_log_level="<unset>"
 173 AC_ARG_WITH(internal-maximum-log-level,
 174    [AC_HELP_STRING([--with-internal-maximum-log-level=NUMBER],
 175                    [limit eina internal log level to the given number, any call to EINA_LOG() with values greater than this will be compiled out, ignoring runtime settings, but saving function calls.])],
 176    [
 177     if test "x${withval}" != "xno"; then
 178        if echo "${withval}" | grep '^[[0-9]]\+$' >/dev/null 2>/dev/null; then
 179           AC_MSG_NOTICE([ignoring any EINA_LOG() with level greater than ${withval}])
 180           AC_DEFINE_UNQUOTED(EINA_LOG_LEVEL_MAXIMUM, ${withval}, [if set, logging is limited to this amount.])
 181           with_max_log_level="${withval}"
 182        else
 183           AC_MSG_ERROR([--with-internal-maximum-log-level takes a decimal number, got "${withval}" instead.])
 184        fi
 185     fi
 186     ], [:])
 187
 188 AC_ARG_ENABLE([amalgamation],
 189    [AC_HELP_STRING([--enable-amalgamation], [enable generation of one single file with all source code in it, helps compiler optimizations.])],
 190    [if test "x${enableval}" = "xyes"; then
 191        do_amalgamation="yes"
 192     else
 193        do_amalgamation="no"
 194     fi
 195    ],
 196    [do_amalgamation="no"]
 197 )
 198 AM_CONDITIONAL(EINA_AMALGAMATION, test "x${do_amalgamation}" = "xyes")
 199
 200 # Choose best memory pool
 201 AC_ARG_ENABLE([default-mempool],
 202    [AC_HELP_STRING([--enable-default-mempool], [Default memory allocator could be faster for some computer. @<:@default=disabled@:>@])],
 203    [
 204     if test "x${enableval}" = "xyes"; then
 205        have_default_mempool="yes"
 206     else
 207        have_default_mempool="no"
 208     fi
 209    ],
 210    [have_default_mempool="no"]
 211 )
 212 AC_MSG_CHECKING([whether to use default mempool allocator])
 213 AC_MSG_RESULT([${have_default_mempool}])
 214
 215 if test "x${have_default_mempool}" = "xyes" ; then
 216    EINA_CONFIGURE_DEFAULT_MEMPOOL="#define EINA_DEFAULT_MEMPOOL"
 217 fi
 218 AC_SUBST(EINA_CONFIGURE_DEFAULT_MEMPOOL)
 219
 220 # Report stringshare usage
 221 AC_ARG_ENABLE([stringshare-usage],
 222    [AC_HELP_STRING([--enable-stringshare-usage], [Report stringshare usage on stringshare shutdown. @<:@default=disabled@:>@])],
 223    [
 224     if test "x${enableval}" = "xyes"; then
 225        have_stringshare_usage="yes"
 226     else
 227        have_stringshare_usage="no"
 228     fi
 229    ],
 230    [have_stringshare_usage="no"]
 231 )
 232 AC_MSG_CHECKING([whether to report stringshare usage])
 233 AC_MSG_RESULT([${have_stringshare_usage}])
 234
 235 if test "x${have_stringshare_usage}" = "xyes"; then
 236    AC_DEFINE(EINA_STRINGSHARE_USAGE, 1, [Report Eina stringshare usage pattern])
 237 fi
 238
 239 # Check if we want to benchmark on real data
 240 enable_benchmark_e17="no"
 241 AC_ARG_ENABLE([e17],
 242    [AC_HELP_STRING([--enable-e17], [enable heavy benchmark @<:@default=no@:>@])],
 243    [
 244     if test "x${enableval}" = "xyes" ; then
 245        enable_benchmark_e17="yes"
 246     else
 247        enable_benchmark_e17="no"
 248     fi
 249    ],
 250    [enable_benchmark_e17="no"])
 251
 252 AC_MSG_CHECKING([whether e17 real data benchmark are built])
 253 AC_MSG_RESULT([${enable_benchmark_e17}])
 254
 255 AM_CONDITIONAL(EINA_ENABLE_BENCHMARK_E17, test "x${enable_benchmark_e17}" = "xyes")
 256
 257
 258 ### Checks for programs
 259 AC_PROG_CC
 260
 261 # pkg-config
 262 PKG_PROG_PKG_CONFIG
 263
 264 # Check whether pkg-config supports Requires.private
 265 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
 266    pkgconfig_requires_private="Requires.private"
 267 else
 268    pkgconfig_requires_private="Requires"
 269 fi
 270 AC_SUBST(pkgconfig_requires_private)
 271
 272 # doxygen program for documentation building
 273
 274 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 275
 276
 277 ### Checks for libraries
 278
 279 # Evil library for compilation on Windows CE
 280
 281 EFL_EINA_BUILD=""
 282 case "$host_os" in
 283    mingw*)
 284       PKG_CHECK_MODULES([EVIL], [evil])
 285       AC_DEFINE(HAVE_EVIL, 1, [Set to 1 if evil package is installed])
 286       requirement_eina="evil"
 287       EFL_EINA_BUILD="-DEFL_EINA_BUILD"
 288    ;;
 289 esac
 290 AC_SUBST(EFL_EINA_BUILD)
 291
 292 # Check ememoa memory pool library
 293
 294 AC_ARG_ENABLE([ememoa],
 295    [AC_HELP_STRING([--enable-ememoa], [build ememoa memory pool module @<:@default=yes@:>@])],
 296    [
 297     if test "x${enableval}" = "xyes" ; then
 298        enable_ememoa="yes"
 299     else
 300        enable_ememoa="no"
 301     fi
 302    ],
 303    [enable_ememoa="yes"]
 304 )
 305 AC_MSG_CHECKING([whether to use ememoa for memory pool])
 306 AC_MSG_RESULT([$enable_ememoa])
 307
 308 if test "x${enable_ememoa}" = "xyes" ; then
 309    PKG_CHECK_MODULES([EMEMOA],
 310       [ememoa >= 0.0.26 ],
 311       [enable_ememoa="yes"],
 312       [enable_ememoa="no"]
 313    )
 314 fi
 315
 316
 317 ### Checks for header files
 318 AC_HEADER_ASSERT
 319 AC_HEADER_DIRENT
 320 AC_HEADER_TIME
 321
 322
 323 ### Checks for types
 324 AC_CHECK_HEADER([inttypes.h],
 325                 [EINA_CONFIGURE_HAVE_INTTYPES_H="#define EINA_HAVE_INTTYPES_H"])
 326 AC_SUBST(EINA_CONFIGURE_HAVE_INTTYPES_H)
 327
 328 AC_CHECK_HEADER([stdint.h],
 329                 [EINA_CONFIGURE_HAVE_STDINT_H="#define EINA_HAVE_STDINT_H"])
 330 AC_SUBST(EINA_CONFIGURE_HAVE_STDINT_H)
 331
 332 AC_CHECK_SIZEOF(wchar_t)
 333 EINA_SIZEOF_WCHAR_T=$ac_cv_sizeof_wchar_t
 334 AC_SUBST(EINA_SIZEOF_WCHAR_T)
 335
 336 ### Checks for structures
 337
 338
 339 ### Checks for compiler characteristics
 340 AC_C_CONST
 341 AC_C_BIGENDIAN
 342 AC_C_INLINE
 343 AC_C___ATTRIBUTE__
 344 AC_PROG_CC_STDC
 345
 346 EINA_CPPFLAGS=""
 347 EINA_CFLAGS=""
 348 case "$host_os" in
 349    mingw32ce*)
 350       EINA_CPPFLAGS="-D_WIN32_WCE=0x0420"
 351       EINA_CFLAGS="${EVIL_CFLAGS}"
 352       ;;
 353    mingw*)
 354       EINA_CPPFLAGS="-D_WIN32_WINNT=0x0501"
 355       EINA_CFLAGS="${EVIL_CFLAGS}"
 356       ;;
 357 esac
 358
 359 m4_ifdef([v_mic],
 360    [
 361     EFL_COMPILER_FLAG([-Wall])
 362     EFL_COMPILER_FLAG([-W])
 363    ])
 364
 365 EFL_COMPILER_FLAG([-Wshadow])
 366
 367 AC_SUBST(EINA_CPPFLAGS)
 368 AC_SUBST(EINA_CFLAGS)
 369
 370
 371 ### Checks for linker characteristics
 372 EINA_LIBS=
 373 lt_enable_auto_import=""
 374 case "${host_os}" in
 375    mingw*)
 376       EINA_LIBS="-ldl ${EVIL_LIBS} -lm"
 377       lt_enable_auto_import="-Wl,--enable-auto-import"
 378    ;;
 379    dragonfly*|openbsd*)
 380       EINA_LIBS="-lm"
 381    ;;
 382    freebsd*|netbsd*)
 383       EINA_LIBS="-lrt -lm"
 384    ;;
 385    darwin*)
 386       EINA_LIBS="-lm"
 387    ;;
 388    cygwin*)
 389       EINA_LIBS="-ldl -lm"
 390    ;;
 391    *)
 392       EINA_LIBS="-ldl -lrt -lm"
 393    ;;
 394 esac
 395 AC_SUBST(EINA_LIBS)
 396 AC_SUBST(lt_enable_auto_import)
 397
 398 EFL_LINKER_FLAG([-fno-strict-aliasing])
 399
 400
 401 ### Checks for library functions
 402 AC_FUNC_ALLOCA
 403 AC_CHECK_FUNCS(strlcpy)
 404
 405 #dlopen and dladdr
 406 dlopen_libs=""
 407 case "$host_os" in
 408    mingw*)
 409 # managed by evil
 410       AC_DEFINE(HAVE_DLADDR)
 411       ;;
 412    *)
 413       AC_CHECK_FUNCS([dlopen], [res="yes"], [res="no"])
 414       if test "x${res}" = "xyes" ; then
 415          AC_CHECK_FUNCS([dladdr], [AC_DEFINE(HAVE_DLADDR)])
 416       else
 417          AC_CHECK_LIB([dl], [dlopen], [res="yes"], [res="no"])
 418          if test "x${res}" = "xyes" ; then
 419             AC_CHECK_LIB([dl], [dladdr], [AC_DEFINE(HAVE_DLADDR)])
 420             dlopen_libs="-ldl"
 421          else
 422             AC_MSG_ERROR([Cannot find dlopen])
 423          fi
 424       fi
 425       ;;
 426 esac
 427 AC_SUBST(dlopen_libs)
 428
 429 EFL_CHECK_FNMATCH([], [AC_MSG_ERROR([Cannot find fnmatch()])])
 430
 431 # iconv library
 432 have_iconv="no"
 433 AC_ARG_WITH([iconv-link],
 434    AC_HELP_STRING([--with-iconv-link=ICONV_LINK], [explicitly specify an iconv link option]),
 435    [
 436     LIBS="$withval $LIBS"
 437     have_iconv="yes"
 438    ])
 439
 440 AC_MSG_CHECKING(for explicit iconv link options)
 441 if test "x${iconv_libs}" = "x" ; then
 442    AC_MSG_RESULT([no explicit iconv link option])
 443 else
 444    AC_MSG_RESULT([$iconv_libs])
 445 fi
 446
 447 if test "x${have_iconv}" = "xno" ; then
 448    AC_CHECK_HEADERS([iconv.h], [have_iconv="yes"])
 449
 450    if test "x${have_iconv}" = "xyes" ; then
 451       AC_MSG_CHECKING([whether iconv() is in libc])
 452
 453       AC_LINK_IFELSE(
 454          [AC_LANG_PROGRAM(
 455              [[
 456 #include <stdlib.h>
 457 #include <iconv.h>
 458              ]],
 459              [[
 460 iconv_t ic;
 461 size_t count = iconv(ic, NULL, NULL, NULL, NULL);
 462              ]])],
 463          [have_iconv="yes"],
 464          [have_iconv="no"])
 465
 466       AC_MSG_RESULT([${have_iconv}])
 467    fi
 468
 469    if test "x${have_iconv}" = "xno" ; then
 470       AC_MSG_CHECKING([whether iconv() is in libiconv.a])
 471
 472       LIBS_save="${LIBS}"
 473       LIBS="-liconv $LIBS"
 474       AC_LINK_IFELSE(
 475          [AC_LANG_PROGRAM(
 476              [[
 477 #include <stdlib.h>
 478 #include <iconv.h>
 479              ]],
 480              [[
 481 iconv_t ic;
 482 size_t count;
 483 count = iconv(ic, NULL, NULL, NULL, NULL);
 484              ]])],
 485          [have_iconv="yes"],
 486          [
 487           have_iconv="no"
 488           LIBS=${LIBS_save}
 489          ])
 490
 491       AC_MSG_RESULT([${have_iconv}])
 492    fi
 493
 494    if test "x${have_iconv}" = "xno" ; then
 495       AC_MSG_CHECKING([whether iconv() is in libiconv_plug.a])
 496
 497       LIBS_save="${LIBS}"
 498       LIBS="-liconv_plug $LIBS"
 499       AC_LINK_IFELSE(
 500          [AC_LANG_PROGRAM(
 501              [[
 502 #include <stdlib.h>
 503 #include <iconv.h>
 504              ]],
 505              [[
 506 iconv_t ic;
 507 size_t count = iconv(ic, NULL, NULL, NULL, NULL);
 508              ]])],
 509          [have_iconv="yes"],
 510          [
 511           have_iconv="no"
 512           LIBS=${LIBS_save}
 513          ])
 514
 515       AC_MSG_RESULT([${have_iconv}])
 516    fi
 517 fi
 518
 519 if test "x${have_iconv}" = "xyes" ; then
 520    AC_DEFINE([HAVE_ICONV], [1], [Set to 1 if iconv library is installed])
 521 fi
 522
 523
 524 ### Modules
 525
 526 if test "x${have_default_mempool}" = "xyes" ; then
 527    enable_chained_pool="no"
 528    enable_pass_through="static"
 529 else
 530    enable_chained_pool="static"
 531    enable_pass_through="no"
 532 fi
 533
 534 enable_one_big="static"
 535
 536 EINA_CHECK_MODULE([chained-pool],   [${enable_chained_pool}], [chained pool])
 537 EINA_CHECK_MODULE([ememoa-fixed],   [${enable_ememoa}],       [ememoa fixed])
 538 EINA_CHECK_MODULE([ememoa-unknown], [${enable_ememoa}],       [ememoa unknown])
 539 EINA_CHECK_MODULE([fixed-bitmap],   [no],                     [fixed bitmap])
 540 EINA_CHECK_MODULE([pass-through],   [${enable_pass_through}], [pass through])
 541 EINA_CHECK_MODULE([buddy],          [no],                     [buddy])
 542 EINA_CHECK_MODULE([one-big],        [${enable_one_big}],      [one big])
 543
 544 ### Make the debug preprocessor configurable
 545
 546 ### Unit tests, coverage and benchmarking
 547
 548 EFL_CHECK_TESTS([enable_tests="yes"], [enable_tests="no"])
 549
 550 EFL_CHECK_COVERAGE([${enable_tests}], [enable_coverage="yes"], [enable_coverage="no"])
 551 EINA_CFLAGS="${EINA_CFLAGS} ${EFL_COVERAGE_CFLAGS}"
 552 EINA_LIBS="${EINA_LIBS} ${EFL_COVERAGE_LIBS}"
 553 if test "x$enable_coverage" = "xyes" ; then
 554    EINA_CFLAGS="${EINA_CFLAGS} ${EFL_DEBUG_CFLAGS}"
 555 fi
 556
 557 EFL_CHECK_BENCHMARK([enable_benchmark="yes"], [enable_benchmark="no"])
 558 EINA_BENCH_MODULE([glib], [${enable_benchmark}], [glib-2.0], [enable_benchmark_glib="yes"], [enable_benchmark_glib="no"])
 559
 560 AC_SUBST(requirement_eina)
 561
 562 ### Create the .pc.in file according to the major version
 563 #cat > ${srcdir}/eina-${VMAJ}.pc.in << EOF
 564 #prefix=@prefix@
 565 #exec_prefix=@exec_prefix@
 566 #libdir=@libdir@
 567 #includedir=@includedir@
 568 #
 569 #Name: Eina
 570 #Description: A Library that implements fast data types and miscellaneous tools
 571 #Requires:
 572 #Version: @VERSION@
 573 #Libs: -L${libdir} -leina
 574 #Libs.private: -ldl
 575 #Cflags: -I${includedir}/eina-@VMAJ@ -I${includedir}/eina-@VMAJ@/eina
 576 #EOF
 577
 578 AC_CONFIG_FILES([
 579 Makefile
 580 eina.pc
 581 eina.spec
 582 doc/Makefile
 583 src/Makefile
 584 src/include/Makefile
 585 src/include/eina_config.h
 586 src/lib/Makefile
 587 src/modules/Makefile
 588 src/modules/mp/Makefile
 589 src/modules/mp/chained_pool/Makefile
 590 src/modules/mp/ememoa_fixed/Makefile
 591 src/modules/mp/ememoa_unknown/Makefile
 592 src/modules/mp/pass_through/Makefile
 593 src/modules/mp/fixed_bitmap/Makefile
 594 src/modules/mp/buddy/Makefile
 595 src/modules/mp/one_big/Makefile
 596 src/tests/Makefile
 597 ])
 598
 599 AC_OUTPUT
 600
 601 #####################################################################
 602 ## Info
 603
 604 echo
 605 echo
 606 echo
 607 echo "------------------------------------------------------------------------"
 608 echo "$PACKAGE $VERSION"
 609 echo "------------------------------------------------------------------------"
 610 echo
 611 echo
 612 echo "Configuration Options Summary:"
 613 echo
 614 echo "  Magic debug..........: ${have_magic_debug}"
 615 echo "  Safety checks........: ${have_safety_checks}"
 616 echo "  Maximum log level....: ${with_max_log_level}"
 617 echo "  Report string usage..: ${have_stringshare_usage}"
 618 echo "  Default mempool......: ${have_default_mempool}"
 619 echo "  Thread Support.......: ${have_threads}"
 620 if test "${have_threads}" = "POSIX" ; then
 621 echo "    spinlock...........: ${have_posix_threads_spinlock}"
 622 echo "    debug usage........: ${have_debug_threads}"
 623 fi
 624 echo "  Amalgamation.........: ${do_amalgamation}"
 625 echo "  Iconv support........: ${have_iconv}"
 626 echo
 627 echo "  Documentation........: ${build_doc}"
 628 echo "  Tests................: ${enable_tests}"
 629 echo "  Coverage.............: ${enable_coverage}"
 630 echo "  Benchmark............: ${enable_benchmark}"
 631 if test "x${enable_benchmark}" = "xyes" ; then
 632 echo "    Glib...............: ${enable_benchmark_glib}"
 633 echo "    E17 real data......: ${enable_benchmark_e17}"
 634 fi
 635 echo
 636 echo "  CPU Specific Extensions:"
 637 echo "    MMX................: ${have_mmx}"
 638 echo "    SSE................: ${have_sse}"
 639 echo "    SSE2...............: ${have_sse2}"
 640 echo "    ALTIVEC............: ${have_altivec}"
 641 echo
 642 echo "  Memory pools:"
 643 echo "    Chained pool.......: ${enable_chained_pool}"
 644 echo "    Ememoa fixed.......: ${enable_ememoa_fixed}"
 645 echo "    Ememoa unknown.....: ${enable_ememoa_unknown}"
 646 echo "    Fixed bitmap.......: ${enable_fixed_bitmap}"
 647 echo "    Pass through.......: ${enable_pass_through}"
 648 echo "    Buddy..............: ${enable_buddy}"
 649 echo "    One big............: ${enable_one_big}"
 650 echo
 651 echo "Compilation............: make (or gmake)"
 652 echo "  CPPFLAGS.............: $CPPFLAGS"
 653 echo "  CFLAGS...............: $CFLAGS"
 654 echo "  LDFLAGS..............: $LDFLAGS"
 655 echo
 656 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
 657 echo "  prefix...............: $prefix"
 658 echo
 659 EFL_FORM_VOLTRON