configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([Rygel],
   3         [m4_esyscmd(GNOME_TAG_PATTERN=RYGEL build-aux/git-version-gen .tarball-version)],
   4         [http://bugzilla.gnome.org/enter_bug.cgi?product=Rygel],
   5         [rygel],
   6         [http://live.gnome.org/Rygel])
   7 AC_CONFIG_AUX_DIR([build-aux])
   8
   9 AC_CONFIG_SRCDIR([src/librygel-core/rygel-root-device.vala])
  10 AC_CONFIG_HEADERS([config.h])
  11 AC_CONFIG_MACRO_DIR([m4])
  12
  13 AC_SEARCH_LIBS([strerror],[cposix])
  14 AC_PROG_CC
  15 AC_HEADER_STDC
  16 AC_FUNC_MMAP
  17
  18 AC_SUBST(abs_top_builddir)
  19 AC_SUBST(VERSION)
  20
  21 dnl Initialize automake
  22 AM_INIT_AUTOMAKE([1.11.1 tar-ustar no-dist-gzip dist-xz -Wno-portability])
  23 AM_MAINTAINER_MODE([enable])
  24
  25 dnl Initialize libtool
  26 dnl Disable generation of static libraries
  27 LT_PREREQ([2.2.6])
  28 LT_INIT([dlopen disable-static])
  29
  30 dnl Required versions of library packages
  31 dnl Not all of these are actually used, depending on the configure options.
  32 GLIB_REQUIRED=2.31.13
  33 LIBXML_REQUIRED=2.7
  34 VALA_REQUIRED=0.18.0
  35 VALADOC_REQUIRED=0.2
  36 GSSDP_REQUIRED=0.13.0
  37 GUPNP_REQUIRED=0.19.0
  38 GUPNP_AV_REQUIRED=0.11.4
  39 GUPNP_DLNA_REQUIRED=0.7.0
  40 GSTREAMER_REQUIRED=1.0
  41 GSTPBU_REQUIRED=1.0
  42 GIO_REQUIRED=2.26
  43 GEE_REQUIRED=0.8.0
  44 UUID_REQUIRED=1.41.3
  45 LIBSOUP_REQUIRED=2.34.0
  46 GTK_REQUIRED=2.90.3
  47
  48 dnl Additional requirements for media-export plugin
  49 GSTREAMER_TAG_REQUIRED=1.0
  50 GSTREAMER_APP_REQUIRED=1.0
  51 LIBSQLITE3_REQUIRED=3.5
  52
  53 dnl Additional requirements for tracker plugin
  54 TRACKER_SPARQL_REQUIRED_MIN=0.14.0
  55
  56 VALAFLAGS="--target-glib=2.32 $VALAFLAGS"
  57
  58 RYGEL_BASE_MODULES='gupnp-1.0 >= $GUPNP_REQUIRED gee-0.8 >= $GEE_REQUIRED'
  59 PKG_CHECK_MODULES([LIBRYGEL_CORE_DEPS], [$RYGEL_BASE_MODULES uuid >= $UUID_REQUIRED gssdp-1.0 >= $GSSDP_REQUIRED gio-2.0 >= $GIO_REQUIRED])
  60 RYGEL_BASE_MODULES_VALAFLAGS='--pkg gupnp-1.0 --pkg gee-0.8'
  61 LIBRYGEL_CORE_DEPS_VALAFLAGS="$RYGEL_BASE_MODULES_VALAFLAGS --pkg gssdp-1.0 --pkg gio-2.0 --pkg gmodule-2.0"
  62 AC_SUBST([LIBRYGEL_CORE_DEPS_VALAFLAGS])
  63
  64 RYGEL_COMMON_MODULES="$RYGEL_BASE_MODULES gupnp-av-1.0 >= $GUPNP_AV_REQUIRED"
  65 PKG_CHECK_MODULES([LIBRYGEL_SERVER_DEPS], [$RYGEL_COMMON_MODULES uuid >= $UUID_REQUIRED gssdp-1.0 >= $GSSDP_REQUIRED gio-2.0 >= $GIO_REQUIRED libsoup-2.4 >= $LIBSOUP_REQUIRED])
  66 RYGEL_COMMON_MODULES_VALAFLAGS="$RYGEL_BASE_MODULES_VALAFLAGS --pkg gupnp-av-1.0"
  67 LIBRYGEL_SERVER_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS --pkg gssdp-1.0 --pkg gio-2.0 --pkg libsoup-2.4 --pkg gmodule-2.0"
  68 AC_SUBST([LIBRYGEL_SERVER_DEPS_VALAFLAGS])
  69
  70 PKG_CHECK_MODULES([LIBRYGEL_RENDERER_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED libsoup-2.4 >= $LIBSOUP_REQUIRED])
  71 LIBRYGEL_RENDERER_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS --pkg gio-2.0 --pkg libsoup-2.4"
  72 AC_SUBST([LIBRYGEL_RENDERER_DEPS_VALAFLAGS])
  73
  74 PKG_CHECK_MODULES([RYGEL_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED gssdp-1.0 >= $GSSDP_REQUIRED])
  75
  76 # Not all tests use all of these dependencies,
  77 # but having one set of dependencies keeps things simple.
  78 PKG_CHECK_MODULES([TEST_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED gssdp-1.0 >= $GSSDP_REQUIRED libsoup-2.4 >= $LIBSOUP_REQUIRED libxml-2.0 >= $LIBXML_REQUIRED])
  79 TEST_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS --pkg gio-2.0 --pkg gssdp-1.0 --pkg libsoup-2.4 --pkg libxml-2.0 --pkg gmodule-2.0"
  80 AC_SUBST([TEST_DEPS_VALAFLAGS])
  81
  82 PKG_CHECK_MODULES([EXAMPLE_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED gssdp-1.0 >= $GSSDP_REQUIRED])
  83
  84
  85
  86 dnl Media engine to use
  87 BUILT_ENGINES="librygel-media-engine-simple"
  88
  89 dnl Disabling the gstreamer media_engine also disables
  90 dnl anything else that uses gstreamer.
  91 AC_ARG_WITH([media_engine],
  92             AS_HELP_STRING(
  93                 [--with-media-engine=@<:@gstreamer|simple@:>@],
  94                 [Media Engine to use]),
  95             [with_media_engine="$withval"],
  96             [with_media_engine="gstreamer"])
  97
  98 AS_IF([test "x$with_media_engine" = "xgstreamer"],
  99       [
 100         enable_gstreamer="yes"
 101         BUILT_ENGINES="$BUILT_ENGINES;librygel-media-engine-gst"
 102
 103         PKG_CHECK_MODULES([RYGEL_MEDIA_ENGINE_GSTREAMER_DEPS], [$RYGEL_COMMON_MODULES gstreamer-pbutils-1.0 >= $GSTPBU_REQUIRED gupnp-dlna-1.1 >= $GUPNP_DLNA_REQUIRED])
 104         RYGEL_MEDIA_ENGINE_GSTREAMER_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS --pkg gstreamer-base-1.0 --pkg gstreamer-pbutils-1.0 --pkg gupnp-dlna-1.1"
 105         AC_SUBST([RYGEL_MEDIA_ENGINE_GSTREAMER_DEPS_VALAFLAGS])
 106
 107         PKG_CHECK_MODULES([LIBRYGEL_RENDERER_GST_DEPS], [$RYGEL_COMMON_MODULES gstreamer-1.0 >= $GSTREAMER_REQUIRED])
 108         LIBRYGEL_RENDERER_GST_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS --pkg gstreamer-1.0"
 109         AC_SUBST([LIBRYGEL_RENDERER_GST_DEPS_VALAFLAGS])
 110       ],
 111       [enable_gstreamer="no"])
 112 AM_CONDITIONAL([HAVE_GSTREAMER],[test "x$enable_gstreamer" = "xyes"])
 113 AC_SUBST([BUILT_ENGINES])
 114
 115 dnl Add plugins
 116 RYGEL_ADD_PLUGIN([external],[MediaServer2 DBus consumer],[yes])
 117 AS_IF([test "x$enable_external_plugin" = "xyes"],
 118   [
 119     PKG_CHECK_MODULES([RYGEL_PLUGIN_EXTERNAL_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED])
 120   ])
 121
 122 RYGEL_ADD_PLUGIN([mpris],[MPRIS2 DBus consumer],[yes])
 123 AS_IF([test "x$enable_mpris_plugin" = "xyes"],
 124   [
 125     PKG_CHECK_MODULES([RYGEL_PLUGIN_MPRIS_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED])
 126   ])
 127
 128 RYGEL_ADD_PLUGIN([mediathek],[ZDF Mediathek],[no])
 129 AS_IF([test "x$enable_mediathek_plugin" = "xyes"],
 130   [
 131     PKG_CHECK_MODULES([RYGEL_PLUGIN_MEDIATHEK_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED libsoup-2.4 >= $LIBSOUP_REQUIRED])
 132   ])
 133
 134 AS_IF([test "x$with_media_engine" = "xgstreamer"],
 135       [
 136         RYGEL_ADD_PLUGIN([playbin],[GStreamer playbin],[yes])
 137         AS_IF([test "x$enable_playbin_plugin" = "xyes"],
 138           [
 139             PKG_CHECK_MODULES([RYGEL_PLUGIN_PLAYBIN_DEPS], [$RYGEL_COMMON_MODULES gstreamer-1.0 >= $GSTREAMER_TAG_REQUIRED])
 140           ])
 141
 142         RYGEL_ADD_PLUGIN([media-export],[MediaExport],[yes])
 143         AS_IF([test "x$enable_media_export_plugin" = "xyes"],
 144           [
 145             PKG_CHECK_MODULES([RYGEL_PLUGIN_MEDIA_EXPORT_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED gupnp-dlna-1.1 >= $GUPNP_DLNA_REQUIRED gstreamer-tag-1.0 >= $GSTREAMER_TAG_REQUIRED gstreamer-app-1.0 >= $GSTREAMER_TAG_REQUIRED sqlite3 >= $LIBSQLITE3_REQUIRED])
 146             RYGEL_PLUGIN_MEDIA_EXPORT_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS --pkg gupnp-dlna-1.1 --pkg gstreamer-tag-1.0 --pkg gstreamer-app-1.0 --pkg sqlite3"
 147             AC_SUBST([RYGEL_PLUGIN_MEDIA_EXPORT_DEPS_VALAFLAGS])
 148           ])
 149
 150         RYGEL_ADD_PLUGIN([gst-launch],[GStreamer launchline],[no])
 151         AS_IF([test "x$enable_gst_launch_plugin" = "xyes"],
 152           [
 153             PKG_CHECK_MODULES([RYGEL_PLUGIN_GST_LAUNCH_DEPS], [$RYGEL_COMMON_MODULES gstreamer-1.0 >= $GSTREAMER_REQUIRED])
 154             RYGEL_PLUGIN_GST_LAUNCH_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS --pkg gstreamer-1.0"
 155             AC_SUBST([RYGEL_PLUGIN_GST_LAUNCH_DEPS_VALAFLAGS])
 156           ])
 157
 158         RYGEL_ADD_STAMP([src/media-engines/gstreamer/librygel_media_engine_gst_la_vala.stamp])
 159         RYGEL_ADD_STAMP([src/librygel-renderer-gst/librygel_renderer_gst_2_0_la_vala.stamp])
 160       ],
 161       [
 162         RYGEL_DISABLE_PLUGIN([playbin])
 163         RYGEL_DISABLE_PLUGIN([media-export])
 164         RYGEL_DISABLE_PLUGIN([gst-launch])
 165       ])
 166
 167 dnl Example plugins:
 168 AC_ARG_ENABLE([example-plugins],
 169               AS_HELP_STRING([--enable-example-plugins],[enable example plugins]),,
 170               enable_example_plugins=no)
 171 AM_CONDITIONAL([BUILD_EXAMPLE_PLUGINS], [test "x$[]enable_example_plugins" = "xyes"])
 172
 173 dnl Explicitly add stamp files for targets that are not plugins
 174 RYGEL_ADD_STAMP([src/librygel-core/librygel_core_2_0_la_vala.stamp])
 175 RYGEL_ADD_STAMP([src/librygel-server/librygel_server_2_0_la_vala.stamp])
 176 RYGEL_ADD_STAMP([src/librygel-renderer/librygel_renderer_2_0_la_vala.stamp])
 177 RYGEL_ADD_STAMP([src/rygel/rygel_vala.stamp])
 178 RYGEL_ADD_STAMP([src/ui/rygel_preferences_vala.stamp])
 179 RYGEL_ADD_STAMP([src/media-engines/simple/librygel_media_engine_simple_la_vala.stamp])
 180
 181 AS_IF([test "x$with_media_engine" = "xgstreamer"],
 182       [
 183         RYGEL_CHECK_PACKAGES([gupnp-dlna-1.1 gstreamer-1.0
 184                               gstreamer-pbutils-1.0])
 185       ])
 186
 187 dnl Debugging
 188 AC_ARG_ENABLE(debug,
 189         AS_HELP_STRING([--enable-debug],[enable debugging]),,
 190         enable_debug=no)
 191 if test "x$enable_debug" = "xyes"; then
 192         CFLAGS="$CFLAGS -O0 -g"
 193         RYGEL_DEBUG_VALAFLAGS="-g"
 194 fi
 195
 196 AC_SUBST(RYGEL_DEBUG_VALAFLAGS)
 197
 198 dnl Strict compiler
 199 AC_ARG_ENABLE(strict-cc,
 200         AS_HELP_STRING([--enable-strict-cc],[enable strict C compiler]),,
 201         enable_strict_cc=no)
 202 if test "x$enable_strict_cc" = "xyes"; then
 203         CFLAGS="$CFLAGS -Wall -Werror"
 204 else
 205         CFLAGS="$CFLAGS -w"
 206 fi
 207
 208 dnl Run uninstalled
 209 AC_ARG_ENABLE(uninstalled,
 210     AS_HELP_STRING([--enable-uninstalled],[run uninstalled]),,
 211         enable_uninstalled=no)
 212 if test "x$enable_uninstalled" = "xyes"; then
 213         AC_MSG_WARN("You want to run the tools uninstalled only? Fine!")
 214 fi
 215 AM_CONDITIONAL([UNINSTALLED], [test "x$enable_uninstalled" = "xyes"])
 216
 217 dnl Check wether user wants to build UIs
 218 AC_ARG_WITH( ui,
 219   AS_HELP_STRING([--without-ui],[Do not build UI applications]),
 220   try_ui=$withval, try_ui=yes )
 221
 222 HAVE_GTK=no
 223 if test x$try_ui = xyes ; then
 224     dnl check for gtk
 225     PKG_CHECK_MODULES([RYGEL_UI_DEPS], [$RYGEL_BASE_MODULES gtk+-3.0 >= $GTK_REQUIRED gssdp-1.0 >= $GSSDP_REQUIRED gee-0.8 >= $GEE_REQUIRED],
 226       [
 227         RYGEL_CHECK_PACKAGES([gtk+-3.0], [HAVE_GTK=yes])
 228         RYGEL_UI_DEPS_VALAFLAGS="$RYGEL_BASE_MODULES_VALAFLAGS --pkg gtk+-3.0 --pkg gssdp-1.0 --pkg gee-0.8"
 229         AC_SUBST([RYGEL_UI_DEPS_VALAFLAGS])
 230
 231         PKG_CHECK_MODULES([EXAMPLE_UI_DEPS],
 232                           [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED
 233                            gssdp-1.0 >= $GSSDP_REQUIRED
 234                            gstreamer-video-1.0 >= $GSTREAMER_REQUIRED
 235                            gtk+-3.0 >= $GTK_REQUIRED])
 236       ],
 237       [
 238         AC_MSG_WARN([UI dependencies not found.])
 239         AC_MSG_WARN([UI applications will not be built.])
 240       ])
 241
 242 else
 243     AC_MSG_NOTICE([UI applications disabled.])
 244 fi
 245
 246 AM_CONDITIONAL(BUILD_UI, test "x$HAVE_GTK" = "xyes")
 247
 248 dnl Tests
 249 AC_ARG_ENABLE([tests],
 250               AS_HELP_STRING([--enable-tests],[always build tests]),,
 251               enable_tests=no)
 252 AM_CONDITIONAL([ALWAYS_TEST], [test "x$enable_tests" = "xyes"])
 253
 254 dnl Generate coverage data
 255 AC_ARG_ENABLE([coverage],
 256   AS_HELP_STRING([--enable-coverage],
 257                  [Generate converage reports for unit tests]),
 258   [],
 259   [enable_coverage=no])
 260 AM_CONDITIONAL([ENABLE_COVERAGE],[test "x$enable_coverage" != "xno"])
 261 AS_IF([test "x$enable_coverage" != "xno"],
 262   [
 263     AC_PATH_PROG([LCOV], [lcov])
 264     AC_PATH_PROG([GENHTML], [genhtml])
 265     AC_SUBST([COVERAGE_LIBS],["-lgcov"])
 266     AC_SUBST([COVERAGE_CFLAGS],["-fprofile-arcs -ftest-coverage"])
 267     AC_SUBST(COVERAGE_VALAFLAGS,["-g"])
 268   ]
 269 )
 270
 271 dnl Check additional requirements for MediaExport plugins
 272 if test "x$enable_media_export_plugin" = "xyes";
 273 then
 274     RYGEL_CHECK_PACKAGES([sqlite3 gstreamer-tag-1.0 gstreamer-app-1.0])
 275     AC_CHECK_HEADER([unistr.h],
 276                     AC_CHECK_LIB([unistring],
 277                                  [u8_strcoll],
 278                                  [have_unistring=yes],[have_unistring=no]))
 279     if test "x$have_unistring" = "xyes"; then
 280         AC_DEFINE([HAVE_UNISTRING],[1],[Use libunistring for collation])
 281         COLLATION_CFLAGS=
 282         COLLATION_LIBS=-lunistring
 283         AC_SUBST([COLLATION_CFLAGS])
 284         AC_SUBST([COLLATION_LIBS])
 285     fi
 286 fi
 287
 288
 289 RYGEL_ADD_PLUGIN([tracker],[Tracker],[yes])
 290 AS_IF([test "x$enable_tracker_plugin" = "xyes"],
 291   [
 292     PKG_CHECK_MODULES([RYGEL_PLUGIN_TRACKER_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED])
 293
 294     tracker_api_version="0.14"
 295     PKG_CHECK_MODULES(TRACKER_SPARQL,
 296                       tracker-sparql-0.14 >= $TRACKER_SPARQL_REQUIRED_MIN,
 297                       [tracker_api_version="0.14"],
 298                       [tracker_api_version=""])
 299     AS_IF([test "x$[]tracker_api_version" = "x"],
 300           [
 301             PKG_CHECK_MODULES(TRACKER_SPARQL,
 302                               tracker-sparql-0.15 >=  $TRACKER_SPARQL_REQUIRED_MIN,
 303                               [tracker_api_version="0.15"],
 304                               [tracker_api_version=""])
 305           ])
 306     AS_IF([test "x$[]tracker_api_version" = "x"],
 307           [
 308             PKG_CHECK_MODULES(TRACKER_SPARQL,
 309                               tracker-sparql-0.16 >=  $TRACKER_SPARQL_REQUIRED_MIN,
 310                               [tracker_api_version="0.16"],
 311                               [])
 312           ])
 313     AS_IF([test "x$enable_vala" = "xyes"],
 314           [VALA_CHECK_PACKAGES([tracker-sparql-$tracker_api_version])])
 315
 316     RYGEL_PLUGIN_TRACKER_DEPS_VALAFLAGS="--pkg tracker-sparql-$tracker_api_version"
 317     AC_SUBST([RYGEL_PLUGIN_TRACKER_DEPS_VALAFLAGS])
 318   ])
 319
 320 # This should be called only after all RYGEL_CHECK_VALA() and RYGEL_ADD_PLUGIN() calls:
 321 RYGEL_CHECK_VALA([$VALA_REQUIRED],
 322                  [gupnp-1.0
 323                   gupnp-av-1.0
 324                   gio-2.0
 325                   gee-0.8
 326                   posix])
 327
 328 dnl Gettext
 329 GETTEXT_PACKAGE=rygel
 330 AC_SUBST(GETTEXT_PACKAGE)
 331 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 332   [Define the gettext package to be used])
 333
 334 AM_GLIB_GNU_GETTEXT
 335 IT_PROG_INTLTOOL([0.40.0])
 336
 337 dnl Shave the output
 338 AM_SILENT_RULES([yes])
 339
 340 dnl documenation
 341 AC_PATH_PROG([XSLTPROC], [xsltproc])
 342 AM_CONDITIONAL([HAVE_XSLTPROC], [test x"$XSLTPROC" != x])
 343
 344 dnl Use valadoc for API documentation:
 345 dnl This is on by default when using autogen.sh
 346 dnl (so it is not on by default when building from a tarball with configure.)
 347 AC_ARG_ENABLE(valadoc,
 348   AS_HELP_STRING([--enable-valadoc[=@<:@no/auto/yes@:>@]], [Enable valadoc support]),,
 349     [enable_valadoc=no])
 350
 351 found_valadoc=no
 352 AS_IF([test "x$enable_valadoc" != "xno"], [
 353     AC_PATH_PROG(VALADOC, valadoc, :)
 354     AS_IF([test -x "$VALADOC"], [
 355       found_valadoc=yes
 356       AC_SUBST(VALADOC)
 357       PKG_CHECK_MODULES([GTKDOC],[gtk-doc >= 1.0])
 358     ], [
 359       AS_IF([test "x$enable_valadoc" == "xyes"], AC_MSG_ERROR([Unable to find valadoc]))
 360     ])
 361   ])
 362
 363 AM_CONDITIONAL(ENABLE_VALADOC, test x$found_valadoc = xyes)
 364
 365 AC_CONFIG_FILES([
 366 Makefile
 367 src/Makefile
 368 src/librygel-core/Makefile
 369 src/librygel-renderer/Makefile
 370 src/librygel-renderer-gst/Makefile
 371 src/librygel-server/Makefile
 372 src/rygel/Makefile
 373 src/ui/Makefile
 374 src/media-engines/Makefile
 375 src/media-engines/gstreamer/Makefile
 376 src/media-engines/simple/Makefile
 377 src/plugins/Makefile
 378 data/Makefile
 379 data/xml/Makefile
 380 data/xml/MediaServer3.xml.in
 381 data/xml/MediaRenderer2.xml.in
 382 data/icons/Makefile
 383 data/icons/32x32/Makefile
 384 data/icons/48x48/Makefile
 385 data/icons/120x120/Makefile
 386 data/icons/128x128/Makefile
 387 data/icons/scalable/Makefile
 388 data/rygel.desktop.in
 389 data/rygel-preferences.desktop.in
 390 doc/Makefile
 391 doc/reference/Makefile
 392 doc/reference/librygel-core/Makefile
 393 doc/reference/librygel-renderer/Makefile
 394 doc/reference/librygel-server/Makefile
 395 doc/reference/librygel-renderer-gst/Makefile
 396 po/Makefile.in
 397 rygel-core-2.0.pc
 398 rygel-renderer-2.0.pc
 399 rygel-server-2.0.pc
 400 rygel-renderer-gst-2.0.pc
 401 tests/Makefile
 402 examples/Makefile
 403 examples/renderer-plugins/Makefile
 404 examples/renderer-plugins/vala/Makefile
 405 examples/renderer-plugins/C/Makefile
 406 examples/server-plugins/Makefile
 407 examples/server-plugins/vala/Makefile
 408 examples/server-plugins/C/Makefile
 409 ])
 410 AC_OUTPUT
 411
 412 echo "
 413
 414                     ${PACKAGE} ${VERSION}
 415                     ============
 416
 417
 418         Prefix:                 ${prefix}
 419         Source code location:   ${srcdir}
 420         Compiler:               ${CC}
 421         CFLAGS:                 ${CFLAGS}
 422         VALAFLAGS:              ${VALAFLAGS}
 423         uninstalled:            ${enable_uninstalled}
 424         preferences ui:         ${HAVE_GTK}
 425         Media Engine:           ${with_media_engine}
 426     Plugins:
 427         examples:               ${enable_example_plugins}
 428         tracker:                ${enable_tracker_plugin}
 429             version:            ${tracker_api_version}
 430         mediathek:              ${enable_mediathek_plugin}
 431         media-export            ${enable_media_export_plugin}
 432         external:               ${enable_external_plugin}
 433         MPRIS2:                 ${enable_mpris_plugin}
 434         gst-launch:             ${enable_gst_launch_plugin}
 435         playbin:                ${enable_playbin_plugin}
 436 "