configure.ac

   1 dnl -*- mode: m4 -*-
   2 AC_PREREQ([2.63])
   3
   4 m4_define([dbus_major_version], [1])
   5 m4_define([dbus_minor_version], [4])
   6 m4_define([dbus_micro_version], [7])
   7 m4_define([dbus_version],
   8           [dbus_major_version.dbus_minor_version.dbus_micro_version])
   9 AC_INIT([dbus],[dbus_version],[https://bugs.freedesktop.org/enter_bug.cgi?product=dbus],[dbus])
  10
  11 AC_CANONICAL_HOST
  12
  13 AC_CONFIG_HEADERS([config.h])
  14 AC_CONFIG_MACRO_DIR([m4])
  15
  16 AM_INIT_AUTOMAKE([1.10 tar-ustar -Wno-portability])
  17
  18 GETTEXT_PACKAGE=dbus-1
  19 AC_SUBST(GETTEXT_PACKAGE)
  20 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[The name of the gettext domain])
  21
  22  ## must come before we use the $USE_MAINTAINER_MODE variable later
  23 AM_MAINTAINER_MODE
  24
  25 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  26
  27 AC_DEFINE_UNQUOTED(DBUS_DAEMON_NAME,"dbus-daemon",[Name of executable])
  28
  29 # libtool versioning - this applies to libdbus
  30 #
  31 # See http://sources.redhat.com/autobook/autobook/autobook_91.html#SEC91 for details
  32 #
  33
  34 ## increment if the interface has additions, changes, removals.
  35 LT_CURRENT=8
  36
  37 ## increment any time the source changes; set to
  38 ##  0 if you increment CURRENT
  39 LT_REVISION=4
  40
  41 ## increment if any interfaces have been added; set to 0
  42 ## if any interfaces have been changed or removed. removal has
  43 ## precedence over adding, so set to 0 if both happened.
  44 LT_AGE=5
  45
  46 AC_SUBST(LT_CURRENT)
  47 AC_SUBST(LT_REVISION)
  48 AC_SUBST(LT_AGE)
  49
  50 DBUS_MAJOR_VERSION=dbus_major_version
  51 DBUS_MINOR_VERSION=dbus_minor_version
  52 DBUS_MICRO_VERSION=dbus_micro_version
  53 DBUS_VERSION=dbus_major_version.dbus_minor_version.dbus_micro_version
  54
  55 AC_SUBST(DBUS_MAJOR_VERSION)
  56 AC_SUBST(DBUS_MINOR_VERSION)
  57 AC_SUBST(DBUS_MICRO_VERSION)
  58 AC_SUBST(DBUS_VERSION)
  59
  60 AC_PROG_CC
  61 AM_PROG_CC_C_O
  62 AC_PROG_CXX
  63 AC_USE_SYSTEM_EXTENSIONS
  64 AC_ISC_POSIX
  65 AC_HEADER_STDC
  66 AC_C_INLINE
  67 AM_PROG_LIBTOOL
  68 AC_PROG_MKDIR_P
  69 COMPILER_COVERAGE
  70 COMPILER_OPTIMISATIONS
  71
  72 # Initialize libtool
  73 LT_INIT([win32-dll])
  74 LT_LANG([Windows Resource])
  75
  76 # Set some internal variables depending on the platform for later use.
  77 dbus_win=no
  78 dbus_cygwin=no
  79 dbus_unix=no
  80 case "${host}" in
  81     *-mingw32ce*)
  82         dbus_win=yes
  83         dbus_wince=yes
  84         ;;
  85     *-mingw32*)
  86         dbus_win=yes
  87         ;;
  88     *-cygwin*)
  89         dbus_cygwin=yes
  90         dbus_unix=yes
  91         ;;
  92     *)
  93         dbus_unix=yes
  94        ;;
  95 esac
  96
  97 # Special defines for certain platforms
  98 if test "$dbus_win" = yes; then
  99     AC_DEFINE(DBUS_WIN,1,[Defined if we run on a W32 API based system])
 100     BUILD_TIMESTAMP=`date --iso-8601=minutes`
 101     AC_SUBST(BUILD_TIMESTAMP)
 102     # Assume DBUS_VERSION is always three numbers
 103     BUILD_FILEVERSION=`echo "$DBUS_VERSION" | sed -e 's/\./,/g'`,0
 104     AC_SUBST(BUILD_FILEVERSION)
 105     AC_CHECK_TOOL(WINDRES, windres, no)
 106     if test "$WINDRES" = no; then
 107       AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 108     fi
 109     if test "$dbus_wince" = yes; then
 110       AC_DEFINE(DBUS_WINCE,1,[Defined if we run on a W32 CE API based system])
 111       AC_DEFINE(_WIN32_WCE, 0x0502, [Defined to get newer W32 CE APIs])
 112     fi
 113 else
 114     AC_DEFINE(DBUS_UNIX,1,[Defined if we run on a Unix-based system])
 115 fi
 116 if test "$dbus_cygwin" = yes; then
 117     AC_DEFINE(DBUS_CYGWIN,1,[Defined if we run on a cygwin API based system])
 118 fi
 119
 120 AM_CONDITIONAL(DBUS_WIN, test "$dbus_win" = yes)
 121 AM_CONDITIONAL(DBUS_WINCE, test "$dbus_wince" = yes)
 122 AM_CONDITIONAL(DBUS_UNIX, test "$dbus_unix" = yes)
 123 AM_CONDITIONAL(DBUS_CYGWIN, test "$dbus_cygwin" = yes)
 124
 125 AC_ARG_ENABLE(tests, AS_HELP_STRING([--enable-tests],[enable unit test code in the library and binaries]),enable_tests=$enableval,enable_tests=$USE_MAINTAINER_MODE)
 126 AC_ARG_ENABLE(ansi, AS_HELP_STRING([--enable-ansi],[enable -ansi -pedantic gcc flags]),enable_ansi=$enableval,enable_ansi=no)
 127 AC_ARG_ENABLE(verbose-mode, AS_HELP_STRING([--enable-verbose-mode],[support verbose debug mode]),enable_verbose_mode=$enableval,enable_verbose_mode=$USE_MAINTAINER_MODE)
 128 AC_ARG_ENABLE(asserts, AS_HELP_STRING([--enable-asserts],[include assertion checks]),enable_asserts=$enableval,enable_asserts=$USE_MAINTAINER_MODE)
 129 AC_ARG_ENABLE(checks, AS_HELP_STRING([--enable-checks],[include sanity checks on public API]),enable_checks=$enableval,enable_checks=yes)
 130 AC_ARG_ENABLE(xml-docs, AS_HELP_STRING([--enable-xml-docs],[build XML documentation (requires xmlto)]),enable_xml_docs=$enableval,enable_xml_docs=auto)
 131 AC_ARG_ENABLE(doxygen-docs, AS_HELP_STRING([--enable-doxygen-docs],[build DOXYGEN documentation (requires Doxygen)]),enable_doxygen_docs=$enableval,enable_doxygen_docs=auto)
 132 AC_ARG_ENABLE(abstract-sockets, AS_HELP_STRING([--enable-abstract-sockets],[use abstract socket namespace (linux only)]),enable_abstract_sockets=$enableval,enable_abstract_sockets=auto)
 133 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--enable-selinux],[build with SELinux support]),enable_selinux=$enableval,enable_selinux=auto)
 134 AC_ARG_ENABLE(libaudit,AS_HELP_STRING([--enable-libaudit],[build audit daemon support for SELinux]),enable_libaudit=$enableval,enable_libaudit=auto)
 135 AC_ARG_ENABLE(dnotify, AS_HELP_STRING([--enable-dnotify],[build with dnotify support (linux only)]),enable_dnotify=$enableval,enable_dnotify=auto)
 136 AC_ARG_ENABLE(inotify, AS_HELP_STRING([--enable-inotify],[build with inotify support (linux only)]),enable_inotify=$enableval,enable_inotify=auto)
 137 AC_ARG_ENABLE(kqueue, AS_HELP_STRING([--enable-kqueue],[build with kqueue support]),enable_kqueue=$enableval,enable_kqueue=auto)
 138 AC_ARG_ENABLE(console-owner-file, AS_HELP_STRING([--enable-console-owner-file],[enable console owner file]),enable_console_owner_file=$enableval,enable_console_owner_file=auto)
 139 AC_ARG_ENABLE(userdb-cache, AS_HELP_STRING([--enable-userdb-cache],[build with userdb-cache support]),enable_userdb_cache=$enableval,enable_userdb_cache=yes)
 140 AC_ARG_ENABLE(launchd, AS_HELP_STRING([--enable-launchd],[build with launchd auto-launch support]),enable_launchd=$enableval,enable_launchd=auto)
 141
 142 AC_ARG_WITH(xml, AS_HELP_STRING([--with-xml=[libxml/expat]],[XML library to use (libxml may be named libxml2 on some systems)]))
 143 AC_ARG_WITH(init-scripts, AS_HELP_STRING([--with-init-scripts=[redhat]],[Style of init scripts to install]))
 144 AC_ARG_WITH(session-socket-dir, AS_HELP_STRING([--with-session-socket-dir=[dirname]],[Where to put sockets for the per-login-session message bus]))
 145 AC_ARG_WITH(test-socket-dir, AS_HELP_STRING([--with-test-socket-dir=[dirname]],[Where to put sockets for make check]))
 146 AC_ARG_WITH(system-pid-file, AS_HELP_STRING([--with-system-pid-file=[pidfile]],[PID file for systemwide daemon]))
 147 AC_ARG_WITH(system-socket, AS_HELP_STRING([--with-system-socket=[filename]],[UNIX domain socket for systemwide daemon]))
 148 AC_ARG_WITH(console-auth-dir, AS_HELP_STRING([--with-console-auth-dir=[dirname]],[directory to check for console ownerhip]))
 149 AC_ARG_WITH(console-owner-file, AS_HELP_STRING([--with-console-owner-file=[filename]],[file whose owner determines current console owner]))
 150 AC_ARG_WITH(launchd-agent-dir, AS_HELP_STRING([--with-launchd-agent-dir=[dirname]],[directory to put the launchd agent (default: /Library/LaunchAgents)]))
 151 AC_ARG_WITH(dbus_user, AS_HELP_STRING([--with-dbus-user=<user>],[User for running the DBUS daemon (messagebus)]))
 152 AC_ARG_WITH(dbus_daemondir, AS_HELP_STRING([--with-dbus-daemondir=[dirname]],[Directory for installing the DBUS daemon]))
 153
 154 dnl DBUS_BUILD_TESTS controls unit tests built in to .c files
 155 dnl and also some stuff in the test/ subdir
 156 AM_CONDITIONAL(DBUS_BUILD_TESTS, test x$enable_tests = xyes)
 157 if test x$enable_tests = xyes; then
 158     AC_DEFINE(DBUS_BUILD_TESTS,1,[Build test code])
 159 fi
 160
 161 if test x$enable_verbose_mode = xyes; then
 162     AC_DEFINE(DBUS_ENABLE_VERBOSE_MODE,1,[Support a verbose mode])
 163 fi
 164
 165 if test x$enable_asserts = xno; then
 166     AC_DEFINE(DBUS_DISABLE_ASSERT,1,[Disable assertion checking])
 167     AC_DEFINE(G_DISABLE_ASSERT,1,[Disable GLib assertion macros])
 168     R_DYNAMIC_LDFLAG=""
 169 else
 170     # -rdynamic is needed for glibc's backtrace_symbols to work.
 171     # No clue how much overhead this adds, but it's useful
 172     # to do this on any assertion failure,
 173     # so for now it's enabled anytime asserts are (currently not
 174     # in production builds).
 175
 176     # To get -rdynamic you pass -export-dynamic to libtool.
 177     AC_DEFINE(DBUS_BUILT_R_DYNAMIC,1,[whether -export-dynamic was passed to libtool])
 178     R_DYNAMIC_LDFLAG=-export-dynamic
 179 fi
 180 AC_SUBST(R_DYNAMIC_LDFLAG)
 181
 182 if test x$enable_checks = xno; then
 183     AC_DEFINE(DBUS_DISABLE_CHECKS,1,[Disable public API sanity checking])
 184     AC_DEFINE(G_DISABLE_CHECKS,1,[Disable GLib public API sanity checking])
 185 fi
 186
 187 if test x$enable_userdb_cache = xyes; then
 188     AC_DEFINE(DBUS_ENABLE_USERDB_CACHE,1,[Build with caching of user data])
 189 fi
 190
 191 if test x$enable_compiler_coverage = xyes; then
 192      ## so that config.h changes when you toggle gcov support
 193      AC_DEFINE_UNQUOTED(DBUS_GCOV_ENABLED, 1, [Defined if gcov is enabled to force a rebuild due to config.h changing])
 194 fi
 195
 196 # glibc21.m4 serial 3
 197 dnl Copyright (C) 2000-2002, 2004 Free Software Foundation, Inc.
 198 dnl This file is free software; the Free Software Foundation
 199 dnl gives unlimited permission to copy and/or distribute it,
 200 dnl with or without modifications, as long as this notice is preserved.
 201
 202 # Test for the GNU C Library, version 2.1 or newer.
 203 # From Bruno Haible.
 204
 205 AC_CACHE_CHECK(whether we are using the GNU C Library 2.1 or newer,
 206   ac_cv_gnu_library_2_1,
 207   [AC_EGREP_CPP([Lucky GNU user],
 208     [
 209 #include <features.h>
 210 #ifdef __GNU_LIBRARY__
 211  #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 1) || (__GLIBC__ > 2)
 212   Lucky GNU user
 213  #endif
 214 #endif
 215     ],
 216     ac_cv_gnu_library_2_1=yes,
 217     ac_cv_gnu_library_2_1=no)
 218   ]
 219 )
 220
 221 #### Integer sizes
 222
 223 AC_CHECK_SIZEOF(char)
 224 AC_CHECK_SIZEOF(short)
 225 AC_CHECK_SIZEOF(long)
 226 AC_CHECK_SIZEOF(int)
 227 AC_CHECK_SIZEOF(void *)
 228 AC_CHECK_SIZEOF(long long)
 229 AC_CHECK_SIZEOF(__int64)
 230
 231 ### See what our 64 bit type is called
 232 AC_MSG_CHECKING([64-bit integer type])
 233
 234 case 8 in
 235 $ac_cv_sizeof_int)
 236   dbusint64=int
 237   dbusint64_constant='(val)'
 238   dbusuint64_constant='(val)'
 239   dbusint64_printf_modifier='""'
 240   ;;
 241 $ac_cv_sizeof_long)
 242   dbusint64=long
 243   dbusint64_constant='(val##L)'
 244   dbusuint64_constant='(val##UL)'
 245   dbusint64_printf_modifier='"l"'
 246   ;;
 247 $ac_cv_sizeof_long_long)
 248   dbusint64='long long'
 249   dbusint64_constant='(val##LL)'
 250   dbusuint64_constant='(val##ULL)'
 251   # Ideally we discover what the format is, but this is
 252   # only used in verbose mode, so eh...
 253   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 254     dbusint64_printf_modifier='"ll"'
 255   fi
 256   ;;
 257 $ac_cv_sizeof___int64)
 258   dbusint64=__int64
 259   dbusint64_constant='(val##i64)'
 260   dbusuint64_constant='(val##ui64)'
 261   # See above case
 262   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 263     dbusint64_printf_modifier='"ll"'
 264   fi
 265   ;;
 266 esac
 267
 268 if test -z "$dbusint64" ; then
 269         DBUS_INT64_TYPE="no_int64_type_detected"
 270         DBUS_HAVE_INT64=0
 271         DBUS_INT64_CONSTANT=
 272         DBUS_UINT64_CONSTANT=
 273         AC_MSG_RESULT([none found])
 274 else
 275         DBUS_INT64_TYPE="$dbusint64"
 276         DBUS_HAVE_INT64=1
 277         DBUS_INT64_CONSTANT="$dbusint64_constant"
 278         DBUS_UINT64_CONSTANT="$dbusuint64_constant"
 279         if test x"$dbusint64_printf_modifier" != x; then
 280                 AC_DEFINE_UNQUOTED(DBUS_INT64_PRINTF_MODIFIER, [$dbusint64_printf_modifier], [Define to printf modifier for 64 bit integer type])
 281         fi
 282         AC_MSG_RESULT($DBUS_INT64_TYPE)
 283 fi
 284
 285 AC_SUBST(DBUS_INT64_TYPE)
 286 AC_SUBST(DBUS_INT64_CONSTANT)
 287 AC_SUBST(DBUS_UINT64_CONSTANT)
 288 AC_SUBST(DBUS_HAVE_INT64)
 289
 290 ### see what 32-bit int is called
 291 AC_MSG_CHECKING([32-bit integer type])
 292
 293 case 4 in
 294 $ac_cv_sizeof_short)
 295   dbusint32=short
 296   ;;
 297 $ac_cv_sizeof_int)
 298   dbusint32=int
 299   ;;
 300 $ac_cv_sizeof_long)
 301   dbusint32=long
 302   ;;
 303 esac
 304
 305 if test -z "$dbusint32" ; then
 306         DBUS_INT32_TYPE="no_int32_type_detected"
 307         AC_MSG_ERROR([No 32-bit integer type found])
 308 else
 309         DBUS_INT32_TYPE="$dbusint32"
 310         AC_MSG_RESULT($DBUS_INT32_TYPE)
 311 fi
 312
 313 AC_SUBST(DBUS_INT32_TYPE)
 314
 315 ### see what 16-bit int is called
 316 AC_MSG_CHECKING([16-bit integer type])
 317
 318 case 2 in
 319 $ac_cv_sizeof_short)
 320   dbusint16=short
 321   ;;
 322 $ac_cv_sizeof_int)
 323   dbusint16=int
 324   ;;
 325 esac
 326
 327 if test -z "$dbusint16" ; then
 328         DBUS_INT16_TYPE="no_int16_type_detected"
 329         AC_MSG_ERROR([No 16-bit integer type found])
 330 else
 331         DBUS_INT16_TYPE="$dbusint16"
 332         AC_MSG_RESULT($DBUS_INT16_TYPE)
 333 fi
 334
 335 AC_SUBST(DBUS_INT16_TYPE)
 336
 337 ## byte order
 338 case $host_os in
 339         darwin*)
 340                 # check at compile-time, so that it is possible to build universal
 341                 # (with multiple architectures at once on the compile line)
 342                 AH_VERBATIM([WORDS_BIGENDIAN_DARWIN], [
 343                         /* Use the compiler-provided endianness defines to allow universal compiling. */
 344                         #if defined(__BIG_ENDIAN__)
 345                         #define WORDS_BIGENDIAN 1
 346                         #endif
 347                 ])
 348                 ;;
 349         *)
 350                 AC_C_BIGENDIAN
 351                 ;;
 352 esac
 353
 354 dnl **********************************
 355 dnl *** va_copy checks (from GLib) ***
 356 dnl **********************************
 357 dnl we currently check for all three va_copy possibilities, so we get
 358 dnl all results in config.log for bug reports.
 359 AC_CACHE_CHECK([for an implementation of va_copy()],dbus_cv_va_copy,[
 360         AC_LINK_IFELSE([#include <stdarg.h>
 361 #include <stdlib.h>
 362         static void f (int i, ...) {
 363         va_list args1, args2;
 364         va_start (args1, i);
 365         va_copy (args2, args1);
 366         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 367           exit (1);
 368         va_end (args1); va_end (args2);
 369         }
 370         int main() {
 371           f (0, 42);
 372           return 0;
 373         }],
 374         [dbus_cv_va_copy=yes],
 375         [dbus_cv_va_copy=no])
 376 ])
 377 AC_CACHE_CHECK([for an implementation of __va_copy()],dbus_cv___va_copy,[
 378         AC_LINK_IFELSE([#include <stdarg.h>
 379 #include <stdlib.h>
 380         static void f (int i, ...) {
 381         va_list args1, args2;
 382         va_start (args1, i);
 383         __va_copy (args2, args1);
 384         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 385           exit (1);
 386         va_end (args1); va_end (args2);
 387         }
 388         int main() {
 389           f (0, 42);
 390           return 0;
 391         }],
 392         [dbus_cv___va_copy=yes],
 393         [dbus_cv___va_copy=no])
 394 ])
 395
 396 if test "x$dbus_cv_va_copy" = "xyes"; then
 397   dbus_va_copy_func=va_copy
 398 else if test "x$dbus_cv___va_copy" = "xyes"; then
 399   dbus_va_copy_func=__va_copy
 400 fi
 401 fi
 402
 403 if test -n "$dbus_va_copy_func"; then
 404   AC_DEFINE_UNQUOTED(DBUS_VA_COPY,$dbus_va_copy_func,[A 'va_copy' style function])
 405 fi
 406
 407 AC_LANG_PUSH(C)
 408 AC_CACHE_CHECK([whether va_lists can be copied by value],
 409         dbus_cv_va_val_copy,
 410         [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 411 [[
 412         #include <stdarg.h>
 413         #include <stdlib.h>
 414 ]],
 415 [[
 416         static void f (int i, ...) {
 417         va_list args1, args2;
 418         va_start (args1, i);
 419         args2 = args1;
 420         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 421           exit (1);
 422         va_end (args1); va_end (args2);
 423         }
 424         int main() {
 425           f (0, 42);
 426           return 0;
 427         }
 428 ]])],
 429         [dbus_cv_va_val_copy=yes],
 430         [dbus_cv_va_val_copy=no],
 431         [dbus_cv_va_val_copy=yes])
 432 ])
 433 AC_LANG_POP(C)
 434
 435 if test "x$dbus_cv_va_val_copy" = "xno"; then
 436   AC_DEFINE(DBUS_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 437 fi
 438
 439
 440 #### Atomic integers
 441
 442 AC_CACHE_CHECK([whether $CC knows __sync_sub_and_fetch()],
 443   dbus_cv_sync_sub_and_fetch,
 444   [AC_LINK_IFELSE(
 445      AC_LANG_PROGRAM([], [[int a = 4; int b = __sync_sub_and_fetch(&a, 4); exit(b); ]]),
 446      [dbus_cv_sync_sub_and_fetch=yes],
 447      [dbus_cv_sync_sub_and_fetch=no])
 448   ])
 449
 450 if test "x$dbus_cv_sync_sub_and_fetch" = "xyes" ; then
 451    have_sync=1
 452 else
 453    have_sync=0
 454 fi
 455
 456 AC_DEFINE_UNQUOTED([DBUS_USE_SYNC], [$have_sync], [Use the gcc __sync extension])
 457
 458 #### Various functions
 459 AC_SEARCH_LIBS(socket,[socket network])
 460 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 461
 462 AC_CHECK_FUNCS(vsnprintf vasprintf nanosleep usleep setenv clearenv unsetenv socketpair getgrouplist fpathconf setrlimit poll setlocale localeconv strtoll strtoull)
 463
 464 #### Check for broken poll; taken from Glib's configure
 465
 466 AC_MSG_CHECKING([for broken poll])
 467 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 468     #include <stdlib.h>
 469     #include <fcntl.h>
 470     #include <poll.h>
 471     #ifdef HAVE_SYS_POLL_H
 472     #include <sys/poll.h>
 473     #endif
 474     int main(void) {
 475       struct pollfd fds[1];
 476       int fd;
 477       fd = open("/dev/null", 1);
 478       fds[0].fd = fd;
 479       fds[0].events = POLLIN;
 480       fds[0].revents = 0;
 481       if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 482             exit(1);  /* Does not work for devices -- fail */
 483       }
 484       exit(0);
 485     }]])],
 486   [broken_poll=no],
 487   [broken_poll=yes
 488    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 489   [broken_poll="no (cross compiling)"])
 490 AC_MSG_RESULT($broken_poll)
 491
 492 AC_MSG_CHECKING(for dirfd)
 493 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 494 #include <sys/types.h>
 495 #include <dirent.h>
 496 ]], [[
 497 DIR *dirp;
 498 dirp = opendir(".");
 499 dirfd(dirp);
 500 closedir(dirp);
 501 ]])],
 502 [dbus_have_dirfd=yes],
 503 [dbus_have_dirfd=no])
 504 AC_MSG_RESULT($dbus_have_dirfd)
 505 if test "$dbus_have_dirfd" = yes; then
 506         AC_DEFINE(HAVE_DIRFD,1,[Have dirfd function])
 507 else
 508         AC_MSG_CHECKING(for DIR *dirp->dd_fd)
 509         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 510 #include <sys/types.h>
 511 #include <dirent.h>
 512         ]], [[
 513 DIR *dirp;
 514 int fd;
 515 dirp = opendir(".");
 516 fd = dirp->dd_fd;
 517 closedir(dirp);
 518         ]])],
 519         [dbus_have_ddfd=yes],
 520         [dbus_have_ddfd=no])
 521         AC_MSG_RESULT($dbus_have_ddfd)
 522         if test "$dbus_have_ddfd" = yes; then
 523                 AC_DEFINE(HAVE_DDFD,1,[Have the ddfd member of DIR])
 524         fi
 525 fi
 526
 527 AC_CHECK_HEADERS(sys/resource.h)
 528
 529 AC_CHECK_HEADERS(dirent.h)
 530
 531 AC_CHECK_HEADERS(execinfo.h, [AC_CHECK_FUNCS(backtrace)])
 532
 533 AC_CHECK_HEADERS(errno.h)
 534
 535 AC_CHECK_HEADERS(signal.h)
 536
 537 AC_CHECK_HEADERS(locale.h)
 538
 539 AC_CHECK_HEADERS(byteswap.h)
 540
 541 AC_CHECK_HEADERS(unistd.h)
 542
 543 AC_CHECK_HEADERS(ws2tcpip.h)
 544
 545 AC_CHECK_HEADERS(wspiapi.h)
 546
 547 # Add -D_POSIX_PTHREAD_SEMANTICS if on Solaris
 548 #
 549 case $host_os in
 550     solaris*)
 551        CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS" ;;
 552 esac
 553
 554 # checking for a posix version of getpwnam_r
 555 # if we are cross compiling and can not run the test
 556 # assume getpwnam_r is the posix version
 557 # it is up to the person cross compiling to change
 558 # this behavior if desired
 559 AC_LANG_PUSH(C)
 560 AC_CACHE_CHECK([for posix getpwnam_r],
 561                 ac_cv_func_posix_getpwnam_r,
 562                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 563 [[
 564 #include <errno.h>
 565 #include <pwd.h>
 566 ]],
 567 [[
 568     char buffer[10000];
 569     struct passwd pwd, *pwptr = &pwd;
 570     int error;
 571     errno = 0;
 572     error = getpwnam_r ("", &pwd, buffer,
 573                         sizeof (buffer), &pwptr);
 574    return (error < 0 && errno == ENOSYS)
 575            || error == ENOSYS;
 576 ]])],
 577         [ac_cv_func_posix_getpwnam_r=yes],
 578         [ac_cv_func_posix_getpwnam_r=no],
 579         [ac_cv_func_posix_getpwnam_r=yes]
 580 )])
 581 AC_LANG_POP(C)
 582
 583 if test "$ac_cv_func_posix_getpwnam_r" = yes; then
 584         AC_DEFINE(HAVE_POSIX_GETPWNAM_R,1,
 585                 [Have POSIX function getpwnam_r])
 586 else
 587         AC_CACHE_CHECK([for nonposix getpwnam_r],
 588                 ac_cv_func_nonposix_getpwnam_r,
 589                 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pwd.h>]], [[char buffer[10000];
 590                         struct passwd pwd;
 591                         getpwnam_r ("", &pwd, buffer,
 592                                         sizeof (buffer));]])],
 593                         [ac_cv_func_nonposix_getpwnam_r=yes],
 594                         [ac_cv_func_nonposix_getpwnam_r=no])])
 595                 if test "$ac_cv_func_nonposix_getpwnam_r" = yes; then
 596                 AC_DEFINE(HAVE_NONPOSIX_GETPWNAM_R,1,
 597                         [Have non-POSIX function getpwnam_r])
 598         fi
 599 fi
 600
 601 dnl check for socklen_t
 602 AC_MSG_CHECKING(whether socklen_t is defined)
 603 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 604 #include <sys/types.h>
 605 #include <sys/socket.h>
 606 #include <netdb.h>
 607 ]], [[
 608 socklen_t foo;
 609 foo = 1;
 610 ]])],
 611 [dbus_have_socklen_t=yes],
 612 [dbus_have_socklen_t=no])
 613 AC_MSG_RESULT($dbus_have_socklen_t)
 614
 615 if test "x$dbus_have_socklen_t" = "xyes"; then
 616     AC_DEFINE(HAVE_SOCKLEN_T,1,[Have socklen_t type])
 617 fi
 618
 619 dnl check for writev header and writev function so we're
 620 dnl good to go if HAVE_WRITEV gets defined.
 621 AC_CHECK_HEADERS(sys/uio.h, [AC_CHECK_FUNCS(writev)])
 622
 623 dnl needed on darwin for NAME_MAX
 624 AC_CHECK_HEADERS(sys/syslimits.h)
 625
 626 dnl Make it easy to check if we have MSG_NOSIGNAL without actually having to include sys/socket.h
 627 AC_CHECK_DECLS([MSG_NOSIGNAL], [], [], [[ #include <sys/socket.h> ]])
 628
 629 dnl check for flavours of varargs macros (test from GLib)
 630 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 631 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 632 int a(int p1, int p2, int p3);
 633 #define call_a(...) a(1,__VA_ARGS__)
 634 call_a(2,3);
 635 ]])],
 636 [dbus_have_iso_c_varargs=yes],
 637 [dbus_have_iso_c_varargs=no])
 638 AC_MSG_RESULT($dbus_have_iso_c_varargs)
 639
 640 AC_MSG_CHECKING(for GNUC varargs macros)
 641 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 642 int a(int p1, int p2, int p3);
 643 #define call_a(params...) a(1,params)
 644 call_a(2,3);
 645 ]])],
 646 [dbus_have_gnuc_varargs=yes],
 647 [dbus_have_gnuc_varargs=no])
 648 AC_MSG_RESULT($dbus_have_gnuc_varargs)
 649
 650 dnl Output varargs tests
 651 if test x$dbus_have_iso_c_varargs = xyes; then
 652     AC_DEFINE(HAVE_ISO_VARARGS,1,[Have ISO C99 varargs macros])
 653 fi
 654 if test x$dbus_have_gnuc_varargs = xyes; then
 655     AC_DEFINE(HAVE_GNUC_VARARGS,1,[Have GNU-style varargs macros])
 656 fi
 657
 658 dnl Check for various credentials.
 659 AC_MSG_CHECKING(for struct cmsgcred)
 660 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 661 #include <sys/types.h>
 662 #include <sys/socket.h>
 663 ]], [[
 664 struct cmsgcred cred;
 665
 666 cred.cmcred_pid = 0;
 667 ]])],
 668 [dbus_have_struct_cmsgcred=yes],
 669 [dbus_have_struct_cmsgcred=no])
 670 AC_MSG_RESULT($dbus_have_struct_cmsgcred)
 671
 672 if test x$dbus_have_struct_cmsgcred = xyes; then
 673     AC_DEFINE(HAVE_CMSGCRED,1,[Have cmsgcred structure])
 674 fi
 675
 676 AC_CHECK_FUNCS(getpeerucred getpeereid)
 677
 678 AC_CHECK_FUNCS(pipe2 accept4)
 679
 680 #### Abstract sockets
 681
 682 if test x$enable_abstract_sockets = xauto; then
 683 AC_LANG_PUSH(C)
 684 warn_on_xcompile=no
 685 AC_CACHE_CHECK([abstract socket namespace],
 686                 ac_cv_have_abstract_sockets,
 687                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 688 [[
 689 #include <sys/types.h>
 690 #include <stdlib.h>
 691 #include <string.h>
 692 #include <stdio.h>
 693 #include <sys/socket.h>
 694 #include <sys/un.h>
 695 #include <errno.h>
 696 ]],
 697 [[
 698   size_t slen;
 699   int listen_fd;
 700   struct sockaddr_un addr;
 701
 702   listen_fd = socket (PF_UNIX, SOCK_STREAM, 0);
 703
 704   if (listen_fd < 0)
 705     {
 706       fprintf (stderr, "socket() failed: %s\n", strerror (errno));
 707       exit (1);
 708     }
 709
 710   memset (&addr, '\0', sizeof (addr));
 711   addr.sun_family = AF_UNIX;
 712   strcpy (addr.sun_path, "X/tmp/dbus-fake-socket-path-used-in-configure-test");
 713   /* SUN_LEN uses strlen() so need to calculate it before adding \0 at the
 714    * beginning.
 715    */
 716   slen = SUN_LEN(&addr);
 717   addr.sun_path[0] = '\0'; /* this is what makes it abstract */
 718
 719   if (bind (listen_fd, (struct sockaddr*) &addr, slen) < 0)
 720     {
 721        fprintf (stderr, "Abstract socket namespace bind() failed: %s\n",
 722                 strerror (errno));
 723        exit (1);
 724     }
 725   else
 726     exit (0);
 727 ]])],
 728               [ac_cv_have_abstract_sockets=yes],
 729               [ac_cv_have_abstract_sockets=no],
 730               [
 731                 ac_cv_have_abstract_sockets=no
 732                 warn_on_xcompile=yes
 733               ]
 734 )])
 735 if test x$warn_on_xcompile = xyes ; then
 736   AC_MSG_WARN([Cannot check for abstract sockets when cross-compiling, please use --enable-abstract-sockets])
 737 fi
 738 AC_LANG_POP(C)
 739 fi
 740
 741 if test x$enable_abstract_sockets = xyes; then
 742     if test x$ac_cv_have_abstract_sockets = xno; then
 743         AC_MSG_ERROR([Abstract sockets explicitly required, and support not detected.])
 744     fi
 745 fi
 746
 747 if test x$enable_abstract_sockets = xno; then
 748    ac_cv_have_abstract_sockets=no;
 749 fi
 750
 751 if test x$ac_cv_have_abstract_sockets = xyes ; then
 752    DBUS_PATH_OR_ABSTRACT=abstract
 753    AC_DEFINE(HAVE_ABSTRACT_SOCKETS,1,[Have abstract socket namespace])
 754 else
 755    DBUS_PATH_OR_ABSTRACT=path
 756 fi
 757
 758 # this is used in addresses to prefer abstract, e.g.
 759 # unix:path=/foo or unix:abstract=/foo
 760 AC_SUBST(DBUS_PATH_OR_ABSTRACT)
 761
 762 PKG_PROG_PKG_CONFIG
 763
 764 #### Sort out XML library
 765
 766 # see what we have
 767 AC_CHECK_LIB(expat, XML_ParserCreate_MM,
 768              [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ],
 769              have_expat=false)
 770
 771 # see what we want to use
 772 dbus_use_libxml=false
 773 dbus_use_expat=false
 774 if test x$with_xml = xexpat; then
 775         if ! $have_expat ; then
 776            AC_MSG_ERROR([Explicitly requested expat but expat not found])
 777         fi
 778         dbus_use_expat=true
 779 elif test x$with_xml = xlibxml; then
 780         PKG_CHECK_MODULES(LIBXML, libxml-2.0 >= 2.6.0, have_libxml=true, have_libxml=false)
 781         if ! $have_libxml ; then
 782            AC_MSG_ERROR([Explicitly requested libxml but libxml not found])
 783         fi
 784         dbus_use_libxml=true
 785 else
 786         ### expat is the default because libxml can't currently survive
 787         ### our brutal OOM-handling unit test setup.
 788         ### http://bugzilla.gnome.org/show_bug.cgi?id=109368
 789         if test x$have_expat = xfalse; then
 790                 AC_MSG_ERROR([Could not find expat.h, check config.log for failed attempts])
 791         fi
 792         ### By default, only use Expat since it's tested and known to work.  If you're a
 793         ### general-purpose OS vendor, please don't enable libxml.  For embedded use
 794         ### if your OS is built around libxml, that's another case.
 795         dbus_use_expat=true
 796 fi
 797
 798 AM_CONDITIONAL(DBUS_USE_EXPAT, $dbus_use_expat)
 799 AM_CONDITIONAL(DBUS_USE_LIBXML, $dbus_use_libxml)
 800
 801 if $dbus_use_expat; then
 802    XML_LIBS=-lexpat
 803    XML_CFLAGS=
 804 fi
 805 if $dbus_use_libxml; then
 806    XML_LIBS=$LIBXML_LIBS
 807    XML_CFLAGS=$LIBXML_CFLAGS
 808 fi
 809
 810 # Thread lib detection
 811 AC_CHECK_FUNC(pthread_cond_timedwait,[AC_CHECK_LIB(pthread,pthread_cond_timedwait,
 812                                                     [THREAD_LIBS="-lpthread"])])
 813 save_libs="$LIBS"
 814 LIBS="$LIBS $THREAD_LIBS"
 815 AC_CHECK_FUNC(pthread_condattr_setclock,have_pthread_condattr_setclock=true,have_pthread_condattr_setclock=false)
 816 if test x$have_pthread_condattr_setclock = xtrue; then
 817     AC_SEARCH_LIBS([clock_getres],[rt],[THREAD_LIBS="$THREAD_LIBS -lrt"])
 818     AC_MSG_CHECKING([for CLOCK_MONOTONIC])
 819     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>
 820 #include <pthread.h>
 821 ]], [[
 822 struct timespec monotonic_timer;
 823 pthread_condattr_t attr;
 824 pthread_condattr_init (&attr);
 825 pthread_condattr_setclock (&attr, CLOCK_MONOTONIC);
 826 clock_getres (CLOCK_MONOTONIC,&monotonic_timer);
 827 ]])],
 828 [have_clock_monotonic=true],
 829 [have_clock_monotonic=false])
 830 if test x$have_clock_monotonic = xtrue; then
 831     AC_MSG_RESULT([found])
 832     AC_DEFINE(HAVE_MONOTONIC_CLOCK, 1, [Define if we have CLOCK_MONOTONIC])
 833 else
 834     AC_MSG_RESULT([not found])
 835 fi
 836 fi
 837 LIBS="$save_libs"
 838
 839 # SELinux detection
 840 if test x$enable_selinux = xno ; then
 841     have_selinux=no;
 842 else
 843     # See if we have SELinux library
 844     AC_CHECK_LIB(selinux, is_selinux_enabled,
 845                  have_selinux=yes, have_selinux=no)
 846
 847     # see if we have the SELinux header with the new D-Bus stuff in it
 848     if test x$have_selinux = xyes ; then
 849         AC_MSG_CHECKING([for DBUS Flask permissions in selinux/av_permissions.h])
 850         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <selinux/av_permissions.h>]],
 851                           [[#ifdef DBUS__ACQUIRE_SVC return 0;
 852                             #else
 853                             #error DBUS__ACQUIRE_SVC not defined
 854                             #endif]])],
 855                           [have_selinux=yes],
 856                           [have_selinux=no])
 857         AC_MSG_RESULT($have_selinux)
 858     fi
 859
 860     if test x$enable_selinux = xauto ; then
 861         if test x$have_selinux = xno ; then
 862                 AC_MSG_WARN([Sufficiently new SELinux library not found])
 863         fi
 864     else
 865         if test x$have_selinux = xno ; then
 866                 AC_MSG_ERROR([SElinux explicitly required, and SELinux library not found])
 867         fi
 868     fi
 869 fi
 870
 871 AM_CONDITIONAL(HAVE_SELINUX, test x$have_selinux = xyes)
 872
 873 if test x$have_selinux = xyes ; then
 874     # the selinux code creates threads
 875     # which requires libpthread even on linux
 876     AC_CHECK_FUNC(pthread_create,,[AC_CHECK_LIB(pthread,pthread_create,
 877                                                 [SELINUX_THREAD_LIBS="-lpthread"])])
 878
 879     SELINUX_LIBS="-lselinux $SELINUX_THREAD_LIBS"
 880     AC_DEFINE(HAVE_SELINUX,1,[SELinux support])
 881 else
 882     SELINUX_LIBS=
 883 fi
 884
 885 # inotify checks
 886 if test x$enable_inotify = xno ; then
 887     have_inotify=no;
 888 else
 889     AC_CHECK_HEADERS(sys/inotify.h, have_inotify=yes, have_inotify=no)
 890 fi
 891
 892 dnl check if inotify backend is enabled
 893 if test x$have_inotify = xyes; then
 894    AC_DEFINE(DBUS_BUS_ENABLE_INOTIFY,1,[Use inotify])
 895    AC_CHECK_FUNCS(inotify_init1)
 896 fi
 897
 898 AM_CONDITIONAL(DBUS_BUS_ENABLE_INOTIFY, test x$have_inotify = xyes)
 899
 900 # dnotify checks
 901 if test x$enable_dnotify = xno ; then
 902     have_dnotify=no;
 903 else
 904     if test x$have_inotify = xno -a x$host_os = xlinux-gnu -o x$host_os = xlinux; then
 905         have_dnotify=yes;
 906     else
 907         have_dnotify=no;
 908     fi
 909 fi
 910
 911 dnl check if dnotify backend is enabled
 912 if test x$have_dnotify = xyes; then
 913    AC_DEFINE(DBUS_BUS_ENABLE_DNOTIFY_ON_LINUX,1,[Use dnotify on Linux])
 914 fi
 915
 916 AM_CONDITIONAL(DBUS_BUS_ENABLE_DNOTIFY_ON_LINUX, test x$have_dnotify = xyes)
 917
 918 # kqueue checks
 919 if test x$enable_kqueue = xno ; then
 920     have_kqueue=no
 921 else
 922     have_kqueue=yes
 923     AC_CHECK_HEADER(sys/event.h, , have_kqueue=no)
 924     AC_CHECK_FUNC(kqueue, , have_kqueue=no)
 925
 926     if test x$enable_kqueue = xyes -a x$have_kqueue = xno; then
 927         AC_MSG_ERROR(kqueue support explicitly enabled but not available)
 928     fi
 929 fi
 930
 931 dnl check if kqueue backend is enabled
 932 if test x$have_kqueue = xyes; then
 933    AC_DEFINE(DBUS_BUS_ENABLE_KQUEUE,1,[Use kqueue])
 934 fi
 935
 936 AM_CONDITIONAL(DBUS_BUS_ENABLE_KQUEUE, test x$have_kqueue = xyes)
 937
 938 # launchd checks
 939 if test x$enable_launchd = xno ; then
 940     have_launchd=no
 941 else
 942     have_launchd=yes
 943     AC_CHECK_HEADER([launch.h], , have_launchd=no)
 944     AC_PATH_PROG([LAUNCHCTL], [launchctl])
 945     if test "x$LAUNCHCTL" = "x"; then
 946         have_launchd=no
 947     fi
 948
 949     if test x$enable_launchd = xyes && test x$have_launchd = xno ; then
 950         AC_MSG_ERROR([launchd support explicitly enabled but not available])
 951     fi
 952 fi
 953
 954 dnl check if launchd is enabled
 955 if test x$have_launchd = xyes; then
 956     AC_DEFINE(DBUS_ENABLE_LAUNCHD,1,[Use launchd autolaunch])
 957 fi
 958
 959 AM_CONDITIONAL(DBUS_ENABLE_LAUNCHD, test x$have_launchd = xyes)
 960
 961 #### Directory to place launchd agent file
 962 if test "x$with_launchd_agent_dir" = "x"; then
 963    LAUNCHD_AGENT_DIR="/Library/LaunchAgents"
 964 else
 965    LAUNCHD_AGENT_DIR="$with_launchd_agent_dir"
 966 fi
 967
 968 AC_SUBST(LAUNCHD_AGENT_DIR)
 969
 970 dnl console owner file
 971 if test x$enable_console_owner_file = xno ; then
 972     have_console_owner_file=no;
 973 else
 974     case $host_os in
 975     solaris*)
 976         have_console_owner_file=yes;
 977         AC_DEFINE(HAVE_CONSOLE_OWNER_FILE,1,[Have console owner file])
 978         ;;
 979     *)
 980         have_console_owner_file=no;;
 981     esac
 982 fi
 983
 984 AM_CONDITIONAL(HAVE_CONSOLE_OWNER_FILE, test x$have_console_owner_file = xyes)
 985
 986 # libaudit detection
 987 if test x$enable_libaudit = xno ; then
 988     have_libaudit=no;
 989 else
 990     # See if we have audit daemon & capabilities library
 991     AC_CHECK_LIB(audit, audit_log_user_avc_message,
 992                  have_libaudit=yes, have_libaudit=no)
 993     if test x$have_libaudit = xyes ; then
 994         AC_CHECK_LIB(cap-ng, capng_clear,
 995                  have_libaudit=yes, have_libaudit=no)
 996     fi
 997 fi
 998
 999 AM_CONDITIONAL(HAVE_LIBAUDIT, test x$have_libaudit = xyes)
1000
1001 if test x$have_libaudit = xyes ; then
1002     SELINUX_LIBS="$SELINUX_LIBS -laudit -lcap-ng"
1003     AC_DEFINE(HAVE_LIBAUDIT,1,[audit daemon SELinux support])
1004 fi
1005
1006 # Check for ADT API
1007 AC_MSG_CHECKING(for ADT API)
1008 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1009 #include <bsm/adt.h>
1010 adt_user_context = ADT_USER;
1011 ]], [[]])], [ check_adt_audit=yes ], [ check_adt_audit=no ])
1012
1013 if test ${check_adt_audit} = yes
1014 then
1015    AC_DEFINE([HAVE_ADT], [], [Adt audit API])
1016    ADT_LIBS="-lbsm"
1017    LIBS="-lbsm $LIBS"
1018    AC_MSG_RESULT(yes)
1019 else
1020    AC_MSG_RESULT(no)
1021 fi
1022
1023 # Check for SCM_RIGHTS
1024 AC_MSG_CHECKING([for SCM_RIGHTS])
1025 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1026 #include <sys/socket.h>
1027 #include <sys/un.h>
1028 static int x = SCM_RIGHTS;
1029 ]], [[]])],
1030 [ AC_MSG_RESULT([supported])
1031   AC_DEFINE([HAVE_UNIX_FD_PASSING], [1], [Supports sending UNIX file descriptors]) ],
1032 [ AC_MSG_RESULT([not supported]) ])
1033
1034 NETWORK_libs=
1035 if test x$dbus_win = xyes ; then
1036   if test x$dbus_wince = xyes ; then
1037     NETWORK_libs="-lws2"
1038   else
1039     NETWORK_libs="-lws2_32"
1040   fi
1041 fi
1042
1043 #### Set up final flags
1044 DBUS_CLIENT_CFLAGS=
1045 DBUS_CLIENT_LIBS="$THREAD_LIBS $NETWORK_libs"
1046 AC_SUBST(DBUS_CLIENT_CFLAGS)
1047 AC_SUBST(DBUS_CLIENT_LIBS)
1048
1049 DBUS_BUS_CFLAGS="$XML_CFLAGS"
1050 DBUS_BUS_LIBS="$XML_LIBS $SELINUX_LIBS $THREAD_LIBS $ADT_LIBS $NETWORK_libs"
1051 AC_SUBST(DBUS_BUS_CFLAGS)
1052 AC_SUBST(DBUS_BUS_LIBS)
1053
1054 DBUS_LAUNCHER_CFLAGS="$XML_CFLAGS"
1055 DBUS_LAUNCHER_LIBS="$XML_LIBS $THREAD_LIBS $NETWORK_libs"
1056 AC_SUBST(DBUS_LAUNCHER_CFLAGS)
1057 AC_SUBST(DBUS_LAUNCHER_LIBS)
1058
1059 DBUS_TEST_CFLAGS=
1060 DBUS_TEST_LIBS="$THREAD_LIBS $NETWORK_libs"
1061 AC_SUBST(DBUS_TEST_CFLAGS)
1062 AC_SUBST(DBUS_TEST_LIBS)
1063
1064 ### X11 detection
1065 DBUS_X_LIBS=
1066 DBUS_X_CFLAGS=
1067
1068 AC_ARG_ENABLE([x11-autolaunch],
1069   AS_HELP_STRING([--enable-x11-autolaunch], [build with X11 auto-launch support]),
1070   [], [enable_x11_autolaunch=auto])
1071
1072 if test "x$dbus_win" = xyes; then
1073     if test "x$enable_x11_autolaunch" = xyes; then
1074         AC_MSG_ERROR([X11 auto-launch is not supported on Windows])
1075     fi
1076
1077     enable_x11_autolaunch=no
1078 fi
1079
1080 if test "x$enable_x11_autolaunch" = xno; then
1081     have_x11=no
1082 else
1083     AC_PATH_XTRA
1084
1085     if test "x$no_x" = xyes; then
1086         have_x11=no
1087     else
1088         have_x11=yes
1089         DBUS_X_LIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
1090         DBUS_X_CFLAGS="$X_CFLAGS"
1091     fi
1092 fi
1093
1094 if test "x$enable_x11_autolaunch,$have_x11" = xyes,no; then
1095     AC_MSG_ERROR([X11 auto-launch requires X headers/libraries])
1096 else
1097     # move from "auto" to "yes" or "no" if necessary
1098     enable_x11_autolaunch="$have_x11"
1099 fi
1100
1101 if test "x$enable_x11_autolaunch" = xyes ; then
1102    AC_DEFINE([DBUS_BUILD_X11], [1], [Define to enable X11 auto-launch])
1103 fi
1104
1105 AC_SUBST([DBUS_X_CFLAGS])
1106 AC_SUBST([DBUS_X_LIBS])
1107
1108 #### gcc warning flags
1109
1110 cc_supports_flag() {
1111   AC_MSG_CHECKING(whether $CC supports "$*")
1112   save_CFLAGS="$CFLAGS"
1113   CFLAGS="$*"
1114   AC_TRY_COMPILE([], [], [rc=yes], [rc=no])
1115   CFLAGS="$save_CFLAGS"
1116   AC_MSG_RESULT([$rc])
1117   test "x$rc" = xyes
1118 }
1119
1120 ld_supports_flag() {
1121   AC_MSG_CHECKING([whether $LD supports "$@"])
1122   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1123     int one(void) { return 1; }
1124     int two(void) { return 2; }
1125   ]], [[ two();  ]])],
1126     [_ac_ld_flag_supported=yes],
1127     [_ac_ld_flag_supported=no])
1128
1129   if test "$_ac_ld_flag_supported" = "yes"; then
1130     rm -f conftest.c
1131     touch conftest.c
1132     if $CC -c conftest.c; then
1133       ld_out=`$LD $@ -o conftest conftest.o 2>&1`
1134       ld_ret=$?
1135       if test $ld_ret -ne 0 ; then
1136         _ac_ld_flag_supported=no
1137       elif echo "$ld_out" | egrep 'option ignored|^usage:|unrecognized option|illegal option' >/dev/null ; then
1138         _ac_ld_flag_supported=no
1139       fi
1140     fi
1141     rm -f conftest.c conftest.o conftest
1142   fi
1143
1144   AC_MSG_RESULT($_ac_ld_flag_supported)
1145   if test "$_ac_ld_flag_supported" = "yes" ; then
1146     return 0
1147   else
1148     return 1
1149   fi
1150 }
1151
1152 # Don't bother with -Werror on Windows for now, too many warnings
1153 if test x$dbus_win != xyes -a x$dbus_cygwin != xyes -a x$USE_MAINTAINER_MODE = xyes; then
1154   if cc_supports_flag "-Werror"; then
1155     CFLAGS="$CFLAGS -Werror"
1156   fi
1157 fi
1158
1159 dnl This whole "if" block is in m4 quotes ([]) because it uses them
1160 dnl for character ranges internally. m4 macros cannot be used inside this
1161 dnl block.
1162 [if test "x$GCC" = "xyes"; then
1163   case " $CFLAGS " in
1164   *[\ \ ]-Wall[\ \      ]*) ;;
1165   *) CFLAGS="$CFLAGS -Wall" ;;
1166   esac
1167
1168   case " $CFLAGS " in
1169   *[\ \ ]-Wchar-subscripts[\ \  ]*) ;;
1170   *) CFLAGS="$CFLAGS -Wchar-subscripts" ;;
1171   esac
1172
1173   case " $CFLAGS " in
1174   *[\ \ ]-Wmissing-declarations[\ \     ]*) ;;
1175   *) CFLAGS="$CFLAGS -Wmissing-declarations" ;;
1176   esac
1177
1178   case " $CFLAGS " in
1179   *[\ \ ]-Wmissing-prototypes[\ \       ]*) ;;
1180   *) CFLAGS="$CFLAGS -Wmissing-prototypes" ;;
1181   esac
1182
1183   case " $CFLAGS " in
1184   *[\ \ ]-Wnested-externs[\ \   ]*) ;;
1185   *) CFLAGS="$CFLAGS -Wnested-externs" ;;
1186   esac
1187
1188   case " $CFLAGS " in
1189   *[\ \ ]-Wpointer-arith[\ \    ]*) ;;
1190   *) CFLAGS="$CFLAGS -Wpointer-arith" ;;
1191   esac
1192
1193   case " $CFLAGS " in
1194   *[\ \ ]-Wcast-align[\ \       ]*) ;;
1195   *) CFLAGS="$CFLAGS -Wcast-align" ;;
1196   esac
1197
1198   case " $CFLAGS " in
1199   *[\ \ ]-Wno-address[\ \       ]*) ;;
1200   *) CFLAGS="$CFLAGS -Wno-address" ;;
1201   esac
1202
1203   case " $CFLAGS " in
1204   *[\ \ ]-Wfloat-equal[\ \      ]*) ;;
1205   *) if cc_supports_flag -Wfloat-equal; then
1206         CFLAGS="$CFLAGS -Wfloat-equal"
1207      fi
1208      ;;
1209   esac
1210
1211   case " $CFLAGS " in
1212   *[\ \ ]-Wdeclaration-after-statement[\ \      ]*) ;;
1213   *) if cc_supports_flag -Wdeclaration-after-statement; then
1214         CFLAGS="$CFLAGS -Wdeclaration-after-statement"
1215      fi
1216      ;;
1217   esac
1218
1219   case " $CFLAGS " in
1220   *[\ \ ]-fno-common[\ \        ]*) ;;
1221   *) if cc_supports_flag -fno-common; then
1222         CFLAGS="$CFLAGS -fno-common"
1223      fi
1224      ;;
1225   esac
1226
1227   case " $CFLAGS " in
1228   *[\ \ ]-fPIC[\ \      ]*) ;;
1229   *) if test x$dbus_win = xno && cc_supports_flag -fPIC; then
1230         PIC_CFLAGS="-fPIC"
1231         if ld_supports_flag -z,relro; then
1232            PIC_LDFLAGS="-Wl,-z,relro"
1233         fi
1234      fi
1235      ;;
1236   esac
1237
1238   case " $CFLAGS " in
1239   *[\ \ ]-fPIE[\ \      ]*) ;;
1240   *) if test x$dbus_win = xno && cc_supports_flag -fPIE; then
1241         PIE_CFLAGS="-fPIE"
1242         if ld_supports_flag -z,relro; then
1243            PIE_LDFLAGS="-pie -Wl,-z,relro"
1244         else
1245            PIE_LDFLAGS="-pie"
1246         fi
1247      fi
1248      ;;
1249   esac
1250
1251   ### Disabled warnings, and compiler flag overrides
1252
1253   # Let's just ignore unused for now
1254   case " $CFLAGS " in
1255   *[\ \ ]-Wno-unused[\ \        ]*) ;;
1256   *) CFLAGS="$CFLAGS -Wno-unused" ;;
1257   esac
1258
1259   # This group is for warnings we currently don't pass.
1260   # We would like to, however.  Please fix.
1261
1262   # http://bugs.freedesktop.org/show_bug.cgi?id=17433
1263   case " $CFLAGS " in
1264   *[\ \ ]-Wno-sign-compare[\ \  ]*) ;;
1265   *) CFLAGS="$CFLAGS -Wno-sign-compare" ;;
1266   esac
1267   case " $CFLAGS " in
1268   *[\ \ ]-Wno-pointer-sign[\ \  ]*) ;;
1269   *) if cc_supports_flag -Wno-pointer-sign; then
1270         CFLAGS="$CFLAGS -Wno-pointer-sign"
1271      fi
1272      ;;
1273   esac
1274
1275   # This one is special - it's not a warning override.
1276   # http://bugs.freedesktop.org/show_bug.cgi?id=10599
1277   case " $CFLAGS " in
1278   *[\ \ ]-fno-strict-aliasing[\ \       ]*) ;;
1279   *) CFLAGS="$CFLAGS -fno-strict-aliasing" ;;
1280   esac
1281   ### End disabled warnings
1282
1283   if test "x$enable_ansi" = "xyes"; then
1284     case " $CFLAGS " in
1285     *[\ \       ]-ansi[\ \      ]*) ;;
1286     *) CFLAGS="$CFLAGS -ansi" ;;
1287     esac
1288
1289     case " $CFLAGS " in
1290     *[\ \       ]-D_POSIX_C_SOURCE*) ;;
1291     *) CFLAGS="$CFLAGS -D_POSIX_C_SOURCE=199309L" ;;
1292     esac
1293
1294     case " $CFLAGS " in
1295     *[\ \       ]-D_BSD_SOURCE[\ \      ]*) ;;
1296     *) CFLAGS="$CFLAGS -D_BSD_SOURCE" ;;
1297     esac
1298
1299     case " $CFLAGS " in
1300     *[\ \       ]-pedantic[\ \  ]*) ;;
1301     *) CFLAGS="$CFLAGS -pedantic" ;;
1302     esac
1303   fi
1304 fi]
1305
1306 AC_SUBST(PIC_CFLAGS)
1307 AC_SUBST(PIC_LDFLAGS)
1308 AC_SUBST(PIE_CFLAGS)
1309 AC_SUBST(PIE_LDFLAGS)
1310
1311 if ld_supports_flag --gc-sections; then
1312   SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
1313   CFLAGS="-ffunction-sections -fdata-sections $CFLAGS"
1314 fi
1315 AC_SUBST(SECTION_FLAGS)
1316 AC_SUBST(SECTION_LDFLAGS)
1317 AC_MSG_RESULT($ac_gcsections)
1318
1319 case $host_os in
1320     solaris*)
1321         # Solaris' C library apparently needs these runes to be threadsafe...
1322         CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS -D_REENTRANT"
1323 esac
1324
1325 ### Doxygen Documentation
1326
1327 AC_PATH_PROG(DOXYGEN, doxygen, no)
1328
1329 AC_MSG_CHECKING([whether to build Doxygen documentation])
1330
1331 if test x$DOXYGEN = xno ; then
1332     have_doxygen=no
1333 else
1334     have_doxygen=yes
1335 fi
1336
1337 if test x$enable_doxygen_docs = xauto ; then
1338     if test x$have_doxygen = xno ; then
1339         enable_doxygen_docs=no
1340     else
1341         enable_doxygen_docs=yes
1342     fi
1343 fi
1344
1345 if test x$enable_doxygen_docs = xyes; then
1346     if test x$have_doxygen = xno; then
1347         AC_MSG_ERROR([Building Doxygen docs explicitly required, but Doxygen not found])
1348     fi
1349 fi
1350
1351 AM_CONDITIONAL(DBUS_DOXYGEN_DOCS_ENABLED, test x$enable_doxygen_docs = xyes)
1352 AC_MSG_RESULT($enable_doxygen_docs)
1353
1354 ### XML Documentation
1355
1356 AC_PATH_PROG(XMLTO, xmlto, no)
1357
1358 AC_MSG_CHECKING([whether to build XML documentation])
1359
1360 if test x$XMLTO = xno ; then
1361     have_xmlto=no
1362 else
1363     have_xmlto=yes
1364 fi
1365
1366 if test x$enable_xml_docs = xauto ; then
1367     if test x$have_xmlto = xno ; then
1368         enable_xml_docs=no
1369     else
1370         enable_xml_docs=yes
1371     fi
1372 fi
1373
1374 if test x$enable_xml_docs = xyes; then
1375     if test x$have_xmlto = xno; then
1376         AC_MSG_ERROR([Building XML docs explicitly required, but xmlto not found])
1377     fi
1378 fi
1379
1380 AM_CONDITIONAL(DBUS_XML_DOCS_ENABLED, test x$enable_xml_docs = xyes)
1381 AC_MSG_RESULT($enable_xml_docs)
1382
1383 AC_PATH_PROG([MAN2HTML], [man2html])
1384 AC_ARG_VAR([MAN2HTML], [Path to man2html (optional)])
1385 AM_CONDITIONAL(DBUS_HAVE_MAN2HTML, test x$MAN2HTML != x)
1386
1387 AM_CONDITIONAL(DBUS_CAN_UPLOAD_DOCS,
1388     test x$enable_doxygen_docs = xyes -a x$enable_xml_docs = xyes -a \
1389          x$MAN2HTML != x)
1390
1391 #### Have to go $localstatedir->$prefix/var->/usr/local/var
1392
1393 #### find the actual value for $prefix that we'll end up with
1394 ##   (I know this is broken and should be done in the Makefile, but
1395 ##    that's a major pain and almost nobody actually seems to care)
1396 AS_AC_EXPAND(EXPANDED_PREFIX, "$prefix")
1397 AS_AC_EXPAND(EXPANDED_LOCALSTATEDIR, "$localstatedir")
1398 AS_AC_EXPAND(EXPANDED_SYSCONFDIR, "$sysconfdir")
1399 AS_AC_EXPAND(EXPANDED_BINDIR, "$bindir")
1400 AS_AC_EXPAND(EXPANDED_LIBDIR, "$libdir")
1401 AS_AC_EXPAND(EXPANDED_LIBEXECDIR, "$libexecdir")
1402 AS_AC_EXPAND(EXPANDED_DATADIR, "$datadir")
1403
1404 #### Check our operating system
1405 operating_system=unknown
1406 if test -f /etc/redhat-release || test -f $EXPANDED_SYSCONFDIR/redhat-release ; then
1407    operating_system=redhat
1408 fi
1409
1410 if test -f /etc/slackware-version || test -f $EXPANDED_SYSCONFDIR/slackware-version ; then
1411    operating_system=slackware
1412 fi
1413
1414 if test -f /usr/bin/cygwin1.dll || test -f $EXPANDED_BINDIR/cygwin1.dll ; then
1415    operating_system=cygwin
1416 fi
1417
1418 #### Sort out init scripts
1419
1420 if test x$with_init_scripts = x; then
1421     case x$operating_system in
1422         xredhat)        with_init_scripts=redhat ;;
1423         xslackware)     with_init_scripts=slackware ;;
1424         xcygwin)        with_init_scripts=cygwin ;;
1425         *)                      with_init_scripts=none ;;
1426     esac
1427 fi
1428
1429 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_RED_HAT, test x$with_init_scripts = xredhat)
1430 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_SLACKWARE, test x$with_init_scripts = xslackware)
1431 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_CYGWIN, test x$with_init_scripts = xcygwin)
1432
1433 ##### systemd unit files
1434 AC_ARG_WITH([systemdsystemunitdir],
1435 AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
1436         [], [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
1437 if test "x$with_systemdsystemunitdir" != xno; then
1438    AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
1439 fi
1440 AM_CONDITIONAL(HAVE_SYSTEMD, [test -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ])
1441
1442 ##### Set up location for system bus socket
1443 if ! test -z "$with_system_socket"; then
1444    DBUS_SYSTEM_SOCKET=$with_system_socket
1445 else
1446    DBUS_SYSTEM_SOCKET=${EXPANDED_LOCALSTATEDIR}/run/dbus/system_bus_socket
1447 fi
1448
1449 AC_SUBST(DBUS_SYSTEM_SOCKET)
1450 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_SOCKET,"$DBUS_SYSTEM_SOCKET",[The name of the socket the system bus listens on by default])
1451
1452 ## system bus only listens on local domain sockets, and never
1453 ## on an abstract socket (so only root can create the socket)
1454 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$DBUS_SYSTEM_SOCKET"
1455 AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
1456 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS, "$DBUS_SYSTEM_BUS_DEFAULT_ADDRESS",[The default D-Bus address of the system bus])
1457
1458 #### Set up the pid file
1459 if ! test -z "$with_system_pid_file"; then
1460    DBUS_SYSTEM_PID_FILE=$with_system_pid_file
1461 elif test x$with_init_scripts = xredhat ; then
1462    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/messagebus.pid
1463 else
1464    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/dbus/pid
1465 fi
1466
1467 AC_SUBST(DBUS_SYSTEM_PID_FILE)
1468
1469 #### Directory to check for console ownership
1470 if ! test -z "$with_console_auth_dir"; then
1471    DBUS_CONSOLE_AUTH_DIR=$with_console_auth_dir
1472 else
1473    DBUS_CONSOLE_AUTH_DIR=/var/run/console/
1474 fi
1475
1476 AC_SUBST(DBUS_CONSOLE_AUTH_DIR)
1477 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_AUTH_DIR, "$DBUS_CONSOLE_AUTH_DIR", [Directory to check for console ownerhip])
1478
1479 #### File to check for console ownership
1480 if test x$have_console_owner_file = xyes; then
1481    if ! test -z "$with_console_owner_file"; then
1482       DBUS_CONSOLE_OWNER_FILE=$with_console_owner_file
1483    else
1484       DBUS_CONSOLE_OWNER_FILE=/dev/console
1485    fi
1486 else
1487   DBUS_CONSOLE_OWNER_FILE=
1488 fi
1489
1490 AC_SUBST(DBUS_CONSOLE_OWNER_FILE)
1491 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_OWNER_FILE, "$DBUS_CONSOLE_OWNER_FILE", [File to check for console ownerhip])
1492
1493 #### User to start the system bus as
1494 if test -z "$with_dbus_user" ; then
1495     DBUS_USER=messagebus
1496 else
1497     DBUS_USER=$with_dbus_user
1498 fi
1499 AC_SUBST(DBUS_USER)
1500 AC_DEFINE_UNQUOTED(DBUS_USER,"$DBUS_USER", [User for running the system BUS daemon])
1501
1502 #### Prefix to install into
1503 DBUS_PREFIX=$EXPANDED_PREFIX
1504 AC_SUBST(DBUS_PREFIX)
1505 AC_DEFINE_UNQUOTED(DBUS_PREFIX,"$DBUS_PREFIX", [Prefix for installing DBUS])
1506
1507 #### Direcotry to install data files into
1508 DBUS_DATADIR=$EXPANDED_DATADIR
1509 AC_SUBST(DBUS_DATADIR)
1510 AC_DEFINE_UNQUOTED(DBUS_DATADIR,"$DBUS_DATADIR", [Directory for installing DBUS data files])
1511
1512 #### Directory to install dbus-daemon
1513 if test -z "$with_dbus_daemondir" ; then
1514     DBUS_DAEMONDIR=$EXPANDED_BINDIR
1515 else
1516     DBUS_DAEMONDIR=$with_dbus_daemondir
1517 fi
1518 AC_SUBST(DBUS_DAEMONDIR)
1519 AC_DEFINE_UNQUOTED(DBUS_DAEMONDIR,"$DBUS_DAEMONDIR", [Directory for installing the DBUS daemon])
1520
1521 #### Directory to install the other binaries
1522 DBUS_BINDIR="$EXPANDED_BINDIR"
1523 AC_SUBST(DBUS_BINDIR)
1524 AC_DEFINE_UNQUOTED(DBUS_BINDIR,"$DBUS_BINDIR", [Directory for installing the binaries])
1525
1526 #### Directory to install the libexec binaries
1527 DBUS_LIBEXECDIR="$EXPANDED_LIBEXECDIR"
1528 AC_SUBST(DBUS_LIBEXECDIR)
1529 AC_DEFINE_UNQUOTED(DBUS_LIBEXECDIR,"$DBUS_LIBEXECDIR", [Directory for installing the libexec binaries])
1530
1531 #### Tell tests where to find certain stuff in builddir
1532
1533 DBUS_PWD=`pwd`
1534 # Useful in a cross-compilation environment, where the tests are run on the host system.
1535 AC_ARG_WITH(dbus-test-dir, AS_HELP_STRING([--with-dbus-test-dir=[dirname]],[path where the tests tools are available]),
1536                            DBUS_PWD=$withval)
1537 AC_DEFUN([TEST_PATH], [
1538 TEST_$1=${DBUS_PWD}/test/$2
1539 AC_DEFINE_UNQUOTED(TEST_$1, "$TEST_$1",
1540                    [Full path to test file test/$2 in builddir])
1541 AC_SUBST(TEST_$1)
1542 ])
1543 AC_DEFUN([TEST_PROG], [
1544 TEST_$1=${DBUS_PWD}/test/$2
1545 AC_DEFINE_UNQUOTED(TEST_$1, "$TEST_$1$EXEEXT",
1546                    [Full path to test file test/$2 in builddir])
1547 AC_SUBST(TEST_$1)
1548 ])
1549
1550 TEST_PATH(VALID_SERVICE_DIR, data/valid-service-files)
1551 TEST_PATH(INVALID_SERVICE_DIR, data/invalid-service-files)
1552 TEST_PATH(VALID_SERVICE_SYSTEM_DIR, data/valid-service-files-system)
1553 TEST_PATH(INVALID_SERVICE_SYSTEM_DIR, data/invalid-service-files-system)
1554 TEST_PROG(SERVICE_BINARY, test-service)
1555 TEST_PROG(SHELL_SERVICE_BINARY, test-shell-service)
1556 TEST_PROG(EXIT_BINARY, test-exit)
1557 TEST_PROG(SEGFAULT_BINARY, test-segfault)
1558 TEST_PROG(SLEEP_FOREVER_BINARY, test-sleep-forever)
1559 TEST_PROG(PRIVSERVER_BINARY, name-test/test-privserver)
1560
1561 AC_DEFINE_UNQUOTED(TEST_BUS_BINARY, "$DBUS_PWD/bus/dbus-daemon$EXEEXT",
1562                    [Full path to the daemon in the builddir])
1563 AC_SUBST(TEST_BUS_BINARY)
1564
1565 ## Export the non-setuid external helper
1566 TEST_LAUNCH_HELPER_BINARY="$DBUS_PWD/bus/dbus-daemon-launch-helper-test$EXEEXT"
1567 AC_SUBST(TEST_LAUNCH_HELPER_BINARY)
1568 AC_DEFINE_UNQUOTED(DBUS_TEST_LAUNCH_HELPER_BINARY, "$TEST_LAUNCH_HELPER_BINARY",
1569                    [Full path to the launch helper test program in the builddir])
1570
1571 #### Find socket directories
1572 if ! test -z "$TMPDIR" ; then
1573    DEFAULT_SOCKET_DIR=$TMPDIR
1574 elif ! test -z "$TEMP" ; then
1575    DEFAULT_SOCKET_DIR=$TEMP
1576 elif ! test -z "$TMP" ; then
1577    DEFAULT_SOCKET_DIR=$TMP
1578 else
1579    DEFAULT_SOCKET_DIR=/tmp
1580 fi
1581
1582 DEFAULT_SOCKET_DIR=`echo $DEFAULT_SOCKET_DIR | sed 's/+/%2B/g'`
1583
1584 if ! test -z "$with_test_socket_dir" ; then
1585    TEST_SOCKET_DIR="$with_test_socket_dir"
1586 else
1587    TEST_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1588 fi
1589 AC_SUBST(TEST_SOCKET_DIR)
1590 AC_DEFINE_UNQUOTED(DBUS_TEST_SOCKET_DIR, "$TEST_SOCKET_DIR", [Where to put test sockets])
1591
1592 if ! test -z "$with_session_socket_dir" ; then
1593    DBUS_SESSION_SOCKET_DIR="$with_session_socket_dir"
1594 else
1595    DBUS_SESSION_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1596 fi
1597 AC_DEFINE_UNQUOTED(DBUS_SESSION_SOCKET_DIR, "$DBUS_SESSION_SOCKET_DIR", [Where per-session bus puts its sockets])
1598 AC_SUBST(DBUS_SESSION_SOCKET_DIR)
1599
1600 if test x$dbus_win = xyes; then
1601         DBUS_SESSION_BUS_DEFAULT_ADDRESS="nonce-tcp:"
1602 elif test x$have_launchd = xyes; then
1603         DBUS_SESSION_BUS_DEFAULT_ADDRESS="launchd:env=DBUS_LAUNCHD_SESSION_BUS_SOCKET"
1604 else
1605         DBUS_SESSION_BUS_DEFAULT_ADDRESS="unix:tmpdir=$DBUS_SESSION_SOCKET_DIR"
1606 fi
1607 AC_SUBST(DBUS_SESSION_BUS_DEFAULT_ADDRESS)
1608
1609 # darwin needs this to initialize the environment
1610 AC_CHECK_HEADERS(crt_externs.h)
1611 AC_CHECK_FUNC(_NSGetEnviron, [AC_DEFINE(HAVE_NSGETENVIRON, 1, [Define if your system needs _NSGetEnviron to set up the environment])])
1612 AH_VERBATIM(_DARWIN_ENVIRON,
1613 [
1614 #if defined(HAVE_NSGETENVIRON) && defined(HAVE_CRT_EXTERNS_H)
1615 # include <sys/time.h>
1616 # include <crt_externs.h>
1617 # define environ (*_NSGetEnviron())
1618 #endif
1619 ])
1620
1621 AC_CONFIG_FILES([
1622 Doxyfile
1623 dbus/versioninfo.rc
1624 dbus/dbus-arch-deps.h
1625 bus/system.conf
1626 bus/session.conf
1627 bus/messagebus
1628 bus/messagebus-config
1629 bus/org.freedesktop.dbus-session.plist
1630 bus/rc.messagebus
1631 bus/dbus.service
1632 bus/dbus.socket
1633 Makefile
1634 dbus/Makefile
1635 bus/Makefile
1636 tools/Makefile
1637 test/Makefile
1638 test/name-test/Makefile
1639 doc/Makefile
1640 doc/dbus-daemon.1
1641 dbus-1.pc
1642 test/data/valid-config-files/debug-allow-all.conf
1643 test/data/valid-config-files/debug-allow-all-sha1.conf
1644 test/data/valid-config-files-system/debug-allow-all-pass.conf
1645 test/data/valid-config-files-system/debug-allow-all-fail.conf
1646 test/data/valid-service-files/org.freedesktop.DBus.TestSuite.PrivServer.service
1647 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteEchoService.service
1648 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteForkingEchoService.service
1649 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteSegfaultService.service
1650 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1651 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1652 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteEchoService.service
1653 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteSegfaultService.service
1654 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1655 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1656 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoExec.service
1657 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoUser.service
1658 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoService.service
1659 ])
1660 AC_OUTPUT
1661
1662 dnl ==========================================================================
1663 echo "
1664                     D-Bus $VERSION
1665                   ==============
1666
1667         prefix:                   ${EXPANDED_PREFIX}
1668         exec_prefix:              ${exec_prefix}
1669         libdir:                   ${EXPANDED_LIBDIR}
1670         libexecdir:               ${EXPANDED_LIBEXECDIR}
1671         bindir:                   ${EXPANDED_BINDIR}
1672         sysconfdir:               ${EXPANDED_SYSCONFDIR}
1673         localstatedir:            ${EXPANDED_LOCALSTATEDIR}
1674         datadir:                  ${EXPANDED_DATADIR}
1675         source code location:     ${srcdir}
1676         compiler:                 ${CC}
1677         cflags:                   ${CFLAGS}
1678         cppflags:                 ${CPPFLAGS}
1679         cxxflags:                 ${CXXFLAGS}
1680         64-bit int:               ${DBUS_INT64_TYPE}
1681         32-bit int:               ${DBUS_INT32_TYPE}
1682         16-bit int:               ${DBUS_INT16_TYPE}
1683         Doxygen:                  ${DOXYGEN:-not found}
1684         xmlto:                    ${XMLTO:-not found}
1685         man2html:                 ${MAN2HTML:-not found}"
1686
1687 echo "
1688         Maintainer mode:          ${USE_MAINTAINER_MODE}
1689         gcc coverage profiling:   ${enable_compiler_coverage}
1690         Building unit tests:      ${enable_tests}
1691         Building verbose mode:    ${enable_verbose_mode}
1692         Building assertions:      ${enable_asserts}
1693         Building checks:          ${enable_checks}
1694         Building SELinux support: ${have_selinux}
1695         Building inotify support: ${have_inotify}
1696         Building dnotify support: ${have_dnotify}
1697         Building kqueue support:  ${have_kqueue}
1698         Building X11 code:        ${enable_x11}
1699         Building Doxygen docs:    ${enable_doxygen_docs}
1700         Building XML docs:        ${enable_xml_docs}
1701         Building cache support:   ${enable_userdb_cache}
1702         Building launchd support: ${have_launchd}
1703         Using XML parser:         ${with_xml}
1704         Init scripts style:       ${with_init_scripts}
1705         Abstract socket names:    ${ac_cv_have_abstract_sockets}
1706         System bus socket:        ${DBUS_SYSTEM_SOCKET}
1707         System bus address:       ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
1708         System bus PID file:      ${DBUS_SYSTEM_PID_FILE}
1709         Session bus address:      ${DBUS_SESSION_BUS_DEFAULT_ADDRESS}
1710         Console auth dir:         ${DBUS_CONSOLE_AUTH_DIR}
1711         Console owner file:       ${have_console_owner_file}
1712         Console owner file path:  ${DBUS_CONSOLE_OWNER_FILE}
1713         System bus user:          ${DBUS_USER}
1714         Session bus services dir: ${EXPANDED_DATADIR}/dbus-1/services
1715         'make check' socket dir:  ${TEST_SOCKET_DIR}
1716 "
1717 if test x$have_launchd = xyes; then
1718         echo "        launchd agent dir:        ${LAUNCHD_AGENT_DIR}"
1719 fi
1720 echo
1721
1722 if test x$enable_tests = xyes; then
1723         echo "NOTE: building with unit tests increases the size of the installed library and renders it insecure."
1724 fi
1725 if test x$enable_tests = xyes -a x$enable_asserts = xno; then
1726         echo "NOTE: building with unit tests but without assertions means tests may not properly report failures (this configuration is only useful when doing something like profiling the tests)"
1727 fi
1728 if test x$enable_compiler_coverage = xyes; then
1729         echo "NOTE: building with coverage profiling is definitely for developers only."
1730 fi
1731 if test x$enable_verbose_mode = xyes; then
1732         echo "NOTE: building with verbose mode increases library size, may slightly increase security risk, and decreases performance."
1733 fi
1734 if test x$enable_asserts = xyes; then
1735         echo "NOTE: building with assertions increases library size and decreases performance."
1736 fi
1737 if test x$enable_checks = xno; then
1738         echo "NOTE: building without checks for arguments passed to public API makes it harder to debug apps using D-Bus, but will slightly decrease D-Bus library size and _very_ slightly improve performance."
1739 fi
1740 if test x$dbus_use_libxml = xtrue; then
1741         echo
1742         echo "WARNING: You have chosen to use libxml as your xml parser however this code path is not maintained by the D-Bus developers and if it breaks you get to keep the pieces.  If you have selected this option in err please reconfigure with expat (e.g. --with-xml=expat)."
1743 fi