configure.ac

   1 # gstreamer-vaapi package version number
   2 m4_define([gst_vaapi_major_version], [0])
   3 m4_define([gst_vaapi_minor_version], [5])
   4 m4_define([gst_vaapi_micro_version], [0])
   5 m4_define([gst_vaapi_pre_version],   [1])
   6 m4_define([gst_vaapi_version],
   7           [gst_vaapi_major_version.gst_vaapi_minor_version.gst_vaapi_micro_version])
   8 m4_if(gst_vaapi_pre_version, [0], [], [
   9 m4_append([gst_vaapi_version], gst_vaapi_pre_version, [.pre])
  10 ])
  11
  12 # glib version number
  13 m4_define([glib_major_version], [2])
  14 m4_define([glib_minor_version], [28])
  15 m4_define([glib_micro_version], [0])
  16 m4_define([glib_major_minor_version],
  17           [glib_major_version.glib_minor_version])
  18 m4_define([glib_version],
  19           [glib_major_version.glib_minor_version.glib_micro_version])
  20
  21 # gst version number
  22 m4_define([gst_major_version], [0])
  23 m4_define([gst_minor_version], [10])
  24 m4_define([gst_micro_version], [36])
  25 m4_define([gst_major_minor_version],
  26           [gst_major_version.gst_minor_version])
  27 m4_define([gst_version],
  28           [gst_major_version.gst_minor_version.gst_micro_version])
  29
  30 # gst plugins-base version number
  31 m4_define([gst_plugins_base_major_version], [0])
  32 m4_define([gst_plugins_base_minor_version], [10])
  33 m4_define([gst_plugins_base_micro_version], [31])
  34 m4_define([gst_plugins_base_version],
  35           [gst_plugins_base_major_version.gst_plugins_base_minor_version.gst_plugins_base_micro_version])
  36
  37 # gst plugins-bad version number
  38 m4_define([gst_plugins_bad_major_version], [0])
  39 m4_define([gst_plugins_bad_minor_version], [10])
  40 m4_define([gst_plugins_bad_micro_version], [22])
  41 m4_define([gst_plugins_bad_version],
  42           [gst_plugins_bad_major_version.gst_plugins_bad_minor_version.gst_plugins_bad_micro_version])
  43
  44 # Wayland minimum version number
  45 m4_define([wayland_api_version], [0.95.0])
  46
  47 # VA-API minimum version number
  48 m4_define([va_api_version],     [0.30.4])
  49 m4_define([va_api_drm_version], [0.33.0])
  50 m4_define([va_api_x11_version], [0.31.0])
  51 m4_define([va_api_glx_version], [0.32.0])
  52 m4_define([va_api_wld_version], [0.33.0])
  53
  54 # libva package version number
  55 m4_define([libva_drm_package_version], [1.1.0])
  56 m4_define([libva_x11_package_version], [1.0.3])
  57 m4_define([libva_glx_package_version], [1.0.9])
  58 m4_define([libva_wld_package_version], [1.1.0])
  59
  60 # gtk-doc version number
  61 # XXX: introspection annotations require gtk-doc >= 1.12
  62 m4_define([gtkdoc_major_version], [1])
  63 m4_define([gtkdoc_minor_version], [9])
  64 m4_define([gtkdoc_version], [gtkdoc_major_version.gtkdoc_minor_version])
  65
  66 AC_PREREQ([2.58])
  67 AC_INIT([gst_vaapi], [gst_vaapi_version],
  68     [gwenole.beauchesne@intel.com],
  69     [gstreamer-vaapi])
  70
  71 AC_CONFIG_HEADERS([config.h])
  72 AC_CONFIG_SRCDIR([Makefile.am])
  73 AC_CONFIG_MACRO_DIR([m4])
  74 AC_CONFIG_AUX_DIR([build-aux])
  75
  76 AC_CANONICAL_TARGET
  77
  78 AM_INIT_AUTOMAKE
  79
  80 TODAY="`LC_ALL=C date +'%a, %d %b %Y %X %z'`"
  81 AC_SUBST(TODAY)
  82
  83 GST_VAAPI_MAJOR_VERSION=gst_vaapi_major_version
  84 AC_SUBST(GST_VAAPI_MAJOR_VERSION)
  85
  86 LIBVA_PACKAGE_VERSION=libva_x11_package_version
  87 AC_SUBST(LIBVA_PACKAGE_VERSION)
  88
  89 WAYLAND_API_VERSION=wayland_api_version
  90 AC_SUBST(WAYLAND_API_VERSION)
  91
  92 dnl Versions for GStreamer and plugins-base
  93 GST_MAJORMINOR=gst_major_minor_version
  94 GST_VERSION_REQUIRED=gst_version
  95 GST_PLUGINS_BASE_VERSION_REQUIRED=gst_plugins_base_version
  96 GST_PLUGINS_BAD_VERSION_REQUIRED=gst_plugins_bad_version
  97 AC_SUBST(GST_MAJORMINOR)
  98 AC_SUBST(GST_VERSION_REQUIRED)
  99 AC_SUBST(GST_PLUGINS_BASE_VERSION_REQUIRED)
 100 AC_SUBST(GST_PLUGINS_BAD_VERSION_REQUIRED)
 101
 102 dnl Use pretty build output with automake >= 1.11
 103 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [
 104   AM_DEFAULT_VERBOSITY=1
 105   AC_SUBST(AM_DEFAULT_VERBOSITY)
 106 ])
 107
 108 dnl Check for tools
 109 AC_PROG_CC
 110 AM_PROG_CC_C_O
 111
 112 dnl Initialize libtool
 113 LT_PREREQ([2.2])
 114 LT_INIT
 115
 116 AC_ARG_ENABLE(drm,
 117     AS_HELP_STRING([--enable-drm],
 118                    [enable DRM backend @<:@default=yes@:>@]),
 119     [], [enable_drm="yes"])
 120
 121 AC_ARG_ENABLE(x11,
 122     AS_HELP_STRING([--enable-x11],
 123                    [enable X11 output @<:@default=yes@:>@]),
 124     [], [enable_x11="yes"])
 125
 126 AC_ARG_ENABLE(glx,
 127     AS_HELP_STRING([--enable-glx],
 128                    [enable OpenGL/X11 output @<:@default=yes@:>@]),
 129     [], [enable_glx="yes"])
 130
 131 AC_ARG_ENABLE(wayland,
 132     AC_HELP_STRING([--enable-wayland],
 133                    [enable Wayland output @<:@default=yes@:>@]),
 134     [], [enable_wayland="yes"])
 135
 136 dnl Check for basic libraries
 137 AC_CHECK_LIB(m, tan)
 138
 139 dnl Check for Gtk doc
 140 GTKDOC_VERSION=gtkdoc_version
 141 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
 142 m4_ifdef([GTK_DOC_CHECK], [
 143 GTK_DOC_CHECK([$GTKDOC_VERSION], [--flavour no-tmpl])], [
 144 AM_CONDITIONAL([ENABLE_GTK_DOC], [false])])
 145 AC_SUBST(GTKDOC_VERSION)
 146
 147 dnl Check for GLib
 148 GLIB_VERSION_REQUIRED=glib_version
 149 PKG_CHECK_MODULES([GLIB], [glib-2.0 >= $GLIB_VERSION_REQUIRED])
 150 AC_SUBST(GLIB_VERSION_REQUIRED)
 151
 152 dnl ---------------------------------------------------------------------------
 153 dnl -- GStreamer                                                             --
 154 dnl ---------------------------------------------------------------------------
 155
 156 dnl GStreamer Core
 157 PKG_CHECK_MODULES([GST],      [gstreamer-$GST_MAJORMINOR >= gst_version])
 158 PKG_CHECK_MODULES([GST_BASE], [gstreamer-base-$GST_MAJORMINOR >= gst_version])
 159
 160 AC_CACHE_CHECK([for GstBaseSink::query hook], ac_cv_have_gst_base_sink_query, [
 161     saved_CFLAGS="$CFLAGS"
 162     CFLAGS="$CFLAGS $GST_BASE_CFLAGS"
 163     saved_LIBS="$LIBS"
 164     LIBS="$LIBS $GST_BASE_LIBS"
 165     AC_COMPILE_IFELSE(
 166         [AC_LANG_PROGRAM(
 167             [[#include <gst/base/gstbasesink.h>]],
 168             [[GstBaseSinkClass klass; klass.query = NULL;]])],
 169         [ac_cv_have_gst_base_sink_query="yes"],
 170         [ac_cv_have_gst_base_sink_query="no"]
 171     )
 172     CFLAGS="$saved_CFLAGS"
 173     LIBS="$saved_LIBS"
 174 ])
 175 if test "$ac_cv_have_gst_base_sink_query" != "yes"; then
 176     AC_MSG_ERROR([GstBaseSink does not contain the 'query' vfunc])
 177 fi
 178
 179 dnl GStreamer -base plugins
 180 PKG_CHECK_MODULES([GST_PLUGINS_BASE],
 181     [gstreamer-plugins-base-$GST_MAJORMINOR >= gst_plugins_base_version])
 182 PKG_CHECK_MODULES([GST_INTERFACES],
 183     [gstreamer-interfaces-$GST_MAJORMINOR >= gst_plugins_base_version])
 184
 185 dnl ... GstVideoOverlayComposition (gstreamer-video)
 186 PKG_CHECK_MODULES([GST_VIDEO],
 187     [gstreamer-video-$GST_MAJORMINOR >= gst_plugins_base_version])
 188
 189 AC_CACHE_CHECK([for GstVideoOverlayComposition],
 190     ac_cv_have_gst_video_overlay_composition, [
 191     saved_CFLAGS="$CFLAGS"
 192     CFLAGS="$CFLAGS $GST_CFLAGS"
 193     saved_LIBS="$LIBS"
 194     LIBS="$LIBS $GST_LIBS"
 195     AC_COMPILE_IFELSE(
 196         [AC_LANG_PROGRAM(
 197             [[#include <gst/video/video-overlay-composition.h>]],
 198             [[GstVideoOverlayComposition *c = gst_video_overlay_composition_new(0);]])],
 199         [ac_cv_have_gst_video_overlay_composition="yes"],
 200         [ac_cv_have_gst_video_overlay_composition="no"]
 201     )
 202     CFLAGS="$saved_CFLAGS"
 203     LIBS="$saved_LIBS"
 204 ])
 205 if test "$ac_cv_have_gst_video_overlay_composition" != "yes"; then
 206     AC_MSG_ERROR([GstVideoOverlayComposition is not available])
 207 fi
 208
 209 dnl GStreamer -bad plugins
 210 PKG_CHECK_MODULES([GST_BASEVIDEO],
 211     [gstreamer-basevideo-$GST_MAJORMINOR >= gst_plugins_bad_version])
 212
 213 dnl ... bitstream parsers
 214 USE_CODEC_PARSERS=1
 215 USE_LOCAL_CODEC_PARSERS=0
 216
 217 PKG_CHECK_MODULES([GST_CODEC_PARSERS],
 218     [gstreamer-codecparsers-$GST_MAJORMINOR >= gst_plugins_bad_version])
 219
 220 dnl ... 0.10.23 addition, could be implemented otherwise
 221 AC_CACHE_CHECK([for GstH264SliceHdr::n_emulation_prevention_bytes],
 222     ac_cv_have_gst_h264_slice_hdr_epb_count, [
 223     saved_CFLAGS="$CFLAGS"
 224     CFLAGS="$CFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 225     saved_LIBS="$LIBS"
 226     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 227     AC_COMPILE_IFELSE(
 228         [AC_LANG_PROGRAM(
 229             [[#include <gst/codecparsers/gsth264parser.h>]],
 230             [[GstH264SliceHdr slice_hdr;
 231               slice_hdr.n_emulation_prevention_bytes = 0;]])],
 232         [ac_cv_have_gst_h264_slice_hdr_epb_count="yes"],
 233         [ac_cv_have_gst_h264_slice_hdr_epb_count="no"]
 234     )
 235     CFLAGS="$saved_CFLAGS"
 236     LIBS="$saved_LIBS"
 237 ])
 238
 239 if test "$ac_cv_have_gst_h264_slice_hdr_epb_count" = "yes"; then
 240     AC_DEFINE_UNQUOTED(HAVE_GST_H264_SLICE_HDR_EPB_COUNT, 1,
 241         [Defined to 1 if GstH264SliceHdr::n_emulation_prevention_bytes exists.])
 242 fi
 243
 244 dnl ... JPEG parser, not upstream yet
 245 AC_CACHE_CHECK([for JPEG parser],
 246     ac_cv_have_gst_jpeg_parser, [
 247     saved_CFLAGS="$CFLAGS"
 248     CFLAGS="$CFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 249     saved_LIBS="$LIBS"
 250     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 251     AC_COMPILE_IFELSE(
 252         [AC_LANG_PROGRAM(
 253             [[#include <gst/codecparsers/gstjpegparser.h>]],
 254             [[GstJpegImage jpeg_image;]])],
 255         [ac_cv_have_gst_jpeg_parser="yes"],
 256         [ac_cv_have_gst_jpeg_parser="no" USE_LOCAL_CODEC_PARSERS=1]
 257     )
 258     CFLAGS="$saved_CFLAGS"
 259     LIBS="$saved_LIBS"
 260 ])
 261
 262 if test "$ac_cv_have_gst_jpeg_parser" = "yes"; then
 263     AC_DEFINE_UNQUOTED(HAVE_GST_JPEG_PARSER, 1,
 264         [Defined to 1 if JPEG parser exists.])
 265 fi
 266 AM_CONDITIONAL(USE_LOCAL_CODEC_PARSERS, test $USE_LOCAL_CODEC_PARSERS -eq 1)
 267
 268 dnl GST_ALL_LDFLAGS:
 269 dnl LDFLAGS really should only contain flags, not libs - they get added before
 270 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 271 GST_ALL_LDFLAGS="-no-undefined"
 272 AC_SUBST(GST_ALL_LDFLAGS)
 273
 274 dnl GST_PLUGIN_LDFLAGS:
 275 dnl this really should only contain flags, not libs - they get added before
 276 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 277 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^([_]*gst_plugin_desc|gst_.*_get_type)\$\$' $GST_ALL_LDFLAGS"
 278 AC_SUBST(GST_PLUGIN_LDFLAGS)
 279
 280 dnl Check for the GStreamer plugins directory
 281 AC_MSG_CHECKING([for GStreamer plugins directory])
 282 GST_PLUGINS_DIR=`$PKG_CONFIG gstreamer-$GST_MAJORMINOR --variable pluginsdir`
 283 if test -z "$GST_PLUGINS_DIR"; then
 284     echo "FAIL FAIL FAIL"
 285     GST_PLUGINS_DIR="\$(libdir)/gstreamer-$GST_MAJORMINOR"
 286 fi
 287 AC_MSG_RESULT([$GST_PLUGINS_DIR])
 288 plugindir="$GST_PLUGINS_DIR"
 289 AC_SUBST(plugindir)
 290
 291 dnl ---------------------------------------------------------------------------
 292 dnl -- Renderers                                                             --
 293 dnl ---------------------------------------------------------------------------
 294
 295 dnl Check for DRM/libudev
 296 USE_DRM=0
 297 if test "$enable_drm" = "yes"; then
 298     PKG_CHECK_MODULES(DRM, [libdrm], [USE_DRM=1], [USE_DRM=0])
 299     PKG_CHECK_MODULES(UDEV, [libudev], [:], [USE_DRM=0])
 300
 301     if test $USE_DRM -eq 1; then
 302         saved_CPPFLAGS="$CPPFLAGS"
 303         CPPFLAGS="$CPPFLAGS $DRM_CFLAGS"
 304         AC_CHECK_HEADERS([drm_fourcc.h], [:], [USE_DRM=0])
 305         CPPFLAGS="$saved_CPPFLAGS"
 306     fi
 307 fi
 308
 309 dnl Check for X11
 310 USE_X11=0
 311 if test "$enable_x11" = "yes"; then
 312     PKG_CHECK_MODULES(X11, [x11], [USE_X11=1], [USE_X11=0])
 313     if test $USE_X11 -eq 1; then
 314         saved_CPPFLAGS="$CPPFLAGS"
 315         CPPFLAGS="$CPPFLAGS $X11_CFLAGS"
 316         AC_CHECK_HEADERS([X11/Xlib.h X11/Xutil.h X11/Xatom.h], [:], [USE_X11=0])
 317         CPPFLAGS="$saved_CPPFLAGS"
 318     fi
 319 fi
 320
 321 dnl Check for XRandR
 322 HAVE_XRANDR=0
 323 if test $USE_X11 -eq 1; then
 324     HAVE_XRANDR=1
 325     PKG_CHECK_MODULES([XRANDR], [xrandr], [:], [HAVE_XRANDR=0])
 326     if test $HAVE_XRANDR -eq 1; then
 327         saved_CPPFLAGS="$CPPFLAGS"
 328         CPPFLAGS="$CPPFLAGS $XRANDR_CFLAGS"
 329         AC_CHECK_HEADERS([X11/extensions/Xrandr.h], [:], [HAVE_XRANDR=0])
 330         CPPFLAGS="$saved_CPPFLAGS"
 331     fi
 332 fi
 333 if test $HAVE_XRANDR -eq 1; then
 334     AC_DEFINE_UNQUOTED(HAVE_XRANDR, 1,
 335         [Defined to 1 if the XRandR extension exists.])
 336 fi
 337
 338 dnl OpenGL
 339 enable_opengl="no"
 340 if test "$enable_glx" = "yes"; then
 341     enable_opengl="yes"
 342 fi
 343
 344 HAVE_GL=0
 345 if test "$enable_opengl" = "yes"; then
 346     HAVE_GL=1
 347     PKG_CHECK_MODULES([GL], [gl], [:], [HAVE_GL=0])
 348     saved_CPPFLAGS="$CPPFLAGS"
 349     CPPFLAGS="$CPPFLAGS $GL_CFLAGS"
 350     AC_CHECK_HEADERS([GL/gl.h GL/glext.h], [:], [HAVE_GL=0], [
 351 #ifdef HAVE_GL_GL_H
 352 # include <GL/gl.h>
 353 #endif
 354     ])
 355     CPPFLAGS="$saved_CPPFLAGS"
 356 fi
 357
 358 dnl ... GLX
 359 USE_GLX=0
 360 if test "$enable_glx" = "yes" -a $HAVE_GL -eq 1 -a $USE_X11 -eq 1; then
 361     USE_GLX=1
 362     saved_CPPFLAGS="$CPPFLAGS"
 363     saved_LIBS="$LIBS"
 364     CPPFLAGS="$CPPFLAGS $GL_CFLAGS"
 365     LIBS="$LIBS $GL_LIBS"
 366     AC_CHECK_HEADERS([GL/glx.h], [:], [USE_GLX=0], [
 367 #ifdef HAVE_GL_GL_H
 368 # include <GL/gl.h>
 369 #endif
 370     ])
 371     AC_CHECK_LIB([GL], [glXCreateContext], [:], [USE_GLX=0])
 372     CPPFLAGS="$saved_CPPFLAGS"
 373     LIBS="$saved_LIBS"
 374 fi
 375
 376 dnl Check for Wayland
 377 USE_WAYLAND=0
 378 if test "$enable_wayland" = "yes"; then
 379     PKG_CHECK_MODULES(WAYLAND, [wayland-client >= wayland_api_version],
 380         [USE_WAYLAND=1], [USE_WAYLAND=0])
 381
 382     if test $USE_WAYLAND -eq 1; then
 383         saved_CPPFLAGS="$CPPFLAGS"
 384         CPPFLAGS="$CPPFLAGS $WAYLAND_CFLAGS"
 385         AC_CHECK_HEADERS([wayland-client.h], [:], [USE_WAYLAND=0])
 386         CPPFLAGS="$saved_CPPFLAGS"
 387     fi
 388 fi
 389
 390 dnl ---------------------------------------------------------------------------
 391 dnl -- VA-API                                                                --
 392 dnl ---------------------------------------------------------------------------
 393
 394 dnl Core API
 395 LIBVA_PKGNAME="libva"
 396 PKG_CHECK_MODULES(LIBVA, [$LIBVA_PKGNAME >= va_api_version])
 397 AC_SUBST(LIBVA_PKGNAME)
 398
 399 VA_VERSION=`$PKG_CONFIG --modversion libva`
 400 VA_MAJOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f1`
 401 VA_MINOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f2`
 402 VA_MICRO_VERSION=`echo "$VA_VERSION" | cut -d'.' -f3`
 403 VA_VERSION_STR="$VA_VERSION"
 404
 405 dnl VA/DRM API
 406 HAVE_VA_DRM=0
 407 if test $USE_DRM -eq 1; then
 408     PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm >= va_api_drm_version],
 409         [HAVE_VA_DRM=1], [USE_DRM=0])
 410
 411     if test $HAVE_VA_DRM -eq 1; then
 412         saved_CPPFLAGS="$CPPFLAGS"
 413         CPPFLAGS="$LIBVA_DRM_CFLAGS"
 414         AC_CHECK_HEADERS([va/va_drm.h], [:], [HAVE_VA_DRM=0 USE_DRM=0])
 415         CPPFLAGS="$saved_CPPFLAGS"
 416     fi
 417 fi
 418
 419 dnl VA/X11 API
 420 HAVE_VA_X11=0
 421 LIBVA_X11_PKGNAME="libva-x11"
 422 if test $USE_X11 -eq 1; then
 423     PKG_CHECK_MODULES(LIBVA_X11, [$LIBVA_X11_PKGNAME >= va_api_x11_version],
 424         [HAVE_VA_X11=1], [USE_X11=0])
 425 fi
 426 AC_SUBST(LIBVA_X11_PKGNAME)
 427
 428 dnl VA/GLX API
 429 HAVE_VA_GLX=0
 430 LIBVA_GLX_PKGNAME="libva-glx"
 431 if test $USE_GLX -eq 1; then
 432     PKG_CHECK_MODULES(LIBVA_GLX, [$LIBVA_GLX_PKGNAME >= va_api_glx_version],
 433         [HAVE_VA_GLX=1], [LIBVA_GLX_PKGNAME="$LIBVA_X11_PKGNAME"])
 434
 435     if test $HAVE_VA_GLX -eq 1; then
 436         saved_CPPFLAGS="$CPPFLAGS"
 437         CPPFLAGS="$LIBVA_GLX_CFLAGS"
 438         AC_CHECK_HEADERS([va/va_glx.h], [:], [HAVE_VA_GLX=0])
 439         CPPFLAGS="$saved_CPPFLAGS"
 440     fi
 441 fi
 442 AC_SUBST(LIBVA_GLX_PKGNAME)
 443
 444 dnl Check for JPEG decoding API (0.32.1+)
 445 USE_JPEG_DECODER=0
 446 AC_CACHE_CHECK([for JPEG decoding API],
 447     ac_cv_have_jpeg_decoding_api, [
 448     saved_CFLAGS="$CFLAGS"
 449     CFLAGS="$CFLAGS $LIBVA_CFLAGS"
 450     saved_LIBS="$LIBS"
 451     LIBS="$CFLAGS $LIBVA_LIBS"
 452     AC_COMPILE_IFELSE(
 453         [AC_LANG_PROGRAM(
 454             [[#include <va/va.h>]],
 455             [[VAPictureParameterBufferJPEGBaseline pic_param;
 456               VASliceParameterBufferJPEGBaseline slice_param;
 457               VAHuffmanTableBufferJPEGBaseline huffman_table;
 458               VAIQMatrixBufferJPEGBaseline iq_matrix;]])],
 459         [ac_cv_have_jpeg_decoding_api="yes" USE_JPEG_DECODER=1],
 460         [ac_cv_have_jpeg_decoding_api="no"]
 461     )
 462     CFLAGS="$saved_CFLAGS"
 463     LIBS="$saved_LIBS"
 464 ])
 465
 466 dnl VA/Wayland API
 467 if test "$enable_wayland" = "yes"; then
 468     PKG_CHECK_MODULES([LIBVA_WAYLAND], [libva-wayland >= va_api_wld_version],
 469         [:], [USE_WAYLAND=0])
 470 fi
 471
 472 dnl ---------------------------------------------------------------------------
 473 dnl -- Generate files and summary                                            --
 474 dnl ---------------------------------------------------------------------------
 475
 476 case ":$USE_X11:$USE_GLX:$USE_WAYLAND:$USE_DRM:" in
 477 *:1:*)
 478     ;;
 479 *)
 480     AC_MSG_ERROR([No renderer is enabled])
 481     ;;
 482 esac
 483
 484 AC_DEFINE_UNQUOTED(USE_JPEG_DECODER, $USE_JPEG_DECODER,
 485     [Defined to 1 if JPEG decoder is used])
 486 AM_CONDITIONAL(USE_JPEG_DECODER, test $USE_JPEG_DECODER -eq 1)
 487
 488 AC_DEFINE_UNQUOTED(USE_DRM, $USE_DRM,
 489     [Defined to 1 if DRM is enabled])
 490 AM_CONDITIONAL(USE_DRM, test $USE_DRM -eq 1)
 491
 492 AC_DEFINE_UNQUOTED(USE_X11, $USE_X11,
 493     [Defined to 1 if X11 is enabled])
 494 AM_CONDITIONAL(USE_X11, test $USE_X11 -eq 1)
 495
 496 AC_DEFINE_UNQUOTED(USE_GLX, $USE_GLX,
 497     [Defined to 1 if GLX is enabled])
 498 AM_CONDITIONAL(USE_GLX, test $USE_GLX -eq 1)
 499
 500 AC_DEFINE_UNQUOTED(USE_WAYLAND, $USE_WAYLAND,
 501     [Defined to 1 if WAYLAND is enabled])
 502 AM_CONDITIONAL(USE_WAYLAND, test $USE_WAYLAND -eq 1)
 503
 504 pkgconfigdir=${libdir}/pkgconfig
 505 AC_SUBST(pkgconfigdir)
 506
 507 AC_CONFIG_FILES([
 508     Makefile
 509     debian.upstream/Makefile
 510     debian.upstream/changelog
 511     debian.upstream/control
 512     debian.upstream/gstreamer$GST_MAJORMINOR-vaapi-doc.install:\
 513 debian.upstream/gstreamer-vaapi-doc.install.in
 514     debian.upstream/gstreamer$GST_MAJORMINOR-vaapi.install:\
 515 debian.upstream/gstreamer-vaapi.install.in
 516     debian.upstream/libgstvaapi$GST_VAAPI_MAJOR_VERSION.install:\
 517 debian.upstream/libgstvaapi.install.in
 518     debian.upstream/libgstvaapi-dev.install
 519     debian.upstream/libgstvaapi-drm-$GST_VAAPI_MAJOR_VERSION.install:\
 520 debian.upstream/libgstvaapi-drm.install.in
 521     debian.upstream/libgstvaapi-glx-$GST_VAAPI_MAJOR_VERSION.install:\
 522 debian.upstream/libgstvaapi-glx.install.in
 523     debian.upstream/libgstvaapi-wayland-$GST_VAAPI_MAJOR_VERSION.install:\
 524 debian.upstream/libgstvaapi-wayland.install.in
 525     debian.upstream/libgstvaapi-x11-$GST_VAAPI_MAJOR_VERSION.install:\
 526 debian.upstream/libgstvaapi-x11.install.in
 527     docs/Makefile
 528     docs/reference/Makefile
 529     docs/reference/libs/Makefile
 530     docs/reference/libs/libs-docs.xml
 531     docs/reference/plugins/Makefile
 532     docs/reference/plugins/plugins-docs.xml
 533     ext/Makefile
 534     gst-libs/Makefile
 535     gst-libs/gst/Makefile
 536     gst-libs/gst/codecparsers/Makefile
 537     gst-libs/gst/vaapi/Makefile
 538     gst/Makefile
 539     gst/vaapi/Makefile
 540     pkgconfig/Makefile
 541     pkgconfig/gstreamer-vaapi-$GST_MAJORMINOR.pc:\
 542 pkgconfig/gstreamer-vaapi.pc.in
 543     pkgconfig/gstreamer-vaapi-drm-$GST_MAJORMINOR.pc:\
 544 pkgconfig/gstreamer-vaapi-drm.pc.in
 545     pkgconfig/gstreamer-vaapi-glx-$GST_MAJORMINOR.pc:\
 546 pkgconfig/gstreamer-vaapi-glx.pc.in
 547     pkgconfig/gstreamer-vaapi-wayland-$GST_MAJORMINOR.pc:\
 548 pkgconfig/gstreamer-vaapi-wayland.pc.in
 549     pkgconfig/gstreamer-vaapi-x11-$GST_MAJORMINOR.pc:\
 550 pkgconfig/gstreamer-vaapi-x11.pc.in
 551     tests/Makefile
 552 ])
 553 AC_OUTPUT
 554
 555 dnl Print summary
 556 yesno() {
 557     test $1 -eq 1 && echo yes || echo no
 558 }
 559
 560 VIDEO_OUTPUTS=""
 561 AS_IF([test $USE_DRM -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS drm"])
 562 AS_IF([test $USE_X11 -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS x11"])
 563 AS_IF([test $USE_GLX -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS glx"])
 564 AS_IF([test $USE_WAYLAND -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS wayland"])
 565
 566 echo
 567 echo $PACKAGE configuration summary:
 568 echo
 569 echo VA-API version ................... : $VA_VERSION_STR
 570 echo Video outputs .................... : $VIDEO_OUTPUTS
 571 echo