configure.ac

   1 dnl  Copyright 2005 Red Hat, Inc.
   2 dnl
   3 dnl  Permission to use, copy, modify, distribute, and sell this software and its
   4 dnl  documentation for any purpose is hereby granted without fee, provided that
   5 dnl  the above copyright notice appear in all copies and that both that
   6 dnl  copyright notice and this permission notice appear in supporting
   7 dnl  documentation, and that the name of Red Hat not be used in
   8 dnl  advertising or publicity pertaining to distribution of the software without
   9 dnl  specific, written prior permission.  Red Hat makes no
  10 dnl  representations about the suitability of this software for any purpose.  It
  11 dnl  is provided "as is" without express or implied warranty.
  12 dnl
  13 dnl  RED HAT DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
  14 dnl  INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
  15 dnl  EVENT SHALL RED HAT BE LIABLE FOR ANY SPECIAL, INDIRECT OR
  16 dnl  CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
  17 dnl  DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
  18 dnl  TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
  19 dnl  PERFORMANCE OF THIS SOFTWARE.
  20 dnl
  21 dnl Process this file with autoconf to create configure.
  22
  23 AC_PREREQ([2.57])
  24
  25 #   Pixman versioning scheme
  26 #
  27 #   - The version in git has an odd MICRO version number
  28 #
  29 #   - Released versions both development and stable have an even MICRO
  30 #     version number
  31 #
  32 #   - Released development versions have an odd MINOR number
  33 #
  34 #   - Released stable versions have an event MINOR number
  35 #
  36 #   - Versions that break ABI must have a new MAJOR number
  37 #
  38 #   - If you break the ABI, then at least this must be done:
  39 #
  40 #        - increment MAJOR
  41 #
  42 #        - In the first development release where you break ABI, find
  43 #          all instances of "pixman-n" and change them to pixman-(n+1)
  44 #
  45 #          This needs to be done at least in
  46 #                    configure.ac
  47 #                    all Makefile.am's
  48 #                    pixman-n.pc.in
  49 #
  50 #      This ensures that binary incompatible versions can be installed
  51 #      in parallel.  See http://www106.pair.com/rhp/parallel.html for
  52 #      more information
  53 #
  54
  55 m4_define([pixman_major], 0)
  56 m4_define([pixman_minor], 13)
  57 m4_define([pixman_micro], 3)
  58
  59 m4_define([pixman_version],[pixman_major.pixman_minor.pixman_micro])
  60
  61 AC_INIT(pixman, pixman_version, "sandmann@daimi.au.dk", pixman)
  62 AM_INIT_AUTOMAKE([dist-bzip2])
  63
  64 AM_CONFIG_HEADER(config.h)
  65
  66 AC_PROG_CC
  67 AC_PROG_LIBTOOL
  68 AC_CHECK_FUNCS([getisax])
  69 AC_C_BIGENDIAN
  70 AC_C_INLINE
  71 #
  72 # We ignore pixman_major in the version here because the major version should
  73 # always be encoded in the actual library name. Ie., the soname is:
  74 #
  75 #      pixman-$(pixman_major).0.minor.micro
  76 #
  77 m4_define([lt_current], [pixman_minor])
  78 m4_define([lt_revision], [pixman_micro])
  79 m4_define([lt_age], [pixman_minor])
  80
  81 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
  82
  83 PIXMAN_VERSION_MAJOR=pixman_major()
  84 AC_SUBST(PIXMAN_VERSION_MAJOR)
  85 PIXMAN_VERSION_MINOR=pixman_minor()
  86 AC_SUBST(PIXMAN_VERSION_MINOR)
  87 PIXMAN_VERSION_MICRO=pixman_micro()
  88 AC_SUBST(PIXMAN_VERSION_MICRO)
  89
  90 AC_SUBST(LT_VERSION_INFO)
  91
  92 # Check for dependencies
  93 #PKG_CHECK_MODULES(DEP, x11)
  94
  95 changequote(,)dnl
  96 if test "x$GCC" = "xyes"; then
  97   case " $CFLAGS " in
  98   *[\ \ ]-Wall[\ \      ]*) ;;
  99   *) CFLAGS="$CFLAGS -Wall" ;;
 100   esac fi changequote([,])dnl
 101
 102 AC_PATH_PROG(PERL, perl, no)
 103 if test "x$PERL" = xno; then
 104     AC_MSG_ERROR([Perl is required to build pixman.])
 105 fi
 106 AC_SUBST(PERL)
 107
 108 dnl =========================================================================
 109 dnl -fvisibility stuff
 110
 111 have_gcc4=no
 112 AC_MSG_CHECKING(for -fvisibility)
 113 AC_COMPILE_IFELSE([
 114 #if defined(__GNUC__) && (__GNUC__ >= 4)
 115 #else
 116 error Need GCC 4.0 for visibility
 117 #endif
 118 int main () { return 0; }
 119 ], have_gcc4=yes)
 120
 121 if test "x$have_gcc4" = "xyes"; then
 122    CFLAGS="$CFLAGS -fvisibility=hidden"
 123 fi
 124 AC_MSG_RESULT($have_gcc4)
 125
 126 have_sunstudio8=no
 127 AC_MSG_CHECKING([for -xldscope (Sun compilers)])
 128 AC_COMPILE_IFELSE([
 129 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
 130 #else
 131 error Need Sun Studio 8 for visibility
 132 #endif
 133 int main () { return 0; }
 134 ], have_sunstudio8=yes)
 135
 136 if test "x$have_sunstudio8" = "xyes"; then
 137    CFLAGS="$CFLAGS -xldscope=hidden"
 138 fi
 139 AC_MSG_RESULT($have_sunstudio8)
 140
 141 dnl ===========================================================================
 142 dnl Check for MMX
 143
 144 MMX_CFLAGS="-mmmx -Winline"
 145
 146 have_mmx_intrinsics=no
 147 AC_MSG_CHECKING(whether to use MMX intrinsics)
 148 xserver_save_CFLAGS=$CFLAGS
 149 CFLAGS="$CFLAGS $MMX_CFLAGS"
 150 AC_COMPILE_IFELSE([
 151 #if defined(__GNUC__) && (__GNUC__ < 3 || (__GNUC__ == 3 && __GNUC_MINOR__ < 4))
 152 error "Need GCC >= 3.4 for MMX intrinsics"
 153 #endif
 154 #include <mmintrin.h>
 155 int main () {
 156     __m64 v = _mm_cvtsi32_si64 (1);
 157     return _mm_cvtsi64_si32 (v);
 158 }], have_mmx_intrinsics=yes)
 159 CFLAGS=$xserver_save_CFLAGS
 160
 161 AC_ARG_ENABLE(mmx,
 162    [AC_HELP_STRING([--disable-mmx],
 163                    [disable MMX fast paths])],
 164    [enable_mmx=$enableval], [enable_mmx=auto])
 165
 166 if test $enable_mmx = no ; then
 167    have_mmx_intrinsics=disabled
 168 fi
 169
 170 if test $have_mmx_intrinsics = yes ; then
 171    AC_DEFINE(USE_MMX, 1, [use MMX compiler intrinsics])
 172 else
 173    MMX_CFLAGS=
 174 fi
 175
 176 AC_MSG_RESULT($have_mmx_intrinsics)
 177 if test $enable_mmx = yes && test $have_mmx_intrinsics = no ; then
 178    AC_MSG_ERROR([MMX intrinsics not detected])
 179 fi
 180
 181 AM_CONDITIONAL(USE_MMX, test $have_mmx_intrinsics = yes)
 182
 183 dnl ===========================================================================
 184 dnl Check for SSE2
 185
 186 SSE2_CFLAGS="-mmmx -msse2 -Winline"
 187
 188 have_sse2_intrinsics=no
 189 AC_MSG_CHECKING(whether to use SSE2 intrinsics)
 190 xserver_save_CFLAGS=$CFLAGS
 191 CFLAGS="$CFLAGS -msse2 $SSE2_CFLAGS"
 192
 193 AC_COMPILE_IFELSE([
 194 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 2))
 195 #   if !defined(__amd64__) && !defined(__x86_64__)
 196 #      error "Need GCC >= 4.2 for SSE2 intrinsics on x86"
 197 #   endif
 198 #endif
 199 #include <mmintrin.h>
 200 #include <xmmintrin.h>
 201 #include <emmintrin.h>
 202 int main () {
 203     __m128i a, b, c;
 204         c = _mm_xor_si128 (a, b);
 205     return 0;
 206 }], have_sse2_intrinsics=yes)
 207 CFLAGS=$xserver_save_CFLAGS
 208
 209 AC_ARG_ENABLE(sse2,
 210    [AC_HELP_STRING([--disable-sse2],
 211                    [disable SSE2 fast paths])],
 212    [enable_sse2=$enableval], [enable_sse2=auto])
 213
 214 if test $enable_sse2 = no ; then
 215    have_sse2_intrinsics=disabled
 216 fi
 217
 218 if test $have_sse2_intrinsics = yes ; then
 219    AC_DEFINE(USE_SSE2, 1, [use SSE2 compiler intrinsics])
 220 fi
 221
 222 AC_MSG_RESULT($have_sse2_intrinsics)
 223 if test $enable_sse2 = yes && test $have_sse2_intrinsics = no ; then
 224    AC_MSG_ERROR([SSE2 intrinsics not detected])
 225 fi
 226
 227 AM_CONDITIONAL(USE_SSE2, test $have_sse2_intrinsics = yes)
 228
 229 dnl ========================================================
 230 AC_SUBST(MMX_CFLAGS)
 231 AC_SUBST(SSE2_CFLAGS)
 232
 233 dnl Check for VMX/Altivec
 234 if test -n "`$CC -v 2>&1 | grep version | grep Apple`"; then
 235     VMX_CFLAGS="-faltivec"
 236 else
 237     VMX_CFLAGS="-maltivec -mabi=altivec"
 238 fi
 239
 240 have_vmx_intrinsics=no
 241 AC_MSG_CHECKING(whether to use VMX/Altivec intrinsics)
 242 xserver_save_CFLAGS=$CFLAGS
 243 CFLAGS="$CFLAGS $VMX_CFLAGS"
 244 AC_COMPILE_IFELSE([
 245 #if defined(__GNUC__) && (__GNUC__ < 3 || (__GNUC__ == 3 && __GNUC_MINOR__ < 4))
 246 error "Need GCC >= 3.4 for sane altivec support"
 247 #endif
 248 #include <altivec.h>
 249 int main () {
 250     vector unsigned int v = vec_splat_u32 (1);
 251     v = vec_sub (v, v);
 252     return 0;
 253 }], have_vmx_intrinsics=yes)
 254 CFLAGS=$xserver_save_CFLAGS
 255
 256 AC_ARG_ENABLE(vmx,
 257    [AC_HELP_STRING([--disable-vmx],
 258                    [disable VMX fast paths])],
 259    [enable_vmx=$enableval], [enable_vmx=auto])
 260
 261 if test $enable_vmx = no ; then
 262    have_vmx_intrinsics=disabled
 263 fi
 264
 265 if test $have_vmx_intrinsics = yes ; then
 266    AC_DEFINE(USE_VMX, 1, [use VMX compiler intrinsics])
 267 else
 268    VMX_CFLAGS=
 269 fi
 270
 271 AC_MSG_RESULT($have_vmx_intrinsics)
 272 if test $enable_vmx = yes && test $have_vmx_intrinsics = no ; then
 273    AC_MSG_ERROR([VMX intrinsics not detected])
 274 fi
 275
 276 AC_SUBST(VMX_CFLAGS)
 277
 278 AM_CONDITIONAL(USE_VMX, test $have_vmx_intrinsics = yes)
 279
 280 dnl Check for ARM SIMD instructions
 281
 282 have_arm_simd=no
 283 AC_MSG_CHECKING(whether to use ARM SIMD assembler)
 284 xserver_save_CFLAGS=$CFLAGS
 285 CFLAGS="$CFLAGS $ARM_CFLAGS"
 286 AC_COMPILE_IFELSE([
 287 int main () {
 288     asm("uqadd8 r1, r1, r2");
 289     return 0;
 290 }], have_arm_simd=yes)
 291 CFLAGS=$xserver_save_CFLAGS
 292
 293 AC_ARG_ENABLE(arm-simd,
 294    [AC_HELP_STRING([--disable-arm-simd],
 295                    [disable ARM SIMD fast paths])],
 296    [enable_arm_simd=$enableval], [enable_arm_simd=auto])
 297
 298 if test $enable_arm_simd = no ; then
 299    have_arm_simd=disabled
 300 fi
 301
 302 if test $have_arm_simd = yes ; then
 303    AC_DEFINE(USE_ARM_SIMD, 1, [use ARM SIMD compiler intrinsics])
 304 else
 305    ARM_CFLAGS=
 306 fi
 307
 308 AC_MSG_RESULT($have_arm_simd)
 309 if test $enable_arm_simd = yes && test $have_arm_simd = no ; then
 310    AC_MSG_ERROR([ARM SIMD intrinsics not detected])
 311 fi
 312
 313 AC_SUBST(ARM_CFLAGS)
 314
 315 AM_CONDITIONAL(USE_ARM_SIMD, test $have_arm_simd = yes)
 316
 317
 318 AC_ARG_ENABLE(gtk,
 319    [AC_HELP_STRING([--enable-gtk],
 320                    [enable tests using GTK+ [default=auto]])],
 321    [enable_gtk=$enableval], [enable_gtk=auto])
 322
 323 PKG_PROG_PKG_CONFIG
 324 if test $enable_gtk = auto ; then
 325    PKG_CHECK_EXISTS([gtk+-2.0], [enable_gtk=yes], [enable_gtk=no])
 326 fi
 327 if test $enable_gtk = yes ; then
 328    PKG_CHECK_MODULES(GTK, [gtk+-2.0])
 329 fi
 330
 331 AM_CONDITIONAL(HAVE_GTK, [test "x$enable_gtk" = xyes])
 332
 333 AC_SUBST(GTK_CFLAGS)
 334 AC_SUBST(GTK_LIBS)
 335 AC_SUBST(DEP_CFLAGS)
 336 AC_SUBST(DEP_LIBS)
 337
 338 AC_OUTPUT([pixman-1.pc
 339            pixman-1-uninstalled.pc
 340            Makefile
 341            pixman/Makefile
 342            pixman/pixman-version.h
 343            test/Makefile])