configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [0])
   4 m4_define([v_min], [9])
   5 m4_define([v_mic], [9])
   6 m4_define([v_rev], m4_esyscmd([(svnversion "${SVN_REPO_PATH:-.}" | grep -v export || echo 0) | awk -F : '{printf("%s\n", $1);}' | tr -d ' :MSP\n']))
   7 m4_if(v_rev, [0], [m4_define([v_rev], m4_esyscmd([git log 2> /dev/null | (grep -m1 git-svn-id || echo 0) | sed -e 's/.*@\([0-9]*\).*/\1/' | tr -d '\n']))])
   8 ##--   When released, remove the dnl on the below line
   9 dnl m4_undefine([v_rev])
  10 ##--   When doing snapshots - change soname. remove dnl on below line
  11 m4_define([relname], [ver-pre-svn-07])
  12 m4_define([v_rel], [-release relname])
  13 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  14 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])],
  15 [m4_define([v_ver], [v_maj.v_min.v_mic])])
  16 m4_define([lt_rev], m4_eval(v_maj + v_min))
  17 m4_define([lt_cur], v_mic)
  18 m4_define([lt_age], v_min)
  19 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  20 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  21
  22 AC_INIT([eina], [v_ver], [enlightenment-devel@lists.sourceforge.net])
  23 AC_PREREQ([2.59])
  24 AC_CONFIG_SRCDIR([configure.ac])
  25 AC_CONFIG_MACRO_DIR([m4])
  26 AC_CANONICAL_BUILD
  27 AC_CANONICAL_HOST
  28 AC_ISC_POSIX
  29
  30 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  31 AM_CONFIG_HEADER([config.h])
  32 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  33
  34 AC_LIBTOOL_WIN32_DLL
  35 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  36 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  37 AC_PROG_LIBTOOL
  38
  39 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  40 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  41 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  42 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  43 AC_DEFINE_UNQUOTED(VMAJ, [v_maj], [Major version])
  44 AC_DEFINE_UNQUOTED(VMIN, [v_min], [Minor version])
  45 AC_DEFINE_UNQUOTED(VMIC, [v_mic], [Micro version])
  46 AC_DEFINE_UNQUOTED(VREV, [v_rev], [Revison])
  47 version_info="lt_rev:lt_cur:lt_age"
  48 release_info="v_rel"
  49 AC_SUBST(version_info)
  50 AC_SUBST(release_info)
  51 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  52 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  53 VMAJ=v_maj
  54 AC_SUBST(VMAJ)
  55
  56 ### Needed information
  57
  58 requirement_eina=""
  59
  60 case "$host_os" in
  61    mingw32ce*)
  62       MODULE_ARCH="$host_os-$host_cpu"
  63       ;;
  64    *)
  65       MODULE_ARCH="$host_os-$host_cpu-$relname"
  66       ;;
  67 esac
  68 AC_SUBST(MODULE_ARCH)
  69 AC_DEFINE_UNQUOTED(MODULE_ARCH, "${MODULE_ARCH}", "Module architecture")
  70
  71 case "$host_os" in
  72    mingw*)
  73       MODULE_EXT=".dll"
  74       ;;
  75    *)
  76       MODULE_EXT=".so"
  77       ;;
  78 esac
  79
  80 AC_DEFINE_UNQUOTED(SHARED_LIB_SUFFIX, "${MODULE_EXT}", [Suffix for shared objects])
  81
  82 EFL_CHECK_CPU_MMX([have_mmx="yes"], [have_mmx="no"])
  83 EFL_CHECK_CPU_SSE([have_sse="yes"], [have_sse="no"])
  84 EFL_CHECK_CPU_SSE2([have_sse2="yes"], [have_sse2="no"])
  85 EFL_CHECK_CPU_ALTIVEC([have_altivec="yes"], [have_altivec="no"])
  86
  87 EFL_CHECK_THREADS(
  88    [
  89     if test "x${_efl_have_posix_threads}" = "xyes" ; then
  90        have_threads="POSIX"
  91     else
  92        if test "x${_efl_have_win32_threads}" = "xyes" ; then
  93           have_threads="Win32"
  94        else
  95           have_threads="no"
  96        fi
  97     fi
  98    ],
  99    [have_threads="no"])
 100 EFL_CHECK_SPINLOCK([have_posix_threads_spinlock="yes"], [have_posix_threads_spinlock="no"])
 101 EFL_CHECK_RWLOCK(
 102   [have_posix_threads_rwlock="yes"]
 103   EINA_CONFIGURE_RWLOCKS_ENABLED="#define EINA_RWLOCKS_ENABLED",
 104   [have_posix_threads_rwlock="no"])
 105 AC_SUBST([EINA_CONFIGURE_RWLOCKS_ENABLED])
 106
 107 ### Additional options to configure
 108
 109 # Magic debug
 110 AC_ARG_ENABLE([magic-debug],
 111    [AC_HELP_STRING([--disable-magic-debug], [disable magic debug of eina structure @<:@default=enabled@:>@])],
 112    [
 113     if test "x${enableval}" = "xyes" ; then
 114        have_magic_debug="yes"
 115     else
 116        have_magic_debug="no"
 117     fi
 118    ],
 119    [have_magic_debug="yes"])
 120
 121 AC_MSG_CHECKING([whether magic debug is enable])
 122 AC_MSG_RESULT([${have_magic_debug}])
 123
 124 if test "x${have_magic_debug}" = "xyes" ; then
 125    EINA_CONFIGURE_MAGIC_DEBUG="#define EINA_MAGIC_DEBUG"
 126 fi
 127 AC_SUBST(EINA_CONFIGURE_MAGIC_DEBUG)
 128
 129 # Safety checks (avoid crashes on wrong api usage)
 130 AC_ARG_ENABLE(safety-checks,
 131    [AC_HELP_STRING([--disable-safety-checks], [disable safety checks for NULL pointers and like. @<:@default=enabled@:>@])],
 132    [
 133     if test "x${enableval}" = "xyes" ; then
 134        have_safety_checks="yes"
 135     else
 136        have_safety_checks="no"
 137     fi
 138    ],
 139    [have_safety_checks="yes"])
 140
 141 AC_MSG_CHECKING(whether to do safety checking on api parameters)
 142 AC_MSG_RESULT($have_safety_checks)
 143
 144 AM_CONDITIONAL(SAFETY_CHECKS, test "x$have_safety_checks" = "xyes")
 145 if test "x$have_safety_checks" = "xyes"; then
 146   AC_DEFINE(EINA_SAFETY_CHECKS, 1, [disable safety checks for NULL pointers and like.])
 147   EINA_CONFIGURE_SAFETY_CHECKS="#define EINA_SAFETY_CHECKS"
 148 fi
 149 AC_SUBST(EINA_CONFIGURE_SAFETY_CHECKS)
 150
 151 with_max_log_level="<unset>"
 152 AC_ARG_WITH(internal-maximum-log-level,
 153    [AC_HELP_STRING([--with-internal-maximum-log-level=NUMBER],
 154                    [limit eina internal log level to the given number, any call to EINA_LOG() with values greater than this will be compiled out, ignoring runtime settings, but saving function calls.])],
 155    [
 156     if test "x${withval}" != "xno"; then
 157        if echo "${withval}" | grep '^[[0-9]]\+$' >/dev/null 2>/dev/null; then
 158           AC_MSG_NOTICE([ignoring any EINA_LOG() with level greater than ${withval}])
 159           AC_DEFINE_UNQUOTED(EINA_LOG_LEVEL_MAXIMUM, ${withval}, [if set, logging is limited to this amount.])
 160           with_max_log_level="${withval}"
 161        else
 162           AC_MSG_ERROR([--with-internal-maximum-log-level takes a decimal number, got "${withval}" instead.])
 163        fi
 164     fi
 165     ], [:])
 166
 167 AC_ARG_ENABLE([amalgamation],
 168    [AC_HELP_STRING([--enable-amalgamation], [enable generation of one single file with all source code in it, helps compiler optimizations.])],
 169    [if test "x${enableval}" = "xyes"; then
 170        do_amalgamation="yes"
 171     else
 172        do_amalgamation="no"
 173     fi
 174    ],
 175    [do_amalgamation="no"]
 176 )
 177 AM_CONDITIONAL(EINA_AMALGAMATION, test "x${do_amalgamation}" = "xyes")
 178
 179 # Choose best memory pool
 180 AC_ARG_ENABLE([default-mempool],
 181    [AC_HELP_STRING([--enable-default-mempool], [Default memory allocator could be faster for some computer. @<:@default=disabled@:>@])],
 182    [
 183     if test "x${enableval}" = "xyes"; then
 184        have_default_mempool="yes"
 185     else
 186        have_default_mempool="no"
 187     fi
 188    ],
 189    [have_default_mempool="no"]
 190 )
 191 AC_MSG_CHECKING([whether to use default mempool allocator])
 192 AC_MSG_RESULT([${have_default_mempool}])
 193
 194 if test "x${have_default_mempool}" = "xyes" ; then
 195    EINA_CONFIGURE_DEFAULT_MEMPOOL="#define EINA_DEFAULT_MEMPOOL"
 196 fi
 197 AC_SUBST(EINA_CONFIGURE_DEFAULT_MEMPOOL)
 198
 199 # Report stringshare usage
 200 AC_ARG_ENABLE([stringshare-usage],
 201    [AC_HELP_STRING([--enable-stringshare-usage], [Report stringshare usage on stringshare shutdown. @<:@default=disabled@:>@])],
 202    [
 203     if test "x${enableval}" = "xyes"; then
 204        have_stringshare_usage="yes"
 205     else
 206        have_stringshare_usage="no"
 207     fi
 208    ],
 209    [have_stringshare_usage="no"]
 210 )
 211 AC_MSG_CHECKING([whether to report stringshare usage])
 212 AC_MSG_RESULT([${have_stringshare_usage}])
 213
 214 if test "x${have_stringshare_usage}" = "xyes"; then
 215    AC_DEFINE(EINA_STRINGSHARE_USAGE, 1, [Report Eina stringshare usage pattern])
 216 fi
 217
 218 # Check if we want to benchmark on real data
 219 enable_benchmark_e17="no"
 220 AC_ARG_ENABLE([e17],
 221    [AC_HELP_STRING([--enable-e17], [enable heavy benchmark @<:@default=no@:>@])],
 222    [
 223     if test "x${enableval}" = "xyes" ; then
 224        enable_benchmark_e17="yes"
 225     else
 226        enable_benchmark_e17="no"
 227     fi
 228    ],
 229    [enable_benchmark_e17="no"])
 230
 231 AC_MSG_CHECKING([whether e17 real data benchmark are built])
 232 AC_MSG_RESULT([${enable_benchmark_e17}])
 233
 234 AM_CONDITIONAL(EINA_ENABLE_BENCHMARK_E17, test "x${enable_benchmark_e17}" = "xyes")
 235
 236
 237 ### Checks for programs
 238 AC_PROG_CC
 239
 240 # pkg-config
 241 PKG_PROG_PKG_CONFIG
 242
 243 # Check whether pkg-config supports Requires.private
 244 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
 245    pkgconfig_requires_private="Requires.private"
 246 else
 247    pkgconfig_requires_private="Requires"
 248 fi
 249 AC_SUBST(pkgconfig_requires_private)
 250
 251 # doxygen program for documentation building
 252
 253 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 254
 255
 256 ### Checks for libraries
 257
 258 # Evil library for compilation on Windows CE
 259
 260 EFL_EINA_BUILD=""
 261 case "$host_os" in
 262    mingw*)
 263       PKG_CHECK_MODULES([EVIL], [evil])
 264       AC_DEFINE(HAVE_EVIL, 1, [Set to 1 if evil package is installed])
 265       requirement_eina="evil"
 266       EFL_EINA_BUILD="-DEFL_EINA_BUILD"
 267    ;;
 268 esac
 269 AC_SUBST(EFL_EINA_BUILD)
 270
 271 # Check ememoa memory pool library
 272
 273 AC_ARG_ENABLE([ememoa],
 274    [AC_HELP_STRING([--enable-ememoa], [build ememoa memory pool module @<:@default=yes@:>@])],
 275    [
 276     if test "x${enableval}" = "xyes" ; then
 277        enable_ememoa="yes"
 278     else
 279        enable_ememoa="no"
 280     fi
 281    ],
 282    [enable_ememoa="yes"]
 283 )
 284 AC_MSG_CHECKING([whether to use ememoa for memory pool])
 285 AC_MSG_RESULT([$enable_ememoa])
 286
 287 if test "x${enable_ememoa}" = "xyes" ; then
 288    PKG_CHECK_MODULES([EMEMOA],
 289       [ememoa >= 0.0.26 ],
 290       [enable_ememoa="yes"],
 291       [enable_ememoa="no"]
 292    )
 293 fi
 294
 295
 296 ### Checks for header files
 297 AC_HEADER_ASSERT
 298 AC_HEADER_DIRENT
 299 AC_HEADER_TIME
 300
 301
 302 ### Checks for types
 303 AC_CHECK_HEADER([inttypes.h],
 304                 [EINA_CONFIGURE_HAVE_INTTYPES_H="#define EINA_HAVE_INTTYPES_H"])
 305 AC_SUBST(EINA_CONFIGURE_HAVE_INTTYPES_H)
 306
 307 AC_CHECK_HEADER([stdint.h],
 308                 [EINA_CONFIGURE_HAVE_STDINT_H="#define EINA_HAVE_STDINT_H"])
 309 AC_SUBST(EINA_CONFIGURE_HAVE_STDINT_H)
 310
 311 AC_CHECK_SIZEOF(wchar_t)
 312 EINA_SIZEOF_WCHAR_T=$ac_cv_sizeof_wchar_t
 313 AC_SUBST(EINA_SIZEOF_WCHAR_T)
 314
 315 ### Checks for structures
 316
 317
 318 ### Checks for compiler characteristics
 319 AC_C_CONST
 320 AC_C_BIGENDIAN
 321 AC_C_INLINE
 322 AC_C___ATTRIBUTE__
 323 AC_PROG_CC_STDC
 324
 325 EINA_CPPFLAGS=""
 326 EINA_CFLAGS=""
 327 case "$host_os" in
 328    mingw32ce*)
 329       EINA_CPPFLAGS="-D_WIN32_WCE=0x0420"
 330       EINA_CFLAGS="${EVIL_CFLAGS}"
 331       ;;
 332    mingw*)
 333       EINA_CPPFLAGS="-D_WIN32_WINNT=0x0501"
 334       EINA_CFLAGS="${EVIL_CFLAGS}"
 335       ;;
 336 esac
 337
 338 m4_ifdef([v_mic],
 339    [
 340     EFL_COMPILER_FLAG([-Wall])
 341     EFL_COMPILER_FLAG([-W])
 342    ])
 343
 344 EFL_COMPILER_FLAG([-Wshadow])
 345
 346 AC_SUBST(EINA_CPPFLAGS)
 347 AC_SUBST(EINA_CFLAGS)
 348
 349
 350 ### Checks for linker characteristics
 351 EINA_LIBS=
 352 lt_enable_auto_import=""
 353 case "${host_os}" in
 354    mingw*)
 355       EINA_LIBS="-ldl ${EVIL_LIBS} -lm"
 356       lt_enable_auto_import="-Wl,--enable-auto-import"
 357    ;;
 358    dragonfly*|openbsd*)
 359       EINA_LIBS="-lm"
 360    ;;
 361    freebsd*|netbsd*)
 362       EINA_LIBS="-lrt -lm"
 363    ;;
 364    darwin*)
 365       EINA_LIBS="-lm"
 366    ;;
 367    cygwin*)
 368       EINA_LIBS="-ldl -lm"
 369    ;;
 370    *)
 371       EINA_LIBS="-ldl -lrt -lm"
 372    ;;
 373 esac
 374 AC_SUBST(EINA_LIBS)
 375 AC_SUBST(lt_enable_auto_import)
 376
 377 EFL_LINKER_FLAG([-fno-strict-aliasing])
 378
 379
 380 ### Checks for library functions
 381 AC_FUNC_ALLOCA
 382 AC_CHECK_FUNCS(strlcpy)
 383
 384 #dlopen and dladdr
 385 dlopen_libs=""
 386 case "$host_os" in
 387    mingw*)
 388 # managed by evil
 389       AC_DEFINE(HAVE_DLADDR)
 390       ;;
 391    *)
 392       AC_CHECK_FUNCS([dlopen], [res="yes"], [res="no"])
 393       if test "x${res}" = "xyes" ; then
 394          AC_CHECK_FUNCS([dladdr], [AC_DEFINE(HAVE_DLADDR)])
 395       else
 396          AC_CHECK_LIB([dl], [dlopen], [res="yes"], [res="no"])
 397          if test "x${res}" = "xyes" ; then
 398             AC_CHECK_LIB([dl], [dladdr], [AC_DEFINE(HAVE_DLADDR)])
 399             dlopen_libs="-ldl"
 400          else
 401             AC_MSG_ERROR([Cannot find dlopen])
 402          fi
 403       fi
 404       ;;
 405 esac
 406 AC_SUBST(dlopen_libs)
 407
 408 EFL_CHECK_FNMATCH([], [AC_MSG_ERROR([Cannot find fnmatch()])])
 409
 410 # iconv library
 411 have_iconv="no"
 412 AC_ARG_WITH([iconv-link],
 413    AC_HELP_STRING([--with-iconv-link=ICONV_LINK], [explicitly specify an iconv link option]),
 414    [
 415     LIBS="$withval $LIBS"
 416     have_iconv="yes"
 417    ])
 418
 419 AC_MSG_CHECKING(for explicit iconv link options)
 420 if test "x${iconv_libs}" = "x" ; then
 421    AC_MSG_RESULT([no explicit iconv link option])
 422 else
 423    AC_MSG_RESULT([$iconv_libs])
 424 fi
 425
 426 if test "x${have_iconv}" = "xno" ; then
 427    AC_CHECK_HEADERS([iconv.h], [have_iconv="yes"])
 428
 429    if test "x${have_iconv}" = "xyes" ; then
 430       AC_MSG_CHECKING([whether iconv() is in libc])
 431
 432       AC_LINK_IFELSE(
 433          [AC_LANG_PROGRAM(
 434              [[
 435 #include <stdlib.h>
 436 #include <iconv.h>
 437              ]],
 438              [[
 439 iconv_t ic;
 440 size_t count = iconv(ic, NULL, NULL, NULL, NULL);
 441              ]])],
 442          [have_iconv="yes"],
 443          [have_iconv="no"])
 444
 445       AC_MSG_RESULT([${have_iconv}])
 446    fi
 447
 448    if test "x${have_iconv}" = "xno" ; then
 449       AC_MSG_CHECKING([whether iconv() is in libiconv.a])
 450
 451       LIBS_save="${LIBS}"
 452       LIBS="-liconv $LIBS"
 453       AC_LINK_IFELSE(
 454          [AC_LANG_PROGRAM(
 455              [[
 456 #include <stdlib.h>
 457 #include <iconv.h>
 458              ]],
 459              [[
 460 iconv_t ic;
 461 size_t count;
 462 count = iconv(ic, NULL, NULL, NULL, NULL);
 463              ]])],
 464          [have_iconv="yes"],
 465          [
 466           have_iconv="no"
 467           LIBS=${LIBS_save}
 468          ])
 469
 470       AC_MSG_RESULT([${have_iconv}])
 471    fi
 472
 473    if test "x${have_iconv}" = "xno" ; then
 474       AC_MSG_CHECKING([whether iconv() is in libiconv_plug.a])
 475
 476       LIBS_save="${LIBS}"
 477       LIBS="-liconv_plug $LIBS"
 478       AC_LINK_IFELSE(
 479          [AC_LANG_PROGRAM(
 480              [[
 481 #include <stdlib.h>
 482 #include <iconv.h>
 483              ]],
 484              [[
 485 iconv_t ic;
 486 size_t count = iconv(ic, NULL, NULL, NULL, NULL);
 487              ]])],
 488          [have_iconv="yes"],
 489          [
 490           have_iconv="no"
 491           LIBS=${LIBS_save}
 492          ])
 493
 494       AC_MSG_RESULT([${have_iconv}])
 495    fi
 496 fi
 497
 498 if test "x${have_iconv}" = "xyes" ; then
 499    AC_DEFINE([HAVE_ICONV], [1], [Set to 1 if iconv library is installed])
 500 fi
 501
 502
 503 ### Modules
 504
 505 if test "x${have_default_mempool}" = "xyes" ; then
 506    enable_chained_pool="no"
 507    enable_pass_through="static"
 508 else
 509    enable_chained_pool="static"
 510    enable_pass_through="no"
 511 fi
 512
 513 enable_one_big="static"
 514
 515 EINA_CHECK_MODULE([chained-pool],   [${enable_chained_pool}], [chained pool])
 516 EINA_CHECK_MODULE([ememoa-fixed],   [${enable_ememoa}],       [ememoa fixed])
 517 EINA_CHECK_MODULE([ememoa-unknown], [${enable_ememoa}],       [ememoa unknown])
 518 EINA_CHECK_MODULE([fixed-bitmap],   [no],                     [fixed bitmap])
 519 EINA_CHECK_MODULE([pass-through],   [${enable_pass_through}], [pass through])
 520 EINA_CHECK_MODULE([buddy],          [no],                     [buddy])
 521 EINA_CHECK_MODULE([one-big],        [${enable_one_big}],      [one big])
 522
 523 ### Make the debug preprocessor configurable
 524
 525 ### Unit tests, coverage and benchmarking
 526
 527 EFL_CHECK_TESTS([enable_tests="yes"], [enable_tests="no"])
 528
 529 EFL_CHECK_COVERAGE([${enable_tests}], [enable_coverage="yes"], [enable_coverage="no"])
 530 EINA_CFLAGS="${EINA_CFLAGS} ${EFL_COVERAGE_CFLAGS}"
 531 EINA_LIBS="${EINA_LIBS} ${EFL_COVERAGE_LIBS}"
 532 if test "x$enable_coverage" = "xyes" ; then
 533    EINA_CFLAGS="${EINA_CFLAGS} ${EFL_DEBUG_CFLAGS}"
 534 fi
 535
 536 EFL_CHECK_BENCHMARK([enable_benchmark="yes"], [enable_benchmark="no"])
 537 EINA_BENCH_MODULE([glib], [${enable_benchmark}], [glib-2.0], [enable_benchmark_glib="yes"], [enable_benchmark_glib="no"])
 538
 539 AC_SUBST(requirement_eina)
 540
 541 ### Create the .pc.in file according to the major version
 542 #cat > ${srcdir}/eina-${VMAJ}.pc.in << EOF
 543 #prefix=@prefix@
 544 #exec_prefix=@exec_prefix@
 545 #libdir=@libdir@
 546 #includedir=@includedir@
 547 #
 548 #Name: Eina
 549 #Description: A Library that implements fast data types and miscellaneous tools
 550 #Requires:
 551 #Version: @VERSION@
 552 #Libs: -L${libdir} -leina
 553 #Libs.private: -ldl
 554 #Cflags: -I${includedir}/eina-@VMAJ@ -I${includedir}/eina-@VMAJ@/eina
 555 #EOF
 556
 557 AC_CONFIG_FILES([
 558 Makefile
 559 eina-0.pc
 560 eina.spec
 561 doc/Makefile
 562 src/Makefile
 563 src/include/Makefile
 564 src/include/eina_config.h
 565 src/lib/Makefile
 566 src/modules/Makefile
 567 src/modules/mp/Makefile
 568 src/modules/mp/chained_pool/Makefile
 569 src/modules/mp/ememoa_fixed/Makefile
 570 src/modules/mp/ememoa_unknown/Makefile
 571 src/modules/mp/pass_through/Makefile
 572 src/modules/mp/fixed_bitmap/Makefile
 573 src/modules/mp/buddy/Makefile
 574 src/modules/mp/one_big/Makefile
 575 src/tests/Makefile
 576 ])
 577
 578 AC_OUTPUT
 579
 580 #####################################################################
 581 ## Info
 582
 583 echo
 584 echo
 585 echo
 586 echo "------------------------------------------------------------------------"
 587 echo "$PACKAGE $VERSION"
 588 echo "------------------------------------------------------------------------"
 589 echo
 590 echo
 591 echo "Configuration Options Summary:"
 592 echo
 593 echo "  Magic debug..........: ${have_magic_debug}"
 594 echo "  Safety checks........: ${have_safety_checks}"
 595 echo "  Maximum log level....: ${with_max_log_level}"
 596 echo "  Report string usage..: ${have_stringshare_usage}"
 597 echo "  Default mempool......: ${have_default_mempool}"
 598 echo "  Thread Support.......: ${have_threads}"
 599 if test "${have_threads}" = "POSIX" ; then
 600 echo "    spinlock...........: ${have_posix_threads_spinlock}"
 601 echo "    rwlock.............: ${have_posix_threads_rwlock}"
 602 fi
 603 echo "  Amalgamation.........: ${do_amalgamation}"
 604 echo "  Iconv support........: ${have_iconv}"
 605 echo
 606 echo "  Documentation........: ${build_doc}"
 607 echo "  Tests................: ${enable_tests}"
 608 echo "  Coverage.............: ${enable_coverage}"
 609 echo "  Benchmark............: ${enable_benchmark}"
 610 if test "x${enable_benchmark}" = "xyes" ; then
 611 echo "    Glib...............: ${enable_benchmark_glib}"
 612 echo "    E17 real data......: ${enable_benchmark_e17}"
 613 fi
 614 echo
 615 echo "  CPU Specific Extensions:"
 616 echo "    MMX................: ${have_mmx}"
 617 echo "    SSE................: ${have_sse}"
 618 echo "    SSE2...............: ${have_sse2}"
 619 echo "    ALTIVEC............: ${have_altivec}"
 620 echo
 621 echo "  Memory pools:"
 622 echo "    Chained pool.......: ${enable_chained_pool}"
 623 echo "    Ememoa fixed.......: ${enable_ememoa_fixed}"
 624 echo "    Ememoa unknown.....: ${enable_ememoa_unknown}"
 625 echo "    Fixed bitmap.......: ${enable_fixed_bitmap}"
 626 echo "    Pass through.......: ${enable_pass_through}"
 627 echo "    Buddy..............: ${enable_buddy}"
 628 echo "    One big............: ${enable_one_big}"
 629 echo
 630 echo "Compilation............: make (or gmake)"
 631 echo "  CPPFLAGS.............: $CPPFLAGS"
 632 echo "  CFLAGS...............: $CFLAGS"
 633 echo "  LDFLAGS..............: $LDFLAGS"
 634 echo
 635 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
 636 echo "  prefix...............: $prefix"
 637 echo
 638 EFL_FORM_VOLTRON