configure.ac

   1 #  Copyright 2005 Adam Jackson.
   2 #
   3 #  Permission is hereby granted, free of charge, to any person obtaining a
   4 #  copy of this software and associated documentation files (the "Software"),
   5 #  to deal in the Software without restriction, including without limitation
   6 #  on the rights to use, copy, modify, merge, publish, distribute, sub
   7 #  license, and/or sell copies of the Software, and to permit persons to whom
   8 #  the Software is furnished to do so, subject to the following conditions:
   9 #
  10 #  The above copyright notice and this permission notice (including the next
  11 #  paragraph) shall be included in all copies or substantial portions of the
  12 #  Software.
  13 #
  14 #  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15 #  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16 #  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
  17 #  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
  18 #  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  19 #  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  20 #
  21 # Process this file with autoconf to produce a configure script
  22
  23 AC_PREREQ([2.60])
  24 AC_INIT([intel-gpu-tools],
  25         [1.3],
  26         [https://bugs.freedesktop.org/enter_bug.cgi?product=xorg],
  27         [intel-gpu-tools])
  28
  29 AC_CONFIG_SRCDIR([Makefile.am])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_MACRO_DIR([m4])
  32 AC_CONFIG_AUX_DIR([build-aux])
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_GNU_SOURCE
  36
  37 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  38 AM_PATH_PYTHON([3],, [:])
  39 AM_MAINTAINER_MODE
  40
  41 # Checks for functions, headers, structures, etc.
  42 AC_CHECK_HEADERS([termios.h])
  43 AC_CHECK_MEMBERS([struct sysinfo.totalram],[],[],[AC_INCLUDES_DEFAULT
  44                   #include <sys/sysinfo.h>
  45                   ])
  46 AC_CHECK_FUNCS([swapctl])
  47 AC_CHECK_FUNCS([asprintf])
  48
  49 # Initialize libtool
  50 AC_DISABLE_STATIC
  51 AC_PROG_LIBTOOL
  52
  53 # Require X.Org macros 1.16 or later for XORG_TESTSET_CFLAG
  54 m4_ifndef([XORG_MACROS_VERSION],
  55           [m4_fatal([must install xorg-macros 1.16 or later before running autoconf/autogen])])
  56 XORG_MACROS_VERSION(1.16)
  57 XORG_DEFAULT_OPTIONS
  58
  59 PKG_CHECK_MODULES(DRM, [libdrm_intel >= 2.4.38 libdrm])
  60 PKG_CHECK_MODULES(PCIACCESS, [pciaccess >= 0.10])
  61
  62 # for dma-buf tests
  63 AC_ARG_ENABLE(nouveau, AS_HELP_STRING([--disable-nouveau],
  64               [Enable use of nouveau API for prime tests (default: enabled)]),
  65               [NOUVEAU=$enableval], [NOUVEAU=yes])
  66 if test "x$NOUVEAU" = xyes; then
  67         PKG_CHECK_MODULES(DRM_NOUVEAU, [libdrm_nouveau >= 2.4.33])
  68         AC_DEFINE(HAVE_NOUVEAU, 1, [Have nouveau support])
  69 fi
  70 AM_CONDITIONAL(HAVE_NOUVEAU, [test "x$NOUVEAU" = xyes])
  71
  72 # for testdisplay
  73 PKG_CHECK_MODULES(CAIRO, cairo)
  74 PKG_CHECK_MODULES(LIBUDEV, [libudev], [udev=yes], [udev=no])
  75 if test x"$udev" = xyes; then
  76         AC_DEFINE(HAVE_UDEV,1,[Enable udev-based monitor hotplug detection])
  77 fi
  78 PKG_CHECK_MODULES(GLIB, glib-2.0)
  79
  80 # -----------------------------------------------------------------------------
  81 #                       Configuration options
  82 # -----------------------------------------------------------------------------
  83 # Define a configure option for the shadder debugger
  84 AC_ARG_ENABLE(shader-debugger, AS_HELP_STRING([--enable-shader-debugger],
  85               [Enable shader debugging support [autodetected]]),
  86               [BUILD_SHADER_DEBUGGER="$enableval"], [BUILD_SHADER_DEBUGGER=auto])
  87
  88 # Shadder debugger depends on python3, intel-genasm and objcopy
  89 if test "x$BUILD_SHADER_DEBUGGER" != xno; then
  90         # Check Python 3 is installed
  91         if test "$PYTHON" = ":" ; then
  92                 if test "x$BUILD_SHADER_DEBUGGER" = xyes; then
  93                         AC_MSG_ERROR([Shader debugger requested, python version 3 not found.])
  94                 else
  95                         BUILD_SHADER_DEBUGGER=no
  96                 fi
  97         fi
  98         # Check for the Intel Chipset assembler compiler
  99         AC_PATH_PROGS([GEN4ASM], intel-gen4asm)
 100         if test -z "$GEN4ASM" ; then
 101                 if test "x$BUILD_SHADER_DEBUGGER" = xyes; then
 102                         AC_MSG_ERROR([Shader debugger requested, but intel-gen4asm not found.])
 103                 else
 104                         BUILD_SHADER_DEBUGGER=no
 105                 fi
 106         fi
 107         # Check for the objcopy GNU binary utiliy command
 108         AC_PATH_PROGS([OBJCOPY], objcopy)
 109         if test -z "$OBJCOPY" ; then
 110                 if test "x$BUILD_SHADER_DEBUGGER" = xyes; then
 111                         AC_MSG_ERROR([Shader debugger requested, but objcopy command not found.])
 112                 else
 113                         BUILD_SHADER_DEBUGGER=no
 114                 fi
 115         fi
 116 fi
 117
 118 AM_CONDITIONAL(BUILD_SHADER_DEBUGGER, [test "x$BUILD_SHADER_DEBUGGER" != xno])
 119 # -----------------------------------------------------------------------------
 120
 121 # To build multithread code, gcc uses -pthread, Solaris Studio cc uses -mt
 122 XORG_TESTSET_CFLAG([THREAD_CFLAGS], [-pthread], [-mt])
 123 AC_SUBST([THREAD_CFLAGS])
 124
 125 AC_CONFIG_FILES([
 126                  Makefile
 127                  benchmarks/Makefile
 128                  demos/Makefile
 129                  lib/Makefile
 130                  man/Makefile
 131                  scripts/Makefile
 132                  tests/Makefile
 133                  tools/Makefile
 134                  debugger/Makefile
 135                  debugger/system_routine/Makefile
 136                  ])
 137 AC_OUTPUT
 138
 139 # vim: set ft=config ts=8 sw=8 tw=0 noet :