configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Copyright (C) 1995-2012 Free Software Foundation, Inc.
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2, or (at your option)
   8 # any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 AC_PREREQ([2.69])
  19 AC_INIT([GNU Automake], [1.12a], [bug-automake@gnu.org])
  20
  21 AC_CONFIG_SRCDIR([automake.in])
  22 AC_CONFIG_AUX_DIR([lib])
  23
  24 AM_SILENT_RULES([yes])
  25
  26 AC_CANONICAL_HOST
  27 AC_CANONICAL_BUILD
  28
  29 # Save the AUTOCONF setting before AM_INIT_AUTOMAKE overrides it; this
  30 # way we can run Autoconf tests from configure (or from the test
  31 # suite) without being bothered by 'missing'.  Likewise for autom4te,
  32 # autoreconf, autoheader, and autoupdate.
  33 AC_SUBST([am_AUTOCONF], ["${AUTOCONF-autoconf}"])
  34 AC_SUBST([am_AUTOM4TE], ["${AUTOM4TE-autom4te}"])
  35 AC_SUBST([am_AUTORECONF], ["${AUTORECONF-autoreconf}"])
  36 AC_SUBST([am_AUTOHEADER], ["${AUTOHEADER-autoheader}"])
  37 AC_SUBST([am_AUTOUPDATE], ["${AUTOUPDATE-autoupdate}"])
  38
  39 dnl We call AC_PROG_CC in an unusual way, and only for use in our
  40 dnl testsuite, so also use 'no-dependencies' and 'no-define' among
  41 dnl the automake options to avoid bloating and potential problems.
  42 AM_INIT_AUTOMAKE([dist-xz filename-length-max=99 color-tests
  43                   parallel-tests silent-rules no-define no-dependencies])
  44
  45 # The API version is the base version.  We must guarantee
  46 # compatibility for all releases with the same API version.
  47 # Our current rule is that:
  48 # * All releases, including the prereleases, in an X.Y series
  49 #   are compatible.  So 1.5.1c is compatible with 1.5.
  50 # * Prereleases on the trunk are all incompatible -- 1.5b and 1.5c
  51 #   aren't the same.
  52 APIVERSION=`echo "$VERSION" | sed -e 's/^\([[0-9]]*\.[[0-9]]*[[a-z]]*\).*$/\1/'`
  53 AC_SUBST([APIVERSION])
  54
  55 AC_SUBST([pkgvdatadir], ["\${datadir}/$PACKAGE-$APIVERSION"])
  56 AC_SUBST([scriptdir], ["\${pkgvdatadir}"])
  57 AC_SUBST([amdir], ["\${pkgvdatadir}/am"])
  58 AC_SUBST([automake_acdir], ["\${datadir}/aclocal-$APIVERSION"])
  59 AC_SUBST([system_acdir], ["\${datadir}/aclocal"])
  60
  61 # $AUTOMAKE and $ACLOCAL are always run after a "cd $top_srcdir",
  62 # hence '.' is really what we want for perllibdir, libdir, and acdir.
  63 # Use '-I' with aclocal so that our own *.m4 files in m4/ gets included,
  64 # not copied, in aclocal.m4.
  65 ACLOCAL="\
  66   perllibdir=\"`pwd`/lib$PATH_SEPARATOR./lib\" \"`pwd`/aclocal\" \
  67   --automake-acdir=m4 --system-acdir=m4/acdir -I m4"
  68 AUTOMAKE="\
  69   perllibdir=\"`pwd`/lib$PATH_SEPARATOR./lib\" \"`pwd`/automake\" \
  70   --libdir=lib"
  71
  72 AC_PATH_PROG([PERL], [perl])
  73 if test -z "$PERL"; then
  74    AC_MSG_ERROR([perl not found])
  75 fi
  76 # Save details about the selected perl interpreter in config.log.
  77 AM_RUN_LOG([$PERL --version])
  78 $PERL -e 'require 5.006;' || {
  79    AC_MSG_ERROR(
  80 [perl 5.6 or better is required; perl 5.8.2 or better
  81 is recommended.  If you have several perl versions
  82 installed, select the one Automake should use using
  83   ./configure PERL=/path/to/perl])
  84 }
  85
  86 # We require ithreads support, and version 5.7.2 for CLONE.
  87 AC_CACHE_CHECK([whether $PERL supports ithreads], [am_cv_prog_PERL_ithreads],
  88 [if $PERL -e '
  89     require 5.007_002;
  90     use Config;
  91     if ($Config{useithreads})
  92       {
  93         require threads;
  94         import threads;
  95         require Thread::Queue;
  96         import Thread::Queue;
  97         exit 0;
  98       }
  99     exit 1;' >&AS_MESSAGE_LOG_FD 2>&1
 100 then
 101   am_cv_prog_PERL_ithreads=yes
 102 else
 103   am_cv_prog_PERL_ithreads=no
 104 fi])
 105 if test $am_cv_prog_PERL_ithreads = yes; then
 106   PERL_THREADS=1;
 107 else
 108   PERL_THREADS=0;
 109 fi
 110 AC_SUBST([PERL_THREADS])
 111
 112 # The test suite will skip some tests if tex is absent.
 113 AC_CHECK_PROG([TEX], [tex], [tex])
 114 # Save details about the selected TeX program in config.log.
 115 # Redirect input from /dev/null, as TeX might otherwise hang waiting
 116 # for input from the terminal.
 117 AM_RUN_LOG([$TEX --version </dev/null])
 118
 119 # The test suite will skip some tests if no lex or yacc program is
 120 # available.
 121 # We don't use AC_PROG_LEX nor AC_PROG_YACC here because:
 122 #  1. we don't want flex (resp. bison) to be preferred to system lex
 123 #     (resp. system yacc);
 124 #  2. we don't want $LEX (resp. $YACC) to be defined to ':' (resp. 'yacc')
 125 #     by default;
 126 #  3. we prefer not to have the variables YFLAGS, LEX_OUTPUT_ROOT and
 127 #     LEXLIB to be calculated and/or AC_SUBST'd;
 128 #  4. we prefer that the YACC and LEX variables are not reported in the
 129 #     configure help screen.
 130 AC_CHECK_PROGS([YACC], [yacc byacc 'bison -y'], [false])
 131 AC_CHECK_PROGS([LEX], [lex flex], [false])
 132
 133 # Test for Autoconf.  We run Autoconf in a subdirectory to ease
 134 # deletion of any files created (such as those added to
 135 # autom4te.cache).  We used to perform only the last of the three
 136 # following tests, but some users were unable to figure out that their
 137 # installation was broken since --version appeared to work.
 138
 139 required_autoconf_version=2.62
 140 AC_CACHE_CHECK([whether autoconf is installed], [am_cv_autoconf_installed],
 141 [if AM_RUN_LOG([$am_AUTOCONF --version]);
 142 then
 143   am_cv_autoconf_installed=yes
 144 else
 145   am_cv_autoconf_installed=no
 146 fi])
 147 if test "$am_cv_autoconf_installed" = no; then
 148   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.
 149     Please make sure it is installed and in your PATH.])
 150 fi
 151
 152 AC_CACHE_CHECK([whether autoconf works], [am_cv_autoconf_works],
 153 [mkdir conftest
 154 echo 'AC''_INIT' > conftest/conftest.ac
 155 if AM_RUN_LOG([cd conftest && $am_AUTOCONF -o /dev/null conftest.ac]);
 156 then
 157   am_cv_autoconf_works=yes
 158 else
 159   am_cv_autoconf_works=no
 160 fi
 161 rm -rf conftest])
 162 if test "$am_cv_autoconf_works" = no; then
 163   AC_MSG_ERROR([The installed version of autoconf does not work.
 164     Please check config.log for error messages before this one.])
 165 fi
 166
 167 AC_CACHE_CHECK([whether autoconf is recent enough], [am_cv_autoconf_version],
 168 [mkdir conftest
 169 dnl Creative quoting required to avoid spurious expansion of AC_PREREQ macro
 170 echo 'AC'"_PREREQ([[$required_autoconf_version]])" > conftest/conftest.ac
 171 if AM_RUN_LOG([cd conftest && $am_AUTOCONF -o /dev/null conftest.ac]);
 172 then
 173   am_cv_autoconf_version=yes
 174 else
 175   am_cv_autoconf_version=no
 176 fi
 177 rm -rf conftest])
 178 if test "$am_cv_autoconf_version" = no; then
 179   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.])
 180 fi
 181
 182 # Test for ln.  We need use it to install the versioned binaries.
 183 AC_MSG_CHECKING([whether ln works])
 184 AC_CACHE_VAL([am_cv_prog_ln], [
 185 rm -f conftest conftest.file
 186 : >conftest.file
 187 if ln conftest.file conftest 2>/dev/null; then
 188   am_cv_prog_ln=ln
 189 else
 190   am_cv_prog_ln='cp -p'
 191 fi
 192 rm -f conftest conftest.file])
 193 AC_SUBST([LN], [$am_cv_prog_ln])
 194 result=no
 195 test "x$am_cv_prog_ln" = xln && result=yes
 196 AC_MSG_RESULT([$result])
 197
 198 # The amount we should wait after modifying files depends on the platform.
 199 # On Windows '95, '98 and ME, files modifications have 2-seconds
 200 # granularity and can be up to 3 seconds in the future w.r.t. the
 201 # system clock.  When it is important to ensure one file is older
 202 # than another we wait at least 5 seconds between creations.
 203 case $build in
 204   *-pc-msdosdjgpp) MODIFICATION_DELAY=5;;
 205   *)               MODIFICATION_DELAY=2;;
 206 esac
 207 AC_SUBST([MODIFICATION_DELAY])
 208
 209 # Test for things needed by the test suite.
 210 AC_PROG_EGREP
 211 AC_PROG_FGREP
 212
 213 AC_CACHE_CHECK([whether $SHELL has working 'set -e' with exit trap],
 214 [am_cv_sh_errexit_works],
 215 [if $SHELL -ec "trap 'exit \$?' 0; (exit 77); exit 77"; test $? = 77
 216 then
 217   am_cv_sh_errexit_works=yes
 218 else
 219   am_cv_sh_errexit_works=no
 220 fi
 221 ])
 222 if test $am_cv_sh_errexit_works = no; then
 223   AC_MSG_WARN(["${MAKE-make} check" will leave leftover directories t/*.dir])
 224   AC_MSG_WARN([you can clean them up manually using "${MAKE-make} clean" or])
 225   AC_MSG_WARN(["cd t && ${MAKE-make} clean-local-check'])
 226 fi
 227 AC_SUBST([sh_errexit_works], [$am_cv_sh_errexit_works])
 228
 229
 230 ###########################################################################
 231
 232 # Look for C, C++ and fortran compilers to be used in the testsuite.
 233
 234 dnl We don't want to abort our configuration script if no C compiler is
 235 dnl available, as such a compiler is only required to run part of the
 236 dnl testsuite, not to build or install Automake.  Ditto for C++, Fortran
 237 dnl and Fortran 77 compilers.  Unfortunately, autoconf does not offer an
 238 dnl easy way to obtain this behaviour, so we'll need a few hacks.
 239
 240 dnl We want the body of this macro to expand as a single shell statement,
 241 dnl thus we wrap it into { ... } brackets.
 242 AC_DEFUN([_AM_WRAP_MSG_ERROR], [ {
 243   AC_MSG_WARN([$1])
 244   am__failed=yes
 245   break
 246 } ])
 247
 248 AC_DEFUN([_AM_COMPILER_CAN_FAIL], [
 249   m4_pushdef([AC_MSG_FAILURE], m4_defn([_AM_WRAP_MSG_ERROR]))
 250   m4_pushdef([AC_MSG_ERROR],   m4_defn([_AM_WRAP_MSG_ERROR]))
 251   am__failed=no
 252   while :; do
 253      $1
 254      break
 255   done
 256   AS_IF([test $am__failed = yes], [$2])
 257   # We have to clear these cache variables, so that future checks on
 258   # compilers for different languages won't be confused.
 259   unset ac_cv_objext ac_cv_exeext
 260   # We also need to meddle with the autoconf internals to ensure that
 261   # checks to find object and executable extensions will be run anew.
 262   # FIXME: In the long run, the better thing to do would be to fix
 263   # FIXME: autoconf instead ...
 264   m4_undefine([m4_provide(_AC_COMPILER_OBJEXT)])
 265   m4_undefine([m4_provide(_AC_COMPILER_EXEEXT)])
 266   m4_popdef([AC_MSG_FAILURE])
 267   m4_popdef([AC_MSG_ERROR])
 268 ])
 269
 270 AC_DEFUN([_AM_SKIP_COMP_TESTS],
 271   [AC_MSG_NOTICE([tests requiring the $1 compiler will be skipped])])
 272
 273 # Prefer generic compilers to GNU ones when possible.  This will ensure
 274 # more testsuite coverage "in the wild".
 275 # Note that we don't look for the MSVC C/C++ compiler here.  This is
 276 # deliberate; for more discussion and rationale, see:
 277 # <http://lists.gnu.org/archive/html/automake-patches/2012-01/msg00130.html>
 278
 279 AC_MSG_NOTICE([will now look for generic compilers])
 280
 281 # C compiler.
 282 _AM_COMPILER_CAN_FAIL(dnl
 283   [AC_PROG_CC([cc gcc])],
 284   [CC=false; _AM_SKIP_COMP_TESTS([C])])
 285
 286 AS_IF([test x"$GCC" = x"yes"], [am_CC_is_GNU=yes], [am_CC_is_GNU=no])
 287
 288 # The list of C++ compilers here has been copied, pasted and edited
 289 # from 'lib/autoconf/c.m4:AC_PROG_CXX' in the Autoconf distribution.
 290 # Keep it in sync, or better again, find out a way to avoid this code
 291 # duplication.
 292 _AM_COMPILER_CAN_FAIL([AC_PROG_CXX(dnl
 293   [aCC CC FCC KCC RCC xlC_r xlC c++ cxx cc++ gpp g++])],
 294   [CXX=false; _AM_SKIP_COMP_TESTS([C++])])
 295
 296 AS_IF([test x"$GXX" = x"yes"], [am_CXX_is_GNU=yes], [am_CXX_is_GNU=no])
 297
 298 # The lists of Fortran compilers here has been copied, pasted and edited
 299 # from file 'lib/autoconf/fortran.m4' in the Autoconf distribution.
 300 # Keep it in sync, or better again, find out a way to avoid this code
 301 # duplication.
 302
 303 _AM_COMPILER_CAN_FAIL([AC_PROG_FC(dnl
 304   [xlf95 f95 fort ifort ifc efc pgfortran pgf95 lf95 ftn nagfor] dnl
 305   [xlf90 f90 pgf90 pghpf epcf90 g95 gfortran])],
 306   [FC=false; _AM_SKIP_COMP_TESTS([Fortran])])
 307
 308 AS_IF([test x"$GFC" = x"yes"], [am_FC_is_GNU=yes], [am_FC_is_GNU=no])
 309
 310 _AM_COMPILER_CAN_FAIL([AC_PROG_F77(dnl
 311   [xlf f77 frt pgf77 cf77 fort77 fl32 af77 g77 gfortran])],
 312   [F77=false; _AM_SKIP_COMP_TESTS([Fortran 77])])
 313
 314 AS_IF([test x"$G77" = x"yes"], [am_F77_is_GNU=yes], [am_F77_is_GNU=no])
 315
 316 # Some tests will need the GNU compilers.  Searching for them here would
 317 # be overkill, since our testsuite already handles their search and setup
 318 # pretty well.  But in case the compilers already found are the GNU ones,
 319 # we want to use them in the testsuite where GNU compilers are required.
 320 # Also, in case the compilers detected above (at configure time) are not
 321 # the GNU ones, we cannot use the values of CFLAGS, CXXFLAGS, FCFLAGS and
 322 # FFLAGS detected for them with the GNU compilers too, since it's likely
 323 # they won't be compatible.  So we allow the user to define variants of
 324 # these variables for the GNU compilers separately.
 325
 326 AC_MSG_NOTICE([will now look for GNU compilers])
 327
 328 # GNU C compiler.
 329 AC_ARG_VAR([GNU_CC],     [GNU C compiler])
 330 AC_ARG_VAR([GNU_CFLAGS], [GNU C compiler flags])
 331 if test $am_CC_is_GNU = yes; then
 332   AC_MSG_NOTICE([$CC is already a GNU C compiler])
 333   GNU_CC=$CC GNU_CFLAGS=${GNU_CFLAGS-$CFLAGS}
 334 else
 335   AC_CHECK_TOOLS([GNU_CC], [gcc], [false])
 336 fi
 337 AS_IF([AM_RUN_LOG([$GNU_CC --version && $GNU_CC -v])], [],
 338       [AC_MSG_WARN([botched installation for GNU C compiler])
 339        _AM_SKIP_COMP_TESTS([GNU C])])
 340
 341 # GNU C++ compiler.
 342 AC_ARG_VAR([GNU_CXX],      [GNU C++ compiler])
 343 AC_ARG_VAR([GNU_CXXFLAGS], [GNU C++ compiler flags])
 344 if test $am_CXX_is_GNU = yes; then
 345   AC_MSG_NOTICE([$CXX is already a GNU C++ compiler])
 346   GNU_CXX=$CXX
 347   GNU_CXXFLAGS=${GNU_CXXFLAGS-$CXXFLAGS}
 348 else
 349   AC_CHECK_TOOLS([GNU_CXX], [g++ gpp], [false])
 350 fi
 351 AS_IF([AM_RUN_LOG([$GNU_CXX --version && $GNU_CXX -v])], [],
 352       [AC_MSG_WARN([botched installation for GNU C++ compiler])
 353        _AM_SKIP_COMP_TESTS([GNU C++])])
 354
 355 # GNU Fortran compiler.
 356 AC_ARG_VAR([GNU_FC],      [GNU Fortran compiler])
 357 AC_ARG_VAR([GNU_FCFLAGS], [GNU Fortran compiler flags])
 358 if test $am_FC_is_GNU = yes; then
 359   AC_MSG_NOTICE([$FC is already a GNU Fortran compiler])
 360   GNU_FC=$FC
 361   GNU_FCFLAGS=${GNU_FCFLAGS-$FCFLAGS}
 362 else
 363   AC_CHECK_TOOLS([GNU_FC], [gfortran], [false])
 364 fi
 365 AS_IF([AM_RUN_LOG([$GNU_FC --version && $GNU_FC -v])], [],
 366       [AC_MSG_WARN([botched installation for GNU Fortran compiler])
 367        _AM_SKIP_COMP_TESTS([GNU Fortran])])
 368
 369 # GNU Fortran 77 compiler.
 370 AC_ARG_VAR([GNU_F77],    [GNU Fortran 77 compiler])
 371 AC_ARG_VAR([GNU_FFLAGS], [GNU Fortran 77 compiler flags])
 372 if test $am_F77_is_GNU = yes; then
 373   AC_MSG_NOTICE([$F77 is already a GNU Fortran 77 compiler])
 374   GNU_F77=$F77
 375   GNU_FFLAGS=${GNU_FFLAGS-$FFLAGS}
 376 else
 377   AC_CHECK_TOOLS([GNU_F77], [g77 gfortran], [false])
 378 fi
 379 AS_IF([AM_RUN_LOG([$GNU_F77 --version && $GNU_F77 -v])], [],
 380       [AC_MSG_WARN([botched installation for GNU Fortran 77 compiler])
 381       _AM_SKIP_COMP_TESTS([GNU Fortran 77])])
 382
 383 # GNU Java compiler.
 384 AC_ARG_VAR([GNU_GCJ], [GNU Java compiler])
 385 AC_ARG_VAR([GNU_GCJFLAGS], [GNU Java compiler flags])
 386 AC_CHECK_TOOLS([GNU_GCJ], [gcj], [false])
 387 AS_IF([AM_RUN_LOG([$GNU_GCJ --version && $GNU_GCJ -v])], [],
 388       [AC_MSG_WARN([botched installation for GNU Java compiler])
 389       _AM_SKIP_COMP_TESTS([GNU Java])])
 390
 391 # If we have been able to find at least a working compiler above, we
 392 # know what the object and executable extensions for this platform are.
 393 OBJEXT=${ac_cv_objext-UNKNOWN}
 394 EXEEXT=${ac_cv_exeext-UNKNOWN}
 395 AC_SUBST([OBJEXT])
 396 AC_SUBST([EXEEXT])
 397
 398 ###########################################################################
 399
 400 AC_CONFIG_FILES([Makefile])
 401
 402 AC_CONFIG_LINKS([GNUmakefile:GNUmakefile])
 403 AC_CONFIG_LINKS([defs:defs])
 404
 405 AC_CONFIG_FILES([t/wrap/aclocal-${APIVERSION}:t/wrap/aclocal.in],
 406                 [chmod +x t/wrap/aclocal-${APIVERSION}],
 407                 [APIVERSION=$APIVERSION])
 408 AC_CONFIG_FILES([t/wrap/automake-${APIVERSION}:t/wrap/automake.in],
 409                 [chmod +x t/wrap/automake-${APIVERSION}],
 410                 [APIVERSION=$APIVERSION])
 411
 412 AC_OUTPUT
 413
 414 # Inform the user if this version of automake is a beta release or
 415 # a development snapshot.
 416 # According to HACKING, the version of a development snapshot should
 417 # end with an "odd" letter (a, c, ...), the version of a test release
 418 # should end wit an "even" letter (b, d, ...).
 419
 420 am_stable_version_rx='[[1-9]\.[0-9]+(\.[0-9]+)?]'
 421 am_beta_version_rx="[$am_stable_version_rx[bdfhjlnprtvxz]]"
 422
 423 am_release_type=`AS_ECHO(["$PACKAGE_VERSION"]) | LC_ALL=C awk ["
 424   /^$am_stable_version_rx$/ { print \"stable\"; exit(0); }
 425   /^$am_beta_version_rx$/ { print \"beta version\"; exit(0); }
 426   { print \"development snapshot\"; }"]`
 427
 428 test "$am_release_type" = stable || cat <<EOF
 429
 430 WARNING: You are about to use a $am_release_type of automake.
 431 WARNING: It might easily suffer from new bugs or regressions.
 432 WARNING: You are strongly advised not to use it in production code.
 433
 434 Please report bugs, problems and feedback to <AC_PACKAGE_BUGREPORT>.
 435 EOF
 436
 437 AS_EXIT([0])