configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.11.0.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.11
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 AG_GST_LIBTOOL_PREPARE
  47
  48 dnl FIXME: this macro doesn't actually work;
  49 dnl the generated libtool script has no support for the listed tags.
  50 dnl So this needs to be fixed first if we want to use this
  51 dnl AS_LIBTOOL_TAGS
  52
  53 AC_LIBTOOL_WIN32_DLL
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** required versions of GStreamer stuff ***
  57 GST_REQ=0.11.0
  58 GSTPB_REQ=0.11.0
  59
  60 dnl *** autotools stuff ****
  61
  62 dnl allow for different autotools
  63 AS_AUTOTOOLS_ALTERNATE
  64
  65 dnl Add parameters for aclocal
  66 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  67
  68 dnl set up gettext
  69 dnl the version check needs to stay here because autopoint greps for it
  70 AM_GNU_GETTEXT_VERSION([0.17])
  71 AM_GNU_GETTEXT([external])
  72 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  73
  74 dnl *** check for arguments to configure ***
  75
  76 AG_GST_ARG_DEBUG
  77 AG_GST_ARG_PROFILING
  78 AG_GST_ARG_VALGRIND
  79 AG_GST_ARG_GCOV
  80
  81 AG_GST_ARG_EXAMPLES
  82
  83 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  84 AG_GST_ARG_WITH_PACKAGE_NAME
  85 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  86
  87 AG_GST_ARG_WITH_PLUGINS
  88
  89 AG_GST_ARG_ENABLE_EXTERNAL
  90
  91 AG_GST_ARG_ENABLE_EXPERIMENTAL
  92
  93 dnl *** checks for platform ***
  94
  95 dnl * hardware/architecture *
  96
  97 dnl common/m4/gst-arch.m4
  98 dnl check CPU type
  99 AG_GST_ARCH
 100
 101 dnl Determine endianness
 102 AC_C_BIGENDIAN
 103
 104 dnl *** checks for programs ***
 105
 106 dnl find a compiler
 107 AC_PROG_CC
 108 AC_PROG_CC_STDC
 109
 110 dnl determine c++ compiler
 111 AC_PROG_CXX
 112 dnl determine if c++ is available on this system
 113 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 114
 115 dnl determine c++ preprocessor
 116 dnl FIXME: do we need this ?
 117 AC_PROG_CXXCPP
 118
 119 AS_PROG_OBJC
 120
 121 dnl check if the compiler supports '-c' and '-o' options
 122 AM_PROG_CC_C_O
 123
 124 dnl find an assembler
 125 AM_PROG_AS
 126
 127 dnl check if the compiler supports do while(0) macros
 128 AG_GST_CHECK_DOWHILE_MACROS
 129
 130 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 131 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 132
 133 dnl check for documentation tools
 134 GTK_DOC_CHECK([1.3])
 135 AS_PATH_PYTHON([2.1])
 136 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 137
 138 dnl *** checks for libraries ***
 139
 140 dnl check for libm, for sin()
 141 AC_CHECK_LIBM
 142 AC_SUBST(LIBM)
 143
 144 dnl *** checks for header files ***
 145
 146 dnl check if we have ANSI C header files
 147 AC_HEADER_STDC
 148
 149 dnl used by ext/wavpack
 150 AX_CREATE_STDINT_H
 151
 152 dnl used in gst/rtp/gstasteriskh263.c
 153 AC_CHECK_HEADERS([netinet/in.h])
 154 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 155 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 156
 157 dnl used in gst/udp
 158 AC_CHECK_HEADERS([sys/time.h])
 159
 160 dnl *** checks for types/defines ***
 161
 162 dnl Check for FIONREAD ioctl declaration.  This check is needed
 163 dnl for the UDP plugin to build on Solaris
 164 GST_CHECK_FIONREAD
 165
 166 dnl *** checks for structures ***
 167
 168 dnl *** checks for compiler characteristics ***
 169
 170 dnl check if we have GCC inline-asm
 171 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 172 if test x$HAVE_GCC_ASM = xyes ; then
 173   AC_DEFINE(HAVE_GCC_ASM, 1,
 174     [Define if compiler supports gcc inline assembly])
 175 fi
 176 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 177
 178 dnl *** checks for library functions ***
 179
 180 LIBS_SAVE=$LIBS
 181 LIBS="$LIBS $LIBM"
 182 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 183 LIBS=$LIBS_SAVE
 184
 185 dnl Check whether isinf() is defined by math.h
 186 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 187     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 188 if test "$ac_cv_have_isinf" = "yes"
 189 then
 190     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 191 fi
 192
 193 dnl Check for mmap (needed by electricfence plugin)
 194 AC_FUNC_MMAP
 195 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 196
 197 dnl Check for mmap (needed by electricfence plugin)
 198
 199 AC_CHECK_TYPE([struct ip_mreqn], [
 200               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 201               [#include <netinet/in.h>])
 202
 203 dnl *** checks for dependency libraries ***
 204
 205 dnl GLib is required
 206 AG_GST_GLIB_CHECK([2.20])
 207
 208 dnl Orc
 209 ORC_CHECK([0.4.11])
 210
 211 dnl checks for gstreamer
 212 dnl uninstalled is selected preferentially -- see pkg-config(1)
 213 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 214 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 215 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 216 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 217 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 218 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 219
 220 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 221 if test -z $GST_TOOLS_DIR; then
 222   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 223 fi
 224 AC_SUBST(GST_TOOLS_DIR)
 225
 226 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 227 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 228
 229 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 230
 231 dnl Check for documentation xrefs
 232 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 233 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 234 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 235 AC_SUBST(GLIB_PREFIX)
 236 AC_SUBST(GST_PREFIX)
 237 AC_SUBST(GSTPB_PREFIX)
 238
 239 dnl GTK is optional and used in examples
 240 HAVE_GTK=no
 241 GTK2_REQ=2.14.0
 242 GTK3_REQ=2.91.3
 243 if test "x$BUILD_EXAMPLES" = "xyes"; then
 244   AC_MSG_CHECKING([which gtk+ version to compile examples against (optional)])
 245   AC_ARG_WITH([gtk],
 246     AC_HELP_STRING([--with-gtk=3.0|2.0],
 247                    [which gtk+ version to compile against (default: 2.0)]),
 248     [case "$with_gtk" in
 249         2.0) GTK_REQ=$GTK2_REQ ;;
 250         3.0) GTK_REQ=$GTK3_REQ ;;
 251         *) AC_MSG_ERROR([invalid gtk+ version specified]);;
 252     esac],
 253     [with_gtk=2.0
 254      GTK_REQ=$GTK2_REQ])
 255   AC_MSG_RESULT([$with_gtk (>= $GTK_REQ)])
 256   PKG_CHECK_MODULES(GTK, gtk+-$with_gtk >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 257   dnl some examples need gtk+-x11
 258   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-$with_gtk >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 259   AC_SUBST(GTK_LIBS)
 260   AC_SUBST(GTK_CFLAGS)
 261 fi
 262 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 263 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 264
 265 dnl *** set variables based on configure arguments ***
 266
 267 dnl set license and copyright notice
 268 GST_LICENSE="LGPL"
 269 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 270 AC_SUBST(GST_LICENSE)
 271
 272 dnl set location of plugin directory
 273 AG_GST_SET_PLUGINDIR
 274
 275 dnl set release date/time
 276 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 277   ["${srcdir}/gst-plugins-good.doap"],
 278   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 279
 280 dnl define an ERROR_CFLAGS Makefile variable
 281 dnl -Wundef: too many broken headers
 282 if test "x$HAVE_OSX_VIDEO" != "xyes"; then
 283   AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 284         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 285         -Wwrite-strings -Wold-style-definition -Waggregate-return
 286         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 287         -Wnested-externs ])
 288 else
 289   dnl work-around for us passing GST_CFLAGS to the ObjC-compiler, which
 290   dnl doesn't understand all warning flags that the C compiler knows about
 291   dnl (e.g. -Waddress) or causes problems with some flags (-Waggregate-return)
 292   AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 293         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 294         -Wwrite-strings -Wold-style-definition
 295         -Winit-self -Wmissing-include-dirs -Wno-multichar
 296         -Wnested-externs ])
 297 fi
 298
 299 dnl define an ERROR_CXXFLAGS Makefile variable
 300 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 301         -Wmissing-declarations -Wredundant-decls
 302         -Wwrite-strings
 303         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar ])
 304
 305 dnl define correct level for debugging messages
 306 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 307
 308 dnl used in examples
 309 AG_GST_DEFAULT_ELEMENTS
 310
 311 dnl *** plug-ins to include ***
 312
 313 dnl these are all the gst plug-ins, compilable without additional libs
 314 dnl videofilter is at the top because others depend on it
 315 AG_GST_CHECK_PLUGIN(videofilter)
 316 AG_GST_CHECK_PLUGIN(alpha)
 317 AG_GST_CHECK_PLUGIN(apetag)
 318 AG_GST_CHECK_PLUGIN(audiofx)
 319 AG_GST_CHECK_PLUGIN(audioparsers)
 320 AG_GST_CHECK_PLUGIN(auparse)
 321 AG_GST_CHECK_PLUGIN(autodetect)
 322 AG_GST_CHECK_PLUGIN(avi)
 323 AG_GST_CHECK_PLUGIN(cutter)
 324 AG_GST_CHECK_PLUGIN(debugutils)
 325 AG_GST_CHECK_PLUGIN(deinterlace)
 326 AG_GST_CHECK_PLUGIN(effectv)
 327 AG_GST_CHECK_PLUGIN(equalizer)
 328 AG_GST_CHECK_PLUGIN(flv)
 329 AG_GST_CHECK_PLUGIN(id3demux)
 330 AG_GST_CHECK_PLUGIN(icydemux)
 331 AG_GST_CHECK_PLUGIN(interleave)
 332 AG_GST_CHECK_PLUGIN(flx)
 333 AG_GST_CHECK_PLUGIN(goom)
 334 AG_GST_CHECK_PLUGIN(goom2k1)
 335 AG_GST_CHECK_PLUGIN(imagefreeze)
 336 AG_GST_CHECK_PLUGIN(isomp4)
 337 AG_GST_CHECK_PLUGIN(law)
 338 AG_GST_CHECK_PLUGIN(level)
 339 AG_GST_CHECK_PLUGIN(matroska)
 340 AG_GST_CHECK_PLUGIN(monoscope)
 341 AG_GST_CHECK_PLUGIN(multifile)
 342 AG_GST_CHECK_PLUGIN(multipart)
 343 AG_GST_CHECK_PLUGIN(replaygain)
 344 AG_GST_CHECK_PLUGIN(rtp)
 345 AG_GST_CHECK_PLUGIN(rtpmanager)
 346 AG_GST_CHECK_PLUGIN(rtsp)
 347 AG_GST_CHECK_PLUGIN(shapewipe)
 348 AG_GST_CHECK_PLUGIN(smpte)
 349 AG_GST_CHECK_PLUGIN(spectrum)
 350 AG_GST_CHECK_PLUGIN(udp)
 351 AG_GST_CHECK_PLUGIN(videobox)
 352 AG_GST_CHECK_PLUGIN(videocrop)
 353 AG_GST_CHECK_PLUGIN(videomixer)
 354 AG_GST_CHECK_PLUGIN(wavenc)
 355 AG_GST_CHECK_PLUGIN(wavparse)
 356 AG_GST_CHECK_PLUGIN(y4m)
 357
 358 dnl *** checks for socket and nsl libraries ***
 359 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 360
 361 dnl disable gst plugins we might not be able to build on this
 362 dnl platform: udp and rtsp (ugly but minimally invasive)
 363 dnl FIXME: maybe move to sys
 364 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 365 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 366
 367 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 368   AG_GST_DISABLE_PLUGIN(udp)
 369   AG_GST_DISABLE_PLUGIN(rtsp)
 370 fi
 371
 372 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 373   WIN32_LIBS="-lws2_32"
 374   AC_SUBST(WIN32_LIBS)
 375 fi
 376
 377 dnl disable experimental plug-ins
 378 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 379   AG_GST_DISABLE_PLUGIN(monoscope)
 380 fi
 381
 382 dnl *** sys plug-ins ***
 383
 384 echo
 385 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 386 echo
 387
 388 dnl DirectSound
 389 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 390 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 391   HAVE_DIRECTSOUND="no"
 392   save_CFLAGS="$CFLAGS"
 393   save_LDFLAGS="$LDFLAGS"
 394   save_LIBS="$LIBS"
 395   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 396   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 397   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 398   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 399   AC_LINK_IFELSE([
 400 #include <windows.h>
 401 #include <dxerr9.h>
 402 #include <dsound.h>
 403
 404 int main ()
 405 {
 406   DXGetErrorString9 (0);
 407   DirectSoundCreate(NULL, NULL, NULL);
 408
 409   return 0;
 410 }
 411 ],
 412     [HAVE_DIRECTSOUND="yes"],
 413     [HAVE_DIRECTSOUND="no"])
 414   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 415   CFLAGS=$save_CFLAGS
 416   LDFLAGS=$save_LDFLAGS
 417   LIBS=$save_LIBS
 418
 419   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 420     dnl this is much more than we want
 421     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 422     AC_SUBST(DIRECTSOUND_CFLAGS)
 423     AC_SUBST(DIRECTSOUND_LDFLAGS)
 424     AC_SUBST(DIRECTSOUND_LIBS)
 425   fi
 426   AC_SUBST(HAVE_DIRECTSOUND)
 427 ])
 428
 429 dnl *** OSS audio *** (Linux, *BSD)
 430 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 431 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 432  HAVE_OSS="yes"
 433 dnl Linux and newer BSD versions :
 434  AC_CHECK_HEADER(sys/soundcard.h, [
 435    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 436    ] , [
 437 dnl Some old BSD versions and also newer OpenBSD versions :
 438    AC_CHECK_HEADER(soundcard.h, [
 439      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 440      ], [
 441   dnl Some old BSD versions :
 442      AC_CHECK_HEADER(machine/soundcard.h, [
 443        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 444          [Define if OSS includes are in /machine/])
 445        ], [
 446        HAVE_OSS="no"
 447      ])
 448    ])
 449  ])
 450 ])
 451
 452 dnl *** oss4 ***
 453 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 454 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 455   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 456   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 457       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 458       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 459 ])
 460
 461 dnl *** Sun Audio ***
 462 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 463 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 464   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 465 ])
 466
 467 dnl *** OSX Audio ***
 468 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 469 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 470   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 471 ])
 472
 473 dnl *** OS X video ***
 474 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 475 HAVE_OSX_VIDEO="no"
 476 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 477   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 478 ])
 479 dnl in case header OpenGL/gl.h is found on other platforms
 480 case "$host" in
 481   *-*darwin*)
 482     dnl do nothing
 483     ;;
 484   *)
 485     HAVE_OSX_VIDEO="no"
 486     ;;
 487 esac
 488
 489
 490 dnl *** Video 4 Linux 2 ***
 491 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 492 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 493 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 494 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 495   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 496   AC_TRY_COMPILE([
 497 #include <sys/types.h>
 498 #ifdef __sun /* Solaris */
 499 #include <sys/types.h>
 500 #include <sys/videodev2.h>
 501 #else /* Linux */
 502 #include <linux/types.h>
 503 #define _LINUX_TIME_H
 504 #define __user
 505 #include <linux/videodev2.h>
 506 #endif
 507 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 508 #error too early v4l2 version or no v4l2 at all
 509 #endif
 510     ], [
 511 return 0;
 512     ], [
 513       HAVE_GST_V4L2="yes"
 514       AC_MSG_RESULT(yes)
 515     ], [
 516       HAVE_GST_V4L2="no"
 517       AC_MSG_RESULT(no)
 518
 519       HAVE_VIDEODEV=no
 520       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 521       [
 522         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 523       ])
 524
 525       if test "x$HAVE_VIDEODEV" = "xyes"; then
 526         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 527         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 528       else
 529         AC_MSG_WARN([video4linux2 was not found])
 530       fi
 531     ])
 532
 533   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 534     dnl check for missing v4l2_buffer declaration (see #135919)
 535     MISSING_DECL=0
 536     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 537     AC_TRY_COMPILE([
 538 #include <sys/types.h>
 539 #ifdef __sun /* Solaris */
 540 #include <sys/types.h>
 541 #include <sys/videodev2.h>
 542 #else /* Linux */
 543 #include <linux/types.h>
 544 #define _LINUX_TIME_H
 545 #define __user
 546 #include <linux/videodev2.h>
 547 #endif
 548     ],[
 549 struct v4l2_buffer buf;
 550 buf.index = 0;
 551 return 0;
 552     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 553     if [ test x$MISSING_DECL = x1 ]; then
 554       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 555     fi
 556
 557     dnl check for XOverlay libraries
 558     AG_GST_CHECK_XV
 559   fi
 560 ])
 561
 562 # Optional gudev for device probing
 563 AC_ARG_WITH([gudev],
 564   AC_HELP_STRING([--with-gudev],
 565     [device detection with gudev]),
 566   [],
 567   [with_gudev=check])
 568 if test x$HAVE_GST_V4L2 = xyes; then
 569   if test x$with_gudev != xno; then
 570       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 571           [ have_gudev=yes
 572             AC_DEFINE(HAVE_GUDEV, 1,
 573                [Whether gudev is available for device detection])
 574             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 575           ], [
 576           have_gudev=no
 577           ])
 578   else
 579     have_gudev=no
 580   fi
 581 fi
 582 AC_SUBST(GUDEV_CFLAGS)
 583 AC_SUBST(GUDEV_LIBS)
 584
 585 # Make libv4l2 non-automagic
 586 AC_ARG_WITH([libv4l2],
 587   AC_HELP_STRING([--with-libv4l2],
 588     [support video buffer conversion using libv4l2]),
 589   [],
 590   [with_libv4l2=check])
 591 if test x$HAVE_GST_V4L2 = xyes; then
 592   if test x$with_libv4l2 != xno; then
 593       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 594           [ have_libv4l2=yes
 595             AC_DEFINE(HAVE_LIBV4L2, 1,
 596                 [Whether libv4l2 is available for video buffer conversion])
 597           ], [
 598           have_libv4l2=no
 599           ])
 600   else
 601     have_libv4l2=no
 602   fi
 603 fi
 604
 605 dnl Check for X11
 606 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 607 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 608                   [ximagesrc], [
 609   AC_PATH_XTRA
 610
 611   dnl now try to find the HEADER
 612   ac_cflags_save="$CFLAGS"
 613   ac_cppflags_save="$CPPFLAGS"
 614   CFLAGS="$CFLAGS $X_CFLAGS"
 615   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 616   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 617
 618   if test "x$HAVE_X" = "xno"
 619   then
 620     AC_MSG_NOTICE([cannot find X11 development files])
 621   else
 622     dnl this is much more than we want
 623     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 624     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 625     dnl it does not add the libs; therefore we add them here
 626     X_LIBS="$X_LIBS -lX11"
 627     AC_SUBST(X_CFLAGS)
 628     AC_SUBST(X_LIBS)
 629
 630     dnl check for Xfixes
 631     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 632     if test "x$HAVE_XFIXES" = "xyes"
 633     then
 634         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 635     fi
 636     AC_SUBST(XFIXES_LIBS)
 637     AC_SUBST(XFIXES_CFLAGS)
 638
 639     dnl check for Xdamage
 640     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 641     if test "x$HAVE_XDAMAGE" = "xyes"
 642     then
 643         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 644     fi
 645     AC_SUBST(XDAMAGE_LIBS)
 646     AC_SUBST(XDAMAGE_CFLAGS)
 647   fi
 648   AC_SUBST(HAVE_X)
 649   CFLAGS="$ac_cflags_save"
 650   CPPFLAGS="$ac_cppflags_save"
 651 ])
 652
 653 dnl FIXME: this should be rolled into the test above, it's just an additional
 654 dnl feature of the ximagesrc plug-in
 655 dnl This is the same as in gst-plugins-base
 656 dnl check for X Shm
 657 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 658 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 659   if test x$HAVE_X = xyes; then
 660     AC_CHECK_LIB(Xext, XShmAttach,
 661                  HAVE_XSHM="yes", HAVE_XSHM="no",
 662                  $X_LIBS)
 663     if test "x$HAVE_XSHM" = "xyes"; then
 664       XSHM_LIBS="-lXext"
 665     else
 666       dnl On AIX, it is in XextSam instead, but we still need -lXext
 667       AC_CHECK_LIB(XextSam, XShmAttach,
 668                    HAVE_XSHM="yes", HAVE_XSHM="no",
 669                    $X_LIBS)
 670       if test "x$HAVE_XSHM" = "xyes"; then
 671         XSHM_LIBS="-lXext -lXextSam"
 672       fi
 673     fi
 674   fi
 675 ], ,[
 676   AC_SUBST(HAVE_XSHM)
 677   AC_SUBST(XSHM_LIBS)
 678 ])
 679
 680 dnl for V4L2, we also need to know if we have XVIDEO
 681 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 682 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 683                   [], [
 684   AG_GST_CHECK_XV
 685 ])
 686
 687 dnl *** ext plug-ins ***
 688 dnl keep this list sorted alphabetically !
 689
 690 if test "x$BUILD_EXTERNAL" = "xyes"; then
 691
 692 echo
 693 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 694 echo
 695
 696 dnl *** aalib ***
 697 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 698 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 699   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 700   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 701 ])
 702
 703 dnl *** annodex ***
 704 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 705 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 706   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 707 ])
 708
 709 dnl *** cairo ***
 710 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 711 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 712   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 713 ])
 714
 715 dnl *** cairo-gobject ***
 716 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO_GOBJECT, true)
 717 AG_GST_CHECK_FEATURE(CAIRO_GOBJECT,
 718   [Cairo graphics rendering gobject bindings], cairooverlay, [
 719   AG_GST_PKG_CHECK_MODULES(CAIRO_GOBJECT, cairo-gobject >= 1.10.0)
 720 ])
 721
 722 dnl *** FLAC ***
 723 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 724 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 725   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 726 ])
 727
 728 dnl *** GDK pixbuf ***
 729 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 730 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 731   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 732 ])
 733
 734 dnl *** HAL ***
 735 translit(dnm, m, l) AM_CONDITIONAL(USE_HAL, true)
 736 AG_GST_CHECK_FEATURE(HAL, [HAL libraries], halelements, [
 737   AG_GST_PKG_CHECK_MODULES(HAL, [hal >= 0.5.6, dbus-1 >= 0.32])
 738 ])
 739
 740 dnl *** Jack ***
 741 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 742 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 743   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 744   AC_SUBST(JACK_CFLAGS)
 745   AC_SUBST(JACK_LIBS)
 746
 747   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 748   if test x$HAVE_JACK_0_120_1 = xyes; then
 749     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 750   fi
 751   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 752   if test x$HAVE_JACK_1_9_7 = xyes; then
 753     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 754   fi
 755
 756 ])
 757
 758 dnl *** jpeg ***
 759 dnl FIXME: we could use header checks here as well IMO
 760 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 761 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 762   AC_ARG_WITH(jpeg-mmx,
 763     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 764   OLD_LIBS="$LIBS"
 765   if test x$with_jpeg_mmx != x; then
 766     LIBS="$LIBS -L$with_jpeg_mmx"
 767   fi
 768   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 769   JPEG_LIBS="$LIBS -ljpeg-mmx"
 770   LIBS="$OLD_LIBS"
 771   if test x$HAVE_JPEG != xyes; then
 772     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 773     JPEG_LIBS="-ljpeg"
 774   fi
 775   AC_SUBST(JPEG_LIBS)
 776 ])
 777
 778 dnl *** libcaca ***
 779 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 780 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 781   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 782 ])
 783
 784 dnl *** libdv ***
 785 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 786 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 787   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 788 ])
 789
 790 dnl *** libpng ***
 791 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 792 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 793   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 794 ])
 795
 796 dnl *** pulseaudio ***
 797 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 798 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 799
 800   dnl used in ext/pulse/pulseutil.c
 801   AC_CHECK_HEADERS([process.h])
 802
 803   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 0.9.10)
 804   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_11, libpulse >= 0.9.11)
 805   if test x$HAVE_PULSE_0_9_11 = xyes; then
 806     AC_DEFINE(HAVE_PULSE_0_9_11, 1, [defined if pulseaudio >= 0.9.11 is available])
 807   fi
 808   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_12, libpulse >= 0.9.12)
 809   if test x$HAVE_PULSE_0_9_12 = xyes; then
 810     AC_DEFINE(HAVE_PULSE_0_9_12, 1, [defined if pulseaudio >= 0.9.12 is available])
 811   fi
 812   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_13, libpulse >= 0.9.13)
 813   if test x$HAVE_PULSE_0_9_13 = xyes; then
 814     AC_DEFINE(HAVE_PULSE_0_9_13, 1, [defined if pulseaudio >= 0.9.13 is available])
 815   fi
 816   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_15, libpulse >= 0.9.15)
 817   if test x$HAVE_PULSE_0_9_15 = xyes; then
 818     AC_DEFINE(HAVE_PULSE_0_9_15, 1, [defined if pulseaudio >= 0.9.15 is available])
 819   fi
 820   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_16, libpulse >= 0.9.16)
 821   if test x$HAVE_PULSE_0_9_16 = xyes; then
 822     AC_DEFINE(HAVE_PULSE_0_9_16, 1, [defined if pulseaudio >= 0.9.16 is available])
 823   fi
 824   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_20, libpulse >= 0.9.20)
 825   if test x$HAVE_PULSE_0_9_20 = xyes; then
 826     AC_DEFINE(HAVE_PULSE_0_9_20, 1, [defined if pulseaudio >= 0.9.20 is available])
 827   fi
 828 ])
 829
 830 dnl *** dv1394 ***
 831 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 832 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 833   dnl first test for libraw1394 >= 2.0.0
 834   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 835   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 836   dnl now see how far we got
 837   if test x$HAVE_RAW1394 = xyes && \
 838      test x$HAVE_LIBIEC61883 = xyes; then
 839        AG_GST_CHECK_LIBHEADER(AVC1394,
 840         avc1394, avc1394_send_command, $RAW1394_LIBS,
 841         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 842        AG_GST_CHECK_LIBHEADER(ROM1394,
 843         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 844         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 845        if test x$HAVE_AVC1394 = xyes && \
 846           test x$HAVE_AVC1394 = xyes && \
 847           test x$HAVE_ROM1394 = xyes; then
 848           HAVE_DV1394=yes
 849           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 850           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 851           AC_SUBST(DV1394_CFLAGS)
 852           AC_SUBST(DV1394_LIBS)
 853         fi
 854   else
 855        if test x$HAVE_RAW1394 = xno; then
 856           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 857           AG_GST_CHECK_LIBHEADER(AVC1394,
 858            avc1394, avc1394_send_command, $RAW1394_LIBS,
 859            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 860           AG_GST_CHECK_LIBHEADER(ROM1394,
 861            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 862            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 863           if test x$HAVE_RAW1394 = xyes && \
 864              test x$HAVE_AVC1394 = xyes && \
 865              test x$HAVE_ROM1394 = xyes; then
 866              HAVE_DV1394=yes
 867              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 868              DV1394_CFLAGS="$RAW1394_CFLAGS"
 869              if test x$HAVE_LIBIEC61883 = xyes; then
 870                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 871                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 872              fi
 873              AC_SUBST(DV1394_CFLAGS)
 874              AC_SUBST(DV1394_LIBS)
 875            fi
 876          fi
 877   fi
 878 ])
 879 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 880
 881 dnl *** shout2 ***
 882 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 883 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 884   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 885   if test $HAVE_SHOUT2 = no
 886   then
 887     AM_PATH_SHOUT2(HAVE_SHOUT2="yes")
 888     AC_SUBST(SHOUT2_CFLAGS)
 889     AC_SUBST(SHOUT2_LIBS)
 890   fi
 891 ])
 892
 893 dnl *** soup ***
 894 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 895 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 896   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 897     HAVE_SOUP="yes"
 898     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 899   ],[
 900     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26, HAVE_SOUP="yes", [
 901       HAVE_SOUP="no"
 902     ])
 903   ])
 904   AC_SUBST(SOUP_CFLAGS)
 905   AC_SUBST(SOUP_LIBS)
 906 ])
 907
 908 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 909 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 910 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 911 dnl   speex_jitter.h is 1.1.x only
 912 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 913 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 914   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 915   if test $HAVE_SPEEX = no
 916   then
 917     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 918       AC_CHECK_HEADER(speex/speex_jitter.h, [
 919         dnl speex 1.1.x :
 920         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 921           dnl speex 1.1.5 or + :
 922           HAVE_SPEEX="yes"
 923           SPEEX_LIBS="-lspeex"
 924           AC_SUBST(SPEEX_CFLAGS)
 925           AC_SUBST(SPEEX_LIBS)
 926         ],[
 927           HAVE_SPEEX="no"
 928         ])
 929       ],[
 930         dnl speex 1.0.x :
 931           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 932             dnl speex 1.0.4
 933             HAVE_SPEEX="yes"
 934             SPEEX_LIBS="-lspeex"
 935             AC_SUBST(SPEEX_CFLAGS)
 936             AC_SUBST(SPEEX_LIBS)
 937
 938             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 939               [defined if speex 1.0.x API detected])
 940         ],[
 941             HAVE_SPEEX="no"
 942             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 943         ], [
 944 #include <speex/speex.h>
 945         ])
 946       ])
 947     ])
 948   fi
 949 ])
 950
 951 dnl *** taglib ***
 952 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 953 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 954   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 955   if test "x$HAVE_CXX" != "xyes"; then
 956     USE_TAGLIB=false
 957     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 958   else
 959     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 960     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 961         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 962       ], [
 963         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 964     ])
 965     AC_SUBST(TAGLIB_CXXFLAGS)
 966   fi
 967 ])
 968
 969 dnl *** wavpack ***
 970 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 971 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 972   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 973     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 974       HAVE_WAVPACK=yes
 975       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 976     ],[
 977       HAVE_WAVPACK=no
 978     ])
 979   ])
 980   AC_SUBST(WAVPACK_CFLAGS)
 981   AC_SUBST(WAVPACK_LIBS)
 982 ])
 983
 984 dnl *** qtdemux & id3demux & matroska prefer to have zlib ***
 985 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 986 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for id3demux/qtdemux/matroska],, [
 987   AG_GST_CHECK_LIBHEADER(ZLIB,
 988     z, uncompress,, zlib.h, [
 989     HAVE_ZLIB="yes"
 990     ZLIB_LIBS="-lz"
 991     AC_SUBST(ZLIB_LIBS)
 992   ])
 993 ])
 994
 995 dnl *** matroska prefers to have bz2 ***
 996 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 997 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 998   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 999   AC_SUBST(BZ2_LIBS)
1000 ])
1001
1002 else
1003
1004 dnl not building plugins with external dependencies,
1005 dnl but we still need to set the conditionals
1006 AM_CONDITIONAL(USE_AALIB, false)
1007 AM_CONDITIONAL(USE_ANNODEX, false)
1008 AM_CONDITIONAL(USE_BZ2, false)
1009 AM_CONDITIONAL(USE_CAIRO, false)
1010 AM_CONDITIONAL(USE_CAIRO_GOBJECT, false)
1011 AM_CONDITIONAL(USE_DIRECTSOUND, false)
1012 AM_CONDITIONAL(USE_DV1394, false)
1013 AM_CONDITIONAL(USE_FLAC, false)
1014 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
1015 AM_CONDITIONAL(USE_GST_V4L2, false)
1016 AM_CONDITIONAL(USE_HAL, false)
1017 AM_CONDITIONAL(USE_JACK, false)
1018 AM_CONDITIONAL(USE_JPEG, false)
1019 AM_CONDITIONAL(USE_LIBCACA, false)
1020 AM_CONDITIONAL(USE_LIBDV, false)
1021 AM_CONDITIONAL(USE_LIBIEC61883, false)
1022 AM_CONDITIONAL(USE_LIBPNG, false)
1023 AM_CONDITIONAL(USE_OSS, false)
1024 AM_CONDITIONAL(USE_OSS4, false)
1025 AM_CONDITIONAL(USE_OSX_AUDIO, false)
1026 AM_CONDITIONAL(USE_OSX_VIDEO, false)
1027 AM_CONDITIONAL(USE_PULSE, false)
1028 AM_CONDITIONAL(USE_SHOUT2, false)
1029 AM_CONDITIONAL(USE_SOUP, false)
1030 AM_CONDITIONAL(USE_SPEEX, false)
1031 AM_CONDITIONAL(USE_SUNAUDIO, false)
1032 AM_CONDITIONAL(USE_TAGLIB, false)
1033 AM_CONDITIONAL(USE_WAVPACK, false)
1034 AM_CONDITIONAL(USE_X, false)
1035 AM_CONDITIONAL(USE_XSHM, false)
1036 AM_CONDITIONAL(USE_XVIDEO, false)
1037 AM_CONDITIONAL(USE_ZLIB, false)
1038
1039 fi dnl of EXT plugins
1040
1041 dnl *** finalize CFLAGS, LDFLAGS, LIBS
1042
1043 dnl Overview:
1044 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1045 dnl GST_*:              flags shared by all built objects
1046 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1047 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
1048 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1049 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1050
1051 dnl GST_OPTION_CFLAGS
1052 if test "x$USE_DEBUG" = xyes; then
1053    PROFILE_CFLAGS="-g"
1054 fi
1055 AC_SUBST(PROFILE_CFLAGS)
1056
1057 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1058   dnl Define _only_ for git (not pre-releases or releases)
1059   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1060 else
1061   DEPRECATED_CFLAGS=""
1062 fi
1063 AC_SUBST(DEPRECATED_CFLAGS)
1064
1065 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
1066 dnl at make time with e.g. make ERROR_CFLAGS=""
1067 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1068 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1069 AC_SUBST(GST_OPTION_CFLAGS)
1070 AC_SUBST(GST_OPTION_CXXFLAGS)
1071
1072 dnl our libraries need to be versioned correctly
1073 AC_SUBST(GST_LT_LDFLAGS)
1074
1075 dnl FIXME: do we want to rename to GST_ALL_* ?
1076 dnl prefer internal headers to already installed ones
1077 dnl also add builddir include for enumtypes and marshal
1078 dnl add ERROR_CFLAGS, but overridable
1079 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1080 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
1081 AC_SUBST(GST_CFLAGS)
1082 AC_SUBST(GST_CXXFLAGS)
1083 AC_SUBST(GST_LIBS)
1084
1085 dnl LDFLAGS really should only contain flags, not libs - they get added before
1086 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1087 GST_ALL_LDFLAGS="-no-undefined"
1088 AC_SUBST(GST_ALL_LDFLAGS)
1089
1090 dnl this really should only contain flags, not libs - they get added before
1091 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1092 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
1093 AC_SUBST(GST_PLUGIN_LDFLAGS)
1094
1095 dnl *** output files ***
1096
1097 dnl keep this alphabetic per directory, please
1098 AC_CONFIG_FILES(
1099 Makefile
1100 gst/Makefile
1101 gst/alpha/Makefile
1102 gst/apetag/Makefile
1103 gst/audiofx/Makefile
1104 gst/audioparsers/Makefile
1105 gst/auparse/Makefile
1106 gst/autodetect/Makefile
1107 gst/avi/Makefile
1108 gst/cutter/Makefile
1109 gst/deinterlace/Makefile
1110 gst/debugutils/Makefile
1111 gst/effectv/Makefile
1112 gst/equalizer/Makefile
1113 gst/flv/Makefile
1114 gst/goom/Makefile
1115 gst/goom2k1/Makefile
1116 gst/id3demux/Makefile
1117 gst/icydemux/Makefile
1118 gst/imagefreeze/Makefile
1119 gst/interleave/Makefile
1120 gst/isomp4/Makefile
1121 gst/law/Makefile
1122 gst/level/Makefile
1123 gst/matroska/Makefile
1124 gst/monoscope/Makefile
1125 gst/multifile/Makefile
1126 gst/multipart/Makefile
1127 gst/replaygain/Makefile
1128 gst/rtp/Makefile
1129 gst/rtpmanager/Makefile
1130 gst/rtsp/Makefile
1131 gst/shapewipe/Makefile
1132 gst/smpte/Makefile
1133 gst/spectrum/Makefile
1134 gst/udp/Makefile
1135 gst/videobox/Makefile
1136 gst/videocrop/Makefile
1137 gst/videofilter/Makefile
1138 gst/videomixer/Makefile
1139 gst/wavenc/Makefile
1140 gst/wavparse/Makefile
1141 gst/flx/Makefile
1142 gst/y4m/Makefile
1143 ext/Makefile
1144 ext/aalib/Makefile
1145 ext/annodex/Makefile
1146 ext/cairo/Makefile
1147 ext/dv/Makefile
1148 ext/flac/Makefile
1149 ext/gdk_pixbuf/Makefile
1150 ext/hal/Makefile
1151 ext/jack/Makefile
1152 ext/jpeg/Makefile
1153 ext/libcaca/Makefile
1154 ext/libpng/Makefile
1155 ext/pulse/Makefile
1156 ext/raw1394/Makefile
1157 ext/shout2/Makefile
1158 ext/soup/Makefile
1159 ext/speex/Makefile
1160 ext/taglib/Makefile
1161 ext/wavpack/Makefile
1162 sys/Makefile
1163 sys/directsound/Makefile
1164 sys/oss/Makefile
1165 sys/oss4/Makefile
1166 sys/osxaudio/Makefile
1167 sys/osxvideo/Makefile
1168 sys/sunaudio/Makefile
1169 sys/v4l2/Makefile
1170 sys/waveform/Makefile
1171 sys/ximage/Makefile
1172 po/Makefile.in
1173 tests/Makefile
1174 tests/check/Makefile
1175 tests/examples/Makefile
1176 tests/examples/audiofx/Makefile
1177 tests/examples/cairo/Makefile
1178 tests/examples/equalizer/Makefile
1179 tests/examples/jack/Makefile
1180 tests/examples/level/Makefile
1181 tests/examples/pulse/Makefile
1182 tests/examples/rtp/Makefile
1183 tests/examples/shapewipe/Makefile
1184 tests/examples/spectrum/Makefile
1185 tests/examples/v4l2/Makefile
1186 tests/files/Makefile
1187 tests/icles/Makefile
1188 common/Makefile
1189 common/m4/Makefile
1190 m4/Makefile
1191 docs/Makefile
1192 docs/plugins/Makefile
1193 docs/version.entities
1194 pkgconfig/Makefile
1195 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1196 gst-plugins-good.spec
1197 )
1198
1199 dnl Create the config.h file for Visual Studio builds
1200 dnl Beware of spaces and /'s in some of the shell variable contents.
1201 sed \
1202     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1203     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1204     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1205     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1206     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1207     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1208     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1209     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1210     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1211     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1212     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1213     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1214     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1215     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1216     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1217     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1218     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1219     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1220     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1221     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1222     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1223     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1224     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1225     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1226     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1227     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1228     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1229     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1230     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1231     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
1232     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1233     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1234     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1235     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1236     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1237     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1238     config.h.in >win32/common/config.h-new
1239
1240 AC_OUTPUT
1241
1242 AG_GST_OUTPUT_PLUGINS
1243 ORC_OUTPUT
1244