configure.ac

   1 AC_PREREQ(2.62)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 AC_INIT(GStreamer libav, 1.5.0.1,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gst-libav)
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([ext/libav/gstav.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use major.minor as a version
  39 GST_API_VERSION=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  40 dnl we override it here if we need to for the release candidate of new series
  41 GST_API_VERSION=1.0
  42 AC_SUBST(GST_API_VERSION)
  43
  44 AG_GST_LIBTOOL_PREPARE
  45 AS_LIBTOOL(GST, 501, 0, 501)
  46
  47 dnl *** required versions of GStreamer stuff ***
  48 GST_REQ=1.5.0.1
  49 GST_PBREQ=1.5.0.1
  50
  51 ORC_REQ=0.4.16
  52 ORC_CHECK([$ORC_REQ])
  53
  54 dnl *** autotools stuff ****
  55
  56 dnl allow for different autotools
  57 AS_AUTOTOOLS_ALTERNATE
  58
  59 dnl Add parameters for aclocal
  60 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  61
  62 dnl *** check for arguments to configure ***
  63
  64 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  65
  66 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  67 AG_GST_ARG_WITH_PACKAGE_NAME
  68 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  69 AG_GST_ARG_VALGRIND
  70 AG_GST_ARG_GCOV
  71
  72 dnl *** checks for platform ***
  73
  74 dnl * hardware/architecture *
  75
  76 dnl common/m4/gst-arch.m4
  77 dnl check CPU type
  78 AG_GST_ARCH
  79
  80 dnl *** checks for programs ***
  81
  82 dnl find a compiler
  83 AC_PROG_CC
  84 AC_PROG_CC_STDC
  85
  86 dnl check if the compiler supports '-c' and '-o' options
  87 AM_PROG_CC_C_O
  88
  89 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
  90 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
  91
  92 dnl check for documentation tools
  93 GTK_DOC_CHECK([1.12])
  94 AG_GST_PLUGIN_DOCS([1.12])
  95
  96 dnl *** checks for libraries ***
  97
  98 dnl check for libm, for sin()
  99 LT_LIB_M
 100 AC_SUBST(LIBM)
 101
 102 dnl *** checks for header files ***
 103
 104 dnl check if we have ANSI C header files
 105 AC_HEADER_STDC
 106
 107 dnl *** checks for types/defines ***
 108
 109 dnl *** checks for structures ***
 110
 111 dnl *** checks for compiler characteristics ***
 112
 113 dnl *** checks for library functions ***
 114
 115 dnl *** checks for dependancy libraries ***
 116
 117 dnl checks for gstreamer
 118 dnl uninstalled is selected preferentially -- see pkg-config(1)
 119 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ])
 120 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ])
 121 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GST_PBREQ])
 122 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 123 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 124
 125 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 126 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 127
 128 dnl *** set variables based on configure arguments ***
 129
 130 dnl set location of plugin directory
 131 AG_GST_SET_PLUGINDIR
 132
 133 dnl build static plugins or not
 134 AC_MSG_CHECKING([whether to build static plugins or not])
 135 AC_ARG_ENABLE(
 136   static-plugins,
 137   AC_HELP_STRING(
 138     [--enable-static-plugins],
 139     [build static plugins @<:@default=no@:>@]),
 140   [AS_CASE(
 141     [$enableval], [no], [], [yes], [],
 142     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 143   [enable_static_plugins=no])
 144 AC_MSG_RESULT([$enable_static_plugins])
 145 if test "x$enable_static_plugins" = xyes; then
 146   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 147     [Define if static plugins should be built])
 148   GST_PLUGIN_LIBTOOLFLAGS=""
 149 else
 150   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 151 fi
 152 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 153 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 154
 155 dnl define an ERROR_CFLAGS Makefile variable
 156 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 157     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 158     -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition
 159     -Winit-self -Wmissing-include-dirs -Waddress
 160     -Waggregate-return -Wno-multichar -Wnested-externs ])
 161
 162 dnl define correct level for debugging messages
 163 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 164
 165 dnl *** finalize CFLAGS, LDFLAGS, LIBS ***
 166
 167 dnl Overview:
 168 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 169 dnl GST_*:              flags shared by built objects to link against GStreamer
 170 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 171 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 172 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 173 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 174
 175 dnl GST_OPTION_CFLAGS
 176 if test "x$USE_DEBUG" = xyes; then
 177    PROFILE_CFLAGS="-g"
 178 fi
 179 AC_SUBST(PROFILE_CFLAGS)
 180
 181 if test "x$GST_GIT" = "xyes"; then
 182   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 183 else
 184   DEPRECATED_CFLAGS=""
 185 fi
 186 AC_SUBST(DEPRECATED_CFLAGS)
 187
 188 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 189 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 190
 191 AC_SUBST(GST_OPTION_CFLAGS)
 192
 193 dnl FIXME: do we want to rename to GST_ALL_* ?
 194 dnl prefer internal headers to already installed ones
 195 dnl also add builddir include for enumtypes and marshal
 196 dnl add GST_OPTION_CFLAGS, but overridable
 197 GST_CFLAGS="$GST_CFLAGS"
 198 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 199 AC_SUBST(GST_CFLAGS)
 200 AC_SUBST(GST_LIBS)
 201
 202 GST_ALL_LDFLAGS="-no-undefined"
 203 AC_SUBST(GST_ALL_LDFLAGS)
 204
 205 dnl this really should only contain flags, not libs - they get added before
 206 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 207 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 208 AC_SUBST(GST_PLUGIN_LDFLAGS)
 209
 210 dnl Add MacOSX specific flags
 211 AC_CANONICAL_HOST
 212 case $host_os in
 213      darwin*)
 214         DARWIN_LDFLAGS="-Wl,-read_only_relocs,suppress"
 215         ;;
 216      *)
 217         DARWIN_LDFLAGS=""
 218         ;;
 219 esac
 220 AC_SUBST(DARWIN_LDFLAGS)
 221
 222 dnl *** Check for bz2
 223 save_LIBS=$LIBS
 224 LIBS="$LIBS -lbz2"
 225 AC_MSG_CHECKING([for BZ2_bzlibVersion in -lbz2])
 226 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <bzlib.h>]], [[const char *version = BZ2_bzlibVersion ();]])],[HAVE_BZ2=yes],[HAVE_BZ2=no])
 227 AC_MSG_RESULT($HAVE_BZ2)
 228 LIBS=$save_LIBS
 229 AM_CONDITIONAL(HAVE_BZ2, test "x$HAVE_BZ2" = "xyes")
 230 if test "x$HAVE_BZ2" = "xno"; then
 231   AC_WARN([libbz2 not found, matroska demuxer will not be able to read bz2 tracks])
 232 fi
 233
 234 AC_ARG_ENABLE(lgpl,
 235               [AC_HELP_STRING([--enable-lgpl], [build a LGPL licensed gst-libav])])
 236 AM_CONDITIONAL(GST_LIBAV_ENABLE_LGPL, test "x$enable_lgpl" = "xyes")
 237 if test "x$enable_lgpl" = "xyes"; then
 238   AC_DEFINE([GST_LIBAV_ENABLE_LGPL], [], [Defined if building a LGPL-only version of gst-libav])
 239 fi
 240
 241 dnl *** configure external libs ***
 242
 243 HAVE_LIBAV_UNINSTALLED=1
 244
 245 AC_ARG_WITH(system-libav,
 246             [AC_HELP_STRING([--with-system-libav], [use system Libav libraries])])
 247
 248 if test "x$with_system_libav" = "xyes"; then
 249   PKG_CHECK_MODULES(LIBAV, libavformat libavcodec libavutil)
 250   PKG_CHECK_MODULES(SWSCALE, libswscale libavutil)
 251   saved_CPPFLAGS="$CPPFLAGS"
 252   CPPFLAGS="$CPPFLAGS $LIBAV_CFLAGS"
 253   AC_CHECK_HEADERS([avi.h])
 254   CPPFLAGS="$saved_CPPFLAGS"
 255   AC_DEFINE([LIBAV_SOURCE], ["system install"], [Describes where the Libav libraries come from.])
 256   HAVE_LIBAV_UNINSTALLED=0
 257   AC_MSG_NOTICE([Using system-installed libav code])
 258 else
 259   AC_MSG_NOTICE([Using local Libav snapshot])
 260
 261   dnl libgstlibav.la: include dirs
 262   LIBAV_CFLAGS="-I \$(top_srcdir)/gst-libs/ext/libav \
 263                 -I \$(top_builddir)/gst-libs/ext/libav \
 264                  -Wno-deprecated-declarations"
 265
 266   LIBAV_DEPS="\$(top_builddir)/gst-libs/ext/libav/libavformat/libavformat.a \
 267               \$(top_builddir)/gst-libs/ext/libav/libavcodec/libavcodec.a \
 268               \$(top_builddir)/gst-libs/ext/libav/libavutil/libavutil.a"
 269   if test "x$enable_static_plugins" = xyes; then
 270       dnl with static linking we can't use the .a archive directly as they would
 271       dnl be included in the final libgstlibav.a as a file and won't be usable.
 272       dnl libav*.a must be copied to the final destination too
 273       LIBAV_LIBS="-lavformat -lavcodec -lavutil"
 274   else
 275       dnl libgstlibav.la: libs to statically link to
 276       LIBAV_LIBS="$LIBAV_DEPS"
 277   fi
 278
 279   dnl
 280   SWSCALE_CFLAGS="-I \$(top_srcdir)/gst-libs/ext/libav \
 281                   -I \$(top_builddir)/gst-libs/ext/libav \
 282                   -Wno-deprecated-declarations"
 283
 284   SWSCALE_DEPS="\$(top_builddir)/gst-libs/ext/libav/libswscale/libswscale.a \
 285                 \$(top_builddir)/gst-libs/ext/libav/libavutil/libavutil.a"
 286   if test "x$enable_static_plugins" = xyes; then
 287       dnl with static linking we can't use the .a archive directly as they would
 288       dnl be included in the final libgstswscale.a as a file and won't be usable.
 289       dnl libav*.a must be copied to the final destination too
 290       SWSCALE_LIBS="-lswscale -lavutil"
 291   else
 292       dnl libgstswscale.la: libs to statically link to
 293       SWSCALE_LIBS="$SWSCALE_DEPS"
 294   fi
 295
 296   LIBAV_SUBDIRS=gst-libs
 297   AC_DEFINE(HAVE_AVI_H)
 298   AC_DEFINE([LIBAV_SOURCE], ["local snapshot"], [Describes where the Libav libraries come from.])
 299
 300   AC_ARG_WITH(libav-extra-configure,
 301       AC_HELP_STRING([--with-libav-extra-configure="xxx"],
 302       [extra configure options for internal libav ./configure script]),,
 303       with_libav=no)
 304
 305   # basic arguments
 306   emblibav_configure_args="--prefix=$prefix"
 307
 308   # Enable pic and static so that we get .a files, but with PIC code.
 309   emblibav_configure_args="$emblibav_configure_args --disable-avserver --disable-avplay\
 310         --disable-avconv --disable-avprobe --enable-static --enable-pic \
 311         --disable-encoder=flac --disable-decoder=cavs --disable-protocols --disable-devices\
 312         --disable-network --disable-hwaccels --disable-dxva2 --disable-vdpau\
 313         --disable-filters --disable-doc --enable-optimizations"
 314
 315   if test "x$enable_lgpl" != "xyes"; then
 316     emblibav_configure_args="$emblibav_configure_args --enable-gpl"
 317   fi
 318
 319   # if we are cross-compiling, tell libav so
 320   case $host in
 321       *android*)
 322         target_os=linux
 323       ;;
 324       *darwin*)
 325         target_os=darwin
 326       ;;
 327       *)
 328         target_os=`echo $host_os | sed 's/-gnu//'`
 329       ;;
 330   esac
 331
 332   if test "x$cross_compiling" = xyes; then
 333     emblibav_configure_args="$emblibav_configure_args --enable-cross-compile \
 334         --target-os=$target_os --arch=$host_cpu --cross-prefix=$host_alias-"
 335   fi
 336
 337   case $host_os in
 338     mingw32*)
 339       emblibav_configure_args="$emblibav_configure_args --enable-memalign-hack"
 340       WIN32_LIBS="-lws2_32"
 341       ;;
 342     *)
 343       WIN32_LIBS=
 344       ;;
 345   esac
 346
 347   if test x"$AR" != x; then
 348     emblibav_configure_args="$emblibav_configure_args --ar=\\\"\\\$AR\\\""
 349   fi
 350
 351   if test x"$AS" != x; then
 352     emblibav_configure_args="$emblibav_configure_args --as=\\\"\\\$CC\\\""
 353   fi
 354
 355   if test x"$CC" != x; then
 356     emblibav_configure_args="$emblibav_configure_args --cc=\\\"\\\$CC\\\""
 357   fi
 358
 359   if test x"$LD" != x; then
 360     emblibav_configure_args="$emblibav_configure_args --ld=\\\"\\\$CC\\\""
 361   fi
 362
 363   if test x"$NM" != x; then
 364     emblibav_configure_args="$emblibav_configure_args --nm=\\\"\\\$NM\\\""
 365   fi
 366
 367   dnl checks for extra enable/disable flags
 368   LIBAV_OPTS=`cd $srcdir/gst-libs/ext/libav && ./configure --help`
 369   # Let's check if we can disable the building of the libav binary
 370   can_disable=`echo "$LIBAV_OPTS" | grep 'disable-ffmpeg'`
 371   if test "$can_disable" != ""; then
 372     emblibav_configure_args="$emblibav_configure_args --disable-ffmpeg"
 373   fi
 374   dnl check if libswscale needs enabling explicitly
 375   can_enable=`echo "$LIBAV_OPTS" | grep 'enable-swscale'`
 376   if test "$can_enable" != ""; then
 377     emblibav_configure_args="$emblibav_configure_args --enable-swscale"
 378   fi
 379
 380   # append extra configure options to emblibav_configure_args if needed
 381   if test "x$with_libav_extra_configure" != "xno"; then
 382     emblibav_configure_args="$emblibav_configure_args $with_libav_extra_configure"
 383   fi
 384
 385   AC_SUBST(LIBAV_CO_DIR)
 386   AC_SUBST(LIBAV_SVN)
 387   AC_SUBST(LIBAV_REVISION)
 388   AC_SUBST(LIBAV_EXTERNALS_REVISION)
 389   AC_CONFIG_COMMANDS([configure-embedded-libav],
 390     [echo "Configuring included Libav instance with args $emblibav_configure_args"
 391      origdir=`pwd`
 392      dnl Don't put path on the configure call when not needed, as FFmpeg's configure relies on it
 393      dnl to detect out-of-tree builds
 394      if test -z "$srcdir" -o "$srcdir" = .; then
 395        confcmd=./configure
 396      else
 397        confcmd="$ac_abs_top_srcdir"/gst-libs/ext/libav/configure
 398      fi
 399
 400      AS_MKDIR_P(["$ac_top_build_prefix"gst-libs/ext/libav])
 401      cd "$ac_top_build_prefix"gst-libs/ext/libav &&
 402          eval "$confcmd $emblibav_configure_args" ||
 403          AC_MSG_ERROR([Failed to configure embedded Libav tree])
 404      cd "$origdir"
 405     ],
 406     [emblibav_configure_args="$emblibav_configure_args"])
 407   AC_MSG_NOTICE([Using included Libav code])
 408 fi
 409
 410 AC_SUBST(LIBAV_CFLAGS)
 411 AC_SUBST(LIBAV_DEPS)
 412 AC_SUBST(LIBAV_LIBS)
 413 AC_SUBST(LIBAV_SUBDIRS)
 414 AC_SUBST(SWSCALE_CFLAGS)
 415 AC_SUBST(SWSCALE_DEPS)
 416 AC_SUBST(SWSCALE_LIBS)
 417 AC_SUBST(WIN32_LIBS)
 418
 419 if test x$HAVE_LIBAV_UNINSTALLED = x1; then
 420   AC_DEFINE(HAVE_LIBAV_UNINSTALLED, [], [Defined if building against uninstalled Libav source])
 421 fi
 422 AM_CONDITIONAL(HAVE_LIBAV_UNINSTALLED, test x$HAVE_LIBAV_UNINSTALLED = x1)
 423
 424 AC_CONFIG_FILES(
 425 Makefile
 426 common/Makefile
 427 common/m4/Makefile
 428 gst-libav.spec
 429 ext/Makefile
 430 ext/libav/Makefile
 431 ext/libswscale/Makefile
 432 gst-libs/Makefile
 433 gst-libs/ext/Makefile
 434 docs/Makefile
 435 docs/plugins/Makefile
 436 docs/version.entities
 437 tests/Makefile
 438 tests/check/Makefile
 439 tests/files/Makefile
 440 pkgconfig/Makefile
 441 pkgconfig/gstreamer-plugins-libav-uninstalled.pc
 442 )
 443 AC_OUTPUT
 444
 445 ORC_OUTPUT