configure.ac

   1 # Copyright (c) 2007 Intel Corporation. All Rights Reserved.
   2 #
   3 # Permission is hereby granted, free of charge, to any person obtaining a
   4 # copy of this software and associated documentation files (the
   5 # "Software"), to deal in the Software without restriction, including
   6 # without limitation the rights to use, copy, modify, merge, publish,
   7 # distribute, sub license, and/or sell copies of the Software, and to
   8 # permit persons to whom the Software is furnished to do so, subject to
   9 # the following conditions:
  10 #
  11 # The above copyright notice and this permission notice (including the
  12 # next paragraph) shall be included in all copies or substantial portions
  13 # of the Software.
  14 #
  15 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  16 # OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  17 # MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.
  18 # IN NO EVENT SHALL PRECISION INSIGHT AND/OR ITS SUPPLIERS BE LIABLE FOR
  19 # ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
  20 # TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
  21 # SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  22
  23 # VA-API version
  24 # - increment major for any ABI change (which shall not occur!)
  25 # - increment minor for any interface change (e.g. new/modified function)
  26 # - increment micro for any other change (new flag, new codec definition, etc.)
  27 # - reset micro version to zero when minor version is incremented
  28 # - reset minor version to zero when major version is incremented
  29 m4_define([va_api_major_version], [0])
  30 m4_define([va_api_minor_version], [32])
  31 m4_define([va_api_micro_version], [0])
  32
  33 m4_define([va_api_version],
  34           [va_api_major_version.va_api_minor_version.va_api_micro_version])
  35
  36 # libva package version number, (as distinct from shared library version)
  37 # XXX: we want the package version to remain at 1.0.x for VA-API 0.32.y
  38 #
  39 # - major version is automatically generated from VA-API major version
  40 # - minor version is automatically generated from VA-API minor version
  41 # - increment micro for any library release
  42 # - reset micro version to zero when VA-API major or minor version is changed
  43 m4_define([libva_major_version], [m4_eval(va_api_major_version + 1)])
  44 m4_define([libva_minor_version], [m4_eval(va_api_minor_version - 32)])
  45 m4_define([libva_micro_version], [14])
  46 m4_define([libva_pre_version],   [0])
  47
  48 m4_define([libva_version],
  49           [libva_major_version.libva_minor_version.libva_micro_version])
  50 m4_if(libva_pre_version, [0], [], [
  51 m4_append([libva_version], libva_pre_version, [.pre])
  52 ])
  53
  54 # libva library version number (generated, do not change)
  55 # XXX: we want the SONAME to remain at libva.so.1 for VA-API major == 0
  56 #
  57 # The library name is generated libva.<x>.<y>.0 where
  58 # <x> = VA-API major version + 1
  59 # <y> = 100 * VA-API minor version + VA-API micro version
  60 #
  61 # For example:
  62 # VA-API 0.32.0 generates libva.so.1.3200.0
  63 # VA-API 0.34.1 generates libva.so.1.3401.0
  64 # VA-API 1.2.13 generates libva.so.2.213.0
  65 m4_define([libva_interface_bias], [m4_eval(va_api_major_version + 1)])
  66 m4_define([libva_interface_age],  [0])
  67 m4_define([libva_binary_age],
  68           [m4_eval(100 * va_api_minor_version + va_api_micro_version - libva_interface_age)])
  69
  70 m4_define([libva_lt_current],
  71           [m4_eval(100 * va_api_minor_version + va_api_micro_version + libva_interface_bias)])
  72 m4_define([libva_lt_revision],
  73           [m4_eval(libva_interface_age)])
  74 m4_define([libva_lt_age],
  75           [m4_eval(libva_binary_age - libva_interface_age)])
  76
  77 AC_PREREQ(2.57)
  78 AC_INIT([libva], [libva_version], [waldo.bastian@intel.com], libva)
  79 AC_CONFIG_SRCDIR([Makefile.am])
  80 AM_INIT_AUTOMAKE([dist-bzip2])
  81
  82 AM_CONFIG_HEADER([config.h])
  83 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  84
  85 VA_API_MAJOR_VERSION=va_api_major_version
  86 VA_API_MINOR_VERSION=va_api_minor_version
  87 VA_API_MICRO_VERSION=va_api_micro_version
  88 VA_API_VERSION=va_api_version
  89 AC_SUBST(VA_API_MAJOR_VERSION)
  90 AC_SUBST(VA_API_MINOR_VERSION)
  91 AC_SUBST(VA_API_MICRO_VERSION)
  92 AC_SUBST(VA_API_VERSION)
  93
  94 LIBVA_MAJOR_VERSION=libva_major_version
  95 LIBVA_MINOR_VERSION=libva_minor_version
  96 LIBVA_MICRO_VERSION=libva_micro_version
  97 LIBVA_VERSION=libva_version
  98 AC_SUBST(LIBVA_MAJOR_VERSION)
  99 AC_SUBST(LIBVA_MINOR_VERSION)
 100 AC_SUBST(LIBVA_MICRO_VERSION)
 101 AC_SUBST(LIBVA_VERSION)
 102
 103 LIBVA_LT_CURRENT=libva_lt_current
 104 LIBVA_LT_REV=libva_lt_revision
 105 LIBVA_LT_AGE=libva_lt_age
 106 LIBVA_LT_VERSION="$LIBVA_LT_CURRENT:$LIBVA_LT_REV:$LIBVA_LT_AGE"
 107 LIBVA_LT_LDFLAGS="-version-info $LIBVA_LT_VERSION"
 108 AC_SUBST(LIBVA_LT_VERSION)
 109 AC_SUBST(LIBVA_LT_LDFLAGS)
 110
 111 AC_ARG_ENABLE(glx,
 112               [AC_HELP_STRING([--enable-glx],
 113                               [build with OpenGL for X11 support])],
 114               [], [enable_glx=yes])
 115
 116 AC_ARG_ENABLE(dummy-driver,
 117               [AC_HELP_STRING([--enable-dummy-driver],
 118                               [build dummy video driver])],
 119               [], [enable_dummy_driver=yes])
 120 AM_CONDITIONAL(BUILD_DUMMY_DRIVER, test x$enable_dummy_driver = xyes)
 121
 122 AC_ARG_ENABLE(dummy-backend,
 123               [AC_HELP_STRING([--enable-dummy-backend],
 124                               [build dummy libva backend])],
 125               [], [enable_dummy_backend=no])
 126
 127 AC_ARG_WITH(drivers-path,
 128             [AC_HELP_STRING([--with-drivers-path=[[path]]], [drivers path])],,
 129             [with_drivers_path="$libdir/dri"])
 130
 131 LIBVA_DRIVERS_PATH="$with_drivers_path"
 132 AC_SUBST(LIBVA_DRIVERS_PATH)
 133
 134 AC_DISABLE_STATIC
 135 AC_PROG_LIBTOOL
 136 AC_PROG_CC
 137 AC_PROG_CXX
 138
 139 AC_HEADER_STDC
 140 AC_SYS_LARGEFILE
 141
 142 PKG_CHECK_MODULES([X11], [x11])
 143 PKG_CHECK_MODULES([XEXT],[xext])
 144 PKG_CHECK_MODULES([XFIXES], [xfixes])
 145 PKG_CHECK_MODULES([DRM], [libdrm])
 146
 147 if test x$enable_dummy_backend = xyes; then
 148     PKG_CHECK_MODULES([UDEV], [libudev], [libudev=yes], [libudev=no])
 149 fi
 150 if test x$libudev = xno; then
 151    enable_dummy_backend=no
 152 fi
 153 AM_CONDITIONAL(BUILD_DUMMY_BACKEND, test x$enable_dummy_backend = xyes)
 154
 155 # Check for OpenGL (X11)
 156 USE_GLX="no"
 157 GL_DEPS_CFLAGS=""
 158 GL_DEPS_LIBS=""
 159 if test x$enable_glx = xyes; then
 160     AC_CHECK_HEADERS([GL/gl.h])
 161     AC_CHECK_HEADERS([GL/glx.h])
 162     AC_CHECK_LIB(GL, glXCreateContext, [
 163         USE_GLX="yes"
 164         GL_DEPS_LIBS="-lX11 -lGL"
 165     ])
 166 fi
 167 AC_SUBST(GL_DEPS_CFLAGS)
 168 AC_SUBST(GL_DEPS_LIBS)
 169 AM_CONDITIONAL(USE_GLX, test "$USE_GLX" = "yes")
 170
 171 # TBD: Check for EGL
 172 USE_EGL="yes"
 173 AM_CONDITIONAL(USE_EGL, test "$USE_EGL" = "yes")
 174
 175 # We only need the headers, we don't link against the DRM libraries
 176 LIBVA_CFLAGS="$DRM_CFLAGS"
 177 AC_SUBST(LIBVA_CFLAGS)
 178 AC_SUBST(LIBVA_LIBS)
 179
 180 pkgconfigdir=${libdir}/pkgconfig
 181 AC_SUBST(pkgconfigdir)
 182
 183 LIBVA_DISPLAY=x11
 184 libvacorelib=libva.la
 185 libvabackendlib=libva-$LIBVA_DISPLAY.la
 186 AC_SUBST([libvacorelib])
 187 AC_SUBST([libvabackendlib])
 188
 189 AC_OUTPUT([
 190         Makefile
 191         va/Makefile
 192         va/va_version.h
 193         va/x11/Makefile
 194         va/glx/Makefile
 195         va/egl/Makefile
 196         va/dummy/Makefile
 197         dummy_drv_video/Makefile
 198         test/Makefile
 199         test/basic/Makefile
 200         test/decode/Makefile
 201         test/putsurface/Makefile
 202         test/encode/Makefile
 203         test/vainfo/Makefile
 204         pkgconfig/libva-egl.pc
 205         pkgconfig/libva-glx.pc
 206         pkgconfig/libva-tpi.pc
 207         pkgconfig/libva-x11.pc
 208         pkgconfig/libva.pc
 209         pkgconfig/Makefile
 210 ])
 211
 212 # Print a small summary
 213
 214 echo ""
 215 echo "libva - ${LIBVA_VERSION} (VA-API ${VA_API_VERSION})"
 216 echo ""
 217
 218 echo " \95 Global :"
 219 echo "     Prefix: ${prefix}"
 220 echo ""
 221
 222 AS_IF([test x$enable_dummy_driver = xyes], [DRIVERS="dummy $DRIVERS"])
 223
 224 echo " \95 Drivers: ${DRIVERS}"
 225
 226 AS_IF([test x$USE_GLX = xyes], [BACKENDS="glx $BACKENDS"])
 227 AS_IF([test x$USE_EGL = xyes], [BACKENDS="egl $BACKENDS"])
 228
 229 BACKENDS="x11 $BACKENDS"
 230 AS_IF([test x$enable_dummy_backend = xyes], [BACKENDS="dummy
 231 $BACKENDS"])
 232
 233 echo " \95 Winsys : ${BACKENDS}"
 234