configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT([GStreamer Good Plug-ins],[1.13.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-good])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl PKG_CONFIG_SYSROOT_DIR is a valid environment variable
  34 m4_pattern_allow(PKG_CONFIG_SYSROOT_DIR)
  35
  36 dnl use pretty build output with automake >= 1.11
  37 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  38   [AM_DEFAULT_VERBOSITY=1
  39    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  40
  41 dnl our libraries and install dirs use GST_API_VERSION in the filename
  42 dnl to allow side-by-side installation of different API versions
  43 GST_API_VERSION=1.0
  44 AC_SUBST(GST_API_VERSION)
  45 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  46   [GStreamer API Version])
  47
  48 AG_GST_LIBTOOL_PREPARE
  49 AS_LIBTOOL(GST, 1300, 0, 1300)
  50
  51 dnl *** required versions of GStreamer stuff ***
  52 GST_REQ=1.13.0.1
  53 GSTPB_REQ=1.13.0.1
  54
  55 dnl *** autotools stuff ****
  56
  57 dnl allow for different autotools
  58 AS_AUTOTOOLS_ALTERNATE
  59
  60 dnl Add parameters for aclocal
  61 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  62
  63 dnl set up gettext
  64 dnl the version check needs to stay here because autopoint greps for it
  65 AM_GNU_GETTEXT_VERSION([0.17])
  66 AM_GNU_GETTEXT([external])
  67 AG_GST_GETTEXT([gst-plugins-good-$GST_API_VERSION])
  68
  69 dnl *** check for arguments to configure ***
  70
  71 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  72 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  73
  74 AG_GST_ARG_DEBUG
  75 AG_GST_ARG_PROFILING
  76 AG_GST_ARG_VALGRIND
  77 AG_GST_ARG_GCOV
  78
  79 AG_GST_ARG_EXAMPLES
  80
  81 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  82 AG_GST_ARG_WITH_PACKAGE_NAME
  83 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  84
  85 AG_GST_ARG_WITH_PLUGINS
  86
  87 AG_GST_ARG_ENABLE_EXTERNAL
  88
  89 AG_GST_ARG_ENABLE_EXPERIMENTAL
  90
  91 AG_GST_PKG_CONFIG_PATH
  92
  93 dnl *** checks for platform ***
  94
  95 dnl * hardware/architecture *
  96
  97 dnl common/m4/gst-arch.m4
  98 dnl check CPU type
  99 AG_GST_ARCH
 100
 101 dnl Determine endianness
 102 AC_C_BIGENDIAN
 103
 104 dnl *** checks for programs ***
 105
 106 dnl find a compiler
 107 AC_PROG_CC
 108 AC_PROG_CC_STDC
 109
 110 dnl determine c++ compiler
 111 AC_PROG_CXX
 112 dnl determine if c++ is available on this system
 113 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 114
 115 dnl determine c++ preprocessor
 116 dnl FIXME: do we need this ?
 117 AC_PROG_CXXCPP
 118
 119 AC_PROG_OBJC
 120
 121 dnl check if the compiler supports '-c' and '-o' options
 122 AM_PROG_CC_C_O
 123
 124 dnl find an assembler
 125 AM_PROG_AS
 126
 127 dnl check if the compiler supports do while(0) macros
 128 AG_GST_CHECK_DOWHILE_MACROS
 129
 130 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 131 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 132
 133 dnl check for documentation tools
 134 GTK_DOC_CHECK([1.12])
 135 AG_GST_PLUGIN_DOCS([1.12])
 136
 137 dnl *** checks for libraries ***
 138
 139 dnl check for libm, for sin()
 140 LT_LIB_M
 141 AC_SUBST(LIBM)
 142
 143 AC_CHECK_FUNCS(clock_gettime, [], [
 144   AC_CHECK_LIB(rt, clock_gettime, [
 145     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 146     LIBRT="-lrt"
 147     AC_SUBST([LIBRT])
 148   ])
 149 ])
 150
 151 dnl check for pthreads
 152 AX_PTHREAD
 153
 154 dnl *** checks for header files ***
 155
 156 dnl check if we have ANSI C header files
 157 AC_HEADER_STDC
 158
 159 dnl used by ext/wavpack
 160 AX_CREATE_STDINT_H
 161
 162 dnl used in gst/udp
 163 AC_CHECK_HEADERS([sys/time.h])
 164
 165 dnl used in gst/udp
 166 AC_CHECK_HEADERS([sys/socket.h])
 167
 168 dnl *** checks for types/defines ***
 169
 170 dnl Check for FIONREAD ioctl declaration.  This check is needed
 171 dnl for the UDP plugin to build on Solaris
 172 GST_CHECK_FIONREAD
 173
 174 dnl *** checks for structures ***
 175
 176 dnl *** checks for compiler characteristics ***
 177
 178 dnl check if we have GCC inline-asm
 179 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 180 if test x$HAVE_GCC_ASM = xyes ; then
 181   AC_DEFINE(HAVE_GCC_ASM, 1,
 182     [Define if compiler supports gcc inline assembly])
 183 fi
 184 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 185
 186 dnl *** checks for library functions ***
 187
 188 LIBS_SAVE=$LIBS
 189 LIBS="$LIBS $LIBM"
 190 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 191 LIBS=$LIBS_SAVE
 192
 193 dnl Check whether isinf() is defined by math.h
 194 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 195     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 196 if test "$ac_cv_have_isinf" = "yes"
 197 then
 198     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 199 fi
 200
 201 dnl Check for mmap (needed by electricfence plugin)
 202 AC_FUNC_MMAP
 203 AC_CHECK_SIZEOF([off_t])
 204 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 205
 206 dnl Check for mmap (needed by electricfence plugin)
 207
 208 AC_CHECK_TYPE([struct ip_mreqn], [
 209               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 210               [#include <netinet/in.h>])
 211
 212 dnl *** checks for dependency libraries ***
 213
 214
 215 dnl GLib
 216 GLIB_REQ=2.40.0
 217 AG_GST_GLIB_CHECK([$GLIB_REQ])
 218
 219 dnl Orc
 220 ORC_CHECK([0.4.17])
 221
 222 dnl checks for gstreamer
 223 dnl uninstalled is selected preferentially -- see pkg-config(1)
 224 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 225 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 226 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 227 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 228 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 229 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 230
 231 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_API_VERSION`
 232 if test -z $GST_TOOLS_DIR; then
 233   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 234 fi
 235 AC_SUBST(GST_TOOLS_DIR)
 236
 237 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 238 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 239
 240 AG_GST_PKG_CHECK_MODULES(GST_GL, gstreamer-gl-[$GST_API_VERSION], [$GST_REQ], no)
 241
 242 dnl FIXME: if uninstalled setup we might not want to pick up an installed gst-gl?
 243 if test "x$HAVE_GST_GL" = "xyes"; then
 244
 245   AC_MSG_CHECKING([GStreamer OpenGL window systems ...])
 246   GST_GL_WINSYS=`$PKG_CONFIG --variable=gl_winsys gstreamer-gl-1.0`
 247   AC_MSG_RESULT([$GST_GL_WINSYS])
 248   GST_GL_HAVE_WINDOW_X11=""
 249   GST_GL_HAVE_WINDOW_WAYLAND=""
 250   GST_GL_HAVE_WINDOW_ANDROID=""
 251   GST_GL_HAVE_WINDOW_COCOA=""
 252   GST_GL_HAVE_WINDOW_EAGL=""
 253   case "$GST_GL_WINSYS" in  *x11*) GST_GL_HAVE_WINDOW_X11="1" ;; esac
 254   case "$GST_GL_WINSYS" in  *wayland*) GST_GL_HAVE_WINDOW_WAYLAND="1" ;; esac
 255   case "$GST_GL_WINSYS" in  *android*) GST_GL_HAVE_WINDOW_ANDROID="1" ;; esac
 256   case "$GST_GL_WINSYS" in  *cocoa*) GST_GL_HAVE_WINDOW_COCOA="1" ;; esac
 257   case "$GST_GL_WINSYS" in  *eagl*) GST_GL_HAVE_WINDOW_EAGL="1" ;; esac
 258
 259   AC_MSG_CHECKING([GStreamer OpenGL platforms ...])
 260   GST_GL_PLATFORMS=`$PKG_CONFIG --variable=gl_platforms gstreamer-gl-1.0`
 261   AC_MSG_RESULT([$GST_GL_PLATFORMS])
 262   GST_GL_HAVE_PLATFORM_GLX=""
 263   GST_GL_HAVE_PLATFORM_EGL=""
 264   GST_GL_HAVE_PLATFORM_CGL=""
 265   GST_GL_HAVE_PLATFORM_EAGL=""
 266   case "$GST_GL_PLATFORMS" in  *glx*) GST_GL_HAVE_PLATFORM_GLX="1" ;; esac
 267   case "$GST_GL_PLATFORMS" in  *egl*) GST_GL_HAVE_PLATFORM_EGL="1" ;; esac
 268   case "$GST_GL_PLATFORMS" in  *cgl*) GST_GL_HAVE_PLATFORM_CGL="1" ;; esac
 269   case "$GST_GL_PLATFORMS" in  *eagl*) GST_GL_HAVE_PLATFORM_EAGL="1" ;; esac
 270
 271   AC_MSG_CHECKING([GStreamer OpenGL apis ...])
 272   GST_GL_APIS=`$PKG_CONFIG --variable=gl_apis gstreamer-gl-1.0`
 273   AC_MSG_RESULT([$GST_GL_APIS])
 274   GST_GL_HAVE_API_GLES2=""
 275   GST_GL_HAVE_API_GL=""
 276   case "$GST_GL_APIS" in  *gles2*) GST_GL_HAVE_API_GLES2="1" ;; esac
 277   case "$GST_GL_APIS" in "gl"|"gl "*|*" gl"|*" gl "*) GST_GL_HAVE_API_GL="1" ;; esac
 278 fi
 279
 280 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 281
 282 dnl Check for documentation xrefs
 283 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 284 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 285 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 286 AC_SUBST(GLIB_PREFIX)
 287 AC_SUBST(GST_PREFIX)
 288 AC_SUBST(GSTPB_PREFIX)
 289
 290 dnl GTK is optional and used in examples
 291 HAVE_GTK=no
 292 GTK_REQ=3.0.0
 293 if test "x$BUILD_EXAMPLES" = "xyes"; then
 294   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 295   dnl some examples need gtk+-x11
 296   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 297   AC_SUBST(GTK_LIBS)
 298   AC_SUBST(GTK_CFLAGS)
 299 fi
 300 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 301 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 302
 303 dnl Check for -Bsymbolic-functions linker flag used to avoid
 304 dnl intra-library PLT jumps, if available.
 305 AC_ARG_ENABLE(Bsymbolic,
 306               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 307               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 308                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 309                LDFLAGS=-Wl,-Bsymbolic-functions
 310                LIBS=
 311                AC_TRY_LINK([], [return 0],
 312                            AC_MSG_RESULT(yes)
 313                            enable_Bsymbolic=yes,
 314                            AC_MSG_RESULT(no)
 315                            enable_Bsymbolic=no)
 316                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 317
 318 dnl *** set variables based on configure arguments ***
 319
 320 dnl set license and copyright notice
 321 GST_LICENSE="LGPL"
 322 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 323 AC_SUBST(GST_LICENSE)
 324
 325 dnl set location of plugin directory
 326 AG_GST_SET_PLUGINDIR
 327
 328 dnl set release date/time
 329 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 330   ["${srcdir}/gst-plugins-good.doap"],
 331   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 332
 333 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 334 dnl make sure it doesn't complain about unused variables if debugging is disabled
 335 NO_WARNINGS=""
 336 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 337
 338 dnl define an ERROR_CFLAGS Makefile variable
 339 dnl -Wundef: too many broken headers
 340 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 341       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 342       -Wwrite-strings -Wold-style-definition -Waggregate-return
 343       -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 344       -Wnested-externs $NO_WARNINGS])
 345
 346 dnl define an ERROR_CXXFLAGS Makefile variable
 347 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 348         -Wmissing-declarations -Wredundant-decls
 349         -Wwrite-strings
 350         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 351         $NO_WARNINGS])
 352
 353 dnl define an ERROR_OBJCFLAGS Makefile variable
 354 AG_GST_SET_ERROR_OBJCFLAGS($FATAL_WARNINGS, [
 355       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 356       -Wwrite-strings -Wold-style-definition
 357       -Winit-self -Wmissing-include-dirs -Wno-multichar
 358       -Wnested-externs $NO_WARNINGS])
 359
 360 dnl define correct level for debugging messages
 361 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 362
 363 dnl used in examples
 364 AG_GST_DEFAULT_ELEMENTS
 365
 366 dnl *** plug-ins to include ***
 367
 368 dnl these are all the gst plug-ins, compilable without additional libs
 369 dnl videofilter is at the top because others depend on it
 370 AG_GST_CHECK_PLUGIN(alpha)
 371 AG_GST_CHECK_PLUGIN(apetag)
 372 AG_GST_CHECK_PLUGIN(audiofx)
 373 AG_GST_CHECK_PLUGIN(audioparsers)
 374 AG_GST_CHECK_PLUGIN(auparse)
 375 AG_GST_CHECK_PLUGIN(autodetect)
 376 AG_GST_CHECK_PLUGIN(avi)
 377 AG_GST_CHECK_PLUGIN(cutter)
 378 AG_GST_CHECK_PLUGIN(debugutils)
 379 AG_GST_CHECK_PLUGIN(deinterlace)
 380 AG_GST_CHECK_PLUGIN(dtmf)
 381 AG_GST_CHECK_PLUGIN(effectv)
 382 AG_GST_CHECK_PLUGIN(equalizer)
 383 AG_GST_CHECK_PLUGIN(flv)
 384 AG_GST_CHECK_PLUGIN(flx)
 385 AG_GST_CHECK_PLUGIN(goom)
 386 AG_GST_CHECK_PLUGIN(goom2k1)
 387 AG_GST_CHECK_PLUGIN(icydemux)
 388 AG_GST_CHECK_PLUGIN(id3demux)
 389 AG_GST_CHECK_PLUGIN(imagefreeze)
 390 AG_GST_CHECK_PLUGIN(interleave)
 391 AG_GST_CHECK_PLUGIN(isomp4)
 392 AG_GST_CHECK_PLUGIN(law)
 393 AG_GST_CHECK_PLUGIN(level)
 394 AG_GST_CHECK_PLUGIN(matroska)
 395 AG_GST_CHECK_PLUGIN(monoscope)
 396 AG_GST_CHECK_PLUGIN(multifile)
 397 AG_GST_CHECK_PLUGIN(multipart)
 398 AG_GST_CHECK_PLUGIN(replaygain)
 399 AG_GST_CHECK_PLUGIN(rtp)
 400 AG_GST_CHECK_PLUGIN(rtpmanager)
 401 AG_GST_CHECK_PLUGIN(rtsp)
 402 AG_GST_CHECK_PLUGIN(shapewipe)
 403 AG_GST_CHECK_PLUGIN(smpte)
 404 AG_GST_CHECK_PLUGIN(spectrum)
 405 AG_GST_CHECK_PLUGIN(udp)
 406 AG_GST_CHECK_PLUGIN(videobox)
 407 AG_GST_CHECK_PLUGIN(videocrop)
 408 AG_GST_CHECK_PLUGIN(videofilter)
 409 AG_GST_CHECK_PLUGIN(videomixer)
 410 AG_GST_CHECK_PLUGIN(wavenc)
 411 AG_GST_CHECK_PLUGIN(wavparse)
 412 AG_GST_CHECK_PLUGIN(y4m)
 413
 414 dnl disable experimental plug-ins
 415 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 416   AG_GST_DISABLE_PLUGIN(monoscope)
 417 fi
 418
 419 dnl *** sys plug-ins ***
 420
 421 echo
 422 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 423 echo
 424
 425 dnl DirectSound
 426 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 427 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 428   HAVE_DIRECTSOUND="no"
 429   save_CFLAGS="$CFLAGS"
 430   save_LDFLAGS="$LDFLAGS"
 431   save_LIBS="$LIBS"
 432   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 433   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 434   LIBS="$LIBS -ldsound -ldxerr9 -luser32 -lole32"
 435   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 436   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 437 #include <windows.h>
 438 #include <dxerr9.h>
 439 #include <dsound.h>
 440 ]], [[
 441   DXGetErrorString9 (0);
 442   DirectSoundCreate(NULL, NULL, NULL);
 443   CLSIDFromString(NULL, NULL);
 444 ]])
 445 ],
 446     [HAVE_DIRECTSOUND="yes"],
 447     [HAVE_DIRECTSOUND="no"])
 448   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 449   CFLAGS=$save_CFLAGS
 450   LDFLAGS=$save_LDFLAGS
 451   LIBS=$save_LIBS
 452
 453   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 454     dnl this is much more than we want
 455     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32 -lole32"
 456     AC_SUBST(DIRECTSOUND_CFLAGS)
 457     AC_SUBST(DIRECTSOUND_LDFLAGS)
 458     AC_SUBST(DIRECTSOUND_LIBS)
 459   fi
 460   AC_SUBST(HAVE_DIRECTSOUND)
 461 ])
 462
 463 dnl *** Win32 WaveOut ***
 464 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVEFORM, true)
 465 AG_GST_CHECK_FEATURE(WAVEFORM, [Win32 WaveForm], waveformsink, [
 466   AC_CHECK_HEADER(mmsystem.h, HAVE_WAVEFORM="yes", HAVE_WAVEFORM="no", [#include <windows.h>])
 467 ])
 468
 469 dnl *** OSS audio *** (Linux, *BSD)
 470 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 471 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 472  HAVE_OSS="yes"
 473 dnl Linux and newer BSD versions :
 474  AC_CHECK_HEADER(sys/soundcard.h, [
 475    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 476    ] , [
 477 dnl Some old BSD versions and also newer OpenBSD versions :
 478    AC_CHECK_HEADER(soundcard.h, [
 479      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 480      ], [
 481   dnl Some old BSD versions :
 482      AC_CHECK_HEADER(machine/soundcard.h, [
 483        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 484          [Define if OSS includes are in /machine/])
 485        ], [
 486        HAVE_OSS="no"
 487      ])
 488    ])
 489  ])
 490 ])
 491
 492 dnl *** oss4 ***
 493 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 494 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 495   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 496   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 497       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 498       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 499 ])
 500
 501 dnl *** OSX Audio ***
 502 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 503 HAVE_IOS="no"
 504 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 505   AC_CHECK_HEADER(CoreAudio/CoreAudio.h,
 506     [HAVE_OSX_AUDIO="yes"],
 507     [AC_CHECK_HEADER(CoreAudio/CoreAudioTypes.h,
 508     [
 509       HAVE_OSX_AUDIO="yes"
 510       HAVE_IOS="yes"
 511     ], [
 512       HAVE_OSX_AUDIO="no"
 513       HAVE_IOS="no"
 514     ])]
 515   )
 516 ])
 517 if test "x$HAVE_IOS" = "xyes"; then
 518   AC_DEFINE(HAVE_IOS, 1, [building for iOS platofrm])
 519 fi
 520 AM_CONDITIONAL(HAVE_IOS, test "x$HAVE_IOS" = "xyes")
 521
 522 dnl *** OS X video ***
 523 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 524 HAVE_OSX_VIDEO="no"
 525 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 526   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 527
 528   dnl in case header OpenGL/gl.h is found on other platforms (or older, unsupported OS X)
 529   dnl also require Snow Leopard or newer
 530
 531   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 532         #include <AvailabilityMacros.h>
 533         #if MAC_OS_X_VERSION_MIN_REQUIRED < 1060
 534         #error Too old OSX version
 535         #endif
 536       ]], [[return 0;]])],[HAVE_OSX_VIDEO="yes"],[HAVE_OSX_VIDEO="no"])
 537 ])
 538
 539 dnl *** Video 4 Linux 2 ***
 540 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 541 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 542 HAVE_GST_V4L2=no
 543 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], video4linux2, [
 544   AC_MSG_CHECKING([Checking for video4linux2 header ...])
 545   AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_GST_V4L2=yes ],
 546   [
 547     AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_GST_V4L2=yes ],
 548     [
 549       AC_CHECK_HEADER(sys/videoio.h, [ HAVE_GST_V4L2=yes ])
 550     ])
 551   ])
 552   if test "x$HAVE_VIDEODEV" = "xno"; then
 553      AC_MSG_WARN([video4linux2 was not found])
 554   fi
 555 ])
 556
 557 # Optional gudev for device probing
 558 AC_ARG_WITH([gudev],
 559   AS_HELP_STRING([--with-gudev],[device detection with gudev]),
 560   [],
 561   [with_gudev=check])
 562 if test x$HAVE_GST_V4L2 = xyes; then
 563   if test x$with_gudev != xno; then
 564     PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 147 ],
 565       [ AC_DEFINE(HAVE_GUDEV, 1,
 566           [Whether gudev is available for device detection])
 567       ],
 568       [true])
 569   fi
 570 fi
 571
 572 AC_SUBST(GUDEV_CFLAGS)
 573 AC_SUBST(GUDEV_LIBS)
 574
 575 # Make libv4l2 non-automagic
 576 AC_ARG_WITH([libv4l2],
 577   AS_HELP_STRING([--with-libv4l2],[support video buffer conversion using libv4l2]),
 578   [],
 579   [with_libv4l2=check])
 580 if test x$HAVE_GST_V4L2 = xyes; then
 581   if test x$with_libv4l2 != xno; then
 582       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 583           [ have_libv4l2=yes
 584             AC_DEFINE(HAVE_LIBV4L2, 1,
 585                 [Whether libv4l2 is available for video buffer conversion])
 586           ], [
 587           have_libv4l2=no
 588           ])
 589   else
 590     have_libv4l2=no
 591   fi
 592 fi
 593
 594 dnl Allow enabling v4l2 device probing
 595 AS_CASE([$host],
 596     [*-*linux*],
 597       [AS_CASE([$host_cpu],
 598         [arm*], [
 599           enable_v4l2_probe="yes"],
 600         [aarch64*], [
 601           enable_v4l2_probe="yes"])])
 602 AC_ARG_ENABLE(
 603   v4l2-probe,
 604   AC_HELP_STRING(
 605     [--enable-v4l2-probe],
 606     [enable V4L2 plugin to probe devices @<:@default=no@:>@]))
 607 if test "x$enable_v4l2_probe" = "xyes"; then
 608   AC_DEFINE(GST_V4L2_ENABLE_PROBE, 1,
 609     [Define if Video4Linux probe shall be run at plugin load])
 610 fi
 611
 612 dnl Check for X11
 613 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 614 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 615                   [ximagesrc], [
 616   PKG_CHECK_MODULES([X], [x11], [
 617     HAVE_X="yes"
 618     dnl check for Xfixes
 619     PKG_CHECK_MODULES([XFIXES], [ xfixes ], [
 620       AC_DEFINE(HAVE_XFIXES, 1, [Defined if Xfixes is available])
 621     ], [ HAVE_XFIXES="no" ])
 622
 623     dnl check for Xdamage
 624     PKG_CHECK_MODULES([XDAMAGE], [ xdamage ], [
 625       AC_DEFINE(HAVE_XDAMAGE, 1, [Defined if Xdamage is available])
 626     ], [ HAVE_XDAMAGE="no" ])
 627
 628     dnl check for X Shm
 629     PKG_CHECK_MODULES([XEXT], [ xext ], [
 630       AC_CHECK_LIB([Xext], [ XShmAttach ], [
 631         AC_DEFINE(HAVE_XSHM, 1, [Defined if XShm is available])
 632         XSHM_LIBS="$XEXT_LIBS"
 633         XSHM_CFLAGS="$XEXT_CFLAGS"
 634       ], [ HAVE_XEXT="no" ] , [ $X_LIBS ])
 635     ])
 636     AC_SUBST(XSHM_LIBS)
 637     AC_SUBST(XSHM_CFLAGS)
 638   ], [ HAVE_X="no" ])
 639 ])
 640
 641 dnl *** ext plug-ins ***
 642 dnl keep this list sorted alphabetically !
 643
 644 if test "x$BUILD_EXTERNAL" = "xyes"; then
 645
 646 echo
 647 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 648 echo
 649
 650 dnl *** aalib ***
 651 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 652 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 653   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 654 ])
 655
 656 dnl *** cairo ***
 657 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 658 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering and gobject bindings], cairo, [
 659   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.10.0 cairo-gobject >= 1.10.0)
 660 ])
 661
 662 dnl *** FLAC ***
 663 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 664 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 665   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 666 ])
 667
 668 dnl *** GDK pixbuf ***
 669 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 670 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 671   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 672 ])
 673
 674 dnl *** gtk+ ***
 675 HAVE_GTK3_GL="no"
 676 translit(dnm, m, l) AM_CONDITIONAL(USE_GTK3, true)
 677 AG_GST_CHECK_FEATURE(GTK3, [Gtk+ elements], gtk, [
 678   PKG_CHECK_MODULES(GTK3, gtk+-3.0, [
 679     AC_DEFINE([HAVE_GTK3], 1, [Define if Gtk+ 3.0 is installed])
 680     HAVE_GTK3="yes"
 681   ], [
 682     HAVE_GTK3="no"
 683   ])
 684   PKG_CHECK_MODULES(GTK3_GL, gtk+-3.0 >= 3.15.0, [
 685     GDK_WINDOWING="no"
 686     if test "x$GST_GL_HAVE_WINDOW_X11" = "x1" -a "x$GST_GL_HAVE_PLATFORM_GLX" = "x1"; then
 687       PKG_CHECK_MODULES(GTK3_X11, gtk+-x11-3.0, [
 688         GTK3_CFLAGS="$GTK3_CFLAGS $GTK3_X11_CFLAGS"
 689         GTK3_LIBS="$GTK3_LIBS $GTK3_X11_LIBS"
 690         GDK_WINDOWING="yes"
 691       ], [AC_MSG_NOTICE([Could not find Gtk X11 integration])])
 692     fi
 693     if test "x$GST_GL_HAVE_WINDOW_WAYLAND" = "x1" -a "x$GST_GL_HAVE_PLATFORM_EGL" = "x1"; then
 694       PKG_CHECK_MODULES(GTK3_WAYLAND, gtk+-wayland-3.0, [
 695         GTK3_CFLAGS="$GTK3_CFLAGS $GTK3_WAYLAND_CFLAGS"
 696         GTK3_LIBS="$GTK3_LIBS $GTK3_WAYLAND_LIBS"
 697         GDK_WINDOWING="yes"
 698       ], [AC_MSG_NOTICE([Could not find Gtk Wayland integration])])
 699     fi
 700     if test "x$GDK_WINDOWING" = "xyes" -a "x$HAVE_GST_GL" = "xyes"; then
 701       AC_DEFINE([HAVE_GTK3_GL], 1, [Define if Gtk+ 3.0 GL is installed])
 702       HAVE_GTK3_GL="yes"
 703     fi
 704   ], [
 705       HAVE_GTK3_GL="no"
 706   ])
 707 ])
 708 AM_CONDITIONAL(USE_GTK3_GL, test "x$HAVE_GTK3_GL" = "xyes")
 709
 710 dnl *** Jack ***
 711 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 712 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 713   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 714   AC_SUBST(JACK_CFLAGS)
 715   AC_SUBST(JACK_LIBS)
 716
 717   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 718   if test x$HAVE_JACK_0_120_1 = xyes; then
 719     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 720   fi
 721   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 722   if test x$HAVE_JACK_1_9_7 = xyes; then
 723     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 724   fi
 725
 726 ])
 727
 728 dnl *** jpeg ***
 729 dnl FIXME: we could use header checks here as well IMO
 730 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 731 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 732   AC_ARG_WITH(jpeg-mmx,
 733     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 734   OLD_LIBS="$LIBS"
 735   if test x$with_jpeg_mmx != x; then
 736     LIBS="$LIBS -L$with_jpeg_mmx"
 737   fi
 738   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 739   JPEG_LIBS="$LIBS -ljpeg-mmx"
 740   LIBS="$OLD_LIBS"
 741   if test x$HAVE_JPEG != xyes; then
 742     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 743     JPEG_LIBS="-ljpeg"
 744   fi
 745   AC_SUBST(JPEG_LIBS)
 746 ])
 747
 748 dnl *** lame ***
 749 translit(dnm, m, l) AM_CONDITIONAL(USE_LAME, true)
 750 AG_GST_CHECK_FEATURE(LAME, [lame mp3 encoder library], lame, [
 751   AG_GST_CHECK_LIBHEADER(LAME, mp3lame, lame_init, $LIBM, lame/lame.h,
 752   [
 753     HAVE_LAME="yes"
 754     LAME_LIBS="-lmp3lame $LIBM"
 755     dnl is lame presets available
 756     LAME_CFLAGS=""
 757     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <lame/lame.h>]], [[ int preset = MEDIUM ]])],[LAME_CFLAGS="-DGSTLAME_PRESET"],[LAME_CFLAGS=""
 758     ])
 759     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <lame/lame.h>]], [[
 760         void *ptr = &lame_set_VBR_quality
 761       ]])],[LAME_CFLAGS="$LAME_CFLAGS -DHAVE_LAME_SET_VBR_QUALITY"],[LAME_CFLAGS="$LAME_CFLAGS"
 762     ])
 763   AC_SUBST(LAME_CFLAGS)
 764   AC_SUBST(LAME_LIBS)
 765   ])
 766 ])
 767
 768 dnl *** libcaca ***
 769 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 770 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 771   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 772 ])
 773
 774 dnl *** libdv ***
 775 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 776 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 777   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 778 ])
 779
 780 dnl *** libpng ***
 781 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 782 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 783   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 784   if test $HAVE_LIBPNG = "yes"; then
 785     PKG_CHECK_MODULES(LIBPNG_1_5, libpng >= 1.5.1, [
 786         AC_DEFINE(HAVE_LIBPNG_1_5, 1, [Defined if libpng version is 1.5.1 or newer])
 787       ], [true])
 788   fi
 789 ])
 790
 791 dnl *** mpg123 ***
 792 translit(dnm, m, l) AM_CONDITIONAL(USE_MPG123, true)
 793 AG_GST_CHECK_FEATURE(MPG123, [mpg123 audio decoder], mpg123, [
 794   PKG_CHECK_MODULES(MPG123, libmpg123 >= 1.13, HAVE_MPG123="yes", HAVE_MPG123="no")
 795   AC_SUBST(MPG123_CFLAGS)
 796   AC_SUBST(MPG123_LIBS)
 797 ])
 798
 799 dnl *** pulseaudio ***
 800 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 801 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 802
 803   dnl used in ext/pulse/pulseutil.c
 804   AC_CHECK_HEADERS([process.h])
 805
 806   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 2.0)
 807 ])
 808
 809 dnl *** dv1394 ***
 810 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 811 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 812   dnl first test for libraw1394 >= 2.0.0
 813   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 814   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 815   dnl now see how far we got
 816   if test x$HAVE_RAW1394 = xyes && \
 817      test x$HAVE_LIBIEC61883 = xyes; then
 818        AG_GST_CHECK_LIBHEADER(AVC1394,
 819         avc1394, avc1394_send_command, $RAW1394_LIBS,
 820         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 821        AG_GST_CHECK_LIBHEADER(ROM1394,
 822         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 823         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 824        if test x$HAVE_AVC1394 = xyes && \
 825           test x$HAVE_AVC1394 = xyes && \
 826           test x$HAVE_ROM1394 = xyes; then
 827           HAVE_DV1394=yes
 828           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 829           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 830           AC_SUBST(DV1394_CFLAGS)
 831           AC_SUBST(DV1394_LIBS)
 832         fi
 833   else
 834        if test x$HAVE_RAW1394 = xno; then
 835           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 836           AG_GST_CHECK_LIBHEADER(AVC1394,
 837            avc1394, avc1394_send_command, $RAW1394_LIBS,
 838            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 839           AG_GST_CHECK_LIBHEADER(ROM1394,
 840            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 841            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 842           if test x$HAVE_RAW1394 = xyes && \
 843              test x$HAVE_AVC1394 = xyes && \
 844              test x$HAVE_ROM1394 = xyes; then
 845              HAVE_DV1394=yes
 846              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 847              DV1394_CFLAGS="$RAW1394_CFLAGS"
 848              if test x$HAVE_LIBIEC61883 = xyes; then
 849                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 850                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 851              fi
 852              AC_SUBST(DV1394_CFLAGS)
 853              AC_SUBST(DV1394_LIBS)
 854            fi
 855          fi
 856   fi
 857 ])
 858 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 859
 860 dnl *** Qt ***
 861 translit(dnm, m, l) AM_CONDITIONAL(USE_QT, true)
 862 AG_GST_CHECK_FEATURE(QT, [Qt elements], qt, [
 863   PKG_CHECK_MODULES(QT, Qt5Core Qt5Gui Qt5Qml Qt5Quick >= 5.4.0, [
 864       QT_PATH=`$PKG_CONFIG --variable=exec_prefix Qt5Core`
 865       QT_HOST_PATH=`$PKG_CONFIG --variable=host_bins Qt5Core`
 866       AC_ARG_WITH([moc],
 867            AS_HELP_STRING([--with-moc], [Set location of qt moc tool]),
 868            [MOC=$withval])
 869       AC_PATH_PROGS(MOC, [moc-qt5 moc], [moc], ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
 870       AC_ARG_WITH([rcc],
 871            AS_HELP_STRING([--with-rcc], [Set location of qt rcc tool]),
 872            [RCC=$withval])
 873       AC_PATH_PROGS(RCC, [rcc-qt5 rcc], [rcc], ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
 874       AC_ARG_WITH([uic],
 875                AS_HELP_STRING([--with-uic], [Set location of qt uic tool]),
 876                [UIC=$withval])
 877       AC_PATH_PROGS(UIC, [uic-qt5 uic], [uic], ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
 878       if test "x$MOC" = "x" || test "x$UIC" = "x" || test "x$RCC" = "x"; then
 879         AC_MSG_WARN([One of the required qt build programs was not found])
 880         HAVE_QT="no"
 881       else
 882         HAVE_QT="yes"
 883         HAVE_QT_WINDOWING="no"
 884         QT_VERSION="`$PKG_CONFIG --define-prefix --modversion Qt5Core`"
 885         QPA_INCLUDE_PATH=`$PKG_CONFIG --variable=includedir Qt5Core`/QtGui/${QT_VERSION}/QtGui
 886         AS_IF([test -f "$PKG_CONFIG_SYSROOT_DIR/$QPA_INCLUDE_PATH/qpa/qplatformnativeinterface.h"], [
 887           QT_CFLAGS="$QT_CFLAGS -I$PKG_CONFIG_SYSROOT_DIR/$QPA_INCLUDE_PATH"
 888           HAVE_QT_QPA_HEADER="yes"
 889         ], [AC_MSG_NOTICE([Cannot find QPA])])
 890         if test "x$GST_GL_HAVE_WINDOW_X11" = "x1" -a "x$GST_GL_HAVE_PLATFORM_GLX" = "x1" || test "x$GST_GL_HAVE_WINDOW_X11" = "x1" -a "x$GST_GL_HAVE_PLATFORM_EGL" = "x1"; then
 891           PKG_CHECK_MODULES(QT_X11, Qt5X11Extras, [
 892             AC_DEFINE([HAVE_QT_X11], [], [Define if Qt X11 integration is installed])
 893             QT_CFLAGS="$QT_CFLAGS $QT_X11_CFLAGS"
 894             QT_LIBS="$QT_LIBS $QT_X11_LIBS"
 895             HAVE_QT_WINDOWING="yes"
 896           ], [AC_MSG_NOTICE([Could not find Qt X11 integration])])
 897         fi
 898         if test "x$GST_GL_HAVE_WINDOW_WAYLAND" = "x1" -a "x$GST_GL_HAVE_PLATFORM_EGL" = "x1" -a "x$HAVE_QT_QPA_HEADER" = "xyes"; then
 899           PKG_CHECK_MODULES(QT_WAYLAND, Qt5WaylandClient, [
 900             AC_DEFINE([HAVE_QT_WAYLAND], [],
 901                 [Define if Qt Wayland integration is installed])
 902             QT_CFLAGS="$QT_CFLAGS $QT_WAYLAND_CFLAGS"
 903             QT_LIBS="$QT_LIBS $QT_WAYLAND_LIBS"
 904             HAVE_QT_WINDOWING="yes"
 905           ], [AC_MSG_NOTICE([Could not find Qt Wayland integration])])
 906         fi
 907         if test "x$GST_GL_HAVE_PLATFORM_EGL" = "x1"; then
 908           if test "x$GST_GL_HAVE_WINDOW_ANDROID" = "x1"; then
 909             PKG_CHECK_MODULES(QT_ANDROID, Qt5AndroidExtras, [
 910               # c++ on android requires a standard library and there are multiple
 911               # choices.  cerbero provides a pkg-config file the describes a choice
 912               # so try to use that.  Outside cerbero one has to pass these flags
 913               # manually for the library one is using
 914               PKG_CHECK_MODULES(GNUSTL, gnustl, [
 915                 QT_CFLAGS="$QT_CFLAGS $GNUSTL_CFLAGS"
 916                 QT_LIBS="$QT_LIBS $GNUSTL_LIBS"
 917                 ], [
 918                 AC_MSG_NOTICE([Could not find Standard C++ library])])
 919               AC_DEFINE([HAVE_QT_EGLFS], [],
 920                 [Define if Qt eglfs integration is installed])
 921               QT_CFLAGS="$QT_CFLAGS $QT_ANDROID_CFLAGS"
 922               QT_LIBS="$QT_LIBS $QT_ANDROID_LIBS"
 923               HAVE_QT_WINDOWING="yes"
 924             ], [AC_MSG_NOTICE([Could not find Qt Android integration])])
 925           else
 926               AC_DEFINE([HAVE_QT_EGLFS], [],
 927                 [Define if Qt eglfs integration is installed])
 928               HAVE_QT_WINDOWING="yes"
 929           fi
 930         fi
 931         if test "x$GST_GL_HAVE_WINDOW_COCOA" = "x1" -a "x$GST_GL_HAVE_PLATFORM_CGL" = "x1"; then
 932           PKG_CHECK_MODULES(QT_MAC, Qt5MacExtras, [
 933             AC_DEFINE([HAVE_QT_MAC], [],
 934                 [Define if Qt Mac integration is installed])
 935             QT_LIBDIR=`$PKG_CONFIG --variable=libdir Qt5Core`
 936             QT_CFLAGS="$QT_CFLAGS $QT_MAC_CFLAGS -F$QT_LIBDIR -framework QtCore -framework QtGui -framework QtQuick -framework QtQml -framework QtMacExtras"
 937             QT_LIBS="$QT_LIBS $QT_MAC_LIBS"
 938             HAVE_QT_WINDOWING="yes"
 939           ], [AC_MSG_NOTICE([Could not find Qt Mac integration])])
 940         fi
 941         if test "x$GST_GL_HAVE_WINDOW_EAGL" = "x1" -a "x$GST_GL_HAVE_PLATFORM_EAGL" = "x1"; then
 942           if test "x$HAVE_IOS" = "xyes"; then
 943             # iOS doesn't have its own extras package so if we have the core
 944             # modules we are good to go
 945             AC_DEFINE([HAVE_QT_IOS], [],
 946                 [Define if Qt iOS integration is installed])
 947             HAVE_QT_WINDOWING="yes"
 948           fi
 949         fi
 950         if test "x$HAVE_QT_WINDOWING" = "xno"; then
 951           AC_MSG_WARN([Could not find any Qt Windowing integration])
 952           HAVE_QT="no"
 953         fi
 954         AC_SUBST([QT_CFLAGS])
 955         AC_SUBST([QT_LIBS])
 956       fi
 957   ], [
 958       HAVE_QT="no"
 959   ])
 960 ])
 961
 962 dnl *** shout2 ***
 963 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 964 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 965   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 966 ])
 967
 968 dnl *** soup ***
 969 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 970 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 971   PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.48, [HAVE_SOUP="yes"], [HAVE_SOUP="no"])
 972   AC_SUBST(SOUP_CFLAGS)
 973   AC_SUBST(SOUP_LIBS)
 974 ])
 975
 976 dnl *** speex ***
 977 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 978 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 979   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 980 ])
 981
 982 dnl *** taglib ***
 983 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 984 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 985   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 986   if test "x$HAVE_CXX" != "xyes"; then
 987     USE_TAGLIB=false
 988     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 989   else
 990     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 991     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 992         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 993       ], [
 994         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 995     ])
 996     AC_SUBST(TAGLIB_CXXFLAGS)
 997   fi
 998 ])
 999
1000 dnl *** twolame ***
1001 translit(dnm, m, l) AM_CONDITIONAL(USE_TWOLAME, true)
1002 AG_GST_CHECK_FEATURE(TWOLAME, [twolame], twolame, [
1003   PKG_CHECK_MODULES(TWOLAME, twolame >= 0.3.10, [
1004       HAVE_TWOLAME="yes"], [
1005       HAVE_TWOLAME="no"
1006   ])
1007   AC_SUBST(TWOLAME_CFLAGS)
1008   AC_SUBST(TWOLAME_LIBS)
1009 ])
1010
1011
1012 dnl *** vpx ***
1013 translit(dnm, m, l) AM_CONDITIONAL(USE_VPX, vpx)
1014 AG_GST_CHECK_FEATURE(VPX, [VPX decoder], vpx, [
1015   PKG_CHECK_MODULES(VPX, vpx >= 1.1.0, [HAVE_VPX="yes"], [HAVE_VPX="no"])
1016   HAVE_VP8=no
1017   HAVE_VP9=no
1018
1019   if test $HAVE_VPX = "yes"; then
1020     OLD_LIBS="$LIBS"
1021     OLD_CFLAGS="$CFLAGS"
1022     CFLAGS="$CFLAGS $VPX_CFLAGS"
1023     LIBS="$LIBS $VPX_LIBS"
1024     AC_CHECK_LIB(vpx, vpx_codec_vp8_cx_algo, [
1025       HAVE_VP8=yes
1026       AC_DEFINE(HAVE_VP8_ENCODER, 1, [Defined if the VP8 encoder is available])
1027     ])
1028     AC_CHECK_LIB(vpx, vpx_codec_vp8_dx_algo, [
1029       HAVE_VP8=yes
1030       AC_DEFINE(HAVE_VP8_DECODER, 1, [Defined if the VP8 decoder is available])
1031     ])
1032
1033     PKG_CHECK_MODULES(VPX_130, vpx >= 1.3.0, [
1034       AC_CHECK_LIB(vpx, vpx_codec_vp9_cx_algo, [
1035         HAVE_VP9=yes
1036         AC_DEFINE(HAVE_VP9_ENCODER, 1, [Defined if the VP9 encoder is available])
1037       ])
1038       AC_CHECK_LIB(vpx, vpx_codec_vp9_dx_algo, [
1039         HAVE_VP9=yes
1040         AC_DEFINE(HAVE_VP9_DECODER, 1, [Defined if the VP9 decoder is available])
1041       ])
1042     ], [true])
1043
1044     PKG_CHECK_MODULES(VPX_140, vpx >= 1.4.0, [
1045       AC_DEFINE(HAVE_VPX_1_4, 1, [Defined if the VPX library version is 1.4 or bigger])
1046     ], [true])
1047
1048     LIBS="$OLD_LIBS"
1049     CFLAGS="$OLD_CFLAGS"
1050   fi
1051   AC_SUBST(VPX_LIBS)
1052   AC_SUBST(VPX_CFLAGS)
1053 ])
1054
1055 dnl *** wavpack ***
1056 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
1057 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
1058   AG_GST_PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.60.0)
1059 ])
1060
1061 dnl *** qtdemux & matroska prefer to have zlib ***
1062 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
1063 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
1064   AG_GST_CHECK_LIBHEADER(ZLIB,
1065     z, uncompress,, zlib.h, [
1066     HAVE_ZLIB="yes"
1067     ZLIB_LIBS="-lz"
1068     AC_SUBST(ZLIB_LIBS)
1069   ])
1070 ])
1071
1072 dnl *** matroska prefers to have bz2 ***
1073 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
1074 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
1075   save_LIBS=$LIBS
1076   LIBS="$LIBS -lbz2"
1077   AC_MSG_CHECKING([for BZ2_bzlibVersion in -lbz2])
1078   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <bzlib.h>]], [[const char *version = BZ2_bzlibVersion ();]])],[HAVE_BZ2=yes],[HAVE_BZ2=no])
1079   AC_MSG_RESULT($HAVE_BZ2)
1080   LIBS=$save_LIBS
1081   if test "x$HAVE_BZ2" = "xyes"; then
1082     BZ2_LIBS="-lbz2"
1083   fi
1084   AC_SUBST(BZ2_LIBS)
1085 ])
1086
1087 else
1088
1089 dnl not building plugins with external dependencies,
1090 dnl but we still need to set the conditionals
1091 AM_CONDITIONAL(USE_AALIB, false)
1092 AM_CONDITIONAL(USE_BZ2, false)
1093 AM_CONDITIONAL(USE_CAIRO, false)
1094 AM_CONDITIONAL(USE_DIRECTSOUND, false)
1095 AM_CONDITIONAL(USE_DV1394, false)
1096 AM_CONDITIONAL(USE_FLAC, false)
1097 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
1098 AM_CONDITIONAL(USE_GTK3, false)
1099 AM_CONDITIONAL(USE_GTK3_GL, false)
1100 AM_CONDITIONAL(USE_JACK, false)
1101 AM_CONDITIONAL(USE_JPEG, false)
1102 AM_CONDITIONAL(USE_LAME, false)
1103 AM_CONDITIONAL(USE_LIBCACA, false)
1104 AM_CONDITIONAL(USE_LIBDV, false)
1105 AM_CONDITIONAL(USE_LIBIEC61883, false)
1106 AM_CONDITIONAL(USE_LIBPNG, false)
1107 AM_CONDITIONAL(USE_MPG123, false)
1108 AM_CONDITIONAL(USE_OSS, false)
1109 AM_CONDITIONAL(USE_OSS4, false)
1110 AM_CONDITIONAL(USE_OSX_AUDIO, false)
1111 AM_CONDITIONAL(USE_OSX_VIDEO, false)
1112 AM_CONDITIONAL(USE_PULSE, false)
1113 AM_CONDITIONAL(USE_QT, false)
1114 AM_CONDITIONAL(USE_SHOUT2, false)
1115 AM_CONDITIONAL(USE_SOUP, false)
1116 AM_CONDITIONAL(USE_SPEEX, false)
1117 AM_CONDITIONAL(USE_TAGLIB, false)
1118 AM_CONDITIONAL(USE_TWOLAME, false)
1119 AM_CONDITIONAL(USE_VPX, false)
1120 AM_CONDITIONAL(USE_WAVEFORM, false)
1121 AM_CONDITIONAL(USE_WAVPACK, false)
1122 AM_CONDITIONAL(USE_X, false)
1123 AM_CONDITIONAL(USE_ZLIB, false)
1124
1125 fi dnl of EXT plugins
1126
1127 dnl *** finalize CFLAGS, LDFLAGS, LIBS
1128
1129 dnl Overview:
1130 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1131 dnl GST_*:              flags shared by all built objects
1132 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1133 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
1134 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1135 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1136
1137 dnl GST_OPTION_CFLAGS
1138 if test "x$USE_DEBUG" = xyes; then
1139    PROFILE_CFLAGS="-g"
1140 fi
1141 AC_SUBST(PROFILE_CFLAGS)
1142
1143 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1144   dnl Define _only_ for git (not pre-releases or releases)
1145   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1146 else
1147   DEPRECATED_CFLAGS=""
1148 fi
1149 AC_SUBST(DEPRECATED_CFLAGS)
1150
1151 VISIBILITY_CFLAGS=""
1152 AS_COMPILER_FLAG([-fvisibility=hidden], [VISIBILITY_CFLAGS="-fvisibility=hidden"])
1153 AC_SUBST(VISIBILITY_CFLAGS)
1154
1155 VISIBILITY_CXXFLAGS=""
1156 if test "x$HAVE_CXX" = "xyes"; then
1157   AS_CXX_COMPILER_FLAG([-fvisibility=hidden], [VISIBILITY_CXXFLAGS="-fvisibility=hidden"])
1158 fi
1159 AC_SUBST(VISIBILITY_CXXFLAGS)
1160
1161 dnl disable strict aliasing
1162 AS_COMPILER_FLAG([-fno-strict-aliasing], [EXTRA_CFLAGS="-fno-strict-aliasing"])
1163 AC_SUBST(EXTRA_CFLAGS)
1164
1165 dnl every flag in GST_OPTION_CFLAGS, GST_OPTION_CXXFLAGS and GST_OPTION_OBJCFLAGS can be overridden
1166 dnl at make time with e.g. make ERROR_CFLAGS=""
1167 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1168 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1169 GST_OPTION_OBJCFLAGS="\$(WARNING_OBJCFLAGS) \$(ERROR_OBJCFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1170 AC_SUBST(GST_OPTION_CFLAGS)
1171 AC_SUBST(GST_OPTION_CXXFLAGS)
1172 AC_SUBST(GST_OPTION_OBJCFLAGS)
1173
1174 dnl our libraries need to be versioned correctly
1175 AC_SUBST(GST_LT_LDFLAGS)
1176
1177 dnl FIXME: do we want to rename to GST_ALL_* ?
1178 dnl prefer internal headers to already installed ones
1179 dnl also add builddir include for enumtypes and marshal
1180 dnl add ERROR_CFLAGS, but overridable
1181 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
1182 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $EXTRA_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS) \$(VISIBILITY_CXXFLAGS)"
1183 GST_OBJCFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $EXTRA_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_OBJCFLAGS)"
1184 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $EXTRA_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS) \$(VISIBILITY_CFLAGS)"
1185 AC_SUBST(GST_CFLAGS)
1186 AC_SUBST(GST_CXXFLAGS)
1187 AC_SUBST(GST_OBJCFLAGS)
1188 AC_SUBST(GST_LIBS)
1189
1190 dnl LDFLAGS really should only contain flags, not libs - they get added before
1191 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1192 GST_ALL_LDFLAGS="-no-undefined"
1193 if test "x${enable_Bsymbolic}" = "xyes"; then
1194   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
1195 fi
1196 AC_SUBST(GST_ALL_LDFLAGS)
1197
1198 dnl this really should only contain flags, not libs - they get added before
1199 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1200 GST_PLUGIN_LDFLAGS="-module -avoid-version $GST_ALL_LDFLAGS"
1201 AC_SUBST(GST_PLUGIN_LDFLAGS)
1202
1203 dnl *** output files ***
1204
1205 $MKDIR_P tests/check/orc
1206
1207 dnl keep this alphabetic per directory, please
1208 AC_CONFIG_FILES(
1209 Makefile
1210 gst/Makefile
1211 gst/alpha/Makefile
1212 gst/apetag/Makefile
1213 gst/audiofx/Makefile
1214 gst/audioparsers/Makefile
1215 gst/auparse/Makefile
1216 gst/autodetect/Makefile
1217 gst/avi/Makefile
1218 gst/cutter/Makefile
1219 gst/deinterlace/Makefile
1220 gst/dtmf/Makefile
1221 gst/debugutils/Makefile
1222 gst/effectv/Makefile
1223 gst/equalizer/Makefile
1224 gst/flv/Makefile
1225 gst/goom/Makefile
1226 gst/goom2k1/Makefile
1227 gst/id3demux/Makefile
1228 gst/icydemux/Makefile
1229 gst/imagefreeze/Makefile
1230 gst/interleave/Makefile
1231 gst/isomp4/Makefile
1232 gst/law/Makefile
1233 gst/level/Makefile
1234 gst/matroska/Makefile
1235 gst/monoscope/Makefile
1236 gst/multifile/Makefile
1237 gst/multipart/Makefile
1238 gst/replaygain/Makefile
1239 gst/rtp/Makefile
1240 gst/rtpmanager/Makefile
1241 gst/rtsp/Makefile
1242 gst/shapewipe/Makefile
1243 gst/smpte/Makefile
1244 gst/spectrum/Makefile
1245 gst/udp/Makefile
1246 gst/videobox/Makefile
1247 gst/videocrop/Makefile
1248 gst/videofilter/Makefile
1249 gst/videomixer/Makefile
1250 gst/wavenc/Makefile
1251 gst/wavparse/Makefile
1252 gst/flx/Makefile
1253 gst/y4m/Makefile
1254 ext/Makefile
1255 ext/aalib/Makefile
1256 ext/cairo/Makefile
1257 ext/dv/Makefile
1258 ext/flac/Makefile
1259 ext/gdk_pixbuf/Makefile
1260 ext/gtk/Makefile
1261 ext/jack/Makefile
1262 ext/jpeg/Makefile
1263 ext/lame/Makefile
1264 ext/libcaca/Makefile
1265 ext/libpng/Makefile
1266 ext/mpg123/Makefile
1267 ext/pulse/Makefile
1268 ext/qt/Makefile
1269 ext/raw1394/Makefile
1270 ext/shout2/Makefile
1271 ext/soup/Makefile
1272 ext/speex/Makefile
1273 ext/taglib/Makefile
1274 ext/twolame/Makefile
1275 ext/vpx/Makefile
1276 ext/wavpack/Makefile
1277 sys/Makefile
1278 sys/directsound/Makefile
1279 sys/oss/Makefile
1280 sys/oss4/Makefile
1281 sys/osxaudio/Makefile
1282 sys/osxvideo/Makefile
1283 sys/v4l2/Makefile
1284 sys/waveform/Makefile
1285 sys/ximage/Makefile
1286 po/Makefile.in
1287 tests/Makefile
1288 tests/check/Makefile
1289 tests/examples/Makefile
1290 tests/examples/audiofx/Makefile
1291 tests/examples/cairo/Makefile
1292 tests/examples/equalizer/Makefile
1293 tests/examples/gtk/Makefile
1294 tests/examples/jack/Makefile
1295 tests/examples/level/Makefile
1296 tests/examples/rtp/Makefile
1297 tests/examples/shapewipe/Makefile
1298 tests/examples/spectrum/Makefile
1299 tests/examples/v4l2/Makefile
1300 tests/files/Makefile
1301 tests/icles/Makefile
1302 common/Makefile
1303 common/m4/Makefile
1304 m4/Makefile
1305 docs/Makefile
1306 docs/plugins/Makefile
1307 docs/version.entities
1308 pkgconfig/Makefile
1309 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1310 )
1311 AC_OUTPUT
1312
1313 AG_GST_OUTPUT_PLUGINS
1314 ORC_OUTPUT
1315