configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # This file is part of PulseAudio.
   5 #
   6 # Copyright 2004-2008 Lennart Poettering
   7 # Copyright 2006-2007 Pierre Ossman <ossman@cendio.se> for Cendio AB
   8 #
   9 # PulseAudio is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU Lesser General Public License as published by
  11 # the Free Software Foundation; either version 2 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # PulseAudio is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  17 # General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public License
  20 # along with PulseAudio; if not, write to the Free Software Foundation,
  21 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  22
  23 AC_PREREQ(2.63)
  24
  25 m4_define(PA_MAJOR, [0])
  26 m4_define(PA_MINOR, [9])
  27 m4_define(PA_MICRO, [15])
  28
  29 AC_INIT([pulseaudio],[PA_MAJOR.PA_MINOR.PA_MICRO],[mzchyfrnhqvb (at) 0pointer (dot) net])
  30 AC_CONFIG_SRCDIR([src/daemon/main.c])
  31 AC_CONFIG_MACRO_DIR([m4])
  32 AC_CONFIG_HEADERS([config.h])
  33 AM_INIT_AUTOMAKE([foreign 1.10 -Wall])
  34
  35 AC_SUBST(PA_MAJORMINOR, PA_MAJOR.PA_MINOR)
  36 AC_SUBST(PA_MAJORMINORMICRO, PA_MAJOR.PA_MINOR.PA_MICRO)
  37 AC_SUBST(PACKAGE_URL, [http://pulseaudio.org/])
  38
  39 AC_SUBST(PA_API_VERSION, 12)
  40 AC_SUBST(PA_PROTOCOL_VERSION, 15)
  41
  42 # The stable ABI for client applications, for the version info x:y:z
  43 # always will hold y=z
  44 AC_SUBST(LIBPULSE_VERSION_INFO, [7:1:7])
  45
  46 # A simplified, synchronous, ABI-stable interface for client
  47 # applications, for the version info x:y:z always will hold y=z
  48 AC_SUBST(LIBPULSE_SIMPLE_VERSION_INFO, [0:2:0])
  49
  50 # The ABI-stable network browsing interface for client applications,
  51 # for the version info x:y:z always will hold y=z
  52 AC_SUBST(LIBPULSE_BROWSE_VERSION_INFO, [1:1:1])
  53
  54 # The ABI-stable GLib adapter for client applications, for the version
  55 # info x:y:z always will hold y=z
  56 AC_SUBST(LIBPULSE_MAINLOOP_GLIB_VERSION_INFO, [0:4:0])
  57
  58 AC_CANONICAL_HOST
  59 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  60
  61 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  62    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  63    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  64 fi
  65
  66 #### Platform hacks ####
  67
  68 case $host in
  69    *-*-solaris* )
  70       AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  71       AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
  72       AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  73       ;;
  74 esac
  75
  76 #### Checks for programs. ####
  77
  78 # mkdir -p
  79
  80 AC_PROG_MKDIR_P
  81
  82 # CC
  83
  84 AC_PROG_CC
  85 AC_PROG_CC_C99
  86 AM_PROG_CC_C_O
  87 AC_PROG_GCC_TRADITIONAL
  88 AC_USE_SYSTEM_EXTENSIONS
  89
  90 # M4
  91
  92 AC_PATH_PROG([M4], [m4 gm4], [no])
  93 if test "x$M4" = xno ; then
  94    AC_MSG_ERROR([m4 missing])
  95 fi
  96
  97 dnl Compiler flags
  98 DESIRED_FLAGS="-Wall -W -Wextra -pedantic -pipe -Wno-long-long -Winline -Wvla -Wno-overlength-strings -Wunsafe-loop-optimizations -Wundef -Wformat=2 -Wlogical-op -Wsign-compare -Wpacked -Wformat-security -Wmissing-include-dirs -Wformat-nonliteral -Wold-style-definition -Wpointer-arith -Winit-self -Wdeclaration-after-statement -Wfloat-equal -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-declarations -Wmissing-noreturn -Wshadow -Wendif-labels -Wcast-align -Wstrict-aliasing=2 -Wwrite-strings -Wno-unused-parameter -ffast-math -Wp,-D_FORTIFY_SOURCE=2 -fno-common -fdiagnostics-show-option"
  99
 100 for flag in $DESIRED_FLAGS ; do
 101   CC_CHECK_CFLAGS([$flag], [CFLAGS="$CFLAGS $flag"])
 102 done
 103
 104 dnl Check whether to build tests by default (as compile-test) or not
 105 AC_ARG_ENABLE([default-build-tests],
 106     AS_HELP_STRING([--disable-default-build-tests], [Build test programs only during make check]))
 107
 108 AM_CONDITIONAL([BUILD_TESTS_DEFAULT], [test "x$enable_default_build_tests" = "xno"])
 109
 110 # Native atomic operation support
 111 AC_ARG_ENABLE([atomic-arm-linux-helpers],
 112     AS_HELP_STRING([--disable-atomic-arm-linux-helpers],[use inline asm or libatomic_ops instead]),
 113         [
 114             case "${enableval}" in
 115                 yes) atomic_arm_linux_helpers=yes ;;
 116                 no) atomic_arm_linux_helpers=no ;;
 117                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-atomic-arm-linux-helpers) ;;
 118             esac
 119         ],
 120         [atomic_arm_linux_helpers=auto])
 121
 122 AC_ARG_ENABLE([atomic-arm-memory-barrier],
 123     AS_HELP_STRING([--enable-atomic-arm-memory-barrier],[only really needed in SMP arm systems]),
 124         [
 125             case "${enableval}" in
 126                 yes) AC_DEFINE_UNQUOTED(ATOMIC_ARM_MEMORY_BARRIER_ENABLED, 1, [Enable memory barriers]) ;;
 127                 no) ;;
 128                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-atomic-arm-linux-helpers) ;;
 129             esac
 130         ],)
 131
 132 AC_MSG_CHECKING([target operating system])
 133 case $host in
 134         *-*-linux*)
 135             AC_MSG_RESULT([linux])
 136             pulse_target_os=linux
 137         ;;
 138         *)
 139             AC_MSG_RESULT([unknown])
 140             pulse_target_os=unknown
 141         ;;
 142 esac
 143
 144 # If everything else fails use libatomic_ops
 145 need_libatomic_ops=yes
 146
 147 AC_CACHE_CHECK([whether $CC knows __sync_bool_compare_and_swap()],
 148   pulseaudio_cv_sync_bool_compare_and_swap,
 149   [AC_LINK_IFELSE(
 150      AC_LANG_PROGRAM([], [[int a = 4; __sync_bool_compare_and_swap(&a, 4, 5);]]),
 151      [pulseaudio_cv_sync_bool_compare_and_swap=yes],
 152      [pulseaudio_cv_sync_bool_compare_and_swap=no])
 153   ])
 154
 155 if test "$pulseaudio_cv_sync_bool_compare_and_swap" = "yes" ; then
 156     AC_DEFINE([HAVE_ATOMIC_BUILTINS], 1, [Have __sync_bool_compare_and_swap() and friends.])
 157     need_libatomic_ops=no
 158 else
 159     # HW specific atomic ops stuff
 160     AC_MSG_CHECKING([architecture for native atomic operations])
 161     case $host_cpu in
 162         arm*)
 163             AC_MSG_RESULT([arm])
 164             AC_MSG_CHECKING([whether we can use Linux kernel helpers])
 165             # The Linux kernel helper functions have been there since 2.6.16. However
 166             # compile time checking for kernel version in cross compile environment
 167             # (which is usually the case for arm cpu) is tricky (or impossible).
 168             if test "x$pulse_target_os" = "xlinux" && test "x$atomic_arm_linux_helpers" != "xno"; then
 169                 AC_MSG_RESULT([yes])
 170                 AC_DEFINE_UNQUOTED(ATOMIC_ARM_LINUX_HELPERS, 1, [special arm linux implementation])
 171                 need_libatomic_ops=no
 172             else
 173                AC_MSG_RESULT([no])
 174                AC_CACHE_CHECK([compiler support for arm inline asm atomic operations],
 175                  pulseaudio_cv_support_arm_atomic_ops,
 176                  [AC_COMPILE_IFELSE(
 177                     AC_LANG_PROGRAM([],
 178                       [[volatile int a=0;
 179                         int o=0, n=1, r;
 180                         asm volatile ("ldrex    %0, [%1]\n"
 181                                          "subs  %0, %0, %2\n"
 182                                          "strexeq %0, %3, [%1]\n"
 183                                          : "=&r" (r)
 184                                          : "r" (&a), "Ir" (o), "r" (n)
 185                                          : "cc");
 186                         return (a==1 ? 0 : -1);
 187                       ]]),
 188                     [pulseaudio_cv_support_arm_atomic_ops=yes],
 189                     [pulseaudio_cv_support_arm_atomic_ops=no])
 190                  ])
 191                AS_IF([test "$pulseaudio_cv_support_arm_atomic_ops" = "yes"], [
 192                    AC_DEFINE([ATOMIC_ARM_INLINE_ASM], 1, [Have ARMv6 instructions.])
 193                    need_libatomic_ops=no
 194                  ])
 195            fi
 196         ;;
 197         *)
 198             AC_MSG_RESULT([unknown])
 199         ;;
 200     esac
 201 fi
 202
 203 CC_CHECK_TLS
 204
 205 AC_CACHE_CHECK([whether $CC knows _Bool],
 206   pulseaudio_cv__Bool,
 207   [AC_COMPILE_IFELSE(
 208      AC_LANG_PROGRAM([], [[_Bool b;]]),
 209      [pulseaudio_cv__Bool=yes],
 210      [pulseaudio_cv__Bool=no])
 211   ])
 212
 213 AS_IF([test "$pulseaudio_cv__Bool" = "yes"], [
 214     AC_DEFINE([HAVE_STD_BOOL], 1, [Have _Bool.])
 215   ])
 216
 217 #### libtool stuff ####
 218 LT_PREREQ(2.2)
 219 LT_CONFIG_LTDL_DIR([libltdl])
 220 LT_INIT([dlopen win32-dll disable-static])
 221 LTDL_INIT([convenience recursive])
 222
 223 #### Determine build environment ####
 224
 225 os_is_win32=0
 226
 227 case "$host_os" in
 228         mingw*)
 229         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 230         os_is_win32=1
 231                 ;;
 232         esac
 233
 234 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 235
 236 ###################################
 237 #   Basic environment checks      #
 238 ###################################
 239
 240 #### Checks for header files. ####
 241
 242 # ISO
 243 AC_HEADER_STDC
 244
 245 # POSIX
 246 AC_CHECK_HEADERS([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
 247     netinet/in_systm.h netinet/tcp.h poll.h pwd.h sched.h \
 248     sys/mman.h sys/resource.h sys/select.h sys/socket.h sys/wait.h \
 249     syslog.h sys/dl.h dlfcn.h linux/sockios.h])
 250 AC_CHECK_HEADERS([netinet/ip.h], [], [],
 251                  [#include <sys/types.h>
 252                   #if HAVE_NETINET_IN_H
 253                   # include <netinet/in.h>
 254                   #endif
 255                   #if HAVE_NETINET_IN_SYSTM_H
 256                   # include <netinet/in_systm.h>
 257                   #endif
 258                  ])
 259 AC_CHECK_HEADERS([regex.h], [HAVE_REGEX=1], [HAVE_REGEX=0])
 260 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 261
 262 AM_CONDITIONAL(HAVE_REGEX, test "x$HAVE_REGEX" = "x1")
 263 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 264
 265 # Linux
 266 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 267
 268 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 269
 270 AC_CHECK_HEADERS([sys/prctl.h])
 271
 272 # Solaris
 273 AC_CHECK_HEADERS([sys/filio.h])
 274
 275 # Windows
 276 AC_CHECK_HEADERS([windows.h winsock2.h ws2tcpip.h])
 277
 278 # Other
 279 AC_CHECK_HEADERS([sys/ioctl.h])
 280 AC_CHECK_HEADERS([byteswap.h])
 281 AC_CHECK_HEADERS([sys/syscall.h])
 282 AC_CHECK_HEADERS([sys/eventfd.h])
 283 AC_CHECK_HEADERS([execinfo.h])
 284
 285 #### Typdefs, structures, etc. ####
 286
 287 AC_C_CONST
 288 AC_C_BIGENDIAN
 289 AC_TYPE_PID_T
 290 AC_TYPE_SIZE_T
 291 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
 292     [Define ssize_t if it is not done by the standard libs.])])
 293 AC_TYPE_OFF_T
 294
 295 AC_TYPE_UID_T
 296 AC_CHECK_DECLS(environ)
 297
 298 AC_CHECK_DEFINE([SIGXCPU], [signal.h], [
 299 HAVE_SIGXCPU=1
 300 AC_DEFINE([HAVE_SIGXCPU], 1, [Have SIGXCPU?])
 301 ], [HAVE_SIGXCPU=0])
 302 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 303
 304 # Solaris lacks this
 305 AC_CHECK_DEFINE([INADDR_NONE], [netinet/in.h], [],
 306     [AC_CHECK_DEFINE([INADDR_NONE], [winsock2.h], [],
 307         [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])])
 308
 309 #### POSIX threads ####
 310
 311 ACX_PTHREAD
 312
 313 #### Check for libs ####
 314
 315 # ISO
 316 AC_SEARCH_LIBS([pow], [m])
 317
 318 # POSIX
 319 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 320 AC_SEARCH_LIBS([dlopen], [dl])
 321 AC_SEARCH_LIBS([shm_open], [rt])
 322 AC_SEARCH_LIBS([inet_ntop], [nsl])
 323 AC_SEARCH_LIBS([timer_create], [rt])
 324
 325 # BSD
 326 AC_SEARCH_LIBS([connect], [socket])
 327
 328 # Non-standard
 329
 330 # This magic is needed so we do not needlessly add static libs to the win32
 331 # build, disabling its ability to make dlls.
 332 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 333
 334 AC_CHECK_LIB(gdbm, gdbm_open)
 335 AC_CHECK_HEADERS(gdbm.h, [], [AC_MSG_ERROR([gdbm.h not found])])
 336
 337 #### Check for functions ####
 338
 339 # ISO
 340 AC_CHECK_FUNCS([lrintf strtof])
 341
 342 # POSIX
 343 AC_FUNC_FORK
 344 AC_FUNC_GETGROUPS
 345 AC_FUNC_SELECT_ARGTYPES
 346 AC_CHECK_FUNCS([chmod chown clock_gettime getaddrinfo getgrgid_r \
 347     getpwuid_r gettimeofday getuid inet_ntop inet_pton mlock nanosleep \
 348     pipe posix_fadvise posix_madvise posix_memalign setpgid setsid shm_open \
 349     sigaction sleep sysconf])
 350 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 351
 352 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 353
 354 # X/OPEN
 355 AC_CHECK_FUNCS([readlink])
 356
 357 # SUSv2
 358 AC_CHECK_FUNCS([ctime_r usleep])
 359
 360 # SUSv3
 361 AC_CHECK_FUNCS([strerror_r])
 362
 363 # BSD
 364 AC_CHECK_FUNCS([lstat])
 365
 366 # Non-standard
 367
 368 AC_CHECK_FUNCS([setresuid setresgid setreuid setregid seteuid setegid ppoll strsignal sig2str strtof_l])
 369
 370 AC_FUNC_ALLOCA
 371
 372 AC_CACHE_CHECK([for PTHREAD_PRIO_INHERIT],
 373   pulseaudio_cv_PTHREAD_PRIO_INHERIT,
 374   [save_CC=$CC; CC=$PTHREAD_CC
 375    save_CFLAGS=$CFLAGS; CFLAGS=$PTHREAD_CFLAGS
 376    save_LIBS=$LIBS; LIBS=$PTHREAD_LIBS
 377    AC_LINK_IFELSE(
 378      AC_LANG_PROGRAM(
 379        [[
 380          #include <pthread.h>
 381        ]],
 382        [[int i = PTHREAD_PRIO_INHERIT;]]),
 383      [pulseaudio_cv_PTHREAD_PRIO_INHERIT=yes],
 384      [pulseaudio_cv_PTHREAD_PRIO_INHERIT=no])
 385    CC=$save_CC
 386    CFLAGS=$save_CFLAGS
 387    LIBS=$save_LIBS
 388   ])
 389
 390 AS_IF([test "$pulseaudio_cv_PTHREAD_PRIO_INHERIT" = "yes"], [
 391     AC_DEFINE([HAVE_PTHREAD_PRIO_INHERIT], 1, [Have PTHREAD_PRIO_INHERIT.])
 392   ])
 393
 394 AC_DEFINE_UNQUOTED(PA_CFLAGS,"$CFLAGS", [The CFLAGS used during compilation])
 395
 396 #### Large File-Support (LFS) ####
 397
 398 AC_SYS_LARGEFILE
 399
 400 # Check for open64 to know if the current system does have open64() and similar functions
 401 AC_CHECK_FUNCS([open64])
 402
 403 #### [lib]iconv ####
 404
 405 AM_ICONV
 406
 407 IT_PROG_INTLTOOL([0.35.0])
 408 GETTEXT_PACKAGE=pulseaudio
 409 AC_SUBST([GETTEXT_PACKAGE])
 410 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
 411 AM_GLIB_GNU_GETTEXT
 412
 413 pulselocaledir='${prefix}/${DATADIRNAME}/locale'
 414 AC_SUBST(pulselocaledir)
 415
 416 ###################################
 417 #      External libraries         #
 418 ###################################
 419
 420 #### pkg-config ####
 421
 422 # Check for pkg-config manually first, as if its not installed the
 423 # PKG_PROG_PKG_CONFIG macro won't be defined.
 424 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 425
 426 if test x"$have_pkg_config" = "xno"; then
 427     AC_MSG_ERROR(pkg-config is required to install this program)
 428 fi
 429
 430 PKG_PROG_PKG_CONFIG
 431
 432 #### X11 (optional) ####
 433
 434 AC_ARG_ENABLE([x11],
 435     AS_HELP_STRING([--disable-x11],[Disable optional X11 support]),
 436         [
 437             case "${enableval}" in
 438                 yes) x11=yes ;;
 439                 no) x11=no ;;
 440                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-x11) ;;
 441             esac
 442         ],
 443         [x11=auto])
 444
 445 if test "x${x11}" != xno ; then
 446     PKG_CHECK_MODULES(X11, [ x11 ice sm ],
 447         HAVE_X11=1,
 448         [
 449             HAVE_X11=0
 450             if test "x$x11" = xyes ; then
 451                 AC_MSG_ERROR([*** X11 not found])
 452             fi
 453         ])
 454 else
 455     HAVE_X11=0
 456 fi
 457
 458 if test "x${HAVE_X11}" = x1 ; then
 459    AC_DEFINE([HAVE_X11], 1, [Have X11?])
 460 fi
 461
 462 AC_SUBST(X11_CFLAGS)
 463 AC_SUBST(X11_LIBS)
 464 AC_SUBST(HAVE_X11)
 465 AM_CONDITIONAL([HAVE_X11], [test "x$HAVE_X11" = x1])
 466
 467 #### Capabilities (optional) ####
 468
 469 CAP_LIBS=''
 470
 471 AC_ARG_WITH(
 472         [caps],
 473         AS_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 474
 475 if test "x${with_caps}" != "xno"; then
 476     AC_SEARCH_LIBS([cap_init], [cap], [], [
 477                     if test "x${with_caps}" = "xyes" ; then
 478                         AC_MSG_ERROR([*** POSIX caps libraries not found])
 479                     fi])
 480     AC_CHECK_HEADERS([sys/capability.h], [], [
 481                     if test "x${with_caps}" = "xyes" ; then
 482                         AC_MSG_ERROR([*** POSIX caps headers not found])
 483                     fi])
 484 fi
 485
 486 #### Valgrind (optional) ####
 487
 488 AC_CHECK_HEADERS([valgrind/memcheck.h])
 489
 490 #### Sound file ####
 491
 492 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.10 ])
 493 AC_SUBST(LIBSNDFILE_CFLAGS)
 494 AC_SUBST(LIBSNDFILE_LIBS)
 495
 496 PKG_CHECK_MODULES(LIBSPEEX, [ speexdsp >= 1.2 ])
 497 AC_SUBST(LIBSPEEX_CFLAGS)
 498 AC_SUBST(LIBSPEEX_LIBS)
 499
 500 #### atomic-ops ###
 501
 502 AC_MSG_CHECKING([whether we need libatomic_ops])
 503 if test "x$need_libatomic_ops" = "xyes"; then
 504    AC_MSG_RESULT([yes])
 505    AC_CHECK_HEADERS([atomic_ops.h], [], [
 506    AC_MSG_ERROR([*** libatomic-ops headers not found])
 507    ])
 508
 509    # Win32 does not need the lib and breaks horribly if we try to include it
 510    if test "x$os_is_win32" != "x1" ; then
 511        LIBS="$LIBS -latomic_ops"
 512    fi
 513 else
 514    AC_MSG_RESULT([no])
 515 fi
 516
 517 #### Libsamplerate support (optional) ####
 518
 519 AC_ARG_ENABLE([samplerate],
 520     AS_HELP_STRING([--disable-samplerate],[Disable optional libsamplerate support]),
 521         [
 522             case "${enableval}" in
 523                 yes) samplerate=yes ;;
 524                 no) samplerate=no ;;
 525                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-samplerate) ;;
 526             esac
 527         ],
 528         [samplerate=auto])
 529
 530 if test "x${samplerate}" != xno ; then
 531     PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ],
 532         HAVE_LIBSAMPLERATE=1,
 533         [
 534             HAVE_LIBSAMPLERATE=0
 535             if test "x$samplerate" = xyes ; then
 536                 AC_MSG_ERROR([*** Libsamplerate not found])
 537             fi
 538         ])
 539 else
 540     HAVE_LIBSAMPLERATE=0
 541 fi
 542
 543 if test "x${HAVE_LIBSAMPLERATE}" = x1 ; then
 544    AC_DEFINE([HAVE_LIBSAMPLERATE], 1, [Have libsamplerate?])
 545 fi
 546
 547 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 548 AC_SUBST(LIBSAMPLERATE_LIBS)
 549 AC_SUBST(HAVE_LIBSAMPLERATE)
 550 AM_CONDITIONAL([HAVE_LIBSAMPLERATE], [test "x$HAVE_LIBSAMPLERATE" = x1])
 551
 552 #### OSS support (optional) ####
 553
 554 AC_ARG_ENABLE([oss],
 555     AS_HELP_STRING([--disable-oss],[Disable optional OSS support]),
 556         [
 557             case "${enableval}" in
 558                 yes) oss=yes ;;
 559                 no) oss=no ;;
 560                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-oss) ;;
 561             esac
 562         ],
 563         [oss=auto])
 564
 565 if test "x${oss}" != xno ; then
 566     AC_CHECK_HEADERS([sys/soundcard.h],
 567         [
 568             HAVE_OSS=1
 569             AC_DEFINE([HAVE_OSS], 1, [Have OSS?])
 570         ],
 571         [
 572             HAVE_OSS=0
 573             if test "x$oss" = xyes ; then
 574                 AC_MSG_ERROR([*** OSS support not found])
 575             fi
 576         ])
 577 else
 578     HAVE_OSS=0
 579 fi
 580
 581 AC_SUBST(HAVE_OSS)
 582 AM_CONDITIONAL([HAVE_OSS], [test "x$HAVE_OSS" = x1])
 583
 584
 585 #### ALSA support (optional) ####
 586
 587 AC_ARG_ENABLE([alsa],
 588     AS_HELP_STRING([--disable-alsa],[Disable optional ALSA support]),
 589         [
 590             case "${enableval}" in
 591                 yes) alsa=yes ;;
 592                 no) alsa=no ;;
 593                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-alsa) ;;
 594             esac
 595         ],
 596         [alsa=auto])
 597
 598 if test "x${alsa}" != xno ; then
 599     PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.17 ],
 600         [
 601             HAVE_ALSA=1
 602             AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?])
 603         ],
 604         [
 605             HAVE_ALSA=0
 606             if test "x$alsa" = xyes ; then
 607                 AC_MSG_ERROR([*** Needed alsa >= 1.0.17 support not found])
 608             fi
 609         ])
 610 else
 611     HAVE_ALSA=0
 612 fi
 613
 614 AC_SUBST(ASOUNDLIB_CFLAGS)
 615 AC_SUBST(ASOUNDLIB_LIBS)
 616 AC_SUBST(HAVE_ALSA)
 617 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 618
 619 #### Solaris audio support (optional) ####
 620
 621 AC_ARG_ENABLE([solaris],
 622     AS_HELP_STRING([--disable-solaris],[Disable optional Solaris audio support]),
 623         [
 624             case "${enableval}" in
 625                 yes) solaris=yes ;;
 626                 no) solaris=no ;;
 627                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-solaris) ;;
 628             esac
 629         ],
 630         [solaris=auto])
 631
 632 if test "x${solaris}" != xno ; then
 633     AC_CHECK_HEADERS([sys/audio.h],
 634         [
 635             HAVE_SOLARIS=1
 636             AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?])
 637         ],
 638         [
 639             HAVE_SOLARIS=0
 640             if test "x$solaris" = xyes ; then
 641                 AC_MSG_ERROR([*** Solaris audio support not found])
 642             fi
 643         ])
 644 else
 645     HAVE_SOLARIS=0
 646 fi
 647
 648 AC_SUBST(HAVE_SOLARIS)
 649 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 650
 651 #### GLib 2 support (optional) ####
 652
 653 AC_ARG_ENABLE([glib2],
 654     AS_HELP_STRING([--disable-glib2],[Disable optional GLib 2 support]),
 655         [
 656             case "${enableval}" in
 657                 yes) glib2=yes ;;
 658                 no) glib2=no ;;
 659                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-glib2) ;;
 660             esac
 661         ],
 662         [glib2=auto])
 663
 664 if test "x${glib2}" != xno ; then
 665     PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ],
 666         HAVE_GLIB20=1,
 667         [
 668             HAVE_GLIB20=0
 669             if test "x$glib2" = xyes ; then
 670                 AC_MSG_ERROR([*** GLib 2 support not found])
 671             fi
 672         ])
 673 else
 674     HAVE_GLIB20=0
 675 fi
 676
 677 AC_SUBST(GLIB20_CFLAGS)
 678 AC_SUBST(GLIB20_LIBS)
 679 AC_SUBST(HAVE_GLIB20)
 680 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 681
 682 #### GConf support (optional) ####
 683
 684 AC_ARG_ENABLE([gconf],
 685     AS_HELP_STRING([--disable-gconf],[Disable optional GConf support]),
 686         [
 687             case "${enableval}" in
 688                 yes) gconf=yes ;;
 689                 no) gconf=no ;;
 690                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-gconf) ;;
 691             esac
 692         ],
 693         [gconf=auto])
 694
 695 if test "x${gconf}" != xno ; then
 696     PKG_CHECK_MODULES(GCONF, [ gconf-2.0 >= 2.4.0 ],
 697         HAVE_GCONF=1,
 698         [
 699             HAVE_GCONF=0
 700             if test "x$gconf" = xyes ; then
 701                 AC_MSG_ERROR([*** GConf support not found])
 702             fi
 703         ])
 704 else
 705     HAVE_GCONF=0
 706 fi
 707
 708 AC_SUBST(GCONF_CFLAGS)
 709 AC_SUBST(GCONF_LIBS)
 710 AC_SUBST(HAVE_GCONF)
 711 AM_CONDITIONAL([HAVE_GCONF], [test "x$HAVE_GCONF" = x1])
 712
 713 #### Avahi support (optional) ####
 714
 715 AC_ARG_ENABLE([avahi],
 716     AS_HELP_STRING([--disable-avahi],[Disable optional Avahi support]),
 717         [
 718             case "${enableval}" in
 719                 yes) avahi=yes ;;
 720                 no) avahi=no ;;
 721                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-avahi) ;;
 722             esac
 723         ],
 724         [avahi=auto])
 725
 726 if test "x${avahi}" != xno ; then
 727     PKG_CHECK_MODULES(AVAHI, [ avahi-client >= 0.6.0 ],
 728         HAVE_AVAHI=1,
 729         [
 730                 HAVE_AVAHI=0
 731                 if test "x$avahi" = xyes ; then
 732                         AC_MSG_ERROR([*** Avahi support not found])
 733                 fi
 734         ])
 735 else
 736     HAVE_AVAHI=0
 737 fi
 738
 739 AC_SUBST(AVAHI_CFLAGS)
 740 AC_SUBST(AVAHI_LIBS)
 741 AC_SUBST(HAVE_AVAHI)
 742 AM_CONDITIONAL([HAVE_AVAHI], [test "x$HAVE_AVAHI" = x1])
 743
 744 ### LIBOIL ####
 745
 746 PKG_CHECK_MODULES(LIBOIL, [ liboil-0.3 >= 0.3.0 ])
 747 AC_SUBST(LIBOIL_CFLAGS)
 748 AC_SUBST(LIBOIL_LIBS)
 749
 750 ### JACK (optional) ####
 751
 752 AC_ARG_ENABLE([jack],
 753     AS_HELP_STRING([--disable-jack],[Disable optional JACK support]),
 754         [
 755             case "${enableval}" in
 756                 yes) jack=yes ;;
 757                 no) jack=no ;;
 758                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-jack) ;;
 759             esac
 760         ],
 761         [jack=auto])
 762
 763 if test "x${jack}" != xno ; then
 764     PKG_CHECK_MODULES(JACK, [ jack >= 0.100 ],
 765         HAVE_JACK=1,
 766         [
 767             HAVE_JACK=0
 768             if test "x$jack" = xyes ; then
 769                 AC_MSG_ERROR([*** JACK support not found])
 770             fi
 771         ])
 772 else
 773     HAVE_JACK=0
 774 fi
 775
 776 AC_SUBST(JACK_CFLAGS)
 777 AC_SUBST(JACK_LIBS)
 778 AC_SUBST(HAVE_JACK)
 779 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
 780
 781 #### Async DNS support (optional) ####
 782
 783 AC_ARG_ENABLE([asyncns],
 784     AS_HELP_STRING([--disable-asyncns],[Disable optional Async DNS support]),
 785         [
 786             case "${enableval}" in
 787                 yes) asyncns=yes ;;
 788                 no) asyncns=no ;;
 789                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-asyncns) ;;
 790             esac
 791         ],
 792         [asyncns=auto])
 793
 794 if test "x${asyncns}" != xno ; then
 795     PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ],
 796         HAVE_LIBASYNCNS=1,
 797         [
 798             HAVE_LIBASYNCNS=0
 799             if test "x$asyncns" = xyes ; then
 800                 AC_MSG_ERROR([*** Async DNS support not found])
 801             fi
 802         ])
 803 else
 804     HAVE_LIBASYNCNS=0
 805 fi
 806
 807 AC_SUBST(LIBASYNCNS_CFLAGS)
 808 AC_SUBST(LIBASYNCNS_LIBS)
 809 AC_SUBST(HAVE_LIBASYNCNS)
 810 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 811
 812 if test "x$HAVE_LIBASYNCNS" != "x0" ; then
 813    AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?])
 814 fi
 815
 816 #### TCP wrappers (optional) ####
 817
 818 AC_ARG_ENABLE([tcpwrap],
 819     AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 820         [
 821             case "${enableval}" in
 822                 yes) tcpwrap=yes ;;
 823                 no) tcpwrap=no ;;
 824                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 825             esac
 826         ],
 827         [tcpwrap=auto])
 828
 829 if test "x${tcpwrap}" != xno ; then
 830     ACX_LIBWRAP
 831     if test "x${LIBWRAP_LIBS}" = x && test "x$tcpwrap" = xyes ; then
 832         AC_MSG_ERROR([*** TCP wrappers support not found])
 833     fi
 834 else
 835     LIBWRAP_LIBS=
 836 fi
 837
 838 AC_SUBST(LIBWRAP_LIBS)
 839
 840 #### LIRC support (optional) ####
 841
 842 AC_ARG_ENABLE([lirc],
 843     AS_HELP_STRING([--disable-lirc],[Disable optional LIRC support]),
 844         [
 845             case "${enableval}" in
 846                 yes) lirc=yes ;;
 847                 no) lirc=no ;;
 848                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-lirc) ;;
 849             esac
 850         ],
 851         [lirc=auto])
 852
 853 if test "x${lirc}" != xno ; then
 854     ACX_LIRC
 855     if test "x${HAVE_LIRC}" = x0 && test "x$lirc" = xyes ; then
 856         AC_MSG_ERROR([*** LIRC support not found])
 857     fi
 858 else
 859     HAVE_LIRC=0
 860 fi
 861
 862 AC_SUBST(LIRC_CFLAGS)
 863 AC_SUBST(LIRC_LIBS)
 864 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 865
 866 #### HAL support (optional) ####
 867
 868 AC_ARG_ENABLE([hal],
 869     AS_HELP_STRING([--disable-hal],[Disable optional HAL support]),
 870         [
 871             case "${enableval}" in
 872                 yes) hal=yes ;;
 873                 no) hal=no ;;
 874                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-hal) ;;
 875             esac
 876         ],
 877         [hal=auto])
 878 if test "x${hal}" != xno -a \( "x$HAVE_OSS" = "x1" -o "x$HAVE_ALSA" = "x1" \) ; then
 879     PKG_CHECK_MODULES(HAL, [ hal >= 0.5.7 ],
 880         HAVE_HAL=1,
 881         [
 882             HAVE_HAL=0
 883             if test "x$hal" = xyes ; then
 884                 AC_MSG_ERROR([*** HAL support not found])
 885             fi
 886         ])
 887 else
 888     HAVE_HAL=0
 889 fi
 890
 891 AC_SUBST(HAL_CFLAGS)
 892 AC_SUBST(HAL_LIBS)
 893 AC_SUBST(HAVE_HAL)
 894 AM_CONDITIONAL([HAVE_HAL], [test "x$HAVE_HAL" = x1])
 895
 896 #### BlueZ support (optional) ####
 897
 898 AC_ARG_ENABLE([bluez],
 899     AS_HELP_STRING([--disable-bluez],[Disable optional BlueZ support]),
 900         [
 901             case "${enableval}" in
 902                 yes) bluez=yes ;;
 903                 no) bluez=no ;;
 904                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-bluez) ;;
 905             esac
 906         ],
 907         [bluez=auto])
 908 if test "x${bluez}" != xno ; then
 909     PKG_CHECK_MODULES(BLUEZ, [ bluez >= 3.0 ],
 910         HAVE_BLUEZ=1,
 911         [
 912             HAVE_BLUEZ=0
 913             if test "x$bluez" = xyes ; then
 914                 AC_MSG_ERROR([*** BLUEZ support not found])
 915             fi
 916         ])
 917 else
 918     HAVE_BLUEZ=0
 919 fi
 920
 921 AC_SUBST(BLUEZ_CFLAGS)
 922 AC_SUBST(BLUEZ_LIBS)
 923 AC_SUBST(HAVE_BLUEZ)
 924 AM_CONDITIONAL([HAVE_BLUEZ], [test "x$HAVE_BLUEZ" = x1])
 925
 926 #### D-Bus support (optional) ####
 927
 928 AC_ARG_ENABLE([dbus],
 929     AS_HELP_STRING([--disable-dbus],[Disable optional D-Bus support]),
 930         [
 931             case "${enableval}" in
 932                 yes) dbus=yes ;;
 933                 no) dbus=no ;;
 934                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-dbus) ;;
 935             esac
 936         ],
 937         [dbus=auto])
 938
 939 if test "x$HAVE_HAL" = x1 ; then
 940    dbus=yes
 941 fi
 942
 943 if test "x${dbus}" != xno || test "x${bluez}" != xno || "x${hal}" != xno ; then
 944
 945     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.0.0 ],
 946         [
 947             HAVE_DBUS=1
 948             saved_LIBS="$LIBS"
 949             LIBS="$LIBS $DBUS_LIBS"
 950             AC_CHECK_FUNCS(dbus_watch_get_unix_fd)
 951             LIBS="$saved_LIBS"
 952             AC_DEFINE([HAVE_DBUS], 1, [Have D-Bus.])
 953         ],
 954         [
 955             HAVE_DBUS=0
 956             if test "x$dbus" = xyes ; then
 957                 AC_MSG_ERROR([*** D-Bus support not found])
 958             fi
 959         ])
 960 else
 961     HAVE_DBUS=0
 962 fi
 963
 964 AC_SUBST(DBUS_CFLAGS)
 965 AC_SUBST(DBUS_LIBS)
 966 AC_SUBST(HAVE_DBUS)
 967 AM_CONDITIONAL([HAVE_DBUS], [test "x$HAVE_DBUS" = x1])
 968
 969 #### PolicyKit support (optional) ####
 970
 971 AC_ARG_ENABLE([polkit],
 972     AS_HELP_STRING([--disable-polkit],[Disable optional PolicyKit support]),
 973         [
 974             case "${enableval}" in
 975                 yes) polkit=yes ;;
 976                 no) polkit=no ;;
 977                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-polkit) ;;
 978             esac
 979         ],
 980         [polkit=auto])
 981
 982 if test "x${polkit}" != xno ; then
 983
 984     PKG_CHECK_MODULES(POLKIT, [ polkit-dbus >= 0.7 ],
 985         [
 986             HAVE_POLKIT=1
 987             AC_DEFINE([HAVE_POLKIT], 1, [Have PolicyKit])
 988             policydir=`pkg-config polkit-dbus --variable prefix`/share/PolicyKit/policy/
 989             AC_SUBST(policydir)
 990         ],
 991         [
 992             HAVE_POLKIT=0
 993             if test "x$polkit" = xyes ; then
 994                 AC_MSG_ERROR([*** PolicyKit support not found])
 995             fi
 996         ])
 997 else
 998     HAVE_POLKIT=0
 999 fi
1000
1001 AC_SUBST(POLKIT_CFLAGS)
1002 AC_SUBST(POLKIT_LIBS)
1003 AC_SUBST(HAVE_POLKIT)
1004 AM_CONDITIONAL([HAVE_POLKIT], [test "x$HAVE_POLKIT" = x1])
1005
1006 #### OpenSSL support (optional) ####
1007
1008 AC_ARG_ENABLE([openssl],
1009     AS_HELP_STRING([--disable-openssl],[Disable OpenSSL support (used for Airtunes/RAOP)]),
1010         [
1011             case "${enableval}" in
1012                 yes) openssl=yes ;;
1013                 no) openssl=no ;;
1014                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-openssl) ;;
1015             esac
1016         ],
1017         [openssl=auto])
1018
1019 if test "x${openssl}" != xno ; then
1020
1021     PKG_CHECK_MODULES(OPENSSL, [ openssl > 0.9 ],
1022         [
1023             HAVE_OPENSSL=1
1024             AC_DEFINE([HAVE_OPENSSL], 1, [Have OpenSSL])
1025         ],
1026         [
1027             HAVE_OPENSSL=0
1028             if test "x$openssl" = xyes ; then
1029                 AC_MSG_ERROR([*** OpenSSL support not found])
1030             fi
1031         ])
1032 else
1033     HAVE_OPENSSL=0
1034 fi
1035
1036 AC_SUBST(OPENSSL_CFLAGS)
1037 AC_SUBST(OPENSSL_LIBS)
1038 AC_SUBST(HAVE_OPENSSL)
1039 AM_CONDITIONAL([HAVE_OPENSSL], [test "x$HAVE_OPENSSL" = x1])
1040
1041 ### Build and Install man pages ###
1042 AC_ARG_ENABLE(manpages,
1043         AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]),
1044 [case "${enableval}" in
1045   yes) manpages=yes ;;
1046   no)  manpages=no ;;
1047   *) AC_MSG_ERROR([bad value ${enableval} for --disable-manpages]) ;;
1048 esac],[manpages=yes])
1049
1050 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$manpages" = xyes])
1051
1052 #### PulseAudio system group & user  #####
1053
1054 AC_ARG_WITH(system_user, AS_HELP_STRING([--with-system-user=<user>],[User for running the PulseAudio daemon as a system-wide instance (pulse)]))
1055 if test -z "$with_system_user" ; then
1056     PA_SYSTEM_USER=pulse
1057 else
1058     PA_SYSTEM_USER=$with_system_user
1059 fi
1060 AC_SUBST(PA_SYSTEM_USER)
1061 AC_DEFINE_UNQUOTED(PA_SYSTEM_USER,"$PA_SYSTEM_USER", [User for running the PulseAudio system daemon])
1062
1063 AC_ARG_WITH(system_group,AS_HELP_STRING([--with-system-group=<group>],[Group for running the PulseAudio daemon as a system-wide instance (pulse)]))
1064 if test -z "$with_system_group" ; then
1065     PA_SYSTEM_GROUP=pulse
1066 else
1067     PA_SYSTEM_GROUP=$with_system_group
1068 fi
1069 AC_SUBST(PA_SYSTEM_GROUP)
1070 AC_DEFINE_UNQUOTED(PA_SYSTEM_GROUP,"$PA_SYSTEM_GROUP", [Group for the PulseAudio system daemon])
1071
1072 AC_ARG_WITH(realtime_group,AS_HELP_STRING([--with-realtime-group=<group>],[Group for users that are allowed to start the PulseAudio daemon with realtime scheduling (realtime)]))
1073 if test -z "$with_realtime_group" ; then
1074     PA_REALTIME_GROUP=pulse-rt
1075 else
1076     PA_REALTIME_GROUP=$with_realtime_group
1077 fi
1078 AC_SUBST(PA_REALTIME_GROUP)
1079 AC_DEFINE_UNQUOTED(PA_REALTIME_GROUP,"$PA_REALTIME_GROUP", [Realtime group])
1080
1081 AC_ARG_WITH(access_group,AS_HELP_STRING([--with-access-group=<group>],[Group which is allowed access to a system-wide PulseAudio daemon (pulse-access)]))
1082 if test -z "$with_access_group" ; then
1083     PA_ACCESS_GROUP=pulse-access
1084 else
1085     PA_ACCESS_GROUP=$with_access_group
1086 fi
1087 AC_SUBST(PA_ACCESS_GROUP)
1088 AC_DEFINE_UNQUOTED(PA_ACCESS_GROUP,"$PA_ACCESS_GROUP", [Access group])
1089
1090 AC_ARG_ENABLE(
1091         per_user_esound_socket,
1092         AS_HELP_STRING([--disable-per-user-esound-socket], [Use global esound socket directory /tmp/.esd/socket.]),
1093         [
1094             case "${enableval}" in
1095                 yes) per_user_esound_socket=1 ;;
1096                 no) per_user_esound_socket=0 ;;
1097                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-per-user-esound-socket) ;;
1098             esac
1099         ],
1100         [per_user_esound_socket=1])
1101
1102 if test "x$per_user_esound_socket" = "x1"; then
1103    AC_DEFINE([USE_PER_USER_ESOUND_SOCKET], [1], [Define this if you want per-user esound socket directories])
1104 fi
1105
1106 #### PulseAudio system runtime dir ####
1107 PA_SYSTEM_RUNTIME_PATH="${localstatedir}/run/pulse"
1108 AC_SUBST(PA_SYSTEM_RUNTIME_PATH)
1109 PA_SYSTEM_CONFIG_PATH="${localstatedir}/lib/pulse"
1110 AC_SUBST(PA_SYSTEM_CONFIG_PATH)
1111 PA_SYSTEM_STATE_PATH="${localstatedir}/lib/pulse"
1112 AC_SUBST(PA_SYSTEM_STATE_PATH)
1113
1114 ###################################
1115 #            Output               #
1116 ###################################
1117
1118 AC_ARG_ENABLE(
1119         [static-bins],
1120         AS_HELP_STRING([--enable-static-bins],[Statically link executables.]),
1121         [STATIC_BINS=1], [STATIC_BINS=0])
1122 AM_CONDITIONAL([STATIC_BINS], [test "x$STATIC_BINS" = "x1"])
1123
1124 AC_ARG_WITH(
1125         [preopen-mods],
1126         AS_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
1127         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
1128 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
1129 if test "x$PREOPEN_MODS" != "xall" ; then
1130     tmpLIBS=""
1131     for mod in $PREOPEN_MODS; do
1132         tmpLIBS="$tmpLIBS module-$mod.la"
1133     done
1134     PREOPEN_MODS="$tmpLIBS"
1135     AC_SUBST(PREOPEN_MODS)
1136 fi
1137
1138 AC_ARG_WITH(
1139         [module-dir],
1140         AS_HELP_STRING([--with-module-dir],[Directory where to install the modules to (defaults to ${libdir}/pulse-${PA_MAJORMINORMICRO}/modules/]),
1141         [modlibexecdir=$withval], [modlibexecdir="${libdir}/pulse-${PA_MAJORMINORMICRO}/modules/"])
1142
1143 AC_SUBST(modlibexecdir)
1144
1145 AC_ARG_ENABLE(
1146         [force-preopen],
1147         AS_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]),
1148         [FORCE_PREOPEN=$enableval], [FORCE_PREOPEN=no])
1149 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "xyes"])
1150
1151 AC_CONFIG_FILES([
1152 Makefile
1153 libltdl/Makefile
1154 src/Makefile
1155 man/Makefile
1156 libpulse.pc
1157 libpulse-simple.pc
1158 libpulse-browse.pc
1159 libpulse-mainloop-glib.pc
1160 doxygen/Makefile
1161 doxygen/doxygen.conf
1162 src/pulse/version.h
1163 po/Makefile.in
1164 ])
1165 AC_OUTPUT
1166
1167 # ==========================================================================
1168 ENABLE_X11=no
1169 if test "x$HAVE_X11" = "x1" ; then
1170    ENABLE_X11=yes
1171 fi
1172
1173 ENABLE_OSS=no
1174 if test "x$HAVE_OSS" = "x1" ; then
1175    ENABLE_OSS=yes
1176 fi
1177
1178 ENABLE_ALSA=no
1179 if test "x$HAVE_ALSA" = "x1" ; then
1180    ENABLE_ALSA=yes
1181 fi
1182
1183 ENABLE_SOLARIS=no
1184 if test "x$HAVE_SOLARIS" = "x1" ; then
1185    ENABLE_SOLARIS=yes
1186 fi
1187
1188 ENABLE_GLIB20=no
1189 if test "x$HAVE_GLIB20" = "x1" ; then
1190    ENABLE_GLIB20=yes
1191 fi
1192
1193 ENABLE_GCONF=no
1194 if test "x$HAVE_GCONF" = "x1" ; then
1195    ENABLE_GCONF=yes
1196 fi
1197
1198 ENABLE_AVAHI=no
1199 if test "x$HAVE_AVAHI" = "x1" ; then
1200    ENABLE_AVAHI=yes
1201 fi
1202
1203 ENABLE_JACK=no
1204 if test "x$HAVE_JACK" = "x1" ; then
1205    ENABLE_JACK=yes
1206 fi
1207
1208 ENABLE_LIBASYNCNS=no
1209 if test "x$HAVE_LIBASYNCNS" = "x1" ; then
1210    ENABLE_LIBASYNCNS=yes
1211 fi
1212
1213 ENABLE_LIRC=no
1214 if test "x$HAVE_LIRC" = "x1" ; then
1215    ENABLE_LIRC=yes
1216 fi
1217
1218 ENABLE_HAL=no
1219 if test "x$HAVE_HAL" = "x1" ; then
1220    ENABLE_HAL=yes
1221 fi
1222
1223 ENABLE_TCPWRAP=no
1224 if test "x${LIBWRAP_LIBS}" != x ; then
1225    ENABLE_TCPWRAP=yes
1226 fi
1227
1228 ENABLE_LIBSAMPLERATE=no
1229 if test "x${HAVE_LIBSAMPLERATE}" = "x1" ; then
1230    ENABLE_LIBSAMPLERATE=yes
1231 fi
1232
1233 ENABLE_BLUEZ=no
1234 if test "x${HAVE_BLUEZ}" = "x1" ; then
1235    ENABLE_BLUEZ=yes
1236 fi
1237
1238 ENABLE_POLKIT=no
1239 if test "x${HAVE_POLKIT}" = "x1" ; then
1240    ENABLE_POLKIT=yes
1241 fi
1242
1243 ENABLE_OPENSSL=no
1244 if test "x${HAVE_OPENSSL}" = "x1" ; then
1245    ENABLE_OPENSSL=yes
1246 fi
1247
1248 ENABLE_PER_USER_ESOUND_SOCKET=no
1249 if test "x$per_user_esound_socket" = "x1" ; then
1250    ENABLE_PER_USER_ESOUND_SOCKET=yes
1251 fi
1252
1253 echo "
1254  ---{ $PACKAGE_NAME $VERSION }---
1255
1256     prefix:                        ${prefix}
1257     sysconfdir:                    ${sysconfdir}
1258     localstatedir:                 ${localstatedir}
1259     System Runtime Path:           ${PA_SYSTEM_RUNTIME_PATH}
1260     System State Path:             ${PA_SYSTEM_STATE_PATH}
1261     System Config Path:            ${PA_SYSTEM_CONFIG_PATH}
1262     Compiler:                      ${CC}
1263     CFLAGS:                        ${CFLAGS}
1264
1265     Have X11:                      ${ENABLE_X11}
1266     Enable OSS:                    ${ENABLE_OSS}
1267     Enable Alsa:                   ${ENABLE_ALSA}
1268     Enable Solaris:                ${ENABLE_SOLARIS}
1269     Enable GLib 2.0:               ${ENABLE_GLIB20}
1270     Enable GConf:                  ${ENABLE_GCONF}
1271     Enable Avahi:                  ${ENABLE_AVAHI}
1272     Enable Jack:                   ${ENABLE_JACK}
1273     Enable Async DNS:              ${ENABLE_LIBASYNCNS}
1274     Enable LIRC:                   ${ENABLE_LIRC}
1275     Enable HAL:                    ${ENABLE_HAL}
1276     Enable BlueZ:                  ${ENABLE_BLUEZ}
1277     Enable TCP Wrappers:           ${ENABLE_TCPWRAP}
1278     Enable libsamplerate:          ${ENABLE_LIBSAMPLERATE}
1279     Enable PolicyKit:              ${ENABLE_POLKIT}
1280     Enable OpenSSL (for Airtunes): ${ENABLE_OPENSSL}
1281
1282     System User:                   ${PA_SYSTEM_USER}
1283     System Group:                  ${PA_SYSTEM_GROUP}
1284     Realtime Group:                ${PA_REALTIME_GROUP}
1285     Access Group:                  ${PA_ACCESS_GROUP}
1286     Enable per-user EsounD socket: ${ENABLE_PER_USER_ESOUND_SOCKET}
1287     Force preopen:                 ${FORCE_PREOPEN}
1288     Preopened modules:             ${PREOPEN_MODS}
1289 "