configure.ac

   1 m4_define([weston_major_version], [1])
   2 m4_define([weston_minor_version], [3])
   3 m4_define([weston_micro_version], [0])
   4 m4_define([weston_version],
   5           [weston_major_version.weston_minor_version.weston_micro_version])
   6
   7 AC_PREREQ([2.64])
   8 AC_INIT([weston],
   9         [weston_version],
  10         [https://bugs.freedesktop.org/enter_bug.cgi?product=Wayland&component=weston&version=weston_version],
  11         [weston],
  12         [http://wayland.freedesktop.org/])
  13
  14 AC_SUBST([WESTON_VERSION_MAJOR], [weston_major_version])
  15 AC_SUBST([WESTON_VERSION_MINOR], [weston_minor_version])
  16 AC_SUBST([WESTON_VERSION_MICRO], [weston_micro_version])
  17 AC_SUBST([WESTON_VERSION], [weston_version])
  18
  19 AC_CONFIG_HEADERS([config.h])
  20
  21 AC_USE_SYSTEM_EXTENSIONS
  22 AC_SYS_LARGEFILE
  23
  24 AM_INIT_AUTOMAKE([1.11 parallel-tests foreign no-dist-gzip dist-xz color-tests])
  25
  26 AM_SILENT_RULES([yes])
  27
  28 # Check for programs
  29 AC_PROG_CC
  30 AC_PROG_SED
  31
  32 # Initialize libtool
  33 LT_PREREQ([2.2])
  34 LT_INIT([disable-static])
  35
  36 AC_ARG_VAR([WESTON_NATIVE_BACKEND],
  37            [Set the native backend to use, if Weston is not running under Wayland nor X11. @<:@default=drm-backend.so@:>@])
  38
  39 PKG_PROG_PKG_CONFIG()
  40
  41 AC_CHECK_FUNC([dlopen], [],
  42               AC_CHECK_LIB([dl], [dlopen], DLOPEN_LIBS="-ldl"))
  43 AC_SUBST(DLOPEN_LIBS)
  44
  45 AC_CHECK_DECL(SFD_CLOEXEC,[],
  46               [AC_MSG_ERROR("SFD_CLOEXEC is needed to compile weston")],
  47               [[#include <sys/signalfd.h>]])
  48 AC_CHECK_DECL(TFD_CLOEXEC,[],
  49               [AC_MSG_ERROR("TFD_CLOEXEC is needed to compile weston")],
  50               [[#include <sys/timerfd.h>]])
  51 AC_CHECK_DECL(CLOCK_MONOTONIC,[],
  52               [AC_MSG_ERROR("CLOCK_MONOTONIC is needed to compile weston")],
  53               [[#include <time.h>]])
  54 AC_CHECK_HEADERS([execinfo.h])
  55
  56 AC_CHECK_FUNCS([mkostemp strchrnul initgroups])
  57
  58 COMPOSITOR_MODULES="wayland-server >= 1.2.91 pixman-1"
  59
  60 AC_ARG_ENABLE(egl, [  --disable-egl],,
  61               enable_egl=yes)
  62 AM_CONDITIONAL(ENABLE_EGL, test x$enable_egl = xyes)
  63 if test x$enable_egl = xyes; then
  64         AC_DEFINE([ENABLE_EGL], [1], [Build Weston with EGL support])
  65         PKG_CHECK_MODULES(EGL, [egl >= 7.10 glesv2])
  66 fi
  67
  68 AC_ARG_ENABLE(xkbcommon,
  69               AS_HELP_STRING([--disable-xkbcommon], [Disable libxkbcommon
  70                               support: This is only useful in environments
  71                               where you do not have a hardware keyboard. If
  72                               libxkbcommon support is disabled clients will not
  73                               be sent a keymap and and must know how to
  74                               interpret the keycode sent for any key event.]),,
  75               enable_xkbcommon=yes)
  76 if test x$enable_xkbcommon = xyes; then
  77         AC_DEFINE(ENABLE_XKBCOMMON, [1], [Build Weston with libxkbcommon support])
  78         COMPOSITOR_MODULES="$COMPOSITOR_MODULES xkbcommon"
  79 fi
  80
  81 AC_ARG_ENABLE(setuid-install, [  --enable-setuid-install],,
  82               enable_setuid_install=yes)
  83 AM_CONDITIONAL(ENABLE_SETUID_INSTALL, test x$enable_setuid_install = xyes)
  84
  85
  86 AC_ARG_ENABLE(xwayland, [  --enable-xwayland],,
  87               enable_xwayland=yes)
  88 AC_ARG_ENABLE(xwayland-test, [  --enable-xwayland-test],,
  89               enable_xwayland_test=yes)
  90 AM_CONDITIONAL(ENABLE_XWAYLAND, test x$enable_xwayland = xyes)
  91 AM_CONDITIONAL(ENABLE_XWAYLAND_TEST, test x$enable_xwayland = xyes -a x$enable_xwayland_test = xyes)
  92 if test x$enable_xwayland = xyes; then
  93   PKG_CHECK_MODULES([XWAYLAND], xcb xcb-xfixes xcb-composite xcursor cairo-xcb)
  94   AC_DEFINE([BUILD_XWAYLAND], [1], [Build the X server launcher])
  95
  96   AC_ARG_WITH(xserver-path, AS_HELP_STRING([--with-xserver-path=PATH],
  97               [Path to X server]), [XSERVER_PATH="$withval"],
  98               [XSERVER_PATH="$bindir/Xorg"])
  99   AC_SUBST([XSERVER_PATH])
 100   if test x$enable_xwayland_test = xyes; then
 101     PKG_CHECK_MODULES([XWAYLAND_TEST], xcb xcb-dri2 libdrm)
 102   fi
 103 fi
 104
 105
 106 AC_ARG_ENABLE(x11-compositor, [  --enable-x11-compositor],,
 107               enable_x11_compositor=yes)
 108 AM_CONDITIONAL(ENABLE_X11_COMPOSITOR, test x$enable_x11_compositor = xyes)
 109 if test x$enable_x11_compositor = xyes; then
 110   PKG_CHECK_MODULES([XCB], xcb)
 111   xcb_save_LIBS=$LIBS
 112   xcb_save_CFLAGS=$CFLAGS
 113   CFLAGS=$XCB_CFLAGS
 114   LIBS=$XCB_LIBS
 115   AC_CHECK_FUNCS([xcb_poll_for_queued_event])
 116   LIBS=$xcb_save_LIBS
 117   CFLAGS=$xcb_save_CFLAGS
 118
 119   X11_COMPOSITOR_MODULES="x11 x11-xcb xcb-shm"
 120
 121   PKG_CHECK_MODULES(X11_COMPOSITOR_XKB, [xcb-xkb],
 122                     [have_xcb_xkb="yes"], [have_xcb_xkb="no"])
 123   if test "x$have_xcb_xkb" = xyes; then
 124         # Most versions of XCB have totally broken XKB bindings, where the
 125         # events don't work.  Make sure we can actually use them.
 126         xcb_xkb_save_CFLAGS=$CFLAGS
 127         CFLAGS=$X11_COMPOSITOR_XKB_CFLAGS
 128         AC_CHECK_MEMBER([struct xcb_xkb_state_notify_event_t.xkbType],
 129                         [], [have_xcb_xkb=no], [[#include <xcb/xkb.h>]])
 130         CFLAGS=$xcb_xkb_save_CFLAGS
 131   fi
 132   if test "x$have_xcb_xkb" = xyes; then
 133         X11_COMPOSITOR_MODULES="$X11_COMPOSITOR_MODULES xcb-xkb"
 134         AC_DEFINE([HAVE_XCB_XKB], [1], [libxcb supports XKB protocol])
 135   fi
 136
 137   PKG_CHECK_MODULES(X11_COMPOSITOR, [$X11_COMPOSITOR_MODULES])
 138   AC_DEFINE([BUILD_X11_COMPOSITOR], [1], [Build the X11 compositor])
 139 fi
 140
 141
 142 AC_ARG_ENABLE(drm-compositor, [  --enable-drm-compositor],,
 143               enable_drm_compositor=yes)
 144 AM_CONDITIONAL(ENABLE_DRM_COMPOSITOR, test x$enable_drm_compositor = xyes -a x$enable_egl = xyes)
 145 if test x$enable_drm_compositor = xyes -a x$enable_egl = xyes; then
 146   AC_DEFINE([BUILD_DRM_COMPOSITOR], [1], [Build the DRM compositor])
 147   PKG_CHECK_MODULES(DRM_COMPOSITOR, [libudev >= 136 libdrm >= 2.4.30 gbm mtdev >= 1.1.0])
 148
 149   # For libdrm usage in launcher-util.c
 150   COMPOSITOR_MODULES="$COMPOSITOR_MODULES libdrm"
 151 fi
 152
 153 PKG_CHECK_MODULES(COMPOSITOR, [$COMPOSITOR_MODULES])
 154
 155 AC_ARG_ENABLE(wayland-compositor, [  --enable-wayland-compositor],,
 156               enable_wayland_compositor=yes)
 157 AM_CONDITIONAL(ENABLE_WAYLAND_COMPOSITOR,
 158                test x$enable_wayland_compositor = xyes -a x$enable_egl = xyes)
 159 if test x$enable_wayland_compositor = xyes -a x$enable_egl = xyes; then
 160   AC_DEFINE([BUILD_WAYLAND_COMPOSITOR], [1],
 161             [Build the Wayland (nested) compositor])
 162   PKG_CHECK_MODULES(WAYLAND_COMPOSITOR, [wayland-client wayland-egl])
 163 fi
 164
 165
 166 AC_ARG_ENABLE(headless-compositor, [  --enable-headless-compositor],,
 167               enable_headless_compositor=yes)
 168 AM_CONDITIONAL(ENABLE_HEADLESS_COMPOSITOR,
 169                test x$enable_headless_compositor = xyes)
 170
 171
 172 AC_ARG_ENABLE(rpi-compositor,
 173               AS_HELP_STRING([--disable-rpi-compositor],
 174                              [do not build the Raspberry Pi backend]),,
 175               enable_rpi_compositor=yes)
 176 AM_CONDITIONAL(ENABLE_RPI_COMPOSITOR, test "x$enable_rpi_compositor" = "xyes")
 177 have_bcm_host="no"
 178 if test "x$enable_rpi_compositor" = "xyes"; then
 179   AC_DEFINE([BUILD_RPI_COMPOSITOR], [1], [Build the compositor for Raspberry Pi])
 180   PKG_CHECK_MODULES(RPI_COMPOSITOR, [libudev >= 136 mtdev >= 1.1.0])
 181   PKG_CHECK_MODULES(RPI_BCM_HOST, [bcm_host],
 182                     [have_bcm_host="yes"
 183                      AC_DEFINE([HAVE_BCM_HOST], [1], [have Raspberry Pi BCM headers])],
 184                     [AC_MSG_WARN([Raspberry Pi BCM host libraries not found, will use stubs instead.])])
 185 fi
 186 AM_CONDITIONAL(INSTALL_RPI_COMPOSITOR, test "x$have_bcm_host" = "xyes")
 187
 188
 189 AC_ARG_ENABLE([fbdev-compositor], [  --enable-fbdev-compositor],,
 190               enable_fbdev_compositor=yes)
 191 AM_CONDITIONAL([ENABLE_FBDEV_COMPOSITOR],
 192                [test x$enable_fbdev_compositor = xyes])
 193 AS_IF([test x$enable_fbdev_compositor = xyes], [
 194   AC_DEFINE([BUILD_FBDEV_COMPOSITOR], [1], [Build the fbdev compositor])
 195   PKG_CHECK_MODULES([FBDEV_COMPOSITOR], [libudev >= 136 mtdev >= 1.1.0])
 196 ])
 197
 198 AC_ARG_ENABLE([rdp-compositor], [  --enable-rdp-compositor],,
 199               enable_rdp_compositor=no)
 200 AM_CONDITIONAL([ENABLE_RDP_COMPOSITOR],
 201                [test x$enable_rdp_compositor = xyes])
 202 if test x$enable_rdp_compositor = xyes; then
 203   AC_DEFINE([BUILD_RDP_COMPOSITOR], [1], [Build the RDP compositor])
 204   PKG_CHECK_MODULES(RDP_COMPOSITOR, [freerdp >= 1.1.0])
 205 fi
 206
 207 AC_ARG_WITH(cairo,
 208             AS_HELP_STRING([--with-cairo=@<:@image|gl|glesv2@:>@]
 209                            [Which Cairo renderer to use for the clients]),
 210                            [],[with_cairo="image"])
 211
 212 if test "x$with_cairo" = "ximage"; then
 213         cairo_modules="cairo"
 214 else
 215 if test "x$with_cairo" = "xgl"; then
 216         cairo_modules="cairo-gl"
 217 else
 218 if test "x$with_cairo" = "xglesv2"; then
 219         cairo_modules="cairo-glesv2"
 220 else
 221         AC_ERROR([Unknown cairo renderer requested])
 222 fi
 223 fi
 224 fi
 225
 226 # Included for legacy compat
 227 AC_ARG_WITH(cairo-glesv2,
 228             AS_HELP_STRING([--with-cairo-glesv2],
 229                            [Use GLESv2 cairo]))
 230 if test "x$with_cairo_glesv2" = "xyes"; then
 231   cairo_modules="cairo-glesv2"
 232   with_cairo="glesv2"
 233 fi
 234
 235 if test "x$cairo_modules" = "xcairo-glesv2"; then
 236 AC_DEFINE([USE_CAIRO_GLESV2], [1], [Use the GLESv2 GL cairo backend])
 237 fi
 238
 239 PKG_CHECK_MODULES(PIXMAN, [pixman-1])
 240 PKG_CHECK_MODULES(PNG, [libpng])
 241 PKG_CHECK_MODULES(WEBP, [libwebp], [have_webp=yes], [have_webp=no])
 242 AS_IF([test "x$have_webp" = "xyes"],
 243       [AC_DEFINE([HAVE_WEBP], [1], [Have webp])])
 244
 245 AC_ARG_ENABLE(vaapi-recorder, [  --enable-vaapi-recorder],,
 246               enable_vaapi_recorder=auto)
 247 if test x$enable_vaapi_recorder != xno; then
 248   PKG_CHECK_MODULES(LIBVA, [libva >= 0.34.0 libva-drm >= 0.34.0],
 249                     [have_libva=yes], [have_libva=no])
 250   if test "x$have_libva" = "xno" -a "x$enable_vaapi_recorder" = "xyes"; then
 251     AC_MSG_ERROR([vaapi-recorder explicitly enabled, but libva couldn't be found])
 252   fi
 253   AS_IF([test "x$have_libva" = "xyes"],
 254         [AC_DEFINE([BUILD_VAAPI_RECORDER], [1], [Build the vaapi recorder])])
 255 fi
 256 AM_CONDITIONAL(ENABLE_VAAPI_RECORDER, test "x$have_libva" = xyes)
 257
 258
 259 AC_CHECK_LIB([jpeg], [jpeg_CreateDecompress], have_jpeglib=yes)
 260 if test x$have_jpeglib = xyes; then
 261   JPEG_LIBS="-ljpeg"
 262 else
 263   AC_ERROR([libjpeg not found])
 264 fi
 265 AC_SUBST(JPEG_LIBS)
 266
 267 PKG_CHECK_MODULES(CAIRO, [cairo])
 268
 269 AC_ARG_ENABLE(simple-clients,
 270               AS_HELP_STRING([--disable-simple-clients],
 271                              [do not build the simple wl_shm clients]),,
 272               enable_simple_clients=yes)
 273 AM_CONDITIONAL(BUILD_SIMPLE_CLIENTS, test "x$enable_simple_clients" = "xyes")
 274 if test x$enable_simple_clients = xyes; then
 275   PKG_CHECK_MODULES(SIMPLE_CLIENT, [wayland-client])
 276 fi
 277
 278 AC_ARG_ENABLE(simple-egl-clients,
 279               AS_HELP_STRING([--disable-simple-egl-clients],
 280                              [do not build the simple EGL clients]),,
 281               enable_simple_egl_clients="$enable_egl")
 282 AM_CONDITIONAL(BUILD_SIMPLE_EGL_CLIENTS, test "x$enable_simple_egl_clients" = "xyes")
 283 if test x$enable_simple_egl_clients = xyes; then
 284   PKG_CHECK_MODULES(SIMPLE_EGL_CLIENT,
 285                     [egl >= 7.10 glesv2 wayland-client wayland-egl wayland-cursor])
 286 fi
 287
 288 AC_ARG_ENABLE(clients, [  --enable-clients],, enable_clients=yes)
 289 AM_CONDITIONAL(BUILD_CLIENTS, test x$enable_clients = xyes)
 290 if test x$enable_clients = xyes; then
 291   AC_DEFINE([BUILD_CLIENTS], [1], [Build the Wayland clients])
 292
 293   PKG_CHECK_MODULES(CLIENT, [wayland-client cairo >= 1.10.0 xkbcommon wayland-cursor])
 294   PKG_CHECK_MODULES(SERVER, [wayland-server])
 295   PKG_CHECK_MODULES(WESTON_INFO, [wayland-client])
 296
 297   PKG_CHECK_MODULES(POPPLER, [poppler-glib glib-2.0 gobject-2.0 gio-2.0 ],
 298                              [have_poppler=yes], [have_poppler=no])
 299
 300   # Only check for cairo-egl if a GL or GLES renderer requested
 301   AS_IF([test "x$cairo_modules" = "xcairo-gl" -o "x$cairo_modules" = "xcairo-glesv2"], [
 302     PKG_CHECK_MODULES(CAIRO_EGL, [wayland-egl egl >= 7.10 cairo-egl >= 1.11.3 $cairo_modules],
 303                       [have_cairo_egl=yes], [have_cairo_egl=no])
 304     AS_IF([test "x$have_cairo_egl" = "xyes"],
 305           [AC_DEFINE([HAVE_CAIRO_EGL], [1], [Have cairo-egl])],
 306           [AC_ERROR([cairo-egl not used because $CAIRO_EGL_PKG_ERRORS])])],
 307   [have_cairo_egl=no])
 308
 309   PKG_CHECK_MODULES(PANGO, [pangocairo], [have_pango=yes], [have_pango=no])
 310 fi
 311
 312 AC_ARG_ENABLE(resize-optimization,
 313               AS_HELP_STRING([--disable-resize-optimization],
 314                              [disable resize optimization allocating a big buffer in toytoolkit]),,
 315               enable_resize_optimization=yes)
 316 AS_IF([test "x$enable_resize_optimization" = "xyes"],
 317       [AC_DEFINE([USE_RESIZE_POOL], [1], [Use resize memory pool as a performance optimization])])
 318
 319 PKG_CHECK_MODULES(SYSTEMD_LOGIN, [libsystemd-login],
 320                   [have_systemd_login=yes], [have_systemd_login=no])
 321 AS_IF([test "x$have_systemd_login" = "xyes"],
 322       [AC_DEFINE([HAVE_SYSTEMD_LOGIN], [1], [Have systemd-login])])
 323 AM_CONDITIONAL(HAVE_SYSTEMD_LOGIN, test "x$have_systemd_login" = "xyes")
 324
 325 PKG_CHECK_MODULES(SYSTEMD_LOGIN_209, [libsystemd-login >= 209],
 326                   [have_systemd_login_209=yes], [have_systemd_login_209=no])
 327 AS_IF([test "x$have_systemd_login_209" = "xyes"],
 328       [AC_DEFINE([HAVE_SYSTEMD_LOGIN_209], [1], [Have systemd-login >= 209])])
 329
 330 AC_ARG_ENABLE(weston-launch, [  --enable-weston-launch],, enable_weston_launch=yes)
 331 AM_CONDITIONAL(BUILD_WESTON_LAUNCH, test x$enable_weston_launch == xyes)
 332 if test x$enable_weston_launch == xyes; then
 333   PKG_CHECK_MODULES(WESTON_LAUNCH, [libdrm])
 334
 335   AC_CHECK_LIB([pam], [pam_open_session], [have_pam=yes], [have_pam=no])
 336   if test x$have_pam == xno; then
 337     AC_ERROR([weston-launch requires pam])
 338   fi
 339   WESTON_LAUNCH_LIBS="$WESTON_LAUNCH_LIBS -lpam"
 340 fi
 341
 342 if test x$enable_egl = xyes; then
 343   PKG_CHECK_MODULES(GLU, [glu], [have_glu=yes], [have_glu=no])
 344 fi
 345 AM_CONDITIONAL(HAVE_GLU, test "x$have_glu" = "xyes")
 346
 347
 348 AM_CONDITIONAL(HAVE_POPPLER, test "x$have_poppler" = "xyes")
 349
 350 AM_CONDITIONAL(HAVE_PANGO, test "x$have_pango" = "xyes")
 351
 352 AM_CONDITIONAL(HAVE_CAIRO_GLESV2,
 353                [test "x$have_cairo_egl" = "xyes" -a "x$cairo_modules" = "xcairo-glesv2" -a "x$enable_egl" = "xyes"])
 354
 355 AM_CONDITIONAL(BUILD_FULL_GL_CLIENTS,
 356                test x$cairo_modules = "xcairo-gl" -a "x$have_cairo_egl" = "xyes" -a "x$enable_egl" = "xyes")
 357
 358 AM_CONDITIONAL(BUILD_SUBSURFACES_CLIENT,
 359                [test '(' "x$have_cairo_egl" != "xyes" -o "x$cairo_modules" = "xcairo-glesv2" ')' -a "x$enable_simple_egl_clients" = "xyes"])
 360
 361 AM_CONDITIONAL(ENABLE_DESKTOP_SHELL, true)
 362
 363 AC_ARG_ENABLE(tablet-shell,
 364               AS_HELP_STRING([--disable-tablet-shell],
 365                              [do not build tablet-shell server plugin and client]),,
 366               enable_tablet_shell=yes)
 367 AM_CONDITIONAL(ENABLE_TABLET_SHELL,
 368                test "x$enable_tablet_shell" = "xyes")
 369
 370 # CMS modules
 371 AC_ARG_ENABLE(colord,
 372               AS_HELP_STRING([--disable-colord],
 373                              [do not build colord CMS support]),,
 374               enable_colord=auto)
 375 if test "x$enable_colord" != "xno"; then
 376         PKG_CHECK_MODULES(COLORD,
 377                           colord >= 0.1.27,
 378                           have_colord=yes,
 379                           have_colord=no)
 380         if test "x$have_colord" = "xno" -a "x$enable_colord" = "xyes"; then
 381           AC_MSG_ERROR([colord support explicitly requested, but colord couldn't be found])
 382         fi
 383         if test "x$have_colord" = "xyes"; then
 384              enable_colord=yes
 385         fi
 386 fi
 387 AM_CONDITIONAL(ENABLE_COLORD, test "x$enable_colord" = "xyes")
 388
 389 # dbus support
 390 AC_ARG_ENABLE(dbus,
 391               AS_HELP_STRING([--disable-dbus],
 392                              [do not build with dbus support]),,
 393               enable_dbus=auto)
 394 if test "x$enable_dbus" != "xno"; then
 395         PKG_CHECK_MODULES(DBUS,
 396                           dbus-1 >= 1.6,
 397                           have_dbus=yes,
 398                           have_dbus=no)
 399         if test "x$have_dbus" = "xno" -a "x$enable_dbus" = "xyes"; then
 400                 AC_MSG_ERROR([dbus support explicitly requested, but libdbus couldn't be found])
 401         fi
 402         if test "x$have_dbus" = "xyes"; then
 403                 enable_dbus=yes
 404                 AC_DEFINE([HAVE_DBUS], [1], [Build with dbus support])
 405         else
 406                 enable_dbus=no
 407         fi
 408 fi
 409 AM_CONDITIONAL(ENABLE_DBUS, test "x$enable_dbus" = "xyes")
 410
 411 AC_ARG_ENABLE(wcap-tools, [  --disable-wcap-tools],, enable_wcap_tools=yes)
 412 AM_CONDITIONAL(BUILD_WCAP_TOOLS, test x$enable_wcap_tools = xyes)
 413 if test x$enable_wcap_tools = xyes; then
 414   AC_DEFINE([BUILD_WCAP_TOOLS], [1], [Build the wcap tools])
 415   PKG_CHECK_MODULES(WCAP, [cairo])
 416   WCAP_LIBS="$WCAP_LIBS -lm"
 417 fi
 418
 419 AC_CHECK_PROG(RSVG_CONVERT, rsvg-convert, rsvg-convert)
 420 AM_CONDITIONAL(HAVE_RSVG_CONVERT, test -n "$RSVG_CONVERT")
 421
 422 PKG_CHECK_MODULES(SETBACKLIGHT, [libudev libdrm], enable_setbacklight=yes, enable_setbacklight=no)
 423 AM_CONDITIONAL(BUILD_SETBACKLIGHT, test "x$enable_setbacklight" = "xyes")
 424
 425 if test "x$GCC" = "xyes"; then
 426         GCC_CFLAGS="-Wall -Wextra -Wno-unused-parameter \
 427                 -Wno-missing-field-initializers -g -fvisibility=hidden \
 428                 -Wstrict-prototypes -Wmissing-prototypes"
 429 fi
 430 AC_SUBST(GCC_CFLAGS)
 431
 432 AC_ARG_ENABLE(libunwind,
 433               AS_HELP_STRING([--disable-libunwind],
 434                              [Disable libunwind usage for backtraces]),,
 435               enable_libunwind=auto)
 436 AM_CONDITIONAL(HAVE_LIBUNWIND, [test "x$enable_libunwind" = xyes])
 437 if test "x$enable_libunwind" != "xno"; then
 438         PKG_CHECK_MODULES(LIBUNWIND,
 439                           libunwind,
 440                           have_libunwind=yes,
 441                           have_libunwind=no)
 442         if test "x$have_libunwind" = "xno" -a "x$enable_libunwind" = "xyes"; then
 443           AC_MSG_ERROR([libunwind support explicitly requested, but libunwind couldn't be found])
 444         fi
 445         if test "x$have_libunwind" = "xyes"; then
 446              enable_libunwind=yes
 447              AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
 448         fi
 449 fi
 450
 451
 452 if test "x$WESTON_NATIVE_BACKEND" = "x"; then
 453         WESTON_NATIVE_BACKEND="drm-backend.so"
 454 fi
 455 AC_MSG_NOTICE([Weston's native backend: $WESTON_NATIVE_BACKEND])
 456 AC_DEFINE_UNQUOTED([WESTON_NATIVE_BACKEND], ["$WESTON_NATIVE_BACKEND"],
 457                    [The default backend to load, if not wayland nor x11.])
 458
 459 AC_ARG_ENABLE(demo-clients,
 460               AS_HELP_STRING([--enable-demo-clients],
 461                              [install demo clients built with weston]),,
 462               enable_demo_clients=no)
 463 AM_CONDITIONAL(ENABLE_DEMO_CLIENTS, [test "x$enable_demo_clients" = "xyes"])
 464
 465 PKG_CHECK_MODULES(LCMS, lcms2,
 466                   [have_lcms=yes], [have_lcms=no])
 467 if test "x$have_lcms" = xyes; then
 468        AC_DEFINE(HAVE_LCMS, 1, [Have lcms support])
 469 fi
 470 AM_CONDITIONAL(HAVE_LCMS, [test "x$have_lcms" = xyes])
 471
 472 AC_PATH_PROG([wayland_scanner], [wayland-scanner])
 473 if test x$wayland_scanner = x; then
 474         AC_MSG_ERROR([wayland-scanner is needed to compile weston])
 475 fi
 476
 477 AC_CONFIG_FILES([Makefile
 478                  shared/Makefile
 479                  src/Makefile
 480                  src/xwayland/Makefile
 481                  src/version.h
 482                  src/weston.pc
 483                  clients/Makefile
 484                  wcap/Makefile
 485                  data/Makefile
 486                  protocol/Makefile
 487                  man/Makefile
 488                  tests/Makefile])
 489 AC_OUTPUT
 490
 491 AC_MSG_RESULT([
 492         Native Backend                  ${WESTON_NATIVE_BACKEND}
 493         setuid Install                  ${enable_setuid_install}
 494
 495         Cairo Renderer                  ${with_cairo}
 496         EGL                             ${enable_egl}
 497         libxkbcommon                    ${enable_xkbcommon}
 498         XWayland                        ${enable_xwayland}
 499         dbus                            ${enable_dbus}
 500
 501         Build wcap utility              ${enable_wcap_tools}
 502         Build Tablet Shell              ${enable_tablet_shell}
 503
 504         weston-launch utility           ${enable_weston_launch}
 505         systemd-login support           ${have_systemd_login}
 506
 507         DRM Compositor                  ${enable_drm_compositor}
 508         X11 Compositor                  ${enable_x11_compositor}
 509         Wayland Compositor              ${enable_wayland_compositor}
 510         Headless Compositor             ${enable_headless_compositor}
 511         RPI Compositor                  ${enable_rpi_compositor}
 512         FBDEV Compositor                ${enable_fbdev_compositor}
 513         RDP Compositor                  ${enable_rdp_compositor}
 514
 515         Raspberry Pi BCM headers        ${have_bcm_host}
 516
 517         Build Clients                   ${enable_clients}
 518         Build EGL Clients               ${have_cairo_egl}
 519         Build Simple Clients            ${enable_simple_clients}
 520         Build Simple EGL Clients        ${enable_simple_egl_clients}
 521
 522         Install Demo Clients            ${enable_demo_clients}
 523
 524         Colord Support                  ${have_colord}
 525         GLU Support                     ${have_glu}
 526         LCMS2 Support                   ${have_lcms}
 527         libwebp Support                 ${have_webp}
 528         libunwind Support               ${have_libunwind}
 529         VA H.264 encoding Support       ${have_libva}
 530 ])