configure.ac

   1 # vim:set et ts=4:
   2 #
   3 # ibus-pinyin - The Chinese PinYin engine for IBus
   4 #
   5 # Copyright (c) 2008-2010 Peng Huang <shawn.p.huang@gmail.com>
   6 #
   7 # This program is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 2, or (at your option)
  10 # any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  20
  21 # if not 1, append datestamp to the version number.
  22 m4_define([ibus_released], [1])
  23 m4_define([ibus_major_version], [1])
  24 m4_define([ibus_minor_version], [4])
  25 m4_define([ibus_micro_version], [0])
  26 m4_define(ibus_maybe_datestamp,
  27     m4_esyscmd([if test x]ibus_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  28
  29 m4_define([ibus_version],
  30     ibus_major_version.ibus_minor_version.ibus_micro_version[]ibus_maybe_datestamp)
  31
  32 AC_INIT([ibus-pinyin], [ibus_version], [http://code.google.com/p/ibus/issues/entry],[ibus-pinyin])
  33 AM_INIT_AUTOMAKE([1.10])
  34 AC_GNU_SOURCE
  35
  36 AC_CONFIG_HEADERS([config.h])
  37 AC_CONFIG_MACRO_DIR([m4])
  38 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  39
  40 # define PACKAGE_VERSION_* variables
  41 AS_VERSION
  42 AS_NANO
  43 AM_SANITY_CHECK
  44 AM_MAINTAINER_MODE
  45 AM_DISABLE_STATIC
  46 AC_PROG_CC
  47 AC_PROG_CXX
  48 AM_PROG_CC_C_O
  49 AC_ISC_POSIX
  50 AC_HEADER_STDC
  51 IT_PROG_INTLTOOL([0.35.0])
  52 AM_PROG_LIBTOOL
  53
  54 # check ibus
  55 PKG_CHECK_MODULES(IBUS, [
  56     ibus-1.0 >= 1.3.99
  57 ])
  58
  59 # check sqlite
  60 PKG_CHECK_MODULES(SQLITE, [
  61     sqlite3
  62 ])
  63 AC_PATH_PROG(SQLITE3, sqlite3)
  64
  65 # check libpinyin
  66 # --disable-libpinyin
  67 AC_ARG_ENABLE(libpinyin,
  68     AS_HELP_STRING([--disable-libpinyin],
  69          [do not use libpinyin]),
  70     [enable_libpinyin=$enableval],
  71     [enable_libpinyin=yes]
  72 )
  73
  74 PKG_CHECK_MODULES(LIBPINYIN, [
  75     libpinyin >= 0.2.0
  76 ], [],
  77 [enable_libpinyin=no])
  78
  79 AM_CONDITIONAL(IBUS_BUILD_LIBPINYIN, [test x"$enable_libpinyin" = x"yes"])
  80
  81 # check uuid
  82 AC_CHECK_FUNCS([uuid_create], [], [
  83     PKG_CHECK_MODULES(LIBUUID, uuid, [
  84         # uuid.pc exist
  85         AC_DEFINE(HAVE_LIBUUID, 1, [Define if found libuuid])
  86         HAVE_LIBUUID=yes
  87     ], [
  88         # uuid.pc does not exist
  89         uuid_old_LIBS=$LIBS
  90         AC_CHECK_HEADERS(uuid/uuid.h, [
  91             AC_SEARCH_LIBS(uuid_generate, uuid, [
  92                 test x"$ac_cv_search_uuid_generate" != x"none required" && LIBUUID_LIBS=$ac_cv_search_uuid_generate
  93                 AC_DEFINE(HAVE_LIBUUID, 1, [Define if found libuuid])
  94                 HAVE_LIBUUID=yes
  95             ], [
  96                 AC_MSG_ERROR([Can not find uuid_create and uuid_generate in libc or libuuid])
  97             ])
  98         ], [
  99             AC_MSG_ERROR([Can not find uuid_create and uuid_generate in libc or libuuid])
 100         ])
 101         LIBS=$uuid_old_LIBS
 102     ])
 103 ])
 104
 105 AM_CONDITIONAL(HAVE_LIBUUID, test x"$HAVE_LIBUUID" = x"yes")
 106
 107 # check if ibus_config_get_values, which is available in ibus-1.3.99+ (git master)
 108 save_CFLAGS="$CFLAGS"
 109 save_LIBS="$LIBS"
 110 CFLAGS="$CFLAGS $IBUS_CFLAGS"
 111 LIBS="$LIBS $IBUS_LIBS"
 112 AC_CHECK_FUNCS([ibus_config_get_values])
 113 CFLAGS="$save_CFLAGS"
 114 LIBS="$save_LIBS"
 115
 116
 117 # check env
 118 AC_PATH_PROG(ENV, env)
 119 AC_SUBST(ENV)
 120
 121 # check python
 122 AM_PATH_PYTHON([2.5])
 123
 124 # --enable-boost
 125 AC_ARG_ENABLE(boost,
 126     AC_HELP_STRING([--enable-boost],
 127         [Use boost to replace stdc++0x.]),
 128         [enable_boost=$enableval],
 129         [enable_boost=no]
 130 )
 131 if test x"$enable_boost" = x"yes"; then
 132     # check boost
 133     BOOST_REQUIRE([1.39])
 134     BOOST_FIND_HEADER([boost/bind.hpp])
 135     BOOST_FIND_HEADER([boost/signals2.hpp])
 136 fi
 137 AM_CONDITIONAL(HAVE_BOOST, test x"$enable_boost" = x"yes")
 138
 139 # --enable-opencc
 140 AC_ARG_ENABLE(opencc,
 141     AC_HELP_STRING([--enable-opencc],
 142         [Use opencc for simplified and traditional Chinese conversion]),
 143         [enable_opencc=$enableval],
 144         [enable_opencc=no]
 145 )
 146 if test x"$enable_opencc" = x"yes"; then
 147     # check opencc
 148     PKG_CHECK_MODULES(OPENCC, [opencc], [
 149         AC_DEFINE(HAVE_OPENCC, 1, [Define if found opencc])
 150     ])
 151 fi
 152
 153 # define GETTEXT_* variables
 154 GETTEXT_PACKAGE=ibus-pinyin
 155 AC_SUBST(GETTEXT_PACKAGE)
 156 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Gettext package])
 157
 158 AM_GLIB_GNU_GETTEXT
 159
 160 # --disable-lua-extension
 161 AC_ARG_ENABLE(lua-extension,
 162     AS_HELP_STRING([--disable-lua-extension],
 163          [do not build lua extension]),
 164     [enable_lua_extension=$enableval],
 165     [enable_lua_extension=yes]
 166 )
 167
 168 # check lua
 169 PKG_CHECK_MODULES(LUA, [
 170     lua >= 5.1
 171 ], [],
 172 [has_lua_extension=no]
 173 )
 174
 175 if test x"$has_lua_extension" = x"no";
 176 then
 177     PKG_CHECK_MODULES(LUA, [
 178         lua5.1
 179     ], [],
 180     [enable_lua_extension=no]
 181     );
 182 fi
 183
 184 AM_CONDITIONAL(IBUS_BUILD_LUA_EXTENSION, [test x"$enable_lua_extension" = x"yes"])
 185
 186 # --disable-english-input-mode
 187 AC_ARG_ENABLE(english-input-mode,
 188     AS_HELP_STRING([--disable-english-input-mode],
 189     [do not build english input mode]),
 190     [enable_english_input_mode=$enableval],
 191     [enable_english_input_mode=yes]
 192 )
 193
 194 AM_CONDITIONAL(IBUS_BUILD_ENGLISH_INPUT_MODE, [test x"$enable_english_input_mode" = x"yes"])
 195
 196 # OUTPUT files
 197 AC_CONFIG_FILES([ po/Makefile.in
 198 Makefile
 199 ibus-pinyin.spec
 200 lua/Makefile
 201 src/Makefile
 202 src/pinyin.xml.in
 203 setup/Makefile
 204 setup/ibus-setup-pinyin
 205 setup/ibus-setup-libpinyin
 206 setup/version.py
 207 data/Makefile
 208 data/icons/Makefile
 209 m4/Makefile
 210 ])
 211
 212 AC_OUTPUT
 213
 214 AC_MSG_RESULT([
 215 Build options:
 216     Version                     $VERSION
 217     Install prefix              $prefix
 218     Use boost                   $enable_boost
 219     Use opencc                  $enable_opencc
 220     Use libpinyin               $enable_libpinyin
 221     Build lua extension         $enable_lua_extension
 222     Build english input mode    $enable_english_input_mode
 223 ])
 224