configure.ac

   1 AC_PREREQ(2.65)
   2 AC_CONFIG_MACRO_DIR([m4])
   3
   4 AC_INIT([glib-networking],[2.31.20],[http://bugzilla.gnome.org/enter_bug.cgi?product=glib&component=network])
   5
   6 AC_CONFIG_SRCDIR([proxy/libproxy/glibproxyresolver.h])
   7 AC_CONFIG_HEADERS([config.h])
   8
   9 dnl Other initialization
  10 AM_INIT_AUTOMAKE([1.11 no-dist-gzip dist-xz -Wno-portability])
  11 AM_MAINTAINER_MODE([enable])
  12 AM_SILENT_RULES([yes])
  13 LT_INIT
  14
  15 dnl Checks for programs.
  16 AC_PROG_CC
  17 AM_PROG_CC_C_O
  18 AC_PROG_CPP
  19
  20 dnl Checks for libraries.
  21
  22 dnl ****************************
  23 dnl *** Checks for intltool  ***
  24 dnl ****************************
  25
  26 IT_PROG_INTLTOOL([0.35.0])
  27 GETTEXT_PACKAGE=glib-networking
  28
  29 AC_SUBST([GETTEXT_PACKAGE])
  30 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[The gettext domain name])
  31 AM_GLIB_GNU_GETTEXT
  32
  33 dnl *****************************
  34 dnl *** Check GLib GIO        ***
  35 dnl *****************************
  36 AM_PATH_GLIB_2_0(2.31.6,,AC_MSG_ERROR(GLIB not found),gio)
  37
  38 GIO_MODULE_DIR=$($PKG_CONFIG --variable giomoduledir gio-2.0)
  39 AS_IF([test "x$GIO_MODULE_DIR" = "x"],
  40       [AC_MSG_FAILURE(GIO_MODULE_DIR is missing from gio-2.0.pc)])
  41 AC_SUBST(GIO_MODULE_DIR)
  42
  43 AC_PATH_PROG(GIO_QUERYMODULES, gio-querymodules)
  44 AC_SUBST(GIO_QUERYMODULES)
  45
  46 dnl *****************************
  47 dnl *** Checks for LibProxy   ***
  48 dnl *****************************
  49
  50 AC_ARG_WITH(libproxy,
  51     [AC_HELP_STRING([--with-libproxy],
  52                     [support for libproxy @<:@default=check@:>@])],
  53     [],
  54     [with_libproxy=check])
  55 AS_IF([test "x$with_libproxy" != "xno"],
  56     [PKG_CHECK_MODULES(LIBPROXY, [libproxy-1.0 >= 0.3.1],
  57         [with_libproxy=yes; proxy_support=libproxy],
  58         [AS_IF([test "x$with_libproxy" = "xyes"],
  59                [AC_MSG_FAILURE("$LIBPROXY_PKG_ERRORS")])])])
  60 AM_CONDITIONAL(HAVE_LIBPROXY, [test "x$with_libproxy" = "xyes"])
  61 AC_SUBST(LIBPROXY_CFLAGS)
  62 AC_SUBST(LIBPROXY_LIBS)
  63
  64 dnl **************************************
  65 dnl *** Checks for GNOME proxy backend ***
  66 dnl **************************************
  67 AC_ARG_WITH(gnome-proxy,
  68     [AC_HELP_STRING([--with-gnome-proxy],
  69                     [support for GNOME proxy configuration @<:@default=check@:>@])],
  70     [],
  71     [with_gnome_proxy=check])
  72 AS_IF([test "x$with_gnome_proxy" != "xno"],
  73     [PKG_CHECK_MODULES(GSETTINGS_DESKTOP_SCHEMAS, [gsettings-desktop-schemas],
  74         [with_gnome_proxy=yes; proxy_support="gnome $proxy_support"],
  75         [AS_IF([test "x$with_gnome_proxy" = "xyes"],
  76                [AC_MSG_FAILURE("$GSETTINGS_DESKTOP_SCHEMAS_PKG_ERRORS")])])])
  77 AM_CONDITIONAL(HAVE_GNOME_PROXY, [test "x$with_gnome_proxy" = "xyes"])
  78 AC_SUBST(GSETTINGS_DESKTOP_SCHEMAS_CFLAGS)
  79
  80 dnl *****************************
  81 dnl *** Checks for GNUTLS     ***
  82 dnl *****************************
  83
  84 GNUTLS_MIN_REQUIRED=2.11.0
  85 GNUTLS_MIN_PKCS11=2.12.8
  86
  87 AC_ARG_WITH(gnutls,
  88     [AC_HELP_STRING([--with-gnutls],
  89                     [support for GNUTLS @<:@default=yes@:>@])],
  90     [],
  91     [with_gnutls=yes])
  92 if test "x$with_gnutls" != "xno"; then
  93         PKG_CHECK_MODULES(GNUTLS,
  94                           [gnutls >= $GNUTLS_MIN_REQUIRED],
  95                           [with_gnutls=yes
  96                            tls_support="${tls_support}gnutls "],
  97                           [AS_IF([test "x$with_gnutls" = "xyes"],
  98                                  [AC_MSG_FAILURE("$GNUTLS_PKG_ERRORS")])])
  99 fi
 100 AM_CONDITIONAL(HAVE_GNUTLS, [test "x$with_gnutls" = "xyes"])
 101 AC_SUBST(GNUTLS_CFLAGS)
 102 AC_SUBST(GNUTLS_LIBS)
 103
 104 if test "x$with_gnutls" = "xyes"; then
 105     AC_MSG_CHECKING([location of system Certificate Authority list])
 106     AC_ARG_WITH(ca-certificates,
 107                 [AC_HELP_STRING([--with-ca-certificates=@<:@path@:>@],
 108                                 [path to system Certificate Authority list])])
 109     if test "$with_ca_certificates" = "no"; then
 110         AC_MSG_RESULT([disabled])
 111     else
 112         if test -z "$with_ca_certificates"; then
 113             for f in /etc/pki/tls/certs/ca-bundle.crt \
 114                      /etc/ssl/certs/ca-certificates.crt; do
 115                 if test -f "$f"; then
 116                     with_ca_certificates="$f"
 117                 fi
 118             done
 119             if test -z "$with_ca_certificates"; then
 120                 AC_MSG_ERROR([could not find. Use --with-ca-certificates=path to set, or --without-ca-certificates to disable])
 121             fi
 122         fi
 123
 124         AC_MSG_RESULT($with_ca_certificates)
 125         AC_DEFINE_UNQUOTED(GTLS_SYSTEM_CA_FILE, ["$with_ca_certificates"], [The system TLS CA list])
 126     fi
 127 fi
 128
 129 dnl *****************************
 130 dnl *** Checks for pkcs11    ***
 131 dnl *****************************
 132
 133 P11_KIT_REQUIRED=0.8
 134
 135 AC_ARG_WITH(pkcs11,
 136         [AC_HELP_STRING([--with-pkcs11],
 137                         [support for pkcs11 @<:@default=check@:>@])],
 138                         [],
 139                         [with_pkcs11=check])
 140 if test "x$with_pkcs11" != "xno"; then
 141         PKG_CHECK_MODULES(PKCS11,
 142                           [p11-kit-1 >= $P11_KIT_REQUIRED gnutls >= $GNUTLS_MIN_PKCS11],
 143                           [with_pkcs11=yes
 144                            pkcs11_support=p11-kit
 145                            tls_support="${tls_support}gnutls-pkcs11 "
 146                            AC_DEFINE_UNQUOTED([HAVE_PKCS11], [1], [Building with PKCS#11 support])],
 147                           [AS_IF([test "x$with_pkcs11" = "xyes"],
 148                                  [AC_MSG_FAILURE("$PKCS11_PKG_ERRORS")])
 149                            pkcs11_support=no])
 150 else
 151         pkcs11_support=no
 152 fi
 153 AM_CONDITIONAL(HAVE_PKCS11, [test "x$with_pkcs11" = "xyes"])
 154 AC_SUBST(PKCS11_CFLAGS)
 155 AC_SUBST(PKCS11_LIBS)
 156
 157 dnl ************************************
 158 dnl *** Enable lcov coverage reports ***
 159 dnl ************************************
 160
 161 AC_ARG_ENABLE(gcov,
 162   AS_HELP_STRING([--enable-gcov],
 163                  [Enable gcov]),
 164   [use_gcov=$enableval], [use_gcov=no])
 165
 166 if test "x$use_gcov" = "xyes"; then
 167   dnl we need gcc:
 168   if test "$GCC" != "yes"; then
 169     AC_MSG_ERROR([GCC is required for --enable-gcov])
 170   fi
 171
 172   ltp_version_list="1.6 1.7 1.8 1.9"
 173   AC_CHECK_PROG(LTP, lcov, lcov)
 174   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
 175
 176   if test "$LTP"; then
 177     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
 178       glib_cv_ltp_version=invalid
 179       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
 180       for ltp_check_version in $ltp_version_list; do
 181         if test "$ltp_version" = "$ltp_check_version"; then
 182           glib_cv_ltp_version="$ltp_check_version (ok)"
 183         fi
 184       done
 185     ])
 186   else
 187     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
 188     AC_MSG_ERROR([$ltp_msg])
 189   fi
 190
 191   case $glib_cv_ltp_version in
 192     ""|invalid[)]
 193       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
 194       AC_MSG_ERROR([$ltp_msg])
 195       LTP="exit 0;"
 196       ;;
 197   esac
 198
 199   if test -z "$LTP_GENHTML"; then
 200     AC_MSG_ERROR([Could not find genhtml from the LTP package])
 201   fi
 202
 203   AC_DEFINE(HAVE_GCOV, 1, [Whether you have gcov])
 204
 205   dnl Remove all optimization flags from CFLAGS
 206   changequote({,})
 207   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
 208   changequote([,])
 209
 210   dnl Add the special gcc flags
 211   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
 212   LDFLAGS="$LDFLAGS -lgcov"
 213 fi
 214
 215 dnl ****************************************************
 216 dnl *** Warnings to show if using GCC                ***
 217 dnl *** (do this last so -Werror won't mess up tests ***
 218 dnl ****************************************************
 219
 220 AC_ARG_ENABLE(more-warnings,
 221               AS_HELP_STRING([--disable-more-warnings], [Inhibit compiler warnings]),
 222               set_more_warnings=no)
 223
 224 if test "$GCC" = "yes" -a "$set_more_warnings" != "no"; then
 225         CFLAGS="$CFLAGS \
 226                 -Wall -Wstrict-prototypes -Werror=missing-prototypes \
 227                 -Werror=implicit-function-declaration \
 228                 -Werror=pointer-arith -Werror=init-self -Werror=format=2 \
 229                 -Werror=missing-include-dirs \
 230                 -Werror=declaration-after-statement"
 231 fi
 232
 233 dnl *****************************
 234 dnl *** done                  ***
 235 dnl *****************************
 236 AC_CONFIG_FILES([Makefile
 237                  po/Makefile.in po/Makefile
 238                  proxy/libproxy/Makefile
 239                  proxy/gnome/Makefile
 240                  proxy/tests/Makefile
 241                  tls/gnutls/Makefile
 242                  tls/pkcs11/Makefile
 243                  tls/tests/Makefile
 244                 ])
 245 AC_OUTPUT
 246
 247 echo ""
 248 echo     "  Proxy support:     ${proxy_support:-no}"
 249 echo     "  TLS support:       ${tls_support:-no}"
 250 if test "$tls_support" != "no"; then
 251     echo "  PKCS#11 Support:   $pkcs11_support"
 252     echo "  TLS CA file:       ${with_ca_certificates:-(none)}"
 253     if test -n "$with_ca_certificates"; then
 254         if ! test -f "$with_ca_certificates"; then
 255             AC_MSG_WARN([Specified certificate authority file '$with_ca_certificates' does not exist])
 256         fi
 257     fi
 258 fi