configure.ac

   1 #  Copyright 2005 Adam Jackson.
   2 #
   3 #  Permission is hereby granted, free of charge, to any person obtaining a
   4 #  copy of this software and associated documentation files (the "Software"),
   5 #  to deal in the Software without restriction, including without limitation
   6 #  on the rights to use, copy, modify, merge, publish, distribute, sub
   7 #  license, and/or sell copies of the Software, and to permit persons to whom
   8 #  the Software is furnished to do so, subject to the following conditions:
   9 #
  10 #  The above copyright notice and this permission notice (including the next
  11 #  paragraph) shall be included in all copies or substantial portions of the
  12 #  Software.
  13 #
  14 #  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15 #  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16 #  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
  17 #  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
  18 #  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  19 #  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  20 #
  21 # Process this file with autoconf to produce a configure script
  22
  23 AC_PREREQ([2.60])
  24 AC_INIT([intel-gpu-tools],
  25         [1.4],
  26         [https://bugs.freedesktop.org/enter_bug.cgi?product=xorg],
  27         [intel-gpu-tools])
  28
  29 AC_CONFIG_SRCDIR([Makefile.am])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_MACRO_DIR([m4])
  32 AC_CONFIG_AUX_DIR([build-aux])
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_GNU_SOURCE
  36
  37 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  38 AM_PATH_PYTHON([3],, [:])
  39
  40 AC_PROG_CC
  41 AM_PROG_LEX
  42 AC_PROG_YACC
  43
  44 # Checks for functions, headers, structures, etc.
  45 AC_HEADER_STDC
  46 AC_CHECK_HEADERS([termios.h])
  47 AC_CHECK_MEMBERS([struct sysinfo.totalram],[],[],[AC_INCLUDES_DEFAULT
  48                   #include <sys/sysinfo.h>
  49                   ])
  50 AC_CHECK_FUNCS([swapctl])
  51 AC_CHECK_FUNCS([asprintf])
  52
  53 # Initialize libtool
  54 AC_DISABLE_STATIC
  55 AC_PROG_LIBTOOL
  56
  57 # Require X.Org macros 1.16 or later for XORG_TESTSET_CFLAG
  58 m4_ifndef([XORG_MACROS_VERSION],
  59           [m4_fatal([must install xorg-macros 1.16 or later before running autoconf/autogen])])
  60 XORG_MACROS_VERSION(1.16)
  61 XORG_DEFAULT_OPTIONS
  62
  63 # warning flags for the assembler. We can't quite use CWARNFLAGS for it yet as
  64 # it generates waaaay too many warnings.
  65 ASSEMBLER_WARN_CFLAGS=""
  66 if test "x$GCC" = "xyes"; then
  67         ASSEMBLER_WARN_CFLAGS="-Wall -Wstrict-prototypes \
  68         -Wmissing-prototypes -Wmissing-declarations \
  69         -Wnested-externs -fno-strict-aliasing"
  70 fi
  71 AC_SUBST(ASSEMBLER_WARN_CFLAGS)
  72
  73 PKG_CHECK_MODULES(DRM, [libdrm_intel >= 2.4.40 libdrm])
  74 PKG_CHECK_MODULES(PCIACCESS, [pciaccess >= 0.10])
  75 PKG_CHECK_MODULES(OVERLAY_XVLIB, [xv x11 xext], enable_overlay_xvlib=yes, enable_overlay_xvlib=no)
  76 PKG_CHECK_MODULES(OVERLAY_XLIB, [cairo-xlib], enable_overlay_xlib=yes, enable_overlay_xlib=no)
  77
  78 AM_CONDITIONAL(BUILD_OVERLAY_XVLIB, [test "x$enable_overlay_xvlib" = xyes])
  79 AM_CONDITIONAL(BUILD_OVERLAY_XLIB, [test "x$enable_overlay_xlib" = xyes])
  80 AM_CONDITIONAL(BUILD_OVERLAY, [test "x$enable_overlay_xlib" = xyes -o "x$enable_overlay_xvlib"])
  81 if test x$enable_overlay_xvlib = xyes; then
  82         AC_DEFINE(HAVE_OVERLAY_XVLIB, 1, [Enable XV backend])
  83 fi
  84 if test x$enable_overlay_xlib = xyes; then
  85         AC_DEFINE(HAVE_OVERLAY_XLIB, 1, [Enable X backend])
  86 fi
  87 PKG_CHECK_MODULES(XRANDR, xrandr >= 1.3, AC_DEFINE(HAVE_XRANDR, 1, [Have libXrandr]), [have_xrandr=no])
  88
  89 # for testdisplay
  90 PKG_CHECK_MODULES(CAIRO, [cairo >= 1.12.0])
  91 PKG_CHECK_MODULES(LIBUDEV, [libudev], [udev=yes], [udev=no])
  92 if test x"$udev" = xyes; then
  93         AC_DEFINE(HAVE_UDEV,1,[Enable udev-based monitor hotplug detection])
  94 fi
  95 PKG_CHECK_MODULES(GLIB, glib-2.0)
  96
  97 # can we build the assembler?
  98 AS_IF([test x"$LEX" != "x:" -a x"$YACC" != xyacc],
  99       [enable_assembler=yes],
 100       [enable_assembler=no])
 101 AM_CONDITIONAL(BUILD_ASSEMBLER, [test "x$enable_assembler" = xyes])
 102
 103 # -----------------------------------------------------------------------------
 104 #                       Configuration options
 105 # -----------------------------------------------------------------------------
 106 # for dma-buf tests
 107 AC_ARG_ENABLE(nouveau, AS_HELP_STRING([--disable-nouveau],
 108               [Enable use of nouveau API for prime tests (default: enabled)]),
 109               [NOUVEAU=$enableval], [NOUVEAU=yes])
 110 if test "x$NOUVEAU" = xyes; then
 111         PKG_CHECK_MODULES(DRM_NOUVEAU, [libdrm_nouveau >= 2.4.33])
 112         AC_DEFINE(HAVE_NOUVEAU, 1, [Have nouveau support])
 113 fi
 114 AM_CONDITIONAL(HAVE_NOUVEAU, [test "x$NOUVEAU" = xyes])
 115
 116 #Configure options for the python quick-dumper
 117 AC_ARG_ENABLE(dumper,
 118               AS_HELP_STRING([--disable-dumper],
 119                              [Disable the python based register dumper (default: enabled)]),
 120                              [DUMPER=$enableval], [DUMPER=yes])
 121 if test "x$DUMPER" == xyes; then
 122         AC_DEFINE(HAVE_DUMPER, 1, [Have dumper support])
 123         # SWIG configuration
 124         AX_PKG_SWIG(2.0.0, [], [ AC_MSG_ERROR([SWIG 2.0.0 or higher is required to build..]) ])
 125         AX_PYTHON_DEVEL([>= '3.0'])
 126         AX_SWIG_PYTHON
 127 fi
 128 AM_CONDITIONAL(HAVE_DUMPER, [test "x$DUMPER" = xyes])
 129
 130 # Define a configure option for the shadder debugger
 131 AC_ARG_ENABLE(shader-debugger, AS_HELP_STRING([--enable-shader-debugger],
 132               [Enable shader debugging support [autodetected]]),
 133               [BUILD_SHADER_DEBUGGER="$enableval"], [BUILD_SHADER_DEBUGGER=auto])
 134
 135 # Shadder debugger depends on python3, intel-genasm and objcopy
 136 if test "x$BUILD_SHADER_DEBUGGER" != xno; then
 137         # Check Python 3 is installed
 138         if test "$PYTHON" = ":" ; then
 139                 if test "x$BUILD_SHADER_DEBUGGER" = xyes; then
 140                         AC_MSG_ERROR([Shader debugger requested, python version 3 not found.])
 141                 else
 142                         BUILD_SHADER_DEBUGGER=no
 143                 fi
 144         fi
 145         # Check for the Intel Chipset assembler compiler
 146         AC_PATH_PROGS([GEN4ASM], intel-gen4asm)
 147         if test -z "$GEN4ASM" ; then
 148                 if test "x$BUILD_SHADER_DEBUGGER" = xyes; then
 149                         AC_MSG_ERROR([Shader debugger requested, but intel-gen4asm not found.])
 150                 else
 151                         BUILD_SHADER_DEBUGGER=no
 152                 fi
 153         fi
 154         # Check for the objcopy GNU binary utiliy command
 155         AC_PATH_PROGS([OBJCOPY], objcopy)
 156         if test -z "$OBJCOPY" ; then
 157                 if test "x$BUILD_SHADER_DEBUGGER" = xyes; then
 158                         AC_MSG_ERROR([Shader debugger requested, but objcopy command not found.])
 159                 else
 160                         BUILD_SHADER_DEBUGGER=no
 161                 fi
 162         fi
 163 fi
 164
 165 AM_CONDITIONAL(BUILD_SHADER_DEBUGGER, [test "x$BUILD_SHADER_DEBUGGER" != xno])
 166 AS_IF([test "x$BUILD_SHADER_DEBUGGER" != xno],
 167       [enable_debugger=yes], [enable_debugger=no])
 168
 169 # -----------------------------------------------------------------------------
 170
 171 # To build multithread code, gcc uses -pthread, Solaris Studio cc uses -mt
 172 XORG_TESTSET_CFLAG([THREAD_CFLAGS], [-pthread], [-mt])
 173 AC_SUBST([THREAD_CFLAGS])
 174
 175 AC_ARG_ENABLE(tests,
 176               AS_HELP_STRING([--disable-tests],
 177               [Disable tests build (default: enabled)]),
 178               [BUILD_TESTS=$enableval], [BUILD_TESTS="yes"])
 179 if test "x$BUILD_TESTS" = xyes; then
 180         AC_DEFINE(BUILD_TESTS, 1, [Build tests])
 181 fi
 182 AM_CONDITIONAL(BUILD_TESTS, [test "x$BUILD_TESTS" = xyes])
 183
 184 AC_CONFIG_FILES([
 185                  Makefile
 186                  benchmarks/Makefile
 187                  demos/Makefile
 188                  lib/Makefile
 189                  man/Makefile
 190                  scripts/Makefile
 191                  tests/Makefile
 192                  tools/Makefile
 193                  tools/quick_dump/Makefile
 194                  debugger/Makefile
 195                  debugger/system_routine/Makefile
 196                  assembler/Makefile
 197                  assembler/doc/Makefile
 198                  assembler/test/Makefile
 199                  assembler/intel-gen4asm.pc
 200                  overlay/Makefile
 201                  ])
 202 AC_OUTPUT
 203
 204 # Print a summary of the compilation
 205 echo ""
 206 echo "Intel GPU tools"
 207
 208 echo ""
 209 echo " • Tests:"
 210 echo "       Build tests        : ${BUILD_TESTS}"
 211 echo "       Compile prime tests: ${NOUVEAU}"
 212 echo ""
 213 echo " • Tools:"
 214 echo "       Assembler          : ${enable_assembler}"
 215 echo "       Debugger           : ${enable_debugger}"
 216 echo "       Python dumper      : ${DUMPER}"
 217 echo "       Overlay            : X: ${enable_overlay_xlib}, Xv: ${enable_overlay_xvlib}"
 218 echo ""
 219
 220 # vim: set ft=config ts=8 sw=8 tw=0 noet :