configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of PulseAudio.
   7 #
   8 # Copyright 2004-2008 Lennart Poettering
   9 # Copyright 2006-2007 Pierre Ossman <ossman@cendio.se> for Cendio AB
  10 #
  11 # PulseAudio is free software; you can redistribute it and/or modify it
  12 # under the terms of the GNU Lesser General Public License as published by
  13 # the Free Software Foundation; either version 2 of the License, or
  14 # (at your option) any later version.
  15 #
  16 # PulseAudio is distributed in the hope that it will be useful, but
  17 # WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  19 # General Public License for more details.
  20 #
  21 # You should have received a copy of the GNU Lesser General Public License
  22 # along with PulseAudio; if not, write to the Free Software Foundation,
  23 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  24
  25 AC_PREREQ(2.57)
  26
  27 m4_define(PA_MAJOR, [0])
  28 m4_define(PA_MINOR, [9])
  29 m4_define(PA_MICRO, [10])
  30
  31 AC_INIT([pulseaudio], PA_MAJOR.PA_MINOR.PA_MICRO,[mzchyfrnhqvb (at) 0pointer (dot) net])
  32 AC_CONFIG_SRCDIR([src/daemon/main.c])
  33 AC_CONFIG_HEADERS([config.h])
  34 AM_INIT_AUTOMAKE([foreign -Wall])
  35
  36 AC_SUBST(PA_MAJORMINOR, "PA_MAJOR.PA_MINOR")
  37 AC_SUBST(PACKAGE_URL, [http://pulseaudio.org/])
  38
  39 AC_SUBST(PA_API_VERSION, 11)
  40 AC_SUBST(PA_PROTOCOL_VERSION, 12)
  41
  42 # The stable ABI for client applications, for the version info x:y:z
  43 # always will hold y=z
  44 AC_SUBST(LIBPULSE_VERSION_INFO, [4:0:4])
  45
  46 # A simplified, synchronous, ABI-stable interface for client
  47 # applications, for the version info x:y:z always will hold y=z
  48 AC_SUBST(LIBPULSE_SIMPLE_VERSION_INFO, [0:1:0])
  49
  50 # The ABI-stable network browsing interface for client applications,
  51 # for the version info x:y:z always will hold y=z
  52 AC_SUBST(LIBPULSE_BROWSE_VERSION_INFO, [1:1:1])
  53
  54 # The ABI-stable GLib adapter for client applications, for the version
  55 # info x:y:z always will hold y=z
  56 AC_SUBST(LIBPULSE_MAINLOOP_GLIB_VERSION_INFO, [0:3:0])
  57
  58 # An internally used, ABI-unstable library that contains the
  59 # PulseAudio core, SONAMEs are bumped on every release, version info
  60 # suffix will always be 0:0
  61 AC_SUBST(LIBPULSECORE_VERSION_INFO, [5:0:0])
  62
  63 AC_CANONICAL_HOST
  64
  65 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  66    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  67    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  68 fi
  69
  70 #### Platform hacks ####
  71
  72 case $host in
  73    *-*-solaris* )
  74       AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  75       AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
  76       AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  77       ;;
  78 esac
  79
  80 #### Checks for programs. ####
  81
  82 # mkdir -p
  83
  84 AC_PROG_MKDIR_P
  85
  86 # CC
  87
  88 AC_PROG_CC
  89 AM_PROG_CC_C_O
  90 AC_PROG_GCC_TRADITIONAL
  91 AC_GNU_SOURCE
  92
  93 # M4
  94
  95 AC_PATH_PROG([M4], [m4 gm4], [no])
  96 if test "x$M4" = xno ; then
  97    AC_MSG_ERROR([m4 missing])
  98 fi
  99
 100 # GCC flags
 101
 102 test_gcc_flag() {
 103     AC_LANG_CONFTEST([int main(int argc, char*argv[]) {}])
 104     $CC -c conftest.c $CFLAGS -o conftest.o > /dev/null 2> /dev/null
 105     ret=$?
 106     rm -f conftest.o
 107     return $ret
 108 }
 109
 110 # If using GCC specify some additional parameters
 111 if test "x$GCC" = "xyes" ; then
 112
 113     # We use gnu99 instead of c99 because many have interpreted the standard
 114     # in a way that int64_t isn't defined on non-64 bit platforms.
 115     DESIRED_FLAGS="-std=gnu99 -Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wcast-align -Wwrite-strings -Winline -Wno-unused-parameter -ffast-math"
 116
 117     for flag in $DESIRED_FLAGS ; do
 118         AC_MSG_CHECKING([whether $CC accepts $flag])
 119         if test_gcc_flag $flag ; then
 120            CFLAGS="$CFLAGS $flag"
 121            AC_MSG_RESULT([yes])
 122         else
 123            AC_MSG_RESULT([no])
 124         fi
 125     done
 126 fi
 127
 128 AC_MSG_CHECKING([whether $CC knows __sync_bool_compare_and_swap()])
 129 AC_LANG_CONFTEST([int main() { int a = 4; __sync_bool_compare_and_swap(&a, 4, 5); }])
 130 $CC conftest.c $CFLAGS -o conftest > /dev/null 2> /dev/null
 131 ret=$?
 132 rm -f conftest.o conftest
 133 if test $ret -eq 0 ; then
 134     AC_DEFINE([HAVE_ATOMIC_BUILTINS], 1, [Have __sync_bool_compare_and_swap() and friends.])
 135     AC_MSG_RESULT([yes])
 136 else
 137     AC_MSG_RESULT([no])
 138 fi
 139
 140 AC_MSG_CHECKING([whether $CC knows __thread])
 141 AC_LANG_CONFTEST([static __thread int a = 6; int main() { a = 5; }])
 142 $CC conftest.c $CFLAGS -o conftest > /dev/null 2> /dev/null
 143 ret=$?
 144 rm -f conftest.o conftest
 145 if test $ret -eq 0 ; then
 146     AC_DEFINE([HAVE_TLS_BUILTIN], 1, [Have __thread().])
 147     AC_MSG_RESULT([yes])
 148 else
 149     AC_MSG_RESULT([no])
 150 fi
 151
 152 AC_MSG_CHECKING([whether $CC knows _Bool])
 153 AC_LANG_CONFTEST([int main() { _Bool b; }])
 154 $CC conftest.c $CFLAGS -o conftest > /dev/null 2> /dev/null
 155 ret=$?
 156 rm -f conftest.o conftest
 157 if test $ret -eq 0 ; then
 158     AC_DEFINE([HAVE_STD_BOOL], 1, [Have _Bool.])
 159     AC_MSG_RESULT([yes])
 160 else
 161     AC_MSG_RESULT([no])
 162 fi
 163
 164 #### libtool stuff ####
 165
 166 AC_LTDL_ENABLE_INSTALL
 167 AC_LIBLTDL_INSTALLABLE
 168 AC_LIBTOOL_DLOPEN
 169 AC_LIBTOOL_WIN32_DLL
 170 AC_PROG_LIBTOOL
 171 AC_SUBST(LTDLINCL)
 172 AC_SUBST(LIBLTDL)
 173 AC_CONFIG_SUBDIRS(libltdl)
 174
 175 if test "x$enable_ltdl_install" = "xno" && test "x$ac_cv_lib_ltdl_lt_dlinit" = "xno" ; then
 176     AC_MSG_ERROR([[
 177
 178         *** Cannot find the libltdl development files.
 179         *** Maybe you need to install the libltdl-dev package.
 180         ]])
 181 fi
 182
 183 #### Determine build environment ####
 184
 185 os_is_win32=0
 186
 187 case "$host_os" in
 188         mingw*)
 189         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 190         os_is_win32=1
 191                 ;;
 192         esac
 193
 194 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 195
 196 ###################################
 197 #   Basic environment checks      #
 198 ###################################
 199
 200 #### Checks for header files. ####
 201
 202 # ISO
 203 AC_HEADER_STDC
 204
 205 # POSIX
 206 AC_CHECK_HEADERS([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
 207     netinet/in_systm.h netinet/tcp.h poll.h pwd.h sched.h \
 208     sys/mman.h sys/resource.h sys/select.h sys/socket.h sys/wait.h \
 209     syslog.h sys/dl.h dlfcn.h linux/sockios.h])
 210 AC_CHECK_HEADERS([netinet/ip.h], [], [],
 211                  [#include <sys/types.h>
 212                   #if HAVE_NETINET_IN_H
 213                   # include <netinet/in.h>
 214                   #endif
 215                   #if HAVE_NETINET_IN_SYSTM_H
 216                   # include <netinet/in_systm.h>
 217                   #endif
 218                  ])
 219 AC_CHECK_HEADERS([regex.h], [HAVE_REGEX=1], [HAVE_REGEX=0])
 220 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 221
 222 AM_CONDITIONAL(HAVE_REGEX, test "x$HAVE_REGEX" = "x1")
 223 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 224
 225 # Linux
 226 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 227
 228 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 229
 230 AC_CHECK_HEADERS([sys/prctl.h])
 231
 232 # Solaris
 233 AC_CHECK_HEADERS([sys/filio.h])
 234
 235 # Windows
 236 AC_CHECK_HEADERS([windows.h winsock2.h ws2tcpip.h])
 237
 238 # Other
 239 AC_CHECK_HEADERS([sys/ioctl.h])
 240 AC_CHECK_HEADERS([byteswap.h])
 241 AC_CHECK_HEADERS([sys/syscall.h])
 242
 243 #### Typdefs, structures, etc. ####
 244
 245 AC_C_CONST
 246 AC_C_BIGENDIAN
 247 AC_TYPE_PID_T
 248 AC_TYPE_SIZE_T
 249 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
 250     [Define ssize_t if it is not done by the standard libs.])])
 251 AC_TYPE_OFF_T
 252 AC_TYPE_SIGNAL
 253 AC_TYPE_UID_T
 254
 255 AC_CHECK_DEFINE([SIGXCPU], [signal.h], [
 256 HAVE_SIGXCPU=1
 257 AC_DEFINE([HAVE_SIGXCPU], 1, [Have SIGXCPU?])
 258 ], [HAVE_SIGXCPU=0])
 259 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 260
 261 # Solaris lacks this
 262 AC_CHECK_DEFINE([INADDR_NONE], [netinet/in.h], [],
 263     [AC_CHECK_DEFINE([INADDR_NONE], [winsock2.h], [],
 264         [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])])
 265
 266 #### POSIX threads ####
 267
 268 ACX_PTHREAD
 269
 270 #### Check for libs ####
 271
 272 # ISO
 273 AC_SEARCH_LIBS([pow], [m])
 274
 275 # POSIX
 276 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 277 AC_SEARCH_LIBS([dlopen], [dl])
 278 AC_SEARCH_LIBS([shm_open], [rt])
 279 AC_SEARCH_LIBS([inet_ntop], [nsl])
 280 AC_SEARCH_LIBS([timer_create], [rt])
 281
 282 # BSD
 283 AC_SEARCH_LIBS([connect], [socket])
 284
 285 # Non-standard
 286
 287 # This magic is needed so we do not needlessly add static libs to the win32
 288 # build, disabling its ability to make dlls.
 289 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 290
 291 #### Check for functions ####
 292
 293 # ISO
 294 AC_CHECK_FUNCS([lrintf strtof])
 295
 296 # POSIX
 297 AC_FUNC_FORK
 298 AC_FUNC_GETGROUPS
 299 AC_FUNC_SELECT_ARGTYPES
 300 AC_CHECK_FUNCS([chmod chown clock_gettime getaddrinfo getgrgid_r \
 301     getpwuid_r gettimeofday getuid inet_ntop inet_pton mlock nanosleep \
 302     pipe posix_fadvise posix_madvise posix_memalign setpgid setsid shm_open \
 303     sigaction sleep sysconf])
 304 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 305
 306 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 307
 308 # X/OPEN
 309 AC_CHECK_FUNCS([readlink])
 310
 311 # SUSv2
 312 AC_CHECK_FUNCS([ctime_r usleep])
 313
 314 # SUSv3
 315 AC_CHECK_FUNCS([strerror_r])
 316
 317 # BSD
 318 AC_CHECK_FUNCS([lstat])
 319
 320 # Non-standard
 321
 322 AC_CHECK_FUNCS([setresuid setresgid setreuid setregid seteuid setegid ppoll strsignal sig2str strtof_l])
 323
 324 AC_MSG_CHECKING([for PTHREAD_PRIO_INHERIT])
 325 AC_LANG_CONFTEST([AC_LANG_SOURCE([[
 326 #include <pthread.h>
 327 int main() { int i = PTHREAD_PRIO_INHERIT; }]])])
 328 $PTHREAD_CC conftest.c $PTHREAD_CFLAGS $CFLAGS $PTHREAD_LIBS -o conftest > /dev/null 2> /dev/null
 329 ret=$?
 330 rm -f conftest.o conftest
 331
 332 if test $ret -eq 0 ; then
 333     AC_DEFINE([HAVE_PTHREAD_PRIO_INHERIT], 1, [Have PTHREAD_PRIO_INHERIT.])
 334     AC_MSG_RESULT([yes])
 335 else
 336     AC_MSG_RESULT([no])
 337 fi
 338
 339 #### Large File-Support (LFS) ####
 340
 341 AC_SYS_LARGEFILE
 342
 343 # Check for open64 to know if the current system does have open64() and similar functions
 344 AC_CHECK_FUNCS([open64])
 345
 346 #### [lib]iconv ####
 347
 348 AM_ICONV
 349
 350 ###################################
 351 #      External libraries         #
 352 ###################################
 353
 354 #### X11 (optional) ####
 355
 356 HAVE_X11=0
 357
 358 # The macro tests the host, not the build target
 359 if test "x$os_is_win32" != "x1" ; then
 360     AC_PATH_XTRA
 361     test "x$no_x" != "xyes" && HAVE_X11=1
 362 fi
 363
 364 AC_SUBST(HAVE_X11)
 365 AM_CONDITIONAL(HAVE_X11, test "x$HAVE_X11" = "x1")
 366 if test "x$HAVE_X11" = "x1" ; then
 367     AC_DEFINE([HAVE_X11], 1, [Have X11])
 368 fi
 369
 370 #### Capabilities (optional) ####
 371
 372 CAP_LIBS=''
 373
 374 AC_ARG_WITH(
 375         [caps],
 376         AC_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 377
 378 if test "x${with_caps}" != "xno"; then
 379     AC_SEARCH_LIBS([cap_init], [cap], [], [
 380                     if test "x${with_caps}" = "xyes" ; then
 381                         AC_MSG_ERROR([*** POSIX caps libraries not found])
 382                     fi])
 383     AC_CHECK_HEADERS([sys/capability.h], [], [
 384                     if test "x${with_caps}" = "xyes" ; then
 385                         AC_MSG_ERROR([*** POSIX caps headers not found])
 386                     fi])
 387 fi
 388
 389 #### pkg-config ####
 390
 391 # Check for pkg-config manually first, as if its not installed the
 392 # PKG_PROG_PKG_CONFIG macro won't be defined.
 393 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 394
 395 if test x"$have_pkg_config" = "xno"; then
 396     AC_MSG_ERROR(pkg-config is required to install this program)
 397 fi
 398
 399 PKG_PROG_PKG_CONFIG
 400
 401 #### Sound file ####
 402
 403 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.10 ])
 404 AC_SUBST(LIBSNDFILE_CFLAGS)
 405 AC_SUBST(LIBSNDFILE_LIBS)
 406
 407 #### atomic-ops ###
 408
 409 AC_CHECK_HEADERS([atomic_ops.h], [], [
 410 AC_MSG_ERROR([*** libatomic-ops headers not found])
 411 ])
 412
 413 # Win32 does not need the lib and breaks horribly if we try to include it
 414 if test "x$os_is_win32" != "x1" ; then
 415     LIBS="$LIBS -latomic_ops"
 416 fi
 417
 418 #### Libsamplerate support (optional) ####
 419
 420 AC_ARG_ENABLE([samplerate],
 421     AC_HELP_STRING([--disable-samplerate], [Disable optional libsamplerate support]),
 422         [
 423             case "${enableval}" in
 424                 yes) samplerate=yes ;;
 425                 no) samplerate=no ;;
 426                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-samplerate) ;;
 427             esac
 428         ],
 429         [samplerate=auto])
 430
 431 if test "x${samplerate}" != xno ; then
 432     PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ],
 433         HAVE_LIBSAMPLERATE=1,
 434         [
 435             HAVE_LIBSAMPLERATE=0
 436             if test "x$samplerate" = xyes ; then
 437                 AC_MSG_ERROR([*** Libsamplerate not found])
 438             fi
 439         ])
 440 else
 441     HAVE_LIBSAMPLERATE=0
 442 fi
 443
 444 if test "x${HAVE_LIBSAMPLERATE}" = x1 ; then
 445    AC_DEFINE([HAVE_LIBSAMPLERATE], 1, [Have libsamplerate?])
 446 fi
 447
 448 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 449 AC_SUBST(LIBSAMPLERATE_LIBS)
 450 AC_SUBST(HAVE_LIBSAMPLERATE)
 451 AM_CONDITIONAL([HAVE_LIBSAMPLERATE], [test "x$HAVE_LIBSAMPLERATE" = x1])
 452
 453 #### OSS support (optional) ####
 454
 455 AC_ARG_ENABLE([oss],
 456     AC_HELP_STRING([--disable-oss], [Disable optional OSS support]),
 457         [
 458             case "${enableval}" in
 459                 yes) oss=yes ;;
 460                 no) oss=no ;;
 461                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-oss) ;;
 462             esac
 463         ],
 464         [oss=auto])
 465
 466 if test "x${oss}" != xno ; then
 467     AC_CHECK_HEADERS([sys/soundcard.h],
 468         [
 469             HAVE_OSS=1
 470             AC_DEFINE([HAVE_OSS], 1, [Have OSS?])
 471         ],
 472         [
 473             HAVE_OSS=0
 474             if test "x$oss" = xyes ; then
 475                 AC_MSG_ERROR([*** OSS support not found])
 476             fi
 477         ])
 478 else
 479     HAVE_OSS=0
 480 fi
 481
 482 AC_SUBST(HAVE_OSS)
 483 AM_CONDITIONAL([HAVE_OSS], [test "x$HAVE_OSS" = x1])
 484
 485
 486 #### ALSA support (optional) ####
 487
 488 AC_ARG_ENABLE([alsa],
 489     AC_HELP_STRING([--disable-alsa], [Disable optional ALSA support]),
 490         [
 491             case "${enableval}" in
 492                 yes) alsa=yes ;;
 493                 no) alsa=no ;;
 494                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-alsa) ;;
 495             esac
 496         ],
 497         [alsa=auto])
 498
 499 if test "x${alsa}" != xno ; then
 500     PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.0 ],
 501         [
 502             HAVE_ALSA=1
 503             AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?])
 504         ],
 505         [
 506             HAVE_ALSA=0
 507             if test "x$alsa" = xyes ; then
 508                 AC_MSG_ERROR([*** ALSA support not found])
 509             fi
 510         ])
 511 else
 512     HAVE_ALSA=0
 513 fi
 514
 515 AC_SUBST(ASOUNDLIB_CFLAGS)
 516 AC_SUBST(ASOUNDLIB_LIBS)
 517 AC_SUBST(HAVE_ALSA)
 518 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 519
 520 #### Solaris audio support (optional) ####
 521
 522 AC_ARG_ENABLE([solaris],
 523     AC_HELP_STRING([--disable-solaris], [Disable optional Solaris audio support]),
 524         [
 525             case "${enableval}" in
 526                 yes) solaris=yes ;;
 527                 no) solaris=no ;;
 528                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-solaris) ;;
 529             esac
 530         ],
 531         [solaris=auto])
 532
 533 if test "x${solaris}" != xno ; then
 534     AC_CHECK_HEADERS([sys/audio.h],
 535         [
 536             HAVE_SOLARIS=1
 537             AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?])
 538         ],
 539         [
 540             HAVE_SOLARIS=0
 541             if test "x$solaris" = xyes ; then
 542                 AC_MSG_ERROR([*** Solaris audio support not found])
 543             fi
 544         ])
 545 else
 546     HAVE_SOLARIS=0
 547 fi
 548
 549 AC_SUBST(HAVE_SOLARIS)
 550 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 551
 552 #### GLib 2 support (optional) ####
 553
 554 AC_ARG_ENABLE([glib2],
 555     AC_HELP_STRING([--disable-glib2], [Disable optional GLib 2 support]),
 556         [
 557             case "${enableval}" in
 558                 yes) glib2=yes ;;
 559                 no) glib2=no ;;
 560                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-glib2) ;;
 561             esac
 562         ],
 563         [glib2=auto])
 564
 565 if test "x${glib2}" != xno ; then
 566     PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ],
 567         HAVE_GLIB20=1,
 568         [
 569             HAVE_GLIB20=0
 570             if test "x$glib2" = xyes ; then
 571                 AC_MSG_ERROR([*** GLib 2 support not found])
 572             fi
 573         ])
 574 else
 575     HAVE_GLIB20=0
 576 fi
 577
 578 AC_SUBST(GLIB20_CFLAGS)
 579 AC_SUBST(GLIB20_LIBS)
 580 AC_SUBST(HAVE_GLIB20)
 581 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 582
 583 #### GConf support (optional) ####
 584
 585 AC_ARG_ENABLE([gconf],
 586     AC_HELP_STRING([--disable-gconf], [Disable optional GConf support]),
 587         [
 588             case "${enableval}" in
 589                 yes) gconf=yes ;;
 590                 no) gconf=no ;;
 591                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-gconf) ;;
 592             esac
 593         ],
 594         [glib=auto])
 595
 596 if test "x${gconf}" != xno ; then
 597     PKG_CHECK_MODULES(GCONF, [ gconf-2.0 >= 2.4.0 ],
 598         HAVE_GCONF=1,
 599         [
 600             HAVE_GCONF=0
 601             if test "x$gconf" = xyes ; then
 602                 AC_MSG_ERROR([*** GConf support not found])
 603             fi
 604         ])
 605 else
 606     HAVE_GCONF=0
 607 fi
 608
 609 AC_SUBST(GCONF_CFLAGS)
 610 AC_SUBST(GCONF_LIBS)
 611 AC_SUBST(HAVE_GCONF)
 612 AM_CONDITIONAL([HAVE_GCONF], [test "x$HAVE_GCONF" = x1])
 613
 614 #### Avahi support (optional) ####
 615
 616 AC_ARG_ENABLE([avahi],
 617     AC_HELP_STRING([--disable-avahi], [Disable optional Avahi support]),
 618         [
 619             case "${enableval}" in
 620                 yes) avahi=yes ;;
 621                 no) avahi=no ;;
 622                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-avahi) ;;
 623             esac
 624         ],
 625         [avahi=auto])
 626
 627 if test "x${avahi}" != xno ; then
 628     PKG_CHECK_MODULES(AVAHI, [ avahi-client >= 0.6.0 ],
 629         HAVE_AVAHI=1,
 630         [
 631                 HAVE_AVAHI=0
 632                 if test "x$avahi" = xyes ; then
 633                         AC_MSG_ERROR([*** Avahi support not found])
 634                 fi
 635         ])
 636 else
 637     HAVE_AVAHI=0
 638 fi
 639
 640 AC_SUBST(AVAHI_CFLAGS)
 641 AC_SUBST(AVAHI_LIBS)
 642 AC_SUBST(HAVE_AVAHI)
 643 AM_CONDITIONAL([HAVE_AVAHI], [test "x$HAVE_AVAHI" = x1])
 644
 645 ### LIBOIL ####
 646
 647 PKG_CHECK_MODULES(LIBOIL, [ liboil-0.3 >= 0.3.0 ])
 648 AC_SUBST(LIBOIL_CFLAGS)
 649 AC_SUBST(LIBOIL_LIBS)
 650
 651 ### JACK (optional) ####
 652
 653 AC_ARG_ENABLE([jack],
 654     AC_HELP_STRING([--disable-jack], [Disable optional JACK support]),
 655         [
 656             case "${enableval}" in
 657                 yes) jack=yes ;;
 658                 no) jack=no ;;
 659                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-jack) ;;
 660             esac
 661         ],
 662         [jack=auto])
 663
 664 if test "x${jack}" != xno ; then
 665     PKG_CHECK_MODULES(JACK, [ jack >= 0.100 ],
 666         HAVE_JACK=1,
 667         [
 668             HAVE_JACK=0
 669             if test "x$jack" = xyes ; then
 670                 AC_MSG_ERROR([*** JACK support not found])
 671             fi
 672         ])
 673 else
 674     HAVE_JACK=0
 675 fi
 676
 677 AC_SUBST(JACK_CFLAGS)
 678 AC_SUBST(JACK_LIBS)
 679 AC_SUBST(HAVE_JACK)
 680 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
 681
 682 #### Async DNS support (optional) ####
 683
 684 AC_ARG_ENABLE([asyncns],
 685     AC_HELP_STRING([--disable-asyncns], [Disable optional Async DNS support]),
 686         [
 687             case "${enableval}" in
 688                 yes) asyncns=yes ;;
 689                 no) asyncns=no ;;
 690                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-asyncns) ;;
 691             esac
 692         ],
 693         [asyncns=auto])
 694
 695 if test "x${asyncns}" != xno ; then
 696     PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ],
 697         HAVE_LIBASYNCNS=1,
 698         [
 699             HAVE_LIBASYNCNS=0
 700             if test "x$asyncns" = xyes ; then
 701                 AC_MSG_ERROR([*** Async DNS support not found])
 702             fi
 703         ])
 704 else
 705     HAVE_LIBASYNCNS=0
 706 fi
 707
 708 AC_SUBST(LIBASYNCNS_CFLAGS)
 709 AC_SUBST(LIBASYNCNS_LIBS)
 710 AC_SUBST(HAVE_LIBASYNCNS)
 711 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 712
 713 if test "x$HAVE_LIBASYNCNS" != "x0" ; then
 714    AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?])
 715 fi
 716
 717 #### TCP wrappers (optional) ####
 718
 719 AC_ARG_ENABLE([tcpwrap],
 720     AC_HELP_STRING([--disable-tcpwrap], [Disable optional TCP wrappers support]),
 721         [
 722             case "${enableval}" in
 723                 yes) tcpwrap=yes ;;
 724                 no) tcpwrap=no ;;
 725                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 726             esac
 727         ],
 728         [tcpwrap=auto])
 729
 730 if test "x${tcpwrap}" != xno ; then
 731     ACX_LIBWRAP
 732     if test "x${LIBWRAP_LIBS}" = x && test "x$tcpwrap" = xyes ; then
 733         AC_MSG_ERROR([*** TCP wrappers support not found])
 734     fi
 735 else
 736     LIBWRAP_LIBS=
 737 fi
 738
 739 AC_SUBST(LIBWRAP_LIBS)
 740
 741 #### LIRC support (optional) ####
 742
 743 AC_ARG_ENABLE([lirc],
 744     AC_HELP_STRING([--disable-lirc], [Disable optional LIRC support]),
 745         [
 746             case "${enableval}" in
 747                 yes) lirc=yes ;;
 748                 no) lirc=no ;;
 749                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-lirc) ;;
 750             esac
 751         ],
 752         [lirc=auto])
 753
 754 if test "x${lirc}" != xno ; then
 755     ACX_LIRC
 756     if test "x${HAVE_LIRC}" = x0 && test "x$lirc" = xyes ; then
 757         AC_MSG_ERROR([*** LIRC support not found])
 758     fi
 759 else
 760     HAVE_LIRC=0
 761 fi
 762
 763 AC_SUBST(LIRC_CFLAGS)
 764 AC_SUBST(LIRC_LIBS)
 765 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 766
 767 #### HAL support (optional) ####
 768
 769 AC_ARG_ENABLE([hal],
 770     AC_HELP_STRING([--disable-hal], [Disable optional HAL support]),
 771         [
 772             case "${enableval}" in
 773                 yes) hal=yes ;;
 774                 no) hal=no ;;
 775                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-hal) ;;
 776             esac
 777         ],
 778         [hal=auto])
 779 if test "x${hal}" != xno -a \( "x$HAVE_OSS" = "x1" -o "x$HAVE_ALSA" = "x1" \) ; then
 780     PKG_CHECK_MODULES(HAL, [ hal >= 0.5.7 ],
 781         HAVE_HAL=1,
 782         [
 783             HAVE_HAL=0
 784             if test "x$hal" = xyes ; then
 785                 AC_MSG_ERROR([*** HAL support not found])
 786             fi
 787         ])
 788 else
 789     HAVE_HAL=0
 790 fi
 791
 792 AC_SUBST(HAL_CFLAGS)
 793 AC_SUBST(HAL_LIBS)
 794 AC_SUBST(HAVE_HAL)
 795 AM_CONDITIONAL([HAVE_HAL], [test "x$HAVE_HAL" = x1])
 796
 797 #### BlueZ support (optional) ####
 798
 799 AC_ARG_ENABLE([bluez],
 800     AC_HELP_STRING([--disable-bluez], [Disable optional BlueZ support]),
 801         [
 802             case "${enableval}" in
 803                 yes) bluez=yes ;;
 804                 no) bluez=no ;;
 805                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-bluez) ;;
 806             esac
 807         ],
 808         [bluez=auto])
 809 if test "x${bluez}" != xno ; then
 810     PKG_CHECK_MODULES(BLUEZ, [ bluez >= 3.0 ],
 811         HAVE_BLUEZ=1,
 812         [
 813             HAVE_BLUEZ=0
 814             if test "x$bluez" = xyes ; then
 815                 AC_MSG_ERROR([*** BLUEZ support not found])
 816             fi
 817         ])
 818 else
 819     HAVE_BLUEZ=0
 820 fi
 821
 822 AC_SUBST(BLUEZ_CFLAGS)
 823 AC_SUBST(BLUEZ_LIBS)
 824 AC_SUBST(HAVE_BLUEZ)
 825 AM_CONDITIONAL([HAVE_BLUEZ], [test "x$HAVE_BLUEZ" = x1])
 826
 827 #### D-Bus support (optional) ####
 828
 829 AC_ARG_ENABLE([dbus],
 830     AC_HELP_STRING([--disable-dbus], [Disable optional D-Bus support]),
 831         [
 832             case "${enableval}" in
 833                 yes) dbus=yes ;;
 834                 no) dbus=no ;;
 835                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-dbus) ;;
 836             esac
 837         ],
 838         [dbus=auto])
 839
 840 if test "x$HAVE_HAL" = x1 ; then
 841    dbus=yes
 842 fi
 843
 844 if test "x${dbus}" != xno || test "x${bluez}" != xno || "x${hal}" != xno ; then
 845
 846     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.0.0 ],
 847         [
 848             HAVE_DBUS=1
 849             saved_LIBS="$LIBS"
 850             LIBS="$LIBS $DBUS_LIBS"
 851             AC_CHECK_FUNCS(dbus_watch_get_unix_fd)
 852             LIBS="$saved_LIBS"
 853             AC_DEFINE([HAVE_DBUS], 1, [Have D-Bus.])
 854         ],
 855         [
 856             HAVE_DBUS=0
 857             if test "x$dbus" = xyes ; then
 858                 AC_MSG_ERROR([*** D-Bus support not found])
 859             fi
 860         ])
 861 else
 862     HAVE_DBUS=0
 863 fi
 864
 865 AC_SUBST(DBUS_CFLAGS)
 866 AC_SUBST(DBUS_LIBS)
 867 AC_SUBST(HAVE_DBUS)
 868 AM_CONDITIONAL([HAVE_DBUS], [test "x$HAVE_DBUS" = x1])
 869
 870 #### PolicyKit support (optional) ####
 871
 872 AC_ARG_ENABLE([polkit],
 873     AC_HELP_STRING([--disable-polkit], [Disable optional PolicyKit support]),
 874         [
 875             case "${enableval}" in
 876                 yes) polkit=yes ;;
 877                 no) polkit=no ;;
 878                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-polkit) ;;
 879             esac
 880         ],
 881         [polkit=auto])
 882
 883 if test "x${polkit}" != xno ; then
 884
 885     PKG_CHECK_MODULES(POLKIT, [ polkit-dbus ],
 886         [
 887             HAVE_POLKIT=1
 888             saved_LIBS="$LIBS"
 889             LIBS="$LIBS $POLKIT_LIBS"
 890             AC_CHECK_FUNCS(polkit_context_is_caller_authorized)
 891             LIBS="$saved_LIBS"
 892             AC_DEFINE([HAVE_POLKIT], 1, [Have PolicyKit])
 893             policydir=`pkg-config polkit-dbus --variable prefix`/share/PolicyKit/policy/
 894             AC_SUBST(policydir)
 895         ],
 896         [
 897             HAVE_POLKIT=0
 898             if test "x$polkit" = xyes ; then
 899                 AC_MSG_ERROR([*** PolicyKit support not found])
 900             fi
 901         ])
 902 else
 903     HAVE_POLKIT=0
 904 fi
 905
 906 AC_SUBST(POLKIT_CFLAGS)
 907 AC_SUBST(POLKIT_LIBS)
 908 AC_SUBST(HAVE_POLKIT)
 909 AM_CONDITIONAL([HAVE_POLKIT], [test "x$HAVE_POLKIT" = x1])
 910
 911 ### Build and Install man pages ###
 912 AC_ARG_ENABLE(manpages,
 913         AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]),
 914 [case "${enableval}" in
 915   yes) manpages=yes ;;
 916   no)  manpages=no ;;
 917   *) AC_MSG_ERROR([bad value ${enableval} for --disable-manpages]) ;;
 918 esac],[manpages=yes])
 919
 920 if test x$manpages = xyes ; then
 921     #
 922     # XMLTOMAN manpage generation
 923     #
 924     AC_ARG_ENABLE(xmltoman,
 925     AS_HELP_STRING([--disable-xmltoman],[Enable rebuilding of man pages with xmltoman]),
 926     [case "${enableval}" in
 927       yes) xmltoman=yes ;;
 928       no)  xmltoman=no ;;
 929       *) AC_MSG_ERROR([bad value ${enableval} for --disable-xmltoman]) ;;
 930     esac],[xmltoman=yes])
 931
 932     if test x$xmltoman = xyes ; then
 933         AC_CHECK_PROG(have_xmltoman, xmltoman, yes, no)
 934     fi
 935
 936     if test x$have_xmltoman = xno -o x$xmltoman = xno; then
 937         if ! test -e man/pulseaudio.1 ; then
 938             AC_MSG_ERROR([*** xmltoman was not found or was disabled, it is required to build the manpages as they have not been pre-built, install xmltoman, pass --disable-manpages or dont pass --disable-xmltoman])
 939             exit 1
 940         fi
 941         AC_MSG_WARN([*** Not rebuilding man pages as xmltoman is not found ***])
 942         xmltoman=no
 943     fi
 944 fi
 945 AM_CONDITIONAL([USE_XMLTOMAN], [test "x$xmltoman" = xyes])
 946 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$manpages" = xyes])
 947
 948 #### PulseAudio system group & user  #####
 949
 950 AC_ARG_WITH(system_user, AS_HELP_STRING([--with-system-user=<user>],[User for running the PulseAudio daemon as a system-wide instance (pulse)]))
 951 if test -z "$with_system_user" ; then
 952     PA_SYSTEM_USER=pulse
 953 else
 954     PA_SYSTEM_USER=$with_system_user
 955 fi
 956 AC_SUBST(PA_SYSTEM_USER)
 957 AC_DEFINE_UNQUOTED(PA_SYSTEM_USER,"$PA_SYSTEM_USER", [User for running the PulseAudio system daemon])
 958
 959 AC_ARG_WITH(system_group,AS_HELP_STRING([--with-system-group=<group>],[Group for running the PulseAudio daemon as a system-wide instance (pulse)]))
 960 if test -z "$with_system_group" ; then
 961     PA_SYSTEM_GROUP=pulse
 962 else
 963     PA_SYSTEM_GROUP=$with_system_group
 964 fi
 965 AC_SUBST(PA_SYSTEM_GROUP)
 966 AC_DEFINE_UNQUOTED(PA_SYSTEM_GROUP,"$PA_SYSTEM_GROUP", [Group for the PulseAudio system daemon])
 967
 968 AC_ARG_WITH(realtime_group,AS_HELP_STRING([--with-realtime-group=<group>],[Group for users that are allowed to start the PulseAudio daemon with realtime scheduling (realtime)]))
 969 if test -z "$with_realtime_group" ; then
 970     PA_REALTIME_GROUP=pulse-rt
 971 else
 972     PA_REALTIME_GROUP=$with_realtime_group
 973 fi
 974 AC_SUBST(PA_REALTIME_GROUP)
 975 AC_DEFINE_UNQUOTED(PA_REALTIME_GROUP,"$PA_REALTIME_GROUP", [Realtime group])
 976
 977 AC_ARG_WITH(access_group,AS_HELP_STRING([--with-access-group=<group>],[Group which is allowed access to a system-wide PulseAudio daemon (pulse-access)]))
 978 if test -z "$with_access_group" ; then
 979     PA_ACCESS_GROUP=pulse-access
 980 else
 981     PA_ACCESS_GROUP=$with_access_group
 982 fi
 983 AC_SUBST(PA_ACCESS_GROUP)
 984 AC_DEFINE_UNQUOTED(PA_ACCESS_GROUP,"$PA_ACCESS_GROUP", [Access group])
 985
 986 AC_ARG_ENABLE(
 987         per_user_esound_socket,
 988         AS_HELP_STRING([--disable-per-user-esound-socket], [Use per-user esound socket directory, like /tmp/.esd-UID/socket.]),
 989         [
 990             case "${enableval}" in
 991                 yes) per_user_esound_socket=1 ;;
 992                 no) per_user_esound_socket=0 ;;
 993                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-per-user-esound-socket) ;;
 994             esac
 995         ],
 996         [per_user_esound_socket=1])
 997
 998 if test "x$per_user_esound_socket" = "x1"; then
 999    AC_DEFINE([USE_PER_USER_ESOUND_SOCKET], [1], [Define this if you want per-user esound socket directories])
1000 fi
1001
1002 #### PulseAudio system runtime dir ####
1003 PA_SYSTEM_RUNTIME_PATH="${localstatedir}/run/pulse"
1004 AC_SUBST(PA_SYSTEM_RUNTIME_PATH)
1005
1006 ###################################
1007 #            Output               #
1008 ###################################
1009
1010 AC_ARG_ENABLE(
1011         [static-bins],
1012         AC_HELP_STRING([--enable-static-bins],[Statically link executables.]),
1013         [STATIC_BINS=1], [STATIC_BINS=0])
1014 AM_CONDITIONAL([STATIC_BINS], [test "x$STATIC_BINS" = "x1"])
1015
1016 AC_ARG_WITH(
1017         [preopen-mods],
1018         AC_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
1019         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
1020 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
1021 if test "x$PREOPEN_MODS" != "xall" ; then
1022     tmpLIBS=""
1023     for mod in $PREOPEN_MODS; do
1024         tmpLIBS="$tmpLIBS module-$mod.la"
1025     done
1026     PREOPEN_MODS="$tmpLIBS"
1027     AC_SUBST(PREOPEN_MODS)
1028 fi
1029
1030 AC_ARG_WITH(
1031         [module-dir],
1032         AC_HELP_STRING([--with-module-dir],[Directory where to install the modules to (defaults to ${libdir}/pulse-${PA_MAJORMINOR}/modules/]),
1033         [modlibexecdir=$withval], [modlibexecdir="${libdir}/pulse-${PA_MAJORMINOR}/modules/"])
1034
1035 AC_SUBST(modlibexecdir)
1036
1037 AC_ARG_ENABLE(
1038         [force-preopen],
1039         AC_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]),
1040         [FORCE_PREOPEN=1], [FORCE_PREOPEN=0])
1041 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "x1"])
1042
1043 AC_CONFIG_FILES([
1044 Makefile
1045 src/Makefile
1046 man/Makefile
1047 libpulse.pc
1048 libpulse-simple.pc
1049 libpulse-browse.pc
1050 libpulse-mainloop-glib.pc
1051 doxygen/Makefile
1052 doxygen/doxygen.conf
1053 src/pulse/version.h
1054 ])
1055 AC_OUTPUT
1056
1057 # ==========================================================================
1058 ENABLE_X11=no
1059 if test "x$HAVE_X11" = "x1" ; then
1060    ENABLE_X11=yes
1061 fi
1062
1063 ENABLE_OSS=no
1064 if test "x$HAVE_OSS" = "x1" ; then
1065    ENABLE_OSS=yes
1066 fi
1067
1068 ENABLE_ALSA=no
1069 if test "x$HAVE_ALSA" = "x1" ; then
1070    ENABLE_ALSA=yes
1071 fi
1072
1073 ENABLE_SOLARIS=no
1074 if test "x$HAVE_SOLARIS" = "x1" ; then
1075    ENABLE_SOLARIS=yes
1076 fi
1077
1078 ENABLE_GLIB20=no
1079 if test "x$HAVE_GLIB20" = "x1" ; then
1080    ENABLE_GLIB20=yes
1081 fi
1082
1083 ENABLE_GCONF=no
1084 if test "x$HAVE_GCONF" = "x1" ; then
1085    ENABLE_GCONF=yes
1086 fi
1087
1088 ENABLE_AVAHI=no
1089 if test "x$HAVE_AVAHI" = "x1" ; then
1090    ENABLE_AVAHI=yes
1091 fi
1092
1093 ENABLE_JACK=no
1094 if test "x$HAVE_JACK" = "x1" ; then
1095    ENABLE_JACK=yes
1096 fi
1097
1098 ENABLE_LIBASYNCNS=no
1099 if test "x$HAVE_LIBASYNCNS" = "x1" ; then
1100    ENABLE_LIBASYNCNS=yes
1101 fi
1102
1103 ENABLE_LIRC=no
1104 if test "x$HAVE_LIRC" = "x1" ; then
1105    ENABLE_LIRC=yes
1106 fi
1107
1108 ENABLE_HAL=no
1109 if test "x$HAVE_HAL" = "x1" ; then
1110    ENABLE_HAL=yes
1111 fi
1112
1113 ENABLE_TCPWRAP=no
1114 if test "x${LIBWRAP_LIBS}" != x ; then
1115    ENABLE_TCPWRAP=yes
1116 fi
1117
1118 ENABLE_LIBSAMPLERATE=no
1119 if test "x${HAVE_LIBSAMPLERATE}" = "x1" ; then
1120    ENABLE_LIBSAMPLERATE=yes
1121 fi
1122
1123 ENABLE_BLUEZ=no
1124 if test "x${HAVE_BLUEZ}" = "x1" ; then
1125    ENABLE_BLUEZ=yes
1126 fi
1127
1128 ENABLE_POLKIT=no
1129 if test "x${HAVE_POLKIT}" = "x1" ; then
1130    ENABLE_POLKIT=yes
1131 fi
1132
1133 ENABLE_PER_USER_ESOUND_SOCKET=no
1134 if test "x$per_user_esound_socket" = "x1" ; then
1135    ENABLE_PER_USER_ESOUND_SOCKET=yes
1136 fi
1137
1138 echo "
1139  ---{ $PACKAGE_NAME $VERSION }---
1140
1141     prefix:                        ${prefix}
1142     sysconfdir:                    ${sysconfdir}
1143     localstatedir:                 ${localstatedir}
1144     System Runtime Path:           ${PA_SYSTEM_RUNTIME_PATH}
1145     Compiler:                      ${CC}
1146     CFLAGS:                        ${CFLAGS}
1147     Have X11:                      ${ENABLE_X11}
1148     Enable OSS:                    ${ENABLE_OSS}
1149     Enable Alsa:                   ${ENABLE_ALSA}
1150     Enable Solaris:                ${ENABLE_SOLARIS}
1151     Enable GLib 2.0:               ${ENABLE_GLIB20}
1152     Enable GConf:                  ${ENABLE_GCONF}
1153     Enable Avahi:                  ${ENABLE_AVAHI}
1154     Enable Jack:                   ${ENABLE_JACK}
1155     Enable Async DNS:              ${ENABLE_LIBASYNCNS}
1156     Enable LIRC:                   ${ENABLE_LIRC}
1157     Enable HAL:                    ${ENABLE_HAL}
1158     Enable BlueZ:                  ${ENABLE_BLUEZ}
1159     Enable TCP Wrappers:           ${ENABLE_TCPWRAP}
1160     Enable libsamplerate:          ${ENABLE_LIBSAMPLERATE}
1161     Enable PolicyKit:              ${ENABLE_POLKIT}
1162     System User:                   ${PA_SYSTEM_USER}
1163     System Group:                  ${PA_SYSTEM_GROUP}
1164     Realtime Group:                ${PA_REALTIME_GROUP}
1165     Access Group:                  ${PA_ACCESS_GROUP}
1166     Enable per-user EsounD socket: ${ENABLE_PER_USER_ESOUND_SOCKET}
1167 "