configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([Rygel],
   3         [m4_esyscmd(GNOME_TAG_PATTERN=RYGEL build-aux/git-version-gen .tarball-version)],
   4         [http://bugzilla.gnome.org/enter_bug.cgi?product=Rygel],
   5         [rygel],
   6         [http://live.gnome.org/Rygel])
   7 AC_CONFIG_AUX_DIR([build-aux])
   8
   9 AC_CONFIG_SRCDIR([src/librygel-core/rygel-root-device.vala])
  10 AC_CONFIG_HEADERS([config.h])
  11 AC_CONFIG_MACRO_DIR([m4])
  12
  13 AC_SEARCH_LIBS([strerror],[cposix])
  14 AC_PROG_CC
  15 AC_HEADER_STDC
  16 AC_FUNC_MMAP
  17
  18 AC_SUBST(abs_top_builddir)
  19 AC_SUBST(VERSION)
  20
  21 dnl Initialize automake
  22 AM_INIT_AUTOMAKE([1.11.1 tar-ustar no-dist-gzip dist-xz -Wno-portability])
  23 AM_MAINTAINER_MODE([enable])
  24
  25 dnl Initialize libtool
  26 dnl Disable generation of static libraries
  27 LT_PREREQ([2.2.6])
  28 LT_INIT([dlopen disable-static])
  29
  30 dnl Required versions of library packages
  31 GLIB_REQUIRED=2.31.13
  32 LIBXML_REQUIRED=2.7
  33 VALA_REQUIRED=0.18.0
  34 VALADOC_REQUIRED=0.2
  35 GSSDP_REQUIRED=0.13.0
  36 GUPNP_REQUIRED=0.19.0
  37 GUPNP_AV_REQUIRED=0.11.4
  38 GUPNP_DLNA_REQUIRED=0.7.0
  39 GSTREAMER_REQUIRED=1.0
  40 GSTPBU_REQUIRED=1.0
  41 GIO_REQUIRED=2.26
  42 GEE_REQUIRED=0.8.0
  43 UUID_REQUIRED=1.41.3
  44 LIBSOUP_REQUIRED=2.34.0
  45 GTK_REQUIRED=2.90.3
  46
  47 dnl Additional requirements for media-export plugin
  48 GSTREAMER_TAG_REQUIRED=1.0
  49 GSTREAMER_APP_REQUIRED=1.0
  50 LIBSQLITE3_REQUIRED=3.5
  51
  52 dnl Additional requirements for tracker plugin
  53 TRACKER_SPARQL_REQUIRED_MIN=0.14.0
  54
  55 PKG_CHECK_MODULES(LIBGLIB, glib-2.0 >= $GLIB_REQUIRED)
  56 VALAFLAGS="--target-glib=2.32 $VALAFLAGS"
  57
  58 PKG_CHECK_MODULES(LIBGSSDP, gssdp-1.0 >= $GSSDP_REQUIRED)
  59 PKG_CHECK_MODULES(LIBGUPNP, gupnp-1.0 >= $GUPNP_REQUIRED)
  60 PKG_CHECK_MODULES(LIBGUPNP_AV, gupnp-av-1.0 >= $GUPNP_AV_REQUIRED)
  61 PKG_CHECK_MODULES(LIBGIO, gio-2.0 >= $GIO_REQUIRED)
  62 PKG_CHECK_MODULES(GEE, gee-0.8 >= $GEE_REQUIRED)
  63 PKG_CHECK_MODULES(UUID, uuid >= $UUID_REQUIRED)
  64 PKG_CHECK_MODULES(LIBSOUP, libsoup-2.4 >= $LIBSOUP_REQUIRED)
  65 PKG_CHECK_MODULES(LIBXML, libxml-2.0 >= $LIBXML_REQUIRED)
  66
  67 dnl Media engine to use
  68 BUILT_ENGINES="librygel-media-engine-simple"
  69
  70 AC_ARG_WITH([media_engine],
  71             AS_HELP_STRING(
  72                 [--with-media-engine=@<:@gstreamer|none@:>@],
  73                 [Media Engine to use]),
  74             [with_media_engine="$withval"],
  75             [with_media_engine="gstreamer"])
  76
  77 AS_IF([test "x$with_media_engine" = "xgstreamer"],
  78       [
  79         PKG_CHECK_MODULES(LIBGUPNP_DLNA, gupnp-dlna-1.1 >= $GUPNP_DLNA_REQUIRED)
  80         PKG_CHECK_MODULES(LIBGSTREAMER, gstreamer-1.0 >= $GSTREAMER_REQUIRED)
  81         PKG_CHECK_MODULES(GSTREAMER_BASE, gstreamer-base-1.0 >= $GSTREAMER_REQUIRED)
  82         PKG_CHECK_MODULES(GST_PBU, gstreamer-pbutils-1.0 >= $GSTPBU_REQUIRED)
  83         enable_gstreamer="yes"
  84         BUILT_ENGINES="$BUILT_ENGINES;librygel-media-engine-gst"
  85       ],
  86       [enable_gstreamer="no"])
  87 AM_CONDITIONAL([HAVE_GSTREAMER],[test "x$enable_gstreamer" = "xyes"])
  88 AC_SUBST([BUILT_ENGINES])
  89
  90 dnl Add plugins
  91 RYGEL_ADD_PLUGIN([external],[MediaServer2 DBus consumer],[yes])
  92 RYGEL_ADD_PLUGIN([mpris],[MPRIS2 DBus consumer],[yes])
  93 RYGEL_ADD_PLUGIN([mediathek],[ZDF Mediathek],[no])
  94 RYGEL_ADD_PLUGIN([tracker],[Tracker],[yes])
  95
  96 AS_IF([test "x$with_media_engine" = "xgstreamer"],
  97       [
  98         RYGEL_ADD_PLUGIN([playbin],[GStreamer playbin],[yes])
  99         RYGEL_ADD_PLUGIN([media-export],[MediaExport],[yes])
 100         RYGEL_ADD_PLUGIN([gst-launch],[GStreamer launchline],[no])
 101         RYGEL_ADD_STAMP([src/media-engines/gstreamer/librygel_media_engine_gst_la_vala.stamp])
 102         RYGEL_ADD_STAMP([src/librygel-renderer-gst/librygel_renderer_gst_2_0_la_vala.stamp])
 103       ],
 104       [
 105         RYGEL_DISABLE_PLUGIN([playbin])
 106         RYGEL_DISABLE_PLUGIN([media-export])
 107         RYGEL_DISABLE_PLUGIN([gst-launch])
 108       ])
 109
 110 dnl Example plugins:
 111 AC_ARG_ENABLE([example-plugins],
 112               AS_HELP_STRING([--enable-example-plugins],[enable example plugins]),,
 113               enable_example_plugins=no)
 114 AM_CONDITIONAL([BUILD_EXAMPLE_PLUGINS], [test "x$[]enable_example_plugins" = "xyes"])
 115
 116 dnl Explicitly add stamp files for targets that are not plugins
 117 RYGEL_ADD_STAMP([src/librygel-core/librygel_core_2_0_la_vala.stamp])
 118 RYGEL_ADD_STAMP([src/librygel-server/librygel_server_2_0_la_vala.stamp])
 119 RYGEL_ADD_STAMP([src/librygel-renderer/librygel_renderer_2_0_la_vala.stamp])
 120 RYGEL_ADD_STAMP([src/rygel/rygel_vala.stamp])
 121 RYGEL_ADD_STAMP([src/ui/rygel_preferences_vala.stamp])
 122 RYGEL_ADD_STAMP([src/media-engines/simple/librygel_media_engine_simple_la_vala.stamp])
 123
 124 RYGEL_CHECK_VALA([$VALA_REQUIRED],
 125                  [gupnp-1.0
 126                   gupnp-av-1.0
 127                   gio-2.0
 128                   gee-0.8
 129                   posix])
 130
 131 AS_IF([test "x$with_media_engine" = "xgstreamer"],
 132       [
 133         RYGEL_CHECK_PACKAGES([gupnp-dlna-1.1 gstreamer-1.0
 134                               gstreamer-pbutils-1.0])
 135       ])
 136
 137 dnl Debugging
 138 AC_ARG_ENABLE(debug,
 139         AS_HELP_STRING([--enable-debug],[enable debugging]),,
 140         enable_debug=no)
 141 if test "x$enable_debug" = "xyes"; then
 142         CFLAGS="$CFLAGS -O0 -g"
 143         RYGEL_DEBUG_VALAFLAGS="-g"
 144 fi
 145
 146 AC_SUBST(RYGEL_DEBUG_VALAFLAGS)
 147
 148 dnl Strict compiler
 149 AC_ARG_ENABLE(strict-cc,
 150         AS_HELP_STRING([--enable-strict-cc],[enable strict C compiler]),,
 151         enable_strict_cc=no)
 152 if test "x$enable_strict_cc" = "xyes"; then
 153         CFLAGS="$CFLAGS -Wall -Werror"
 154 else
 155         CFLAGS="$CFLAGS -w"
 156 fi
 157
 158 dnl Run uninstalled
 159 AC_ARG_ENABLE(uninstalled,
 160     AS_HELP_STRING([--enable-uninstalled],[run uninstalled]),,
 161         enable_uninstalled=no)
 162 if test "x$enable_uninstalled" = "xyes"; then
 163         AC_MSG_WARN("You want to run the tools uninstalled only? Fine!")
 164 fi
 165 AM_CONDITIONAL([UNINSTALLED], [test "x$enable_uninstalled" = "xyes"])
 166
 167 dnl Check wether user wants to build UIs
 168 AC_ARG_WITH( ui,
 169   AS_HELP_STRING([--without-ui],[Do not build UI applications]),
 170   try_ui=$withval, try_ui=yes )
 171
 172 HAVE_GTK=no
 173 if test x$try_ui = xyes ; then
 174     dnl check for gtk
 175     PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQUIRED,
 176       [
 177         RYGEL_CHECK_PACKAGES([gtk+-3.0], [HAVE_GTK=yes])
 178       ],
 179       [
 180         AC_MSG_WARN([gtk $GTK_REQUIRED or greater not found.])
 181         AC_MSG_WARN([UI applications will not be built.])
 182       ])
 183 else
 184     AC_MSG_NOTICE([UI applications disabled.])
 185 fi
 186
 187 AM_CONDITIONAL(BUILD_UI, test "x$HAVE_GTK" = "xyes")
 188
 189 dnl Tests
 190 AC_ARG_ENABLE([tests],
 191               AS_HELP_STRING([--enable-tests],[always build tests]),,
 192               enable_tests=no)
 193 AM_CONDITIONAL([ALWAYS_TEST], [test "x$enable_tests" = "xyes"])
 194
 195 dnl Generate coverage data
 196 AC_ARG_ENABLE([coverage],
 197   AS_HELP_STRING([--enable-coverage],
 198                  [Generate converage reports for unit tests]),
 199   [],
 200   [enable_coverage=no])
 201 AM_CONDITIONAL([ENABLE_COVERAGE],[test "x$enable_coverage" != "xno"])
 202 AS_IF([test "x$enable_coverage" != "xno"],
 203   [
 204     AC_PATH_PROG([LCOV], [lcov])
 205     AC_PATH_PROG([GENHTML], [genhtml])
 206     AC_SUBST([COVERAGE_LIBS],["-lgcov"])
 207     AC_SUBST([COVERAGE_CFLAGS],["-fprofile-arcs -ftest-coverage"])
 208     AC_SUBST(COVERAGE_VALAFLAGS,["-g"])
 209   ]
 210 )
 211
 212 dnl Check additional requirements for MediaExport plugins
 213 if test "x$enable_media_export_plugin" = "xyes";
 214 then
 215     PKG_CHECK_MODULES(LIBSQLITE3, sqlite3 >= $LIBSQLITE3_REQUIRED)
 216     PKG_CHECK_MODULES(GSTREAMER_TAG, gstreamer-tag-1.0 >= $GSTREAMER_TAG_REQUIRED);
 217     PKG_CHECK_MODULES(GSTREAMER_APP, gstreamer-app-1.0 >= $GSTREAMER_APP_REQUIRED);
 218     RYGEL_CHECK_PACKAGES([sqlite3 gstreamer-tag-1.0 gstreamer-app-1.0])
 219     AC_CHECK_HEADER([unistr.h],
 220                     AC_CHECK_LIB([unistring],
 221                                  [u8_strcoll],
 222                                  [have_unistring=yes],[have_unistring=no]))
 223     if test "x$have_unistring" = "xyes"; then
 224         AC_DEFINE([HAVE_UNISTRING],[1],[Use libunistring for collation])
 225         COLLATION_CFLAGS=
 226         COLLATION_LIBS=-lunistring
 227         AC_SUBST([COLLATION_CFLAGS])
 228         AC_SUBST([COLLATION_LIBS])
 229     fi
 230 fi
 231
 232 AS_IF([test "x$enable_tracker_plugin" = "xyes"],
 233   [
 234     PKG_CHECK_MODULES(TRACKER_SPARQL,
 235                       tracker-sparql-0.14 >= $TRACKER_SPARQL_REQUIRED_MIN)
 236     AS_IF([test "x$enable_vala" = "xyes"],
 237           [VALA_CHECK_PACKAGES([tracker-sparql-0.14])])
 238   ])
 239
 240 dnl Gettext
 241 GETTEXT_PACKAGE=rygel
 242 AC_SUBST(GETTEXT_PACKAGE)
 243 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 244   [Define the gettext package to be used])
 245
 246 AM_GLIB_GNU_GETTEXT
 247 IT_PROG_INTLTOOL([0.40.0])
 248
 249 dnl Shave the output
 250 AM_SILENT_RULES([yes])
 251
 252 dnl documenation
 253 AC_PATH_PROG([XSLTPROC], [xsltproc])
 254 AM_CONDITIONAL([HAVE_XSLTPROC], [test x"$XSLTPROC" != x])
 255
 256 dnl Use valadoc for API documentation:
 257 dnl This is on by default when using autogen.sh
 258 dnl (so it is not on by default when building from a tarball with configure.)
 259 AC_ARG_ENABLE(valadoc,
 260   AS_HELP_STRING([--enable-valadoc[=@<:@no/auto/yes@:>@]], [Enable valadoc support]),,
 261     [enable_valadoc=no])
 262
 263 found_valadoc=no
 264 AS_IF([test "x$enable_valadoc" != "xno"], [
 265     AC_PATH_PROG(VALADOC, valadoc, :)
 266     AS_IF([test -x "$VALADOC"], [
 267       found_valadoc=yes
 268       AC_SUBST(VALADOC)
 269       PKG_CHECK_MODULES([GTKDOC],[gtk-doc >= 1.0])
 270     ], [
 271       AS_IF([test "x$enable_valadoc" == "xyes"], AC_MSG_ERROR([Unable to find valadoc]))
 272     ])
 273   ])
 274
 275 AM_CONDITIONAL(ENABLE_VALADOC, test x$found_valadoc = xyes)
 276
 277 AC_CONFIG_FILES([
 278 Makefile
 279 src/Makefile
 280 src/librygel-core/Makefile
 281 src/librygel-renderer/Makefile
 282 src/librygel-renderer-gst/Makefile
 283 src/librygel-server/Makefile
 284 src/rygel/Makefile
 285 src/ui/Makefile
 286 src/media-engines/Makefile
 287 src/media-engines/gstreamer/Makefile
 288 src/media-engines/simple/Makefile
 289 src/plugins/Makefile
 290 data/Makefile
 291 data/xml/Makefile
 292 data/xml/MediaServer3.xml.in
 293 data/xml/MediaRenderer2.xml.in
 294 data/icons/Makefile
 295 data/icons/32x32/Makefile
 296 data/icons/48x48/Makefile
 297 data/icons/120x120/Makefile
 298 data/icons/128x128/Makefile
 299 data/icons/scalable/Makefile
 300 data/rygel.desktop.in
 301 data/rygel-preferences.desktop.in
 302 doc/Makefile
 303 doc/reference/Makefile
 304 doc/reference/librygel-core/Makefile
 305 doc/reference/librygel-renderer/Makefile
 306 doc/reference/librygel-server/Makefile
 307 doc/reference/librygel-renderer-gst/Makefile
 308 po/Makefile.in
 309 rygel-core-2.0.pc
 310 rygel-renderer-2.0.pc
 311 rygel-server-2.0.pc
 312 rygel-renderer-gst-2.0.pc
 313 tests/Makefile
 314 examples/Makefile
 315 examples/renderer-plugins/Makefile
 316 examples/renderer-plugins/vala/Makefile
 317 examples/renderer-plugins/C/Makefile
 318 examples/server-plugins/Makefile
 319 examples/server-plugins/vala/Makefile
 320 examples/server-plugins/C/Makefile
 321 ])
 322 AC_OUTPUT
 323
 324 echo "
 325
 326                     ${PACKAGE} ${VERSION}
 327                     ============
 328
 329
 330         Prefix:                 ${prefix}
 331         Source code location:   ${srcdir}
 332         Compiler:               ${CC}
 333         CFLAGS:                 ${CFLAGS}
 334         VALAFLAGS:              ${VALAFLAGS}
 335         uninstalled:            ${enable_uninstalled}
 336         preferences ui:         ${HAVE_GTK}
 337         Media Engine:           ${with_media_engine}
 338     Plugins:
 339         examples:               ${enable_example_plugins}
 340         tracker:                ${enable_tracker_plugin}
 341         mediathek:              ${enable_mediathek_plugin}
 342         media-export            ${enable_media_export_plugin}
 343         external:               ${enable_external_plugin}
 344         MPRIS2:                 ${enable_mpris_plugin}
 345         gst-launch:             ${enable_gst_launch_plugin}
 346         playbin:                ${enable_playbin_plugin}
 347 "