configure.ac

   1 AC_PREREQ(2.61)
   2 AC_INIT(rpm, 4.10.90, rpm-maint@lists.rpm.org)
   3
   4 AC_CONFIG_SRCDIR([rpmqv.c])
   5 AC_CONFIG_HEADERS([config.h])
   6 AC_CONFIG_MACRO_DIR([m4])
   7
   8 AM_INIT_AUTOMAKE([1.10 foreign tar-ustar dist-bzip2 subdir-objects nostdinc])
   9 dnl Allow silent build on automake versions that support it
  10 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
  11
  12 AC_CONFIG_TESTDIR(tests)
  13
  14 AC_USE_SYSTEM_EXTENSIONS
  15
  16 AC_DISABLE_STATIC
  17
  18 PKG_PROG_PKG_CONFIG
  19
  20 dnl Checks for programs.
  21 AC_PROG_CXX
  22 AC_PROG_AWK
  23 AC_PROG_CC
  24 AC_PROG_CPP
  25 AC_PROG_INSTALL
  26 AC_PROG_LN_S
  27 AC_PROG_MAKE_SET
  28 AC_PROG_LIBTOOL
  29 AC_PROG_YACC
  30
  31 AC_SUBST(__CC, $CC)
  32 AC_PROG_CC_C99
  33 if test "$ac_cv_prog_cc_c99" = no; then
  34     AC_MSG_ERROR([ISO C99 capable compiler required])
  35 fi
  36
  37 AS=${AS-as}
  38 AC_SUBST(AS)
  39 if test "$GCC" = yes; then
  40     CFLAGS="$CFLAGS -fPIC -DPIC -D_REENTRANT -Wall -Wpointer-arith -Wmissing-prototypes -Wstrict-prototypes"
  41     cflags_to_try="-fno-strict-aliasing -fstack-protector -Wempty-body"
  42     AC_MSG_CHECKING([supported compiler flags])
  43     old_cflags=$CFLAGS
  44     echo
  45     for flag in $cflags_to_try; do
  46         CFLAGS="$CFLAGS $flag"
  47         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0;]])],[
  48                 echo "   $flag"
  49                 RPMCFLAGS="$RPMCFLAGS $flag"
  50         ],[])
  51         CFLAGS=$old_cflags
  52     done
  53     CFLAGS="$CFLAGS $RPMCFLAGS"
  54 fi
  55 export CFLAGS
  56
  57 AC_SYS_LARGEFILE
  58
  59 dnl
  60 dnl look for POSIX chmod attributes
  61 dnl
  62 AC_MSG_CHECKING(POSIX chmod)
  63 touch foo.chmodtest
  64 chmod 744 foo.chmodtest
  65 chmod +X foo.chmodtest 2>/dev/null
  66 a=`ls -l foo.chmodtest | awk '{print substr($1,1,10)}'`
  67 rm -f foo.chmodtest
  68 if test "$a" = "-rwxr-xr-x"; then
  69     AC_MSG_RESULT(yes)
  70     FIXPERMS=a+rX,u+w,g-w,o-w
  71 else
  72     AC_MSG_RESULT(no (tell your OS vendor about GNU fileutils))
  73     FIXPERMS=a+r,u+w,g-w,o-w
  74 fi
  75 AC_SUBST(FIXPERMS)
  76
  77 dnl AM_DISABLE_SHARED
  78 AM_PROG_LIBTOOL
  79
  80 AC_CHECK_TOOL(AR, ar, :)
  81
  82 dnl
  83 dnl use defaults if cross-compiling, otherwise use the default path.
  84 dnl
  85 if test "$cross_compiling" = "yes"; then
  86     MYPATH=":"
  87 else
  88     MYPATH=$PATH
  89 fi
  90
  91 dnl
  92 dnl Find some common programs
  93 dnl
  94 AC_PATH_PROG(__7ZIP, 7zip, /usr/bin/7za, $MYPATH)
  95 AC_PATH_PROG(__BZIP2, bzip2, /usr/bin/bzip2, $MYPATH)
  96 AC_PATH_PROG(__CAT, cat, /bin/cat, $MYPATH)
  97 AC_PATH_PROG(__CHGRP, chgrp, /bin/chgrp, $MYPATH)
  98 AC_PATH_PROG(__CHMOD, chmod, /bin/chmod, $MYPATH)
  99 AC_PATH_PROG(__CHOWN, chown, /bin/chown, $MYPATH)
 100 AC_PATH_PROG(__CP, cp, /bin/cp, $MYPATH)
 101 AC_PATH_PROG(__CPIO, cpio, /bin/cpio, $MYPATH)
 102 AC_PATH_PROG(__CURL, curl, /usr/bin/curl, $MYPATH)
 103 AC_PATH_PROG(__FILE, file, /usr/bin/file, $MYPATH)
 104 AC_PATH_PROG(__GPG, gpg, /usr/bin/gpg, $MYPATH)
 105 AC_PATH_PROG(__GREP, grep, /bin/grep, $MYPATH)
 106 AC_PATH_PROG(__GZIP, gzip, /bin/gzip, $MYPATH)
 107 AC_PATH_PROG(__UNZIP, unzip, /usr/bin/unzip, $MYPATH)
 108 AC_PATH_PROG(__ID, id, /usr/bin/id, $MYPATH)
 109 AC_PATH_PROG(__INSTALL, install, /usr/bin/install, $MYPATH)
 110 AC_PATH_PROG(__LRZIP, lrzip, /usr/bin/lrzip, $MYPATH)
 111 AC_PATH_PROG(__LZIP, lzip, /usr/bin/lzip, $MYPATH)
 112 AC_PATH_PROG(__XZ, xz, /usr/bin/xz, $MYPATH)
 113 AC_PATH_PROG(__MAKE, make, /usr/bin/make, $MYPATH)
 114 AC_PATH_PROG(__MKDIR, mkdir, /bin/mkdir, $MYPATH)
 115 AC_PATH_PROG(__MV, mv, /bin/mv, $MYPATH)
 116 AC_PATH_PROG(__PATCH, patch, /usr/bin/patch, $MYPATH)
 117 AC_PATH_PROG(__RESTORECON, restorecon, /sbin/restorecon, $MYPATH)
 118 AC_MSG_CHECKING(old version of patch)
 119     PATCHVERSION=`patch --version 2>&1`
 120
 121     if test "$PATCHVERSION" = "Patch version 2.1"; then
 122         AC_DEFINE(HAVE_OLDPATCH_21, 1,
 123                 [Define if the patch call you'll be using is 2.1 or older])
 124         AC_MSG_RESULT(patch older then 2.2 found)
 125     else
 126         AC_MSG_RESULT(patch later then 2.2 found)
 127     fi
 128
 129 AC_PATH_PROG(__PERL, perl, /usr/bin/perl, $MYPATH)
 130 AC_PATH_PROG(__PGP, pgp, /usr/bin/pgp, $MYPATH)
 131 AC_PATH_PROG(__PYTHON, python, /usr/bin/python, $MYPATH)
 132 AC_PATH_PROG(__RM, rm, /bin/rm, $MYPATH)
 133 AC_PATH_PROG(__RSH, rsh, /usr/bin/rsh, $MYPATH)
 134 AC_PATH_PROG(__SED, sed, /bin/sed, $MYPATH)
 135 AC_PATH_PROG(__SEMODULE, semodule, /usr/bin/semodule, $MYPATH)
 136 AC_PATH_PROG(__SSH, ssh, /usr/bin/ssh, $MYPATH)
 137 AC_PATH_PROG(__TAR, tar, /bin/tar, $MYPATH)
 138
 139 AC_PATH_PROG(__LD, ld, /usr/bin/ld, $MYPATH)
 140 AC_PATH_PROG(__NM, nm, /usr/bin/nm, $MYPATH)
 141 AC_PATH_PROG(__OBJCOPY, objcopy, /usr/bin/objcopy, $MYPATH)
 142 AC_PATH_PROG(__OBJDUMP, objdump, /usr/bin/objdump, $MYPATH)
 143 AC_PATH_PROG(__STRIP, strip, /usr/bin/strip, $MYPATH)
 144
 145 AC_PATH_PROG(__FAKECHROOT, fakechroot, no, $MYPATH)
 146 AM_CONDITIONAL(HAVE_FAKECHROOT, [test "$__FAKECHROOT" != "no"])
 147
 148 dnl see if we have a mkdir that supports `-p' for rpmbuild's purposes
 149 AC_PROG_MKDIR_P
 150 if ! echo $MKDIR_P | grep -q mkdir; then
 151   __MKDIR_P="`echo ${prefix}/lib/rpm/mkinstalldirs`"
 152 else
 153   __MKDIR_P=$MKDIR_P
 154 fi
 155 AC_DEFINE_UNQUOTED(__MKDIR_P, "${__MKDIR_P}",
 156 [A full path to a program, possibly with arguments, that will create a
 157    directory and all necessary parent directories, ala 'mkdir -p'])
 158 AC_SUBST(__MKDIR_P)
 159
 160 #=================
 161 # Check for zlib library.
 162
 163 WITH_ZLIB_INCLUDE=
 164 WITH_ZLIB_LIB=
 165
 166 AC_CHECK_HEADERS([zlib.h],[
 167   AS_IF([test -z "${WITH_ZLIB_LIB}"],[
 168     for zlib in z gz ; do
 169       AC_CHECK_LIB(${zlib}, gzread,
 170         [WITH_ZLIB_LIB="-l${zlib}"; break])
 171     done
 172
 173 dnl zlib-1.0.4 has not gzseek
 174     AC_CHECK_LIB(${zlib}, gzseek, [AC_DEFINE(HAVE_GZSEEK, 1, [Define as 1 if your zlib has gzseek()])])
 175   ])
 176 ],[
 177   AC_MSG_ERROR([missing required header zlib.h])
 178 ])
 179
 180 AC_SUBST(WITH_ZLIB_INCLUDE)
 181 AC_SUBST(WITH_ZLIB_LIB)
 182
 183 #=================
 184 # Check for bzip2 library.
 185
 186 AC_CHECK_HEADERS([bzlib.h],[
 187   AC_CHECK_LIB(bz2, BZ2_bzread, [WITH_BZ2_LIB=-lbz2])
 188 ])
 189 AC_SUBST(WITH_BZ2_LIB)
 190
 191 #=================
 192 # Check for lzma library.
 193
 194 AC_CHECK_HEADERS([lzma.h],[
 195   AC_CHECK_LIB(lzma, lzma_easy_encoder, [WITH_LZMA_LIB=-llzma])
 196 ])
 197 AC_SUBST(WITH_LZMA_LIB)
 198
 199 #=================
 200
 201 dnl
 202 dnl Check for features
 203 dnl
 204
 205 dnl Checks for libraries.
 206
 207 AC_CHECK_FUNC(gethostname, [], [
 208     AC_CHECK_LIB(nsl, gethostname)
 209 ])
 210
 211 AC_CHECK_HEADERS(pthread.h)
 212
 213 AC_CHECK_LIB(pthread, pthread_mutex_trylock, [], [
 214   dnl OSF 5.0 has the the symbols prefixed with __ in libpthread.
 215   AC_CHECK_LIB(pthread, __pthread_mutex_trylock, [], [
 216     AC_CHECK_LIB(thread, mutex_lock)
 217   ])
 218 ])
 219
 220 AC_SEARCH_LIBS(dlopen, [dl])
 221
 222 #=================
 223 # Check for libelf library. Prefer external, otherwise none.
 224 WITH_LIBELF_LIB=
 225 AC_CHECK_HEADER([libelf.h])
 226 AC_CHECK_HEADERS([gelf.h], [
 227         AC_CHECK_LIB(elf, gelf_getvernaux, [
 228             AC_DEFINE(HAVE_LIBELF, 1, [Define to 1 if you have the 'elf' library (-lelf).])
 229             WITH_LIBELF_LIB="-lelf"
 230             WITH_LIBELF=yes
 231         ])
 232 ])
 233 AC_SUBST(WITH_LIBELF_LIB)
 234 AM_CONDITIONAL(LIBELF,[test "$WITH_LIBELF" = yes])
 235
 236 AC_CHECK_HEADERS([dwarf.h], [
 237   WITH_LIBDWARF=yes
 238 ])
 239 AM_CONDITIONAL(LIBDWARF,[test "$WITH_LIBDWARF" = yes])
 240
 241 #=================
 242 # Check for NSS library.
 243 # We need nss.h from NSS which needs nspr.h. Unfortunately both glibc and NSS
 244 # have a header named nss.h... so make extra check for NSS's sechash.h
 245 # which we use too and hopefully is slightly more unique to NSS.
 246 WITH_NSS_INCLUDE=
 247 WITH_NSS_LIB=
 248 AC_CHECK_HEADERS([nspr.h nss.h sechash.h], [], [
 249   AC_MSG_ERROR([missing required NSPR / NSS header])
 250 ])
 251 AC_CHECK_LIB(nss3, NSS_NoDB_Init, [
 252   WITH_NSS_LIB=-lnss3
 253 ], [
 254   AC_MSG_ERROR([missing required NSS library 'nss3'])
 255 ])
 256 AC_SUBST(WITH_NSS_INCLUDE)
 257 AC_SUBST(WITH_NSS_LIB)
 258
 259 #=================
 260 # Check for magic library.
 261 WITH_MAGIC_INCLUDE=
 262 WITH_MAGIC_LIB=
 263
 264 AC_CHECK_HEADER([magic.h], [
 265     AC_CHECK_LIB(magic, magic_open, [
 266       WITH_MAGIC_INCLUDE=
 267       WITH_MAGIC_LIB="-lmagic"
 268     ],[
 269       AC_MSG_ERROR([missing required library 'libmagic'])
 270     ])
 271 ],[
 272       AC_MSG_ERROR([missing required header magic.h])
 273 ])
 274
 275 AC_SUBST(WITH_MAGIC_INCLUDE)
 276 AC_SUBST(WITH_MAGIC_LIB)
 277
 278 #=================
 279 # Check for popt library.
 280 WITH_POPT_INCLUDE=
 281 WITH_POPT_LIB=
 282
 283 AC_CHECK_HEADER([popt.h], [
 284   AC_CHECK_LIB(popt, poptGetContext, [
 285       WITH_POPT_INCLUDE=
 286       WITH_POPT_LIB="-lpopt"
 287   ],[
 288     AC_MSG_ERROR([missing required library popt])
 289   ])
 290 ],[
 291   AC_MSG_ERROR([missing required header popt.h])
 292 ])
 293
 294 AC_SUBST(WITH_POPT_INCLUDE)
 295 AC_SUBST(WITH_POPT_LIB)
 296
 297 #=================
 298 # Process --with/without-external-db
 299 AC_ARG_WITH(external_db, [AS_HELP_STRING([--with-external-db],[build against an external Berkeley db])],
 300 [case "$with_external_db" in
 301 yes|no) ;;
 302 *) AC_MSG_ERROR([invalid argument to --with-external-db]) ;;
 303 esac],
 304 [with_external_db=no])
 305
 306 case "$with_external_db" in
 307 yes )
 308   AC_CHECK_HEADERS([db.h],[
 309     AC_PREPROC_IFELSE([
 310       AC_LANG_SOURCE([
 311         #include <db.h>
 312         #if ((DB_VERSION_MAJOR < 4) || (DB_VERSION_MAJOR == 4 && DB_VERSION_MINOR < 5))
 313         #error Berkeley DB too old
 314         #endif
 315       ])
 316     ],[ WITH_DB_LIB=-ldb ],
 317       [ AC_MSG_ERROR([Berkeley DB version >= 4.5 required])
 318     ])
 319   ],[
 320     AC_MSG_ERROR([missing required header db.h])
 321   ])
 322   ;;
 323 * ) # Fall back to internal db if available
 324   if [ test -x db/dist/configure ]; then
 325     AC_DEFINE(HAVE_DB_H, 1, [Define if you have the <db3/db.h> header file])
 326   else
 327     AC_MSG_ERROR([internal Berkeley DB directory not present, see INSTALL])
 328   fi
 329   ;;
 330 esac
 331
 332 AC_SUBST([WITH_DB_LIB])
 333
 334 AM_GNU_GETTEXT_VERSION([0.16.1])
 335 AM_GNU_GETTEXT([external])
 336
 337 dnl Checks for header files we can live without.
 338 AC_HEADER_STDC
 339 AC_HEADER_MAJOR
 340 AC_STRUCT_DIRENT_D_TYPE
 341
 342 AC_CHECK_HEADERS(limits.h)
 343 AC_CHECK_HEADERS(fcntl.h getopt.h)
 344
 345 AC_CHECK_HEADERS(sys/utsname.h)
 346
 347 AC_CHECK_HEADERS(sys/systemcfg.h)
 348 AC_CHECK_HEADERS(sys/param.h)
 349
 350 dnl statfs portability fiddles.
 351 dnl
 352 dnl We should really emulate/steal sections of the statfs and struct statfs
 353 dnl checks from GNU fileutils.
 354 dnl
 355 AC_MSG_CHECKING(for struct statfs)
 356
 357 dnl
 358 dnl this is easier than nesting AC_TRY_COMPILEs...
 359 dnl
 360 found_struct_statfs=no
 361
 362 if test X$found_struct_statfs = Xno ; then
 363 dnl Solaris 2.6+ wants to use statvfs
 364 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 365 #ifdef HAVE_SYS_TYPES_H
 366 #include <sys/types.h>
 367 #endif
 368 #include <sys/statvfs.h> ]], [[struct statvfs sfs;]])],[AC_MSG_RESULT(in sys/statvfs.h)
 369         AC_DEFINE(STATFS_IN_SYS_STATVFS, 1,
 370                 [statfs in <sys/statvfs.h> (for solaris 2.6+ systems)])
 371         found_struct_statfs=yes],[])
 372 fi
 373
 374 if test X$found_struct_statfs = Xno ; then
 375 dnl first try including sys/vfs.h
 376 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 377 #ifdef HAVE_SYS_TYPES_H
 378 #include <sys/types.h>
 379 #endif
 380 #include <sys/vfs.h> ]], [[struct statfs sfs;]])],[AC_MSG_RESULT(in sys/vfs.h)
 381         AC_DEFINE(STATFS_IN_SYS_VFS, 1, [statfs in <sys/vfs.h> (for linux systems)])
 382         found_struct_statfs=yes],[])
 383 fi
 384
 385 if test X$found_struct_statfs = Xno ; then
 386 dnl ...next try including sys/mount.h
 387 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 388 #ifdef HAVE_SYS_TYPES_H
 389 #include <sys/types.h>
 390 #endif
 391 #ifdef HAVE_SYS_PARAM_H
 392 #include <sys/param.h>
 393 #endif
 394 #include <sys/mount.h> ]], [[struct statfs sfs;]])],[AC_MSG_RESULT(in sys/mount.h)
 395         AC_DEFINE(STATFS_IN_SYS_MOUNT, 1, [statfs in <sys/mount.h> (for Digital Unix 4.0D systems)])
 396         found_struct_statfs=yes],[])
 397 fi
 398
 399 if test X$found_struct_statfs = Xno ; then
 400 dnl ...still no joy.  Try sys/statfs.h
 401 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 402 #ifdef HAVE_SYS_TYPES_H
 403 #include <sys/types.h>
 404 #endif
 405 #include <sys/statfs.h> ]], [[struct statfs sfs;]])],[AC_MSG_RESULT(in sys/statfs.h)
 406         AC_DEFINE(STATFS_IN_SYS_STATFS, 1, [statfs in <sys/statfs.h> (for Irix 6.4 systems)])
 407         found_struct_statfs=yes],[])
 408 fi
 409
 410 if test X$found_struct_statfs = Xno ; then
 411 dnl ...no luck.  Warn the user of impending doom.
 412 AC_MSG_WARN(not found)
 413 fi
 414
 415 dnl
 416 dnl if we found the struct, see if it has the f_bavail member.  Some OSes
 417 dnl don't, including IRIX 6.5+
 418 dnl
 419 if test X$found_struct_statfs = Xyes ; then
 420 AC_MSG_CHECKING(for f_bavail member in struct statfs)
 421 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 422 #ifdef HAVE_SYS_TYPES_H
 423 #include <sys/types.h>
 424 #endif
 425 #if STATFS_IN_SYS_STATVFS
 426 # include <sys/statvfs.h>
 427   typedef struct statvfs STATFS_t;
 428 #else
 429   typedef struct statfs STATFS_t;
 430 # if STATFS_IN_SYS_VFS
 431 #  include <sys/vfs.h>
 432 # elif STATFS_IN_SYS_MOUNT
 433 #  include <sys/mount.h>
 434 # elif STATFS_IN_SYS_STATFS
 435 #  include <sys/statfs.h>
 436 # endif
 437 #endif ]], [[STATFS_t sfs;
 438         sfs.f_bavail = 0;]])],[AC_MSG_RESULT(yes)
 439         AC_DEFINE(STATFS_HAS_F_BAVAIL, 1, [Define if struct statfs has the f_bavail member])],[AC_MSG_RESULT(no)
 440 ])
 441 fi
 442
 443 if test X$found_struct_statfs = Xyes ; then
 444 dnl
 445 dnl now check to see if we have the 4-argument variant of statfs()
 446 dnl this pretty much requires AC_RUN_IFELSE([AC_LANG_SOURCE([[]])],[],[],[])
 447 dnl
 448 AC_MSG_CHECKING([if statfs() requires 4 arguments])
 449 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 450 #ifdef HAVE_SYS_TYPES_H
 451 #include <sys/types.h>
 452 #endif
 453 #ifdef STATFS_IN_SYS_VFS
 454 #include <sys/vfs.h>
 455 #elif STATFS_IN_SYS_MOUNT
 456 #include <sys/mouht.h>
 457 #elif STATFS_IN_SYS_STATFS
 458 #include <sys/statfs.h>
 459 #endif
 460 main() {
 461         struct statfs sfs;
 462         exit (statfs(".", &sfs, sizeof(sfs), 0));
 463 }
 464 ]])],[AC_MSG_RESULT(yes)
 465         AC_DEFINE(STAT_STATFS4, 1, [Define if the statfs() call takes 4 arguments])],[AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)
 466 ])
 467 fi
 468
 469 dnl look for libc features
 470
 471 dnl Check for missing typedefs
 472 AC_TYPE_MODE_T
 473 AC_TYPE_OFF_T
 474 AC_TYPE_PID_T
 475 AC_TYPE_SIZE_T
 476
 477 dnl Checks for library functions.
 478 AC_FUNC_MMAP
 479
 480 AC_CHECK_FUNCS(putenv)
 481
 482 AC_REPLACE_FUNCS(stpcpy stpncpy)
 483
 484 AC_CHECK_FUNCS(__secure_getenv)
 485
 486 AC_CHECK_FUNCS(
 487    [mkstemp getcwd basename dirname realpath setenv unsetenv regcomp lchown],
 488    [], [AC_MSG_ERROR([function required by rpm])])
 489
 490 AC_LIBOBJ(fnmatch)
 491
 492 dnl check if python is requested
 493 AC_ARG_ENABLE(python, [AS_HELP_STRING([--enable-python],[build rpm python bindings])],
 494 [case "$enable_python" in
 495 yes|no) ;;
 496 *) AC_MSG_ERROR([invalid argument to --enable-python])
 497   ;;
 498 esac],
 499 [enable_python=no])
 500
 501 AS_IF([test "$enable_python" = yes],[
 502   AM_PATH_PYTHON([2.6],[
 503     WITH_PYTHON_INCLUDE=`${PYTHON} -c 'from distutils.sysconfig import *; import sys; sys.stdout.write(get_python_inc())'`
 504     WITH_PYTHON_SUBPACKAGE=1
 505     save_CPPFLAGS="$CPPFLAGS"
 506     CPPFLAGS="$CPPFLAGS -I$WITH_PYTHON_INCLUDE"
 507     AC_CHECK_HEADER([Python.h],[],
 508       [AC_MSG_ERROR([missing Python.h])
 509       ])
 510     CPPFLAGS="$save_CPPFLAGS"
 511     save_LIBS="$LIBS"
 512     AC_SEARCH_LIBS([Py_Main],[python${PYTHON_VERSION} python],[
 513       WITH_PYTHON_LIB="$ac_res"
 514     ],[AC_MSG_ERROR([missing python library])
 515     ])
 516     LIBS="$save_LIBS"
 517   ])
 518 ],[
 519     WITH_PYTHON_INCLUDE=
 520     WITH_PYTHON_LIB=
 521     WITH_PYTHON_SUBPACKAGE=0
 522 ])
 523
 524 AC_SUBST(WITH_PYTHON_INCLUDE)
 525 AC_SUBST(WITH_PYTHON_LIB)
 526
 527 AM_CONDITIONAL(ENABLE_PYTHON,[test "$WITH_PYTHON_SUBPACKAGE" = 1])
 528
 529 AC_PATH_PROG(DOXYGEN, doxygen, no)
 530 dnl
 531 dnl Only build internal API + source hacking docs on request
 532 dnl
 533 AC_ARG_WITH(hackingdocs, [AS_HELP_STRING([--with-hackingdocs],[build rpm hacking docs])],,[with_hackingdocs=no])
 534
 535 case "$with_hackingdocs" in
 536 auto)
 537   AS_IF([test "$DOXYGEN" = no],[with_hackingdocs=no],[with_hackingdocs=no])
 538   ;;
 539 yes)
 540   AS_IF([test "$DOXYGEN" = no],
 541     [AC_MSG_ERROR([rpm hacking docs eeds doxygen in PATH])])
 542   ;;
 543 esac
 544 AC_CHECK_PROG(HAVE_DOT,[dot],[YES],[NO])
 545
 546 WITH_SELINUX_LIB=
 547 AC_ARG_WITH(selinux, [AS_HELP_STRING([--with-selinux],[build with selinux support])],
 548 [case "$with_selinux" in
 549 yes|no) ;;
 550 *) AC_MSG_ERROR([invalid argument to --with-selinux])
 551   ;;
 552 esac],
 553 [with_selinux=no])
 554
 555 AS_IF([test "$with_selinux" = yes],[
 556   AC_CHECK_HEADER([selinux/selinux.h],[
 557     save_LIBS="$LIBS"
 558     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],[
 559       AC_MSG_ERROR([--with-selinux given, but is_selinux_enabled not found in libselinux])])
 560     AC_CHECK_LIB([selinux],[selinux_getpolicytype],[],[
 561       AC_MSG_ERROR([--with-selinux given, but selinux_getpolicytype not found in libselinux])])
 562     AC_CHECK_LIB([selinux],[selinux_reset_config],[],[
 563       AC_MSG_ERROR([--with-selinux given, but selinux_reset_config not found in libselinux])])
 564     LIBS="$save_LIBS"
 565   ],[
 566     AC_MSG_ERROR([--with-selinux given, but selinux/selinux.h not found])
 567   ])
 568
 569   AC_CHECK_HEADER([selinux/label.h],[
 570     save_LIBS="$LIBS"
 571     AC_CHECK_LIB([selinux],[selabel_close],[],[
 572       AC_MSG_ERROR([--with-selinux given, but selabel_close not found in libselinux])])
 573     AC_CHECK_LIB([selinux],[selabel_lookup_raw],[],[
 574       AC_MSG_ERROR([--with-selinux given, but selabel_lookup_raw not found in libselinux])])
 575     AC_CHECK_LIB([selinux],[selabel_open],[],[
 576       AC_MSG_ERROR([--with-selinux given, but selabel_open not found in libselinux])])
 577     LIBS="$save_LIBS"
 578   ],[
 579     AC_MSG_ERROR([--with-selinux given, but selinux/label.h not found])
 580   ])
 581
 582   dnl FIXME: semanage is only needed for the sepolicy plugin
 583   AC_CHECK_HEADER([semanage/semanage.h],[
 584     save_LIBS="$LIBS"
 585     AC_CHECK_LIB([semanage],[semanage_begin_transaction],[],[
 586       AC_MSG_ERROR([--with-selinux given, but semanage_begin_transaction missing in libsemanage])])
 587     AC_CHECK_LIB([semanage],[semanage_commit],[],[
 588       AC_MSG_ERROR([--with-selinux given, but semanage_commit missing in libsemanage])])
 589     AC_CHECK_LIB([semanage],[semanage_connect],[],[
 590       AC_MSG_ERROR([--with-selinux given, but semanage_connect missing in libsemanage])])
 591     AC_CHECK_LIB([semanage],[semanage_disconnect],[],[
 592       AC_MSG_ERROR([--with-selinux given, but semanage_disconnect missing in libsemanage])])
 593     AC_CHECK_LIB([semanage],[semanage_handle_create],[],[
 594       AC_MSG_ERROR([--with-selinux given, but semanage_handle_create missing in libsemanage])])
 595     AC_CHECK_LIB([semanage],[semanage_handle_destroy],[],[
 596       AC_MSG_ERROR([--with-selinux given, but semanage_handle_destroy missing in libsemanage])])
 597     AC_CHECK_LIB([semanage],[semanage_is_connected],[],[
 598       AC_MSG_ERROR([--with-selinux given, but semanage_is_connected missing in libsemanage])])
 599     AC_CHECK_LIB([semanage],[semanage_module_install_base_file],[],[
 600       AC_MSG_ERROR([--with-selinux given, but semanage_module_install_base_file missing in libsemanage])])
 601     AC_CHECK_LIB([semanage],[semanage_module_install_file],[],[
 602       AC_MSG_ERROR([--with-selinux given, but semanage_module_install_file missing in libsemanage])])
 603     AC_CHECK_LIB([semanage],[semanage_module_remove],[],[
 604       AC_MSG_ERROR([--with-selinux given, but semanage_module_remove missing in libsemanage])])
 605     AC_CHECK_LIB([semanage],[semanage_select_store],[],[
 606       AC_MSG_ERROR([--with-selinux given, but semanage_select_store missing in libsemanage])])
 607     AC_CHECK_LIB([semanage],[semanage_set_check_contexts],[],[
 608       AC_MSG_ERROR([--with-selinux given, but semanage_set_check_contexts missing in libsemanage])])
 609     AC_CHECK_LIB([semanage],[semanage_set_create_store],[],[
 610       AC_MSG_ERROR([--with-selinux given, but semanage_set_create_store missing in libsemanage])])
 611     AC_CHECK_LIB([semanage],[semanage_set_reload],[],[
 612       AC_MSG_ERROR([--with-selinux given, but semanage_set_reload missing in libsemanage])])
 613     LIBS="$save_LIBS"
 614   ],[
 615     AC_MSG_ERROR([--with-selinux given, but semanage/semanage.h not found])
 616   ])
 617 ])
 618
 619 AS_IF([test "$with_selinux" = yes],[
 620   AC_DEFINE(WITH_SELINUX, 1, [Build with selinux support?])
 621   WITH_SELINUX_LIB="-lselinux"
 622   WITH_SEMANAGE_LIB="-lsemanage"
 623 ])
 624 AC_SUBST(WITH_SELINUX_LIB)
 625 AC_SUBST(WITH_SEMANAGE_LIB)
 626 AM_CONDITIONAL(SELINUX,[test "$with_selinux" = yes])
 627
 628 # libcap
 629 WITH_CAP_LIB=
 630 AC_ARG_WITH(cap, [AS_HELP_STRING([--with-cap],[build with capability support])],
 631 [case "$with_cap" in
 632 yes|no) ;;
 633 *) AC_MSG_ERROR([invalid argument to --with-cap])
 634   ;;
 635 esac],
 636 [with_cap=no])
 637
 638 AS_IF([test "$with_cap" = yes],[
 639   AC_CHECK_HEADER([sys/capability.h],[
 640     AC_CHECK_LIB(cap,[cap_get_file], [
 641       with_cap=yes
 642       save_LIBS="$LIBS"
 643       AC_CHECK_LIB(cap,[cap_compare], [
 644         AC_DEFINE(HAVE_CAP_COMPARE, 1, [Have cap_compare function?])
 645       ])
 646       LIBS="$save_LIBS"
 647     ],[
 648       AC_MSG_ERROR([--with-cap given, but libcap not found])])
 649   ],[
 650     AC_MSG_ERROR([--with-cap given, but sys/capability.h not found])
 651   ])
 652 ])
 653
 654 AS_IF([test "$with_cap" = yes],[
 655   AC_DEFINE(WITH_CAP, 1, [Build with capability support?])
 656   WITH_CAP_LIB="-lcap"
 657 ])
 658 AC_SUBST(WITH_CAP_LIB)
 659 AM_CONDITIONAL(CAP,[test "$with_cap" = yes])
 660
 661 WITH_ACL_LIB=
 662 AC_ARG_WITH(acl, [AS_HELP_STRING([--with-acl],[build with acl support])],
 663 [case "$with_acl" in
 664 yes|no) ;;
 665 *) AC_MSG_ERROR([invalid argument to --with-acl])
 666   ;;
 667 esac],
 668 [with_acl=no])
 669
 670 AS_IF([test "$with_acl" = yes],[
 671   dnl verification uses non-portable acl_equiv_mode()
 672   AC_CHECK_HEADER([acl/libacl.h],[
 673     AC_CHECK_LIB(acl,[acl_equiv_mode],[with_acl=yes],[
 674       AC_MSG_ERROR([--with-acl given, but libacl not found or not suitable])])
 675   ],[
 676     AC_MSG_ERROR([--with-acl given, but acl/libacl.h not found])
 677   ])
 678 ])
 679
 680 AS_IF([test "$with_acl" = yes],[
 681   AC_DEFINE(WITH_ACL, 1, [Build with acl support?])
 682   WITH_ACL_LIB="-lacl"
 683 ])
 684 AC_SUBST(WITH_ACL_LIB)
 685 AM_CONDITIONAL(ACL,[test "$with_acl" = yes])
 686
 687 AC_ARG_WITH([lua], [AS_HELP_STRING([--with-lua], [build with lua support])],
 688             [],
 689             [with_lua=yes])
 690
 691 AS_IF([test "$with_lua" != no],[
 692   PKG_CHECK_MODULES([LUA],
 693     [lua >= 5.1],
 694     [AC_DEFINE(WITH_LUA, 1, [Build with lua support?])],
 695     [AC_MSG_ERROR([lua not present (--without-lua to disable)])])
 696   AC_SUBST(LUA_CFLAGS)
 697   AC_SUBST(LUA_LIBS)
 698 ])
 699 AM_CONDITIONAL(WITH_LUA,[test "$with_lua" = yes])
 700
 701 AC_ARG_ENABLE(plugins, [AS_HELP_STRING([--disable-plugins],[build without plugin support])],,[enable_plugins=yes])
 702 AS_IF([test "$enable_plugins" = yes],[
 703   AC_DEFINE(ENABLE_PLUGINS, 1, [Build with plugin support?])
 704 ])
 705 AM_CONDITIONAL(ENABLE_PLUGINS,[test "$enable_plugins" = yes])
 706
 707
 708 with_dmalloc=no
 709 AC_ARG_WITH(dmalloc, [AS_HELP_STRING([--with-dmalloc],[build with dmalloc debugging support])])
 710 if test "$with_dmalloc" = yes ; then
 711   AC_DEFINE(DMALLOC, 1, [Build with dmalloc support?])
 712   LIBS="$LIBS -ldmalloc"
 713 fi
 714
 715 AC_CHECK_FUNCS(getpassphrase)
 716
 717 #
 718 # get rid of the 4-th tuple, if config.guess returned "linux-gnu" for host_os
 719 #
 720 host_os_gnu=-gnu
 721 if echo "$host_os" | grep '.*-gnulibc1' > /dev/null ; then
 722         host_os=`echo "${host_os}" | sed 's/-gnulibc1$//'`
 723 fi
 724 if echo "$host_os" | grep '.*-gnueabi' > /dev/null ; then
 725         host_os=`echo "${host_os}" | sed 's/-gnueabi$//'`
 726         host_os_gnu=-gnueabi
 727 fi
 728 if echo "$host_os" | grep '.*-gnu' > /dev/null ; then
 729         host_os=`echo "${host_os}" | sed 's/-gnu$//'`
 730 fi
 731
 732 changequote(<, >)
 733 host_os_exact="${host_os}"
 734 host_os_major=`echo "${host_os}" | sed 's/\..*$//'`
 735 host_os_noversion=`echo "${host_os}" | sed 's/[0-9]*\..*$//'`
 736 changequote([, ])
 737
 738 for provscript in ${host_cpu}-${host_os_exact}.prov ${host_os_exact}.prov ${host_os_major}.prov ${host_os_noversion}.prov none ; do {
 739     if test -f ${srcdir}/autodeps/${provscript} ; then
 740        if [[ ${provscript} == none ]] ; then
 741            echo "*** no default provides information is available for ${host_os_noversion}"
 742        else
 743            echo "using ${srcdir}/autodeps/${provscript} for automatic provides generation"
 744        fi
 745        ln -sf ${provscript} ${srcdir}/autodeps/find-provides
 746        break
 747     fi
 748 }; done
 749
 750
 751 for reqscript in ${host_cpu}-${host_os_exact}.req ${host_os_exact}.req ${host_os_major}.req ${host_os_noversion}.req none ; do {
 752     if test -f ${srcdir}/autodeps/${reqscript} ; then
 753        if [[ ${reqscript} == none ]] ; then
 754            echo "*** no default requires information is available for ${host_os_noversion}"
 755        else
 756           echo "using ${srcdir}/autodeps/${reqscript} for automatic requires generation"
 757        fi
 758        ln -sf ${reqscript} ./autodeps/find-requires
 759        break
 760     fi
 761 } done
 762
 763 dnl permit overriding build_vendor for "canonical rpm vendor"
 764 RPMCANONVENDOR="$build_vendor"
 765 AC_ARG_WITH([vendor],
 766   AS_HELP_STRING([--with-vendor=VENDOR], [specify rpm vendor name]),
 767   [RPMCANONVENDOR=$withval])
 768 AC_DEFINE_UNQUOTED([RPMCANONVENDOR],["${RPMCANONVENDOR}"],[canonical vendor])
 769
 770 RPMCANONOS="$host_os_noversion"
 771 RPMCANONGNU="$host_os_gnu"
 772 AC_SUBST(RPMCANONVENDOR)
 773 AC_SUBST(RPMCANONOS)
 774 AC_SUBST(RPMCANONGNU)
 775
 776 if test X"$prefix" = XNONE ; then
 777     usrprefix="$ac_default_prefix"
 778 else
 779     usrprefix=$prefix
 780 fi
 781
 782 RPMCONFIGDIR="`echo ${usrprefix}/lib/rpm`"
 783 AC_SUBST(RPMCONFIGDIR)
 784
 785 AC_SUBST(OBJDUMP)
 786
 787 if test "$with_external_db" = no; then
 788     AC_CONFIG_SUBDIRS(db3)
 789 fi
 790
 791 AM_CONDITIONAL([WITH_INTERNAL_DB],[test "$with_external_db" = no])
 792 AM_CONDITIONAL([DOXYGEN],[test "$DOXYGEN" != no])
 793 AM_CONDITIONAL([HACKINGDOCS],[test "$with_hackingdocs" = yes])
 794
 795 AC_PATH_PROG(AUTOM4TE,autom4te,:)
 796
 797 AC_SUBST([dirstamp],[\${am__leading_dot}dirstamp])
 798
 799 AC_CONFIG_FILES([Makefile
 800         rpmio/Makefile lib/Makefile build/Makefile sign/Makefile
 801         po/Makefile.in scripts/Makefile fileattrs/Makefile
 802         misc/Makefile
 803         doc/Makefile
 804         python/Makefile
 805         luaext/Makefile
 806         tests/Makefile
 807         plugins/Makefile
 808         python/setup.py
 809   ])
 810 AC_OUTPUT