configure.ac

   1 ## Process this file with autoconf to produce configure.
   2 ## In general, the safest way to proceed is to run the following:
   3 ##    % aclocal -I . -I `pwd`/../autoconf && autoheader && autoconf && automake
   4
   5 # make sure we're interpreted by some minimal autoconf
   6 AC_PREREQ(2.57)
   7
   8 AC_INIT(glog, 0.2.1, opensource@google.com)
   9 # The argument here is just something that should be in the current directory
  10 # (for sanity checking)
  11 AC_CONFIG_SRCDIR(README)
  12 AM_INIT_AUTOMAKE
  13 AM_CONFIG_HEADER(src/config.h)
  14
  15 # Checks for programs.
  16 AC_PROG_CC
  17 AC_PROG_CPP
  18 AC_PROG_CXX
  19 AM_CONDITIONAL(GCC, test "$GCC" = yes)   # let the Makefile know if we're gcc
  20
  21 AC_PROG_LIBTOOL
  22 AC_SUBST(LIBTOOL_DEPS)
  23
  24 # Check whether some low-level functions/files are available
  25 AC_HEADER_STDC
  26
  27 # These are tested for by AC_HEADER_STDC, but I check again to set the var
  28 AC_CHECK_HEADER(stdint.h, ac_cv_have_stdint_h=1, ac_cv_have_stdint_h=0)
  29 AC_CHECK_HEADER(sys/types.h, ac_cv_have_systypes_h=1, ac_cv_have_systypes_h=0)
  30 AC_CHECK_HEADER(inttypes.h, ac_cv_have_inttypes_h=1, ac_cv_have_inttypes_h=0)
  31 AC_CHECK_HEADERS(unistd.h, ac_cv_have_unistd_h=1, ac_cv_have_unistd_h=0)
  32 AC_CHECK_HEADERS(syscall.h)
  33 AC_CHECK_HEADERS(sys/syscall.h)
  34 # For backtrace with glibc.
  35 AC_CHECK_HEADERS(execinfo.h)
  36 # For backtrace with libunwind.
  37 AC_CHECK_HEADERS(libunwind.h)
  38 AC_CHECK_HEADERS(ucontext.h)
  39 AC_CHECK_HEADERS(sys/utsname.h)
  40 AC_CHECK_HEADERS(pwd.h)
  41 AC_CHECK_HEADERS(syslog.h)
  42 AC_CHECK_HEADERS(sys/time.h)
  43 AC_CHECK_HEADERS(glob.h)
  44
  45 AC_CHECK_SIZEOF(void *)
  46
  47 # These are the types I need.  We look for them in either stdint.h,
  48 # sys/types.h, or inttypes.h, all of which are part of the default-includes.
  49 AC_CHECK_TYPE(uint16_t, ac_cv_have_uint16_t=1, ac_cv_have_uint16_t=0)
  50 AC_CHECK_TYPE(u_int16_t, ac_cv_have_u_int16_t=1, ac_cv_have_u_int16_t=0)
  51 AC_CHECK_TYPE(__uint16, ac_cv_have___uint16=1, ac_cv_have___uint16=0)
  52
  53 AC_CHECK_FUNC(sigaltstack,
  54               AC_DEFINE(HAVE_SIGALTSTACK, 1,
  55                         [Define if you have the `sigaltstack' function]))
  56 AC_CHECK_FUNC(dladdr,
  57               AC_DEFINE(HAVE_DLADDR, 1,
  58                         [Define if you have the `dladdr' function]))
  59 AC_CHECK_FUNC(fcntl,
  60               AC_DEFINE(HAVE_FCNTL, 1,
  61                         [Define if you have the `fcntl' function]))
  62
  63 AX_C___ATTRIBUTE__
  64 # We only care about these two attributes.
  65 if test x"$ac_cv___attribute__" = x"yes"; then
  66   ac_cv___attribute___noreturn="__attribute__ ((noreturn))"
  67   ac_cv___attribute___printf_4_5="__attribute__((__format__ (__printf__, 4, 5)))"
  68 else
  69   ac_cv___attribute___noreturn=
  70   ac_cv___attribute___printf_4_5=
  71 fi
  72
  73 AX_C___BUILTIN_EXPECT
  74 if test x"$ac_cv___builtin_expect" = x"yes"; then
  75   ac_cv_have___builtin_expect=1
  76 else
  77   ac_cv_have___builtin_expect=0
  78 fi
  79
  80 AX_C___SYNC_VAL_COMPARE_AND_SWAP
  81
  82 # On x86_64, instead of libunwind, we can choose to compile with frame-pointers
  83 # (This isn't needed on i386, where -fno-omit-frame-pointer is the default).
  84 AC_ARG_ENABLE(frame_pointers,
  85               AS_HELP_STRING([--enable-frame-pointers],
  86                              [On x86_64 systems, compile with -fno-omit-frame-pointer (see INSTALL)]),
  87               enable_frame_pointers=no)
  88 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(, [return __x86_64__ == 1 ? 0 : 1])],
  89                   [is_x86_64=yes], [is_x86_64=no])
  90 AM_CONDITIONAL(ENABLE_FRAME_POINTERS, test "$enable_frame_pointers" = yes)
  91 AM_CONDITIONAL(X86_64, test "$is_x86_64" = yes)
  92
  93 # Some of the code in this directory depends on pthreads
  94 ACX_PTHREAD
  95 if test x"$acx_pthread_ok" = x"yes"; then
  96   # To make libglog depend on libpthread on Linux, we need to add
  97   # -lpthread in addition to -pthread.
  98   AC_CHECK_LIB(pthread, pthread_self)
  99 fi
 100
 101 # Check if there is google-gflags library installed.
 102 SAVE_CFLAGS="$CFLAGS"
 103 SAVE_LIBS="$LIBS"
 104 AC_ARG_WITH(gflags, AS_HELP_STRING[--with-gflags=GFLAGS_DIR],
 105   GFLAGS_CFLAGS="-I${with_gflags}/include"
 106   GFLAGS_LIBS="-L${with_gflags}/lib -lgflags"
 107   CFLAGS="$CFLAGS $GFLAGS_CFLAGS"
 108   LIBS="$LIBS $GFLAGS_LIBS"
 109 )
 110 AC_CHECK_LIB(gflags, main, ac_cv_have_libgflags=1, ac_cv_have_libgflags=0)
 111 if test x"$ac_cv_have_libgflags" = x"1"; then
 112   AC_DEFINE(HAVE_LIB_GFLAGS, 1, [define if you have google gflags library])
 113 else
 114   GFLAGS_CFLAGS=
 115   GFLAGS_LIBS=
 116 fi
 117 CFLAGS="$SAVE_CFLAGS"
 118 LIBS="$SAVE_LIBS"
 119
 120 # TODO(hamaji): Use official m4 macros provided by testing libraries
 121 #               once the m4 macro of Google Mocking becomes ready.
 122 # Check if there is Google Test library installed.
 123 AC_CHECK_PROG(GTEST_CONFIG, gtest-config, "yes")
 124 if test x"$GTEST_CONFIG" = "xyes"; then
 125   GTEST_CFLAGS=`gtest-config --cppflags --cxxflags`
 126   GTEST_LIBS=`gtest-config --ldflags --libs`
 127   AC_DEFINE(HAVE_LIB_GTEST, 1, [define if you have google gtest library])
 128
 129   # Check if there is Google Mocking library installed.
 130   AC_CHECK_PROG(GMOCK_CONFIG, gmock-config, "yes")
 131   if test x"$GMOCK_CONFIG" = "xyes"; then
 132     GMOCK_CFLAGS=`gmock-config --cppflags --cxxflags`
 133     GMOCK_LIBS=`gmock-config --ldflags --libs`
 134     AC_DEFINE(HAVE_LIB_GMOCK, 1, [define if you have google gmock library])
 135   else
 136     # We don't run test cases which use Google Mocking framework.
 137     GMOCK_CFLAGS=
 138     GMOCK_LIBS=
 139   fi
 140 else
 141   # We'll use src/googletest.h for our unittests.
 142   GTEST_CFLAGS=
 143   GTEST_LIBS=
 144 fi
 145 AM_CONDITIONAL(HAVE_GMOCK, test x"$GMOCK_CONFIG" = "xyes")
 146
 147 # We want to link in libunwind if it exists
 148 UNWIND_LIBS=
 149 # Unfortunately, we need to check the header file in addition to the
 150 # lib file to check if libunwind is available since libunwind-0.98
 151 # doesn't install all necessary header files.
 152 if test x"$ac_cv_have_libunwind_h" = x"1"; then
 153  AC_CHECK_LIB(unwind, backtrace, UNWIND_LIBS=-lunwind)
 154 fi
 155 AC_SUBST(UNWIND_LIBS)
 156 if test x"$UNWIND_LIBS" != x""; then
 157   AC_DEFINE(HAVE_LIB_UNWIND, 1, [define if you have libunwind])
 158 fi
 159
 160 # We'd like to use read/write locks in several places in the code.
 161 # See if our pthreads support extends to that.  Note: for linux, it
 162 # does as long as you define _XOPEN_SOURCE appropriately.
 163 AC_RWLOCK
 164
 165 # Find out what namespace 'normal' STL code lives in, and also what namespace
 166 # the user wants our classes to be defined in
 167 AC_CXX_STL_NAMESPACE
 168 AC_DEFINE_GOOGLE_NAMESPACE(google)
 169
 170 AC_CXX_USING_OPERATOR
 171
 172 # We want to access the "PC" (Program Counter) register from a struct
 173 # ucontext.  Every system has its own way of doing that.  We try all the
 174 # possibilities we know about.  Note REG_PC should come first (REG_RIP
 175 # is also defined on solaris, but does the wrong thing).
 176 AC_MSG_CHECKING([how to access the program counter from a struct ucontext])
 177 pc_fields="           uc_mcontext.gregs[[REG_PC]]"  # Solaris x86 (32 + 64 bit)
 178 pc_fields="$pc_fields uc_mcontext.gregs[[REG_EIP]]" # Linux (i386)
 179 pc_fields="$pc_fields uc_mcontext.gregs[[REG_RIP]]" # Linux (x86_64)
 180 pc_fields="$pc_fields uc_mcontext.sc_ip"            # Linux (ia64)
 181 pc_fields="$pc_fields uc_mcontext.uc_regs->gregs[[PT_NIP]]" # Linux (ppc)
 182 pc_fields="$pc_fields uc_mcontext.gregs[[R15]]"     # Linux (arm old [untested])
 183 pc_fields="$pc_fields uc_mcontext.arm_pc"           # Linux (arm new [untested])
 184 pc_fields="$pc_fields uc_mcontext.mc_eip"           # FreeBSD (i386)
 185 pc_fields="$pc_fields uc_mcontext.mc_rip"           # FreeBSD (x86_64 [untested])
 186 pc_fields="$pc_fields uc_mcontext->ss.eip"          # OS X (i386, <=10.4)
 187 pc_fields="$pc_fields uc_mcontext->__ss.__eip"      # OS X (i386, >=10.5)
 188 pc_fields="$pc_fields uc_mcontext->ss.rip"          # OS X (x86_64)
 189 pc_fields="$pc_fields uc_mcontext->__ss.__rip"      # OS X (>=10.5 [untested])
 190 pc_fields="$pc_fields uc_mcontext->ss.srr0"         # OS X (ppc, ppc64 [untested])
 191 pc_fields="$pc_fields uc_mcontext->__ss.__srr0"     # OS X (>=10.5 [untested])
 192 pc_field_found=false
 193 for pc_field in $pc_fields; do
 194   if ! $pc_field_found; then
 195     AC_TRY_COMPILE([#define _GNU_SOURCE 1
 196                     #include <ucontext.h>],
 197                    [ucontext_t u; return u.$pc_field == 0;],
 198                    AC_DEFINE_UNQUOTED(PC_FROM_UCONTEXT, $pc_field,
 199                                       How to access the PC from a struct ucontext)
 200                    AC_MSG_RESULT([$pc_field])
 201                  pc_field_found=true)
 202   fi
 203 done
 204 if ! $pc_field_found; then
 205   AC_MSG_WARN(Could not find the PC.  Will not output failed addresses...)
 206 fi
 207
 208 # These are what's needed by logging.h.in and raw_logging.h.in
 209 AC_SUBST(ac_google_start_namespace)
 210 AC_SUBST(ac_google_end_namespace)
 211 AC_SUBST(ac_google_namespace)
 212 AC_SUBST(ac_cv_cxx_using_operator)
 213 AC_SUBST(ac_cv___attribute___noreturn)
 214 AC_SUBST(ac_cv___attribute___printf_4_5)
 215 AC_SUBST(ac_cv_have___builtin_expect)
 216 AC_SUBST(ac_cv_have_stdint_h)
 217 AC_SUBST(ac_cv_have_systypes_h)
 218 AC_SUBST(ac_cv_have_inttypes_h)
 219 AC_SUBST(ac_cv_have_unistd_h)
 220 AC_SUBST(ac_cv_have_uint16_t)
 221 AC_SUBST(ac_cv_have_u_int16_t)
 222 AC_SUBST(ac_cv_have___uint16)
 223 AC_SUBST(ac_cv_have_libgflags)
 224 AC_SUBST(GFLAGS_CFLAGS)
 225 AC_SUBST(GTEST_CFLAGS)
 226 AC_SUBST(GMOCK_CFLAGS)
 227 AC_SUBST(GFLAGS_LIBS)
 228 AC_SUBST(GTEST_LIBS)
 229 AC_SUBST(GMOCK_LIBS)
 230
 231 # Write generated configuration file
 232 AC_CONFIG_FILES([Makefile src/glog/logging.h src/glog/raw_logging.h src/glog/vlog_is_on.h src/glog/stl_logging.h])
 233 AC_OUTPUT(libglog.pc)