configure.ac

   1 AC_PREREQ([2.67])
   2 AC_INIT([cryptsetup],[1.6.2-git])
   3
   4 dnl library version from <major>.<minor>.<release>[-<suffix>]
   5 LIBCRYPTSETUP_VERSION=$(echo $PACKAGE_VERSION | cut -f1 -d-)
   6 LIBCRYPTSETUP_VERSION_INFO=9:0:5
   7 dnl library file name for FIPS selfcheck
   8 LIBCRYPTSETUP_VERSION_FIPS="libcryptsetup.so.4"
   9
  10 AC_CONFIG_SRCDIR(src/cryptsetup.c)
  11 AC_CONFIG_MACRO_DIR([m4])
  12
  13 AC_CONFIG_HEADERS([config.h:config.h.in])
  14
  15 # We do not want to run test in parallel. Really.
  16 # http://lists.gnu.org/archive/html/automake/2013-01/msg00060.html
  17
  18 # For old automake use this
  19 #AM_INIT_AUTOMAKE(dist-bzip2)
  20 AM_INIT_AUTOMAKE([dist-bzip2 1.12 serial-tests])
  21
  22 if test "x$prefix" = "xNONE"; then
  23         sysconfdir=/etc
  24 fi
  25 AC_PREFIX_DEFAULT(/usr)
  26
  27 AC_CANONICAL_HOST
  28 AC_USE_SYSTEM_EXTENSIONS
  29 AC_PROG_CC
  30 AM_PROG_CC_C_O
  31 AC_PROG_CPP
  32 AC_PROG_INSTALL
  33 AC_PROG_MAKE_SET
  34 AC_ENABLE_STATIC(no)
  35 LT_INIT
  36 PKG_PROG_PKG_CONFIG
  37
  38 AC_HEADER_DIRENT
  39 AC_HEADER_STDC
  40 AC_CHECK_HEADERS(fcntl.h malloc.h inttypes.h sys/ioctl.h sys/mman.h \
  41         ctype.h unistd.h locale.h byteswap.h endian.h)
  42
  43 AC_CHECK_HEADERS(uuid/uuid.h,,[AC_MSG_ERROR([You need the uuid library.])])
  44 AC_CHECK_HEADER(libdevmapper.h,,[AC_MSG_ERROR([You need the device-mapper library.])])
  45
  46 saved_LIBS=$LIBS
  47 AC_CHECK_LIB(uuid, uuid_clear, ,[AC_MSG_ERROR([You need the uuid library.])])
  48 AC_SUBST(UUID_LIBS, $LIBS)
  49 LIBS=$saved_LIBS
  50
  51 AC_CHECK_FUNCS([posix_memalign])
  52
  53 AC_C_CONST
  54 AC_C_BIGENDIAN
  55 AC_TYPE_OFF_T
  56 AC_SYS_LARGEFILE
  57
  58 AC_PROG_GCC_TRADITIONAL
  59
  60 dnl ==========================================================================
  61
  62 AM_GNU_GETTEXT([external],[need-ngettext])
  63 AM_GNU_GETTEXT_VERSION([0.15])
  64
  65 dnl ==========================================================================
  66
  67 saved_LIBS=$LIBS
  68 AC_CHECK_LIB(popt, poptConfigFileToString,,
  69         [AC_MSG_ERROR([You need popt 1.7 or newer to compile.])])
  70 AC_SUBST(POPT_LIBS, $LIBS)
  71 LIBS=$saved_LIBS
  72
  73 dnl ==========================================================================
  74 dnl FIPS extensions
  75 AC_ARG_ENABLE([fips], AS_HELP_STRING([--enable-fips],[enable FIPS mode restrictions]),
  76 [with_fips=$enableval],
  77 [with_fips=no])
  78
  79 if test "x$with_fips" = "xyes"; then
  80         AC_DEFINE(ENABLE_FIPS, 1, [Enable FIPS mode restrictions])
  81         AC_DEFINE_UNQUOTED(LIBCRYPTSETUP_VERSION_FIPS, ["$LIBCRYPTSETUP_VERSION_FIPS"],
  82                 [library file name for FIPS selfcheck])
  83
  84         if test "x$enable_static" = "xyes" -o "x$enable_static_cryptsetup" = "xyes" ; then
  85                 AC_MSG_ERROR([Static build is not compatible with FIPS.])
  86         fi
  87
  88         saved_LIBS=$LIBS
  89         AC_CHECK_LIB(fipscheck, FIPSCHECK_verify, ,[AC_MSG_ERROR([You need the fipscheck library.])])
  90         AC_SUBST(FIPSCHECK_LIBS, $LIBS)
  91         LIBS=$saved_LIBS
  92
  93 fi
  94
  95 AC_DEFUN([NO_FIPS], [
  96         if test "x$with_fips" = "xyes"; then
  97                 AC_MSG_ERROR([This option is not compatible with FIPS.])
  98         fi
  99 ])
 100
 101 dnl ==========================================================================
 102 dnl pwquality library (cryptsetup CLI only)
 103 AC_ARG_ENABLE([pwquality], AS_HELP_STRING([--enable-pwquality],[enable password quality checking]),
 104 [with_pwquality=$enableval],
 105 [with_pwquality=no])
 106
 107 if test "x$with_pwquality" = "xyes"; then
 108         AC_DEFINE(ENABLE_PWQUALITY, 1, [Enable password quality checking])
 109         PKG_CHECK_MODULES([PWQUALITY], [pwquality >= 1.0.0],,
 110                 AC_MSG_ERROR([You need pwquality library.]))
 111
 112         dnl FIXME: this is really hack for now
 113         PWQUALITY_STATIC_LIBS="$PWQUALITY_LIBS -lcrack -lz"
 114 fi
 115
 116 dnl ==========================================================================
 117 dnl Crypto backend functions
 118
 119 AC_DEFUN([CONFIGURE_GCRYPT], [
 120         if test "x$with_fips" = "xyes"; then
 121                 GCRYPT_REQ_VERSION=1.4.5
 122         else
 123                 GCRYPT_REQ_VERSION=1.1.42
 124         fi
 125         dnl Check if we can use gcrypt PBKDF2 (1.6.0 supports empty password)
 126         AC_ARG_ENABLE([gcrypt-pbkdf2], AS_HELP_STRING([--enable-gcrypt-pbkdf2],[force enable internal gcrypt PBKDF2]),
 127                 [use_internal_pbkdf2=0],
 128                 [AM_PATH_LIBGCRYPT([1.6.0], [use_internal_pbkdf2=0], [use_internal_pbkdf2=1])])
 129         AM_PATH_LIBGCRYPT($GCRYPT_REQ_VERSION,,[AC_MSG_ERROR([You need the gcrypt library.])])
 130
 131         if test x$enable_static_cryptsetup = xyes; then
 132                 saved_LIBS=$LIBS
 133                 LIBS="$saved_LIBS $LIBGCRYPT_LIBS -static"
 134                 AC_CHECK_LIB(gcrypt, gcry_check_version,,
 135                         AC_MSG_ERROR([Cannot find static gcrypt library.]),
 136                         [-lgpg-error])
 137                 LIBGCRYPT_STATIC_LIBS="$LIBGCRYPT_LIBS -lgpg-error"
 138                 LIBS=$saved_LIBS
 139         fi
 140
 141         CRYPTO_CFLAGS=$LIBGCRYPT_CFLAGS
 142         CRYPTO_LIBS=$LIBGCRYPT_LIBS
 143         CRYPTO_STATIC_LIBS=$LIBGCRYPT_STATIC_LIBS
 144
 145         AC_DEFINE_UNQUOTED(GCRYPT_REQ_VERSION, ["$GCRYPT_REQ_VERSION"], [Requested gcrypt version])
 146 ])
 147
 148 AC_DEFUN([CONFIGURE_OPENSSL], [
 149         PKG_CHECK_MODULES([OPENSSL], [openssl >= 0.9.8],,
 150                 AC_MSG_ERROR([You need openssl library.]))
 151         CRYPTO_CFLAGS=$OPENSSL_CFLAGS
 152         CRYPTO_LIBS=$OPENSSL_LIBS
 153         use_internal_pbkdf2=0
 154
 155         if test x$enable_static_cryptsetup = xyes; then
 156                 saved_PKG_CONFIG=$PKG_CONFIG
 157                 PKG_CONFIG="$PKG_CONFIG --static"
 158                 PKG_CHECK_MODULES([OPENSSL], [openssl])
 159                 CRYPTO_STATIC_LIBS=$OPENSSL_LIBS
 160                 PKG_CONFIG=$saved_PKG_CONFIG
 161         fi
 162         NO_FIPS([])
 163 ])
 164
 165 AC_DEFUN([CONFIGURE_NSS], [
 166         if test x$enable_static_cryptsetup = xyes; then
 167                 AC_MSG_ERROR([Static build of cryptsetup is not supported with NSS.])
 168         fi
 169
 170         AC_MSG_WARN([NSS backend does NOT provide backward compatibility (missing ripemd160 hash).])
 171
 172         PKG_CHECK_MODULES([NSS], [nss],,
 173                 AC_MSG_ERROR([You need nss library.]))
 174
 175         saved_CFLAGS=$CFLAGS
 176         CFLAGS="$CFLAGS $NSS_CFLAGS"
 177         AC_CHECK_DECLS([NSS_GetVersion], [], [], [#include <nss.h>])
 178         CFLAGS=$saved_CFLAGS
 179
 180         CRYPTO_CFLAGS=$NSS_CFLAGS
 181         CRYPTO_LIBS=$NSS_LIBS
 182         use_internal_pbkdf2=1
 183         NO_FIPS([])
 184 ])
 185
 186 AC_DEFUN([CONFIGURE_KERNEL], [
 187         AC_CHECK_HEADERS(linux/if_alg.h,,
 188                 [AC_MSG_ERROR([You need Linux kernel headers with userspace crypto interface.])])
 189 #       AC_CHECK_DECLS([AF_ALG],,
 190 #               [AC_MSG_ERROR([You need Linux kernel with userspace crypto interface.])],
 191 #               [#include <sys/socket.h>])
 192         use_internal_pbkdf2=1
 193         NO_FIPS([])
 194 ])
 195
 196 AC_DEFUN([CONFIGURE_NETTLE], [
 197         AC_CHECK_HEADERS(nettle/sha.h,,
 198                 [AC_MSG_ERROR([You need Nettle cryptographic library.])])
 199
 200         saved_LIBS=$LIBS
 201         AC_CHECK_LIB(nettle, nettle_ripemd160_init,,
 202                 [AC_MSG_ERROR([You need Nettle library version 2.4 or more recent.])])
 203         CRYPTO_LIBS=$LIBS
 204         LIBS=$saved_LIBS
 205
 206         CRYPTO_STATIC_LIBS=$CRYPTO_LIBS
 207         use_internal_pbkdf2=1
 208         NO_FIPS([])
 209 ])
 210
 211 dnl ==========================================================================
 212 saved_LIBS=$LIBS
 213
 214 AC_ARG_ENABLE([static-cryptsetup],
 215         AS_HELP_STRING([--enable-static-cryptsetup],
 216         [enable build of static cryptsetup binary]))
 217 if test x$enable_static_cryptsetup = xyes; then
 218         if test x$enable_static = xno; then
 219                 AC_MSG_WARN([Requested static cryptsetup build, enabling static library.])
 220                 enable_static=yes
 221         fi
 222 fi
 223 AM_CONDITIONAL(STATIC_TOOLS, test x$enable_static_cryptsetup = xyes)
 224
 225 AC_ARG_ENABLE(veritysetup,
 226         AS_HELP_STRING([--disable-veritysetup],
 227         [disable veritysetup support]),[], [enable_veritysetup=yes])
 228 AM_CONDITIONAL(VERITYSETUP, test x$enable_veritysetup = xyes)
 229
 230 AC_ARG_ENABLE([cryptsetup-reencrypt],
 231         AS_HELP_STRING([--enable-cryptsetup-reencrypt],
 232         [enable cryptsetup-reencrypt tool]))
 233 AM_CONDITIONAL(REENCRYPT, test x$enable_cryptsetup_reencrypt = xyes)
 234
 235 AC_ARG_ENABLE(selinux,
 236         AS_HELP_STRING([--disable-selinux],
 237         [disable selinux support [default=auto]]),[], [])
 238
 239 AC_ARG_ENABLE([udev],
 240         AS_HELP_STRING([--disable-udev],
 241         [disable udev support]),[], enable_udev=yes)
 242
 243 dnl Try to use pkg-config for devmapper, but fallback to old detection
 244 PKG_CHECK_MODULES([DEVMAPPER], [devmapper >= 1.02.03],, [
 245         AC_CHECK_LIB(devmapper, dm_task_set_name,,
 246                 [AC_MSG_ERROR([You need the device-mapper library.])])
 247         AC_CHECK_LIB(devmapper, dm_task_set_message,,
 248                 [AC_MSG_ERROR([The device-mapper library on your system is too old.])])
 249         DEVMAPPER_LIBS=$LIBS
 250 ])
 251 LIBS=$saved_LIBS
 252
 253 LIBS="$LIBS $DEVMAPPER_LIBS"
 254 AC_CHECK_DECLS([dm_task_secure_data], [], [], [#include <libdevmapper.h>])
 255 AC_CHECK_DECLS([dm_task_retry_remove], [], [], [#include <libdevmapper.h>])
 256 AC_CHECK_DECLS([DM_UDEV_DISABLE_DISK_RULES_FLAG], [have_cookie=yes], [have_cookie=no], [#include <libdevmapper.h>])
 257 if test "x$enable_udev" = xyes; then
 258         if test "x$have_cookie" = xno; then
 259                 AC_MSG_WARN([The device-mapper library on your system has no udev support, udev support disabled.])
 260         else
 261                 AC_DEFINE(USE_UDEV, 1, [Try to use udev synchronisation?])
 262         fi
 263 fi
 264 LIBS=$saved_LIBS
 265
 266 dnl Crypto backend configuration.
 267 AC_ARG_WITH([crypto_backend],
 268         AS_HELP_STRING([--with-crypto_backend=BACKEND], [crypto backend (gcrypt/openssl/nss/kernel/nettle) [gcrypt]]),
 269         [], with_crypto_backend=gcrypt
 270 )
 271
 272 dnl Kernel crypto API backend needed for benchmark and tcrypt
 273 AC_ARG_ENABLE([kernel_crypto], AS_HELP_STRING([--disable-kernel_crypto],
 274         [disable kernel userspace crypto (no benchmark and tcrypt)]),
 275         [with_kernel_crypto=$enableval],
 276         [with_kernel_crypto=yes])
 277
 278 if test "x$with_kernel_crypto" = "xyes"; then
 279         AC_CHECK_HEADERS(linux/if_alg.h,,
 280                 [AC_MSG_ERROR([You need Linux kernel headers with userspace crypto interface. (Or use --disable-kernel_crypto.)])])
 281         AC_DEFINE(ENABLE_AF_ALG, 1, [Enable using of kernel userspace crypto])
 282 fi
 283
 284 case $with_crypto_backend in
 285         gcrypt)  CONFIGURE_GCRYPT([]) ;;
 286         openssl) CONFIGURE_OPENSSL([]) ;;
 287         nss)     CONFIGURE_NSS([]) ;;
 288         kernel)  CONFIGURE_KERNEL([]) ;;
 289         nettle)  CONFIGURE_NETTLE([]) ;;
 290         *) AC_MSG_ERROR([Unknown crypto backend.]) ;;
 291 esac
 292 AM_CONDITIONAL(CRYPTO_BACKEND_GCRYPT,  test $with_crypto_backend = gcrypt)
 293 AM_CONDITIONAL(CRYPTO_BACKEND_OPENSSL, test $with_crypto_backend = openssl)
 294 AM_CONDITIONAL(CRYPTO_BACKEND_NSS,     test $with_crypto_backend = nss)
 295 AM_CONDITIONAL(CRYPTO_BACKEND_KERNEL,  test $with_crypto_backend = kernel)
 296 AM_CONDITIONAL(CRYPTO_BACKEND_NETTLE,  test $with_crypto_backend = nettle)
 297
 298 AM_CONDITIONAL(CRYPTO_INTERNAL_PBKDF2, test $use_internal_pbkdf2 = 1)
 299 AC_DEFINE_UNQUOTED(USE_INTERNAL_PBKDF2, [$use_internal_pbkdf2], [Use internal PBKDF2])
 300
 301 dnl Magic for cryptsetup.static build.
 302 if test x$enable_static_cryptsetup = xyes; then
 303         saved_PKG_CONFIG=$PKG_CONFIG
 304         PKG_CONFIG="$PKG_CONFIG --static"
 305
 306         LIBS="$saved_LIBS -static"
 307         AC_CHECK_LIB(popt, poptGetContext,,
 308                 AC_MSG_ERROR([Cannot find static popt library.]))
 309
 310         dnl Try to detect needed device-mapper static libraries, try pkg-config first.
 311         LIBS="$saved_LIBS -static"
 312         PKG_CHECK_MODULES([DEVMAPPER_STATIC], [devmapper >= 1.02.27],,[
 313                 DEVMAPPER_STATIC_LIBS=$DEVMAPPER_LIBS
 314                 if test "x$enable_selinux" != xno; then
 315                         AC_CHECK_LIB(sepol, sepol_bool_set)
 316                         AC_CHECK_LIB(selinux, is_selinux_enabled)
 317                         DEVMAPPER_STATIC_LIBS="$DEVMAPPER_STATIC_LIBS $LIBS"
 318                 fi
 319         ])
 320         LIBS="$saved_LIBS $DEVMAPPER_STATIC_LIBS"
 321         AC_CHECK_LIB(devmapper, dm_task_set_uuid,,
 322                 AC_MSG_ERROR([Cannot link with static device-mapper library.]))
 323
 324         dnl Try to detect uuid static library.
 325         LIBS="$saved_LIBS -static"
 326         AC_CHECK_LIB(uuid, uuid_generate,,
 327                 AC_MSG_ERROR([Cannot find static uuid library.]))
 328
 329         LIBS=$saved_LIBS
 330         PKG_CONFIG=$saved_PKG_CONFIG
 331 fi
 332
 333 AC_SUBST([DEVMAPPER_LIBS])
 334 AC_SUBST([DEVMAPPER_STATIC_LIBS])
 335
 336 AC_SUBST([PWQUALITY_LIBS])
 337 AC_SUBST([PWQUALITY_STATIC_LIBS])
 338
 339 AC_SUBST([CRYPTO_CFLAGS])
 340 AC_SUBST([CRYPTO_LIBS])
 341 AC_SUBST([CRYPTO_STATIC_LIBS])
 342
 343 AC_SUBST([LIBCRYPTSETUP_VERSION])
 344 AC_SUBST([LIBCRYPTSETUP_VERSION_INFO])
 345 AC_SUBST([LIBCRYPTSETUP_VERSION_FIPS])
 346
 347 dnl ==========================================================================
 348 AC_ARG_ENABLE([dev-random], AS_HELP_STRING([--enable-dev-random],
 349 [use blocking /dev/random by default for key generator (otherwise use /dev/urandom)]),
 350 [default_rng=/dev/random], [default_rng=/dev/urandom])
 351 AC_DEFINE_UNQUOTED(DEFAULT_RNG, ["$default_rng"], [default RNG type for key generator])
 352
 353 dnl ==========================================================================
 354 AC_DEFUN([CS_DEFINE],
 355         [AC_DEFINE_UNQUOTED(DEFAULT_[]m4_translit([$1], [-a-z], [_A-Z]), [$2], [$3])
 356 ])
 357
 358 AC_DEFUN([CS_STR_WITH], [AC_ARG_WITH([$1],
 359         [AS_HELP_STRING(--with-[$1], [default $2 [$3]])],
 360         [CS_DEFINE([$1], ["$withval"], [$2])],
 361         [CS_DEFINE([$1], ["$3"], [$2])]
 362 )])
 363
 364 AC_DEFUN([CS_NUM_WITH], [AC_ARG_WITH([$1],
 365         [AS_HELP_STRING(--with-[$1], [default $2 [$3]])],
 366         [CS_DEFINE([$1], [$withval], [$2])],
 367         [CS_DEFINE([$1], [$3], [$2])]
 368 )])
 369
 370 dnl ==========================================================================
 371 dnl Python bindings
 372 AC_ARG_ENABLE([python], AS_HELP_STRING([--enable-python],[enable Python bindings]),
 373 [with_python=$enableval],
 374 [with_python=no])
 375
 376 if test "x$with_python" = "xyes"; then
 377         AM_PATH_PYTHON([2.4])
 378
 379         if ! test -x "$PYTHON-config" ; then
 380             AC_MSG_ERROR([Cannot find python development packages to build bindings])
 381         fi
 382
 383         PYTHON_INCLUDES=$($PYTHON-config --includes)
 384         AC_SUBST(PYTHON_INCLUDES)
 385 fi
 386 AM_CONDITIONAL([PYTHON_CRYPTSETUP], [test "x$with_python" = "xyes"])
 387
 388 dnl ==========================================================================
 389 CS_STR_WITH([plain-hash],   [password hashing function for plain mode], [ripemd160])
 390 CS_STR_WITH([plain-cipher], [cipher for plain mode], [aes])
 391 CS_STR_WITH([plain-mode],   [cipher mode for plain mode], [cbc-essiv:sha256])
 392 CS_NUM_WITH([plain-keybits],[key length in bits for plain mode], [256])
 393
 394 CS_STR_WITH([luks1-hash],   [hash function for LUKS1 header], [sha1])
 395 CS_STR_WITH([luks1-cipher], [cipher for LUKS1], [aes])
 396 CS_STR_WITH([luks1-mode],   [cipher mode for LUKS1], [xts-plain64])
 397 CS_NUM_WITH([luks1-keybits],[key length in bits for LUKS1], [256])
 398 CS_NUM_WITH([luks1-iter-time],[PBKDF2 iteration time for LUKS1 (in ms)], [1000])
 399
 400 CS_STR_WITH([loopaes-cipher], [cipher for loop-AES mode], [aes])
 401 CS_NUM_WITH([loopaes-keybits],[key length in bits for loop-AES mode], [256])
 402
 403 CS_NUM_WITH([keyfile-size-maxkb],[maximum keyfile size (in KiB)], [8192])
 404 CS_NUM_WITH([passphrase-size-max],[maximum keyfile size (in characters)], [512])
 405
 406 CS_STR_WITH([verity-hash],       [hash function for verity mode], [sha256])
 407 CS_NUM_WITH([verity-data-block], [data block size for verity mode], [4096])
 408 CS_NUM_WITH([verity-hash-block], [hash block size for verity mode], [4096])
 409 CS_NUM_WITH([verity-salt-size],  [salt size for verity mode], [32])
 410
 411 dnl ==========================================================================
 412
 413 AC_CONFIG_FILES([ Makefile
 414 lib/Makefile
 415 lib/libcryptsetup.pc
 416 lib/crypto_backend/Makefile
 417 lib/luks1/Makefile
 418 lib/loopaes/Makefile
 419 lib/verity/Makefile
 420 lib/tcrypt/Makefile
 421 src/Makefile
 422 po/Makefile.in
 423 man/Makefile
 424 tests/Makefile
 425 python/Makefile
 426 ])
 427 AC_OUTPUT