configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ([2.56])
   5 AC_INIT([libjpeg-turbo], [1.3.1])
   6 BUILD=`date +%Y%m%d`
   7
   8 AM_INIT_AUTOMAKE([-Wall foreign dist-bzip2])
   9 AC_PREFIX_DEFAULT(/opt/libjpeg-turbo)
  10
  11 # Always build with prototypes
  12 AC_DEFINE([HAVE_PROTOTYPES], 1, [Define if your compiler supports prototypes])
  13
  14 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  15
  16 # Checks for programs.
  17 SAVED_CFLAGS=${CFLAGS}
  18 SAVED_CPPFLAGS=${CPPFLAGS}
  19 AC_PROG_CPP
  20 AC_PROG_CC
  21 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  22 AM_PROG_AS
  23 AM_PROG_CC_C_O
  24 AC_PROG_INSTALL
  25 AC_PROG_LIBTOOL
  26 AC_PROG_LN_S
  27
  28 # When the prefix is /opt/libjpeg-turbo, we assume that an "official" binary is
  29 # being created, and thus we install things into specific locations.
  30
  31 old_prefix=${prefix}
  32 if test "x$prefix" = "xNONE" -a "x$ac_default_prefix" != "x"; then
  33   prefix=$ac_default_prefix
  34 fi
  35 DATADIR=`eval echo ${datadir}`
  36 DATADIR=`eval echo $DATADIR`
  37 if test "$DATADIR" = "/opt/libjpeg-turbo/share"; then
  38   datadir='${prefix}'
  39 fi
  40 DATADIR=`eval echo ${datarootdir}`
  41 DATADIR=`eval echo $DATADIR`
  42 if test "$DATADIR" = "/opt/libjpeg-turbo/share"; then
  43   datarootdir='${prefix}'
  44 fi
  45
  46 old_exec_prefix=${exec_prefix}
  47 if test "x$exec_prefix" = "xNONE"; then
  48   exec_prefix=${prefix}
  49 fi
  50
  51 if test "x${libdir}" = 'x${exec_prefix}/lib' -o "x${libdir}" = 'x${prefix}/lib'; then
  52   LIBDIR=`eval echo ${libdir}`
  53   LIBDIR=`eval echo $LIBDIR`
  54   if test "$LIBDIR" = "/opt/libjpeg-turbo/lib"; then
  55     case $host_os in
  56       darwin*)
  57         ;;
  58       *)
  59         AC_CHECK_SIZEOF(long)
  60         if test "${ac_cv_sizeof_long}" = "8"; then
  61           libdir='${exec_prefix}/lib64'
  62         elif test "${ac_cv_sizeof_long}" = "4"; then
  63           libdir='${exec_prefix}/lib32'
  64         fi
  65         ;;
  66     esac
  67   fi
  68 fi
  69 exec_prefix=${old_exec_prefix}
  70 prefix=${old_prefix}
  71
  72 # Check whether compiler supports pointers to undefined structures
  73 AC_MSG_CHECKING(whether compiler supports pointers to undefined structures)
  74 AC_TRY_COMPILE([ typedef struct undefined_structure * undef_struct_ptr; ], ,
  75   AC_MSG_RESULT(yes),
  76   [AC_MSG_RESULT(no)
  77    AC_DEFINE([INCOMPLETE_TYPES_BROKEN], [1],
  78      [Compiler does not support pointers to undefined structures.])])
  79
  80 if test "x${GCC}" = "xyes"; then
  81   if test "x${SAVED_CFLAGS}" = "x"; then
  82     CFLAGS=-O3
  83   fi
  84   if test "x${SAVED_CPPFLAGS}" = "x"; then
  85     CPPFLAGS=-Wall
  86   fi
  87 fi
  88
  89 AC_CHECK_DECL([__SUNPRO_C], [SUNCC="yes"], [SUNCC="no"])
  90 if test "x${SUNCC}" = "xyes"; then
  91   if test "x${SAVED_CFLAGS}" = "x"; then
  92     CFLAGS=-xO5
  93   fi
  94 fi
  95
  96 # Checks for libraries.
  97
  98 # Checks for header files.
  99 AC_HEADER_STDC
 100 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 101 AC_CHECK_HEADER([sys/types.h],
 102   AC_DEFINE([NEED_SYS_TYPES_H], 1, [Define if you have sys/types.h]))
 103
 104 # Checks for typedefs, structures, and compiler characteristics.
 105 AC_C_CONST
 106 AC_C_CHAR_UNSIGNED
 107 AC_C_INLINE
 108 AC_TYPE_SIZE_T
 109 AC_CHECK_TYPES([unsigned char, unsigned short])
 110
 111 AC_MSG_CHECKING([if right shift is signed])
 112 AC_TRY_RUN(
 113   [#include <stdio.h>
 114    int is_shifting_signed (long arg) {
 115      long res = arg >> 4;
 116
 117      if (res == -0x7F7E80CL)
 118        return 1; /* right shift is signed */
 119
 120      /* see if unsigned-shift hack will fix it. */
 121      /* we can't just test exact value since it depends on width of long... */
 122      res |= (~0L) << (32-4);
 123      if (res == -0x7F7E80CL)
 124        return 0; /* right shift is unsigned */
 125
 126      printf("Right shift isn't acting as I expect it to.\n");
 127      printf("I fear the JPEG software will not work at all.\n\n");
 128      return 0; /* try it with unsigned anyway */
 129    }
 130    int main (void) {
 131      exit(is_shifting_signed(-0x7F7E80B1L));
 132    }],
 133   [AC_MSG_RESULT(no)
 134    AC_DEFINE([RIGHT_SHIFT_IS_UNSIGNED], 1, [Define if shift is unsigned])],
 135   [AC_MSG_RESULT(yes)],
 136   [AC_MSG_RESULT(Assuming that right shift is signed on target machine.)])
 137
 138 # test whether global names are unique to at least 15 chars
 139 AC_MSG_CHECKING([for short external names])
 140 AC_TRY_LINK(
 141   [int possibly_duplicate_function () { return 0; }
 142    int possibly_dupli_function () { return 1; }], [ ],
 143   [AC_MSG_RESULT(ok)],
 144   [AC_MSG_RESULT(short)
 145    AC_DEFINE([NEED_SHORT_EXTERNAL_NAMES], 1,
 146      [Define if you need short function names])])
 147
 148 # Checks for library functions.
 149 AC_CHECK_FUNCS([memset memcpy], [],
 150   [AC_DEFINE([NEED_BSD_STRINGS], 1,
 151      [Define if you have BSD-like bzero and bcopy])])
 152
 153 AC_MSG_CHECKING([libjpeg API version])
 154 AC_ARG_VAR(JPEG_LIB_VERSION, [libjpeg API version (62, 70, or 80)])
 155 if test "x$JPEG_LIB_VERSION" = "x"; then
 156   AC_ARG_WITH([jpeg7],
 157     AC_HELP_STRING([--with-jpeg7],
 158       [Emulate libjpeg v7 API/ABI (this makes libjpeg-turbo backward incompatible with libjpeg v6b.)]))
 159   AC_ARG_WITH([jpeg8],
 160     AC_HELP_STRING([--with-jpeg8],
 161       [Emulate libjpeg v8 API/ABI (this makes libjpeg-turbo backward incompatible with libjpeg v6b.)]))
 162   if test "x${with_jpeg8}" = "xyes"; then
 163     JPEG_LIB_VERSION=80
 164   else
 165     if test "x${with_jpeg7}" = "xyes"; then
 166       JPEG_LIB_VERSION=70
 167     else
 168       JPEG_LIB_VERSION=62
 169     fi
 170   fi
 171 fi
 172 JPEG_LIB_VERSION_DECIMAL=`expr $JPEG_LIB_VERSION / 10`.`expr $JPEG_LIB_VERSION % 10`
 173 AC_SUBST(JPEG_LIB_VERSION_DECIMAL)
 174 AC_MSG_RESULT([$JPEG_LIB_VERSION_DECIMAL])
 175 AC_DEFINE_UNQUOTED(JPEG_LIB_VERSION, [$JPEG_LIB_VERSION],
 176   [libjpeg API version])
 177
 178 AC_ARG_VAR(SO_MAJOR_VERSION,
 179   [Major version of the libjpeg-turbo shared library (default is determined by the API version)])
 180 AC_ARG_VAR(SO_MINOR_VERSION,
 181   [Minor version of the libjpeg-turbo shared library (default is determined by the API version)])
 182 if test "x$SO_MAJOR_VERSION" = "x"; then
 183   case "$JPEG_LIB_VERSION" in
 184     62)  SO_MAJOR_VERSION=$JPEG_LIB_VERSION ;;
 185     *)   SO_MAJOR_VERSION=`expr $JPEG_LIB_VERSION / 10` ;;
 186   esac
 187 fi
 188 if test "x$SO_MINOR_VERSION" = "x"; then
 189   case "$JPEG_LIB_VERSION" in
 190     80)  SO_MINOR_VERSION=2 ;;
 191     *)   SO_MINOR_VERSION=0 ;;
 192   esac
 193 fi
 194
 195 RPM_CONFIG_ARGS=
 196
 197 # Memory source/destination managers
 198 SO_AGE=0
 199 MEM_SRCDST_FUNCTIONS=
 200 if test "x${with_jpeg8}" != "xyes"; then
 201   AC_MSG_CHECKING([whether to include in-memory source/destination managers])
 202   AC_ARG_WITH([mem-srcdst],
 203     AC_HELP_STRING([--without-mem-srcdst],
 204       [Do not include in-memory source/destination manager functions when emulating the libjpeg v6b or v7 API/ABI]))
 205   if test "x$with_mem_srcdst" != "xno"; then
 206     AC_MSG_RESULT(yes)
 207     AC_DEFINE([MEM_SRCDST_SUPPORTED], [1],
 208       [Support in-memory source/destination managers])
 209     SO_AGE=1
 210     MEM_SRCDST_FUNCTIONS="global:  jpeg_mem_dest;  jpeg_mem_src;";
 211   else
 212     AC_MSG_RESULT(no)
 213     RPM_CONFIG_ARGS="$RPM_CONFIG_ARGS --without-mem-srcdst"
 214   fi
 215 fi
 216
 217 AC_MSG_CHECKING([libjpeg shared library version])
 218 AC_MSG_RESULT([$SO_MAJOR_VERSION.$SO_AGE.$SO_MINOR_VERSION])
 219 LIBTOOL_CURRENT=`expr $SO_MAJOR_VERSION + $SO_AGE`
 220 AC_SUBST(LIBTOOL_CURRENT)
 221 AC_SUBST(SO_MAJOR_VERSION)
 222 AC_SUBST(SO_MINOR_VERSION)
 223 AC_SUBST(SO_AGE)
 224 AC_SUBST(MEM_SRCDST_FUNCTIONS)
 225
 226 AC_DEFINE_UNQUOTED(LIBJPEG_TURBO_VERSION, [$VERSION], [libjpeg-turbo version])
 227
 228 VERSION_SCRIPT=yes
 229 AC_ARG_ENABLE([ld-version-script],
 230   AS_HELP_STRING([--disable-ld-version-script],
 231     [Disable linker version script for libjpeg-turbo (default is to use linker version script if the linker supports it)]),
 232   [VERSION_SCRIPT=$enableval], [])
 233
 234 AC_MSG_CHECKING([whether the linker supports version scripts])
 235 SAVED_LDFLAGS="$LDFLAGS"
 236 LDFLAGS="$LDFLAGS -Wl,--version-script,conftest.map"
 237 cat > conftest.map <<EOF
 238 VERS_1 {
 239   global: *;
 240 };
 241 EOF
 242 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 243   [VERSION_SCRIPT_FLAG=-Wl,--version-script,;
 244    AC_MSG_RESULT([yes (GNU style)])],
 245   [])
 246 if test "x$VERSION_SCRIPT_FLAG" = "x"; then
 247   LDFLAGS="$SAVED_LDFLAGS -Wl,-M,conftest.map"
 248   AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 249     [VERSION_SCRIPT_FLAG=-Wl,-M,;
 250      AC_MSG_RESULT([yes (Sun style)])],
 251     [])
 252 fi
 253 if test "x$VERSION_SCRIPT_FLAG" = "x"; then
 254   VERSION_SCRIPT=no
 255   AC_MSG_RESULT(no)
 256 fi
 257 LDFLAGS="$SAVED_LDFLAGS"
 258
 259 AC_MSG_CHECKING([whether to use version script when building libjpeg-turbo])
 260 AC_MSG_RESULT($VERSION_SCRIPT)
 261
 262 AM_CONDITIONAL(VERSION_SCRIPT, test "x$VERSION_SCRIPT" = "xyes")
 263 AC_SUBST(VERSION_SCRIPT_FLAG)
 264
 265 # Check for non-broken inline under various spellings
 266 AC_MSG_CHECKING(for inline)
 267 ljt_cv_inline=""
 268 AC_TRY_COMPILE(, [} __attribute__((always_inline)) int foo() { return 0; }
 269 int bar() { return foo();], ljt_cv_inline="inline __attribute__((always_inline))",
 270 AC_TRY_COMPILE(, [} __inline__ int foo() { return 0; }
 271 int bar() { return foo();], ljt_cv_inline="__inline__",
 272 AC_TRY_COMPILE(, [} __inline int foo() { return 0; }
 273 int bar() { return foo();], ljt_cv_inline="__inline",
 274 AC_TRY_COMPILE(, [} inline int foo() { return 0; }
 275 int bar() { return foo();], ljt_cv_inline="inline"))))
 276 AC_MSG_RESULT($ljt_cv_inline)
 277 AC_DEFINE_UNQUOTED([INLINE],[$ljt_cv_inline],[How to obtain function inlining.])
 278
 279 # Arithmetic coding support
 280 AC_MSG_CHECKING([whether to include arithmetic encoding support])
 281 AC_ARG_WITH([arith-enc],
 282   AC_HELP_STRING([--without-arith-enc],
 283     [Do not include arithmetic encoding support]))
 284 if test "x$with_arith_enc" = "xno"; then
 285   AC_MSG_RESULT(no)
 286   RPM_CONFIG_ARGS="$RPM_CONFIG_ARGS --without-arith-enc"
 287 else
 288   AC_DEFINE([C_ARITH_CODING_SUPPORTED], [1], [Support arithmetic encoding])
 289   AC_MSG_RESULT(yes)
 290 fi
 291 AM_CONDITIONAL([WITH_ARITH_ENC], [test "x$with_arith_enc" != "xno"])
 292
 293 AC_MSG_CHECKING([whether to include arithmetic decoding support])
 294 AC_ARG_WITH([arith-dec],
 295   AC_HELP_STRING([--without-arith-dec],
 296     [Do not include arithmetic decoding support]))
 297 if test "x$with_arith_dec" = "xno"; then
 298   AC_MSG_RESULT(no)
 299   RPM_CONFIG_ARGS="$RPM_CONFIG_ARGS --without-arith-dec"
 300 else
 301   AC_DEFINE([D_ARITH_CODING_SUPPORTED], [1], [Support arithmetic decoding])
 302   AC_MSG_RESULT(yes)
 303 fi
 304 AM_CONDITIONAL([WITH_ARITH_DEC], [test "x$with_arith_dec" != "xno"])
 305
 306 AM_CONDITIONAL([WITH_ARITH],
 307   [test "x$with_arith_dec" != "xno" -o "x$with_arith_enc" != "xno"])
 308
 309 # TurboJPEG support
 310 AC_MSG_CHECKING([whether to build TurboJPEG C wrapper])
 311 AC_ARG_WITH([turbojpeg],
 312   AC_HELP_STRING([--without-turbojpeg],
 313     [Do not include the TurboJPEG wrapper library and associated test programs]))
 314 if test "x$with_turbojpeg" = "xno"; then
 315   AC_MSG_RESULT(no)
 316   RPM_CONFIG_ARGS="$RPM_CONFIG_ARGS --without-turbojpeg"
 317 else
 318   AC_MSG_RESULT(yes)
 319 fi
 320
 321 # Java support
 322 AC_ARG_VAR(JAVAC, [Java compiler command (default: javac)])
 323 if test "x$JAVAC" = "x"; then
 324   JAVAC=javac
 325 fi
 326 AC_SUBST(JAVAC)
 327 AC_ARG_VAR(JAVACFLAGS, [Java compiler flags])
 328 AC_SUBST(JAVACFLAGS)
 329 AC_ARG_VAR(JAR, [Java archive command (default: jar)])
 330 if test "x$JAR" = "x"; then
 331   JAR=jar
 332 fi
 333 AC_SUBST(JAR)
 334 AC_ARG_VAR(JAVA, [Java runtime command (default: java)])
 335 if test "x$JAVA" = "x"; then
 336   JAVA=java
 337 fi
 338 AC_SUBST(JAVA)
 339 AC_ARG_VAR(JNI_CFLAGS,
 340   [C compiler flags needed to include jni.h (default: -I/System/Library/Frameworks/JavaVM.framework/Headers on OS X, '-I/usr/java/include -I/usr/java/include/solaris' on Solaris, and '-I/usr/java/default/include -I/usr/java/default/include/linux' on Linux)])
 341
 342 AC_MSG_CHECKING([whether to build TurboJPEG Java wrapper])
 343 AC_ARG_WITH([java],
 344   AC_HELP_STRING([--with-java], [Build Java wrapper for the TurboJPEG library]))
 345 if test "x$with_turbojpeg" = "xno"; then
 346   with_java=no
 347 fi
 348
 349 WITH_JAVA=0
 350 if test "x$with_java" = "xyes"; then
 351   AC_MSG_RESULT(yes)
 352
 353   case $host_os in
 354     darwin*)
 355       DEFAULT_JNI_CFLAGS=-I/System/Library/Frameworks/JavaVM.framework/Headers
 356       ;;
 357     solaris*)
 358       DEFAULT_JNI_CFLAGS='-I/usr/java/include -I/usr/java/include/solaris'
 359       ;;
 360     linux*)
 361       DEFAULT_JNI_CFLAGS='-I/usr/java/default/include -I/usr/java/default/include/linux'
 362       ;;
 363   esac
 364   if test "x$JNI_CFLAGS" = "x"; then
 365     JNI_CFLAGS=$DEFAULT_JNI_CFLAGS
 366   fi
 367
 368   SAVE_CPPFLAGS=${CPPFLAGS}
 369   CPPFLAGS="${CPPFLAGS} ${JNI_CFLAGS}"
 370   AC_CHECK_HEADERS([jni.h], [DUMMY=1],
 371     [AC_MSG_ERROR([Could not find JNI header file])])
 372   CPPFLAGS=${SAVE_CPPFLAGS}
 373   AC_SUBST(JNI_CFLAGS)
 374
 375   RPM_CONFIG_ARGS="$RPM_CONFIG_ARGS --with-java"
 376   JAVA_RPM_CONTENTS_1='%dir %{_datadir}/classes'
 377   JAVA_RPM_CONTENTS_2=%{_datadir}/classes/turbojpeg.jar
 378   WITH_JAVA=1
 379 else
 380   AC_MSG_RESULT(no)
 381 fi
 382 AM_CONDITIONAL([WITH_JAVA], [test "x$with_java" = "xyes"])
 383 AC_SUBST(WITH_JAVA)
 384 AC_SUBST(JAVA_RPM_CONTENTS_1)
 385 AC_SUBST(JAVA_RPM_CONTENTS_2)
 386
 387 # optionally force using gas-preprocessor.pl for compatibility testing
 388 AC_ARG_WITH([gas-preprocessor],
 389   AC_HELP_STRING([--with-gas-preprocessor],
 390     [Force using gas-preprocessor.pl on ARM.]))
 391 if test "x${with_gas_preprocessor}" = "xyes"; then
 392   case $host_os in
 393     darwin*)
 394       CCAS="gas-preprocessor.pl -fix-unreq $CC"
 395       ;;
 396     *)
 397       CCAS="gas-preprocessor.pl -no-fix-unreq $CC"
 398       ;;
 399   esac
 400   AC_SUBST([CCAS])
 401 fi
 402
 403 # SIMD is optional
 404 AC_ARG_WITH([simd],
 405   AC_HELP_STRING([--without-simd], [Do not include SIMD extensions]))
 406 if test "x${with_simd}" != "xno"; then
 407   require_simd=no
 408   if test "x${with_simd}" = "xyes"; then
 409     require_simd=yes
 410   fi
 411   # Check if we're on a supported CPU
 412   AC_MSG_CHECKING([if we have SIMD optimisations for cpu type])
 413   case "$host_cpu" in
 414     x86_64 | amd64)
 415       AC_MSG_RESULT([yes (x86_64)])
 416       AC_PROG_NASM
 417       simd_arch=x86_64
 418       ;;
 419     i*86 | x86 | ia32)
 420       AC_MSG_RESULT([yes (i386)])
 421       AC_PROG_NASM
 422       simd_arch=i386
 423       ;;
 424     arm*)
 425       AC_MSG_RESULT([yes (arm)])
 426       AC_MSG_CHECKING([if the assembler is GNU-compatible and can be used])
 427       AC_CHECK_COMPATIBLE_ARM_ASSEMBLER_IFELSE(
 428         [AC_MSG_RESULT([yes])
 429          simd_arch=arm],
 430         [AC_MSG_RESULT([no])
 431          with_simd=no])
 432       if test "x${with_simd}" = "xno"; then
 433         if test "x${require_simd}" = "xyes"; then
 434           AC_MSG_ERROR([SIMD support can't be enabled.])
 435         else
 436           AC_MSG_WARN([SIMD support can't be enabled.  Performance will suffer.])
 437         fi
 438       fi
 439       ;;
 440     *)
 441       AC_MSG_RESULT([no ("$host_cpu")])
 442       with_simd=no;
 443       if test "x${require_simd}" = "xyes"; then
 444         AC_MSG_ERROR([SIMD support not available for this CPU.])
 445       else
 446         AC_MSG_WARN([SIMD support not available for this CPU.  Performance will suffer.])
 447       fi
 448       ;;
 449   esac
 450
 451   if test "x${with_simd}" != "xno"; then
 452     AC_DEFINE([WITH_SIMD], [1], [Use accelerated SIMD routines.])
 453   fi
 454 else
 455   RPM_CONFIG_ARGS="$RPM_CONFIG_ARGS --without-simd"
 456 fi
 457
 458 AM_CONDITIONAL([WITH_SIMD], [test "x$with_simd" != "xno"])
 459 AM_CONDITIONAL([WITH_SSE_FLOAT_DCT], [test "x$simd_arch" = "xx86_64" -o "x$simd_arch" = "xi386"])
 460 AM_CONDITIONAL([SIMD_I386], [test "x$simd_arch" = "xi386"])
 461 AM_CONDITIONAL([SIMD_X86_64], [test "x$simd_arch" = "xx86_64"])
 462 AM_CONDITIONAL([SIMD_ARM], [test "x$simd_arch" = "xarm"])
 463 AM_CONDITIONAL([X86_64], [test "x$host_cpu" = "xx86_64" -o "x$host_cpu" = "xamd64"])
 464 AM_CONDITIONAL([WITH_TURBOJPEG], [test "x$with_turbojpeg" != "xno"])
 465
 466 AC_ARG_VAR(PKGNAME, [distribution package name (default: libjpeg-turbo)])
 467 if test "x$PKGNAME" = "x"; then
 468   PKGNAME=$PACKAGE_NAME
 469 fi
 470 AC_SUBST(PKGNAME)
 471
 472 case "$host_cpu" in
 473   x86_64)
 474     RPMARCH=x86_64
 475     DEBARCH=amd64
 476     ;;
 477   i*86 | x86 | ia32)
 478     RPMARCH=i386
 479     DEBARCH=i386
 480     ;;
 481 esac
 482
 483 AC_SUBST(RPMARCH)
 484 AC_SUBST(RPM_CONFIG_ARGS)
 485 AC_SUBST(DEBARCH)
 486 AC_SUBST(BUILD)
 487 AC_DEFINE_UNQUOTED([BUILD], "$BUILD", [Build number])
 488
 489 # jconfig.h is the file we use, but we have another before that to
 490 # fool autoheader. the reason is that we include this header in our
 491 # API headers, which can screw things up for users of the lib.
 492 # jconfig.h is a minimal version that allows this package to be built
 493 AC_CONFIG_HEADERS([config.h])
 494 AC_CONFIG_HEADERS([jconfig.h])
 495 AC_CONFIG_FILES([pkgscripts/libjpeg-turbo.spec.tmpl:release/libjpeg-turbo.spec.in])
 496 AC_CONFIG_FILES([pkgscripts/makecygwinpkg.tmpl:release/makecygwinpkg.in])
 497 AC_CONFIG_FILES([pkgscripts/makedpkg.tmpl:release/makedpkg.in])
 498 AC_CONFIG_FILES([pkgscripts/makemacpkg.tmpl:release/makemacpkg.in])
 499 AC_CONFIG_FILES([pkgscripts/Description.plist:release/Description.plist.in])
 500 AC_CONFIG_FILES([pkgscripts/Info.plist:release/Info.plist.in])
 501 AC_CONFIG_FILES([pkgscripts/uninstall.tmpl:release/uninstall.in])
 502 if test "x$with_turbojpeg" != "xno"; then
 503   AC_CONFIG_FILES([tjbenchtest])
 504 fi
 505 if test "x$with_java" = "xyes"; then
 506   AC_CONFIG_FILES([tjbenchtest.java])
 507   AC_CONFIG_FILES([tjexampletest])
 508 fi
 509 AC_CONFIG_FILES([libjpeg.map])
 510 AC_CONFIG_FILES([Makefile simd/Makefile])
 511 AC_CONFIG_FILES([java/Makefile])
 512 AC_CONFIG_FILES([md5/Makefile])
 513 AC_OUTPUT