configure.ac

   1 AC_PREREQ(2.60)
   2 AC_INIT([kmod],
   3         [16],
   4         [linux-modules@vger.kernel.org],
   5         [kmod],
   6         [http://git.kernel.org/?p=utils/kernel/kmod/kmod.git])
   7
   8 AC_CONFIG_SRCDIR([libkmod/libkmod.c])
   9 AC_CONFIG_AUX_DIR([build-aux])
  10 AM_INIT_AUTOMAKE([check-news foreign 1.11 silent-rules
  11         tar-pax no-dist-gzip dist-xz subdir-objects color-tests parallel-tests])
  12 AC_PROG_CC_STDC
  13 AC_USE_SYSTEM_EXTENSIONS
  14 AC_SYS_LARGEFILE
  15 AC_CONFIG_MACRO_DIR([m4])
  16 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  17 AM_SILENT_RULES([yes])
  18 LT_INIT([disable-static pic-only])
  19 AC_PREFIX_DEFAULT([/usr])
  20 AM_MAINTAINER_MODE([enable])
  21
  22 AS_IF([test "x$enable_static" = "xyes"],
  23       [AC_MSG_ERROR([--enable-static is not supported by kmod])])
  24
  25
  26 #####################################################################
  27 # Program checks and configurations
  28 #####################################################################
  29
  30 AC_PROG_CC
  31 AC_PROG_CC_C99
  32 AM_PROG_CC_C_O
  33 AC_PROG_GCC_TRADITIONAL
  34 AC_C_BIGENDIAN
  35
  36 AC_PROG_SED
  37 AC_PROG_MKDIR_P
  38 PKG_PROG_PKG_CONFIG
  39 AC_PATH_PROG([XSLTPROC], [xsltproc])
  40
  41
  42 #####################################################################
  43 # Function and structure checks
  44 #####################################################################
  45
  46 AC_CHECK_FUNCS_ONCE(__xstat)
  47 AC_CHECK_FUNCS_ONCE([__secure_getenv secure_getenv])
  48 AC_CHECK_FUNCS_ONCE([finit_module])
  49
  50 # dietlibc doesn't have st.st_mtim struct member
  51 AC_CHECK_MEMBERS([struct stat.st_mtim], [], [], [#include <sys/stat.h>])
  52
  53 # Check kernel headers
  54 AC_CHECK_HEADERS_ONCE([linux/module.h])
  55
  56 AC_MSG_CHECKING([whether _Static_assert() is supported])
  57 AC_COMPILE_IFELSE(
  58         [AC_LANG_SOURCE([[_Static_assert(1, "Test");]])],
  59         [AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define if _Static_assert() is available])
  60          AC_MSG_RESULT([yes])],
  61         [AC_MSG_RESULT([no])])
  62
  63 #####################################################################
  64 # --with-
  65 #####################################################################
  66
  67 AC_ARG_WITH([rootlibdir],
  68         AS_HELP_STRING([--with-rootlibdir=DIR], [rootfs directory to install shared libraries]),
  69         [], [with_rootlibdir=$libdir])
  70 AC_SUBST([rootlibdir], [$with_rootlibdir])
  71
  72 AC_ARG_WITH([xz],
  73         AS_HELP_STRING([--with-xz], [handle Xz-compressed modules @<:@default=disabled@:>@]),
  74         [], [with_xz=no])
  75 AS_IF([test "x$with_xz" != "xno"], [
  76         PKG_CHECK_MODULES([liblzma], [liblzma >= 4.99])
  77         AC_DEFINE([ENABLE_XZ], [1], [Enable Xz for modules.])
  78 ], [
  79         AC_MSG_NOTICE([Xz support not requested])
  80 ])
  81
  82 AC_ARG_WITH([zlib],
  83         AS_HELP_STRING([--with-zlib], [handle gzipped modules @<:@default=disabled@:>@]),
  84         [], [with_zlib=no])
  85 AS_IF([test "x$with_zlib" != "xno"], [
  86         PKG_CHECK_MODULES([zlib], [zlib])
  87         AC_DEFINE([ENABLE_ZLIB], [1], [Enable zlib for modules.])
  88 ], [
  89         AC_MSG_NOTICE([zlib support not requested])
  90 ])
  91
  92 AC_ARG_WITH([bashcompletiondir],
  93         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
  94         [],
  95         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
  96                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
  97         ] , [
  98                 with_bashcompletiondir=${datadir}/bash-completion/completions
  99         ])])
 100 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
 101
 102 #####################################################################
 103 # --enable-
 104 #####################################################################
 105
 106 AC_ARG_ENABLE([tools],
 107         AS_HELP_STRING([--disable-tools], [disable building tools that provide same functionality as module-init-tools @<:@default=enabled@:>@]),
 108         [], enable_tools=yes)
 109 AM_CONDITIONAL([BUILD_TOOLS], [test "x$enable_tools" = "xyes"])
 110
 111 AC_ARG_ENABLE([manpages],
 112         AS_HELP_STRING([--disable-manpages], [disable manpages @<:@default=enabled@:>@]),
 113         [], enable_manpages=yes)
 114 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$enable_manpages" = "xyes"])
 115 AS_IF(["x$enable_manpages" != "xno"], ["have_manpages=yes"])
 116
 117 AC_ARG_ENABLE([logging],
 118         AS_HELP_STRING([--disable-logging], [disable system logging @<:@default=enabled@:>@]),
 119         [], enable_logging=yes)
 120 AS_IF([test "x$enable_logging" = "xyes"], [
 121         AC_DEFINE(ENABLE_LOGGING, [1], [System logging.])
 122 ])
 123
 124 AC_ARG_ENABLE([debug],
 125         AS_HELP_STRING([--enable-debug], [enable debug messages @<:@default=disabled@:>@]),
 126         [], [enable_debug=no])
 127 AS_IF([test "x$enable_debug" = "xyes"], [
 128         AC_DEFINE(ENABLE_DEBUG, [1], [Debug messages.])
 129 ])
 130
 131 m4_ifdef([GTK_DOC_CHECK], [
 132 GTK_DOC_CHECK([1.14],[--flavour no-tmpl-flat])
 133 ], [
 134 AM_CONDITIONAL([ENABLE_GTK_DOC], false)])
 135
 136
 137 #####################################################################
 138 # Default CFLAGS and LDFLAGS
 139 #####################################################################
 140
 141 CC_CHECK_FLAGS_APPEND(with_cflags, [CFLAGS], [\
 142                        -pipe \
 143                        -DANOTHER_BRICK_IN_THE \
 144                        -Wall \
 145                        -W \
 146                        -Wextra \
 147                        -Wno-inline \
 148                        -Wvla \
 149                        -Wundef \
 150                        -Wformat=2 \
 151                        -Wlogical-op \
 152                        -Wsign-compare \
 153                        -Wformat-security \
 154                        -Wmissing-include-dirs \
 155                        -Wformat-nonliteral \
 156                        -Wold-style-definition \
 157                        -Wpointer-arith \
 158                        -Winit-self \
 159                        -Wdeclaration-after-statement \
 160                        -Wfloat-equal \
 161                        -Wmissing-prototypes \
 162                        -Wstrict-prototypes \
 163                        -Wredundant-decls \
 164                        -Wmissing-declarations \
 165                        -Wmissing-noreturn \
 166                        -Wshadow \
 167                        -Wendif-labels \
 168                        -Wstrict-aliasing=2 \
 169                        -Wwrite-strings \
 170                        -Wno-long-long \
 171                        -Wno-overlength-strings \
 172                        -Wno-unused-parameter \
 173                        -Wno-missing-field-initializers \
 174                        -Wno-unused-result \
 175                        -Wnested-externs \
 176                        -Wchar-subscripts \
 177                        -Wtype-limits \
 178                        -Wuninitialized \
 179                        -fno-common \
 180                        -fdiagnostics-show-option \
 181                        -fdiagnostics-color=auto \
 182                        -fvisibility=hidden \
 183                        -ffunction-sections \
 184                        -fdata-sections])
 185 AC_SUBST([WARNINGFLAGS], $with_cflags)
 186
 187
 188 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [ \
 189                        -Wl,--as-needed \
 190                        -Wl,--gc-sections])
 191 AC_SUBST([GCLDFLAGS], $with_ldflags)
 192
 193 #####################################################################
 194 # Generate files from *.in
 195 #####################################################################
 196
 197 AC_CONFIG_HEADERS(config.h)
 198 AC_CONFIG_FILES([
 199         Makefile
 200         man/Makefile
 201         libkmod/docs/Makefile
 202         libkmod/docs/version.xml
 203 ])
 204
 205
 206 #####################################################################
 207
 208 AC_OUTPUT
 209 AC_MSG_RESULT([
 210         $PACKAGE $VERSION
 211         =======
 212
 213         prefix:                 ${prefix}
 214         sysconfdir:             ${sysconfdir}
 215         libdir:                 ${libdir}
 216         rootlibdir:             ${rootlibdir}
 217         includedir:             ${includedir}
 218         bindir:                 ${bindir}
 219         Bash completions dir:   ${with_bashcompletiondir}
 220
 221         compiler:               ${CC}
 222         cflags:                 ${with_cflags} ${CFLAGS}
 223         ldflags:                ${with_ldflags} ${LDFLAGS}
 224
 225         tools:                  ${enable_tools}
 226         logging:                ${enable_logging}
 227         compression:            xz=${with_xz}  zlib=${with_zlib}
 228         debug:                  ${enable_debug}
 229         doc:                    ${enable_gtk_doc}
 230         man:                    ${enable_manpages}
 231 ])