configure.ac

   1 AC_PREREQ([2.68])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT([GStreamer Base Plug-ins],[1.3.0],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-base])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 dnl CURRENT, REVISION, AGE
  46 dnl - library source changed -> increment REVISION
  47 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  48 dnl - interfaces added -> increment AGE
  49 dnl - interfaces removed -> AGE = 0
  50 dnl
  51 dnl Keep CURRENT as MINOR * 100 + MICRO
  52 dnl Ex : 1.0.0 => 0
  53 dnl      1.0.3 => 3
  54 dnl      1.1.0 => 100
  55 dnl      1.2.5 => 205
  56 dnl      1.10.9 (who knows) => 1009
  57 dnl
  58 dnl sets GST_LT_LDFLAGS
  59 AS_LIBTOOL(GST, 300, 0, 300)
  60
  61 dnl *** required versions of GStreamer stuff ***
  62 GST_REQ=1.3.0
  63
  64 dnl *** autotools stuff ****
  65
  66 dnl allow for different autotools
  67 AS_AUTOTOOLS_ALTERNATE
  68
  69 dnl Add parameters for aclocal
  70 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  71
  72 dnl set up gettext
  73 dnl the version check needs to stay here because autopoint greps for it
  74 AM_GNU_GETTEXT_VERSION([0.17])
  75 AM_GNU_GETTEXT([external])
  76 AG_GST_GETTEXT([gst-plugins-base-$GST_API_VERSION])
  77
  78 dnl *** check for arguments to configure ***
  79
  80 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  81
  82 AG_GST_ARG_DEBUG
  83 AG_GST_ARG_PROFILING
  84 AG_GST_ARG_VALGRIND
  85 AG_GST_ARG_GCOV
  86
  87 AG_GST_ARG_EXAMPLES
  88
  89 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  90 AG_GST_ARG_WITH_PACKAGE_NAME
  91 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  92
  93 AG_GST_PKG_CONFIG_PATH
  94
  95 dnl let distro override plugin install helper path
  96 AC_ARG_WITH(install-plugins-helper,
  97   AS_HELP_STRING([--with-install-plugins-helper],[specify path of helper script to call to install plugins]),
  98   [
  99     case "${withval}" in
 100       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 101       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 103     esac
 104   ],
 105   [
 106     dnl Default value
 107     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 108   ]
 109 )
 110 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 111 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 112     [plugin install helper script])
 113 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 114
 115 AG_GST_ARG_WITH_PLUGINS
 116
 117 AG_GST_ARG_ENABLE_EXTERNAL
 118
 119 AG_GST_ARG_ENABLE_EXPERIMENTAL
 120
 121 dnl *** checks for platform ***
 122 AG_GST_PLATFORM
 123
 124 dnl * hardware/architecture *
 125
 126 dnl common/m4/gst-arch.m4
 127 dnl check CPU type
 128 AG_GST_ARCH
 129
 130 dnl check for large file support
 131 dnl affected plugins must include config.h
 132 AC_SYS_LARGEFILE
 133
 134 dnl *** checks for programs ***
 135
 136 dnl find a compiler
 137 AC_PROG_CC
 138 AC_PROG_CC_STDC
 139
 140 dnl check if the compiler supports '-c' and '-o' options
 141 AM_PROG_CC_C_O
 142
 143 dnl determine if c++ is available on this system
 144 AC_PROG_CXX
 145 dnl CXX may be set to some default even if no c++ compiler is available
 146 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 147 AC_LANG_PUSH([C++])
 148 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 149 AC_LANG_POP([C++])
 150 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 151 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 152
 153 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 154 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 155
 156 dnl check for gobject-introspection
 157 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 158
 159 dnl check for documentation tools
 160 GTK_DOC_CHECK([1.12])
 161 AG_GST_PLUGIN_DOCS([1.12])
 162
 163 dnl *** checks for libraries ***
 164
 165 dnl libm, for sin() etc.
 166 LT_LIB_M
 167 AC_SUBST(LIBM)
 168
 169 dnl *** checks for header files ***
 170
 171 dnl check if we have ANSI C header files
 172 AC_HEADER_STDC
 173
 174 dnl check for GCC specific SSE headers
 175 dnl these are used by the speex resampler code
 176 AC_CHECK_HEADERS([xmmintrin.h emmintrin.h])
 177
 178 dnl used in gst/tcp
 179 AC_CHECK_HEADERS([sys/socket.h],
 180   [HAVE_SYS_SOCKET_H="yes"], [HAVE_SYS_SOCKET_H="no"], [AC_INCLUDES_DEFAULT])
 181 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 182
 183 dnl used in gst-libs/gst/pbutils and associated unit test
 184 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h], [], [], [AC_INCLUDES_DEFAULT])
 185
 186 dnl checks for ARM NEON support
 187 dnl this instruction set is used by the speex resampler code
 188 AC_MSG_CHECKING(for ARM NEON support in current arch/CFLAGS)
 189 AC_LINK_IFELSE([
 190 AC_LANG_PROGRAM([[
 191   #include <arm_neon.h>
 192   int32x4_t testfunc(int16_t *a, int16_t *b) {
 193       return vmull_s16(vld1_s16(a), vld1_s16(b));
 194   }
 195 ]])],
 196 [
 197   AC_DEFINE(HAVE_ARM_NEON,[],[ARM NEON support is enabled])
 198   AC_MSG_RESULT(yes)
 199 ],
 200 [
 201   AC_MSG_RESULT(no)
 202 ])
 203
 204 dnl also, Windows does not have long long
 205 AX_CREATE_STDINT_H
 206
 207 dnl *** checks for functions ***
 208 AC_CHECK_FUNCS([localtime_r gmtime_r])
 209
 210 dnl *** checks for math functions ***
 211 LIBS_SAVE=$LIBS
 212 LIBS="$LIBS $LIBM"
 213 AC_CHECK_FUNCS(log2)
 214 LIBS=$LIBS_SAVE
 215
 216 dnl *** checks for types/defines ***
 217
 218 dnl *** checks for structures ***
 219
 220 dnl *** checks for compiler characteristics ***
 221
 222 dnl *** checks for library functions ***
 223
 224 dnl check for fseeko()
 225 AC_FUNC_FSEEKO
 226
 227 dnl Check for fast float to int casting as defined in C99
 228 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 229 save_libs=$LIBS
 230 LIBS="$LIBS $LIBM"
 231 AC_C99_FUNC_LRINT
 232 AC_C99_FUNC_LRINTF
 233 LIBS=$save_libs
 234
 235 dnl Check for a way to display the function name in debug output
 236 AG_GST_CHECK_FUNCTION
 237
 238 dnl *** checks for dependency libraries ***
 239
 240 dnl GLib
 241 GLIB_REQ=2.32
 242 AG_GST_GLIB_CHECK([$GLIB_REQ])
 243
 244 ORC_CHECK([0.4.18])
 245
 246 dnl checks for gstreamer
 247 dnl uninstalled is selected preferentially -- see pkg-config(1)
 248 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 249 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 250 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 251 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 252 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 253
 254 dnl Check for documentation xrefs
 255 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 256 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 257 AC_SUBST(GLIB_PREFIX)
 258 AC_SUBST(GST_PREFIX)
 259
 260 dnl GTK is optional and only used in examples
 261 HAVE_GTK=no
 262 HAVE_GTK_X11=no
 263 GTK_REQ=3.0.0
 264 if test "x$BUILD_EXAMPLES" = "xyes"; then
 265   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 266   dnl some examples need gtk+-x11
 267   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 268   PKG_CHECK_MODULES(GTK_QUARTZ, gtk+-quartz-3.0 >= $GTK_REQ, HAVE_GTK_QUARTZ=yes, HAVE_GTK_QUARTZ=no)
 269   AC_SUBST(GTK_LIBS)
 270   AC_SUBST(GTK_CFLAGS)
 271 fi
 272 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 273 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 274 AM_CONDITIONAL(HAVE_GTK_QUARTZ, test "x$HAVE_GTK_QUARTZ" = "xyes")
 275
 276 dnl QT is optional and only used in examples
 277 PKG_CHECK_MODULES(QT, QtGui >= 4.6, [
 278   HAVE_QT_GV=yes
 279   HAVE_QT=yes
 280 ], [
 281   HAVE_QT_GV=no
 282   PKG_CHECK_MODULES(QT, QtGui >= 4.0, HAVE_QT=yes, HAVE_QT=no)
 283 ])
 284 if test "x$HAVE_QT" = "xyes"; then
 285   AC_MSG_CHECKING([Qt moc])
 286   QT4_MOC=`$PKG_CONFIG --variable=moc_location QtGui`
 287   AC_MSG_RESULT($QT4_MOC)
 288   AC_SUBST(QT4_MOC)
 289 fi
 290 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 291 AM_CONDITIONAL(HAVE_QT_GV, test "x$HAVE_QT_GV" = "xyes")
 292
 293 dnl chck for linux headers needed by the joystick seek example
 294 AC_COMPILE_IFELSE(
 295 [
 296   AC_LANG_PROGRAM([
 297     #include <linux/input.h>
 298     #include <linux/joystick.h>
 299   ],[
 300     struct js_event js;
 301     js.type = JS_EVENT_AXIS;
 302   ])
 303 ], [
 304   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 305 ], [
 306   HAVE_LINUX_JOYSTICK_HEADERS="no"
 307 ])
 308 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 309
 310 dnl Check for -Bsymbolic-functions linker flag used to avoid
 311 dnl intra-library PLT jumps, if available.
 312 AC_ARG_ENABLE(Bsymbolic,
 313               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 314               [SAVED_LDFLAGS="${LDFLAGS}"
 315                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 316                LDFLAGS=-Wl,-Bsymbolic-functions
 317                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int main (void) { return 0; }]])],[
 318                            AC_MSG_RESULT(yes)
 319                            enable_Bsymbolic=yes],[
 320                            AC_MSG_RESULT(no)
 321                            enable_Bsymbolic=no])
 322                LDFLAGS="${SAVED_LDFLAGS}"])
 323
 324
 325 dnl *** set variables based on configure arguments ***
 326
 327 dnl set license and copyright notice
 328 GST_LICENSE="LGPL"
 329 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 330 AC_SUBST(GST_LICENSE)
 331
 332 dnl set location of plugin directory
 333 AG_GST_SET_PLUGINDIR
 334
 335 dnl set release date/time
 336 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 337   ["${srcdir}/gst-plugins-base.doap"],
 338   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 339
 340 dnl build static plugins or not
 341 AC_MSG_CHECKING([whether to build static plugins or not])
 342 AC_ARG_ENABLE(
 343   static-plugins,
 344   AC_HELP_STRING(
 345     [--enable-static-plugins],
 346     [build static plugins @<:@default=no@:>@]),
 347   [AS_CASE(
 348     [$enableval], [no], [], [yes], [],
 349     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 350   [enable_static_plugins=no])
 351 AC_MSG_RESULT([$enable_static_plugins])
 352 if test "x$enable_static_plugins" = xyes; then
 353   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 354     [Define if static plugins should be built])
 355   GST_PLUGIN_LIBTOOLFLAGS=""
 356 else
 357   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 358 fi
 359 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 360 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 361
 362 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 363 dnl make sure it doesn't complain about unused variables if debugging is disabled
 364 NO_WARNINGS=""
 365 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 366
 367 dnl define an ERROR_CFLAGS Makefile variable
 368 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 369 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 370     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 371     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 372     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 373     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 374
 375 dnl define an ERROR_CXXFLAGS Makefile variable
 376 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 377     -Wmissing-declarations -Wredundant-decls -Wundef
 378     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 379     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 380     -Wno-multichar $NO_WARNINGS])
 381
 382 dnl define correct level for debugging messages
 383 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 384
 385 dnl used in examples
 386 AG_GST_DEFAULT_ELEMENTS
 387
 388 dnl needed for encoding-target
 389 GST_DATADIR="$GST_PREFIX/share"
 390 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 391 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION", [major/minor version])
 392
 393 dnl behaviour of speex based audio resampler
 394 AC_MSG_CHECKING(which audio resample format to use for integer)
 395 AC_ARG_WITH([audioresample_format],
 396         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 397         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 398 AC_MSG_RESULT($ac_cv_audioresample_format)
 399 case $ac_cv_audioresample_format in
 400   int)
 401     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 402     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 403   ;;
 404   float)
 405     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 406     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 407   ;;
 408   auto)
 409     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 410     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 411 esac
 412
 413 dnl Check for mmap (needed by allocators library)
 414 AC_CHECK_FUNC([mmap], [AC_DEFINE(HAVE_MMAP, 1, [Defined if mmap is supported])])
 415
 416 dnl *** plug-ins to include ***
 417
 418 dnl these are all the gst plug-ins, compilable without additional libs
 419 AG_GST_CHECK_PLUGIN(adder)
 420 AG_GST_CHECK_PLUGIN(app)
 421 AG_GST_CHECK_PLUGIN(audioconvert)
 422 AG_GST_CHECK_PLUGIN(audiorate)
 423 AG_GST_CHECK_PLUGIN(audiotestsrc)
 424 AG_GST_CHECK_PLUGIN(encoding)
 425 AG_GST_CHECK_PLUGIN(videoconvert)
 426 AG_GST_CHECK_PLUGIN(gio)
 427 AG_GST_CHECK_PLUGIN(playback)
 428 AG_GST_CHECK_PLUGIN(audioresample)
 429 AG_GST_CHECK_PLUGIN(subparse)
 430 AG_GST_CHECK_PLUGIN(tcp)
 431 AG_GST_CHECK_PLUGIN(typefind)
 432 AG_GST_CHECK_PLUGIN(videotestsrc)
 433 AG_GST_CHECK_PLUGIN(videorate)
 434 AG_GST_CHECK_PLUGIN(videoscale)
 435 AG_GST_CHECK_PLUGIN(volume)
 436
 437 dnl iso-codes is optional, used by libgsttag
 438 AC_ARG_ENABLE(iso-codes,
 439 AS_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 440 [case "${enableval}" in
 441   yes) enable_iso_codes=yes ;;
 442   no)  enable_iso_codes=no ;;
 443   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 444 esac
 445 ],
 446 [enable_iso_codes=yes]) dnl Default value
 447
 448 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 449 if test "x$enable_iso_codes" = "xyes"; then
 450   AC_MSG_RESULT([yes])
 451   have_iso_codes=no
 452   AC_MSG_CHECKING([whether iso-codes are available on this system])
 453   if $PKG_CONFIG iso-codes; then
 454     AC_MSG_RESULT([yes])
 455     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 456     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 457       AC_MSG_RESULT([yes])
 458       AC_MSG_CHECKING([for iso-codes prefix])
 459       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 460       if test -d "$ISO_CODES_PREFIX"; then
 461         AC_MSG_RESULT([yes])
 462         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 463         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 464         ISO_639_DOMAIN="iso_639"
 465         AC_MSG_CHECKING([ISO_639_DOMAIN])
 466         AC_MSG_RESULT([$ISO_639_DOMAIN])
 467         have_iso_codes=yes
 468         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 469         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 470         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 471         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 472       else
 473         AC_MSG_RESULT([no])
 474       fi
 475     else
 476       AC_MSG_RESULT([no])
 477     fi
 478   else
 479     AC_MSG_RESULT([no])
 480   fi
 481   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 482 else
 483   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 484   AM_CONDITIONAL(USE_ISO_CODES, false)
 485 fi
 486
 487 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 488 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 489 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 490   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 491       HAVE_ZLIB="yes"
 492     ], [
 493       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 494         HAVE_ZLIB="yes"
 495         ZLIB_LIBS="-lz"
 496         AC_SUBST(ZLIB_LIBS)
 497       ])
 498     ])
 499 ])
 500
 501 dnl *** sys plug-ins ***
 502
 503 echo
 504 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 505 echo
 506
 507 dnl *** X11 ***
 508 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 509 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 510                   [ximagesink], [
 511   AC_PATH_XTRA
 512   ac_cflags_save="$CFLAGS"
 513   ac_cppflags_save="$CPPFLAGS"
 514   CFLAGS="$CFLAGS $X_CFLAGS"
 515   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 516
 517   dnl now try to find the HEADER
 518   AC_CHECK_HEADER([X11/Xlib.h], [HAVE_X="yes"], [HAVE_X="no"], [AC_INCLUDES_DEFAULT])
 519
 520   if test "x$HAVE_X" = "xno"
 521   then
 522     AC_MSG_NOTICE([cannot find X11 development files])
 523   else
 524     dnl this is much more than we want
 525     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 526     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 527     dnl it does not add the libs; therefore we add them here
 528     X_LIBS="$X_LIBS -lX11"
 529     AC_SUBST(X_CFLAGS)
 530     AC_SUBST(X_LIBS)
 531   fi
 532   AC_SUBST(HAVE_X)
 533   CFLAGS="$ac_cflags_save"
 534   CPPFLAGS="$ac_cppflags_save"
 535 ])
 536
 537 dnl Check for Xv extension
 538 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 539 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 540                   [xvimagesink], [
 541   AG_GST_CHECK_XV
 542 ])
 543
 544 dnl check for X Shm
 545 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 546 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 547   if test x$HAVE_X = xyes; then
 548     AC_CHECK_LIB(Xext, XShmAttach,
 549                  HAVE_XSHM="yes", HAVE_XSHM="no",
 550                  $X_LIBS)
 551     if test "x$HAVE_XSHM" = "xyes"; then
 552       XSHM_LIBS="-lXext"
 553     else
 554       dnl On AIX, it is in XextSam instead, but we still need -lXext
 555       AC_CHECK_LIB(XextSam, XShmAttach,
 556                    HAVE_XSHM="yes", HAVE_XSHM="no",
 557                    $X_LIBS)
 558       if test "x$HAVE_XSHM" = "xyes"; then
 559         XSHM_LIBS="-lXext -lXextSam"
 560       fi
 561     fi
 562   fi
 563 ], , [
 564   AC_SUBST(HAVE_XSHM)
 565   AC_SUBST(XSHM_LIBS)
 566 ])
 567
 568 dnl *** ext plug-ins ***
 569 dnl keep this list sorted alphabetically !
 570
 571 if test "x$BUILD_EXTERNAL" = "xyes"; then
 572
 573 echo
 574 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 575 echo
 576
 577 dnl *** alsa ***
 578 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 579 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 580   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 581     HAVE_ALSA="yes"
 582     AC_SUBST(ALSA_CFLAGS)
 583     AC_SUBST(ALSA_LIBS)
 584   ], [
 585     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 586   ])
 587 ])
 588
 589 dnl *** CDParanoia ***
 590 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 591 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 592 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 593   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 594     HAVE_CDPARANOIA="yes"
 595   ], [
 596     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 597                         cdda_open, -lm,
 598                         cdda_interface.h,
 599                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 600                         HEADER_DIR="no"
 601                         FOUND_CDPARANOIA="yes")
 602     if test "x$FOUND_CDPARANOIA" != "xyes";
 603     then
 604       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 605                           cdda_open, -lm,
 606                           cdda/cdda_interface.h,
 607                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 608                           HEADER_DIR="yes"
 609                           FOUND_CDPARANOIA="yes")
 610     fi
 611     if test "x$HEADER_DIR" = "xyes";
 612     then
 613       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 614                          defined if cdda headers are in a cdda/ directory)
 615     fi
 616     if test "x$FOUND_CDPARANOIA" = "xyes";
 617     then
 618       AC_CHECK_LIB(cdda_paranoia,
 619                    paranoia_cachemodel_size,
 620                    : ,
 621                    HAVE_CDPARANOIA=no,
 622                  [-lcdda_interface])
 623     fi
 624
 625     AC_SUBST(CDPARANOIA_LIBS)
 626   ])
 627 ])
 628 dnl FIXME : add second check somehow if that is necessary
 629 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 630 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 631
 632 dnl *** ivorbis ***
 633 dnl AM_PATH_IVORBIS only takes two options
 634 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 635 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 636   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 637   if test $HAVE_IVORBIS = no
 638   then
 639     IVORBIS_LIBS=
 640     IVORBIS_CFLAGS=
 641     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 642       [IVORBIS_LIBS=-lvorbisidec
 643       HAVE_IVORBIS=yes
 644       case $host in
 645       arm-*-*)
 646         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 647       esac
 648       ],
 649       HAVE_IVORBIS=no)
 650     AC_SUBST(IVORBIS_LIBS)
 651     AC_SUBST(IVORBIS_CFLAGS)
 652   else
 653     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 654       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 655       USE_TREMOLO=no)
 656   fi
 657 ])
 658
 659 dnl *** libvisual ***
 660 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 661 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 662   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 663   if test $HAVE_LIBVISUAL = no
 664   then
 665     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 666     if test x$HAVE_LIBVISUAL = xyes; then
 667       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 668     fi
 669   else
 670     if test x$HAVE_LIBVISUAL = xyes; then
 671       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 672     fi
 673   fi
 674   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 675   if test x$LIBVIS_PLUGINSDIR != x; then
 676     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 677         "$LIBVIS_PLUGINSDIR",
 678         [directory in which the detected libvisual's plugins are located])
 679   fi
 680 ])
 681
 682 dnl *** ogg ***
 683 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 684 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 685   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 686 ])
 687
 688 dnl *** pango ***
 689 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 690 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 691   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.22.0  pangocairo >= 1.22.0)
 692 ])
 693
 694 dnl *** theora ***
 695 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 696 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 697   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 698 ])
 699
 700 dnl *** vorbis ***
 701 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 702 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 703   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 704 ])
 705
 706 if test "x$HAVE_VORBIS" = "xyes"; then
 707   ac_cflags_save="$CFLAGS"
 708   AC_COMPILE_IFELSE([
 709     AC_LANG_PROGRAM([[
 710 #include <vorbis/codec.h>
 711                      ]],[[
 712 vorbis_dsp_state *v;
 713
 714 vorbis_synthesis_restart (v);
 715                      ]])], HAVE_VSR=yes, HAVE_VSR=no)
 716   if test "x$HAVE_VSR" = "xyes"; then
 717     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 718                        [defined if vorbis_synthesis_restart is present])
 719   fi
 720   CFLAGS="$ac_cflags_save"
 721 fi
 722
 723 else
 724
 725 dnl not building plugins with external dependencies,
 726 dnl but we still need to set the conditionals
 727 AM_CONDITIONAL(USE_ALSA, false)
 728 AM_CONDITIONAL(USE_CDPARANOIA, false)
 729 AM_CONDITIONAL(USE_IVORBIS, false)
 730 AM_CONDITIONAL(USE_LIBVISUAL, false)
 731 AM_CONDITIONAL(USE_OGG, false)
 732 AM_CONDITIONAL(USE_PANGO, false)
 733 AM_CONDITIONAL(USE_THEORA, false)
 734 AM_CONDITIONAL(USE_VORBIS, false)
 735
 736 fi dnl of EXT plugins
 737
 738 dnl seeking needs freetype, so check for it here
 739 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 740   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 741 ])
 742 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 743 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 744 AC_SUBST(FT2_CFLAGS)
 745 AC_SUBST(FT2_LIBS)
 746
 747 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 748
 749 dnl Overview:
 750 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 751 dnl GST_*:              flags shared by built objects to link against GStreamer
 752 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 753 dnl                          (compare to other modules) or for i18n
 754 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 755 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 756 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 757 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 758
 759 dnl GST_OPTION_CFLAGS
 760 if test "x$USE_DEBUG" = xyes; then
 761    PROFILE_CFLAGS="-g"
 762 fi
 763 AC_SUBST(PROFILE_CFLAGS)
 764
 765 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 766   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 767   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 768 else
 769   DEPRECATED_CFLAGS=""
 770 fi
 771 AC_SUBST(DEPRECATED_CFLAGS)
 772
 773 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 774 dnl at make time with e.g. make ERROR_CFLAGS=""
 775 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 776 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 777 AC_SUBST(GST_OPTION_CFLAGS)
 778 AC_SUBST(GST_OPTION_CXXFLAGS)
 779
 780 dnl our libraries need to be versioned correctly
 781 AC_SUBST(GST_LT_LDFLAGS)
 782
 783 dnl GST_PLUGINS_BASE_CFLAGS
 784 dnl prefer internal headers to already installed ones
 785 dnl also add builddir include for enumtypes and marshal
 786 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 787 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 788
 789 dnl FIXME: do we want to rename to GST_ALL_* ?
 790 dnl add GST_OPTION_CFLAGS, but overridable
 791 GST_CFLAGS="$GST_CFLAGS"
 792 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 793 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 794 AC_SUBST(GST_CFLAGS)
 795 AC_SUBST(GST_CXXFLAGS)
 796 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 797 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 798 AC_SUBST(GST_LIBS)
 799
 800 dnl LDFLAGS really should only contain flags, not libs - they get added before
 801 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 802 GST_ALL_LDFLAGS="-no-undefined"
 803 if test "x${enable_Bsymbolic}" = "xyes"; then
 804   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 805 fi
 806 AC_SUBST(GST_ALL_LDFLAGS)
 807
 808 dnl GST_LIB_LDFLAGS
 809 dnl linker flags shared by all libraries
 810 dnl LDFLAGS modifier defining exported symbols from built libraries
 811 dnl (export _gst_foo but not __gst_foo)
 812 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 813 AC_SUBST(GST_LIB_LDFLAGS)
 814
 815 dnl this really should only contain flags, not libs - they get added before
 816 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 817 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 818 AC_SUBST(GST_PLUGIN_LDFLAGS)
 819
 820 dnl *** output files ***
 821
 822 $MKDIR_P tests/check/orc
 823
 824 AC_CONFIG_FILES(
 825 Makefile
 826 gst-plugins-base.spec
 827 gst/Makefile
 828 gst/adder/Makefile
 829 gst/app/Makefile
 830 gst/audioconvert/Makefile
 831 gst/audiorate/Makefile
 832 gst/audiotestsrc/Makefile
 833 gst/encoding/Makefile
 834 gst/videoconvert/Makefile
 835 gst/gio/Makefile
 836 gst/playback/Makefile
 837 gst/audioresample/Makefile
 838 gst/subparse/Makefile
 839 gst/tcp/Makefile
 840 gst/typefind/Makefile
 841 gst/videotestsrc/Makefile
 842 gst/videorate/Makefile
 843 gst/videoscale/Makefile
 844 gst/volume/Makefile
 845 sys/Makefile
 846 sys/ximage/Makefile
 847 sys/xvimage/Makefile
 848 ext/Makefile
 849 ext/alsa/Makefile
 850 ext/cdparanoia/Makefile
 851 ext/libvisual/Makefile
 852 ext/ogg/Makefile
 853 ext/pango/Makefile
 854 ext/theora/Makefile
 855 ext/vorbis/Makefile
 856 gst-libs/Makefile
 857 gst-libs/gst/Makefile
 858 gst-libs/gst/allocators/Makefile
 859 gst-libs/gst/audio/Makefile
 860 gst-libs/gst/app/Makefile
 861 gst-libs/gst/fft/Makefile
 862 gst-libs/gst/riff/Makefile
 863 gst-libs/gst/rtp/Makefile
 864 gst-libs/gst/rtsp/Makefile
 865 gst-libs/gst/sdp/Makefile
 866 gst-libs/gst/tag/Makefile
 867 gst-libs/gst/pbutils/Makefile
 868 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 869 gst-libs/gst/video/Makefile
 870 tools/Makefile
 871 pkgconfig/Makefile
 872 pkgconfig/gstreamer-allocators.pc
 873 pkgconfig/gstreamer-allocators-uninstalled.pc
 874 pkgconfig/gstreamer-audio.pc
 875 pkgconfig/gstreamer-audio-uninstalled.pc
 876 pkgconfig/gstreamer-app.pc
 877 pkgconfig/gstreamer-app-uninstalled.pc
 878 pkgconfig/gstreamer-fft.pc
 879 pkgconfig/gstreamer-fft-uninstalled.pc
 880 pkgconfig/gstreamer-pbutils.pc
 881 pkgconfig/gstreamer-pbutils-uninstalled.pc
 882 pkgconfig/gstreamer-riff.pc
 883 pkgconfig/gstreamer-riff-uninstalled.pc
 884 pkgconfig/gstreamer-rtp.pc
 885 pkgconfig/gstreamer-rtp-uninstalled.pc
 886 pkgconfig/gstreamer-rtsp.pc
 887 pkgconfig/gstreamer-rtsp-uninstalled.pc
 888 pkgconfig/gstreamer-sdp.pc
 889 pkgconfig/gstreamer-sdp-uninstalled.pc
 890 pkgconfig/gstreamer-tag.pc
 891 pkgconfig/gstreamer-tag-uninstalled.pc
 892 pkgconfig/gstreamer-video.pc
 893 pkgconfig/gstreamer-video-uninstalled.pc
 894 pkgconfig/gstreamer-plugins-base.pc
 895 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 896 tests/Makefile
 897 tests/check/Makefile
 898 tests/examples/Makefile
 899 tests/examples/app/Makefile
 900 tests/examples/audio/Makefile
 901 tests/examples/dynamic/Makefile
 902 tests/examples/encoding/Makefile
 903 tests/examples/fft/Makefile
 904 tests/examples/gio/Makefile
 905 tests/examples/overlay/Makefile
 906 tests/examples/seek/Makefile
 907 tests/examples/snapshot/Makefile
 908 tests/examples/playback/Makefile
 909 tests/examples/playrec/Makefile
 910 tests/files/Makefile
 911 tests/icles/Makefile
 912 tests/icles/playback/Makefile
 913 docs/Makefile
 914 docs/design/Makefile
 915 docs/libs/Makefile
 916 docs/plugins/Makefile
 917 docs/version.entities
 918 po/Makefile.in
 919 common/Makefile
 920 common/m4/Makefile
 921 m4/Makefile
 922 )
 923
 924 dnl Create the config.h file for Visual Studio builds
 925 dnl Beware of spaces and /'s in some of the shell variable contents.
 926 sed \
 927     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 928     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 929     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 930     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 931     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 932     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 933     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 934     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 935     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 936     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 937     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 938     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 939     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 940     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 941     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 942     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 943     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 944     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 945     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 946     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 947     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 948     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
 949     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
 950     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 951     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 952     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 953     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 954     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 955     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 956     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 957     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 958     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 959     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 960     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 961     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 962     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
 963     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 964     config.h.in >win32/common/config.h-new
 965
 966
 967
 968 AC_OUTPUT
 969
 970 AG_GST_OUTPUT_PLUGINS
 971 ORC_OUTPUT
 972