configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [1])
   4 m4_define([v_min], [0])
   5 m4_define([v_mic], [999])
   6 m4_define([v_rev], m4_esyscmd([(svnversion "${SVN_REPO_PATH:-.}" | grep -v export || echo 0) | awk -F : '{printf("%s\n", $1);}' | tr -d ' :MSP\n']))
   7 m4_if(v_rev, [0], [m4_define([v_rev], m4_esyscmd([git log 2> /dev/null | (grep -m1 git-svn-id || echo 0) | sed -e 's/.*@\([0-9]*\).*/\1/' | tr -d '\n']))])
   8 ##--   When released, remove the dnl on the below line
   9 dnl m4_undefine([v_rev])
  10 ##--   When doing snapshots - change soname. remove dnl on below line
  11 dnl m4_define([relname], [ver-pre-svn-07])
  12 dnl m4_define([v_rel], [-release relname])
  13 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  14 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])], [m4_define([v_ver], [v_maj.v_min.v_mic])])
  15 m4_define([lt_rev], m4_eval(v_maj + v_min))
  16 m4_define([lt_cur], v_mic)
  17 m4_define([lt_age], v_min)
  18 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  19 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  20
  21 AC_INIT([eina], [v_ver], [enlightenment-devel@lists.sourceforge.net])
  22 AC_PREREQ([2.59])
  23 AC_CONFIG_SRCDIR([configure.ac])
  24 AC_CONFIG_MACRO_DIR([m4])
  25
  26 AC_CONFIG_HEADERS([config.h])
  27 AH_TOP([
  28 #ifndef EFL_CONFIG_H__
  29 #define EFL_CONFIG_H__
  30 ])
  31 AH_BOTTOM([
  32 #endif /* EFL_CONFIG_H__ */
  33 ])
  34
  35 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 AC_GNU_SOURCE
  39
  40 AC_LIBTOOL_WIN32_DLL
  41 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  42 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  43 AC_PROG_LIBTOOL
  44
  45 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  46 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  47 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  48 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  49 AC_DEFINE_UNQUOTED(VMAJ, [v_maj], [Major version])
  50 AC_DEFINE_UNQUOTED(VMIN, [v_min], [Minor version])
  51 AC_DEFINE_UNQUOTED(VMIC, [v_mic], [Micro version])
  52 AC_DEFINE_UNQUOTED(VREV, [v_rev], [Revison])
  53 version_info="lt_rev:lt_cur:lt_age"
  54 release_info="v_rel"
  55 AC_SUBST(version_info)
  56 AC_SUBST(release_info)
  57 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  58 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  59 VMAJ=v_maj
  60 AC_SUBST(VMAJ)
  61
  62
  63 ### Needed information
  64
  65 AC_CANONICAL_BUILD
  66 AC_CANONICAL_HOST
  67
  68 requirement_eina=""
  69
  70 case "$host_os" in
  71    mingw32ce*)
  72       MODULE_ARCH="$host_os-$host_cpu"
  73       ;;
  74    *)
  75       MODULE_ARCH="$host_os-$host_cpu-v_maj.v_min.v_mic"
  76       ;;
  77 esac
  78 AC_SUBST(MODULE_ARCH)
  79 AC_DEFINE_UNQUOTED(MODULE_ARCH, "${MODULE_ARCH}", "Module architecture")
  80
  81 case "$host_os" in
  82    mingw*)
  83       MODULE_EXT=".dll"
  84       ;;
  85    *)
  86       MODULE_EXT=".so"
  87       ;;
  88 esac
  89
  90 AC_DEFINE_UNQUOTED(SHARED_LIB_SUFFIX, "${MODULE_EXT}", [Suffix for shared objects])
  91
  92 EFL_CHECK_CPU_MMX([have_mmx="yes"], [have_mmx="no"])
  93 EFL_CHECK_CPU_SSE([have_sse="yes"], [have_sse="no"])
  94 EFL_CHECK_CPU_SSE2([have_sse2="yes"], [have_sse2="no"])
  95 EFL_CHECK_CPU_ALTIVEC([have_altivec="yes"], [have_altivec="no"])
  96
  97 EFL_CHECK_THREADS(
  98    [
  99     if test "x${_efl_have_posix_threads}" = "xyes" ; then
 100        have_threads="POSIX"
 101     else
 102        if test "x${_efl_have_win32_threads}" = "xyes" ; then
 103           have_threads="Win32"
 104        else
 105           have_threads="no"
 106        fi
 107     fi
 108    ],
 109    [have_threads="no"])
 110 EFL_CHECK_SPINLOCK([have_posix_threads_spinlock="yes"], [have_posix_threads_spinlock="no"])
 111
 112 ### Additional options to configure
 113
 114 # Magic debug
 115 AC_ARG_ENABLE([magic-debug],
 116    [AC_HELP_STRING([--disable-magic-debug], [disable magic debug of eina structure @<:@default=enabled@:>@])],
 117    [
 118     if test "x${enableval}" = "xyes" ; then
 119        have_magic_debug="yes"
 120     else
 121        have_magic_debug="no"
 122     fi
 123    ],
 124    [have_magic_debug="yes"])
 125
 126 AC_MSG_CHECKING([whether magic debug is enable])
 127 AC_MSG_RESULT([${have_magic_debug}])
 128
 129 if test "x${have_magic_debug}" = "xyes" ; then
 130    EINA_CONFIGURE_MAGIC_DEBUG="#define EINA_MAGIC_DEBUG"
 131 fi
 132 AC_SUBST(EINA_CONFIGURE_MAGIC_DEBUG)
 133
 134 # Valgrind
 135 want_valgrind="auto"
 136 have_valgrind="no"
 137
 138 AC_MSG_CHECKING(whether to enable build with valgrind)
 139 AC_ARG_ENABLE(valgrind,
 140   AC_HELP_STRING([--enable-valgrind], [improve valgrind support by hinting it of our memory usages, having it to report proper mempool leaks.]),
 141   [want_valgrind=$enableval]
 142 )
 143 AC_MSG_RESULT($want_valgrind)
 144
 145 if test "x${want_valgrind}" = "xyes" -o "x${want_valgrind}" = "xauto"; then
 146     PKG_CHECK_MODULES(VALGRIND, valgrind >= 2.4.0,
 147         [
 148          requirement_eina="valgrind ${requirement_eina}"
 149          have_valgrind="yes"
 150         ],
 151         [
 152          AC_DEFINE(NVALGRIND, 1, [Valgrind support disabled])
 153          if test "x$want_valgrind" = "xyes"; then
 154             AC_MSG_ERROR([Valgrind >= 2.4.0 is required)])
 155          fi
 156         ]
 157     )
 158 else
 159     AC_DEFINE(NVALGRIND, 1, [Valgrind support disabled])
 160 fi
 161
 162 # Safety checks (avoid crashes on wrong api usage)
 163 AC_ARG_ENABLE(safety-checks,
 164    [AC_HELP_STRING([--disable-safety-checks], [disable safety checks for NULL pointers and like. @<:@default=enabled@:>@])],
 165    [
 166     if test "x${enableval}" = "xyes" ; then
 167        have_safety_checks="yes"
 168     else
 169        have_safety_checks="no"
 170     fi
 171    ],
 172    [have_safety_checks="yes"])
 173
 174 AC_MSG_CHECKING(whether to do safety checking on api parameters)
 175 AC_MSG_RESULT($have_safety_checks)
 176
 177 AM_CONDITIONAL(SAFETY_CHECKS, test "x$have_safety_checks" = "xyes")
 178 if test "x$have_safety_checks" = "xyes"; then
 179   AC_DEFINE(EINA_SAFETY_CHECKS, 1, [disable safety checks for NULL pointers and like.])
 180   EINA_CONFIGURE_SAFETY_CHECKS="#define EINA_SAFETY_CHECKS"
 181 fi
 182 AC_SUBST(EINA_CONFIGURE_SAFETY_CHECKS)
 183
 184 with_max_log_level="<unset>"
 185 AC_ARG_WITH(internal-maximum-log-level,
 186    [AC_HELP_STRING([--with-internal-maximum-log-level=NUMBER],
 187                    [limit eina internal log level to the given number, any call to EINA_LOG() with values greater than this will be compiled out, ignoring runtime settings, but saving function calls.])],
 188    [
 189     if test "x${withval}" != "xno"; then
 190        if echo "${withval}" | grep '^[[0-9]]\+$' >/dev/null 2>/dev/null; then
 191           AC_MSG_NOTICE([ignoring any EINA_LOG() with level greater than ${withval}])
 192           AC_DEFINE_UNQUOTED(EINA_LOG_LEVEL_MAXIMUM, ${withval}, [if set, logging is limited to this amount.])
 193           with_max_log_level="${withval}"
 194        else
 195           AC_MSG_ERROR([--with-internal-maximum-log-level takes a decimal number, got "${withval}" instead.])
 196        fi
 197     fi
 198     ], [:])
 199
 200 AC_ARG_ENABLE([amalgamation],
 201    [AC_HELP_STRING([--enable-amalgamation], [enable generation of one single file with all source code in it, helps compiler optimizations.])],
 202    [if test "x${enableval}" = "xyes"; then
 203        do_amalgamation="yes"
 204     else
 205        do_amalgamation="no"
 206     fi
 207    ],
 208    [do_amalgamation="no"]
 209 )
 210 AM_CONDITIONAL(EINA_AMALGAMATION, test "x${do_amalgamation}" = "xyes")
 211
 212 # Choose best memory pool
 213 AC_ARG_ENABLE([default-mempool],
 214    [AC_HELP_STRING([--enable-default-mempool], [Default memory allocator could be faster for some computer. @<:@default=disabled@:>@])],
 215    [
 216     if test "x${enableval}" = "xyes"; then
 217        have_default_mempool="yes"
 218     else
 219        have_default_mempool="no"
 220     fi
 221    ],
 222    [have_default_mempool="no"]
 223 )
 224 AC_MSG_CHECKING([whether to use default mempool allocator])
 225 AC_MSG_RESULT([${have_default_mempool}])
 226
 227 if test "x${have_default_mempool}" = "xyes" ; then
 228    EINA_CONFIGURE_DEFAULT_MEMPOOL="#define EINA_DEFAULT_MEMPOOL"
 229 fi
 230 AC_SUBST(EINA_CONFIGURE_DEFAULT_MEMPOOL)
 231
 232 # Report stringshare usage
 233 AC_ARG_ENABLE([stringshare-usage],
 234    [AC_HELP_STRING([--enable-stringshare-usage], [Report stringshare usage on stringshare shutdown. @<:@default=disabled@:>@])],
 235    [
 236     if test "x${enableval}" = "xyes"; then
 237        have_stringshare_usage="yes"
 238     else
 239        have_stringshare_usage="no"
 240     fi
 241    ],
 242    [have_stringshare_usage="no"]
 243 )
 244 AC_MSG_CHECKING([whether to report stringshare usage])
 245 AC_MSG_RESULT([${have_stringshare_usage}])
 246
 247 if test "x${have_stringshare_usage}" = "xyes"; then
 248    AC_DEFINE(EINA_STRINGSHARE_USAGE, 1, [Report Eina stringshare usage pattern])
 249 fi
 250
 251 # Check if we want to benchmark on real data
 252 enable_benchmark_e17="no"
 253 AC_ARG_ENABLE([e17],
 254    [AC_HELP_STRING([--enable-e17], [enable heavy benchmark @<:@default=no@:>@])],
 255    [
 256     if test "x${enableval}" = "xyes" ; then
 257        enable_benchmark_e17="yes"
 258     else
 259        enable_benchmark_e17="no"
 260     fi
 261    ],
 262    [enable_benchmark_e17="no"])
 263
 264 AC_MSG_CHECKING([whether e17 real data benchmark are built])
 265 AC_MSG_RESULT([${enable_benchmark_e17}])
 266
 267 AM_CONDITIONAL(EINA_ENABLE_BENCHMARK_E17, test "x${enable_benchmark_e17}" = "xyes")
 268
 269
 270 ### Checks for programs
 271 AC_PROG_CC
 272
 273 # pkg-config
 274 PKG_PROG_PKG_CONFIG
 275
 276 # Check whether pkg-config supports Requires.private
 277 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
 278    pkgconfig_requires_private="Requires.private"
 279 else
 280    pkgconfig_requires_private="Requires"
 281 fi
 282 AC_SUBST(pkgconfig_requires_private)
 283
 284 # doxygen program for documentation building
 285
 286 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 287
 288
 289 ### Checks for libraries
 290
 291 # Evil library for compilation on Windows CE
 292
 293 EFL_EINA_BUILD=""
 294 case "$host_os" in
 295    mingw*)
 296       PKG_CHECK_MODULES([EVIL], [evil])
 297       AC_DEFINE(HAVE_EVIL, 1, [Set to 1 if evil package is installed])
 298       requirement_eina="evil"
 299       EFL_EINA_BUILD="-DEFL_EINA_BUILD"
 300    ;;
 301 esac
 302 AC_SUBST(EFL_EINA_BUILD)
 303
 304 # Check ememoa memory pool library
 305
 306 AC_ARG_ENABLE([ememoa],
 307    [AC_HELP_STRING([--enable-ememoa], [build ememoa memory pool module @<:@default=yes@:>@])],
 308    [
 309     if test "x${enableval}" = "xyes" ; then
 310        enable_ememoa="yes"
 311     else
 312        enable_ememoa="no"
 313     fi
 314    ],
 315    [enable_ememoa="yes"]
 316 )
 317 AC_MSG_CHECKING([whether to use ememoa for memory pool])
 318 AC_MSG_RESULT([$enable_ememoa])
 319
 320 if test "x${enable_ememoa}" = "xyes" ; then
 321    PKG_CHECK_MODULES([EMEMOA],
 322       [ememoa >= 0.0.26 ],
 323       [enable_ememoa="yes"],
 324       [enable_ememoa="no"]
 325    )
 326 fi
 327
 328
 329 ### Checks for header files
 330 AC_HEADER_ASSERT
 331 AC_HEADER_DIRENT
 332 AC_HEADER_TIME
 333 AC_CHECK_HEADERS([unistd.h libgen.h])
 334 EFL_CHECK_PATH_MAX
 335
 336 ### Checks for types
 337 AC_CHECK_HEADER([inttypes.h],
 338    [
 339     EINA_CONFIGURE_HAVE_INTTYPES_H="#define EINA_HAVE_INTTYPES_H"
 340     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define to 1 if you have the <inttypes.h> header file.])
 341    ])
 342 AC_SUBST(EINA_CONFIGURE_HAVE_INTTYPES_H)
 343
 344 AC_CHECK_HEADER([stdint.h],
 345    [
 346     EINA_CONFIGURE_HAVE_STDINT_H="#define EINA_HAVE_STDINT_H"
 347     AC_DEFINE(HAVE_STDINT_H, 1, [Define to 1 if you have the <stdint.h> header file.])
 348    ])
 349 AC_SUBST(EINA_CONFIGURE_HAVE_STDINT_H)
 350
 351 AC_CHECK_SIZEOF(wchar_t)
 352 EINA_SIZEOF_WCHAR_T=$ac_cv_sizeof_wchar_t
 353 AC_SUBST(EINA_SIZEOF_WCHAR_T)
 354
 355 ### Checks for structures
 356
 357
 358 ### Checks for compiler characteristics
 359 AC_C_CONST
 360 AC_C_BIGENDIAN
 361 AC_C_INLINE
 362 AC_C___ATTRIBUTE__
 363 AC_PROG_CC_STDC
 364
 365 have_win32="no"
 366 EINA_CPPFLAGS=""
 367 EINA_CFLAGS=""
 368 case "$host_os" in
 369    mingw32ce*)
 370       EINA_CPPFLAGS="-D_WIN32_WCE=0x0420"
 371       EINA_CFLAGS="${EVIL_CFLAGS}"
 372       have_win32="yes"
 373       ;;
 374    mingw*)
 375       EINA_CPPFLAGS="-D_WIN32_WINNT=0x0501"
 376       EINA_CFLAGS="${EVIL_CFLAGS}"
 377       have_win32="yes"
 378       ;;
 379 esac
 380 AM_CONDITIONAL([EINA_HAVE_WIN32], [test "x$have_win32" = "xyes"])
 381
 382 m4_ifdef([v_mic],
 383    [
 384     EFL_COMPILER_FLAG([-Wall])
 385     EFL_COMPILER_FLAG([-W])
 386    ])
 387
 388 EFL_COMPILER_FLAG([-Wshadow])
 389
 390 AC_SUBST(EINA_CPPFLAGS)
 391 AC_SUBST(EINA_CFLAGS)
 392
 393
 394 ### Checks for linker characteristics
 395 EINA_LIBS=
 396 lt_enable_auto_import=""
 397 case "${host_os}" in
 398    mingw*)
 399       EINA_LIBS="-ldl ${EVIL_LIBS} -lm"
 400       lt_enable_auto_import="-Wl,--enable-auto-import"
 401    ;;
 402    dragonfly*|openbsd*)
 403       EINA_LIBS="-lm"
 404    ;;
 405    freebsd*|netbsd*)
 406       EINA_LIBS="-lrt -lm"
 407    ;;
 408    darwin*)
 409       EINA_LIBS="-lm"
 410    ;;
 411    cygwin*)
 412       EINA_LIBS="-ldl -lm"
 413    ;;
 414    *)
 415       EINA_LIBS="-ldl -lrt -lm"
 416    ;;
 417 esac
 418 AC_SUBST(EINA_LIBS)
 419 AC_SUBST(lt_enable_auto_import)
 420
 421 EFL_LINKER_FLAG([-fno-strict-aliasing])
 422
 423
 424 ### Checks for library functions
 425 AC_ISC_POSIX
 426 AC_FUNC_ALLOCA
 427 AC_CHECK_FUNCS(strlcpy)
 428
 429 #dlopen and dladdr
 430 dlopen_libs=""
 431 case "$host_os" in
 432    mingw*)
 433 # managed by evil
 434       AC_DEFINE(HAVE_DLADDR)
 435       ;;
 436    *)
 437       AC_CHECK_FUNCS([dlopen], [res="yes"], [res="no"])
 438       if test "x${res}" = "xyes" ; then
 439          AC_CHECK_FUNCS([dladdr], [AC_DEFINE(HAVE_DLADDR)])
 440       else
 441          AC_CHECK_LIB([dl], [dlopen], [res="yes"], [res="no"])
 442          if test "x${res}" = "xyes" ; then
 443             AC_CHECK_LIB([dl], [dladdr], [AC_DEFINE(HAVE_DLADDR)])
 444             dlopen_libs="-ldl"
 445          else
 446             AC_MSG_ERROR([Cannot find dlopen])
 447          fi
 448       fi
 449       ;;
 450 esac
 451 AC_SUBST(dlopen_libs)
 452
 453 EFL_CHECK_FNMATCH([], [AC_MSG_ERROR([Cannot find fnmatch()])])
 454
 455 # iconv library
 456 have_iconv="no"
 457 AC_ARG_WITH([iconv-link],
 458    AC_HELP_STRING([--with-iconv-link=ICONV_LINK], [explicitly specify an iconv link option]),
 459    [
 460     LIBS="$withval $LIBS"
 461     have_iconv="yes"
 462    ])
 463
 464 AC_MSG_CHECKING(for explicit iconv link options)
 465 if test "x${iconv_libs}" = "x" ; then
 466    AC_MSG_RESULT([no explicit iconv link option])
 467 else
 468    AC_MSG_RESULT([$iconv_libs])
 469 fi
 470
 471 if test "x${have_iconv}" = "xno" ; then
 472    AC_CHECK_HEADERS([iconv.h], [have_iconv="yes"])
 473
 474    if test "x${have_iconv}" = "xyes" ; then
 475       AC_MSG_CHECKING([whether iconv() is in libc])
 476
 477       AC_LINK_IFELSE(
 478          [AC_LANG_PROGRAM(
 479              [[
 480 #include <stdlib.h>
 481 #include <iconv.h>
 482              ]],
 483              [[
 484 iconv_t ic;
 485 size_t count = iconv(ic, NULL, NULL, NULL, NULL);
 486              ]])],
 487          [have_iconv="yes"],
 488          [have_iconv="no"])
 489
 490       AC_MSG_RESULT([${have_iconv}])
 491    fi
 492
 493    if test "x${have_iconv}" = "xno" ; then
 494       AC_MSG_CHECKING([whether iconv() is in libiconv.a])
 495
 496       LIBS_save="${LIBS}"
 497       LIBS="-liconv $LIBS"
 498       AC_LINK_IFELSE(
 499          [AC_LANG_PROGRAM(
 500              [[
 501 #include <stdlib.h>
 502 #include <iconv.h>
 503              ]],
 504              [[
 505 iconv_t ic;
 506 size_t count;
 507 count = iconv(ic, NULL, NULL, NULL, NULL);
 508              ]])],
 509          [have_iconv="yes"],
 510          [
 511           have_iconv="no"
 512           LIBS=${LIBS_save}
 513          ])
 514
 515       AC_MSG_RESULT([${have_iconv}])
 516    fi
 517
 518    if test "x${have_iconv}" = "xno" ; then
 519       AC_MSG_CHECKING([whether iconv() is in libiconv_plug.a])
 520
 521       LIBS_save="${LIBS}"
 522       LIBS="-liconv_plug $LIBS"
 523       AC_LINK_IFELSE(
 524          [AC_LANG_PROGRAM(
 525              [[
 526 #include <stdlib.h>
 527 #include <iconv.h>
 528              ]],
 529              [[
 530 iconv_t ic;
 531 size_t count = iconv(ic, NULL, NULL, NULL, NULL);
 532              ]])],
 533          [have_iconv="yes"],
 534          [
 535           have_iconv="no"
 536           LIBS=${LIBS_save}
 537          ])
 538
 539       AC_MSG_RESULT([${have_iconv}])
 540    fi
 541 fi
 542
 543 if test "x${have_iconv}" = "xyes" ; then
 544    AC_DEFINE([HAVE_ICONV], [1], [Set to 1 if iconv library is installed])
 545 fi
 546
 547 #check for dirfd API presence
 548 have_dirfd="no"
 549 AC_CHECK_FUNCS([dirfd], [have_dirfd="yes"], [])
 550 if test "x${dirfd}" = "xyes"; then
 551    AC_DEFINE(HAVE_DIRFD)
 552 fi
 553 AC_CHECK_FUNCS([openat], [AC_DEFINE(HAVE_OPENAT)], [])
 554 AC_CHECK_FUNCS([statat], [AC_DEFINE(HAVE_STATAT)], [])
 555 AC_CHECK_FUNCS([fpathconf], [AC_DEFINE(HAVE_FPATHCONF)], [])
 556
 557 ### Modules
 558
 559 if test "x${have_default_mempool}" = "xyes" ; then
 560    enable_chained_pool="no"
 561    enable_pass_through="static"
 562 else
 563    enable_chained_pool="static"
 564    enable_pass_through="no"
 565 fi
 566
 567 enable_one_big="static"
 568
 569 EINA_CHECK_MODULE([chained-pool],   [${enable_chained_pool}], [chained pool])
 570 EINA_CHECK_MODULE([ememoa-fixed],   [${enable_ememoa}],       [ememoa fixed])
 571 EINA_CHECK_MODULE([ememoa-unknown], [${enable_ememoa}],       [ememoa unknown])
 572 EINA_CHECK_MODULE([fixed-bitmap],   [no],                     [fixed bitmap])
 573 EINA_CHECK_MODULE([pass-through],   [${enable_pass_through}], [pass through])
 574 EINA_CHECK_MODULE([buddy],          [no],                     [buddy])
 575 EINA_CHECK_MODULE([one-big],        [${enable_one_big}],      [one big])
 576
 577 ### Make the debug preprocessor configurable
 578
 579 ### Unit tests, coverage and benchmarking
 580
 581 EFL_CHECK_TESTS([enable_tests="yes"], [enable_tests="no"])
 582
 583 EFL_CHECK_COVERAGE([${enable_tests}], [enable_coverage="yes"], [enable_coverage="no"])
 584 EINA_CFLAGS="${EINA_CFLAGS} ${EFL_COVERAGE_CFLAGS}"
 585 EINA_LIBS="${EINA_LIBS} ${EFL_COVERAGE_LIBS}"
 586 if test "x$enable_coverage" = "xyes" ; then
 587    EINA_CFLAGS="${EINA_CFLAGS} ${EFL_DEBUG_CFLAGS}"
 588 fi
 589
 590 EFL_CHECK_BENCHMARK([enable_benchmark="yes"], [enable_benchmark="no"])
 591 EINA_BENCH_MODULE([glib], [${enable_benchmark}], [glib-2.0], [enable_benchmark_glib="yes"], [enable_benchmark_glib="no"])
 592
 593 AC_SUBST(requirement_eina)
 594
 595 ### Create the .pc.in file according to the major version
 596 #cat > ${srcdir}/eina-${VMAJ}.pc.in << EOF
 597 #prefix=@prefix@
 598 #exec_prefix=@exec_prefix@
 599 #libdir=@libdir@
 600 #includedir=@includedir@
 601 #
 602 #Name: Eina
 603 #Description: A Library that implements fast data types and miscellaneous tools
 604 #Requires:
 605 #Version: @VERSION@
 606 #Libs: -L${libdir} -leina
 607 #Libs.private: -ldl
 608 #Cflags: -I${includedir}/eina-@VMAJ@ -I${includedir}/eina-@VMAJ@/eina
 609 #EOF
 610
 611 AC_CONFIG_FILES([
 612 Makefile
 613 eina.pc
 614 eina.spec
 615 doc/Makefile
 616 src/Makefile
 617 src/include/Makefile
 618 src/include/eina_config.h
 619 src/lib/Makefile
 620 src/modules/Makefile
 621 src/modules/mp/Makefile
 622 src/modules/mp/chained_pool/Makefile
 623 src/modules/mp/ememoa_fixed/Makefile
 624 src/modules/mp/ememoa_unknown/Makefile
 625 src/modules/mp/pass_through/Makefile
 626 src/modules/mp/fixed_bitmap/Makefile
 627 src/modules/mp/buddy/Makefile
 628 src/modules/mp/one_big/Makefile
 629 src/tests/Makefile
 630 ])
 631
 632 AC_OUTPUT
 633
 634 #####################################################################
 635 ## Info
 636
 637 echo
 638 echo
 639 echo
 640 echo "------------------------------------------------------------------------"
 641 echo "$PACKAGE $VERSION"
 642 echo "------------------------------------------------------------------------"
 643 echo
 644 echo
 645 echo "Configuration Options Summary:"
 646 echo
 647 echo "  Magic debug..........: ${have_magic_debug}"
 648 echo "  Safety checks........: ${have_safety_checks}"
 649 echo "  Maximum log level....: ${with_max_log_level}"
 650 echo "  Report string usage..: ${have_stringshare_usage}"
 651 echo "  Valgrind support.....: ${have_valgrind}"
 652 echo "  Default mempool......: ${have_default_mempool}"
 653 echo "  Thread Support.......: ${have_threads}"
 654 if test "${have_threads}" = "POSIX" ; then
 655 echo "    spinlock...........: ${have_posix_threads_spinlock}"
 656 echo "    debug usage........: ${have_debug_threads}"
 657 fi
 658 echo "  Amalgamation.........: ${do_amalgamation}"
 659 echo "  Iconv support........: ${have_iconv}"
 660 echo "  File dirfd...........: ${have_dirfd}"
 661 echo
 662 echo "  Documentation........: ${build_doc}"
 663 echo "  Tests................: ${enable_tests}"
 664 echo "  Coverage.............: ${enable_coverage}"
 665 echo "  Benchmark............: ${enable_benchmark}"
 666 if test "x${enable_benchmark}" = "xyes" ; then
 667 echo "    Glib...............: ${enable_benchmark_glib}"
 668 echo "    E17 real data......: ${enable_benchmark_e17}"
 669 fi
 670 echo
 671 echo "  CPU Specific Extensions:"
 672 echo "    MMX................: ${have_mmx}"
 673 echo "    SSE................: ${have_sse}"
 674 echo "    SSE2...............: ${have_sse2}"
 675 echo "    ALTIVEC............: ${have_altivec}"
 676 echo
 677 echo "  Memory pools:"
 678 echo "    Chained pool.......: ${enable_chained_pool}"
 679 echo "    Ememoa fixed.......: ${enable_ememoa_fixed}"
 680 echo "    Ememoa unknown.....: ${enable_ememoa_unknown}"
 681 echo "    Fixed bitmap.......: ${enable_fixed_bitmap}"
 682 echo "    Pass through.......: ${enable_pass_through}"
 683 echo "    Buddy..............: ${enable_buddy}"
 684 echo "    One big............: ${enable_one_big}"
 685 echo
 686 echo "Compilation............: make (or gmake)"
 687 echo "  CPPFLAGS.............: $CPPFLAGS"
 688 echo "  CFLAGS...............: $CFLAGS"
 689 echo "  LDFLAGS..............: $LDFLAGS"
 690 echo
 691 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
 692 echo "  prefix...............: $prefix"
 693 echo
 694 EFL_FORM_VOLTRON