configure.ac

   1 #
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([systemd],
  23         [230],
  24         [http://github.com/systemd/systemd/issues],
  25         [systemd],
  26         [http://www.freedesktop.org/wiki/Software/systemd])
  27
  28 AC_CONFIG_SRCDIR([src/core/main.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_MAINTAINER_MODE([enable])
  37 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects parallel-tests])
  38 AM_SILENT_RULES([yes])
  39 AC_CANONICAL_HOST
  40 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  41
  42 AC_PROG_CC_C99
  43
  44 AX_COMPILER_VENDOR
  45 AS_IF([test "x$ax_cv_c_compiler_vendor" = "xgnu"], [
  46       AC_CHECK_TOOLS([AR], [gcc-ar ar], [:])
  47       AC_CHECK_TOOLS([NM], [gcc-nm nm], [:])
  48       AC_CHECK_TOOLS([RANLIB], [gcc-ranlib ranlib], [:])
  49 ])
  50
  51 LT_PREREQ(2.2)
  52 LT_INIT([disable-static])
  53
  54 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by systemd])])
  55 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by systemd])])
  56
  57 SET_ARCH(X86_64, x86_64*)
  58 SET_ARCH(IA32, i*86*)
  59 SET_ARCH(MIPS, mips*)
  60 SET_ARCH(AARCH64, aarch64*)
  61
  62 # i18n stuff for the PolicyKit policy files, heck whether intltool can be found, disable NLS otherwise
  63 AC_CHECK_PROG(intltool_found, [intltool-merge], [yes], [no])
  64 AS_IF([test x"$intltool_found" != xyes],
  65       [AS_IF([test x"$enable_nls" = xyes],
  66              [AC_MSG_ERROR([--enable-nls requested but intltool not found])],
  67              [AS_IF([test x"$enable_nls" != xno],
  68                     [AC_MSG_WARN([*** Disabling NLS support because intltool was not found])
  69                      enable_nls=no])
  70              ])
  71       ])
  72
  73 AM_NLS
  74 AS_IF([test x"$enable_nls" != xno -o "x$enable_polkit" != xno], [
  75     # intltoolize greps for '^(AC|IT)_PROG_INTLTOOL', so it needs to be on its own line
  76 IT_PROG_INTLTOOL([0.40.0])
  77 ])
  78
  79 AS_IF([test -z "$INTLTOOL_POLICY_RULE"], [
  80     # If intltool is not available, provide a dummy rule to fail generation of %.policy files with a meaningful error message
  81     INTLTOOL_POLICY_RULE='%.policy: %.policy.in ; @echo "  ITMRG   " $@ && echo "*** intltool support required to build target $@" && false'
  82     AC_SUBST(INTLTOOL_POLICY_RULE)
  83 ])
  84
  85 GETTEXT_PACKAGE=systemd
  86 AC_SUBST(GETTEXT_PACKAGE)
  87 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [systemd])
  88
  89 AC_PROG_MKDIR_P
  90 AC_PROG_LN_S
  91 AC_PROG_SED
  92 AC_PROG_GREP
  93 AC_PROG_AWK
  94
  95 AC_PATH_PROG([M4], [m4])
  96
  97 AC_PATH_PROG([QUOTAON], [quotaon], [/usr/sbin/quotaon], [$PATH:/usr/sbin:/sbin])
  98 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/usr/sbin/quotacheck], [$PATH:/usr/sbin:/sbin])
  99
 100 AC_PATH_PROG([SETCAP], [setcap], [/usr/sbin/setcap], [$PATH:/usr/sbin:/sbin])
 101
 102 AC_PATH_PROG([KILL], [kill], [/usr/bin/kill], [$PATH:/usr/sbin:/sbin])
 103
 104 AC_PATH_PROG([KMOD], [kmod], [/usr/bin/kmod], [$PATH:/usr/sbin:/sbin])
 105
 106 AC_PATH_PROG([KEXEC], [kexec], [/usr/sbin/kexec], [$PATH:/usr/sbin:/sbin])
 107
 108 AC_PATH_PROG([SULOGIN], [sulogin], [/usr/sbin/sulogin], [$PATH:/usr/sbin:/sbin])
 109
 110 AC_PATH_PROG([MOUNT_PATH], [mount], [/usr/bin/mount], [$PATH:/usr/sbin:/sbin])
 111 AC_PATH_PROG([UMOUNT_PATH], [umount], [/usr/bin/umount], [$PATH:/usr/sbin:/sbin])
 112
 113 AS_IF([! ln --relative --help > /dev/null 2>&1], [AC_MSG_ERROR([*** ln doesn't support --relative ***])])
 114
 115 M4_DEFINES=
 116
 117 AC_CHECK_TOOL(OBJCOPY, objcopy)
 118 AC_CHECK_TOOL(STRINGS, strings)
 119 AC_CHECK_TOOL(GPERF, gperf)
 120 if test -z "$GPERF" ; then
 121         AC_MSG_ERROR([*** gperf not found])
 122 fi
 123
 124 # ------------------------------------------------------------------------------
 125 address_sanitizer_cflags=
 126 address_sanitizer_cppflags=
 127 address_sanitizer_ldflags=
 128 AC_ARG_ENABLE(address-sanitizer, AS_HELP_STRING([--enable-address-sanitizer], [enable -fsanitize=address]))
 129 AS_IF([test "x$enable_address_sanitizer" = "xyes"], [
 130             CC_CHECK_FLAG_APPEND([with_as_cflags], [CFLAGS], [-fsanitize=address])
 131             AS_IF([test -z "$with_as_cflags"],
 132                   [AC_MSG_ERROR([*** -fsanitize=address is not supported])])
 133             address_sanitizer_cflags="$with_as_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 134             address_sanitizer_cppflags="-DVALGRIND=1"
 135             address_sanitizer_ldflags="-Wc,-fsanitize=address"
 136       ])
 137
 138 undefined_sanitizer_cflags=
 139 undefined_sanitizer_cppflags=
 140 undefined_sanitizer_ldflags=
 141 AC_ARG_ENABLE(undefined-sanitizer, AS_HELP_STRING([--enable-undefined-sanitizer], [enable -fsanitize=undefined]))
 142 AS_IF([test "x$enable_undefined_sanitizer" = "xyes"], [
 143             CC_CHECK_FLAG_APPEND([with_us_cflags], [CFLAGS], [-fsanitize=undefined])
 144             AS_IF([test -z "$with_us_cflags"],
 145                   [AC_MSG_ERROR([*** -fsanitize=undefined is not supported])])
 146             undefined_sanitizer_cflags="$with_us_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 147             undefined_sanitizer_cppflags="-DVALGRIND=1"
 148             undefined_sanitizer_ldflags="-Wc,-fsanitize=undefined"
 149       ])
 150
 151 sanitizer_cflags="$address_sanitizer_cflags $undefined_sanitizer_cflags"
 152 sanitizer_cppflags="$address_sanitizer_cppflags $undefined_sanitizer_cppflags"
 153 sanitizer_ldflags="$address_sanitizer_ldflags $undefined_sanitizer_ldflags"
 154
 155 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 156         -pipe \
 157         -Wall \
 158         -Wextra \
 159         -Wundef \
 160         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
 161         -Wlogical-op \
 162         -Wmissing-include-dirs \
 163         -Wold-style-definition \
 164         -Wpointer-arith \
 165         -Winit-self \
 166         -Wdeclaration-after-statement \
 167         -Wfloat-equal \
 168         -Wsuggest-attribute=noreturn \
 169         -Werror=missing-prototypes \
 170         -Werror=implicit-function-declaration \
 171         -Werror=missing-declarations \
 172         -Werror=return-type \
 173         -Wstrict-prototypes \
 174         -Wredundant-decls \
 175         -Wmissing-noreturn \
 176         -Wshadow \
 177         -Wendif-labels \
 178         -Wstrict-aliasing=2 \
 179         -Wwrite-strings \
 180         -Wno-unused-parameter \
 181         -Wno-missing-field-initializers \
 182         -Wno-unused-result \
 183         -Wno-format-signedness \
 184         -Werror=overflow \
 185         -Wdate-time \
 186         -Wnested-externs \
 187         -ffast-math \
 188         -fno-common \
 189         -fdiagnostics-show-option \
 190         -fno-strict-aliasing \
 191         -fvisibility=hidden \
 192         -fstack-protector \
 193         -fstack-protector-strong \
 194         -fPIE \
 195         --param=ssp-buffer-size=4])
 196
 197 CC_CHECK_FLAG_APPEND([with_cflags], [CFLAGS], [-Werror=shadow], [
 198 #include <time.h>
 199 #include <inttypes.h>
 200 typedef uint64_t usec_t;
 201 usec_t now(clockid_t clock);
 202 int main(void) {
 203         struct timespec now;
 204         return 0;
 205 }
 206 ])
 207
 208 AS_CASE([$CC], [*clang*],
 209         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 210                -Wno-typedef-redefinition \
 211                -Wno-gnu-variable-sized-type-not-at-end \
 212         ])])
 213
 214 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 215         [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 216                -flto])],
 217         [AC_MSG_RESULT([skipping -flto, optimization not enabled])])
 218 AC_SUBST([OUR_CFLAGS], "$with_cflags $sanitizer_cflags")
 219
 220 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 221         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 222                -Wp,-D_FORTIFY_SOURCE=2])],
 223         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 224 AC_SUBST([OUR_CPPFLAGS], "$with_cppflags $sanitizer_cppflags")
 225
 226 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 227         [CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 228                -Wl,--gc-sections])],
 229         [AC_MSG_RESULT([skipping --gc-sections, optimization not enabled])])
 230 AC_SUBST([OUR_CFLAGS], "$with_ldflags $sanitizer_cflags")
 231
 232 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 233         [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 234                -ffunction-sections -fdata-sections])],
 235         [AC_MSG_RESULT([skipping -ffunction/data-section, optimization not enabled])])
 236 AC_SUBST([OUR_CFLAGS], "$with_cflags $sanitizer_cflags")
 237
 238 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 239         -Wl,--as-needed \
 240         -Wl,--no-undefined \
 241         -Wl,-z,relro \
 242         -Wl,-z,now \
 243         -pie \
 244         -Wl,-fuse-ld=gold])
 245 AC_SUBST([OUR_LDFLAGS], "$with_ldflags $sanitizer_ldflags")
 246
 247 AC_CHECK_SIZEOF(pid_t)
 248 AC_CHECK_SIZEOF(uid_t)
 249 AC_CHECK_SIZEOF(gid_t)
 250 AC_CHECK_SIZEOF(time_t)
 251 AC_CHECK_SIZEOF(dev_t)
 252 AC_CHECK_SIZEOF(rlim_t,,[
 253        #include <sys/time.h>
 254        #include <sys/resource.h>
 255 ])
 256
 257 # ------------------------------------------------------------------------------
 258 # we use python to build the man page index
 259 have_python=no
 260 AC_ARG_WITH([python],
 261         [AS_HELP_STRING([--without-python], [Disable building the man page index and systemd-python (default: test)])])
 262
 263 have_lxml=no
 264 AS_IF([test "x$with_python" != "xno"], [
 265         AM_PATH_PYTHON(,, [:])
 266         AS_IF([test "x$PYTHON" != "x:"], [
 267                 AC_MSG_CHECKING([for python lxml module])
 268                 AS_IF(["$PYTHON" -c 'import lxml' 2>/dev/null], [have_lxml=yes])
 269                 AC_MSG_RESULT([$have_lxml])
 270                 AS_IF([test "x$have_lxml" = "xyes"], [have_python=yes],
 271                       [AC_MSG_WARN([*** python support requires python-lxml module installed])])
 272         ])
 273 ])
 274 AS_IF([test "$have_python" != "yes"], [
 275       AS_IF([test "$with_python" = "yes"],
 276             [AC_MSG_ERROR([*** python support requested but python support not found])])
 277       AS_IF([test "$with_python" != "no"],
 278             [AC_MSG_WARN([*** python support not found, some documentation cannot be built])])
 279 ])
 280 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
 281
 282 # ------------------------------------------------------------------------------
 283
 284 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 285 AC_CHECK_HEADERS([linux/btrfs.h], [], [])
 286 AC_CHECK_HEADERS([linux/memfd.h], [], [])
 287
 288 # unconditionally pull-in librt with old glibc versions
 289 AC_SEARCH_LIBS([clock_gettime], [rt], [], [])
 290
 291 save_LIBS="$LIBS"
 292 LIBS=
 293 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 294 CAP_LIBS="$LIBS"
 295 LIBS="$save_LIBS"
 296 AC_SUBST(CAP_LIBS)
 297
 298 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 299 AC_CHECK_DECLS([
 300         memfd_create,
 301         gettid,
 302         pivot_root,
 303         name_to_handle_at,
 304         setns,
 305         getrandom,
 306         renameat2,
 307         kcmp,
 308         keyctl,
 309         LO_FLAGS_PARTSCAN,
 310         copy_file_range],
 311         [], [], [[
 312 #include <sys/types.h>
 313 #include <unistd.h>
 314 #include <sys/mount.h>
 315 #include <fcntl.h>
 316 #include <sched.h>
 317 #include <linux/loop.h>
 318 #include <linux/random.h>
 319 ]])
 320
 321 AC_CHECK_TYPES([char16_t, char32_t, key_serial_t],
 322                [], [], [[
 323 #include <uchar.h>
 324 ]])
 325
 326 AC_CHECK_DECLS([IFLA_INET6_ADDR_GEN_MODE,
 327                 IFLA_MACVLAN_FLAGS,
 328                 IFLA_IPVLAN_MODE,
 329                 IFLA_VTI_REMOTE,
 330                 IFLA_PHYS_PORT_ID,
 331                 IFLA_BOND_AD_INFO,
 332                 IFLA_VLAN_PROTOCOL,
 333                 IFLA_VXLAN_REMCSUM_NOPARTIAL,
 334                 IFLA_IPTUN_ENCAP_DPORT,
 335                 IFLA_GRE_ENCAP_DPORT,
 336                 IFLA_BRIDGE_VLAN_INFO,
 337                 IFLA_BRPORT_PROXYARP,
 338                 IFLA_BRPORT_LEARNING_SYNC,
 339                 IFLA_BR_VLAN_DEFAULT_PVID,
 340                 NDA_IFINDEX,
 341                 IFA_FLAGS],
 342 [], [], [[
 343 #include <inttypes.h>
 344 #include <netinet/in.h>
 345 #include <netinet/ether.h>
 346 #include <linux/rtnetlink.h>
 347 #include <net/if.h>
 348 #include <linux/ip.h>
 349 #include <linux/if_tunnel.h>
 350 #include <linux/if_link.h>
 351 #include <linux/if_bridge.h>
 352 #include <linux/if_addr.h>
 353 #include <linux/neighbour.h>
 354 ]])
 355
 356 # This makes sure pkg.m4 is available.
 357 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 358
 359 # ------------------------------------------------------------------------------
 360 have_dbus=no
 361 AC_ARG_ENABLE(dbus, AS_HELP_STRING([--disable-dbus], [disable usage of dbus-1 in tests]))
 362 AS_IF([test "x$enable_dbus" != "xno"], [
 363         PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2],
 364                 [AC_DEFINE(HAVE_DBUS, 1, [Define if dbus-1 library is available]) have_dbus=yes],
 365                 [have_dbus=no])
 366         AS_IF([test "x$have_dbus" = "xno" -a "x$enable_dbus" = "xyes"],
 367                 [AC_MSG_ERROR([*** dbus-1 support requested but libraries not found])])])
 368 AM_CONDITIONAL(HAVE_DBUS, [test "$have_dbus" = "yes"])
 369
 370 # ------------------------------------------------------------------------------
 371 have_utmp=yes
 372 AC_ARG_ENABLE([utmp], AS_HELP_STRING([--disable-utmp], [disable utmp/wtmp log handling]),
 373         AS_CASE("x${enableval}",
 374                 [xyes], [have_utmp=yes],
 375                 [xno],  [have_utmp=no],
 376                 AC_MSG_ERROR(bad value ${enableval} for --enable-utmp)))
 377 AS_IF([test "x$have_utmp" = "xyes"], [AC_DEFINE(HAVE_UTMP, 1, [Define if utmp/wtmp support is enabled])])
 378 AM_CONDITIONAL([HAVE_UTMP], [test "x$have_utmp" = "xyes"])
 379
 380 # ------------------------------------------------------------------------------
 381 have_coverage=no
 382 AC_ARG_ENABLE(coverage, AS_HELP_STRING([--enable-coverage], [enable test coverage]))
 383 if test "x$enable_coverage" = "xyes" ; then
 384         AC_CHECK_PROG(lcov_found, [lcov], [yes], [no])
 385         if test "x$lcov_found" = xno ; then
 386                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
 387         else
 388                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
 389                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
 390                 if test "$lcov_version_major" -eq 1 -a "$lcov_version_minor" -lt 10; then
 391                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
 392                 else
 393                         have_coverage=yes
 394                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
 395                         -fprofile-arcs \
 396                         -ftest-coverage])
 397                         AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
 398                 fi
 399         fi
 400 fi
 401 AM_CONDITIONAL(ENABLE_COVERAGE, [test "$have_coverage" = "yes"])
 402
 403 # ------------------------------------------------------------------------------
 404 have_kmod=no
 405 AC_ARG_ENABLE(kmod, AS_HELP_STRING([--disable-kmod], [disable loadable modules support]))
 406 if test "x$enable_kmod" != "xno"; then
 407         PKG_CHECK_EXISTS([ libkmod ], have_kmod=yes, have_kmod=no)
 408         if test "x$have_kmod" = "xyes"; then
 409                 PKG_CHECK_MODULES(KMOD, [ libkmod >= 15 ],
 410                         [AC_DEFINE(HAVE_KMOD, 1, [Define if kmod is available])],
 411                         AC_MSG_ERROR([*** kmod version >= 15 not found]))
 412         fi
 413         if test "x$have_kmod" = xno -a "x$enable_kmod" = xyes; then
 414                 AC_MSG_ERROR([*** kmod support requested, but libraries not found])
 415         fi
 416 fi
 417 AM_CONDITIONAL(HAVE_KMOD, [test "$have_kmod" = "yes"])
 418
 419 # ------------------------------------------------------------------------------
 420 have_xkbcommon=no
 421 AC_ARG_ENABLE(xkbcommon, AS_HELP_STRING([--disable-xkbcommon], [disable xkbcommon keymap support]))
 422 if test "x$enable_xkbcommon" != "xno"; then
 423         PKG_CHECK_MODULES(XKBCOMMON, [ xkbcommon >= 0.3.0 ],
 424                 [AC_DEFINE(HAVE_XKBCOMMON, 1, [Define if libxkbcommon is available]) have_xkbcommon=yes], have_xkbcommon=no)
 425         if test "x$have_xkbcommon" = xno -a "x$enable_xkbcommon" = xyes; then
 426                 AC_MSG_ERROR([*** xkbcommon support requested but libraries not found])
 427         fi
 428 fi
 429 AM_CONDITIONAL(HAVE_XKBCOMMON, [test "$have_xkbcommon" = "yes"])
 430
 431 # ------------------------------------------------------------------------------
 432 have_blkid=no
 433 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 434 if test "x$enable_blkid" != "xno"; then
 435         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.24 ],
 436                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 437         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 438                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 439         fi
 440 fi
 441 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 442
 443 # ------------------------------------------------------------------------------
 444 have_libmount=no
 445 PKG_CHECK_MODULES(MOUNT, [ mount >= 2.27 ],
 446         [AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount is available]) have_libmount=yes], have_libmount=no)
 447 if test "x$have_libmount" = xno; then
 448         AC_MSG_ERROR([*** libmount support required but libraries not found])
 449 fi
 450 AM_CONDITIONAL(HAVE_LIBMOUNT, [test "$have_libmount" = "yes"])
 451
 452 # ------------------------------------------------------------------------------
 453 have_seccomp=no
 454 AC_ARG_ENABLE(seccomp, AS_HELP_STRING([--disable-seccomp], [Disable optional SECCOMP support]))
 455 if test "x$enable_seccomp" != "xno"; then
 456         PKG_CHECK_MODULES(SECCOMP, [libseccomp >= 1.0.0],
 457                [AC_DEFINE(HAVE_SECCOMP, 1, [Define if seccomp is available])
 458                 have_seccomp=yes
 459                 M4_DEFINES="$M4_DEFINES -DHAVE_SECCOMP"],
 460                [have_seccomp=no])
 461         if test "x$have_seccomp" = "xno" -a "x$enable_seccomp" = "xyes"; then
 462                 AC_MSG_ERROR([*** seccomp support requested but libraries not found])
 463         fi
 464 fi
 465 AM_CONDITIONAL(HAVE_SECCOMP, [test "$have_seccomp" = "yes"])
 466
 467 # ------------------------------------------------------------------------------
 468 have_ima=yes
 469 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
 470                 [case "${enableval}" in
 471                         yes) have_ima=yes ;;
 472                         no) have_ima=no ;;
 473                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 474                 esac],
 475                 [have_ima=yes])
 476
 477 if test "x${have_ima}" != xno ; then
 478         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 479 fi
 480
 481 # ------------------------------------------------------------------------------
 482 have_selinux=no
 483 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 484 if test "x$enable_selinux" != "xno"; then
 485         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 486                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available])
 487                  have_selinux=yes
 488                  M4_DEFINES="$M4_DEFINES -DHAVE_SELINUX"],
 489                 [have_selinux=no])
 490         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 491                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 492         fi
 493 fi
 494 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 495
 496 have_apparmor=no
 497 AC_ARG_ENABLE(apparmor, AS_HELP_STRING([--disable-apparmor], [Disable optional AppArmor support]))
 498 if test "x$enable_apparmor" != "xno"; then
 499         PKG_CHECK_MODULES([APPARMOR], [libapparmor],
 500                 [AC_DEFINE(HAVE_APPARMOR, 1, [Define if AppArmor is available])
 501                  have_apparmor=yes
 502                  M4_DEFINES="$M4_DEFINES -DHAVE_APPARMOR"],
 503                 [have_apparmor=no])
 504         if test "x$have_apparmor" = xno -a "x$enable_apparmor" = xyes; then
 505                 AC_MSG_ERROR([*** AppArmor support requested but libraries not found])
 506         fi
 507 fi
 508 AM_CONDITIONAL(HAVE_APPARMOR, [test "$have_apparmor" = "yes"])
 509
 510 have_adm_group=no
 511 AC_ARG_ENABLE(adm-group, AS_HELP_STRING([--disable-adm-group], [disable adm group]))
 512 AS_IF([test "x$enable_adm_group" != "xno"], [
 513         AC_DEFINE(ENABLE_ADM_GROUP, 1, [Define if the ACL for adm group should be enabled])
 514         have_adm_group=yes
 515         M4_DEFINES="$M4_DEFINES -DENABLE_ADM_GROUP"
 516 ])
 517
 518 have_wheel_group=no
 519 AC_ARG_ENABLE(wheel-group, AS_HELP_STRING([--disable-wheel-group], [disable wheel group]))
 520 AS_IF([test "x$enable_wheel_group" != "xno"], [
 521         AC_DEFINE(ENABLE_WHEEL_GROUP, 1, [Define if the ACL for wheel group should be enabled])
 522         have_wheel_group=yes
 523         M4_DEFINES="$M4_DEFINES -DENABLE_WHEEL_GROUP"
 524 ])
 525
 526
 527 AC_ARG_WITH(debug-shell,
 528         AS_HELP_STRING([--with-debug-shell=PATH],
 529                 [Path to debug shell binary]),
 530         [SUSHELL="$withval"],[
 531         AS_IF([test "x${have_selinux}" != "xno"], [SUSHELL="/sbin/sushell"] , [SUSHELL="/bin/sh"])])
 532
 533 AC_SUBST(SUSHELL)
 534
 535 AC_ARG_WITH([debug-tty],
 536         AS_HELP_STRING([--with-debug-tty=PATH],
 537                 [Specify the tty device for debug shell]),
 538         [DEBUGTTY="$withval"],
 539         [DEBUGTTY=/dev/tty9])
 540
 541 AC_SUBST(DEBUGTTY)
 542
 543 AC_ARG_WITH([certificate-root],
 544         AS_HELP_STRING([--with-certificate-root=PATH],
 545                 [Specify the prefix for TLS certificates [/etc/ssl]]),
 546         [CERTIFICATEROOT="$withval"],
 547         [CERTIFICATEROOT="/etc/ssl"])
 548
 549 AC_SUBST(CERTIFICATEROOT)
 550
 551 # ------------------------------------------------------------------------------
 552 have_xz=no
 553 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
 554 AS_IF([test "x$enable_xz" != "xno"], [
 555         PKG_CHECK_MODULES(XZ, [ liblzma ],
 556                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available])
 557                  have_xz=yes],
 558                  have_xz=no)
 559         AS_IF([test "x$have_xz" = xno -a "x$enable_xz" = xyes],
 560               [AC_MSG_ERROR([*** XZ support requested but libraries not found])])
 561 ])
 562 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 563
 564 # ------------------------------------------------------------------------------
 565 have_zlib=no
 566 AC_ARG_ENABLE(zlib, AS_HELP_STRING([--disable-zlib], [Disable optional ZLIB support]))
 567 AS_IF([test "x$enable_zlib" != "xno"], [
 568         PKG_CHECK_MODULES(ZLIB, [ zlib ],
 569                 [AC_DEFINE(HAVE_ZLIB, 1, [Define if ZLIB is available])
 570                  have_zlib=yes],
 571                  have_zlib=no)
 572         AS_IF([test "x$have_zlib" = xno -a "x$enable_zlib" = xyes],
 573               [AC_MSG_ERROR([*** ZLIB support requested but libraries not found])])
 574 ])
 575 AM_CONDITIONAL(HAVE_ZLIB, [test "$have_zlib" = "yes"])
 576
 577 # ------------------------------------------------------------------------------
 578 have_bzip2=no
 579 AC_ARG_ENABLE(bzip2, AS_HELP_STRING([--enable-bzip2], [Enable optional BZIP2 support]))
 580 AS_IF([test "x$enable_bzip2" != "xno"], [
 581         AC_CHECK_HEADERS(bzlib.h,
 582                 [AC_DEFINE(HAVE_BZIP2, 1, [Define if BZIP2 is available])
 583                  have_bzip2=yes],
 584                 [AS_IF([test "x$enable_bzip2" = xyes],
 585                        [AC_MSG_ERROR([*** BZIP2 support requested but headers not found])])]
 586         )
 587 ])
 588 AM_CONDITIONAL(HAVE_BZIP2, [test "$have_bzip2" = "yes"])
 589
 590 # ------------------------------------------------------------------------------
 591 have_lz4=no
 592 AC_ARG_ENABLE(lz4, AS_HELP_STRING([--disable-lz4], [Disable optional LZ4 support]))
 593 AS_IF([test "x$enable_lz4" != "xno"], [
 594         PKG_CHECK_MODULES(LZ4, [ liblz4 >= 125 ],
 595                [AC_DEFINE(HAVE_LZ4, 1, [Define in LZ4 is available])
 596                 have_lz4=yes],
 597                 have_lz4=no)
 598         AS_IF([test "x$have_lz4" = xno -a "x$enable_lz4" = xyes],
 599               [AC_MSG_ERROR([*** LZ4 support requested but libraries not found])])
 600 ])
 601 AM_CONDITIONAL(HAVE_LZ4, [test "$have_lz4" = "yes"])
 602
 603 AM_CONDITIONAL(HAVE_COMPRESSION, [test "$have_xz" = "yes" -o "$have_lz4" = "yes"])
 604
 605 # ------------------------------------------------------------------------------
 606 AC_ARG_ENABLE([pam],
 607         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 608                 [case "${enableval}" in
 609                         yes) have_pam=yes ;;
 610                         no) have_pam=no ;;
 611                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 612                 esac],
 613                 [have_pam=auto])
 614
 615 if test "x${have_pam}" != xno ; then
 616         AC_CHECK_HEADERS(
 617                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 618                 [have_pam=yes],
 619                 [if test "x$have_pam" = xyes ; then
 620                         AC_MSG_ERROR([*** PAM headers not found.])
 621                 fi])
 622
 623         AC_CHECK_LIB(
 624                 [pam],
 625                 [pam_syslog],
 626                 [have_pam=yes],
 627                 [if test "x$have_pam" = xyes ; then
 628                         AC_MSG_ERROR([*** libpam not found.])
 629                 fi])
 630
 631         if test "x$have_pam" = xyes ; then
 632                 PAM_LIBS="-lpam -lpam_misc"
 633                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 634                 M4_DEFINES="$M4_DEFINES -DHAVE_PAM"
 635         else
 636                 have_pam=no
 637         fi
 638 else
 639         PAM_LIBS=
 640 fi
 641 AC_SUBST(PAM_LIBS)
 642 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 643
 644 # ------------------------------------------------------------------------------
 645 AC_ARG_ENABLE([acl],
 646         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 647                 [case "${enableval}" in
 648                         yes) have_acl=yes ;;
 649                         no) have_acl=no ;;
 650                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 651                 esac],
 652                 [have_acl=auto])
 653
 654 if test "x${have_acl}" != xno ; then
 655         AC_CHECK_HEADERS(
 656                 [sys/acl.h acl/libacl.h],
 657                 [have_acl=yes],
 658                 [if test "x$have_acl" = xyes ; then
 659                         AC_MSG_ERROR([*** ACL headers not found.])
 660                 fi])
 661
 662         AC_CHECK_LIB(
 663                 [acl],
 664                 [acl_get_file],
 665                 [have_acl=yes],
 666                 [if test "x$have_acl" = xyes ; then
 667                         AC_MSG_ERROR([*** libacl not found.])
 668                 fi])
 669
 670         if test "x$have_acl" = xyes ; then
 671                 ACL_LIBS="-lacl"
 672                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 673                 M4_DEFINES="$M4_DEFINES -DHAVE_ACL"
 674         else
 675                 have_acl=no
 676         fi
 677 else
 678         ACL_LIBS=
 679 fi
 680 AC_SUBST(ACL_LIBS)
 681 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 682
 683 # ------------------------------------------------------------------------------
 684 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack],[Disable optional SMACK support]),
 685                 [case "${enableval}" in
 686                         yes) have_smack=yes ;;
 687                         no) have_smack=no ;;
 688                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
 689                 esac],
 690                 [have_smack=auto])
 691
 692 if test "x${have_smack}" != xno; then
 693         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
 694         M4_DEFINES="$M4_DEFINES -DHAVE_SMACK"
 695         have_smack=yes
 696 fi
 697
 698 AM_CONDITIONAL([HAVE_SMACK], [test "x$have_smack" = "xyes"])
 699
 700 have_smack_run_label=no
 701 AC_ARG_WITH(smack-run-label,
 702 AS_HELP_STRING([--with-smack-run-label=STRING],
 703         [run systemd --system itself with a specific SMACK label]),
 704         [AC_DEFINE_UNQUOTED(SMACK_RUN_LABEL, ["$withval"], [Run systemd itself with SMACK label]) have_smack_run_label=yes],
 705         [])
 706
 707 if test "x${have_smack_run_label}" = xyes; then
 708         M4_DEFINES="$M4_DEFINES -DHAVE_SMACK_RUN_LABEL"
 709 fi
 710
 711 AC_ARG_WITH(smack-default-process-label,
 712 AS_HELP_STRING([--with-smack-default-process-label=STRING],
 713         [default SMACK label for executed processes]),
 714         [AC_DEFINE_UNQUOTED(SMACK_DEFAULT_PROCESS_LABEL, ["$withval"], [Default SMACK label for executed processes])],
 715         [])
 716
 717 # ------------------------------------------------------------------------------
 718 AC_ARG_ENABLE([gcrypt],
 719         AS_HELP_STRING([--disable-gcrypt],[Disable optional GCRYPT support]),
 720                 [case "${enableval}" in
 721                         yes) have_gcrypt=yes ;;
 722                         no) have_gcrypt=no ;;
 723                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
 724                 esac],
 725                 [have_gcrypt=auto])
 726
 727 if test "x${have_gcrypt}" != xno ; then
 728         m4_define([AM_PATH_LIBGCRYPT_FAIL],
 729                 [{ test "x$have_gcrypt" != xyes || AC_MSG_ERROR([*** GCRYPT/GPG-ERROR headers not found.]); }]
 730         )
 731         m4_ifdef([AM_PATH_LIBGCRYPT], [AM_PATH_LIBGCRYPT(
 732                         [1.4.5],
 733                         [have_gcrypt=yes],
 734                         dnl  If we have the gcrypt m4 macros, but don't have
 735                         dnl  gcrypt, throw an error if gcrypt is explicitly
 736                         dnl  requested.
 737                         [AM_PATH_LIBGCRYPT_FAIL]
 738                 )],
 739                 dnl  If we don't have the gcrypt m4 macros, but build with
 740                 dnl  gcrypt explicitly requested, throw an error.
 741                 [AM_PATH_LIBGCRYPT_FAIL]
 742         )
 743
 744         have_gpg_error=no
 745         m4_ifdef([AM_PATH_GPG_ERROR], [AM_PATH_GPG_ERROR(
 746                         [1.12],
 747                         [have_gpg_error=yes],
 748                         [AM_PATH_LIBGCRYPT_FAIL]
 749                 )],
 750                 [AM_PATH_LIBGCRYPT_FAIL]
 751         )
 752
 753         if test "x$have_gcrypt" = xyes -a "x$have_gpg_error" = xyes ; then
 754                 GCRYPT_LIBS="$LIBGCRYPT_LIBS $GPG_ERROR_LIBS"
 755                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS $GPG_ERROR_CFLAGS"
 756                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
 757         else
 758                 have_gcrypt=no
 759                 have_gpg_error=no
 760         fi
 761 else
 762         GCRYPT_LIBS=
 763         GCRYPT_CFLAGS=
 764 fi
 765 AC_SUBST(GCRYPT_LIBS)
 766 AC_SUBST(GCRYPT_CFLAGS)
 767 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
 768
 769 # ------------------------------------------------------------------------------
 770 AC_ARG_ENABLE([audit],
 771         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 772                 [case "${enableval}" in
 773                         yes) have_audit=yes ;;
 774                         no) have_audit=no ;;
 775                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 776                 esac],
 777                 [have_audit=auto])
 778
 779 if test "x${have_audit}" != xno ; then
 780         AC_CHECK_HEADERS(
 781                 [libaudit.h],
 782                 [have_audit=yes],
 783                 [if test "x$have_audit" = xyes ; then
 784                         AC_MSG_ERROR([*** AUDIT headers not found.])
 785                 fi])
 786
 787         AC_CHECK_LIB(
 788                 [audit],
 789                 [audit_open],
 790                 [have_audit=yes],
 791                 [if test "x$have_audit" = xyes ; then
 792                         AC_MSG_ERROR([*** libaudit not found.])
 793                 fi])
 794
 795         if test "x$have_audit" = xyes ; then
 796                 AUDIT_LIBS="-laudit"
 797                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 798         else
 799                 have_audit=no
 800         fi
 801 else
 802         AUDIT_LIBS=
 803 fi
 804 AC_SUBST(AUDIT_LIBS)
 805 AM_CONDITIONAL([HAVE_AUDIT], [test "x$have_audit" != xno])
 806
 807 # ------------------------------------------------------------------------------
 808 AC_ARG_ENABLE([elfutils],
 809         AS_HELP_STRING([--disable-elfutils],[Disable optional ELFUTILS support]),
 810                 [case "${enableval}" in
 811                         yes) have_elfutils=yes ;;
 812                         no) have_elfutils=no ;;
 813                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-elfutils) ;;
 814                 esac],
 815                 [have_elfutils=auto])
 816
 817 if test "x${have_elfutils}" != xno ; then
 818         AC_CHECK_HEADERS(
 819                 [elfutils/libdwfl.h],
 820                 [],
 821                 [if test "x$have_elfutils" = xyes ; then
 822                         AC_MSG_ERROR([*** ELFUTILS headers not found.])
 823                 fi])
 824
 825         AC_CHECK_LIB(
 826                 [dw],
 827                 [dwfl_core_file_attach],
 828                 [have_elfutils=yes],
 829                 [if test "x$have_elfutils" = xyes ; then
 830                         AC_MSG_ERROR([*** ELFUTILS >= 158 is required.])
 831                 fi])
 832
 833         if test "x$have_elfutils" = xyes ; then
 834                 ELFUTILS_LIBS="-lelf -ldw"
 835                 AC_DEFINE(HAVE_ELFUTILS, 1, [ELFUTILS available])
 836         else
 837                 have_elfutils=no
 838         fi
 839 else
 840         ELFUTILS_LIBS=
 841 fi
 842 AC_SUBST(ELFUTILS_LIBS)
 843 AM_CONDITIONAL(HAVE_ELFUTILS, [test "$have_elfutils" = "yes"])
 844
 845 # ------------------------------------------------------------------------------
 846 have_libcryptsetup=no
 847 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 848 if test "x$enable_libcryptsetup" != "xno"; then
 849         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.6.0 ],
 850                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 851         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 852                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 853         fi
 854 fi
 855 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 856
 857 # ------------------------------------------------------------------------------
 858 have_qrencode=no
 859 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
 860 if test "x$enable_qrencode" != "xno"; then
 861         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
 862                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
 863         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
 864                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
 865         fi
 866 fi
 867 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
 868
 869 # ------------------------------------------------------------------------------
 870 have_gnutls=no
 871 AC_ARG_ENABLE(gnutls, AS_HELP_STRING([--disable-gnutls], [disable gnutls support]))
 872 if test "x$enable_gnutls" != "xno"; then
 873         PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.1.4],
 874                 [AC_DEFINE(HAVE_GNUTLS, 1, [Define if gnutls is available]) have_gnutls=yes], have_gnutls=no)
 875         if test "x$have_gnutls" = xno -a "x$enable_gnutls" = xyes; then
 876                 AC_MSG_ERROR([*** gnutls support requested but libraries not found])
 877         fi
 878 fi
 879 AM_CONDITIONAL(HAVE_GNUTLS, [test "$have_gnutls" = "yes"])
 880
 881 # ------------------------------------------------------------------------------
 882 have_microhttpd=no
 883 AC_ARG_ENABLE(microhttpd, AS_HELP_STRING([--disable-microhttpd], [disable microhttpd support]))
 884 if test "x$enable_microhttpd" != "xno"; then
 885         PKG_CHECK_MODULES(MICROHTTPD, [libmicrohttpd >= 0.9.33],
 886                 [AC_DEFINE(HAVE_MICROHTTPD, 1, [Define if microhttpd is available])
 887                  have_microhttpd=yes
 888                  M4_DEFINES="$M4_DEFINES -DHAVE_MICROHTTPD"],
 889                 [have_microhttpd=no])
 890         if test "x$have_microhttpd" = xno -a "x$enable_microhttpd" = xyes; then
 891                 AC_MSG_ERROR([*** microhttpd support requested but libraries not found])
 892         fi
 893 fi
 894 AM_CONDITIONAL(HAVE_MICROHTTPD, [test "$have_microhttpd" = "yes"])
 895
 896 # ------------------------------------------------------------------------------
 897 have_libcurl=no
 898 AC_ARG_ENABLE(libcurl, AS_HELP_STRING([--disable-libcurl], [disable libcurl support]))
 899 if test "x$enable_libcurl" != "xno"; then
 900         PKG_CHECK_MODULES(LIBCURL, [libcurl >= 7.32.0],
 901                 [AC_DEFINE(HAVE_LIBCURL, 1, [Define if libcurl is available])
 902                  have_libcurl=yes
 903                  M4_DEFINES="$M4_DEFINES -DHAVE_LIBCURL"],
 904                 [have_libcurl=no])
 905         if test "x$have_libcurl" = xno -a "x$enable_libcurl" = xyes; then
 906                 AC_MSG_ERROR([*** libcurl support requested but libraries not found])
 907         fi
 908 fi
 909 AM_CONDITIONAL(HAVE_LIBCURL, [test "$have_libcurl" = "yes"])
 910
 911 # ------------------------------------------------------------------------------
 912 AM_CONDITIONAL(HAVE_REMOTE, [test "$have_microhttpd" = "yes" -o "$have_libcurl" = "yes"])
 913
 914 # ------------------------------------------------------------------------------
 915 have_libidn=no
 916 AC_ARG_ENABLE(libidn, AS_HELP_STRING([--disable-libidn], [Disable optional LIBIDN support]))
 917 if test "x$enable_libidn" != "xno"; then
 918         PKG_CHECK_MODULES(LIBIDN, [libidn],
 919                [AC_DEFINE(HAVE_LIBIDN, 1, [Define if libidn is available])
 920                 have_libidn=yes
 921                 M4_DEFINES="$M4_DEFINES -DHAVE_LIBIDN"],
 922                [have_libidn=no])
 923         if test "x$have_libidn" = "xno" -a "x$enable_libidn" = "xyes"; then
 924                 AC_MSG_ERROR([*** libidn support requested but libraries not found])
 925         fi
 926 fi
 927 AM_CONDITIONAL(HAVE_LIBIDN, [test "$have_libidn" = "yes"])
 928
 929 # ------------------------------------------------------------------------------
 930 have_libiptc=no
 931 AC_ARG_ENABLE(libiptc, AS_HELP_STRING([--disable-libiptc], [Disable optional LIBIPTC support]))
 932 if test "x$enable_libiptc" != "xno"; then
 933         PKG_CHECK_MODULES(LIBIPTC, [libiptc],
 934                [AC_DEFINE(HAVE_LIBIPTC, 1, [Define if libiptc is available])
 935                 have_libiptc=yes
 936                 M4_DEFINES="$M4_DEFINES -DHAVE_LIBIPTC"],
 937                [have_libiptc=no])
 938         if test "x$have_libiptc" = "xno" -a "x$enable_libiptc" = "xyes"; then
 939                 AC_MSG_ERROR([*** libiptc support requested but libraries not found])
 940         fi
 941 fi
 942 AM_CONDITIONAL(HAVE_LIBIPTC, [test "$have_libiptc" = "yes"])
 943
 944 # ------------------------------------------------------------------------------
 945 have_binfmt=no
 946 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 947 if test "x$enable_binfmt" != "xno"; then
 948         have_binfmt=yes
 949 fi
 950 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 951
 952 # ------------------------------------------------------------------------------
 953 have_vconsole=no
 954 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
 955 if test "x$enable_vconsole" != "xno"; then
 956         have_vconsole=yes
 957 fi
 958 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
 959
 960 # ------------------------------------------------------------------------------
 961 have_quotacheck=no
 962 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
 963 if test "x$enable_quotacheck" != "xno"; then
 964         have_quotacheck=yes
 965 fi
 966 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
 967
 968 # ------------------------------------------------------------------------------
 969 have_tmpfiles=no
 970 AC_ARG_ENABLE(tmpfiles, AS_HELP_STRING([--disable-tmpfiles], [disable tmpfiles support]))
 971 if test "x$enable_tmpfiles" != "xno"; then
 972         have_tmpfiles=yes
 973 fi
 974 AM_CONDITIONAL(ENABLE_TMPFILES, [test "$have_tmpfiles" = "yes"])
 975
 976 # ------------------------------------------------------------------------------
 977 have_sysusers=no
 978 AC_ARG_ENABLE(sysusers, AS_HELP_STRING([--disable-sysusers], [disable sysusers support]))
 979 if test "x$enable_sysusers" != "xno"; then
 980         have_sysusers=yes
 981 fi
 982 AM_CONDITIONAL(ENABLE_SYSUSERS, [test "$have_sysusers" = "yes"])
 983
 984 # ------------------------------------------------------------------------------
 985 have_firstboot=no
 986 AC_ARG_ENABLE(firstboot, AS_HELP_STRING([--disable-firstboot], [disable firstboot support]))
 987 if test "x$enable_firstboot" != "xno"; then
 988         have_firstboot=yes
 989 fi
 990 AM_CONDITIONAL(ENABLE_FIRSTBOOT, [test "$have_firstboot" = "yes"])
 991
 992 # ------------------------------------------------------------------------------
 993 have_randomseed=no
 994 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
 995 if test "x$enable_randomseed" != "xno"; then
 996         have_randomseed=yes
 997 fi
 998 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
 999
1000 # ------------------------------------------------------------------------------
1001 have_backlight=no
1002 AC_ARG_ENABLE(backlight, AS_HELP_STRING([--disable-backlight], [disable backlight tools]))
1003 if test "x$enable_backlight" != "xno"; then
1004         have_backlight=yes
1005 fi
1006 AM_CONDITIONAL(ENABLE_BACKLIGHT, [test "$have_backlight" = "yes"])
1007
1008 # ------------------------------------------------------------------------------
1009 have_rfkill=no
1010 AC_ARG_ENABLE(rfkill, AS_HELP_STRING([--disable-rfkill], [disable rfkill tools]))
1011 if test "x$enable_rfkill" != "xno"; then
1012         have_rfkill=yes
1013 fi
1014 AM_CONDITIONAL(ENABLE_RFKILL, [test "$have_rfkill" = "yes"])
1015
1016 # ------------------------------------------------------------------------------
1017 have_logind=no
1018 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
1019 if test "x$enable_logind" != "xno"; then
1020         have_logind=yes
1021 fi
1022 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
1023 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
1024
1025 AC_ARG_WITH([kill-user-processes],
1026         [AS_HELP_STRING([--without-kill-user-processes], [Set logind's KillUserProcesses=no by default])])
1027 AS_IF([test "$with_kill_user_processes" != "no"],
1028        [kill_user_processes=true
1029         KILL_USER_PROCESSES=yes],
1030        [kill_user_processes=false
1031         KILL_USER_PROCESSES=no])
1032 AC_DEFINE_UNQUOTED(KILL_USER_PROCESSES, [$kill_user_processes], [Default KillUserProcesses setting])
1033 AC_SUBST(KILL_USER_PROCESSES)
1034
1035 # ------------------------------------------------------------------------------
1036 have_machined=no
1037 AC_ARG_ENABLE(machined, AS_HELP_STRING([--disable-machined], [disable machine daemon]))
1038 if test "x$enable_machined" != "xno"; then
1039         have_machined=yes
1040         AC_DEFINE(HAVE_MACHINED, [1], [systemd-machined is enabled])
1041 fi
1042 AM_CONDITIONAL(ENABLE_MACHINED, [test "$have_machined" = "yes"])
1043
1044 # ------------------------------------------------------------------------------
1045 have_importd=no
1046 AC_ARG_ENABLE(importd, AS_HELP_STRING([--disable-importd], [disable import daemon]))
1047 if test "x$enable_importd" != "xno"; then
1048         have_importd=yes
1049 fi
1050 AM_CONDITIONAL(ENABLE_IMPORTD, [test "$have_importd" = "yes"])
1051 AS_IF([test "$have_importd" = "yes"], [ AC_DEFINE(HAVE_IMPORTD, [1], [Importd support available]) ])
1052
1053 # ------------------------------------------------------------------------------
1054 have_hostnamed=no
1055 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
1056 if test "x$enable_hostnamed" != "xno"; then
1057         have_hostnamed=yes
1058 fi
1059 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
1060
1061 # ------------------------------------------------------------------------------
1062 have_timedated=no
1063 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
1064 if test "x$enable_timedated" != "xno"; then
1065         have_timedated=yes
1066 fi
1067 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
1068
1069 # ------------------------------------------------------------------------------
1070 have_timesyncd=no
1071 AC_ARG_ENABLE(timesyncd, AS_HELP_STRING([--disable-timesyncd], [disable timesync daemon]))
1072 if test "x$enable_timesyncd" != "xno"; then
1073         have_timesyncd=yes
1074         M4_DEFINES="$M4_DEFINES -DENABLE_TIMESYNCD"
1075 fi
1076 AM_CONDITIONAL(ENABLE_TIMESYNCD, [test "$have_timesyncd" = "yes"])
1077
1078 AC_ARG_WITH(ntp-servers,
1079         AS_HELP_STRING([--with-ntp-servers=NTPSERVERS],
1080                 [Space-separated list of default NTP servers]),
1081         [NTP_SERVERS="$withval"],
1082         [NTP_SERVERS="time1.google.com time2.google.com time3.google.com time4.google.com"
1083         AC_MSG_WARN([*** Using Google NTP servers.
1084                         Do not ship OSes or devices with these default settings.
1085                         See DISTRO_PORTING for details!])])
1086
1087 AC_DEFINE_UNQUOTED(NTP_SERVERS, ["$NTP_SERVERS"], [Default NTP Servers])
1088 AC_SUBST(NTP_SERVERS)
1089
1090 AC_ARG_WITH(time-epoch,
1091         AS_HELP_STRING([--with-time-epoch=SECONDS],
1092                 [Time epoch for time clients]),
1093         [TIME_EPOCH="$withval"],
1094         [TIME_EPOCH="`stat -c %Y ${srcdir}/NEWS 2>/dev/null || echo 0`"])
1095
1096 AC_DEFINE_UNQUOTED(TIME_EPOCH, [$TIME_EPOCH], [Time Epoch])
1097
1098 # ------------------------------------------------------------------------------
1099 AC_ARG_WITH(system-uid-max,
1100         AS_HELP_STRING([--with-system-uid-max=UID]
1101                 [Maximum UID for system users]),
1102         [SYSTEM_UID_MAX="$withval"],
1103         [SYSTEM_UID_MAX="`awk 'BEGIN { uid=999 } /^\s*SYS_UID_MAX\s+/ { uid=$2 } END { print uid }' /etc/login.defs 2>/dev/null || echo 999`"])
1104
1105 AC_DEFINE_UNQUOTED(SYSTEM_UID_MAX, [$SYSTEM_UID_MAX], [Maximum System UID])
1106 AC_SUBST(SYSTEM_UID_MAX)
1107
1108 # ------------------------------------------------------------------------------
1109 AC_ARG_WITH(system-gid-max,
1110         AS_HELP_STRING([--with-system-gid-max=GID]
1111                 [Maximum GID for system groups]),
1112         [SYSTEM_GID_MAX="$withval"],
1113         [SYSTEM_GID_MAX="`awk 'BEGIN { gid=999 } /^\s*SYS_GID_MAX\s+/ { gid=$2 } END { print gid }' /etc/login.defs 2>/dev/null || echo 999`"])
1114
1115 AC_DEFINE_UNQUOTED(SYSTEM_GID_MAX, [$SYSTEM_GID_MAX], [Maximum System GID])
1116 AC_SUBST(SYSTEM_GID_MAX)
1117
1118 # ------------------------------------------------------------------------------
1119 have_localed=no
1120 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
1121 if test "x$enable_localed" != "xno"; then
1122         have_localed=yes
1123 fi
1124 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
1125
1126 # ------------------------------------------------------------------------------
1127 have_coredump=no
1128 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
1129 if test "x$enable_coredump" != "xno"; then
1130         have_coredump=yes
1131         M4_DEFINES="$M4_DEFINES -DENABLE_COREDUMP"
1132 fi
1133 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
1134
1135 # ------------------------------------------------------------------------------
1136 have_polkit=no
1137 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
1138 if test "x$enable_polkit" != "xno"; then
1139         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
1140         have_polkit=yes
1141 fi
1142 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
1143
1144 # ------------------------------------------------------------------------------
1145 have_resolved=no
1146 AC_ARG_ENABLE(resolved, AS_HELP_STRING([--disable-resolved], [disable resolve daemon]))
1147 AS_IF([test "x$enable_resolved" != "xno"], [
1148         AC_CHECK_LIB([dl], [dlsym], [true], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
1149
1150         have_resolved=yes
1151         M4_DEFINES="$M4_DEFINES -DENABLE_RESOLVED"
1152         AC_DEFINE(HAVE_RESOLVED, [1], [systemd-resolved is enabled])
1153 ])
1154 AM_CONDITIONAL(ENABLE_RESOLVED, [test "$have_resolved" = "yes"])
1155
1156 AC_ARG_WITH(dns-servers,
1157         AS_HELP_STRING([--with-dns-servers=DNSSERVERS],
1158                 [Space-separated list of default DNS servers]),
1159         [DNS_SERVERS="$withval"],
1160         [DNS_SERVERS="8.8.8.8 8.8.4.4 2001:4860:4860::8888 2001:4860:4860::8844"])
1161
1162 AC_DEFINE_UNQUOTED(DNS_SERVERS, ["$DNS_SERVERS"], [Default DNS Servers])
1163 AC_SUBST(DNS_SERVERS)
1164
1165 AC_ARG_WITH(default-dnssec,
1166         AS_HELP_STRING([--with-default-dnssec=MODE],
1167                [Default DNSSEC mode, defaults to "allow-downgrade"]),
1168         [DEFAULT_DNSSEC_MODE="$withval"],
1169         [DEFAULT_DNSSEC_MODE="allow-downgrade"])
1170
1171 AS_CASE("x${DEFAULT_DNSSEC_MODE}",
1172         [xno], [mode=DNSSEC_NO],
1173         [xyes], [mode=DNSSEC_YES],
1174         [xallow-downgrade], [mode=DNSSEC_ALLOW_DOWNGRADE],
1175         AC_MSG_ERROR(Bad DNSSEC mode ${DEFAULT_DNSSEC_MODE}))
1176 AC_DEFINE_UNQUOTED(DEFAULT_DNSSEC_MODE, [$mode], [Default DNSSEC mode])
1177 AC_SUBST(DEFAULT_DNSSEC_MODE)
1178
1179 # ------------------------------------------------------------------------------
1180 have_networkd=no
1181 AC_ARG_ENABLE(networkd, AS_HELP_STRING([--disable-networkd], [disable networkd]))
1182 AS_IF([test "x$enable_networkd" != "xno"], [
1183         AC_DEFINE(ENABLE_NETWORKD, 1, [Define if networkd support is to be enabled])
1184         have_networkd=yes
1185         M4_DEFINES="$M4_DEFINES -DENABLE_NETWORKD"
1186 ])
1187 AM_CONDITIONAL(ENABLE_NETWORKD, [test "x$have_networkd" = "xyes"])
1188
1189 # ------------------------------------------------------------------------------
1190 have_efi=no
1191 AC_ARG_ENABLE(efi, AS_HELP_STRING([--disable-efi], [disable EFI support]))
1192 if test "x$enable_efi" != "xno"; then
1193         AC_DEFINE(ENABLE_EFI, 1, [Define if EFI support is to be enabled])
1194         have_efi=yes
1195 fi
1196 AM_CONDITIONAL(ENABLE_EFI, [test "x$have_efi" = "xyes"])
1197
1198 # ------------------------------------------------------------------------------
1199 AC_CHECK_TOOL(EFI_CC, gcc)
1200
1201 EFI_ARCH=`echo $host | sed "s/\(-\).*$//"`
1202
1203 AM_COND_IF(ARCH_IA32, [
1204         EFI_ARCH=ia32
1205         EFI_MACHINE_TYPE_NAME=ia32])
1206
1207 AM_COND_IF(ARCH_X86_64, [
1208         EFI_MACHINE_TYPE_NAME=x64])
1209
1210 AM_COND_IF(ARCH_AARCH64, [
1211         EFI_MACHINE_TYPE_NAME=aa64])
1212
1213 AC_SUBST([EFI_ARCH])
1214 AC_SUBST([EFI_MACHINE_TYPE_NAME])
1215
1216 have_gnuefi=no
1217 AC_ARG_ENABLE(gnuefi, AS_HELP_STRING([--enable-gnuefi], [Enable optional gnuefi support]))
1218 AS_IF([test "x$enable_gnuefi" != "xno"], [
1219         AC_CHECK_HEADERS(efi/${EFI_ARCH}/efibind.h,
1220                 [AC_DEFINE(HAVE_GNUEFI, 1, [Define if gnuefi is available])
1221                  have_gnuefi=yes],
1222                 [AS_IF([test "x$enable_gnuefi" = xyes],
1223                        [AC_MSG_ERROR([*** gnuefi support requested but headers not found])])
1224         ])
1225
1226         efiroot=$(echo $(cd /usr/lib/$(${EFI_CC} -print-multi-os-directory); pwd))
1227
1228         EFI_LIB_DIR="$efiroot"
1229         AC_ARG_WITH(efi-libdir,
1230                 AS_HELP_STRING([--with-efi-libdir=PATH], [Path to EFI lib directory]),
1231                 [EFI_LIB_DIR="$withval"], [EFI_LIB_DIR="$efiroot"]
1232         )
1233         AC_SUBST([EFI_LIB_DIR])
1234
1235         have_efi_lds=no
1236         AC_ARG_WITH(efi-ldsdir,
1237                 AS_HELP_STRING([--with-efi-ldsdir=PATH], [Path to EFI lds directory]),
1238                 [EFI_LDS_DIR="$withval" && AS_IF([test -f "${EFI_LDS_DIR}/elf_${EFI_ARCH}_efi.lds"],
1239                         [have_efi_lds=yes])],
1240                 [AS_FOR([DIR], [EFI_LDS_DIR], ["${EFI_LIB_DIR}/gnuefi" "${EFI_LIB_DIR}"],
1241                         [AS_IF([test -f "${EFI_LDS_DIR}/elf_${EFI_ARCH}_efi.lds"],
1242                                        [have_efi_lds=yes && break])])])
1243         AS_IF([test "x$have_efi_lds" = xyes],
1244               [AC_SUBST([EFI_LDS_DIR])],
1245               [AS_IF([test "x$enable_gnuefi" = xyes],
1246                      [AC_MSG_ERROR([*** gnuefi support requested but files not found])],
1247                      [have_gnuefi=no])])
1248
1249         AC_ARG_WITH(efi-includedir,
1250                 AS_HELP_STRING([--with-efi-includedir=PATH], [Path to EFI include directory]),
1251                 [EFI_INC_DIR="$withval"], [EFI_INC_DIR="/usr/include"]
1252         )
1253         AC_SUBST([EFI_INC_DIR])
1254 ])
1255 AM_CONDITIONAL(HAVE_GNUEFI, [test "x$have_gnuefi" = xyes])
1256
1257 # ------------------------------------------------------------------------------
1258 have_tpm=no
1259 AC_ARG_ENABLE([tpm], AS_HELP_STRING([--enable-tpm],[Enable optional TPM support]),
1260                 [case "${enableval}" in
1261                         yes) have_tpm=yes ;;
1262                         no) have_tpm=no ;;
1263                         *) AC_MSG_ERROR(bad value ${enableval} for --enable-tpm) ;;
1264                 esac],
1265                 [have_tpm=no])
1266
1267 if test "x${have_tpm}" != xno ; then
1268         AC_DEFINE(SD_BOOT_LOG_TPM, 1, [Define if TPM should be used to log events and extend the registers])
1269 fi
1270
1271 AC_ARG_WITH(tpm-pcrindex,
1272         AS_HELP_STRING([--with-tpm-pcrindex=<NUM>],
1273                 [TPM PCR register number to use]),
1274         [SD_TPM_PCR="$withval"],
1275         [SD_TPM_PCR="8"])
1276
1277 AC_DEFINE_UNQUOTED(SD_TPM_PCR, [$SD_TPM_PCR], [TPM PCR register number to use])
1278
1279 # ------------------------------------------------------------------------------
1280 have_kdbus=no
1281 AC_ARG_ENABLE(kdbus, AS_HELP_STRING([--disable-kdbus], [do not connect to kdbus by default]))
1282 if test "x$enable_kdbus" != "xno"; then
1283         AC_DEFINE(ENABLE_KDBUS, 1, [Define if kdbus is to be connected to by default])
1284         have_kdbus=yes
1285         M4_DEFINES="$M4_DEFINES -DENABLE_KDBUS"
1286 fi
1287 AM_CONDITIONAL(ENABLE_KDBUS, [test "$have_kdbus" = "yes"])
1288
1289 # ------------------------------------------------------------------------------
1290 AC_ARG_WITH(rc-local-script-path-start,
1291         AS_HELP_STRING([--with-rc-local-script-path-start=PATH],
1292                 [Path to /etc/rc.local]),
1293         [RC_LOCAL_SCRIPT_PATH_START="$withval"],
1294         [RC_LOCAL_SCRIPT_PATH_START="/etc/rc.local"])
1295
1296 AC_ARG_WITH(rc-local-script-path-stop,
1297         AS_HELP_STRING([--with-rc-local-script-path-stop=PATH],
1298                 [Path to /usr/sbin/halt.local]),
1299         [RC_LOCAL_SCRIPT_PATH_STOP="$withval"],
1300         [RC_LOCAL_SCRIPT_PATH_STOP="/usr/sbin/halt.local"])
1301
1302 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_START, ["$RC_LOCAL_SCRIPT_PATH_START"], [Path of /etc/rc.local script])
1303 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_STOP, ["$RC_LOCAL_SCRIPT_PATH_STOP"], [Path of /usr/sbin/halt.local script])
1304
1305 AC_SUBST(RC_LOCAL_SCRIPT_PATH_START)
1306 AC_SUBST(RC_LOCAL_SCRIPT_PATH_STOP)
1307
1308 # ------------------------------------------------------------------------------
1309 AC_ARG_WITH(kbd-loadkeys,
1310         AS_HELP_STRING([--with-kbd-loadkeys=PATH],
1311                 [Path to loadkeys]),
1312         [KBD_LOADKEYS="$withval"],
1313         [KBD_LOADKEYS="/usr/bin/loadkeys"])
1314
1315 AC_ARG_WITH(kbd-setfont,
1316         AS_HELP_STRING([--with-kbd-setfont=PATH],
1317                 [Path to setfont]),
1318         [KBD_SETFONT="$withval"],
1319         [KBD_SETFONT="/usr/bin/setfont"])
1320
1321 AC_DEFINE_UNQUOTED(KBD_LOADKEYS, ["$KBD_LOADKEYS"], [Path of loadkeys])
1322 AC_DEFINE_UNQUOTED(KBD_SETFONT, ["$KBD_SETFONT"], [Path of setfont])
1323
1324 AC_SUBST(KBD_LOADKEYS)
1325 AC_SUBST(KBD_SETFONT)
1326
1327 AC_ARG_WITH(telinit,
1328         AS_HELP_STRING([--with-telinit=PATH],
1329                 [Path to telinit]),
1330         [TELINIT="$withval"],
1331         [TELINIT="/lib/sysvinit/telinit"])
1332
1333 AC_DEFINE_UNQUOTED(TELINIT, ["$TELINIT"], [Path to telinit])
1334
1335 AC_SUBST(TELINIT)
1336
1337 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h valgrind/valgrind.h])
1338
1339 # ------------------------------------------------------------------------------
1340 have_myhostname=no
1341 AC_ARG_ENABLE(myhostname, AS_HELP_STRING([--disable-myhostname], [disable nss-myhostname support]))
1342 if test "x$enable_myhostname" != "xno"; then
1343         AC_HEADER_STDC
1344         AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h netdb.h netinet/in.h stdlib.h string.h sys/socket.h sys/time.h unistd.h nss.h sys/ioctl.h sys/auxv.h])
1345
1346         AC_C_CONST
1347         AC_TYPE_SIZE_T
1348         AC_HEADER_TIME
1349
1350         AC_FUNC_SELECT_ARGTYPES
1351         AC_CHECK_FUNCS([gethostbyaddr gethostbyname gettimeofday inet_ntoa memset select socket strcspn strdup strerror strncasecmp strcasecmp strspn])
1352
1353         have_myhostname=yes
1354         AC_DEFINE(HAVE_MYHOSTNAME, [1], [nss-myhostname is enabled])
1355 fi
1356 AM_CONDITIONAL(HAVE_MYHOSTNAME, [test "$have_myhostname" = "yes"])
1357
1358 # ------------------------------------------------------------------------------
1359 AC_ARG_ENABLE(hwdb, [AC_HELP_STRING([--disable-hwdb], [disable hardware database support])],
1360        enable_hwdb=$enableval, enable_hwdb=yes)
1361 AM_CONDITIONAL(ENABLE_HWDB, [test x$enable_hwdb = xyes])
1362
1363 # ------------------------------------------------------------------------------
1364 have_manpages=no
1365 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
1366 AC_PATH_PROG([XSLTPROC], [xsltproc])
1367 AS_IF([test "x$enable_manpages" != xno], [
1368        have_manpages=yes
1369        AS_IF([test -z "$XSLTPROC"],
1370              AC_MSG_ERROR([*** xsltproc is required for man pages]))
1371 ])
1372 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
1373
1374 # ------------------------------------------------------------------------------
1375 AC_ARG_ENABLE(hibernate,
1376        [AC_HELP_STRING([--disable-hibernate], [disable hibernation support])],
1377        enable_hibernate=$enableval, enable_hibernate=yes)
1378 AM_CONDITIONAL(ENABLE_HIBERNATE, [test x$enable_hibernate = xyes])
1379
1380 # ------------------------------------------------------------------------------
1381 AC_ARG_ENABLE(ldconfig,
1382        [AC_HELP_STRING([--disable-ldconfig], [disable ldconfig])],
1383        enable_ldconfig=$enableval, enable_ldconfig=yes)
1384 AM_CONDITIONAL(ENABLE_LDCONFIG, [test x$enable_ldconfig = xyes])
1385
1386 # ------------------------------------------------------------------------------
1387 # Location of the init scripts as mandated by LSB
1388 SYSTEM_SYSVINIT_PATH=/etc/init.d
1389 SYSTEM_SYSVRCND_PATH=/etc/rc.d
1390
1391 AC_ARG_WITH([sysvinit-path],
1392         [AS_HELP_STRING([--with-sysvinit-path=PATH],
1393                 [Specify the path to where the SysV init scripts are located])],
1394         [SYSTEM_SYSVINIT_PATH="$withval"],
1395         [])
1396
1397 AC_ARG_WITH([sysvrcnd-path],
1398         [AS_HELP_STRING([--with-sysvrcnd-path=PATH],
1399                 [Specify the path to the base directory for the SysV rcN.d directories])],
1400         [SYSTEM_SYSVRCND_PATH="$withval"],
1401         [])
1402
1403 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
1404         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
1405         SYSTEM_SYSV_COMPAT="yes"
1406         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
1407 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
1408         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcnd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
1409 else
1410         SYSTEM_SYSV_COMPAT="no"
1411 fi
1412
1413 AC_SUBST(SYSTEM_SYSVINIT_PATH)
1414 AC_SUBST(SYSTEM_SYSVRCND_PATH)
1415 AC_SUBST(M4_DEFINES)
1416
1417 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
1418
1419 AC_ARG_WITH([tty-gid],
1420         [AS_HELP_STRING([--with-tty-gid=GID],
1421                 [Specify the numeric GID of the 'tty' group])],
1422         [TTY_GID="$withval"],
1423         [TTY_GID="5"])
1424
1425 AC_DEFINE_UNQUOTED(TTY_GID, [$TTY_GID], [GID of the 'tty' group])
1426 AC_SUBST(TTY_GID)
1427
1428 AC_ARG_WITH([dbuspolicydir],
1429         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
1430         [],
1431         [with_dbuspolicydir=${sysconfdir}/dbus-1/system.d])
1432 AX_NORMALIZE_PATH([with_dbuspolicydir])
1433
1434 AC_ARG_WITH([dbussessionservicedir],
1435         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
1436         [],
1437         [with_dbussessionservicedir=${datadir}/dbus-1/services])
1438 AX_NORMALIZE_PATH([with_dbussessionservicedir])
1439
1440 AC_ARG_WITH([dbussystemservicedir],
1441         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
1442         [],
1443         [with_dbussystemservicedir=${datadir}/dbus-1/system-services])
1444 AX_NORMALIZE_PATH([with_dbussystemservicedir])
1445
1446 AC_ARG_WITH([bashcompletiondir],
1447         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
1448         [],
1449         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
1450                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
1451         ] , [
1452                 with_bashcompletiondir=${datadir}/bash-completion/completions
1453         ])])
1454 AM_CONDITIONAL(ENABLE_BASH_COMPLETION, [test "$with_bashcompletiondir" != "no"])
1455 AX_NORMALIZE_PATH([with_bashcompletiondir])
1456
1457 AC_ARG_WITH([zshcompletiondir],
1458         AS_HELP_STRING([--with-zshcompletiondir=DIR], [Zsh completions directory]),
1459         [], [with_zshcompletiondir=${datadir}/zsh/site-functions])
1460 AM_CONDITIONAL(ENABLE_ZSH_COMPLETION, [test "$with_zshcompletiondir" != "no"])
1461 AX_NORMALIZE_PATH([with_zshcompletiondir])
1462
1463 AC_ARG_WITH([rootprefix],
1464         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
1465         [], [with_rootprefix=${ac_default_prefix}])
1466 # --with-rootprefix= (empty) should default to "/" but AX_NORMALIZE_PATH
1467 # defaults those to ".", solve that here for now until we can find a suitable
1468 # fix for AX_NORMALIZE_PATH upstream at autoconf-archive.
1469 # See: https://github.com/systemd/systemd/issues/54
1470 if test "x${with_rootprefix}" = "x"; then
1471         with_rootprefix="/"
1472 fi
1473 AX_NORMALIZE_PATH([with_rootprefix])
1474
1475 AC_ARG_WITH([rootlibdir],
1476         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
1477         [],
1478         [with_rootlibdir=${libdir}])
1479 AX_NORMALIZE_PATH([with_rootlibdir])
1480
1481 AC_ARG_WITH([pamlibdir],
1482         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
1483         [],
1484         [with_pamlibdir=${with_rootlibdir}/security])
1485 AX_NORMALIZE_PATH([with_pamlibdir])
1486
1487 AC_ARG_WITH([pamconfdir],
1488         AS_HELP_STRING([--with-pamconfdir=DIR], [Directory for PAM configuration]),
1489         [],
1490         [with_pamconfdir=${sysconfdir}/pam.d])
1491 AX_NORMALIZE_PATH([with_pamconfdir])
1492
1493 AC_ARG_ENABLE([split-usr],
1494         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
1495         [],
1496         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
1497                 enable_split_usr=yes
1498         ], [
1499                 enable_split_usr=no
1500         ])])
1501
1502 AS_IF([test "x${enable_split_usr}" = "xyes"], [
1503         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
1504 ])
1505 AM_CONDITIONAL(ENABLE_SPLIT_USR, [test "x${enable_split_usr}" = "xyes"])
1506
1507 # work around intltool-update issues during 'make distcheck'
1508 AS_IF([test "x$0" != "x./configure"], [
1509         AC_SUBST([INTLTOOL_UPDATE], [/bin/true])
1510 ])
1511
1512 # QEMU and OVMF UEFI firmware
1513 AS_IF([test x"$cross_compiling" = "xyes"], [], [
1514         AC_PATH_PROG([QEMU], [qemu-system-x86_64])
1515         AC_CHECK_FILE([/usr/share/qemu/bios-ovmf.bin], [QEMU_BIOS=/usr/share/qemu/bios-ovmf.bin],
1516                 [AC_CHECK_FILE([/usr/share/qemu-ovmf/bios.bin], [QEMU_BIOS=/usr/share/qemu-ovmf/bios.bin])])
1517         AC_SUBST([QEMU_BIOS])
1518 ])
1519
1520 AC_ARG_ENABLE(tests,
1521         [AC_HELP_STRING([--disable-tests], [disable tests, or enable extra tests with =unsafe])],
1522         enable_tests=$enableval, enable_tests=yes)
1523 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes -o x$enable_tests = xunsafe])
1524 AM_CONDITIONAL(ENABLE_UNSAFE_TESTS, [test x$enable_tests = xunsafe])
1525
1526 AC_ARG_ENABLE(debug,
1527         [AC_HELP_STRING([--enable-debug@<:@=LIST@:>@], [enable extra debugging (hashmap,mmap-cache)])],
1528         [if test "x$enableval" = "xyes"; then
1529                 enableval="hashmap,mmap-cache"
1530         fi
1531         saved_ifs="$IFS"
1532         IFS="$IFS$PATH_SEPARATOR,"
1533         for name in $enableval; do
1534                 case $name in
1535                 hashmap)
1536                         enable_debug_hashmap=yes
1537                         ;;
1538                 mmap-cache)
1539                         enable_debug_mmap_cache=yes
1540                         ;;
1541                 esac
1542         done
1543         IFS="$saved_ifs"],[])
1544
1545 enable_debug=""
1546 AS_IF([test x$enable_debug_hashmap = xyes], [
1547         AC_DEFINE(ENABLE_DEBUG_HASHMAP, 1, [Define if hashmap debugging is to be enabled])
1548         enable_debug="hashmap $enable_debug"
1549 ])
1550 AS_IF([test x$enable_debug_mmap_cache = xyes], [
1551         AC_DEFINE(ENABLE_DEBUG_MMAP_CACHE, 1, [Define if mmap cache debugging is to be enabled])
1552         enable_debug="mmap-cache $enable_debug"
1553 ])
1554 test -z "$enable_debug" && enable_debug="none"
1555
1556 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
1557 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
1558 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
1559 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
1560 AC_SUBST([zshcompletiondir], [$with_zshcompletiondir])
1561 AC_SUBST([pamlibdir], [$with_pamlibdir])
1562 AC_SUBST([pamconfdir], [$with_pamconfdir])
1563 AC_SUBST([rootprefix], [$with_rootprefix])
1564 AC_SUBST([rootlibdir], [$with_rootlibdir])
1565
1566 AC_CONFIG_FILES([
1567         Makefile
1568         po/Makefile.in
1569 ])
1570
1571 AC_OUTPUT
1572 AC_MSG_RESULT([
1573         $PACKAGE_NAME $VERSION
1574
1575         libcryptsetup:                     ${have_libcryptsetup}
1576         PAM:                               ${have_pam}
1577         AUDIT:                             ${have_audit}
1578         IMA:                               ${have_ima}
1579         AppArmor:                          ${have_apparmor}
1580         SELinux:                           ${have_selinux}
1581         SECCOMP:                           ${have_seccomp}
1582         SMACK:                             ${have_smack}
1583         ZLIB:                              ${have_zlib}
1584         XZ:                                ${have_xz}
1585         LZ4:                               ${have_lz4}
1586         BZIP2:                             ${have_bzip2}
1587         ACL:                               ${have_acl}
1588         GCRYPT:                            ${have_gcrypt}
1589         QRENCODE:                          ${have_qrencode}
1590         MICROHTTPD:                        ${have_microhttpd}
1591         GNUTLS:                            ${have_gnutls}
1592         libcurl:                           ${have_libcurl}
1593         libidn:                            ${have_libidn}
1594         libiptc:                           ${have_libiptc}
1595         ELFUTILS:                          ${have_elfutils}
1596         binfmt:                            ${have_binfmt}
1597         vconsole:                          ${have_vconsole}
1598         quotacheck:                        ${have_quotacheck}
1599         tmpfiles:                          ${have_tmpfiles}
1600         sysusers:                          ${have_sysusers}
1601         firstboot:                         ${have_firstboot}
1602         randomseed:                        ${have_randomseed}
1603         backlight:                         ${have_backlight}
1604         rfkill:                            ${have_rfkill}
1605         logind:                            ${have_logind}
1606         Default KillUserProcesses setting: ${KILL_USER_PROCESSES}
1607         machined:                          ${have_machined}
1608         importd:                           ${have_importd}
1609         hostnamed:                         ${have_hostnamed}
1610         timedated:                         ${have_timedated}
1611         timesyncd:                         ${have_timesyncd}
1612         Default NTP servers:               ${NTP_SERVERS}
1613         time epoch:                        ${TIME_EPOCH}
1614         localed:                           ${have_localed}
1615         networkd:                          ${have_networkd}
1616         resolved:                          ${have_resolved}
1617         Default DNS servers:               ${DNS_SERVERS}
1618         Default DNSSEC mode:               ${DEFAULT_DNSSEC_MODE}
1619         coredump:                          ${have_coredump}
1620         polkit:                            ${have_polkit}
1621         efi:                               ${have_efi}
1622         gnuefi:                            ${have_gnuefi}
1623         efi arch:                          ${EFI_ARCH}
1624         EFI machine type:                  ${EFI_MACHINE_TYPE_NAME}
1625         EFI CC                             ${EFI_CC}
1626         EFI libdir:                        ${EFI_LIB_DIR}
1627         EFI ldsdir:                        ${EFI_LDS_DIR}
1628         EFI includedir:                    ${EFI_INC_DIR}
1629         kmod:                              ${have_kmod}
1630         xkbcommon:                         ${have_xkbcommon}
1631         blkid:                             ${have_blkid}
1632         libmount:                          ${have_libmount}
1633         dbus:                              ${have_dbus}
1634         nss-myhostname:                    ${have_myhostname}
1635         hwdb:                              ${enable_hwdb}
1636         tpm:                               ${have_tpm}
1637         kdbus:                             ${have_kdbus}
1638         Python:                            ${have_python}
1639         man pages:                         ${have_manpages}
1640         test coverage:                     ${have_coverage}
1641         Split /usr:                        ${enable_split_usr}
1642         SysV compatibility:                ${SYSTEM_SYSV_COMPAT}
1643         utmp/wtmp support:                 ${have_utmp}
1644         ldconfig support:                  ${enable_ldconfig}
1645         hibernate support:                 ${enable_hibernate}
1646         extra debugging:                   ${enable_debug}
1647         tests:                             ${enable_tests}
1648
1649         prefix:                            ${prefix}
1650         rootprefix:                        ${with_rootprefix}
1651         sysconf dir:                       ${sysconfdir}
1652         datarootdir:                       ${datarootdir}
1653         includedir:                        ${includedir}
1654         lib dir:                           ${libdir}
1655         rootlib dir:                       ${with_rootlibdir}
1656         SysV init scripts:                 ${SYSTEM_SYSVINIT_PATH}
1657         SysV rc?.d directories:            ${SYSTEM_SYSVRCND_PATH}
1658         Build Python:                      ${PYTHON}
1659         PAM modules dir:                   ${with_pamlibdir}
1660         PAM configuration dir:             ${with_pamconfdir}
1661         D-Bus policy dir:                  ${with_dbuspolicydir}
1662         D-Bus session dir:                 ${with_dbussessionservicedir}
1663         D-Bus system dir:                  ${with_dbussystemservicedir}
1664         Bash completions dir:              ${with_bashcompletiondir}
1665         Zsh completions dir:               ${with_zshcompletiondir}
1666         Extra start script:                ${RC_LOCAL_SCRIPT_PATH_START}
1667         Extra stop script:                 ${RC_LOCAL_SCRIPT_PATH_STOP}
1668         Adm group:                         ${have_adm_group}
1669         Wheel group:                       ${have_wheel_group}
1670         Debug shell:                       ${SUSHELL} @ ${DEBUGTTY}
1671         TTY GID:                           ${TTY_GID}
1672         Maximum System UID:                ${SYSTEM_UID_MAX}
1673         Maximum System GID:                ${SYSTEM_GID_MAX}
1674         Certificate root:                  ${CERTIFICATEROOT}
1675
1676         CFLAGS:   ${OUR_CFLAGS} ${CFLAGS}
1677         CPPFLAGS: ${OUR_CPPFLAGS} ${CPPFLAGS}
1678         LDFLAGS:  ${OUR_LDFLAGS} ${LDFLAGS}
1679 ])