configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [1])
   4 m4_define([v_min], [0])
   5 m4_define([v_mic], [0])
   6 m4_define([v_rev], m4_esyscmd([(svnversion "${SVN_REPO_PATH:-.}" | grep -v export || echo 0) | awk -F : '{printf("%s\n", $1);}' | tr -d ' :MSP\n']))
   7 m4_if(v_rev, [0], [m4_define([v_rev], m4_esyscmd([git log 2> /dev/null | (grep -m1 git-svn-id || echo 0) | sed -e 's/.*@\([0-9]*\).*/\1/' | tr -d '\n']))])
   8 ##--   When released, remove the dnl on the below line
   9 m4_undefine([v_rev])
  10 ##--   When doing snapshots - change soname. remove dnl on below line
  11 dnl m4_define([relname], [ver-pre-svn-07])
  12 dnl m4_define([v_rel], [-release relname])
  13 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  14 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])], [m4_define([v_ver], [v_maj.v_min.v_mic])])
  15 m4_define([lt_rev], m4_eval(v_maj + v_min))
  16 m4_define([lt_cur], v_mic)
  17 m4_define([lt_age], v_min)
  18 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  19 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  20
  21 AC_INIT([eina], [v_ver-alpha], [enlightenment-devel@lists.sourceforge.net])
  22 AC_PREREQ([2.59])
  23 AC_CONFIG_SRCDIR([configure.ac])
  24 AC_CONFIG_MACRO_DIR([m4])
  25 AC_CANONICAL_BUILD
  26 AC_CANONICAL_HOST
  27 AC_ISC_POSIX
  28
  29 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  30 AM_CONFIG_HEADER([config.h])
  31 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  32
  33 AC_LIBTOOL_WIN32_DLL
  34 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  35 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  36 AC_PROG_LIBTOOL
  37
  38 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  39 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  40 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  41 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  42 AC_DEFINE_UNQUOTED(VMAJ, [v_maj], [Major version])
  43 AC_DEFINE_UNQUOTED(VMIN, [v_min], [Minor version])
  44 AC_DEFINE_UNQUOTED(VMIC, [v_mic], [Micro version])
  45 AC_DEFINE_UNQUOTED(VREV, [v_rev], [Revison])
  46 version_info="lt_rev:lt_cur:lt_age"
  47 release_info="v_rel"
  48 AC_SUBST(version_info)
  49 AC_SUBST(release_info)
  50 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  51 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  52 VMAJ=v_maj
  53 AC_SUBST(VMAJ)
  54
  55 ### Needed information
  56
  57 requirement_eina=""
  58
  59 case "$host_os" in
  60    mingw32ce*)
  61       MODULE_ARCH="$host_os-$host_cpu"
  62       ;;
  63    *)
  64       MODULE_ARCH="$host_os-$host_cpu-v_maj.v_min.v_mic"
  65       ;;
  66 esac
  67 AC_SUBST(MODULE_ARCH)
  68 AC_DEFINE_UNQUOTED(MODULE_ARCH, "${MODULE_ARCH}", "Module architecture")
  69
  70 case "$host_os" in
  71    mingw*)
  72       MODULE_EXT=".dll"
  73       ;;
  74    *)
  75       MODULE_EXT=".so"
  76       ;;
  77 esac
  78
  79 AC_DEFINE_UNQUOTED(SHARED_LIB_SUFFIX, "${MODULE_EXT}", [Suffix for shared objects])
  80
  81 EFL_CHECK_CPU_MMX([have_mmx="yes"], [have_mmx="no"])
  82 EFL_CHECK_CPU_SSE([have_sse="yes"], [have_sse="no"])
  83 EFL_CHECK_CPU_SSE2([have_sse2="yes"], [have_sse2="no"])
  84 EFL_CHECK_CPU_ALTIVEC([have_altivec="yes"], [have_altivec="no"])
  85
  86 EFL_CHECK_THREADS(
  87    [
  88     if test "x${_efl_have_posix_threads}" = "xyes" ; then
  89        have_threads="POSIX"
  90     else
  91        if test "x${_efl_have_win32_threads}" = "xyes" ; then
  92           have_threads="Win32"
  93        else
  94           have_threads="no"
  95        fi
  96     fi
  97    ],
  98    [have_threads="no"])
  99 EFL_CHECK_SPINLOCK([have_posix_threads_spinlock="yes"], [have_posix_threads_spinlock="no"])
 100 EFL_CHECK_RWLOCK(
 101   [EINA_CONFIGURE_RWLOCKS_ENABLED="#define EINA_RWLOCKS_ENABLED"]
 102   [have_posix_threads_rwlock="yes"],
 103   [have_posix_threads_rwlock="no"])
 104 AC_SUBST([EINA_CONFIGURE_RWLOCKS_ENABLED])
 105
 106 ### Additional options to configure
 107
 108 # Magic debug
 109 AC_ARG_ENABLE([magic-debug],
 110    [AC_HELP_STRING([--disable-magic-debug], [disable magic debug of eina structure @<:@default=enabled@:>@])],
 111    [
 112     if test "x${enableval}" = "xyes" ; then
 113        have_magic_debug="yes"
 114     else
 115        have_magic_debug="no"
 116     fi
 117    ],
 118    [have_magic_debug="yes"])
 119
 120 AC_MSG_CHECKING([whether magic debug is enable])
 121 AC_MSG_RESULT([${have_magic_debug}])
 122
 123 if test "x${have_magic_debug}" = "xyes" ; then
 124    EINA_CONFIGURE_MAGIC_DEBUG="#define EINA_MAGIC_DEBUG"
 125 fi
 126 AC_SUBST(EINA_CONFIGURE_MAGIC_DEBUG)
 127
 128 # Safety checks (avoid crashes on wrong api usage)
 129 AC_ARG_ENABLE(safety-checks,
 130    [AC_HELP_STRING([--disable-safety-checks], [disable safety checks for NULL pointers and like. @<:@default=enabled@:>@])],
 131    [
 132     if test "x${enableval}" = "xyes" ; then
 133        have_safety_checks="yes"
 134     else
 135        have_safety_checks="no"
 136     fi
 137    ],
 138    [have_safety_checks="yes"])
 139
 140 AC_MSG_CHECKING(whether to do safety checking on api parameters)
 141 AC_MSG_RESULT($have_safety_checks)
 142
 143 AM_CONDITIONAL(SAFETY_CHECKS, test "x$have_safety_checks" = "xyes")
 144 if test "x$have_safety_checks" = "xyes"; then
 145   AC_DEFINE(EINA_SAFETY_CHECKS, 1, [disable safety checks for NULL pointers and like.])
 146   EINA_CONFIGURE_SAFETY_CHECKS="#define EINA_SAFETY_CHECKS"
 147 fi
 148 AC_SUBST(EINA_CONFIGURE_SAFETY_CHECKS)
 149
 150 with_max_log_level="<unset>"
 151 AC_ARG_WITH(internal-maximum-log-level,
 152    [AC_HELP_STRING([--with-internal-maximum-log-level=NUMBER],
 153                    [limit eina internal log level to the given number, any call to EINA_LOG() with values greater than this will be compiled out, ignoring runtime settings, but saving function calls.])],
 154    [
 155     if test "x${withval}" != "xno"; then
 156        if echo "${withval}" | grep '^[[0-9]]\+$' >/dev/null 2>/dev/null; then
 157           AC_MSG_NOTICE([ignoring any EINA_LOG() with level greater than ${withval}])
 158           AC_DEFINE_UNQUOTED(EINA_LOG_LEVEL_MAXIMUM, ${withval}, [if set, logging is limited to this amount.])
 159           with_max_log_level="${withval}"
 160        else
 161           AC_MSG_ERROR([--with-internal-maximum-log-level takes a decimal number, got "${withval}" instead.])
 162        fi
 163     fi
 164     ], [:])
 165
 166 AC_ARG_ENABLE([amalgamation],
 167    [AC_HELP_STRING([--enable-amalgamation], [enable generation of one single file with all source code in it, helps compiler optimizations.])],
 168    [if test "x${enableval}" = "xyes"; then
 169        do_amalgamation="yes"
 170     else
 171        do_amalgamation="no"
 172     fi
 173    ],
 174    [do_amalgamation="no"]
 175 )
 176 AM_CONDITIONAL(EINA_AMALGAMATION, test "x${do_amalgamation}" = "xyes")
 177
 178 # Choose best memory pool
 179 AC_ARG_ENABLE([default-mempool],
 180    [AC_HELP_STRING([--enable-default-mempool], [Default memory allocator could be faster for some computer. @<:@default=disabled@:>@])],
 181    [
 182     if test "x${enableval}" = "xyes"; then
 183        have_default_mempool="yes"
 184     else
 185        have_default_mempool="no"
 186     fi
 187    ],
 188    [have_default_mempool="no"]
 189 )
 190 AC_MSG_CHECKING([whether to use default mempool allocator])
 191 AC_MSG_RESULT([${have_default_mempool}])
 192
 193 if test "x${have_default_mempool}" = "xyes" ; then
 194    EINA_CONFIGURE_DEFAULT_MEMPOOL="#define EINA_DEFAULT_MEMPOOL"
 195 fi
 196 AC_SUBST(EINA_CONFIGURE_DEFAULT_MEMPOOL)
 197
 198 # Report stringshare usage
 199 AC_ARG_ENABLE([stringshare-usage],
 200    [AC_HELP_STRING([--enable-stringshare-usage], [Report stringshare usage on stringshare shutdown. @<:@default=disabled@:>@])],
 201    [
 202     if test "x${enableval}" = "xyes"; then
 203        have_stringshare_usage="yes"
 204     else
 205        have_stringshare_usage="no"
 206     fi
 207    ],
 208    [have_stringshare_usage="no"]
 209 )
 210 AC_MSG_CHECKING([whether to report stringshare usage])
 211 AC_MSG_RESULT([${have_stringshare_usage}])
 212
 213 if test "x${have_stringshare_usage}" = "xyes"; then
 214    AC_DEFINE(EINA_STRINGSHARE_USAGE, 1, [Report Eina stringshare usage pattern])
 215 fi
 216
 217 # Check if we want to benchmark on real data
 218 enable_benchmark_e17="no"
 219 AC_ARG_ENABLE([e17],
 220    [AC_HELP_STRING([--enable-e17], [enable heavy benchmark @<:@default=no@:>@])],
 221    [
 222     if test "x${enableval}" = "xyes" ; then
 223        enable_benchmark_e17="yes"
 224     else
 225        enable_benchmark_e17="no"
 226     fi
 227    ],
 228    [enable_benchmark_e17="no"])
 229
 230 AC_MSG_CHECKING([whether e17 real data benchmark are built])
 231 AC_MSG_RESULT([${enable_benchmark_e17}])
 232
 233 AM_CONDITIONAL(EINA_ENABLE_BENCHMARK_E17, test "x${enable_benchmark_e17}" = "xyes")
 234
 235
 236 ### Checks for programs
 237 AC_PROG_CC
 238
 239 # pkg-config
 240 PKG_PROG_PKG_CONFIG
 241
 242 # Check whether pkg-config supports Requires.private
 243 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
 244    pkgconfig_requires_private="Requires.private"
 245 else
 246    pkgconfig_requires_private="Requires"
 247 fi
 248 AC_SUBST(pkgconfig_requires_private)
 249
 250 # doxygen program for documentation building
 251
 252 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 253
 254
 255 ### Checks for libraries
 256
 257 # Evil library for compilation on Windows CE
 258
 259 EFL_EINA_BUILD=""
 260 case "$host_os" in
 261    mingw*)
 262       PKG_CHECK_MODULES([EVIL], [evil])
 263       AC_DEFINE(HAVE_EVIL, 1, [Set to 1 if evil package is installed])
 264       requirement_eina="evil"
 265       EFL_EINA_BUILD="-DEFL_EINA_BUILD"
 266    ;;
 267 esac
 268 AC_SUBST(EFL_EINA_BUILD)
 269
 270 # Check ememoa memory pool library
 271
 272 AC_ARG_ENABLE([ememoa],
 273    [AC_HELP_STRING([--enable-ememoa], [build ememoa memory pool module @<:@default=yes@:>@])],
 274    [
 275     if test "x${enableval}" = "xyes" ; then
 276        enable_ememoa="yes"
 277     else
 278        enable_ememoa="no"
 279     fi
 280    ],
 281    [enable_ememoa="yes"]
 282 )
 283 AC_MSG_CHECKING([whether to use ememoa for memory pool])
 284 AC_MSG_RESULT([$enable_ememoa])
 285
 286 if test "x${enable_ememoa}" = "xyes" ; then
 287    PKG_CHECK_MODULES([EMEMOA],
 288       [ememoa >= 0.0.26 ],
 289       [enable_ememoa="yes"],
 290       [enable_ememoa="no"]
 291    )
 292 fi
 293
 294
 295 ### Checks for header files
 296 AC_HEADER_ASSERT
 297 AC_HEADER_DIRENT
 298 AC_HEADER_TIME
 299
 300
 301 ### Checks for types
 302 AC_CHECK_HEADER([inttypes.h],
 303                 [EINA_CONFIGURE_HAVE_INTTYPES_H="#define EINA_HAVE_INTTYPES_H"])
 304 AC_SUBST(EINA_CONFIGURE_HAVE_INTTYPES_H)
 305
 306 AC_CHECK_HEADER([stdint.h],
 307                 [EINA_CONFIGURE_HAVE_STDINT_H="#define EINA_HAVE_STDINT_H"])
 308 AC_SUBST(EINA_CONFIGURE_HAVE_STDINT_H)
 309
 310 AC_CHECK_SIZEOF(wchar_t)
 311 EINA_SIZEOF_WCHAR_T=$ac_cv_sizeof_wchar_t
 312 AC_SUBST(EINA_SIZEOF_WCHAR_T)
 313
 314 ### Checks for structures
 315
 316
 317 ### Checks for compiler characteristics
 318 AC_C_CONST
 319 AC_C_BIGENDIAN
 320 AC_C_INLINE
 321 AC_C___ATTRIBUTE__
 322 AC_PROG_CC_STDC
 323
 324 EINA_CPPFLAGS=""
 325 EINA_CFLAGS=""
 326 case "$host_os" in
 327    mingw32ce*)
 328       EINA_CPPFLAGS="-D_WIN32_WCE=0x0420"
 329       EINA_CFLAGS="${EVIL_CFLAGS}"
 330       ;;
 331    mingw*)
 332       EINA_CPPFLAGS="-D_WIN32_WINNT=0x0501"
 333       EINA_CFLAGS="${EVIL_CFLAGS}"
 334       ;;
 335 esac
 336
 337 m4_ifdef([v_mic],
 338    [
 339     EFL_COMPILER_FLAG([-Wall])
 340     EFL_COMPILER_FLAG([-W])
 341    ])
 342
 343 EFL_COMPILER_FLAG([-Wshadow])
 344
 345 AC_SUBST(EINA_CPPFLAGS)
 346 AC_SUBST(EINA_CFLAGS)
 347
 348
 349 ### Checks for linker characteristics
 350 EINA_LIBS=
 351 lt_enable_auto_import=""
 352 case "${host_os}" in
 353    mingw*)
 354       EINA_LIBS="-ldl ${EVIL_LIBS} -lm"
 355       lt_enable_auto_import="-Wl,--enable-auto-import"
 356    ;;
 357    dragonfly*|openbsd*)
 358       EINA_LIBS="-lm"
 359    ;;
 360    freebsd*|netbsd*)
 361       EINA_LIBS="-lrt -lm"
 362    ;;
 363    darwin*)
 364       EINA_LIBS="-lm"
 365    ;;
 366    cygwin*)
 367       EINA_LIBS="-ldl -lm"
 368    ;;
 369    *)
 370       EINA_LIBS="-ldl -lrt -lm"
 371    ;;
 372 esac
 373 AC_SUBST(EINA_LIBS)
 374 AC_SUBST(lt_enable_auto_import)
 375
 376 EFL_LINKER_FLAG([-fno-strict-aliasing])
 377
 378
 379 ### Checks for library functions
 380 AC_FUNC_ALLOCA
 381 AC_CHECK_FUNCS(strlcpy)
 382
 383 #dlopen and dladdr
 384 dlopen_libs=""
 385 case "$host_os" in
 386    mingw*)
 387 # managed by evil
 388       AC_DEFINE(HAVE_DLADDR)
 389       ;;
 390    *)
 391       AC_CHECK_FUNCS([dlopen], [res="yes"], [res="no"])
 392       if test "x${res}" = "xyes" ; then
 393          AC_CHECK_FUNCS([dladdr], [AC_DEFINE(HAVE_DLADDR)])
 394       else
 395          AC_CHECK_LIB([dl], [dlopen], [res="yes"], [res="no"])
 396          if test "x${res}" = "xyes" ; then
 397             AC_CHECK_LIB([dl], [dladdr], [AC_DEFINE(HAVE_DLADDR)])
 398             dlopen_libs="-ldl"
 399          else
 400             AC_MSG_ERROR([Cannot find dlopen])
 401          fi
 402       fi
 403       ;;
 404 esac
 405 AC_SUBST(dlopen_libs)
 406
 407 EFL_CHECK_FNMATCH([], [AC_MSG_ERROR([Cannot find fnmatch()])])
 408
 409 # iconv library
 410 have_iconv="no"
 411 AC_ARG_WITH([iconv-link],
 412    AC_HELP_STRING([--with-iconv-link=ICONV_LINK], [explicitly specify an iconv link option]),
 413    [
 414     LIBS="$withval $LIBS"
 415     have_iconv="yes"
 416    ])
 417
 418 AC_MSG_CHECKING(for explicit iconv link options)
 419 if test "x${iconv_libs}" = "x" ; then
 420    AC_MSG_RESULT([no explicit iconv link option])
 421 else
 422    AC_MSG_RESULT([$iconv_libs])
 423 fi
 424
 425 if test "x${have_iconv}" = "xno" ; then
 426    AC_CHECK_HEADERS([iconv.h], [have_iconv="yes"])
 427
 428    if test "x${have_iconv}" = "xyes" ; then
 429       AC_MSG_CHECKING([whether iconv() is in libc])
 430
 431       AC_LINK_IFELSE(
 432          [AC_LANG_PROGRAM(
 433              [[
 434 #include <stdlib.h>
 435 #include <iconv.h>
 436              ]],
 437              [[
 438 iconv_t ic;
 439 size_t count = iconv(ic, NULL, NULL, NULL, NULL);
 440              ]])],
 441          [have_iconv="yes"],
 442          [have_iconv="no"])
 443
 444       AC_MSG_RESULT([${have_iconv}])
 445    fi
 446
 447    if test "x${have_iconv}" = "xno" ; then
 448       AC_MSG_CHECKING([whether iconv() is in libiconv.a])
 449
 450       LIBS_save="${LIBS}"
 451       LIBS="-liconv $LIBS"
 452       AC_LINK_IFELSE(
 453          [AC_LANG_PROGRAM(
 454              [[
 455 #include <stdlib.h>
 456 #include <iconv.h>
 457              ]],
 458              [[
 459 iconv_t ic;
 460 size_t count;
 461 count = iconv(ic, NULL, NULL, NULL, NULL);
 462              ]])],
 463          [have_iconv="yes"],
 464          [
 465           have_iconv="no"
 466           LIBS=${LIBS_save}
 467          ])
 468
 469       AC_MSG_RESULT([${have_iconv}])
 470    fi
 471
 472    if test "x${have_iconv}" = "xno" ; then
 473       AC_MSG_CHECKING([whether iconv() is in libiconv_plug.a])
 474
 475       LIBS_save="${LIBS}"
 476       LIBS="-liconv_plug $LIBS"
 477       AC_LINK_IFELSE(
 478          [AC_LANG_PROGRAM(
 479              [[
 480 #include <stdlib.h>
 481 #include <iconv.h>
 482              ]],
 483              [[
 484 iconv_t ic;
 485 size_t count = iconv(ic, NULL, NULL, NULL, NULL);
 486              ]])],
 487          [have_iconv="yes"],
 488          [
 489           have_iconv="no"
 490           LIBS=${LIBS_save}
 491          ])
 492
 493       AC_MSG_RESULT([${have_iconv}])
 494    fi
 495 fi
 496
 497 if test "x${have_iconv}" = "xyes" ; then
 498    AC_DEFINE([HAVE_ICONV], [1], [Set to 1 if iconv library is installed])
 499 fi
 500
 501
 502 ### Modules
 503
 504 if test "x${have_default_mempool}" = "xyes" ; then
 505    enable_chained_pool="no"
 506    enable_pass_through="static"
 507 else
 508    enable_chained_pool="static"
 509    enable_pass_through="no"
 510 fi
 511
 512 enable_one_big="static"
 513
 514 EINA_CHECK_MODULE([chained-pool],   [${enable_chained_pool}], [chained pool])
 515 EINA_CHECK_MODULE([ememoa-fixed],   [${enable_ememoa}],       [ememoa fixed])
 516 EINA_CHECK_MODULE([ememoa-unknown], [${enable_ememoa}],       [ememoa unknown])
 517 EINA_CHECK_MODULE([fixed-bitmap],   [no],                     [fixed bitmap])
 518 EINA_CHECK_MODULE([pass-through],   [${enable_pass_through}], [pass through])
 519 EINA_CHECK_MODULE([buddy],          [no],                     [buddy])
 520 EINA_CHECK_MODULE([one-big],        [${enable_one_big}],      [one big])
 521
 522 ### Make the debug preprocessor configurable
 523
 524 ### Unit tests, coverage and benchmarking
 525
 526 EFL_CHECK_TESTS([enable_tests="yes"], [enable_tests="no"])
 527
 528 EFL_CHECK_COVERAGE([${enable_tests}], [enable_coverage="yes"], [enable_coverage="no"])
 529 EINA_CFLAGS="${EINA_CFLAGS} ${EFL_COVERAGE_CFLAGS}"
 530 EINA_LIBS="${EINA_LIBS} ${EFL_COVERAGE_LIBS}"
 531 if test "x$enable_coverage" = "xyes" ; then
 532    EINA_CFLAGS="${EINA_CFLAGS} ${EFL_DEBUG_CFLAGS}"
 533 fi
 534
 535 EFL_CHECK_BENCHMARK([enable_benchmark="yes"], [enable_benchmark="no"])
 536 EINA_BENCH_MODULE([glib], [${enable_benchmark}], [glib-2.0], [enable_benchmark_glib="yes"], [enable_benchmark_glib="no"])
 537
 538 AC_SUBST(requirement_eina)
 539
 540 ### Create the .pc.in file according to the major version
 541 #cat > ${srcdir}/eina-${VMAJ}.pc.in << EOF
 542 #prefix=@prefix@
 543 #exec_prefix=@exec_prefix@
 544 #libdir=@libdir@
 545 #includedir=@includedir@
 546 #
 547 #Name: Eina
 548 #Description: A Library that implements fast data types and miscellaneous tools
 549 #Requires:
 550 #Version: @VERSION@
 551 #Libs: -L${libdir} -leina
 552 #Libs.private: -ldl
 553 #Cflags: -I${includedir}/eina-@VMAJ@ -I${includedir}/eina-@VMAJ@/eina
 554 #EOF
 555
 556 AC_CONFIG_FILES([
 557 Makefile
 558 eina-1.pc
 559 eina.spec
 560 doc/Makefile
 561 src/Makefile
 562 src/include/Makefile
 563 src/include/eina_config.h
 564 src/lib/Makefile
 565 src/modules/Makefile
 566 src/modules/mp/Makefile
 567 src/modules/mp/chained_pool/Makefile
 568 src/modules/mp/ememoa_fixed/Makefile
 569 src/modules/mp/ememoa_unknown/Makefile
 570 src/modules/mp/pass_through/Makefile
 571 src/modules/mp/fixed_bitmap/Makefile
 572 src/modules/mp/buddy/Makefile
 573 src/modules/mp/one_big/Makefile
 574 src/tests/Makefile
 575 ])
 576
 577 AC_OUTPUT
 578
 579 #####################################################################
 580 ## Info
 581
 582 echo
 583 echo
 584 echo
 585 echo "------------------------------------------------------------------------"
 586 echo "$PACKAGE $VERSION"
 587 echo "------------------------------------------------------------------------"
 588 echo
 589 echo
 590 echo "Configuration Options Summary:"
 591 echo
 592 echo "  Magic debug..........: ${have_magic_debug}"
 593 echo "  Safety checks........: ${have_safety_checks}"
 594 echo "  Maximum log level....: ${with_max_log_level}"
 595 echo "  Report string usage..: ${have_stringshare_usage}"
 596 echo "  Default mempool......: ${have_default_mempool}"
 597 echo "  Thread Support.......: ${have_threads}"
 598 if test "${have_threads}" = "POSIX" ; then
 599 echo "    spinlock...........: ${have_posix_threads_spinlock}"
 600 echo "    rwlock.............: ${have_posix_threads_rwlock}"
 601 fi
 602 echo "  Amalgamation.........: ${do_amalgamation}"
 603 echo "  Iconv support........: ${have_iconv}"
 604 echo
 605 echo "  Documentation........: ${build_doc}"
 606 echo "  Tests................: ${enable_tests}"
 607 echo "  Coverage.............: ${enable_coverage}"
 608 echo "  Benchmark............: ${enable_benchmark}"
 609 if test "x${enable_benchmark}" = "xyes" ; then
 610 echo "    Glib...............: ${enable_benchmark_glib}"
 611 echo "    E17 real data......: ${enable_benchmark_e17}"
 612 fi
 613 echo
 614 echo "  CPU Specific Extensions:"
 615 echo "    MMX................: ${have_mmx}"
 616 echo "    SSE................: ${have_sse}"
 617 echo "    SSE2...............: ${have_sse2}"
 618 echo "    ALTIVEC............: ${have_altivec}"
 619 echo
 620 echo "  Memory pools:"
 621 echo "    Chained pool.......: ${enable_chained_pool}"
 622 echo "    Ememoa fixed.......: ${enable_ememoa_fixed}"
 623 echo "    Ememoa unknown.....: ${enable_ememoa_unknown}"
 624 echo "    Fixed bitmap.......: ${enable_fixed_bitmap}"
 625 echo "    Pass through.......: ${enable_pass_through}"
 626 echo "    Buddy..............: ${enable_buddy}"
 627 echo "    One big............: ${enable_one_big}"
 628 echo
 629 echo "Compilation............: make (or gmake)"
 630 echo "  CPPFLAGS.............: $CPPFLAGS"
 631 echo "  CFLAGS...............: $CFLAGS"
 632 echo "  LDFLAGS..............: $LDFLAGS"
 633 echo
 634 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
 635 echo "  prefix...............: $prefix"
 636 echo
 637 EFL_FORM_VOLTRON