configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 # Copyright (C) 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010
   3 # Free Software Foundation, Inc.
   4 #
   5 # This file is part of LIBTASN1.
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ(2.61)
  21 AC_INIT([GNU Libtasn1], [2.9], [help-libtasn1@gnu.org])
  22 AC_CONFIG_AUX_DIR([build-aux])
  23 AC_CONFIG_MACRO_DIR([m4])
  24 AC_CONFIG_HEADERS(config.h)
  25 AM_INIT_AUTOMAKE([1.10 -Wall -Werror -Wno-override])
  26
  27 # Library code modified:                              REVISION++
  28 # Interfaces changed/added/removed:   CURRENT++       REVISION=0
  29 # Interfaces added:                             AGE++
  30 # Interfaces removed:                           AGE=0
  31 AC_SUBST(LT_CURRENT, 4)
  32 AC_SUBST(LT_REVISION, 11)
  33 AC_SUBST(LT_AGE, 1)
  34
  35 AC_PROG_CC
  36 gl_EARLY
  37 lgl_EARLY
  38 AC_PROG_YACC
  39 AC_PROG_LN_S
  40
  41 dnl Checks for programs.
  42 AC_PROG_INSTALL
  43 AM_MISSING_PROG(PERL, perl, $missing_dir)
  44 AM_MISSING_PROG(HELP2MAN, help2man, $missing_dir)
  45
  46 AC_LIBTOOL_WIN32_DLL
  47 AM_PROG_LIBTOOL
  48
  49 AC_CHECK_SIZEOF(unsigned long int, 4)
  50 AC_CHECK_SIZEOF(unsigned int, 4)
  51
  52 sj_UPDATE_HEADER_VERSION([$srcdir/lib/libtasn1.h])
  53
  54 # Check for gtk-doc.
  55 GTK_DOC_CHECK(1.2)
  56
  57 # For gnulib compatibility modules.
  58 gl_INIT
  59 lgl_INIT
  60
  61 AC_ARG_ENABLE([gcc-warnings],
  62   [AS_HELP_STRING([--enable-gcc-warnings],
  63                   [turn on lots of GCC warnings (for developers)])],
  64   [case $enableval in
  65      yes|no) ;;
  66      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  67    esac
  68    gl_gcc_warnings=$enableval],
  69   [gl_gcc_warnings=no]
  70 )
  71
  72 if test "$gl_gcc_warnings" = yes; then
  73   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  74
  75   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
  76   nw="$nw -Wc++-compat"             # We don't care strongly about C++ compilers
  77   nw="$nw -Wtraditional"            # Warns on #elif which we use often
  78   nw="$nw -Wtraditional-conversion" # Too many warnings for now
  79   nw="$nw -Wconversion"             # Too many warnings for now
  80   nw="$nw -Wsign-conversion"        # Too many warnings for now
  81   nw="$nw -Wold-style-definition"   #
  82   nw="$nw -Wpadded"                 # Our structs are not padded
  83   nw="$nw -Wundef"                  #
  84   nw="$nw -Wunreachable-code"       # Too many false positives
  85   nw="$nw -Wunused-macros"          # Breaks on bison generated ASN1.c
  86   nw="$nw -Wunsafe-loop-optimizations"
  87   nw="$nw -Wstrict-overflow"
  88
  89   gl_MANYWARN_ALL_GCC([ws])
  90   gl_MANYWARN_COMPLEMENT(ws, [$ws], [$nw])
  91   for w in $ws; do
  92     gl_WARN_ADD([$w])
  93   done
  94
  95   gl_WARN_ADD([-Wno-missing-field-initializers])
  96   gl_WARN_ADD([-Wno-sign-compare])
  97   gl_WARN_ADD([-Wno-pointer-sign])
  98   gl_WARN_ADD([-Wno-unused-parameter])
  99   gl_WARN_ADD([-Wno-stack-protector])            # Some functions cannot be protected
 100   gl_WARN_ADD([-fdiagnostics-show-option])
 101 fi
 102
 103 AC_CONFIG_FILES([
 104   Makefile
 105   doc/Makefile
 106   doc/cyclo/Makefile
 107   doc/reference/Makefile
 108   examples/Makefile
 109   gl/Makefile
 110   lib/Makefile
 111   lib/gllib/Makefile
 112   lib/libtasn1.pc
 113   src/Makefile
 114   tests/Makefile
 115 ])
 116 AC_OUTPUT
 117
 118 AC_MSG_NOTICE([summary of build options:
 119
 120   version:          ${VERSION} shared $LT_CURRENT:$LT_REVISION:$LT_AGE
 121   Host type:        ${host}
 122   Install prefix:   ${prefix}
 123   Compiler:         ${CC}
 124   Warning flags:    errors: ${WERROR_CFLAGS} warnings: ${WARN_CFLAGS}
 125   Library types:    Shared=${enable_shared}, Static=${enable_static}
 126   Valgrind:         ${VALGRIND}
 127   Version script:   $have_ld_version_script
 128 ])