configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [1])
   4 m4_define([v_min], [0])
   5 m4_define([v_mic], [999])
   6 m4_define([v_rev], m4_esyscmd([(svnversion "${SVN_REPO_PATH:-.}" | grep -v export || echo 0) | awk -F : '{printf("%s\n", $1);}' | tr -d ' :MSP\n']))
   7 m4_if(v_rev, [0], [m4_define([v_rev], m4_esyscmd([git log 2> /dev/null | (grep -m1 git-svn-id || echo 0) | sed -e 's/.*@\([0-9]*\).*/\1/' | tr -d '\n']))])
   8 ##--   When released, remove the dnl on the below line
   9 dnl m4_undefine([v_rev])
  10 ##--   When doing snapshots - change soname. remove dnl on below line
  11 dnl m4_define([relname], [ver-pre-svn-07])
  12 dnl m4_define([v_rel], [-release relname])
  13 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  14 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])], [m4_define([v_ver], [v_maj.v_min.v_mic])])
  15 m4_define([lt_cur], m4_eval(v_maj + v_min))
  16 m4_define([lt_rev], v_mic)
  17 m4_define([lt_age], v_min)
  18 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  19 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  20
  21 AC_INIT([eina], [v_ver], [enlightenment-devel@lists.sourceforge.net])
  22 AC_PREREQ([2.59])
  23 AC_CONFIG_SRCDIR([configure.ac])
  24 AC_CONFIG_MACRO_DIR([m4])
  25
  26 AC_CONFIG_HEADERS([config.h])
  27 AH_TOP([
  28 #ifndef EFL_CONFIG_H__
  29 #define EFL_CONFIG_H__
  30 ])
  31 AH_BOTTOM([
  32 #endif /* EFL_CONFIG_H__ */
  33 ])
  34
  35 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 AC_GNU_SOURCE
  39 AC_SYS_LARGEFILE
  40
  41 AC_LIBTOOL_WIN32_DLL
  42 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  43 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  44 AC_PROG_LIBTOOL
  45
  46 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  47 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  48 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  49 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  50 AC_DEFINE_UNQUOTED(VMAJ, [v_maj], [Major version])
  51 AC_DEFINE_UNQUOTED(VMIN, [v_min], [Minor version])
  52 AC_DEFINE_UNQUOTED(VMIC, [v_mic], [Micro version])
  53 AC_DEFINE_UNQUOTED(VREV, [v_rev], [Revison])
  54 version_info="lt_cur:lt_rev:lt_age"
  55 release_info="v_rel"
  56 AC_SUBST(version_info)
  57 AC_SUBST(release_info)
  58 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  59 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  60 VMAJ=v_maj
  61 AC_SUBST(VMAJ)
  62
  63
  64 ### Needed information
  65
  66 AC_CANONICAL_BUILD
  67 AC_CANONICAL_HOST
  68
  69 requirement_eina=""
  70
  71 case "$host_os" in
  72    mingw32ce*)
  73       MODULE_ARCH="$host_os-$host_cpu"
  74       ;;
  75    *)
  76       MODULE_ARCH="$host_os-$host_cpu-v_maj.v_min.v_mic"
  77       ;;
  78 esac
  79 AC_SUBST(MODULE_ARCH)
  80 AC_DEFINE_UNQUOTED(MODULE_ARCH, "${MODULE_ARCH}", "Module architecture")
  81
  82 case "$host_os" in
  83    mingw*)
  84       MODULE_EXT=".dll"
  85       ;;
  86    *)
  87       MODULE_EXT=".so"
  88       ;;
  89 esac
  90
  91 AC_DEFINE_UNQUOTED(SHARED_LIB_SUFFIX, "${MODULE_EXT}", [Suffix for shared objects])
  92
  93 EFL_CHECK_CPU_MMX([have_mmx="yes"], [have_mmx="no"])
  94 EFL_CHECK_CPU_SSE([have_sse="yes"], [have_sse="no"])
  95 EFL_CHECK_CPU_SSE2([have_sse2="yes"], [have_sse2="no"])
  96 EFL_CHECK_CPU_ALTIVEC([have_altivec="yes"], [have_altivec="no"])
  97
  98 EFL_CHECK_THREADS(
  99    [
 100     if test "x${_efl_have_posix_threads}" = "xyes" ; then
 101        have_threads="POSIX"
 102     else
 103        if test "x${_efl_have_win32_threads}" = "xyes" ; then
 104           have_threads="Win32"
 105        else
 106           have_threads="no"
 107        fi
 108     fi
 109    ],
 110    [have_threads="no"])
 111 EFL_CHECK_SPINLOCK([have_posix_threads_spinlock="yes"], [have_posix_threads_spinlock="no"])
 112
 113 ### Additional options to configure
 114
 115 # Magic debug
 116 AC_ARG_ENABLE([magic-debug],
 117    [AC_HELP_STRING([--disable-magic-debug], [disable magic debug of eina structure @<:@default=enabled@:>@])],
 118    [
 119     if test "x${enableval}" = "xyes" ; then
 120        have_magic_debug="yes"
 121     else
 122        have_magic_debug="no"
 123     fi
 124    ],
 125    [have_magic_debug="yes"])
 126
 127 AC_MSG_CHECKING([whether magic debug is enable])
 128 AC_MSG_RESULT([${have_magic_debug}])
 129
 130 if test "x${have_magic_debug}" = "xyes" ; then
 131    EINA_CONFIGURE_MAGIC_DEBUG="#define EINA_MAGIC_DEBUG"
 132 fi
 133 AC_SUBST(EINA_CONFIGURE_MAGIC_DEBUG)
 134
 135 # Valgrind
 136 want_valgrind="auto"
 137 have_valgrind="no"
 138
 139 AC_MSG_CHECKING(whether to enable build with valgrind)
 140 AC_ARG_ENABLE(valgrind,
 141   AC_HELP_STRING([--enable-valgrind], [improve valgrind support by hinting it of our memory usages, having it to report proper mempool leaks.]),
 142   [want_valgrind=$enableval]
 143 )
 144 AC_MSG_RESULT($want_valgrind)
 145
 146 if test "x${want_valgrind}" = "xyes" -o "x${want_valgrind}" = "xauto"; then
 147     PKG_CHECK_MODULES(VALGRIND, valgrind >= 2.4.0,
 148         [
 149          requirement_eina="valgrind ${requirement_eina}"
 150          have_valgrind="yes"
 151         ],
 152         [
 153          AC_DEFINE(NVALGRIND, 1, [Valgrind support disabled])
 154          if test "x$want_valgrind" = "xyes"; then
 155             AC_MSG_ERROR([Valgrind >= 2.4.0 is required)])
 156          fi
 157         ]
 158     )
 159 else
 160     AC_DEFINE(NVALGRIND, 1, [Valgrind support disabled])
 161 fi
 162
 163 # Safety checks (avoid crashes on wrong api usage)
 164 AC_ARG_ENABLE(safety-checks,
 165    [AC_HELP_STRING([--disable-safety-checks], [disable safety checks for NULL pointers and like. @<:@default=enabled@:>@])],
 166    [
 167     if test "x${enableval}" = "xyes" ; then
 168        have_safety_checks="yes"
 169     else
 170        have_safety_checks="no"
 171     fi
 172    ],
 173    [have_safety_checks="yes"])
 174
 175 AC_MSG_CHECKING(whether to do safety checking on api parameters)
 176 AC_MSG_RESULT($have_safety_checks)
 177
 178 AM_CONDITIONAL(SAFETY_CHECKS, test "x$have_safety_checks" = "xyes")
 179 if test "x$have_safety_checks" = "xyes"; then
 180   AC_DEFINE(EINA_SAFETY_CHECKS, 1, [disable safety checks for NULL pointers and like.])
 181   EINA_CONFIGURE_SAFETY_CHECKS="#define EINA_SAFETY_CHECKS"
 182 fi
 183 AC_SUBST(EINA_CONFIGURE_SAFETY_CHECKS)
 184
 185 with_max_log_level="<unset>"
 186 AC_ARG_WITH(internal-maximum-log-level,
 187    [AC_HELP_STRING([--with-internal-maximum-log-level=NUMBER],
 188                    [limit eina internal log level to the given number, any call to EINA_LOG() with values greater than this will be compiled out, ignoring runtime settings, but saving function calls.])],
 189    [
 190     if test "x${withval}" != "xno"; then
 191        if echo "${withval}" | grep '^[[0-9]]\+$' >/dev/null 2>/dev/null; then
 192           AC_MSG_NOTICE([ignoring any EINA_LOG() with level greater than ${withval}])
 193           AC_DEFINE_UNQUOTED(EINA_LOG_LEVEL_MAXIMUM, ${withval}, [if set, logging is limited to this amount.])
 194           with_max_log_level="${withval}"
 195        else
 196           AC_MSG_ERROR([--with-internal-maximum-log-level takes a decimal number, got "${withval}" instead.])
 197        fi
 198     fi
 199     ], [:])
 200
 201 AC_ARG_ENABLE([amalgamation],
 202    [AC_HELP_STRING([--enable-amalgamation], [enable generation of one single file with all source code in it, helps compiler optimizations.])],
 203    [if test "x${enableval}" = "xyes"; then
 204        do_amalgamation="yes"
 205     else
 206        do_amalgamation="no"
 207     fi
 208    ],
 209    [do_amalgamation="no"]
 210 )
 211 AM_CONDITIONAL(EINA_AMALGAMATION, test "x${do_amalgamation}" = "xyes")
 212
 213 # Choose best memory pool
 214 AC_ARG_ENABLE([default-mempool],
 215    [AC_HELP_STRING([--enable-default-mempool], [Default memory allocator could be faster for some computer. @<:@default=disabled@:>@])],
 216    [
 217     if test "x${enableval}" = "xyes"; then
 218        have_default_mempool="yes"
 219     else
 220        have_default_mempool="no"
 221     fi
 222    ],
 223    [have_default_mempool="no"]
 224 )
 225 AC_MSG_CHECKING([whether to use default mempool allocator])
 226 AC_MSG_RESULT([${have_default_mempool}])
 227
 228 if test "x${have_default_mempool}" = "xyes" ; then
 229    EINA_CONFIGURE_DEFAULT_MEMPOOL="#define EINA_DEFAULT_MEMPOOL"
 230 fi
 231 AC_SUBST(EINA_CONFIGURE_DEFAULT_MEMPOOL)
 232
 233 # Report stringshare usage
 234 AC_ARG_ENABLE([stringshare-usage],
 235    [AC_HELP_STRING([--enable-stringshare-usage], [Report stringshare usage on stringshare shutdown. @<:@default=disabled@:>@])],
 236    [
 237     if test "x${enableval}" = "xyes"; then
 238        have_stringshare_usage="yes"
 239     else
 240        have_stringshare_usage="no"
 241     fi
 242    ],
 243    [have_stringshare_usage="no"]
 244 )
 245 AC_MSG_CHECKING([whether to report stringshare usage])
 246 AC_MSG_RESULT([${have_stringshare_usage}])
 247
 248 if test "x${have_stringshare_usage}" = "xyes"; then
 249    AC_DEFINE(EINA_STRINGSHARE_USAGE, 1, [Report Eina stringshare usage pattern])
 250 fi
 251
 252 # Check if we want to benchmark on real data
 253 enable_benchmark_e17="no"
 254 AC_ARG_ENABLE([e17],
 255    [AC_HELP_STRING([--enable-e17], [enable heavy benchmark @<:@default=no@:>@])],
 256    [
 257     if test "x${enableval}" = "xyes" ; then
 258        enable_benchmark_e17="yes"
 259     else
 260        enable_benchmark_e17="no"
 261     fi
 262    ],
 263    [enable_benchmark_e17="no"])
 264
 265 AC_MSG_CHECKING([whether e17 real data benchmark are built])
 266 AC_MSG_RESULT([${enable_benchmark_e17}])
 267
 268 AM_CONDITIONAL(EINA_ENABLE_BENCHMARK_E17, test "x${enable_benchmark_e17}" = "xyes")
 269
 270
 271 ### Checks for programs
 272 AC_PROG_CC
 273 AC_PROG_CXX
 274
 275 # pkg-config
 276 PKG_PROG_PKG_CONFIG
 277
 278 # Check whether pkg-config supports Requires.private
 279 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
 280    pkgconfig_requires_private="Requires.private"
 281 else
 282    pkgconfig_requires_private="Requires"
 283 fi
 284 AC_SUBST(pkgconfig_requires_private)
 285
 286 # doxygen program for documentation building
 287
 288 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 289
 290
 291 ### Checks for libraries
 292
 293 # Evil library for compilation on Windows CE
 294
 295 EFL_EINA_BUILD=""
 296 case "$host_os" in
 297    mingw*)
 298       PKG_CHECK_MODULES([EVIL], [evil])
 299       AC_DEFINE(HAVE_EVIL, 1, [Set to 1 if evil package is installed])
 300       requirement_eina="evil"
 301       EFL_EINA_BUILD="-DEFL_EINA_BUILD"
 302    ;;
 303 esac
 304 AC_SUBST(EFL_EINA_BUILD)
 305
 306 # Check ememoa memory pool library
 307
 308 AC_ARG_ENABLE([ememoa],
 309    [AC_HELP_STRING([--enable-ememoa], [build ememoa memory pool module @<:@default=yes@:>@])],
 310    [
 311     if test "x${enableval}" = "xyes" ; then
 312        enable_ememoa="yes"
 313     else
 314        enable_ememoa="no"
 315     fi
 316    ],
 317    [enable_ememoa="yes"]
 318 )
 319 AC_MSG_CHECKING([whether to use ememoa for memory pool])
 320 AC_MSG_RESULT([$enable_ememoa])
 321
 322 if test "x${enable_ememoa}" = "xyes" ; then
 323    PKG_CHECK_MODULES([EMEMOA],
 324       [ememoa >= 0.0.26 ],
 325       [enable_ememoa="yes"],
 326       [enable_ememoa="no"]
 327    )
 328 fi
 329
 330
 331 ### Checks for header files
 332 AC_HEADER_ASSERT
 333 AC_HEADER_DIRENT
 334 AC_HEADER_TIME
 335 AC_CHECK_HEADERS([unistd.h libgen.h])
 336 EFL_CHECK_PATH_MAX
 337
 338 ### Checks for types
 339 AC_CHECK_HEADER([inttypes.h],
 340    [
 341     EINA_CONFIGURE_HAVE_INTTYPES_H="#define EINA_HAVE_INTTYPES_H"
 342     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define to 1 if you have the <inttypes.h> header file.])
 343    ])
 344 AC_SUBST(EINA_CONFIGURE_HAVE_INTTYPES_H)
 345
 346 AC_CHECK_HEADER([stdint.h],
 347    [
 348     EINA_CONFIGURE_HAVE_STDINT_H="#define EINA_HAVE_STDINT_H"
 349     AC_DEFINE(HAVE_STDINT_H, 1, [Define to 1 if you have the <stdint.h> header file.])
 350    ])
 351 AC_SUBST(EINA_CONFIGURE_HAVE_STDINT_H)
 352
 353 AC_CHECK_SIZEOF(wchar_t)
 354 EINA_SIZEOF_WCHAR_T=$ac_cv_sizeof_wchar_t
 355 AC_SUBST(EINA_SIZEOF_WCHAR_T)
 356
 357 ### Checks for structures
 358
 359
 360 ### Checks for compiler characteristics
 361 AC_C_CONST
 362 AC_C_BIGENDIAN
 363 AC_C_INLINE
 364 AC_C___ATTRIBUTE__
 365 AC_PROG_CC_STDC
 366
 367 have_win32="no"
 368 EINA_CPPFLAGS=""
 369 EINA_CFLAGS=""
 370 case "$host_os" in
 371    mingw32ce*)
 372       EINA_CPPFLAGS="-D_WIN32_WCE=0x0420"
 373       EINA_CFLAGS="${EVIL_CFLAGS}"
 374       have_win32="yes"
 375       ;;
 376    mingw*)
 377       EINA_CPPFLAGS="-D_WIN32_WINNT=0x0501"
 378       EINA_CFLAGS="${EVIL_CFLAGS}"
 379       have_win32="yes"
 380       ;;
 381 esac
 382 AM_CONDITIONAL([EINA_HAVE_WIN32], [test "x$have_win32" = "xyes"])
 383
 384 m4_ifdef([v_mic],
 385    [
 386     EFL_COMPILER_FLAG([-Wall])
 387     EFL_COMPILER_FLAG([-W])
 388    ])
 389
 390 EFL_COMPILER_FLAG([-Wshadow])
 391
 392 AC_SUBST(EINA_CPPFLAGS)
 393 AC_SUBST(EINA_CFLAGS)
 394
 395
 396 ### Checks for linker characteristics
 397 EINA_LIBS=
 398 lt_enable_auto_import=""
 399 case "${host_os}" in
 400    mingw*)
 401       EINA_LIBS="-ldl ${EVIL_LIBS} -lm"
 402       lt_enable_auto_import="-Wl,--enable-auto-import"
 403    ;;
 404    dragonfly*|openbsd*)
 405       EINA_LIBS="-lm"
 406    ;;
 407    freebsd*|netbsd*)
 408       EINA_LIBS="-lrt -lm"
 409    ;;
 410    darwin*)
 411       EINA_LIBS="-lm"
 412    ;;
 413    cygwin*)
 414       EINA_LIBS="-ldl -lm"
 415    ;;
 416    *)
 417       EINA_LIBS="-ldl -lrt -lm"
 418    ;;
 419 esac
 420 AC_SUBST(EINA_LIBS)
 421 AC_SUBST(lt_enable_auto_import)
 422
 423 EFL_LINKER_FLAG([-fno-strict-aliasing])
 424
 425
 426 ### Checks for library functions
 427 AC_ISC_POSIX
 428 AC_FUNC_ALLOCA
 429 AC_CHECK_FUNCS(strlcpy)
 430
 431 #dlopen and dladdr
 432 dlopen_libs=""
 433 case "$host_os" in
 434    mingw*)
 435 # managed by evil
 436       AC_DEFINE(HAVE_DLADDR)
 437       ;;
 438    *)
 439       AC_CHECK_FUNCS([dlopen], [res="yes"], [res="no"])
 440       if test "x${res}" = "xyes" ; then
 441          AC_CHECK_FUNCS([dladdr], [AC_DEFINE(HAVE_DLADDR)])
 442       else
 443          AC_CHECK_LIB([dl], [dlopen], [res="yes"], [res="no"])
 444          if test "x${res}" = "xyes" ; then
 445             AC_CHECK_LIB([dl], [dladdr], [AC_DEFINE(HAVE_DLADDR)])
 446             dlopen_libs="-ldl"
 447          else
 448             AC_MSG_ERROR([Cannot find dlopen])
 449          fi
 450       fi
 451       ;;
 452 esac
 453 AC_SUBST(dlopen_libs)
 454
 455 EFL_CHECK_FNMATCH([], [AC_MSG_ERROR([Cannot find fnmatch()])])
 456
 457 # iconv library
 458 have_iconv="no"
 459 AC_ARG_WITH([iconv-link],
 460    AC_HELP_STRING([--with-iconv-link=ICONV_LINK], [explicitly specify an iconv link option]),
 461    [
 462     LIBS="$withval $LIBS"
 463     have_iconv="yes"
 464    ])
 465
 466 AC_MSG_CHECKING(for explicit iconv link options)
 467 if test "x${iconv_libs}" = "x" ; then
 468    AC_MSG_RESULT([no explicit iconv link option])
 469 else
 470    AC_MSG_RESULT([$iconv_libs])
 471 fi
 472
 473 if test "x${have_iconv}" = "xno" ; then
 474    AC_CHECK_HEADERS([iconv.h], [have_iconv="yes"])
 475
 476    if test "x${have_iconv}" = "xyes" ; then
 477       AC_MSG_CHECKING([whether iconv() is in libc])
 478
 479       AC_LINK_IFELSE(
 480          [AC_LANG_PROGRAM(
 481              [[
 482 #include <stdlib.h>
 483 #include <iconv.h>
 484              ]],
 485              [[
 486 iconv_t ic;
 487 size_t count = iconv(ic, NULL, NULL, NULL, NULL);
 488              ]])],
 489          [have_iconv="yes"],
 490          [have_iconv="no"])
 491
 492       AC_MSG_RESULT([${have_iconv}])
 493    fi
 494
 495    if test "x${have_iconv}" = "xno" ; then
 496       AC_MSG_CHECKING([whether iconv() is in libiconv.a])
 497
 498       LIBS_save="${LIBS}"
 499       LIBS="-liconv $LIBS"
 500       AC_LINK_IFELSE(
 501          [AC_LANG_PROGRAM(
 502              [[
 503 #include <stdlib.h>
 504 #include <iconv.h>
 505              ]],
 506              [[
 507 iconv_t ic;
 508 size_t count;
 509 count = iconv(ic, NULL, NULL, NULL, NULL);
 510              ]])],
 511          [have_iconv="yes"],
 512          [
 513           have_iconv="no"
 514           LIBS=${LIBS_save}
 515          ])
 516
 517       AC_MSG_RESULT([${have_iconv}])
 518    fi
 519
 520    if test "x${have_iconv}" = "xno" ; then
 521       AC_MSG_CHECKING([whether iconv() is in libiconv_plug.a])
 522
 523       LIBS_save="${LIBS}"
 524       LIBS="-liconv_plug $LIBS"
 525       AC_LINK_IFELSE(
 526          [AC_LANG_PROGRAM(
 527              [[
 528 #include <stdlib.h>
 529 #include <iconv.h>
 530              ]],
 531              [[
 532 iconv_t ic;
 533 size_t count = iconv(ic, NULL, NULL, NULL, NULL);
 534              ]])],
 535          [have_iconv="yes"],
 536          [
 537           have_iconv="no"
 538           LIBS=${LIBS_save}
 539          ])
 540
 541       AC_MSG_RESULT([${have_iconv}])
 542    fi
 543 fi
 544
 545 if test "x${have_iconv}" = "xyes" ; then
 546    AC_DEFINE([HAVE_ICONV], [1], [Set to 1 if iconv library is installed])
 547 fi
 548
 549 #check for dirfd API presence
 550 have_dirfd="no"
 551 AC_CHECK_FUNCS([dirfd], [have_dirfd="yes"], [])
 552 if test "x${dirfd}" = "xyes"; then
 553    AC_DEFINE(HAVE_DIRFD)
 554 fi
 555 AC_CHECK_FUNCS([openat], [AC_DEFINE(HAVE_OPENAT)], [])
 556 AC_CHECK_FUNCS([statat], [AC_DEFINE(HAVE_STATAT)], [])
 557 AC_CHECK_FUNCS([fpathconf], [AC_DEFINE(HAVE_FPATHCONF)], [])
 558
 559 ### Modules
 560
 561 if test "x${have_default_mempool}" = "xyes" ; then
 562    enable_chained_pool="no"
 563    enable_pass_through="static"
 564 else
 565    enable_chained_pool="static"
 566    enable_pass_through="no"
 567 fi
 568
 569 enable_one_big="static"
 570
 571 EINA_CHECK_MODULE([chained-pool],   [${enable_chained_pool}], [chained pool])
 572 EINA_CHECK_MODULE([ememoa-fixed],   [${enable_ememoa}],       [ememoa fixed])
 573 EINA_CHECK_MODULE([ememoa-unknown], [${enable_ememoa}],       [ememoa unknown])
 574 EINA_CHECK_MODULE([fixed-bitmap],   [no],                     [fixed bitmap])
 575 EINA_CHECK_MODULE([pass-through],   [${enable_pass_through}], [pass through])
 576 EINA_CHECK_MODULE([buddy],          [no],                     [buddy])
 577 EINA_CHECK_MODULE([one-big],        [${enable_one_big}],      [one big])
 578
 579 ### Make the debug preprocessor configurable
 580
 581 ### Unit tests, coverage and benchmarking
 582
 583 EFL_CHECK_TESTS([enable_tests="yes"], [enable_tests="no"])
 584
 585 EFL_CHECK_COVERAGE([${enable_tests}], [enable_coverage="yes"], [enable_coverage="no"])
 586 EINA_CFLAGS="${EINA_CFLAGS} ${EFL_COVERAGE_CFLAGS}"
 587 EINA_LIBS="${EINA_LIBS} ${EFL_COVERAGE_LIBS}"
 588 if test "x$enable_coverage" = "xyes" ; then
 589    EINA_CFLAGS="${EINA_CFLAGS} ${EFL_DEBUG_CFLAGS}"
 590 fi
 591
 592 EFL_CHECK_BENCHMARK([enable_benchmark="yes"], [enable_benchmark="no"])
 593 EINA_BENCH_MODULE([glib], [${enable_benchmark}], [glib-2.0], [enable_benchmark_glib="yes"], [enable_benchmark_glib="no"])
 594 if test -n "$CXX" && test "x$enable_benchmark" = "xyes" ; then
 595    AC_DEFINE_UNQUOTED([CITYHASH_BENCH], [1], [enable bench tests for google hash method])
 596 fi
 597 AM_CONDITIONAL([CITYHASH_BENCH], [test -n "$CXX" && test "x$enable_benchmark" = "xyes"])
 598
 599 AC_SUBST(requirement_eina)
 600
 601 ### Create the .pc.in file according to the major version
 602 #cat > ${srcdir}/eina-${VMAJ}.pc.in << EOF
 603 #prefix=@prefix@
 604 #exec_prefix=@exec_prefix@
 605 #libdir=@libdir@
 606 #includedir=@includedir@
 607 #
 608 #Name: Eina
 609 #Description: A Library that implements fast data types and miscellaneous tools
 610 #Requires:
 611 #Version: @VERSION@
 612 #Libs: -L${libdir} -leina
 613 #Libs.private: -ldl
 614 #Cflags: -I${includedir}/eina-@VMAJ@ -I${includedir}/eina-@VMAJ@/eina
 615 #EOF
 616
 617 AC_CONFIG_FILES([
 618 Makefile
 619 eina.pc
 620 eina.spec
 621 doc/Makefile
 622 src/Makefile
 623 src/include/Makefile
 624 src/include/eina_config.h
 625 src/lib/Makefile
 626 src/modules/Makefile
 627 src/modules/mp/Makefile
 628 src/modules/mp/chained_pool/Makefile
 629 src/modules/mp/ememoa_fixed/Makefile
 630 src/modules/mp/ememoa_unknown/Makefile
 631 src/modules/mp/pass_through/Makefile
 632 src/modules/mp/fixed_bitmap/Makefile
 633 src/modules/mp/buddy/Makefile
 634 src/modules/mp/one_big/Makefile
 635 src/tests/Makefile
 636 ])
 637
 638 AC_OUTPUT
 639
 640 #####################################################################
 641 ## Info
 642
 643 echo
 644 echo
 645 echo
 646 echo "------------------------------------------------------------------------"
 647 echo "$PACKAGE $VERSION"
 648 echo "------------------------------------------------------------------------"
 649 echo
 650 echo
 651 echo "Configuration Options Summary:"
 652 echo
 653 echo "  Magic debug..........: ${have_magic_debug}"
 654 echo "  Safety checks........: ${have_safety_checks}"
 655 echo "  Maximum log level....: ${with_max_log_level}"
 656 echo "  Report string usage..: ${have_stringshare_usage}"
 657 echo "  Valgrind support.....: ${have_valgrind}"
 658 echo "  Default mempool......: ${have_default_mempool}"
 659 echo "  Thread Support.......: ${have_threads}"
 660 if test "${have_threads}" = "POSIX" ; then
 661 echo "    spinlock...........: ${have_posix_threads_spinlock}"
 662 echo "    debug usage........: ${have_debug_threads}"
 663 fi
 664 echo "  Amalgamation.........: ${do_amalgamation}"
 665 echo "  Iconv support........: ${have_iconv}"
 666 echo "  File dirfd...........: ${have_dirfd}"
 667 echo
 668 echo "  Documentation........: ${build_doc}"
 669 echo "  Tests................: ${enable_tests}"
 670 echo "  Coverage.............: ${enable_coverage}"
 671 echo "  Benchmark............: ${enable_benchmark}"
 672 if test "x${enable_benchmark}" = "xyes" ; then
 673 echo "    Glib...............: ${enable_benchmark_glib}"
 674 echo "    E17 real data......: ${enable_benchmark_e17}"
 675 fi
 676 echo
 677 echo "  CPU Specific Extensions:"
 678 echo "    MMX................: ${have_mmx}"
 679 echo "    SSE................: ${have_sse}"
 680 echo "    SSE2...............: ${have_sse2}"
 681 echo "    ALTIVEC............: ${have_altivec}"
 682 echo
 683 echo "  Memory pools:"
 684 echo "    Chained pool.......: ${enable_chained_pool}"
 685 echo "    Ememoa fixed.......: ${enable_ememoa_fixed}"
 686 echo "    Ememoa unknown.....: ${enable_ememoa_unknown}"
 687 echo "    Fixed bitmap.......: ${enable_fixed_bitmap}"
 688 echo "    Pass through.......: ${enable_pass_through}"
 689 echo "    Buddy..............: ${enable_buddy}"
 690 echo "    One big............: ${enable_one_big}"
 691 echo
 692 echo "Compilation............: make (or gmake)"
 693 echo "  CPPFLAGS.............: $CPPFLAGS"
 694 echo "  CFLAGS...............: $CFLAGS"
 695 echo "  LDFLAGS..............: $LDFLAGS"
 696 echo
 697 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
 698 echo "  prefix...............: $prefix"
 699 echo
 700 EFL_FORM_VOLTRON