configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # in easier to understand terms:
  24 #
  25 # <mclasen> on the stable branch, interface age == micro
  26 # <mclasen> on the unstable (ie master), interface age = 0
  27
  28 m4_define([glib_major_version], [2])
  29 m4_define([glib_minor_version], [31])
  30 m4_define([glib_micro_version], [7])
  31 m4_define([glib_interface_age], [0])
  32 m4_define([glib_binary_age],
  33           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  34 m4_define([glib_version],
  35           [glib_major_version.glib_minor_version.glib_micro_version])
  36
  37 # libtool version related macros
  38 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  39 m4_define([glib_lt_current],
  40           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  41 m4_define([glib_lt_revision], [glib_interface_age])
  42 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  43 m4_define([glib_lt_current_minus_age],
  44           [m4_eval(glib_lt_current - glib_lt_age)])
  45
  46 # if the minor version number is odd, then we want debugging.  Otherwise
  47 # we only want minimal debugging support.
  48 m4_define([glib_debug_default],
  49           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  50
  51
  52 AC_INIT(glib, [glib_version],
  53         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  54
  55 AC_CONFIG_HEADER([config.h])
  56 AC_CONFIG_SRCDIR([glib/glib.h])
  57 AC_CONFIG_MACRO_DIR([m4macros])
  58
  59 # Save this value here, since automake will set cflags later
  60 cflags_set=${CFLAGS+set}
  61
  62 AM_INIT_AUTOMAKE([1.11 no-define no-dist-gzip dist-xz tar-ustar])
  63 AM_MAINTAINER_MODE([enable])
  64
  65 # Support silent build rules. Disable
  66 # by either passing --disable-silent-rules to configure or passing V=1
  67 # to make
  68 AM_SILENT_RULES([yes])
  69
  70 GLIB_MAJOR_VERSION=glib_major_version
  71 GLIB_MINOR_VERSION=glib_minor_version
  72 GLIB_MICRO_VERSION=glib_micro_version
  73 GLIB_INTERFACE_AGE=glib_interface_age
  74 GLIB_BINARY_AGE=glib_binary_age
  75 GLIB_VERSION=glib_version
  76
  77 AC_SUBST(GLIB_MAJOR_VERSION)
  78 AC_SUBST(GLIB_MINOR_VERSION)
  79 AC_SUBST(GLIB_MICRO_VERSION)
  80 AC_SUBST(GLIB_VERSION)
  81 AC_SUBST(GLIB_INTERFACE_AGE)
  82 AC_SUBST(GLIB_BINARY_AGE)
  83
  84 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  85           [Define to the GLIB major version])
  86 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  87           [Define to the GLIB minor version])
  88 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  89           [Define to the GLIB micro version])
  90 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  91           [Define to the GLIB interface age])
  92 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  93           [Define to the GLIB binary age])
  94
  95 # libtool versioning
  96 LT_RELEASE=glib_lt_release
  97 LT_CURRENT=glib_lt_current
  98 LT_REVISION=glib_lt_revision
  99 LT_AGE=glib_lt_age
 100 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 101 AC_SUBST(LT_RELEASE)
 102 AC_SUBST(LT_CURRENT)
 103 AC_SUBST(LT_REVISION)
 104 AC_SUBST(LT_AGE)
 105 AC_SUBST(LT_CURRENT_MINUS_AGE)
 106
 107 dnl Checks for programs.
 108 AC_PROG_CC
 109 AC_PROG_CPP
 110
 111 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 112
 113 AC_CANONICAL_HOST
 114
 115 AC_MSG_CHECKING([for the BeOS])
 116 case $host in
 117   *-*-beos*)
 118     glib_native_beos="yes"
 119     ;;
 120   *)
 121     glib_native_beos="no"
 122     ;;
 123 esac
 124 AC_MSG_RESULT([$glib_native_beos])
 125
 126 dnl
 127
 128 AC_MSG_CHECKING([for Win32])
 129 LIB_EXE_MACHINE_FLAG=X86
 130 case "$host" in
 131   *-*-mingw*)
 132     glib_native_win32=yes
 133     glib_pid_type='void *'
 134     glib_cv_stack_grows=no
 135     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 136     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 137     # (Sorry, I don't know exactly what is the problem, but it is related to
 138     # floating point formatting and decimal point vs. comma.)
 139     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 140     # rigorous enough to notice, though.
 141     # So preset the autoconf cache variables.
 142     ac_cv_func_vsnprintf_c99=no
 143     ac_cv_func_snprintf_c99=no
 144     case "$host" in
 145     x86_64-*-*)
 146       LIB_EXE_MACHINE_FLAG=X64
 147       ;;
 148     esac
 149     ;;
 150   *)
 151     glib_native_win32=no
 152     glib_pid_type=int
 153     ;;
 154 esac
 155 case $host in
 156   *-*-linux*)
 157     glib_os_linux=yes
 158     ;;
 159 esac
 160
 161 AC_MSG_RESULT([$glib_native_win32])
 162
 163 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 164
 165 glib_have_carbon=no
 166 AC_MSG_CHECKING([for Mac OS X Carbon support])
 167 AC_TRY_CPP([
 168 #include <Carbon/Carbon.h>
 169 #include <CoreServices/CoreServices.h>
 170 ], glib_have_carbon=yes)
 171
 172 AC_MSG_RESULT([$glib_have_carbon])
 173
 174 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 175 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 176 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 177 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 178 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 179
 180 if test "$glib_native_win32" = "yes"; then
 181   AC_CHECK_TOOL(WINDRES, windres, no)
 182   if test "$WINDRES" = no; then
 183     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 184   fi
 185   AC_CHECK_TOOL(NM, nm, no)
 186   if test "$NM" = no; then
 187     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 188   fi
 189   AC_CHECK_TOOL(RANLIB, ranlib, :)
 190   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 191 fi
 192 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 193
 194 if test "$glib_native_win32" != yes; then
 195     # libtool option to control which symbols are exported
 196     # right now, symbols starting with _ are not exported
 197     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^g.*"'
 198 else
 199     # We currently use .def files on Windows
 200     LIBTOOL_EXPORT_OPTIONS=
 201 fi
 202 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 203
 204 if test "x$glib_have_carbon" = "xyes"; then
 205   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 206   LDFLAGS="$LDFLAGS -framework Carbon"
 207 fi
 208
 209 gl_GLIBC21
 210 if test "x$GLIBC21" = "xyes"; then
 211   AC_DEFINE([_GNU_SOURCE], 1, [Make all glibc extensions visible])
 212 fi
 213
 214 dnl declare --enable-* args and collect ac_help strings
 215 AC_ARG_ENABLE(debug,
 216               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 217                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 218               enable_debug=glib_debug_default)
 219
 220 AC_ARG_ENABLE(gc_friendly,
 221               [AC_HELP_STRING([--enable-gc-friendly],
 222                               [turn on garbage collector friendliness [default=no]])],,
 223               [enable_gc_friendly=no])
 224 AC_ARG_ENABLE(mem_pools,
 225               [AC_HELP_STRING([--disable-mem-pools],
 226                               [disable all glib memory pools])],,
 227               [disable_mem_pools=no])
 228 AC_ARG_ENABLE(rebuilds,
 229               [AC_HELP_STRING([--disable-rebuilds],
 230                               [disable all source autogeneration rules])],,
 231               [enable_rebuilds=yes])
 232
 233 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 234 if test "x$enable_gc_friendly" = "xyes"; then
 235   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 236   AC_MSG_RESULT([yes])
 237 else
 238   AC_MSG_RESULT([no])
 239 fi
 240
 241 AC_MSG_CHECKING([whether to disable memory pools])
 242 if test "x$disable_mem_pools" = "xno"; then
 243   AC_MSG_RESULT([no])
 244 else
 245   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 246   AC_SUBST(DISABLE_MEM_POOLS)
 247   AC_MSG_RESULT([yes])
 248 fi
 249
 250 dnl location to install runtime libraries, e.g. ../../lib to install
 251 dnl to /lib if libdir is /usr/lib
 252 AC_ARG_WITH(runtime-libdir,
 253            [AC_HELP_STRING([--with-runtime-libdir=RELPATH],
 254                            [install runtime libraries relative to libdir])],
 255            [],
 256            [with_runtime_libdir=""])
 257 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 258 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 259 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 260 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 261 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 262
 263 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 264 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 265 AC_LANG_SAVE
 266 AC_LANG_CPLUSPLUS
 267 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 268 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 269 AC_LANG_RESTORE
 270
 271 AM_PROG_CC_STDC
 272 AM_PROG_CC_C_O
 273 AC_PROG_INSTALL
 274
 275 AC_SYS_LARGEFILE
 276
 277 PKG_PROG_PKG_CONFIG(0.16)
 278
 279 if test "x$enable_debug" = "xyes"; then
 280   if test x$cflags_set != xset ; then
 281       case " $CFLAGS " in
 282       *[[\ \    ]]-g[[\ \       ]]*) ;;
 283       *) CFLAGS="$CFLAGS -g" ;;
 284       esac
 285   fi
 286   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 287 else
 288   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 289
 290   if test "x$enable_debug" = "xno"; then
 291     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 292   fi
 293 fi
 294
 295 # Ensure MSVC-compatible struct packing convention is used when
 296 # compiling for Win32 with gcc.
 297 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 298 # gcc2 uses "-fnative-struct".
 299 if test x"$glib_native_win32" = xyes; then
 300   if test x"$GCC" = xyes; then
 301     msnative_struct=''
 302     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 303     if test -z "$ac_cv_prog_CC"; then
 304       our_gcc="$CC"
 305     else
 306       our_gcc="$ac_cv_prog_CC"
 307     fi
 308     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 309       2.)
 310         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 311           msnative_struct='-fnative-struct'
 312         fi
 313         ;;
 314       *)
 315         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 316           msnative_struct='-mms-bitfields'
 317         fi
 318         ;;
 319     esac
 320     if test x"$msnative_struct" = x ; then
 321       AC_MSG_RESULT([no way])
 322       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 323     else
 324       CFLAGS="$CFLAGS $msnative_struct"
 325       AC_MSG_RESULT([${msnative_struct}])
 326     fi
 327   fi
 328 fi
 329 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 330 AC_SUBST(GLIB_EXTRA_CFLAGS)
 331
 332 AC_EXEEXT
 333
 334 # define a MAINT-like variable REBUILD which is set if Perl
 335 # and awk are found, so autogenerated sources can be rebuilt
 336 AC_PROG_AWK
 337 AC_CHECK_PROGS(PERL, [perl5 perl])
 338 # We would like indent, but don't require it.
 339 AC_CHECK_PROG(INDENT, indent, indent)
 340 REBUILD=\#
 341 if test "x$enable_rebuilds" = "xyes" && \
 342      test -n "$PERL" && \
 343      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 344      test -n "$AWK" ; then
 345   REBUILD=
 346 fi
 347 AC_SUBST(REBUILD)
 348
 349 # Need full path to Perl for glib-mkenums
 350 #
 351 if test "x$PERL" != x ; then
 352   AC_PATH_PROG(PERL_PATH, [$PERL])
 353 fi
 354 if test "x$PERL_PATH" = x ; then
 355   PERL_PATH="/usr/bin/env perl"
 356 fi
 357 AC_SUBST(PERL_PATH)
 358
 359 # Need suitable python path for greport
 360 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 361
 362
 363 dnl ***********************
 364 dnl *** Tests for iconv ***
 365 dnl ***********************
 366 dnl
 367 dnl We do this before the gettext checks, to avoid distortion
 368
 369 dnl On Windows we use a native implementation
 370
 371 if test x"$glib_native_win32" = xyes; then
 372   with_libiconv=native
 373 else
 374   AC_ARG_WITH(libiconv,
 375               [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 376                               [use the libiconv library])],,
 377               [with_libiconv=maybe])
 378
 379   found_iconv=no
 380   case $with_libiconv in
 381     maybe)
 382       # Check in the C library first
 383       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 384       # Check if we have GNU libiconv
 385       if test $found_iconv = "no"; then
 386         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 387       fi
 388       # Check if we have a iconv in -liconv, possibly from vendor
 389       if test $found_iconv = "no"; then
 390         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 391       fi
 392       ;;
 393     no)
 394       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 395       ;;
 396     gnu|yes)
 397       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 398       ;;
 399     native)
 400       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 401       ;;
 402   esac
 403
 404   if test "x$found_iconv" = "xno" ; then
 405      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 406   fi
 407 fi
 408
 409 AC_ARG_ENABLE(iconv-cache,
 410               [AC_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 411                               [cache iconv descriptors [default=auto]])],,
 412               [enable_iconv_cache=auto])
 413
 414 AC_MSG_CHECKING([whether to cache iconv descriptors])
 415 case $enable_iconv_cache in
 416   auto)
 417     if test $ac_cv_gnu_library_2_1 = yes; then
 418       enable_iconv_cache=no
 419     else
 420       enable_iconv_cache=yes
 421     fi
 422   ;;
 423   yes|no)
 424   ;;
 425   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 426   ;;
 427 esac
 428
 429 if test $enable_iconv_cache = yes; then
 430    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 431 fi
 432
 433 AC_MSG_RESULT($enable_iconv_cache)
 434
 435
 436 dnl
 437 dnl zlib support
 438 dnl
 439 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 440 if test "x$found_zlib" = "xno" ; then
 441   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 442   if test "x$found_zlib" = "xno" ; then
 443     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 444   fi
 445   ZLIB_LIBS='-lz'
 446   AC_SUBST(ZLIB_LIBS)
 447 fi
 448
 449 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 450 AC_SUBST(LIBFFI_CFLAGS)
 451 AC_SUBST(LIBFFI_LIBS)
 452
 453 dnl
 454 dnl gettext support
 455 dnl
 456
 457 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 458 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 459 GLIB_GNU_GETTEXT
 460
 461 if test "$gt_cv_have_gettext" != "yes" ; then
 462   AC_MSG_ERROR([
 463 *** You must have either have gettext support in your C library, or use the
 464 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 465 ])
 466 fi
 467
 468 LIBS="$INTLLIBS $LIBS"
 469
 470 GETTEXT_PACKAGE=glib20
 471 AC_SUBST(GETTEXT_PACKAGE)
 472 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 473   [Define the gettext package to be used])
 474
 475 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 476
 477 dnl
 478 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 479 dnl
 480
 481 if test x"$glib_native_win32" != xyes; then
 482   if test x$with_libiconv != xno ; then
 483     case " $INTLLIBS " in
 484     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 485     *) ICONV_LIBS="-liconv" ;;
 486     esac
 487   fi
 488 fi
 489 AC_SUBST(ICONV_LIBS)
 490
 491 case $with_libiconv in
 492   gnu)
 493     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 494     ;;
 495   native)
 496     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 497     ;;
 498 esac
 499
 500 dnl Initialize libtool
 501 LT_PREREQ([2.2])
 502 LT_INIT([disable-static win32-dll])
 503 dnl when using libtool 2.x create libtool early, because it's used in configure
 504 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 505
 506
 507 if test "x$GCC" = "xyes"; then
 508   case " $CFLAGS " in
 509   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 510   *) CFLAGS="$CFLAGS -Wall" ;;
 511   esac
 512 fi
 513
 514 if test "$glib_native_win32" = "yes"; then
 515   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 516     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 517   fi
 518   if test x$enable_static = xyes; then
 519     glib_win32_static_compilation=yes
 520     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 521 #define GOBJECT_STATIC_COMPILATION 1"
 522     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 523   fi
 524 fi
 525 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 526
 527 dnl
 528 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 529 dnl
 530 if test $cross_compiling != yes ; then
 531     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 532     glib_save_LIBS=$LIBS
 533     LIBS="$LIBS -lm"
 534     AC_TRY_RUN([#include <math.h>
 535                  int main (void) { return (log(1) != log(1.)); }],
 536          AC_MSG_RESULT(none needed),
 537          glib_save_CFLAGS=$CFLAGS
 538          CFLAGS="$CFLAGS -std1"
 539          AC_TRY_RUN([#include <math.h>
 540                      int main (void) { return (log(1) != log(1.)); }],
 541              AC_MSG_RESULT(-std1),
 542              AC_MSG_RESULT()
 543              CFLAGS=$glib_save_CFLAGS
 544              AC_MSG_WARN(
 545                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 546          )
 547     )
 548     LIBS=$glib_save_LIBS
 549 fi
 550
 551 dnl NeXTStep cc seems to need this
 552 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 553 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 554   AC_MSG_RESULT(none needed),
 555   glib_save_CFLAGS=$CFLAGS
 556   CFLAGS="$CFLAGS -posix"
 557   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 558     AC_MSG_RESULT(-posix),
 559     AC_MSG_RESULT()
 560     CFLAGS=$glib_save_CFLAGS
 561     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 562
 563 # Checks for library functions.
 564 AC_FUNC_VPRINTF
 565 AC_FUNC_ALLOCA
 566 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2)
 567 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 568
 569 dnl don't use AC_CHECK_FUNCS here, otherwise HAVE_QSORT_R will
 570 dnl be automatically defined, which we don't want to do
 571 dnl until we have checked this function is actually usable
 572 AC_CHECK_FUNC([qsort_r])
 573
 574 # BSD has a qsort_r with wrong argument order
 575 if test x$ac_cv_func_qsort_r = xyes ; then
 576   AC_CACHE_CHECK([if qsort_r uses glibc compatible argument order], glib_cv_have_qsort_r, [
 577   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 578   #define _GNU_SOURCE
 579   #include <stdlib.h>
 580
 581   static int
 582   cmp (const void *a, const void *b, void *c)
 583   {
 584     const int *ia = a;
 585     const int *ib = b;
 586
 587     if (*ia < *ib)
 588       return -1;
 589     else if (*ia > *ib)
 590       return 1;
 591     else
 592       return 0;
 593   }
 594
 595   int
 596   main (int argc, char **argv)
 597   {
 598     int arr[3] = { 1, 2, 0 };
 599     int d = 3;
 600
 601     qsort_r (arr, 3, sizeof (int), cmp, &d);
 602
 603     if (arr[0] == 0 && arr[1] == 1 && arr[2] == 2)
 604       return 0;
 605     else
 606       return 1;
 607   }]])],[glib_cv_have_qsort_r=yes],[glib_cv_have_qsort_r=no],[glib_cv_have_qsort_r=no])])
 608 fi
 609
 610 if test x$glib_cv_have_qsort_r = xyes ; then
 611   AC_DEFINE(HAVE_QSORT_R, 1, [Define to 1 if you have the 'qsort_r' function])
 612 fi
 613
 614 AC_CHECK_SIZEOF(char)
 615 AC_CHECK_SIZEOF(short)
 616 AC_CHECK_SIZEOF(long)
 617 AC_CHECK_SIZEOF(int)
 618 AC_CHECK_SIZEOF(void *)
 619 AC_CHECK_SIZEOF(long long)
 620 AC_CHECK_SIZEOF(__int64)
 621
 622 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 623   :
 624 else
 625   AC_MSG_ERROR([
 626 *** GLib requires a 64 bit type. You might want to consider
 627 *** using the GNU C compiler.
 628 ])
 629 fi
 630
 631 if test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8; then
 632         # long long is a 64 bit integer.
 633         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 634         AC_CACHE_VAL(glib_cv_long_long_format,[
 635                 for format in ll q I64; do
 636                   AC_TRY_RUN([#include <stdio.h>
 637                         int main()
 638                         {
 639                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 640                           char buffer[1000];
 641                           sprintf (buffer, "%${format}u", a);
 642                           sscanf (buffer, "%${format}u", &b);
 643                           exit (b!=a);
 644                         }
 645                         ],
 646                         [glib_cv_long_long_format=${format}
 647                         break],
 648                         [],[:])
 649                 done])
 650         if test -n "$glib_cv_long_long_format"; then
 651           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 652           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 653           if test x"$glib_cv_long_long_format" = xI64; then
 654             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 655           fi
 656         else
 657           AC_MSG_RESULT(none)
 658         fi
 659 elif test x$ac_cv_sizeof___int64 = x8; then
 660         # __int64 is a 64 bit integer.
 661         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 662         # We know this is MSVCRT.DLL, and what the formats are
 663         glib_cv_long_long_format=I64
 664         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 665         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 666         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 667 fi
 668
 669 AC_C_CONST
 670
 671 dnl ok, here we try to check whether the systems prototypes for
 672 dnl malloc and friends actually match the prototypes provided
 673 dnl by gmem.h (keep in sync). i currently only know how to check
 674 dnl this reliably with gcc (-Werror), improvements for other
 675 dnl compilers are apprechiated.
 676 SANE_MALLOC_PROTOS=no
 677 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 678 glib_save_CFLAGS=$CFLAGS
 679 if test "x$GCC" = "xyes"; then
 680   CFLAGS="$CFLAGS -Werror"
 681   AC_TRY_COMPILE([#include <stdlib.h>], [
 682     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 683     void* (*my_malloc_p)  (size_t)         = malloc;
 684     void  (*my_free_p)    (void*)          = free;
 685     void* (*my_realloc_p) (void*, size_t)  = realloc;
 686     my_calloc_p = 0;
 687     my_malloc_p = 0;
 688     my_free_p = 0;
 689     my_realloc_p = 0;
 690   ],
 691     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 692       [Define if you have correct malloc prototypes])
 693     SANE_MALLOC_PROTOS=yes)
 694 fi
 695 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 696 CFLAGS=$glib_save_CFLAGS
 697
 698 dnl
 699 dnl check in which direction the stack grows
 700 dnl
 701 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 702         AC_TRY_RUN([
 703         volatile int *a = 0, *b = 0;
 704         void foo (void);
 705         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 706         void foo (void) { volatile int x = 5; b = &x; }
 707         ],
 708         glib_cv_stack_grows=no
 709         ,
 710         glib_cv_stack_grows=yes
 711         ,)
 712 ])
 713
 714 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 715 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 716 dnl actually supported.
 717 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 718         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 719         __inline int foo () { return 0; }
 720         int main () { return foo (); }
 721         ]])],
 722         glib_cv_has__inline=yes
 723         ,
 724         glib_cv_has__inline=no
 725         ,)
 726 ])
 727 case x$glib_cv_has__inline in
 728 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 729 esac
 730 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 731         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 732         __inline__ int foo () { return 0; }
 733         int main () { return foo (); }
 734         ]])],
 735         glib_cv_has__inline__=yes
 736         ,
 737         glib_cv_has__inline__=no
 738         ,)
 739 ])
 740 case x$glib_cv_has__inline__ in
 741 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 742 esac
 743 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 744         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 745         #undef inline
 746         inline int foo () { return 0; }
 747         int main () { return foo (); }
 748         ]])],
 749         glib_cv_hasinline=yes
 750         ,
 751         glib_cv_hasinline=no
 752         ,)
 753 ])
 754 case x$glib_cv_hasinline in
 755 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 756 esac
 757
 758 # if we can use inline functions in headers
 759 AC_MSG_CHECKING(if inline functions in headers work)
 760 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 761 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 762 #  undef inline
 763 #  define inline __inline__
 764 #elif !defined (G_HAVE_INLINE)
 765 #  undef inline
 766 #  if defined (G_HAVE___INLINE__)
 767 #    define inline __inline__
 768 #  elif defined (G_HAVE___INLINE)
 769 #    define inline __inline
 770 #  endif
 771 #endif
 772
 773 int glib_test_func2 (int);
 774
 775 static inline int
 776 glib_test_func1 (void) {
 777   return glib_test_func2 (1);
 778 }
 779
 780 int
 781 main (void) {
 782   int i = 1;
 783 }]])],[g_can_inline=yes],[g_can_inline=no])
 784 AC_MSG_RESULT($g_can_inline)
 785
 786 dnl *** check for working do while(0) macros ***
 787 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 788         AC_TRY_COMPILE([],[
 789         #define STMT_START do
 790         #define STMT_END while(0)
 791         #define STMT_TEST STMT_START { i = 0; } STMT_END
 792         int main(void) { int i = 1; STMT_TEST; return i; }],
 793         [g_cv_support_dowhile_macros=yes],
 794         [g_cv_support_dowhile_macros=no],
 795         [g_cv_support_dowhile_macros=yes])
 796 ])
 797 if test x$g_cv_support_dowhile_macros = xyes; then
 798   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 799 fi
 800
 801 # check for flavours of varargs macros
 802 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 803 AC_TRY_COMPILE([],[
 804 int a(int p1, int p2, int p3);
 805 #define call_a(...) a(1,__VA_ARGS__)
 806 call_a(2,3);
 807 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 808 AC_MSG_RESULT($g_have_iso_c_varargs)
 809
 810 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 811 if test "$CXX" = ""; then
 812 dnl No C++ compiler
 813   g_have_iso_cxx_varargs=no
 814 else
 815   AC_LANG_CPLUSPLUS
 816   AC_TRY_COMPILE([],[
 817 int a(int p1, int p2, int p3);
 818 #define call_a(...) a(1,__VA_ARGS__)
 819 call_a(2,3);
 820 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 821   AC_LANG_C
 822 fi
 823 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 824
 825 AC_MSG_CHECKING(for GNUC varargs macros)
 826 AC_TRY_COMPILE([],[
 827 int a(int p1, int p2, int p3);
 828 #define call_a(params...) a(1,params)
 829 call_a(2,3);
 830 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 831 AC_MSG_RESULT($g_have_gnuc_varargs)
 832
 833 # check for GNUC visibility support
 834 AC_MSG_CHECKING(for GNUC visibility attribute)
 835 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 836 void
 837 __attribute__ ((visibility ("hidden")))
 838      f_hidden (void)
 839 {
 840 }
 841 void
 842 __attribute__ ((visibility ("internal")))
 843      f_internal (void)
 844 {
 845 }
 846 void
 847 __attribute__ ((visibility ("protected")))
 848      f_protected (void)
 849 {
 850 }
 851 void
 852 __attribute__ ((visibility ("default")))
 853      f_default (void)
 854 {
 855 }
 856 int main (int argc, char **argv)
 857 {
 858         f_hidden();
 859         f_internal();
 860         f_protected();
 861         f_default();
 862         return 0;
 863 }
 864 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 865 AC_MSG_RESULT($g_have_gnuc_visibility)
 866 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 867
 868 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 869 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 870 #else
 871 # include "error: this is not Sun Studio."
 872 #endif
 873 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 874 AC_MSG_RESULT($g_have_sunstudio_visibility)
 875 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 876
 877 # check for bytesex stuff
 878 AC_C_BIGENDIAN
 879 if test x$ac_cv_c_bigendian = xuniversal ; then
 880 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 881 #else
 882 #error Not a big endian.
 883 #endif],
 884     ac_cv_c_bigendian=yes
 885     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 886 #else
 887 #error Not a little endian.
 888 #endif],
 889     ac_cv_c_bigendian=no
 890     ,AC_MSG_WARN([Could not determine endianness.])))
 891 fi
 892
 893
 894 # check for header files
 895 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 896 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 897 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 898 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h])
 899 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
 900 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 901 AC_CHECK_HEADERS([linux/magic.h])
 902 AC_CHECK_HEADERS([sys/prctl.h])
 903
 904 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
 905 [#if HAVE_SYS_PARAM_H
 906  #include <sys/param.h>
 907  #endif
 908 ])
 909
 910 AC_CHECK_HEADERS([xlocale.h])
 911
 912 # check for structure fields
 913 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 914 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 915 #include <sys/stat.h>
 916 #include <unistd.h>
 917 #ifdef HAVE_SYS_STATFS_H
 918 #include <sys/statfs.h>
 919 #endif
 920 #ifdef HAVE_SYS_PARAM_H
 921 #include <sys/param.h>
 922 #endif
 923 #ifdef HAVE_SYS_MOUNT_H
 924 #include <sys/mount.h>
 925 #endif])
 926 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 927 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 928 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 929 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 930
 931 AC_STRUCT_DIRENT_D_TYPE
 932
 933 # Checks for libcharset
 934 AM_LANGINFO_CODESET
 935 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 936 AC_CHECK_FUNCS(setlocale)
 937
 938 # check additional type sizes
 939 AC_CHECK_SIZEOF(size_t)
 940
 941 dnl Try to figure out whether gsize, gssize should be long or int
 942 AC_MSG_CHECKING([for the appropriate definition for size_t])
 943
 944 case $ac_cv_sizeof_size_t in
 945   $ac_cv_sizeof_short)
 946       glib_size_type=short
 947       ;;
 948   $ac_cv_sizeof_int)
 949       glib_size_type=int
 950       ;;
 951   $ac_cv_sizeof_long)
 952       glib_size_type=long
 953       ;;
 954   $ac_cv_sizeof_long_long)
 955       glib_size_type='long long'
 956       ;;
 957   $ac_cv_sizeof__int64)
 958       glib_size_type='__int64'
 959       ;;
 960   *)  AC_MSG_ERROR([No type matching size_t in size])
 961       ;;
 962 esac
 963
 964 dnl If int/long are the same size, we see which one produces
 965 dnl warnings when used in the location as size_t. (This matters
 966 dnl on AIX with xlc)
 967 dnl
 968 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 969    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 970   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 971 #if defined(_AIX) && !defined(__GNUC__)
 972 #pragma options langlvl=stdc89
 973 #endif
 974 #include <stddef.h>
 975 int main ()
 976 {
 977   size_t s = 1;
 978   unsigned int *size_int = &s;
 979   return (int)*size_int;
 980 }
 981     ]])],glib_size_type=int,
 982       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 983 #if defined(_AIX) && !defined(__GNUC__)
 984 #pragma options langlvl=stdc89
 985 #endif
 986 #include <stddef.h>
 987 int main ()
 988 {
 989    size_t s = 1;
 990    unsigned long *size_long = &s;
 991    return (int)*size_long;
 992 }
 993         ]])],glib_size_type=long)])
 994 fi
 995
 996 AC_MSG_RESULT(unsigned $glib_size_type)
 997
 998 # Check for some functions
 999 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
1000 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid)
1001 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat)
1002 # Check for high-resolution sleep functions
1003 AC_CHECK_FUNCS(splice)
1004 AC_CHECK_FUNCS(prlimit)
1005
1006 # To avoid finding a compatibility unusable statfs, which typically
1007 # successfully compiles, but warns to use the newer statvfs interface:
1008 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
1009 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
1010
1011 AC_MSG_CHECKING([whether to use statfs or statvfs])
1012 # Some systems have both statfs and statvfs, pick the most "native" for these
1013 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
1014    [
1015    # on solaris and irix, statfs doesn't even have the f_bavail field
1016    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
1017       [ac_cv_func_statfs=no],
1018    # else, at least on linux, statfs is the actual syscall
1019       [ac_cv_func_statvfs=no])
1020    ])
1021
1022 AS_IF([test x$ac_cv_func_statfs = xyes],
1023       [
1024          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1025          AC_MSG_RESULT([statfs])
1026       ],
1027       [test x$ac_cv_func_statvfs = xyes],
1028       [
1029          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1030          AC_MSG_RESULT([statvfs])
1031       ],
1032       [  AC_MSG_RESULT([neither])])
1033
1034 AC_CHECK_HEADERS(crt_externs.h)
1035 AC_CHECK_FUNCS(_NSGetEnviron)
1036
1037 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
1038
1039 AC_FUNC_VSNPRINTF_C99
1040 AC_FUNC_PRINTF_UNIX98
1041
1042 # Internet address families
1043 if test $glib_native_win32 = yes; then
1044   glib_inet_includes=["
1045 #include <winsock2.h>
1046   "]
1047 else
1048   glib_inet_includes=["
1049 #include <sys/types.h>
1050 #include <sys/socket.h>
1051   "]
1052 fi
1053
1054 glib_failed=false
1055 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1056 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1057 # winsock defines this even though it doesn't support it
1058 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1059 if $glib_failed ; then
1060   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1061 fi
1062
1063 glib_failed=false
1064 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1065 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1066 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1067 if $glib_failed ; then
1068   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1069 fi
1070
1071 AC_CHECK_FUNCS(getprotobyname_r endservent)
1072 AC_CHECK_HEADERS([netdb.h wspiapi.h arpa/nameser_compat.h])
1073
1074 if test $glib_native_win32 = no; then
1075   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1076   NETWORK_LIBS=""
1077   AC_MSG_CHECKING([for res_query])
1078   AC_TRY_LINK([#include <sys/types.h>
1079                #include <netinet/in.h>
1080                #include <arpa/nameser.h>
1081                #include <resolv.h>
1082               ],[
1083                res_query("test", 0, 0, (void *)0, 0);
1084               ],[AC_MSG_RESULT([yes])],
1085               [save_libs="$LIBS"
1086                LIBS="-lresolv $LIBS"
1087                AC_TRY_LINK([#include <sys/types.h>
1088                             #include <netinet/in.h>
1089                             #include <arpa/nameser.h>
1090                             #include <resolv.h>
1091                            ],[
1092                             res_query("test", 0, 0, (void *)0, 0);
1093                            ],[AC_MSG_RESULT([in -lresolv])
1094                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1095                            [LIBS="-lbind $save_libs"
1096                             AC_TRY_LINK([#include <resolv.h>],
1097                                         [res_query("test", 0, 0, (void *)0, 0);],
1098                                         [AC_MSG_RESULT([in -lbind])
1099                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1100                                         [AC_MSG_ERROR(not found)])])
1101                LIBS="$save_libs"])
1102   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1103                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1104                                         [AC_MSG_ERROR(Could not find socket())]))
1105 fi
1106 AC_SUBST(NETWORK_LIBS)
1107
1108 AC_CHECK_HEADER([linux/netlink.h],
1109                 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1110                 [#include <sys/socket.h>])
1111 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1112
1113 case $host in
1114   *-*-solaris* )
1115      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1116      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1117      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1118      ;;
1119 esac
1120
1121 dnl
1122 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1123 dnl
1124 if test "$ac_cv_func_statfs" = yes ; then
1125   AC_MSG_CHECKING([number of arguments to statfs()])
1126   AC_TRY_COMPILE([#include <unistd.h>
1127   #ifdef HAVE_SYS_PARAM_H
1128   #include <sys/param.h>
1129   #endif
1130   #ifdef HAVE_SYS_VFS_H
1131   #include <sys/vfs.h>
1132   #endif
1133   #ifdef HAVE_SYS_MOUNT_H
1134   #include <sys/mount.h>
1135   #endif
1136   #ifdef HAVE_SYS_STATFS_H
1137   #include <sys/statfs.h>
1138   #endif], [struct statfs st;
1139   statfs(NULL, &st);],[
1140     AC_MSG_RESULT([2])
1141     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1142     AC_TRY_COMPILE([#include <unistd.h>
1143   #ifdef HAVE_SYS_PARAM_H
1144   #include <sys/param.h>
1145   #endif
1146   #ifdef HAVE_SYS_VFS_H
1147   #include <sys/vfs.h>
1148   #endif
1149   #ifdef HAVE_SYS_MOUNT_H
1150   #include <sys/mount.h>
1151   #endif
1152   #ifdef HAVE_SYS_STATFS_H
1153   #include <sys/statfs.h>
1154   #endif], [struct statfs st;
1155   statfs(NULL, &st, sizeof (st), 0);],[
1156       AC_MSG_RESULT([4])
1157       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1158       AC_MSG_RESULT(unknown)
1159       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1160 fi
1161
1162 #
1163 # Check whether to use an included printf
1164 #
1165
1166 AC_ARG_ENABLE(included-printf,
1167               [AC_HELP_STRING([--enable-included-printf],
1168                               [use included printf [default=auto]])],
1169               enable_included_printf="$enableval")
1170
1171 need_included_printf=no
1172 if test "x$enable_included_printf" = "xyes" ; then
1173   need_included_printf=yes
1174 fi
1175 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1176   need_included_printf=yes
1177 fi
1178 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1179   need_included_printf=yes
1180 fi
1181 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1182    test -z "$glib_cv_long_long_format" ; then
1183   need_included_printf=yes
1184 fi
1185
1186 if test "x$enable_included_printf" = "xno" &&
1187    test "x$need_included_printf" = "xyes" ; then
1188   AC_MSG_ERROR([
1189 *** Your C library's printf doesn't appear to have the features that
1190 *** GLib needs, but you specified --enable-included-printf=no.])
1191 fi
1192
1193 enable_included_printf=$need_included_printf
1194
1195 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1196 if test "$enable_included_printf" != "yes" ; then
1197   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1198 else
1199   if test -z "$glib_cv_long_long_format" ; then
1200     glib_cv_long_long_format="ll"
1201   fi
1202   AC_DEFINE(HAVE_VASPRINTF,1)
1203 fi
1204
1205 # Checks needed for gnulib vasnprintf
1206 bh_C_SIGNED
1207 jm_AC_TYPE_LONG_LONG
1208 gt_TYPE_LONGDOUBLE
1209 gt_TYPE_WCHAR_T
1210 gt_TYPE_WINT_T
1211 AC_TYPE_SIZE_T
1212 AC_CHECK_TYPES(ptrdiff_t)
1213 jm_AC_TYPE_INTMAX_T
1214 AC_CHECK_FUNCS([snprintf wcslen])
1215 AC_FUNC_SNPRINTF_C99
1216
1217 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1218 # The check is borrowed from the PERL Configure script.
1219 if test "$ac_cv_func_memmove" != "yes"; then
1220   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1221     glib_cv_working_bcopy,[AC_TRY_RUN([
1222       int main() {
1223         char buf[128], abc[128], *b;
1224         int len, off, align;
1225         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1226         for (align = 7; align >= 0; align--) {
1227           for (len = 36; len; len--) {
1228             b = buf+align; bcopy(abc, b, len);
1229             for (off = 1; off <= len; off++) {
1230               bcopy(b, b+off, len); bcopy(b+off, b, len);
1231                 if (bcmp(b, abc, len)) return(1);
1232             }
1233           }
1234         }
1235         return(0);
1236       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1237
1238   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1239   if test "$glib_cv_working_bcopy" = "yes"; then
1240     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1241   fi
1242 fi
1243
1244 # Check if <sys/select.h> needs to be included for fd_set
1245 AC_MSG_CHECKING([for fd_set])
1246 AC_TRY_COMPILE([#include <sys/types.h>],
1247         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1248 if test "$gtk_ok" = "yes"; then
1249     AC_MSG_RESULT([yes, found in sys/types.h])
1250 else
1251     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1252     if test "$gtk_ok" = "yes"; then
1253         # *** FIXME: give it a different name
1254         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1255         AC_MSG_RESULT([yes, found in sys/select.h])
1256     else
1257         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1258         AC_MSG_RESULT(no)
1259     fi
1260 fi
1261
1262 dnl *** check for sane realloc() ***
1263 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1264         AC_TRY_RUN([#include <stdlib.h>
1265         int main() {
1266           return realloc (0, sizeof (int)) == 0;
1267         }],
1268         [glib_cv_sane_realloc=yes],
1269         [glib_cv_sane_realloc=no],
1270         [glib_cv_sane_realloc=yes])
1271 ])
1272 if test x$glib_cv_sane_realloc = xyes; then
1273   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1274 fi
1275
1276 dnl Check for nl_langinfo and CODESET
1277 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1278         AC_TRY_COMPILE([#include <langinfo.h>],
1279                 [char *codeset = nl_langinfo (CODESET);],
1280                 [glib_cv_langinfo_codeset=yes],
1281                 [glib_cv_langinfo_codeset=no])])
1282 if test x$glib_cv_langinfo_codeset = xyes; then
1283   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1284 fi
1285
1286 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1287 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1288         AC_TRY_COMPILE([#include <langinfo.h>],
1289                 [char *str;
1290                  str = nl_langinfo (PM_STR);
1291                  str = nl_langinfo (D_T_FMT);
1292                  str = nl_langinfo (D_FMT);
1293                  str = nl_langinfo (T_FMT);
1294                  str = nl_langinfo (T_FMT_AMPM);
1295                  str = nl_langinfo (MON_1);
1296                  str = nl_langinfo (ABMON_12);
1297                  str = nl_langinfo (DAY_1);
1298                  str = nl_langinfo (ABDAY_7);],
1299                 [glib_cv_langinfo_time=yes],
1300                 [glib_cv_langinfo_time=no])])
1301 if test x$glib_cv_langinfo_time = xyes; then
1302   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1303 fi
1304
1305 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_WC
1306 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_WC)], glib_cv_langinfo_outdigit,[
1307         AC_TRY_COMPILE([#include <langinfo.h>],
1308                 [char *str;
1309                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_WC);
1310                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_WC);
1311                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_WC);
1312                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_WC);
1313                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_WC);
1314                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_WC);
1315                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_WC);
1316                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_WC);
1317                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_WC);
1318                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_WC);],
1319                 [glib_cv_langinfo_outdigit=yes],
1320                 [glib_cv_langinfo_outdigit=no])])
1321 if test x$glib_cv_langinfo_outdigit = xyes; then
1322   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_WC)])
1323 fi
1324
1325 dnl ****************************************
1326 dnl *** posix_memalign                   ***
1327 dnl ****************************************
1328 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1329 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1330     glib_cv_compliant_posix_memalign=0
1331     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1332         AC_TRY_RUN([
1333                 #define _XOPEN_SOURCE 600
1334                 #include <stdlib.h> /* posix_memalign() should be defined here */
1335                 /* some systems break if #include <malloc.h> used */
1336                 static void test_memalign (size_t boundary, size_t size) {
1337                     void *mem = 0;
1338                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1339                         exit (1);
1340                     else
1341                       free (mem);
1342                 }
1343                 int main() {
1344                     test_memalign (  128,   128 - 2 * sizeof (void*));
1345                     test_memalign (  256,   256 - 2 * sizeof (void*));
1346                     test_memalign (  512,   512 - 2 * sizeof (void*));
1347                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1348                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1349                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1350                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1351                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1352                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1353                     exit (0); /* success */
1354                 }
1355                 ],
1356             [glib_cv_compliant_posix_memalign=1], [], [:])
1357       :
1358     fi
1359     ])
1360 if test "$glib_cv_compliant_posix_memalign" = "1"; then
1361     AC_MSG_RESULT(yes)
1362     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1363 else
1364     AC_MSG_RESULT(no)
1365 fi
1366
1367
1368 dnl ****************************************
1369 dnl *** strlcpy/strlcat                  ***
1370 dnl ****************************************
1371 # Check for strlcpy
1372 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1373 AC_TRY_RUN([#include <stdlib.h>
1374 #include <string.h>
1375 int main() {
1376   char p[10];
1377   (void) strlcpy (p, "hi", 10);
1378   if (strlcat (p, "bye", 0) != 3)
1379     return 1;
1380   return 0;
1381 }], glib_cv_have_strlcpy=yes,
1382     glib_cv_have_strlcpy=no,
1383     glib_cv_have_strlcpy=no)])
1384 if test "$glib_cv_have_strlcpy" = "yes"; then
1385     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1386 fi
1387
1388
1389 dnl **********************
1390 dnl *** va_copy checks ***
1391 dnl **********************
1392 dnl we currently check for all three va_copy possibilities, so we get
1393 dnl all results in config.log for bug reports.
1394 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1395         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1396 #include <stdlib.h>
1397         void f (int i, ...) {
1398         va_list args1, args2;
1399         va_start (args1, i);
1400         va_copy (args2, args1);
1401         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1402           exit (1);
1403         va_end (args1); va_end (args2);
1404         }
1405         int main() {
1406           f (0, 42);
1407           return 0;
1408         }]])],
1409         [glib_cv_va_copy=yes],
1410         [glib_cv_va_copy=no])
1411 ])
1412 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1413         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1414 #include <stdlib.h>
1415         void f (int i, ...) {
1416         va_list args1, args2;
1417         va_start (args1, i);
1418         __va_copy (args2, args1);
1419         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1420           exit (1);
1421         va_end (args1); va_end (args2);
1422         }
1423         int main() {
1424           f (0, 42);
1425           return 0;
1426         }]])],
1427         [glib_cv___va_copy=yes],
1428         [glib_cv___va_copy=no])
1429 ])
1430
1431 if test "x$glib_cv_va_copy" = "xyes"; then
1432   g_va_copy_func=va_copy
1433 else if test "x$glib_cv___va_copy" = "xyes"; then
1434   g_va_copy_func=__va_copy
1435 fi
1436 fi
1437
1438 if test -n "$g_va_copy_func"; then
1439   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1440 fi
1441
1442 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1443         AC_TRY_RUN([#include <stdarg.h>
1444 #include <stdlib.h>
1445         void f (int i, ...) {
1446         va_list args1, args2;
1447         va_start (args1, i);
1448         args2 = args1;
1449         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1450           exit (1);
1451         va_end (args1); va_end (args2);
1452         }
1453         int main() {
1454           f (0, 42);
1455           return 0;
1456         }],
1457         [glib_cv_va_val_copy=yes],
1458         [glib_cv_va_val_copy=no],
1459         [glib_cv_va_val_copy=yes])
1460 ])
1461
1462 if test "x$glib_cv_va_val_copy" = "xno"; then
1463   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1464 fi
1465
1466 dnl ***********************
1467 dnl *** g_module checks ***
1468 dnl ***********************
1469 G_MODULE_LIBS=
1470 G_MODULE_LIBS_EXTRA=
1471 G_MODULE_PLUGIN_LIBS=
1472 if test x"$glib_native_win32" = xyes; then
1473   dnl No use for this on Win32
1474   G_MODULE_LDFLAGS=
1475 else
1476   export SED
1477   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1478 fi
1479 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1480 G_MODULE_NEED_USCORE=0
1481 G_MODULE_BROKEN_RTLD_GLOBAL=0
1482 G_MODULE_HAVE_DLERROR=0
1483 dnl *** force native WIN32 shared lib loader
1484 if test -z "$G_MODULE_IMPL"; then
1485   case "$host" in
1486   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1487   esac
1488 fi
1489 dnl *** force native AIX library loader
1490 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1491 if test -z "$G_MODULE_IMPL"; then
1492   case "$host" in
1493   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1494   esac
1495 fi
1496 dnl *** dlopen() and dlsym() in system libraries
1497 if test -z "$G_MODULE_IMPL"; then
1498         AC_CHECK_FUNC(dlopen,
1499                       [AC_CHECK_FUNC(dlsym,
1500                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1501                       [])
1502 fi
1503 dnl *** load_image (BeOS)
1504 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1505   AC_CHECK_LIB(root, load_image,
1506       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1507       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1508       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1509       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1510       [])
1511 fi
1512 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1513 if test -z "$G_MODULE_IMPL"; then
1514         AC_CHECK_FUNC(NSLinkModule,
1515                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1516                        G_MODULE_NEED_USCORE=1],
1517                       [])
1518 fi
1519 dnl *** dlopen() and dlsym() in libdl
1520 if test -z "$G_MODULE_IMPL"; then
1521         AC_CHECK_LIB(dl, dlopen,
1522                      [AC_CHECK_LIB(dl, dlsym,
1523                                    [G_MODULE_LIBS=-ldl
1524                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1525                      [])
1526 fi
1527 dnl *** shl_load() in libdld (HP-UX)
1528 if test -z "$G_MODULE_IMPL"; then
1529         AC_CHECK_LIB(dld, shl_load,
1530                 [G_MODULE_LIBS=-ldld
1531                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1532                 [])
1533 fi
1534 dnl *** additional checks for G_MODULE_IMPL_DL
1535 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1536         LIBS_orig="$LIBS"
1537         LDFLAGS_orig="$LDFLAGS"
1538         LIBS="$G_MODULE_LIBS $LIBS"
1539         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1540 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1541         echo "void glib_plugin_test(void) { }" > plugin.c
1542         ${SHELL} ./libtool --mode=compile ${CC} -shared \
1543                 -export-dynamic -o plugin.o plugin.c 2>&1 >/dev/null
1544         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1545                 glib_cv_rtldglobal_broken,[
1546                 AC_TRY_RUN([
1547 #include <dlfcn.h>
1548 #ifndef RTLD_GLOBAL
1549 #  define RTLD_GLOBAL 0
1550 #endif
1551 #ifndef RTLD_LAZY
1552 #  define RTLD_LAZY 0
1553 #endif
1554 int glib_plugin_test;
1555 int main () {
1556     void *handle, *global, *local;
1557     global = &glib_plugin_test;
1558     handle = dlopen ("./.libs/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1559     if (!handle) return 0;
1560     local = dlsym (handle, "glib_plugin_test");
1561     return global == local;
1562 }                       ],
1563                         [glib_cv_rtldglobal_broken=no],
1564                         [glib_cv_rtldglobal_broken=yes],
1565                         [glib_cv_rtldglobal_broken=no])
1566                 rm -f plugin.c plugin.o plugin.lo .libs/plugin.o
1567                 rmdir .libs 2>/dev/null
1568         ])
1569         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1570                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1571         else
1572                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1573         fi
1574 dnl *** check whether we need preceeding underscores
1575         AC_CACHE_CHECK([for preceeding underscore in symbols],
1576                 glib_cv_uscore,[
1577                 AC_TRY_RUN([#include <dlfcn.h>
1578                 int glib_underscore_test (void) { return 42; }
1579                 int main() {
1580                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1581                   handle = dlopen ((void*)0, 0);
1582                   if (handle) {
1583                     f1 = dlsym (handle, "glib_underscore_test");
1584                     f2 = dlsym (handle, "_glib_underscore_test");
1585                   } return (!f2 || f1);
1586                 }],
1587                         [glib_cv_uscore=yes],
1588                         [glib_cv_uscore=no],
1589                         [])
1590                 rm -f plugin.c plugin.$ac_objext plugin.lo
1591         ])
1592         GLIB_ASSERT_SET(glib_cv_uscore)
1593         if test "x$glib_cv_uscore" = "xyes"; then
1594                 G_MODULE_NEED_USCORE=1
1595         else
1596                 G_MODULE_NEED_USCORE=0
1597         fi
1598
1599         LDFLAGS="$LDFLAGS_orig"
1600 dnl *** check for having dlerror()
1601         AC_CHECK_FUNC(dlerror,
1602                 [G_MODULE_HAVE_DLERROR=1],
1603                 [G_MODULE_HAVE_DLERROR=0])
1604         LIBS="$LIBS_orig"
1605 fi
1606 dnl *** done, have we got an implementation?
1607 if test -z "$G_MODULE_IMPL"; then
1608         G_MODULE_IMPL=0
1609         G_MODULE_SUPPORTED=false
1610 else
1611         G_MODULE_SUPPORTED=true
1612 fi
1613
1614 AC_MSG_CHECKING(for the suffix of module shared libraries)
1615 export SED
1616 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1617 eval $shrext_cmds
1618 module=yes eval std_shrext=$shrext_cmds
1619 # chop the initial dot
1620 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1621 AC_MSG_RESULT(.$glib_gmodule_suffix)
1622 # any reason it may fail?
1623 if test "x$glib_gmodule_suffix" = x; then
1624         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1625 fi
1626
1627 AC_SUBST(G_MODULE_SUPPORTED)
1628 AC_SUBST(G_MODULE_IMPL)
1629 AC_SUBST(G_MODULE_LIBS)
1630 AC_SUBST(G_MODULE_LIBS_EXTRA)
1631 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1632 AC_SUBST(G_MODULE_LDFLAGS)
1633 AC_SUBST(G_MODULE_HAVE_DLERROR)
1634 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1635 AC_SUBST(G_MODULE_NEED_USCORE)
1636 AC_SUBST(GLIB_DEBUG_FLAGS)
1637
1638 dnl **********************
1639 dnl *** g_spawn checks ***
1640 dnl **********************
1641
1642 AC_MSG_CHECKING(for gspawn implementation)
1643 case "$host" in
1644   *-*-mingw*)
1645     GSPAWN=gspawn-win32.lo
1646     ;;
1647   *)
1648     GSPAWN=gspawn.lo
1649     ;;
1650 esac
1651 AC_MSG_RESULT($GSPAWN)
1652 AC_SUBST(GSPAWN)
1653
1654 dnl *************************
1655 dnl *** GIOChannel checks ***
1656 dnl *************************
1657
1658 AC_MSG_CHECKING(for GIOChannel implementation)
1659 case "$host" in
1660   *-*-mingw*)
1661     GIO=giowin32.lo
1662     ;;
1663   *)
1664     GIO=giounix.lo
1665     ;;
1666 esac
1667 AC_MSG_RESULT($GIO)
1668 AC_SUBST(GIO)
1669
1670 dnl *********************************
1671 dnl *** Directory for GIO modules ***
1672 dnl *********************************
1673
1674 AC_ARG_WITH(gio-module-dir,
1675            [AC_HELP_STRING([--with-gio-module-dir=DIR],
1676                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1677            [],
1678            [with_gio_module_dir='${libdir}/gio/modules'])
1679 GIO_MODULE_DIR=$with_gio_module_dir
1680 AC_SUBST(GIO_MODULE_DIR)
1681
1682 dnl **********************************
1683 dnl *** Check for libselinux (GIO) ***
1684 dnl **********************************
1685 AC_ARG_ENABLE(selinux,
1686               AC_HELP_STRING([--disable-selinux],
1687                              [build without selinux support]))
1688 msg_selinux=no
1689 SELINUX_LIBS=
1690 if test "x$enable_selinux" != "xno"; then
1691
1692  AC_CHECK_LIB(selinux, is_selinux_enabled,
1693    [AC_CHECK_HEADERS(selinux/selinux.h,
1694      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1695        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1696         SELINUX_LIBS="-lselinux"
1697         msg_selinux=yes])
1698      ])
1699    ])
1700 fi
1701 AC_SUBST(SELINUX_LIBS)
1702
1703 dnl *****************************
1704 dnl ** Check for inotify (GIO) **
1705 dnl *****************************
1706 inotify_support=no
1707 AC_CHECK_HEADERS([sys/inotify.h],
1708 [
1709         inotify_support=yes
1710         AC_CHECK_FUNCS(inotify_init1)
1711 ])
1712
1713 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1714
1715 dnl *********************************
1716 dnl ** Check for Solaris FEN (GIO) **
1717 dnl *********************************
1718 fen_support=no
1719 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1720 #include <port.h>
1721 #ifndef PORT_SOURCE_FILE
1722 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1723 #endif
1724 int main() { return 0; } ]])],
1725 [
1726         fen_support=yes
1727 ],)
1728
1729 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1730
1731 dnl ****************************
1732 dnl *** Checks for FAM (GIO) ***
1733 dnl ****************************
1734
1735 should_disable_fam=no
1736
1737 AC_ARG_ENABLE(fam,
1738               AC_HELP_STRING([--disable-fam],
1739                              [don't use fam for file system monitoring]),
1740                          [
1741                                 if test "x$enable_fam" = "xno"; then
1742                                         should_disable_fam=yes
1743                                 fi
1744                          ]
1745                          )
1746 fam_support=no
1747 FAM_LIBS=
1748 if test "x$should_disable_fam" = "xno"; then
1749 AC_CHECK_LIB(fam, FAMOpen,
1750   [AC_CHECK_HEADERS(fam.h,
1751     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1752      AC_CHECK_LIB(fam, FAMNoExists,
1753                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1754      FAM_LIBS="-lfam"]
1755      fam_support=yes,
1756     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1757   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1758 AC_SUBST(FAM_LIBS)
1759 fi
1760 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1761
1762
1763 dnl *****************************
1764 dnl *** Check for xattr (GIO) ***
1765 dnl *****************************
1766 AC_ARG_ENABLE(xattr,
1767               AC_HELP_STRING([--disable-xattr], [build without xattr support]))
1768 msg_xattr=no
1769 XATTR_LIBS=
1770 if test "x$enable_xattr" != "xno"; then
1771
1772 dnl either glibc or libattr can provide xattr support
1773
1774 dnl for both of them, we check for getxattr being in
1775 dnl the library and a valid xattr header.
1776
1777 dnl try glibc
1778  AC_CHECK_LIB(c, getxattr,
1779    [AC_CHECK_HEADERS(sys/xattr.h,
1780      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1781       msg_xattr=yes])
1782    ])
1783
1784   if test "x$msg_xattr" != "xyes"; then
1785 dnl   failure. try libattr
1786    AC_CHECK_LIB(attr, getxattr,
1787       [AC_CHECK_HEADERS(attr/xattr.h,
1788        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1789         XATTR_LIBS="-lattr"
1790         msg_xattr=yes])
1791       ])
1792   fi
1793
1794   if test "x$msg_xattr" = "xyes"; then
1795     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1796     AC_TRY_COMPILE([
1797       #include <stdio.h>
1798       #ifdef HAVE_SYS_TYPES_H
1799       #include <sys/types.h>
1800       #endif
1801       #ifdef HAVE_SYS_XATTR_H
1802       #include <sys/xattr.h>
1803       #elif HAVE_ATTR_XATTR_H
1804       #include <attr/xattr.h>
1805       #endif
1806     ],
1807     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1808     [
1809       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1810       AC_MSG_RESULT([yes])
1811     ],
1812     [AC_MSG_RESULT([no])]
1813     )
1814   fi
1815
1816 fi
1817 AC_SUBST(XATTR_LIBS)
1818
1819 dnl ****************************************
1820 dnl *** platform dependent source checks ***
1821 dnl ****************************************
1822
1823 AC_MSG_CHECKING(for platform-dependent source)
1824 case "$host" in
1825   *-*-cygwin*|*-*-mingw*)
1826     PLATFORMDEP=gwin32.lo
1827     ;;
1828   *)
1829     PLATFORMDEP=
1830     ;;
1831 esac
1832 AC_MSG_RESULT($PLATFORMDEP)
1833 AC_SUBST(PLATFORMDEP)
1834
1835 AC_MSG_CHECKING([whether to compile timeloop])
1836 case "$host" in
1837   *-*-cygwin*|*-*-mingw*|*-*-minix)
1838     enable_timeloop=no
1839     ;;
1840   *)
1841     enable_timeloop=yes
1842     ;;
1843 esac
1844 AC_MSG_RESULT($enable_timeloop)
1845 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1846
1847 AC_MSG_CHECKING([if building for some Win32 platform])
1848 case "$host" in
1849   *-*-mingw*|*-*-cygwin*)
1850     platform_win32=yes
1851     ;;
1852   *)
1853     platform_win32=no
1854     ;;
1855 esac
1856 AC_MSG_RESULT($platform_win32)
1857 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1858
1859 dnl ***********************
1860 dnl *** g_thread checks ***
1861 dnl ***********************
1862
1863 AC_ARG_WITH(threads,
1864            [AC_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1865                            [specify a thread implementation to use])],
1866            [],
1867            [with_threads=yes])
1868
1869 dnl error and warning message
1870 dnl *************************
1871
1872 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1873
1874 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1875                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1876                 compilation now, but then your programs might not work.
1877                 Please provide information on how it is done on your system."
1878
1879 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1880                  "
1881
1882 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1883                   provide information on your thread implementation."
1884
1885 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1886                 functions will not be MT-safe during their first call because
1887                 there is no working 'getpwuid_r' on your system."
1888
1889 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1890                 because there is no 'localtime_r' on your system."
1891
1892 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1893                 linking threaded applications. As GLib cannot do that
1894                 automatically, you will get an linkg error everytime you are
1895                 not using the right compiler. In that case you have to relink
1896                 with the right compiler. Ususally just '_r' is appended
1897                 to the compiler name."
1898
1899 dnl determination of thread implementation
1900 dnl ***************************************
1901
1902 AC_MSG_CHECKING(for thread implementation)
1903
1904 have_threads=no
1905 if test "x$with_threads" = xyes || test "x$with_threads" = xposix; then
1906         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1907         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1908         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1909         glib_save_CPPFLAGS="$CPPFLAGS"
1910         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1911         if test "x$have_threads" = xno; then
1912                 AC_TRY_COMPILE([#include <pthread.h>],
1913                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1914                         have_threads=posix)
1915         fi
1916         # Tru64Unix requires -pthread to find pthread.h. See #103020
1917         CPPFLAGS="$CPPFLAGS -pthread"
1918         if test "x$have_threads" = xno; then
1919         AC_TRY_COMPILE([#include <pthread.h>],
1920                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1921                        have_threads=posix)
1922         fi
1923         CPPFLAGS="$glib_save_CPPFLAGS"
1924 fi
1925 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1926         case $host in
1927                 *-*-mingw*)
1928                 have_threads=win32
1929                 ;;
1930         esac
1931 fi
1932
1933 if test "x$have_threads" = xno; then
1934         AC_MSG_RESULT(none available)
1935         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1936 else
1937         AC_MSG_RESULT($have_threads)
1938 fi
1939
1940
1941 dnl determination of G_THREAD_CFLAGS
1942 dnl ********************************
1943
1944 G_THREAD_LIBS=
1945 G_THREAD_LIBS_EXTRA=
1946 G_THREAD_CFLAGS=
1947
1948 dnl
1949 dnl Test program for basic POSIX threads functionality
1950 dnl
1951 m4_define([glib_thread_test],[
1952 #include <pthread.h>
1953 int check_me = 0;
1954 void* func(void* data) {check_me = 42; return &check_me;}
1955 int main()
1956  { pthread_t t;
1957    void *ret;
1958    pthread_create (&t, $1, func, 0);
1959    pthread_join (t, &ret);
1960    return (check_me != 42 || ret != &check_me);
1961 }])
1962
1963 if test x"$have_threads" = xposix; then
1964   # First we test for posix, whether -pthread or -pthreads do the trick as
1965   # both CPPFLAG and LIBS.
1966   # One of them does for most gcc versions and some other platforms/compilers
1967   # too and could be considered as the canonical way to go.
1968   case $host in
1969     *-*-cygwin*|*-*-darwin*)
1970        # skip cygwin and darwin -pthread or -pthreads test
1971        ;;
1972     *-solaris*)
1973       # These compiler/linker flags work with both Sun Studio and gcc
1974       # Sun Studio expands -mt to -D_REENTRANT and -lthread
1975       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
1976       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
1977       G_THREAD_LIBS="-lpthread -lthread"
1978       ;;
1979     *)
1980       for flag in pthread pthreads mt; do
1981         glib_save_CFLAGS="$CFLAGS"
1982         CFLAGS="$CFLAGS -$flag"
1983         AC_TRY_RUN(glib_thread_test(0),
1984                    glib_flag_works=yes,
1985                    glib_flag_works=no,
1986                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
1987                                    glib_flag_works=yes,
1988                                    glib_flag_works=no)])
1989         CFLAGS="$glib_save_CFLAGS"
1990         if test $glib_flag_works = yes ; then
1991            G_THREAD_CFLAGS=-$flag
1992         G_THREAD_LIBS=-$flag
1993         break;
1994         fi
1995       done
1996        ;;
1997   esac
1998 fi
1999
2000 if test x"$G_THREAD_CFLAGS" = x; then
2001
2002   # The canonical -pthread[s] does not work. Try something different.
2003
2004   case $host in
2005         *-aix*)
2006                 if test x"$GCC" = xyes; then
2007                         # GCC 3.0 and above needs -pthread.
2008                         # Should be coverd by the case above.
2009                         # GCC 2.x and below needs -mthreads
2010                         G_THREAD_CFLAGS="-mthreads"
2011                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2012                 else
2013                         # We are probably using the aix compiler. Normaly a
2014                         # program would have to be compiled with the _r variant
2015                         # of the corresponding compiler, but we as GLib cannot
2016                         # do that: but the good news is that for compiling the
2017                         # only difference is the added -D_THREAD_SAFE compile
2018                         # option. This is according to the "C for AIX User's
2019                         # Guide".
2020                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2021                 fi
2022                 ;;
2023         *-dg-dgux*)  # DG/UX
2024                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2025                 ;;
2026         *-sysv5uw7*) # UnixWare 7
2027                 # We are not using gcc with -pthread. Catched above.
2028                 G_THREAD_CFLAGS="-Kthread"
2029                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2030                 ;;
2031         *-mingw*)
2032                 # No flag needed when using MSVCRT.DLL
2033                 G_THREAD_CFLAGS=""
2034                 ;;
2035         *)
2036                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2037                 ;;
2038   esac
2039
2040 fi
2041
2042 # if we are not finding the localtime_r function, then we probably are
2043 # not using the proper multithread flag
2044
2045 glib_save_CPPFLAGS="$CPPFLAGS"
2046 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2047
2048 # First we test, whether localtime_r is declared in time.h
2049 # directly. Then we test whether a macro localtime_r exists, in
2050 # which case localtime_r in the test program is replaced and thus
2051 # if we still find localtime_r in the output, it is not defined as
2052 # a macro.
2053
2054 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2055   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2056                                                            localtime_r(a,b)],
2057                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2058
2059 CPPFLAGS="$glib_save_CPPFLAGS"
2060
2061 AC_MSG_CHECKING(thread related cflags)
2062 AC_MSG_RESULT($G_THREAD_CFLAGS)
2063 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2064
2065 dnl determination of G_THREAD_LIBS
2066 dnl ******************************
2067
2068 case $have_threads in
2069         posix)
2070           glib_save_CPPFLAGS="$CPPFLAGS"
2071           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2072           if test x"$G_THREAD_LIBS" = x; then
2073             case $host in
2074               *-aix*)
2075                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2076                 # probably using the aix compiler.
2077                 AC_MSG_WARN($AIX_COMPILE_INFO)
2078                 ;;
2079               *)
2080                 G_THREAD_LIBS=error
2081                 glib_save_LIBS="$LIBS"
2082                 for thread_lib in "" pthread pthread32 pthreads thread; do
2083                         if test x"$thread_lib" = x; then
2084                                 add_thread_lib=""
2085                                 IN=""
2086                         else
2087                                 add_thread_lib="-l$thread_lib"
2088                                 IN=" in -l$thread_lib"
2089                         fi
2090                         if test x"$have_threads" = xposix; then
2091                                 defattr=0
2092                         else
2093                                 defattr=pthread_attr_default
2094                         fi
2095
2096                         LIBS="$add_thread_lib $glib_save_LIBS"
2097
2098                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2099                         AC_TRY_RUN(glib_thread_test($defattr),
2100                                    glib_result=yes,
2101                                    glib_result=no,
2102                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2103                                                    glib_result=yes,
2104                                                    glib_result=no)])
2105                         AC_MSG_RESULT($glib_result)
2106
2107                         if test "$glib_result" = "yes" ; then
2108                           G_THREAD_LIBS="$add_thread_lib"
2109                           break
2110                         fi
2111                 done
2112                 if test "x$G_THREAD_LIBS" = xerror; then
2113                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2114                 fi
2115                 LIBS="$glib_save_LIBS"
2116                 ;;
2117             esac
2118           fi
2119
2120           g_threads_impl="POSIX"
2121           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2122           CPPFLAGS="$glib_save_CPPFLAGS"
2123           ;;
2124         win32)
2125            g_threads_impl="WIN32"
2126            ;;
2127         *)
2128            g_threads_impl="NONE"
2129            G_THREAD_LIBS=error
2130            ;;
2131 esac
2132
2133 if test "x$G_THREAD_LIBS" = xerror; then
2134         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2135 fi
2136
2137 case $host in
2138   *-*-beos*)
2139     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2140     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2141     ;;
2142   *)
2143     ;;
2144 esac
2145
2146 AC_MSG_CHECKING(thread related libraries)
2147 AC_MSG_RESULT($G_THREAD_LIBS)
2148
2149 dnl check for mt safe function variants and some posix functions
2150 dnl ************************************************************
2151
2152 glib_save_LIBS="$LIBS"
2153 # we are not doing the following for now, as this might require glib
2154 # to always be linked with the thread libs on some platforms.
2155 # LIBS="$LIBS $G_THREAD_LIBS"
2156 AC_CHECK_FUNCS(localtime_r gmtime_r)
2157 if test "$ac_cv_header_pwd_h" = "yes"; then
2158         AC_CACHE_CHECK([for posix getpwuid_r],
2159                 ac_cv_func_posix_getpwuid_r,
2160                 [AC_TRY_RUN([
2161 #include <errno.h>
2162 #include <pwd.h>
2163 int main () {
2164     char buffer[10000];
2165     struct passwd pwd, *pwptr = &pwd;
2166     int error;
2167     errno = 0;
2168     error = getpwuid_r (0, &pwd, buffer,
2169                         sizeof (buffer), &pwptr);
2170    return (error < 0 && errno == ENOSYS)
2171            || error == ENOSYS;
2172 }                               ],
2173                         [ac_cv_func_posix_getpwuid_r=yes],
2174                         [ac_cv_func_posix_getpwuid_r=no])])
2175         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2176         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2177                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2178                         [Have POSIX function getpwuid_r])
2179         else
2180                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2181                         ac_cv_func_nonposix_getpwuid_r,
2182                         [AC_TRY_LINK([#include <pwd.h>],
2183                                 [char buffer[10000];
2184                                 struct passwd pwd;
2185                                 getpwuid_r (0, &pwd, buffer,
2186                                                 sizeof (buffer));],
2187                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2188                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2189                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2190                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2191                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2192                                 [Have non-POSIX function getpwuid_r])
2193                 fi
2194         fi
2195 fi
2196 if test "$ac_cv_header_grp_h" = "yes"; then
2197         AC_CACHE_CHECK([for posix getgrgid_r],
2198                 ac_cv_func_posix_getgrgid_r,
2199                 [AC_TRY_RUN([
2200 #include <errno.h>
2201 #include <grp.h>
2202 int main () {
2203     char buffer[10000];
2204     struct group grp, *grpptr = &grp;
2205     int error;
2206     errno = 0;
2207     error = getgrgid_r (0, &grp, buffer,
2208                         sizeof (buffer), &grpptr);
2209    return (error < 0 && errno == ENOSYS)
2210            || error == ENOSYS;
2211 }                              ],
2212                        [ac_cv_func_posix_getgrgid_r=yes],
2213                        [ac_cv_func_posix_getgrgid_r=no])])
2214         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2215         if test "$ac_cv_func_posix_getgrgid_r" = yes; then
2216                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2217                         [Have POSIX function getgrgid_r])
2218         else
2219                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2220                         ac_cv_func_nonposix_getgrgid_r,
2221                         [AC_TRY_LINK([#include <grp.h>],
2222                                 [char buffer[10000];
2223                                 struct group grp;
2224                                 getgrgid_r (0, &grp, buffer,
2225                                 sizeof (buffer));],
2226                         [ac_cv_func_nonposix_getgrgid_r=yes],
2227                         [ac_cv_func_nonposix_getgrgid_r=no])])
2228                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2229                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2230                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2231                                 [Have non-POSIX function getgrgid_r])
2232                 fi
2233         fi
2234 fi
2235 LIBS="$G_THREAD_LIBS $LIBS"
2236 if test x"$have_threads" = xposix; then
2237         glib_save_CPPFLAGS="$CPPFLAGS"
2238         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2239         # This is not AC_CHECK_FUNC to also work with function
2240         # name mangling in header files.
2241         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2242         AC_TRY_LINK([#include <pthread.h>],
2243                     [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
2244                     [AC_MSG_RESULT(yes)
2245                      AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,[Have function pthread_attr_setstacksize])],
2246                     [AC_MSG_RESULT(no)])
2247         CPPFLAGS="$glib_save_CPPFLAGS"
2248 fi
2249
2250 LIBS="$glib_save_LIBS"
2251
2252 # now spit out all the warnings.
2253 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2254    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2255         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2256 fi
2257 if test "$ac_cv_func_localtime_r" != "yes"; then
2258         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2259 fi
2260
2261 #
2262 # Hack to deal with:
2263 #
2264 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2265 #     building shared libraries with linux.
2266 #  b) FreeBSD doesn't do this either.
2267 #
2268 case $host in
2269   *-*-freebsd*|*-*-linux*)
2270     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2271     ;;
2272   *-*-openbsd*)
2273     LDFLAGS="$LDFLAGS -pthread"
2274     ;;
2275   *)
2276     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2277     ;;
2278 esac
2279
2280 AC_SUBST(G_THREAD_CFLAGS)
2281 AC_SUBST(G_THREAD_LIBS)
2282 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2283 AC_SUBST(G_THREAD_LIBS_EXTRA)
2284
2285 AC_CHECK_FUNCS(clock_gettime, [], [
2286   AC_CHECK_LIB(rt, clock_gettime, [
2287     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2288     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2289     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2290     GLIB_RT_LIBS="-lrt"
2291   ])
2292 ])
2293 AC_SUBST(GLIB_RT_LIBS)
2294
2295
2296 dnl ************************
2297 dnl *** g_atomic_* tests ***
2298 dnl ************************
2299
2300 dnl We need to decide at configure time if GLib will use real atomic
2301 dnl operations ("lock free") or emulated ones with a mutex.  This is
2302 dnl because we must put this information in glibconfig.h so we know if
2303 dnl it is safe or not to inline using compiler intrinsics directly from
2304 dnl the header.
2305 dnl
2306 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2307 dnl user is interested in knowing if they can use the atomic ops across
2308 dnl processes.
2309 dnl
2310 dnl We can currently support the atomic ops natively when building GLib
2311 dnl with recent versions of GCC or MSVC.  MSVC doesn't run ./configure,
2312 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2313 dnl we are using GCC.
2314 dnl
2315 dnl Note that the atomic ops are only available with GCC on x86 when
2316 dnl using -march=i486 or higher.  If we detect that the atomic ops are
2317 dnl not available but would be available given the right flags, we want
2318 dnl to abort and advise the user to fix their CFLAGS.  It's better to do
2319 dnl that then to silently fall back on emulated atomic ops just because
2320 dnl the user had the wrong build environment.
2321
2322 dnl We may add other compilers here in the future...
2323 AC_MSG_CHECKING([for lock-free atomic intrinsics])
2324 AC_TRY_COMPILE([],
2325                [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2326                [glib_cv_g_atomic_lock_free=yes],
2327                [glib_cv_g_atomic_lock_free=no])
2328 AC_MSG_RESULT($glib_cv_g_atomic_lock_free)
2329
2330 if test "$glib_cv_g_atomic_lock_free" = "no"; then
2331   SAVE_CFLAGS="${CFLAGS}"
2332   CFLAGS="-march=i486"
2333   AC_TRY_COMPILE([],
2334                  [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2335                  [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2336                  [])
2337   CFLAGS="${SAVE_CFLAGS}"
2338 fi
2339
2340 dnl We need a more robust approach here...
2341 case $host_cpu in
2342   i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2343     glib_memory_barrier_needed=no
2344     ;;
2345   sparc*|alpha*|powerpc*|ia64)
2346     glib_memory_barrier_needed=yes
2347     ;;
2348   *)
2349     glib_memory_barrier_needed=yes
2350     ;;
2351 esac
2352
2353 dnl ************************
2354 dnl ** Check for futex(2) **
2355 dnl ************************
2356 AC_CACHE_CHECK(for futex(2) system call,
2357     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2358 #include <linux/futex.h>
2359 #include <sys/syscall.h>
2360 #include <unistd.h>
2361 ],[
2362 int
2363 main (void)
2364 {
2365   /* it is not like this actually runs or anything... */
2366   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2367   return 0;
2368 }
2369 ])],glib_cv_futex=yes,glib_cv_futex=no))
2370 if test x"$glib_cv_futex" = xyes; then
2371   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2372 fi
2373
2374 AC_CACHE_CHECK(for eventfd(2) system call,
2375     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2376 #include <sys/eventfd.h>
2377 #include <unistd.h>
2378 ],[
2379 int
2380 main (void)
2381 {
2382   eventfd (0, EFD_CLOEXEC);
2383   return 0;
2384 }
2385 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2386 if test x"$glib_cv_eventfd" = x"yes"; then
2387   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2388 fi
2389 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2390
2391 dnl ****************************************
2392 dnl *** GLib POLL* compatibility defines ***
2393 dnl ****************************************
2394
2395 glib_poll_includes=["
2396 #include <sys/types.h>
2397 #include <sys/poll.h>
2398 "]
2399
2400 if test $ac_cv_header_sys_types_h = yes &&
2401    test $ac_cv_header_sys_poll_h = yes ; then
2402   glib_failed=false
2403   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2404   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2405   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2406   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2407   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2408   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2409   if $glib_failed ; then
2410     AC_MSG_ERROR([Could not determine values for POLL* constants])
2411   fi
2412 else
2413   glib_cv_value_POLLIN=1
2414   glib_cv_value_POLLOUT=4
2415   glib_cv_value_POLLPRI=2
2416   glib_cv_value_POLLERR=8
2417   glib_cv_value_POLLHUP=16
2418   glib_cv_value_POLLNVAL=32
2419 fi
2420
2421 AC_MSG_CHECKING([for broken poll])
2422 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2423         #include <stdlib.h>
2424         #include <fcntl.h>
2425         #include <poll.h>
2426         #ifdef HAVE_SYS_POLL_H
2427         #include <sys/poll.h>
2428         #endif
2429         int main(void) {
2430           struct pollfd fds[1];
2431           int fd;
2432           fd = open("/dev/null", 1);
2433           fds[0].fd = fd;
2434           fds[0].events = POLLIN;
2435           fds[0].revents = 0;
2436           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2437                 exit(1);  /* Does not work for devices -- fail */
2438           }
2439           exit(0);
2440         }]])],
2441   [broken_poll=no],
2442   [broken_poll=yes
2443    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2444   [broken_poll="no (cross compiling)"])
2445 AC_MSG_RESULT($broken_poll)
2446
2447 dnl *********************
2448 dnl *** GRegex checks ***
2449 dnl *********************
2450 PCRE_REQUIRED_VERSION=8.11
2451
2452 # Check if we should compile GRegex
2453 AC_ARG_ENABLE(regex, AC_HELP_STRING([--disable-regex],
2454                                     [disable the compilation of GRegex]),
2455 [case "${enableval}" in
2456   yes) enable_regex=true ;;
2457   no)  enable_regex=false ;;
2458   *) AC_MSG_ERROR(bad value ${enableval} for --enable-regex) ;;
2459 esac],
2460 [enable_regex=true])
2461
2462 AM_CONDITIONAL(ENABLE_REGEX, $enable_regex)
2463
2464 if test x$enable_regex = xtrue; then
2465   AC_DEFINE(ENABLE_REGEX, [], [include GRegex])
2466   # Check if we should use the internal or the system-supplied pcre
2467   AC_ARG_WITH(pcre,
2468              [AC_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2469                              [whether to use system PCRE [default=internal]])])
2470
2471   AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2472
2473   if test "x$with_pcre" = xsystem; then
2474     PKG_CHECK_MODULES(PCRE,
2475                       libpcre >= $PCRE_REQUIRED_VERSION)
2476     AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2477                    glib_save_CFLAGS="$CFLAGS"
2478                    glib_save_LIBS="$LIBS"
2479                    CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2480                    AC_TRY_RUN([#include <pcre.h>
2481                                int main () {
2482                                  int support;
2483                                  pcre_config (PCRE_CONFIG_UTF8, &support);
2484                                  if (!support)
2485                                    return 1;
2486                                  pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2487                                  if (!support)
2488                                    return 1;
2489                                  return 0;
2490                                }],
2491                    glib_cv_pcre_has_unicode=yes,
2492                    glib_cv_pcre_has_unicode=no,
2493                    glib_cv_pcre_has_unicode=yes)
2494                    CFLAGS="$glib_save_CFLAGS"
2495                    LIBS="$glib_save_LIBS"
2496         ])
2497     if test "$glib_cv_pcre_has_unicode" = "no"; then
2498       AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2499     fi
2500     AC_SUBST(PCRE_CFLAGS)
2501     AC_SUBST(PCRE_LIBS)
2502     AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2503     PCRE_REQUIRES=libpcre
2504     AC_SUBST(PCRE_REQUIRES)
2505   else
2506     # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2507     if test x"$GCC" = xyes; then
2508       AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2509       save_CFLAGS="$CFLAGS"
2510       CFLAGS="$CFLAGS -Wno-pointer-sign"
2511       AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2512                             AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2513       CFLAGS="$save_CFLAGS"
2514     fi
2515   fi
2516   AC_SUBST(PCRE_WARN_CFLAGS)
2517 else
2518   AM_CONDITIONAL(USE_SYSTEM_PCRE, false])
2519 fi
2520
2521 dnl **********************
2522 dnl *** Win32 API libs ***
2523 dnl **********************
2524
2525 case $host in
2526   *-*-cygwin*)
2527         G_LIBS_EXTRA="-luser32 -lkernel32"
2528     ;;
2529   *-*-mingw*)
2530         G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm"
2531     ;;
2532   *)
2533         G_LIBS_EXTRA=""
2534     ;;
2535 esac
2536 AC_SUBST(G_LIBS_EXTRA)
2537
2538 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2539 dnl since we need it for g_iconv()
2540
2541 AC_MSG_CHECKING([for EILSEQ])
2542 AC_TRY_COMPILE([
2543 #include <errno.h>
2544 ],
2545 [
2546 int error = EILSEQ;
2547 ], have_eilseq=yes, have_eilseq=no);
2548 AC_MSG_RESULT($have_eilseq)
2549
2550 dnl ******************************************************************
2551 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2552 dnl *** glib-compile-schemas in PATH                               ***
2553 dnl ******************************************************************
2554
2555 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2556
2557 if test $cross_compiling = yes; then
2558   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2559   if test x$GLIB_GENMARSHAL = xno; then
2560     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2561   fi
2562
2563   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2564   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2565     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2566   fi
2567 fi
2568
2569 dnl **************************
2570 dnl *** Checks for gtk-doc ***
2571 dnl **************************
2572
2573 GTK_DOC_CHECK([1.15], [--flavour no-tmpl])
2574
2575 AC_ARG_ENABLE(man,
2576               [AC_HELP_STRING([--enable-man],
2577                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2578               enable_man=no)
2579
2580 if test "${enable_man}" != no; then
2581 dnl
2582 dnl Check for xsltproc
2583 dnl
2584 AC_PATH_PROG([XSLTPROC], [xsltproc])
2585   if test -z "$XSLTPROC"; then
2586     enable_man=no
2587   fi
2588
2589   dnl check for DocBook DTD and stylesheets in the local catalog.
2590   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2591      [DocBook XML DTD V4.1.2],,enable_man=no)
2592   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2593      [DocBook XSL Stylesheets],,enable_man=no)
2594 fi
2595
2596 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2597
2598 dnl
2599 dnl Tracing
2600 dnl
2601
2602 AC_ARG_ENABLE([dtrace],
2603              [AS_HELP_STRING([--enable-dtrace],
2604                               [include tracing support for dtrace])])
2605 have_dtrace=no
2606 AC_MSG_CHECKING([whether to include dtrace tracing support])
2607 if test "x$enable_dtrace" != xno; then
2608   if test x$glib_have_carbon = xyes; then
2609     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2610   else
2611     AC_MSG_RESULT([yes])
2612     AC_CHECK_PROGS(DTRACE, dtrace)
2613     if test -z "$DTRACE"; then
2614       if test "x$enable_dtrace" = xyes; then
2615         AC_MSG_ERROR([dtrace not found])
2616       fi
2617     else
2618       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2619                       [if test "x$enable_dtrace" = xyes; then
2620                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2621                        fi])
2622     fi
2623   fi
2624 else
2625   AC_MSG_RESULT([no])
2626 fi
2627 if test "x$have_dtrace" = xyes; then
2628   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2629 fi
2630 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2631
2632 AC_MSG_CHECKING([whether to include systemtap tracing support])
2633 AC_ARG_ENABLE([systemtap],
2634              [AS_HELP_STRING([--enable-systemtap],
2635                               [include tracing support for systemtap])])
2636 have_systemtap=no
2637 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2638   have_systemtap=yes
2639 fi
2640 AC_MSG_RESULT(${have_systemtap})
2641
2642 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2643
2644 AC_ARG_WITH([tapset-install-dir],
2645             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2646                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2647             [if test "x${withval}" = x; then
2648                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2649              else
2650                ABS_TAPSET_DIR="${withval}"
2651               fi],
2652             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2653 AC_SUBST(ABS_TAPSET_DIR)
2654
2655 dnl ************************************
2656 dnl *** Enable lcov coverage reports ***
2657 dnl ************************************
2658
2659 AC_ARG_ENABLE(gcov,
2660   AS_HELP_STRING([--enable-gcov],
2661                  [enable coverage testing with gcov]),
2662   [use_gcov=$enableval], [use_gcov=no])
2663
2664 if test "x$use_gcov" = "xyes"; then
2665   dnl we need gcc:
2666   if test "$GCC" != "yes"; then
2667     AC_MSG_ERROR([GCC is required for --enable-gcov])
2668   fi
2669
2670   dnl Check if ccache is being used
2671   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2672   case `$SHTOOL path $CC` in
2673     *ccache*[)] gcc_ccache=yes;;
2674     *[)] gcc_ccache=no;;
2675   esac
2676
2677   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2678     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2679   fi
2680
2681   ltp_version_list="1.6 1.7 1.8 1.9"
2682   AC_CHECK_PROG(LTP, lcov, lcov)
2683   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2684
2685   if test "$LTP"; then
2686     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2687       glib_cv_ltp_version=invalid
2688       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2689       for ltp_check_version in $ltp_version_list; do
2690         if test "$ltp_version" = "$ltp_check_version"; then
2691           glib_cv_ltp_version="$ltp_check_version (ok)"
2692         fi
2693       done
2694     ])
2695   else
2696     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2697     AC_MSG_ERROR([$ltp_msg])
2698   fi
2699
2700   case $glib_cv_ltp_version in
2701     ""|invalid[)]
2702       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2703       AC_MSG_ERROR([$ltp_msg])
2704       LTP="exit 0;"
2705       ;;
2706   esac
2707
2708   if test -z "$LTP_GENHTML"; then
2709     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2710   fi
2711
2712   AC_DEFINE(HAVE_GCOV, 1, [Whether you have gcov])
2713
2714   dnl Remove all optimization flags from CFLAGS
2715   changequote({,})
2716   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2717   changequote([,])
2718
2719   dnl Add the special gcc flags
2720   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2721   LDFLAGS="$LDFLAGS -lgcov"
2722 fi
2723
2724 dnl ******************************
2725 dnl *** output the whole stuff ***
2726 dnl ******************************
2727
2728 dnl this section will only be run if config.status is invoked with no
2729 dnl arguments, or with "glib/glibconfig.h" as an argument.
2730 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2731 [
2732         outfile=glib/glibconfig.h-tmp
2733         cat > $outfile <<\_______EOF
2734 /* glibconfig.h
2735  *
2736  * This is a generated file.  Please modify 'configure.ac'
2737  */
2738
2739 #ifndef __GLIBCONFIG_H__
2740 #define __GLIBCONFIG_H__
2741
2742 #include <glib/gmacros.h>
2743
2744 _______EOF
2745
2746         if test x$glib_limits_h = xyes; then
2747           echo '#include <limits.h>' >> $outfile
2748         fi
2749         if test x$glib_float_h = xyes; then
2750           echo '#include <float.h>' >> $outfile
2751         fi
2752         if test x$glib_values_h = xyes; then
2753           echo '#include <values.h>' >> $outfile
2754         fi
2755         if test "$glib_header_alloca_h" = "yes"; then
2756           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2757         fi
2758         if test x$glib_sys_poll_h = xyes; then
2759           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2760         fi
2761         if test x$glib_included_printf != xyes; then
2762           echo "
2763 /* Specifies that GLib's g_print*() functions wrap the
2764  * system printf functions.  This is useful to know, for example,
2765  * when using glibc's register_printf_function().
2766  */" >> $outfile
2767           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2768         fi
2769
2770         cat >> $outfile <<_______EOF
2771
2772 G_BEGIN_DECLS
2773
2774 #define G_MINFLOAT      $glib_mf
2775 #define G_MAXFLOAT      $glib_Mf
2776 #define G_MINDOUBLE     $glib_md
2777 #define G_MAXDOUBLE     $glib_Md
2778 #define G_MINSHORT      $glib_ms
2779 #define G_MAXSHORT      $glib_Ms
2780 #define G_MAXUSHORT     $glib_Mus
2781 #define G_MININT        $glib_mi
2782 #define G_MAXINT        $glib_Mi
2783 #define G_MAXUINT       $glib_Mui
2784 #define G_MINLONG       $glib_ml
2785 #define G_MAXLONG       $glib_Ml
2786 #define G_MAXULONG      $glib_Mul
2787
2788 _______EOF
2789
2790
2791         ### this should always be true in a modern C/C++ compiler
2792         cat >>$outfile <<_______EOF
2793 typedef signed char gint8;
2794 typedef unsigned char guint8;
2795 _______EOF
2796
2797
2798         if test -n "$gint16"; then
2799           cat >>$outfile <<_______EOF
2800 typedef signed $gint16 gint16;
2801 typedef unsigned $gint16 guint16;
2802 #define G_GINT16_MODIFIER $gint16_modifier
2803 #define G_GINT16_FORMAT $gint16_format
2804 #define G_GUINT16_FORMAT $guint16_format
2805 _______EOF
2806         fi
2807
2808
2809         if test -n "$gint32"; then
2810           cat >>$outfile <<_______EOF
2811 typedef signed $gint32 gint32;
2812 typedef unsigned $gint32 guint32;
2813 #define G_GINT32_MODIFIER $gint32_modifier
2814 #define G_GINT32_FORMAT $gint32_format
2815 #define G_GUINT32_FORMAT $guint32_format
2816 _______EOF
2817         fi
2818
2819         cat >>$outfile <<_______EOF
2820 #define G_HAVE_GINT64 1          /* deprecated, always true */
2821
2822 ${glib_extension}typedef signed $gint64 gint64;
2823 ${glib_extension}typedef unsigned $gint64 guint64;
2824
2825 #define G_GINT64_CONSTANT(val)  $gint64_constant
2826 #define G_GUINT64_CONSTANT(val) $guint64_constant
2827 _______EOF
2828
2829         if test x$gint64_format != x ; then
2830           cat >>$outfile <<_______EOF
2831 #define G_GINT64_MODIFIER $gint64_modifier
2832 #define G_GINT64_FORMAT $gint64_format
2833 #define G_GUINT64_FORMAT $guint64_format
2834 _______EOF
2835         else
2836           cat >>$outfile <<_______EOF
2837 #undef G_GINT64_MODIFIER
2838 #undef G_GINT64_FORMAT
2839 #undef G_GUINT64_FORMAT
2840 _______EOF
2841         fi
2842
2843         cat >>$outfile <<_______EOF
2844
2845 #define GLIB_SIZEOF_VOID_P $glib_void_p
2846 #define GLIB_SIZEOF_LONG   $glib_long
2847 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2848
2849 _______EOF
2850
2851         cat >>$outfile <<_______EOF
2852 typedef signed $glib_size_type_define gssize;
2853 typedef unsigned $glib_size_type_define gsize;
2854 #define G_GSIZE_MODIFIER $gsize_modifier
2855 #define G_GSSIZE_FORMAT $gssize_format
2856 #define G_GSIZE_FORMAT $gsize_format
2857
2858 #define G_MAXSIZE       G_MAXU$glib_msize_type
2859 #define G_MINSSIZE      G_MIN$glib_msize_type
2860 #define G_MAXSSIZE      G_MAX$glib_msize_type
2861
2862 typedef gint64 goffset;
2863 #define G_MINOFFSET     G_MININT64
2864 #define G_MAXOFFSET     G_MAXINT64
2865
2866 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
2867 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
2868 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2869
2870 _______EOF
2871
2872         if test -z "$glib_unknown_void_p"; then
2873           cat >>$outfile <<_______EOF
2874
2875 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2876 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2877
2878 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2879 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2880
2881 typedef signed $glib_intptr_type_define gintptr;
2882 typedef unsigned $glib_intptr_type_define guintptr;
2883
2884 #define G_GINTPTR_MODIFIER      $gintptr_modifier
2885 #define G_GINTPTR_FORMAT        $gintptr_format
2886 #define G_GUINTPTR_FORMAT       $guintptr_format
2887 _______EOF
2888         else
2889           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2890         fi
2891
2892
2893
2894         cat >>$outfile <<_______EOF
2895 $glib_atexit
2896 $glib_memmove
2897 $glib_defines
2898 $glib_os
2899 $glib_static_compilation
2900
2901 $glib_vacopy
2902
2903 #ifdef  __cplusplus
2904 #define G_HAVE_INLINE   1
2905 #else   /* !__cplusplus */
2906 $glib_inline
2907 #endif  /* !__cplusplus */
2908
2909 #ifdef  __cplusplus
2910 #define G_CAN_INLINE    1
2911 _______EOF
2912
2913         if test x$g_can_inline = xyes ; then
2914                 cat >>$outfile <<_______EOF
2915 #else   /* !__cplusplus */
2916 #define G_CAN_INLINE    1
2917 _______EOF
2918         fi
2919
2920         cat >>$outfile <<_______EOF
2921 #endif
2922
2923 _______EOF
2924
2925         if test x$g_have_iso_c_varargs = xyes ; then
2926                 cat >>$outfile <<_______EOF
2927 #ifndef __cplusplus
2928 # define G_HAVE_ISO_VARARGS 1
2929 #endif
2930 _______EOF
2931         fi
2932         if test x$g_have_iso_cxx_varargs = xyes ; then
2933                 cat >>$outfile <<_______EOF
2934 #ifdef __cplusplus
2935 # define G_HAVE_ISO_VARARGS 1
2936 #endif
2937 _______EOF
2938         fi
2939         if test x$g_have_gnuc_varargs = xyes ; then
2940                 cat >>$outfile <<_______EOF
2941
2942 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2943  * is passed ISO vararg support is turned off, and there is no work
2944  * around to turn it on, so we unconditionally turn it off.
2945  */
2946 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2947 #  undef G_HAVE_ISO_VARARGS
2948 #endif
2949
2950 #define G_HAVE_GNUC_VARARGS 1
2951 _______EOF
2952         fi
2953
2954         case x$g_stack_grows in
2955         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2956         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2957         esac
2958
2959
2960         echo >>$outfile
2961         if test x$g_have_eilseq = xno; then
2962                 cat >>$outfile <<_______EOF
2963 #ifndef EILSEQ
2964 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
2965  * The correspondence between this and the corresponding definition
2966  * in libiconv is essential.
2967  */
2968 #  define EILSEQ ENOENT
2969 #endif
2970 _______EOF
2971
2972         fi
2973
2974         if test x$g_have_gnuc_visibility = xyes; then
2975                 cat >>$outfile <<_______EOF
2976 #define G_HAVE_GNUC_VISIBILITY 1
2977 _______EOF
2978         fi
2979                 cat >>$outfile <<_______EOF
2980 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
2981 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2982 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
2983 #define G_GNUC_INTERNAL __hidden
2984 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
2985 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2986 #else
2987 #define G_GNUC_INTERNAL
2988 #endif
2989 _______EOF
2990
2991         echo >>$outfile
2992         cat >>$outfile <<_______EOF
2993 #define G_THREADS_ENABLED
2994 #define G_THREADS_IMPL_$g_threads_impl_def
2995 _______EOF
2996
2997         if test x"$g_memory_barrier_needed" != xno; then
2998           echo >>$outfile
2999           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3000         fi
3001         if test x"$g_atomic_lock_free" = xyes; then
3002           echo >>$outfile
3003           echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
3004         fi
3005         echo >>$outfile
3006         g_bit_sizes="16 32 64"
3007         for bits in $g_bit_sizes; do
3008           cat >>$outfile <<_______EOF
3009 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3010 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3011 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3012 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3013 _______EOF
3014         done
3015
3016         cat >>$outfile <<_______EOF
3017 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3018 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3019 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3020 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3021 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3022 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3023 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3024 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3025 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3026 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gsizebits}_TO_LE (val))
3027 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3028 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gsizebits}_TO_BE (val))
3029 #define G_BYTE_ORDER $g_byte_order
3030
3031 #define GLIB_SYSDEF_POLLIN =$g_pollin
3032 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3033 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3034 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3035 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3036 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3037
3038 #define G_MODULE_SUFFIX "$g_module_suffix"
3039
3040 typedef $g_pid_type GPid;
3041
3042 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3043 #define GLIB_SYSDEF_AF_INET $g_af_inet
3044 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3045
3046 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3047 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3048 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3049
3050 G_END_DECLS
3051
3052 #endif /* __GLIBCONFIG_H__ */
3053 _______EOF
3054
3055
3056         if cmp -s $outfile glib/glibconfig.h; then
3057           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3058           rm -f $outfile
3059         else
3060           mv $outfile glib/glibconfig.h
3061         fi
3062 ],[
3063
3064 # Note that if two cases are the same, case goes with the first one.
3065 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3066 # on variable expansion in case labels.  Look at the generated config.status
3067 # for a hint.
3068
3069 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3070   glib_header_alloca_h="$ac_cv_working_alloca_h"
3071 else
3072   glib_header_alloca_h="$ac_cv_header_alloca_h"
3073 fi
3074
3075 case xyes in
3076 x$ac_cv_header_float_h)
3077   glib_float_h=yes
3078   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3079   glib_md=DBL_MIN glib_Md=DBL_MAX
3080   ;;
3081 x$ac_cv_header_values_h)
3082   glib_values_h=yes
3083   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3084   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3085   ;;
3086 esac
3087
3088 case xyes in
3089 x$ac_cv_header_limits_h)
3090   glib_limits_h=yes
3091   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3092   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3093   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3094   ;;
3095 x$ac_cv_header_values_h)
3096   glib_values_h=yes
3097   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3098   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3099   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3100   ;;
3101 esac
3102
3103 if test x$ac_cv_header_sys_poll_h = xyes ; then
3104   glib_sys_poll_h=yes
3105 fi
3106
3107 if test x$enable_included_printf = xyes ; then
3108   glib_included_printf=yes
3109 fi
3110
3111 case 2 in
3112 $ac_cv_sizeof_short)
3113   gint16=short
3114   gint16_modifier='"h"'
3115   gint16_format='"hi"'
3116   guint16_format='"hu"'
3117   ;;
3118 $ac_cv_sizeof_int)
3119   gint16=int
3120   gint16_modifier='""'
3121   gint16_format='"i"'
3122   guint16_format='"u"'
3123   ;;
3124 esac
3125 case 4 in
3126 $ac_cv_sizeof_short)
3127   gint32=short
3128   gint32_modifier='"h"'
3129   gint32_format='"hi"'
3130   guint32_format='"hu"'
3131   ;;
3132 $ac_cv_sizeof_int)
3133   gint32=int
3134   gint32_modifier='""'
3135   gint32_format='"i"'
3136   guint32_format='"u"'
3137   ;;
3138 $ac_cv_sizeof_long)
3139   gint32=long
3140   gint32_modifier='"l"'
3141   gint32_format='"li"'
3142   guint32_format='"lu"'
3143   ;;
3144 esac
3145 case 8 in
3146 $ac_cv_sizeof_int)
3147   gint64=int
3148   gint64_modifier='""'
3149   gint64_format='"i"'
3150   guint64_format='"u"'
3151   glib_extension=
3152   gint64_constant='(val)'
3153   guint64_constant='(val)'
3154   ;;
3155 $ac_cv_sizeof_long)
3156   gint64=long
3157   gint64_modifier='"l"'
3158   gint64_format='"li"'
3159   guint64_format='"lu"'
3160   glib_extension=
3161   gint64_constant='(val##L)'
3162   guint64_constant='(val##UL)'
3163   ;;
3164 $ac_cv_sizeof_long_long)
3165   gint64='long long'
3166   if test -n "$glib_cv_long_long_format"; then
3167     gint64_modifier='"'$glib_cv_long_long_format'"'
3168     gint64_format='"'$glib_cv_long_long_format'i"'
3169     guint64_format='"'$glib_cv_long_long_format'u"'
3170   fi
3171   glib_extension='G_GNUC_EXTENSION '
3172   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3173   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3174   ;;
3175 $ac_cv_sizeof___int64)
3176   gint64='__int64'
3177   if test -n "$glib_cv_long_long_format"; then
3178     gint64_modifier='"'$glib_cv_long_long_format'"'
3179     gint64_format='"'$glib_cv_long_long_format'i"'
3180     guint64_format='"'$glib_cv_long_long_format'u"'
3181   fi
3182   glib_extension=
3183   gint64_constant='(val##i64)'
3184   guint64_constant='(val##ui64)'
3185   ;;
3186 esac
3187 glib_size_t=$ac_cv_sizeof_size_t
3188 glib_size_type_define="$glib_size_type"
3189 glib_void_p=$ac_cv_sizeof_void_p
3190 glib_long=$ac_cv_sizeof_long
3191
3192 case "$glib_size_type" in
3193 short)
3194   gsize_modifier='"h"'
3195   gsize_format='"hu"'
3196   gssize_format='"hi"'
3197   glib_msize_type='SHRT'
3198   ;;
3199 int)
3200   gsize_modifier='""'
3201   gsize_format='"u"'
3202   gssize_format='"i"'
3203   glib_msize_type='INT'
3204   ;;
3205 long)
3206   gsize_modifier='"l"'
3207   gsize_format='"lu"'
3208   gssize_format='"li"'
3209   glib_msize_type='LONG'
3210   ;;
3211 "long long"|__int64)
3212   gsize_modifier='"I64"'
3213   gsize_format='"I64u"'
3214   gssize_format='"I64i"'
3215   glib_msize_type='INT64'
3216   ;;
3217 esac
3218
3219 gintbits=`expr $ac_cv_sizeof_int \* 8`
3220 glongbits=`expr $ac_cv_sizeof_long \* 8`
3221 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3222
3223 case $ac_cv_sizeof_void_p in
3224 $ac_cv_sizeof_int)
3225   glib_intptr_type_define=int
3226   gintptr_modifier='""'
3227   gintptr_format='"i"'
3228   guintptr_format='"u"'
3229   glib_gpi_cast='(gint)'
3230   glib_gpui_cast='(guint)'
3231   ;;
3232 $ac_cv_sizeof_long)
3233   glib_intptr_type_define=long
3234   gintptr_modifier='"l"'
3235   gintptr_format='"li"'
3236   guintptr_format='"lu"'
3237   glib_gpi_cast='(glong)'
3238   glib_gpui_cast='(gulong)'
3239   ;;
3240 $ac_cv_sizeof_long_long)
3241   glib_intptr_type_define='long long'
3242   gintptr_modifier='"I64"'
3243   gintptr_format='"I64i"'
3244   guintptr_format='"I64u"'
3245   glib_gpi_cast='(gint64)'
3246   glib_gpui_cast='(guint64)'
3247   ;;
3248 $ac_cv_sizeof___int64)
3249   glib_intptr_type_define=__int64
3250   gintptr_modifier='"I64"'
3251   gintptr_format='"I64i"'
3252   guintptr_format='"I64u"'
3253   glib_gpi_cast='(gint64)'
3254   glib_gpui_cast='(guint64)'
3255   ;;
3256 *)
3257   glib_unknown_void_p=yes
3258   ;;
3259 esac
3260
3261
3262 case xyes in
3263 x$ac_cv_func_atexit)
3264   glib_atexit="
3265 #ifdef NeXT /* @#%@! NeXTStep */
3266 # define g_ATEXIT(proc) (!atexit (proc))
3267 #else
3268 # define g_ATEXIT(proc) (atexit (proc))
3269 #endif"
3270   ;;
3271 x$ac_cv_func_on_exit)
3272   glib_atexit="
3273 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3274   ;;
3275 esac
3276
3277 case xyes in
3278 x$ac_cv_func_memmove)
3279   glib_memmove='
3280 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3281   ;;
3282 x$glib_cv_working_bcopy)
3283   glib_memmove="
3284 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3285 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3286   ;;
3287 *)
3288   glib_memmove="
3289 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3290  * so we have to roll our own copy routine. */
3291 void g_memmove (void* dest, const void * src, unsigned long len);"
3292   ;;
3293 esac
3294
3295 glib_defines="
3296 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3297 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3298 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3299 "
3300
3301 case xyes in
3302 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3303 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3304 *)                      glib_vacopy=''
3305 esac
3306
3307 if test x$glib_cv_va_val_copy = xno; then
3308   glib_vacopy="\$glib_vacopy
3309 #define G_VA_COPY_AS_ARRAY 1"
3310 fi
3311
3312 if test x$glib_cv_hasinline = xyes; then
3313     glib_inline='#define G_HAVE_INLINE 1'
3314 fi
3315 if test x$glib_cv_has__inline = xyes; then
3316     glib_inline="\$glib_inline
3317 #define G_HAVE___INLINE 1"
3318 fi
3319 if test x$glib_cv_has__inline__ = xyes; then
3320     glib_inline="\$glib_inline
3321 #define G_HAVE___INLINE__ 1"
3322 fi
3323
3324 g_have_gnuc_varargs=$g_have_gnuc_varargs
3325 g_have_iso_c_varargs=$g_have_iso_c_varargs
3326 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3327
3328 g_can_inline=$g_can_inline
3329 g_have_gnuc_visibility=$g_have_gnuc_visibility
3330 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3331
3332 if test x$ac_cv_c_bigendian = xyes; then
3333   g_byte_order=G_BIG_ENDIAN
3334   g_bs_native=BE
3335   g_bs_alien=LE
3336 else
3337   g_byte_order=G_LITTLE_ENDIAN
3338   g_bs_native=LE
3339   g_bs_alien=BE
3340 fi
3341
3342 g_pollin=$glib_cv_value_POLLIN
3343 g_pollout=$glib_cv_value_POLLOUT
3344 g_pollpri=$glib_cv_value_POLLPRI
3345 g_pollhup=$glib_cv_value_POLLHUP
3346 g_pollerr=$glib_cv_value_POLLERR
3347 g_pollnval=$glib_cv_value_POLLNVAL
3348
3349 g_af_unix=$glib_cv_value_AF_UNIX
3350 g_af_inet=$glib_cv_value_AF_INET
3351 g_af_inet6=$glib_cv_value_AF_INET6
3352
3353 g_msg_peek=$glib_cv_value_MSG_PEEK
3354 g_msg_oob=$glib_cv_value_MSG_OOB
3355 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3356
3357 g_stack_grows=$glib_cv_stack_grows
3358
3359 g_have_eilseq=$have_eilseq
3360
3361 g_threads_impl_def=$g_threads_impl
3362
3363 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3364 g_memory_barrier_needed="$glib_memory_barrier_needed"
3365 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3366
3367 g_module_suffix="$glib_gmodule_suffix"
3368
3369 g_pid_type="$glib_pid_type"
3370 case $host in
3371   *-*-beos*)
3372     glib_os="#define G_OS_BEOS"
3373     ;;
3374   *-*-cygwin*)
3375     glib_os="#define G_OS_UNIX
3376 #define G_PLATFORM_WIN32
3377 #define G_WITH_CYGWIN"
3378     ;;
3379   *-*-mingw*)
3380     glib_os="#define G_OS_WIN32
3381 #define G_PLATFORM_WIN32"
3382     ;;
3383   *)
3384     glib_os="#define G_OS_UNIX"
3385     ;;
3386 esac
3387 glib_static_compilation=""
3388 if test x$glib_win32_static_compilation = xyes; then
3389   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3390 #define GOBJECT_STATIC_COMPILATION 1"
3391 fi
3392 ])
3393
3394 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3395 #
3396 # 1.2.14 required for dbus_message_set_serial
3397 PKG_CHECK_MODULES(DBUS1,
3398                   dbus-1 >= 1.2.14,
3399                   [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3400                   have_dbus1=no)
3401 AC_SUBST(DBUS1_CFLAGS)
3402 AC_SUBST(DBUS1_LIBS)
3403 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3404
3405 dnl
3406 dnl Check for -Bsymbolic-functions linker flag used to avoid
3407 dnl intra-library PLT jumps, if available.
3408 dnl
3409
3410 AC_ARG_ENABLE(Bsymbolic,
3411               [AC_HELP_STRING([--disable-Bsymbolic],
3412                               [avoid linking with -Bsymbolic])],,
3413               [SAVED_LDFLAGS="${LDFLAGS}"
3414                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3415                LDFLAGS=-Wl,-Bsymbolic-functions
3416                AC_TRY_LINK([], [int main (void) { return 0; }],
3417                            AC_MSG_RESULT(yes)
3418                            enable_Bsymbolic=yes,
3419                            AC_MSG_RESULT(no)
3420                            enable_Bsymbolic=no)
3421                LDFLAGS="${SAVED_LDFLAGS}"])
3422
3423 if test "x${enable_Bsymbolic}" = "xyes"; then
3424   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3425 fi
3426
3427 AC_SUBST(GLIB_LINK_FLAGS)
3428
3429 #
3430 # Define variables corresponding to the correct include paths to use for
3431 # in-tree building.
3432 #
3433
3434 # for config.h:
3435 config_h_INCLUDES='-I$(top_builddir)'
3436 AC_SUBST(config_h_INCLUDES)
3437
3438 # glib:
3439 #   config.h
3440 #   $(top_builddir)/glib: for glibconfig.h
3441 #   $(top_srcdir)/glib:   for glib.h
3442 #   $(top_srcdir):        for everything
3443 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3444 AC_SUBST(glib_INCLUDES)
3445
3446 # gthread:
3447 #   same as glib
3448 gthread_INCLUDES='$(glib_INCLUDES)'
3449 AC_SUBST(gthread_INCLUDES)
3450
3451 # gobject:
3452 #   same as gthread
3453 gobject_INCLUDES='$(gthread_INCLUDES)'
3454 AC_SUBST(gobject_INCLUDES)
3455
3456 # gmodule:
3457 #   glib includes
3458 #   $(top_srcdir)/gmodule: for gmodule.h
3459 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3460 AC_SUBST(gmodule_INCLUDES)
3461
3462 # gio:
3463 #   same as gmodule
3464 gio_INCLUDES='$(gmodule_INCLUDES)'
3465 AC_SUBST(gio_INCLUDES)
3466
3467
3468 AC_CONFIG_FILES([
3469 glib-2.0.pc
3470 gmodule-2.0.pc
3471 gmodule-export-2.0.pc
3472 gmodule-no-export-2.0.pc
3473 gthread-2.0.pc
3474 gobject-2.0.pc
3475 gio-2.0.pc
3476 gio-unix-2.0.pc
3477 gio-windows-2.0.pc
3478 glib-zip
3479 glib-gettextize
3480 Makefile
3481 build/Makefile
3482 build/win32/Makefile
3483 build/win32/dirent/Makefile
3484 build/win32/vs9/Makefile
3485 build/win32/vs10/Makefile
3486 glib/Makefile
3487 glib/glib.stp
3488 glib/libcharset/Makefile
3489 glib/gnulib/Makefile
3490 glib/pcre/Makefile
3491 glib/update-pcre/Makefile
3492 glib/tests/Makefile
3493 gmodule/Makefile
3494 gmodule/gmoduleconf.h
3495 gobject/Makefile
3496 gobject/gobject.stp
3497 gobject/glib-mkenums
3498 gobject/tests/Makefile
3499 gthread/Makefile
3500 gio/Makefile
3501 gio/gdbus-2.0/codegen/Makefile
3502 gio/gdbus-2.0/codegen/config.py
3503 gio/xdgmime/Makefile
3504 gio/inotify/Makefile
3505 gio/fen/Makefile
3506 gio/fam/Makefile
3507 gio/win32/Makefile
3508 gio/tests/Makefile
3509 gio/tests/gdbus-object-manager-example/Makefile
3510 po/Makefile.in
3511 docs/Makefile
3512 docs/reference/Makefile
3513 docs/reference/glib/Makefile
3514 docs/reference/glib/version.xml
3515 docs/reference/gobject/Makefile
3516 docs/reference/gobject/version.xml
3517 docs/reference/gio/Makefile
3518 docs/reference/gio/gdbus-object-manager-example/Makefile
3519 docs/reference/gio/version.xml
3520 tests/Makefile
3521 tests/gobject/Makefile
3522 tests/refcount/Makefile
3523 m4macros/Makefile
3524 ])
3525
3526 AC_CONFIG_COMMANDS([chmod-scripts],
3527 [chmod 0755 glib-zip
3528 chmod 0755 glib-gettextize
3529 chmod 0755 gobject/glib-mkenums])
3530
3531 # we want to invoke this macro solely so that the config.status script
3532 # and automake generated makefiles know about these generated files.
3533 # They are only needed to distcheck the package
3534 if false; then
3535   AC_CONFIG_FILES([
3536     INSTALL
3537     README
3538     config.h.win32
3539     glib/glibconfig.h.win32
3540     glib/makefile.msc
3541     glib/glib.rc
3542     gmodule/makefile.msc
3543     gmodule/gmodule.rc
3544     gobject/makefile.msc
3545     gobject/gobject.rc
3546     gthread/makefile.msc
3547     gthread/gthread.rc
3548     gio/gio.rc
3549     tests/makefile.msc
3550   ])
3551 fi
3552
3553 AC_OUTPUT