configure.ac

   1 m4_define([weston_major_version], [1])
   2 m4_define([weston_minor_version], [1])
   3 m4_define([weston_micro_version], [90])
   4 m4_define([weston_version],
   5           [weston_major_version.weston_minor_version.weston_micro_version])
   6
   7 AC_PREREQ([2.64])
   8 AC_INIT([weston],
   9         [weston_version],
  10         [https://bugs.freedesktop.org/enter_bug.cgi?product=Wayland&component=weston&version=weston_version],
  11         [weston],
  12         [http://wayland.freedesktop.org/])
  13
  14 AC_SUBST([WESTON_VERSION_MAJOR], [weston_major_version])
  15 AC_SUBST([WESTON_VERSION_MINOR], [weston_minor_version])
  16 AC_SUBST([WESTON_VERSION_MICRO], [weston_micro_version])
  17 AC_SUBST([WESTON_VERSION], [weston_version])
  18
  19 AC_CONFIG_HEADERS([config.h])
  20
  21 AC_USE_SYSTEM_EXTENSIONS
  22
  23 AM_INIT_AUTOMAKE([1.11 parallel-tests foreign no-dist-gzip dist-xz color-tests])
  24
  25 AM_SILENT_RULES([yes])
  26
  27 # Check for programs
  28 AC_PROG_CC
  29 AC_PROG_SED
  30
  31 # Initialize libtool
  32 LT_PREREQ([2.2])
  33 LT_INIT([disable-static])
  34
  35 AC_ARG_VAR([WESTON_NATIVE_BACKEND],
  36            [Set the native backend to use, if Weston is not running under Wayland nor X11. @<:@default=drm-backend.so@:>@])
  37
  38 PKG_PROG_PKG_CONFIG()
  39
  40 AC_CHECK_FUNC([dlopen], [],
  41               AC_CHECK_LIB([dl], [dlopen], DLOPEN_LIBS="-ldl"))
  42 AC_SUBST(DLOPEN_LIBS)
  43
  44 AC_CHECK_DECL(SFD_CLOEXEC,[],
  45               [AC_MSG_ERROR("SFD_CLOEXEC is needed to compile weston")],
  46               [[#include <sys/signalfd.h>]])
  47 AC_CHECK_DECL(TFD_CLOEXEC,[],
  48               [AC_MSG_ERROR("TFD_CLOEXEC is needed to compile weston")],
  49               [[#include <sys/timerfd.h>]])
  50 AC_CHECK_DECL(CLOCK_MONOTONIC,[],
  51               [AC_MSG_ERROR("CLOCK_MONOTONIC is needed to compile weston")],
  52               [[#include <time.h>]])
  53 AC_CHECK_HEADERS([execinfo.h])
  54
  55 AC_CHECK_FUNCS([mkostemp strchrnul])
  56
  57 COMPOSITOR_MODULES="wayland-server >= 1.1.90 xkbcommon pixman-1"
  58
  59 AC_ARG_ENABLE(egl, [  --disable-egl],,
  60               enable_egl=yes)
  61 AM_CONDITIONAL(ENABLE_EGL, test x$enable_egl = xyes)
  62 if test x$enable_egl = xyes; then
  63         AC_DEFINE([ENABLE_EGL], [1], [Build Weston with EGL support])
  64         COMPOSITOR_MODULES="$COMPOSITOR_MODULES egl >= 7.10 glesv2"
  65 fi
  66
  67 PKG_CHECK_MODULES(COMPOSITOR, [$COMPOSITOR_MODULES])
  68
  69 AC_ARG_ENABLE(setuid-install, [  --enable-setuid-install],,
  70               enable_setuid_install=yes)
  71 AM_CONDITIONAL(ENABLE_SETUID_INSTALL, test x$enable_setuid_install = xyes)
  72
  73
  74 AC_ARG_ENABLE(xwayland, [  --enable-xwayland],,
  75               enable_xwayland=yes)
  76 AC_ARG_ENABLE(xwayland-test, [  --enable-xwayland-test],,
  77               enable_xwayland_test=yes)
  78 AM_CONDITIONAL(ENABLE_XWAYLAND, test x$enable_xwayland = xyes)
  79 AM_CONDITIONAL(ENABLE_XWAYLAND_TEST, test x$enable_xwayland = xyes -a x$enable_xwayland_test = xyes)
  80 if test x$enable_xwayland = xyes; then
  81   PKG_CHECK_MODULES([XWAYLAND], xcb xcb-xfixes xcursor cairo-xcb)
  82   AC_DEFINE([BUILD_XWAYLAND], [1], [Build the X server launcher])
  83
  84   AC_ARG_WITH(xserver-path, AS_HELP_STRING([--with-xserver-path=PATH],
  85               [Path to X server]), [XSERVER_PATH="$withval"],
  86               [XSERVER_PATH="$bindir/Xorg"])
  87   AC_SUBST([XSERVER_PATH])
  88   if test x$enable_xwayland_test = xyes; then
  89     PKG_CHECK_MODULES([XWAYLAND_TEST], xcb xcb-dri2 libdrm)
  90   fi
  91 fi
  92
  93
  94 AC_ARG_ENABLE(x11-compositor, [  --enable-x11-compositor],,
  95               enable_x11_compositor=yes)
  96 AM_CONDITIONAL(ENABLE_X11_COMPOSITOR, test x$enable_x11_compositor = xyes)
  97 if test x$enable_x11_compositor = xyes; then
  98   PKG_CHECK_MODULES([XCB], xcb)
  99   xcb_save_LIBS=$LIBS
 100   xcb_save_CFLAGS=$CFLAGS
 101   CFLAGS=$XCB_CFLAGS
 102   LIBS=$XCB_LIBS
 103   AC_CHECK_FUNCS([xcb_poll_for_queued_event])
 104   LIBS=$xcb_save_LIBS
 105   CFLAGS=$xcb_save_CFLAGS
 106
 107   X11_COMPOSITOR_MODULES="x11 x11-xcb xcb-shm"
 108
 109   PKG_CHECK_MODULES(X11_COMPOSITOR_XKB, [xcb-xkb],
 110                     [have_xcb_xkb="yes"], [have_xcb_xkb="no"])
 111   if test "x$have_xcb_xkb" = xyes; then
 112         # Most versions of XCB have totally broken XKB bindings, where the
 113         # events don't work.  Make sure we can actually use them.
 114         xcb_xkb_save_CFLAGS=$CFLAGS
 115         CFLAGS=$X11_COMPOSITOR_XKB_CFLAGS
 116         AC_CHECK_MEMBER([struct xcb_xkb_state_notify_event_t.xkbType],
 117                         [], [have_xcb_xkb=no], [[#include <xcb/xkb.h>]])
 118         CFLAGS=$xcb_xkb_save_CFLAGS
 119   fi
 120   if test "x$have_xcb_xkb" = xyes; then
 121         X11_COMPOSITOR_MODULES="$X11_COMPOSITOR_MODULES xcb-xkb"
 122         AC_DEFINE([HAVE_XCB_XKB], [1], [libxcb supports XKB protocol])
 123   fi
 124
 125   PKG_CHECK_MODULES(X11_COMPOSITOR, [$X11_COMPOSITOR_MODULES])
 126   AC_DEFINE([BUILD_X11_COMPOSITOR], [1], [Build the X11 compositor])
 127 fi
 128
 129
 130 AC_ARG_ENABLE(drm-compositor, [  --enable-drm-compositor],,
 131               enable_drm_compositor=yes)
 132 AM_CONDITIONAL(ENABLE_DRM_COMPOSITOR, test x$enable_drm_compositor = xyes -a x$enable_egl = xyes)
 133 if test x$enable_drm_compositor = xyes -a x$enable_egl = xyes; then
 134   AC_DEFINE([BUILD_DRM_COMPOSITOR], [1], [Build the DRM compositor])
 135   PKG_CHECK_MODULES(DRM_COMPOSITOR, [libudev >= 136 libdrm >= 2.4.30 gbm mtdev >= 1.1.0])
 136 fi
 137
 138
 139 AC_ARG_ENABLE(wayland-compositor, [  --enable-wayland-compositor],,
 140               enable_wayland_compositor=yes)
 141 AM_CONDITIONAL(ENABLE_WAYLAND_COMPOSITOR,
 142                test x$enable_wayland_compositor = xyes -a x$enable_egl = xyes)
 143 if test x$enable_wayland_compositor = xyes -a x$enable_egl = xyes; then
 144   AC_DEFINE([BUILD_WAYLAND_COMPOSITOR], [1],
 145             [Build the Wayland (nested) compositor])
 146   PKG_CHECK_MODULES(WAYLAND_COMPOSITOR, [wayland-client wayland-egl])
 147 fi
 148
 149
 150 AC_ARG_ENABLE(headless-compositor, [  --enable-headless-compositor],,
 151               enable_headless_compositor=yes)
 152 AM_CONDITIONAL(ENABLE_HEADLESS_COMPOSITOR,
 153                test x$enable_headless_compositor = xyes)
 154
 155
 156 AC_ARG_ENABLE(rpi-compositor,
 157               AS_HELP_STRING([--disable-rpi-compositor],
 158                              [do not build the Raspberry Pi backend]),,
 159               enable_rpi_compositor=yes)
 160 AM_CONDITIONAL(ENABLE_RPI_COMPOSITOR, test "x$enable_rpi_compositor" = "xyes")
 161 have_bcm_host="no"
 162 if test "x$enable_rpi_compositor" = "xyes"; then
 163   AC_DEFINE([BUILD_RPI_COMPOSITOR], [1], [Build the compositor for Raspberry Pi])
 164   PKG_CHECK_MODULES(RPI_COMPOSITOR, [libudev >= 136 mtdev >= 1.1.0])
 165   PKG_CHECK_MODULES(RPI_BCM_HOST, [bcm_host],
 166                     [have_bcm_host="yes"
 167                      AC_DEFINE([HAVE_BCM_HOST], [1], [have Raspberry Pi BCM headers])],
 168                     [AC_MSG_WARN([Raspberry Pi BCM host libraries not found, will use stubs instead.])])
 169 fi
 170 AM_CONDITIONAL(INSTALL_RPI_COMPOSITOR, test "x$have_bcm_host" = "xyes")
 171
 172
 173 AC_ARG_ENABLE([fbdev-compositor], [  --enable-fbdev-compositor],,
 174               enable_fbdev_compositor=yes)
 175 AM_CONDITIONAL([ENABLE_FBDEV_COMPOSITOR],
 176                [test x$enable_fbdev_compositor = xyes])
 177 AS_IF([test x$enable_fbdev_compositor = xyes], [
 178   AC_DEFINE([BUILD_FBDEV_COMPOSITOR], [1], [Build the fbdev compositor])
 179   PKG_CHECK_MODULES([FBDEV_COMPOSITOR], [libudev >= 136 mtdev >= 1.1.0])
 180 ])
 181
 182 AC_ARG_ENABLE([rdp-compositor], [  --enable-rdp-compositor],,
 183               enable_rdp_compositor=no)
 184 AM_CONDITIONAL([ENABLE_RDP_COMPOSITOR],
 185                [test x$enable_rdp_compositor = xyes])
 186 if test x$enable_rdp_compositor = xyes; then
 187   PKG_CHECK_MODULES(RDP_COMPOSITOR, [freerdp >= 1.1.0])
 188 fi
 189
 190 AC_ARG_WITH(cairo-glesv2,
 191             AS_HELP_STRING([--with-cairo-glesv2],
 192                            [Use GLESv2 cairo instead of full GL]))
 193 if test "x$with_cairo_glesv2" = "xyes"; then
 194   cairo_modules="cairo-glesv2"
 195   AC_DEFINE([USE_CAIRO_GLESV2], [1], [Use the GLESv2 GL cairo backend])
 196 else
 197   cairo_modules="cairo-gl"
 198 fi
 199
 200 PKG_CHECK_MODULES(PIXMAN, [pixman-1])
 201 PKG_CHECK_MODULES(PNG, [libpng])
 202 PKG_CHECK_MODULES(WEBP, [libwebp], [have_webp=yes], [have_webp=no])
 203 AS_IF([test "x$have_webp" = "xyes"],
 204       [AC_DEFINE([HAVE_WEBP], [1], [Have webp])])
 205
 206 AC_CHECK_LIB([jpeg], [jpeg_CreateDecompress], have_jpeglib=yes)
 207 if test x$have_jpeglib = xyes; then
 208   JPEG_LIBS="-ljpeg"
 209 else
 210   AC_ERROR([libjpeg not found])
 211 fi
 212 AC_SUBST(JPEG_LIBS)
 213
 214 PKG_CHECK_MODULES(CAIRO, [cairo])
 215
 216 AC_ARG_ENABLE(simple-clients,
 217               AS_HELP_STRING([--disable-simple-clients],
 218                              [do not build the simple wl_shm clients]),,
 219               enable_simple_clients=yes)
 220 AM_CONDITIONAL(BUILD_SIMPLE_CLIENTS, test "x$enable_simple_clients" = "xyes")
 221 if test x$enable_simple_clients = xyes; then
 222   PKG_CHECK_MODULES(SIMPLE_CLIENT, [wayland-client])
 223 fi
 224
 225 AC_ARG_ENABLE(simple-egl-clients,
 226               AS_HELP_STRING([--disable-simple-egl-clients],
 227                              [do not build the simple EGL clients]),,
 228               enable_simple_egl_clients=yes)
 229 AM_CONDITIONAL(BUILD_SIMPLE_EGL_CLIENTS, test "x$enable_simple_egl_clients" = "xyes" -a "x$enable_egl" = "xyes")
 230 if test x$enable_simple_egl_clients = xyes -a x$enable_egl = xyes; then
 231   PKG_CHECK_MODULES(SIMPLE_EGL_CLIENT,
 232                     [egl >= 7.10 glesv2 wayland-client wayland-egl wayland-cursor])
 233 fi
 234
 235 AC_ARG_ENABLE(clients, [  --enable-clients],, enable_clients=yes)
 236 AM_CONDITIONAL(BUILD_CLIENTS, test x$enable_clients = xyes)
 237 if test x$enable_clients = xyes; then
 238   AC_DEFINE([BUILD_CLIENTS], [1], [Build the Wayland clients])
 239
 240   PKG_CHECK_MODULES(CLIENT, [wayland-client cairo >= 1.10.0 xkbcommon wayland-cursor])
 241   PKG_CHECK_MODULES(SERVER, [wayland-server])
 242   PKG_CHECK_MODULES(WESTON_INFO, [wayland-client])
 243
 244   PKG_CHECK_MODULES(POPPLER, [poppler-glib glib-2.0 gobject-2.0 gio-2.0 ],
 245                              [have_poppler=yes], [have_poppler=no])
 246   PKG_CHECK_MODULES(CAIRO_EGL, [wayland-egl egl >= 7.10 cairo-egl >= 1.11.3 $cairo_modules],
 247                     [have_cairo_egl=yes], [have_cairo_egl=no])
 248   AS_IF([test "x$have_cairo_egl" = "xyes"],
 249         [AC_DEFINE([HAVE_CAIRO_EGL], [1], [Have cairo-egl])],
 250         [AC_MSG_WARN([clients will use cairo image, cairo-egl not used because $CAIRO_EGL_PKG_ERRORS])])
 251   PKG_CHECK_MODULES(PANGO, [pangocairo], [have_pango=yes], [have_pango=no])
 252 fi
 253
 254 AC_ARG_ENABLE(resize-optimization,
 255               AS_HELP_STRING([--disable-resize-optimization],
 256                              [disable resize optimization allocating a big buffer in toytoolkit]),,
 257               enable_resize_optimization=yes)
 258 AS_IF([test "x$enable_resize_optimization" = "xyes"],
 259       [AC_DEFINE([USE_RESIZE_POOL], [1], [Use resize memory pool as a performance optimization])])
 260
 261 AC_ARG_ENABLE(weston-launch, [  --enable-weston-launch],, enable_weston_launch=yes)
 262 AM_CONDITIONAL(BUILD_WESTON_LAUNCH, test x$enable_weston_launch == xyes)
 263 if test x$enable_weston_launch == xyes; then
 264   PKG_CHECK_MODULES(WESTON_LAUNCH, [libdrm])
 265   PKG_CHECK_MODULES(SYSTEMD_LOGIN, [libsystemd-login],
 266                     [have_systemd_login=yes], [have_systemd_login=no])
 267   AS_IF([test "x$have_systemd_login" = "xyes"],
 268         [AC_DEFINE([HAVE_SYSTEMD_LOGIN], [1], [Have systemd-login])])
 269
 270   AC_CHECK_LIB([pam], [pam_open_session], [have_pam=yes], [have_pam=no])
 271   if test x$have_pam == xno; then
 272     AC_ERROR([weston-launch requires pam])
 273   fi
 274   WESTON_LAUNCH_LIBS="$WESTON_LAUNCH_LIBS -lpam"
 275 fi
 276
 277 if test x$enable_egl = xyes; then
 278   PKG_CHECK_MODULES(GLU, [glu], [have_glu=yes], [have_glu=no])
 279 fi
 280 AM_CONDITIONAL(HAVE_GLU, test "x$have_glu" = "xyes")
 281
 282
 283 AM_CONDITIONAL(HAVE_POPPLER, test "x$have_poppler" = "xyes")
 284
 285 AM_CONDITIONAL(HAVE_PANGO, test "x$have_pango" = "xyes")
 286
 287 AM_CONDITIONAL(HAVE_CAIRO_GLESV2,
 288                [test "x$have_cairo_egl" = "xyes" -a "x$cairo_modules" = "xcairo-glesv2" -a "x$enable_egl" = "xyes"])
 289
 290 AM_CONDITIONAL(BUILD_FULL_GL_CLIENTS,
 291                test x$cairo_modules = "xcairo-gl" -a "x$have_cairo_egl" = "xyes" -a "x$enable_egl" = "xyes")
 292
 293 AM_CONDITIONAL(BUILD_SUBSURFACES_CLIENT,
 294                [test '(' "x$have_cairo_egl" != "xyes" -o "x$cairo_modules" = "xcairo-glesv2" ')' -a "x$enable_simple_egl_clients" = "xyes"])
 295
 296 AM_CONDITIONAL(ENABLE_DESKTOP_SHELL, true)
 297
 298 AC_ARG_ENABLE(tablet-shell,
 299               AS_HELP_STRING([--disable-tablet-shell],
 300                              [do not build tablet-shell server plugin and client]),,
 301               enable_tablet_shell=yes)
 302 AM_CONDITIONAL(ENABLE_TABLET_SHELL,
 303                test "x$enable_tablet_shell" = "xyes")
 304
 305 # CMS modules
 306 AC_ARG_ENABLE(colord,
 307               AS_HELP_STRING([--disable-colord],
 308                              [do not build colord CMS support]),,
 309               enable_colord=auto)
 310 AM_CONDITIONAL(ENABLE_COLORD, test "x$enable_colord" = "xyes")
 311 if test "x$enable_colord" != "xno"; then
 312         PKG_CHECK_MODULES(COLORD,
 313                           colord >= 0.1.27,
 314                           have_colord=yes,
 315                           have_colord=no)
 316         if test "x$have_colord" = "xno" -a "x$enable_colord" = "xyes"; then
 317           AC_MSG_ERROR([colord support explicitly requested, but colord couldn't be found])
 318         fi
 319         if test "x$have_colord" = "xyes"; then
 320              enable_colord=yes
 321         fi
 322 fi
 323
 324 AC_ARG_ENABLE(wcap-tools, [  --disable-wcap-tools],, enable_wcap_tools=yes)
 325 AM_CONDITIONAL(BUILD_WCAP_TOOLS, test x$enable_wcap_tools = xyes)
 326 if test x$enable_wcap_tools = xyes; then
 327   AC_DEFINE([BUILD_WCAP_TOOLS], [1], [Build the wcap tools])
 328   PKG_CHECK_MODULES(WCAP, [cairo])
 329   WCAP_LIBS="$WCAP_LIBS -lm"
 330 fi
 331
 332 AC_CHECK_PROG(RSVG_CONVERT, rsvg-convert, rsvg-convert)
 333 AM_CONDITIONAL(HAVE_RSVG_CONVERT, test -n "$RSVG_CONVERT")
 334
 335 PKG_CHECK_MODULES(SETBACKLIGHT, [libudev libdrm], enable_setbacklight=yes, enable_setbacklight=no)
 336 AM_CONDITIONAL(BUILD_SETBACKLIGHT, test "x$enable_setbacklight" = "xyes")
 337
 338 if test "x$GCC" = "xyes"; then
 339         GCC_CFLAGS="-Wall -Wextra -Wno-unused-parameter \
 340                 -Wno-missing-field-initializers -g -fvisibility=hidden \
 341                 -Wstrict-prototypes -Wmissing-prototypes"
 342 fi
 343 AC_SUBST(GCC_CFLAGS)
 344
 345 AC_ARG_ENABLE(libunwind,
 346               AS_HELP_STRING([--disable-libunwind],
 347                              [Disable libunwind usage for backtraces]),,
 348               enable_libunwind=auto)
 349 AM_CONDITIONAL(HAVE_LIBUNWIND, [test "x$enable_libunwind" = xyes])
 350 if test "x$enable_libunwind" != "xno"; then
 351         PKG_CHECK_MODULES(LIBUNWIND,
 352                           libunwind,
 353                           have_libunwind=yes,
 354                           have_libunwind=no)
 355         if test "x$have_libunwind" = "xno" -a "x$enable_libunwind" = "xyes"; then
 356           AC_MSG_ERROR([libunwind support explicitly requested, but libunwind couldn't be found])
 357         fi
 358         if test "x$have_libunwind" = "xyes"; then
 359              enable_libunwind=yes
 360              AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
 361         fi
 362 fi
 363
 364
 365 if test "x$WESTON_NATIVE_BACKEND" = "x"; then
 366         WESTON_NATIVE_BACKEND="drm-backend.so"
 367 fi
 368 AC_MSG_NOTICE([Weston's native backend: $WESTON_NATIVE_BACKEND])
 369 AC_DEFINE_UNQUOTED([WESTON_NATIVE_BACKEND], ["$WESTON_NATIVE_BACKEND"],
 370                    [The default backend to load, if not wayland nor x11.])
 371
 372 PKG_CHECK_MODULES(LCMS, lcms2,
 373                   [have_lcms=yes], [have_lcms=no])
 374 if test "x$have_lcms" = xyes; then
 375        AC_DEFINE(HAVE_LCMS, 1, [Have lcms support])
 376 fi
 377 AM_CONDITIONAL(HAVE_LCMS, [test "x$have_lcms" = xyes])
 378
 379 WAYLAND_SCANNER_RULES(['$(top_srcdir)/protocol'])
 380
 381 AC_CONFIG_FILES([Makefile
 382                  shared/Makefile
 383                  src/Makefile
 384                  src/xwayland/Makefile
 385                  src/version.h
 386                  src/weston.pc
 387                  clients/Makefile
 388                  wcap/Makefile
 389                  data/Makefile
 390                  protocol/Makefile
 391                  man/Makefile
 392                  tests/Makefile])
 393 AC_OUTPUT